sysdeps/unix/sysv/linux/powerpc/powerpc32/makecontext.S

   1 /* Set up a context to call a function.
   2    Copyright (C) 2002, 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <shlib-compat.h>
  22
  23 #define __ASSEMBLY__
  24 #include <asm/ptrace.h>
  25 #include "ucontext_i.h"
  26
  27 ENTRY(__makecontext)
  28         /* Set up the first 7 args to the function in its registers */
  29         addi    r11,r3,_UC_REG_SPACE+12
  30         clrrwi  r11,r11,4
  31         stw     r11,_UC_REGS_PTR(r3)
  32         stw     r6,_UC_GREGS+(PT_R3*4)(r11)
  33         stw     r7,_UC_GREGS+(PT_R4*4)(r11)
  34         stw     r8,_UC_GREGS+(PT_R5*4)(r11)
  35         stw     r9,_UC_GREGS+(PT_R6*4)(r11)
  36         stw     r10,_UC_GREGS+(PT_R7*4)(r11)
  37         lwz     r8,8(r1)
  38         lwz     r9,12(r1)
  39         stw     r8,_UC_GREGS+(PT_R8*4)(r11)
  40         stw     r9,_UC_GREGS+(PT_R9*4)(r11)
  41
  42         /* Set the NIP to the start of the function */
  43         stw     r4,_UC_GREGS+(PT_NIP*4)(r11)
  44
  45         /* Set the function's r31 to ucp->uc_link for the exitcode below. */
  46         lwz     r7,_UC_LINK(r3)
  47         stw     r7,_UC_GREGS+(PT_R31*4)(r11)
  48
  49         /* Set the function's LR to point to the exitcode below. */
  50 #ifdef PIC
  51         mflr    r0
  52         bl      1f
  53 1:      mflr    r6
  54         addi    r6,r6,L(exitcode)-1b
  55         mtlr    r0
  56 #else
  57         lis     r6,L(exitcode)@ha
  58         addi    r6,r6,L(exitcode)@l
  59 #endif
  60         stw     r6,_UC_GREGS+(PT_LNK*4)(r11)
  61
  62         /*
  63          * Set up the stack frame for the function.
  64          * If we have more than 5 args to the function (8 args to makecontext),
  65          * there will be some arguments on the stack which have to end up
  66          * in registers.  If there are more than 8 args to the function,
  67          * we have to copy (argc - 8) args from our stack to the functions'
  68          * stack (and allow space for them in the frame).
  69          */
  70         lwz     r4,_UC_STACK_SP(r3)
  71         lwz     r8,_UC_STACK_SIZE(r3)
  72         add     r4,r4,r8
  73         rlwinm  r4,r4,0,0,27    /* round down to 16-byte boundary */
  74         addi    r7,r4,-16       /* stack frame for fn's caller */
  75         cmpwi   r5,8
  76         blt     2f              /* less than 8 args is easy */
  77         lwz     r10,16(r1)
  78         stw     r10,_UC_GREGS+(PT_R10*4)(r11)
  79         beq     2f              /* if exactly 8 args */
  80         subi    r9,r5,3
  81         subi    r5,r5,8
  82         rlwinm  r9,r9,2,0,27
  83         subf    r7,r9,r4
  84         mtctr   r5              /* copy the 9th and following args */
  85         addi    r6,r1,16
  86         addi    r8,r7,4
  87 3:      lwzu    r10,4(r6)
  88         stwu    r10,4(r8)
  89         bdnz    3b
  90 2:      stw     r7,_UC_GREGS+(PT_R1*4)(r11)
  91         li      r6,0
  92         stw     r6,0(r7)
  93
  94         blr
  95
  96 /*
  97  * If the function returns, it comes here.  We put ucp->uc_link in
  98  * r31, which is a callee-saved register.  We have to continue with
  99  * the context that r31 points to, or exit if it is 0.
 100  */
 101 L(exitcode):
 102         mr.     r3,r31
 103         beq     4f
 104         bl      JUMPTARGET(__setcontext)
 105 4:      bl      HIDDEN_JUMPTARGET(exit)
 106         b       4b
 107
 108 END(__makecontext)
 109
 110 versioned_symbol (libc, __makecontext, makecontext, GLIBC_2_3_4)
 111
 112 #if SHLIB_COMPAT (libc, GLIBC_2_3_3, GLIBC_2_3_4)
 113
 114 ENTRY(__novec_makecontext)
 115         /* Set up the first 7 args to the function in its registers */
 116         addi    r11,r3,_UC_REG_SPACE
 117         stw     r11,_UC_REGS_PTR(r3)
 118         stw     r6,_UC_GREGS+(PT_R3*4)(r11)
 119         stw     r7,_UC_GREGS+(PT_R4*4)(r11)
 120         stw     r8,_UC_GREGS+(PT_R5*4)(r11)
 121         stw     r9,_UC_GREGS+(PT_R6*4)(r11)
 122         stw     r10,_UC_GREGS+(PT_R7*4)(r11)
 123         lwz     r8,8(r1)
 124         lwz     r9,12(r1)
 125         stw     r8,_UC_GREGS+(PT_R8*4)(r11)
 126         stw     r9,_UC_GREGS+(PT_R9*4)(r11)
 127
 128         /* Set the NIP to the start of the function */
 129         stw     r4,_UC_GREGS+(PT_NIP*4)(r11)
 130
 131         /* Set the function's r31 to ucp->uc_link for the exitcode below. */
 132         lwz     r7,_UC_LINK(r3)
 133         stw     r7,_UC_GREGS+(PT_R31*4)(r11)
 134
 135         /* Set the function's LR to point to the exitcode below. */
 136 #ifdef PIC
 137         mflr    r0
 138         bl      1f
 139 1:      mflr    r6
 140         addi    r6,r6,L(novec_exitcode)-1b
 141         mtlr    r0
 142 #else
 143         lis     r6,L(novec_exitcode)@ha
 144         addi    r6,r6,L(novec_exitcode)@l
 145 #endif
 146         stw     r6,_UC_GREGS+(PT_LNK*4)(r11)
 147
 148         /*
 149          * Set up the stack frame for the function.
 150          * If we have more than 5 args to the function (8 args to makecontext),
 151          * there will be some arguments on the stack which have to end up
 152          * in registers.  If there are more than 8 args to the function,
 153          * we have to copy (argc - 8) args from our stack to the functions'
 154          * stack (and allow space for them in the frame).
 155          */
 156         lwz     r4,_UC_STACK_SP(r3)
 157         lwz     r8,_UC_STACK_SIZE(r3)
 158         add     r4,r4,r8
 159         rlwinm  r4,r4,0,0,27    /* round down to 16-byte boundary */
 160         addi    r7,r4,-16       /* stack frame for fn's caller */
 161         cmpwi   r5,8
 162         blt     2f              /* less than 8 args is easy */
 163         lwz     r10,16(r1)
 164         stw     r10,_UC_GREGS+(PT_R10*4)(r11)
 165         beq     2f              /* if exactly 8 args */
 166         subi    r9,r5,3
 167         subi    r5,r5,8
 168         rlwinm  r9,r9,2,0,27
 169         subf    r7,r9,r4
 170         mtctr   r5              /* copy the 9th and following args */
 171         addi    r6,r1,16
 172         addi    r8,r7,4
 173 3:      lwzu    r10,4(r6)
 174         stwu    r10,4(r8)
 175         bdnz    3b
 176 2:      stw     r7,_UC_GREGS+(PT_R1*4)(r11)
 177         li      r6,0
 178         stw     r6,0(r7)
 179
 180         blr
 181
 182 /*
 183  * If the function returns, it comes here.  We put ucp->uc_link in
 184  * r31, which is a callee-saved register.  We have to continue with
 185  * the context that r31 points to, or exit if it is 0.
 186  */
 187 L(novec_exitcode):
 188         mr.     r3,r31
 189         beq     4f
 190         bl      JUMPTARGET(__novec_setcontext)
 191 4:      bl      HIDDEN_JUMPTARGET(exit)
 192         b       4b
 193
 194 END(__makecontext)
 195
 196 compat_symbol (libc, __novec_makecontext, makecontext, GLIBC_2_3_3)
 197 #endif
 198
 199 #if SHLIB_COMPAT (libc, GLIBC_2_1, GLIBC_2_3_3)
 200
 201 #define _ERRNO_H        1
 202 #include <bits/errno.h>
 203
 204 ENTRY (__makecontext_stub)
 205         li      r3,ENOSYS
 206         b       JUMPTARGET(__syscall_error)
 207         END (__makecontext_stub)
 208
 209 compat_symbol (libc, __makecontext_stub, makecontext, GLIBC_2_1)
 210
 211 #endif