sysdeps/x86_64/setjmp.S

   1 /* setjmp for x86-64.
   2    Copyright (C) 2001, 2003, 2005, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <jmpbuf-offsets.h>
  21 #include <asm-syntax.h>
  22
  23 ENTRY (__sigsetjmp)
  24         /* Save registers.  */
  25         movq %rbx, (JB_RBX*8)(%rdi)
  26 #ifdef PTR_MANGLE
  27         movq %rbp, %rax
  28         PTR_MANGLE (%rax)
  29         movq %rax, (JB_RBP*8)(%rdi)
  30 #else
  31         movq %rbp, (JB_RBP*8)(%rdi)
  32 #endif
  33         movq %r12, (JB_R12*8)(%rdi)
  34         movq %r13, (JB_R13*8)(%rdi)
  35         movq %r14, (JB_R14*8)(%rdi)
  36         movq %r15, (JB_R15*8)(%rdi)
  37         leaq 8(%rsp), %rdx      /* Save SP as it will be after we return.  */
  38 #ifdef PTR_MANGLE
  39         PTR_MANGLE (%rdx)
  40 #endif
  41         movq %rdx, (JB_RSP*8)(%rdi)
  42         movq (%rsp), %rax       /* Save PC we are returning to now.  */
  43 #ifdef PTR_MANGLE
  44         PTR_MANGLE (%rax)
  45 #endif
  46         movq %rax, (JB_PC*8)(%rdi)
  47
  48 #if defined NOT_IN_libc && defined IS_IN_rtld
  49         /* In ld.so we never save the signal mask.  */
  50         xorl %eax, %eax
  51         retq
  52 #else
  53         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  54 # ifdef PIC
  55         jmp C_SYMBOL_NAME (BP_SYM (__sigjmp_save))@PLT
  56 # else
  57         jmp BP_SYM (__sigjmp_save)
  58 # endif
  59 #endif
  60 END (BP_SYM (__sigsetjmp))
  61 hidden_def (__sigsetjmp)