sysdeps/x86_64/elf/start.S

   1 /* Startup code compliant to the ELF x86-64 ABI.
   2    Copyright (C) 2001, 2002, 2003, 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Andreas Jaeger <aj@suse.de>, 2001.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, see
  35    <http://www.gnu.org/licenses/>.  */
  36
  37 /* This is the canonical entry point, usually the first thing in the text
  38    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  39    point runs, most registers' values are unspecified, except for:
  40
  41    %rdx         Contains a function pointer to be registered with `atexit'.
  42                 This is how the dynamic linker arranges to have DT_FINI
  43                 functions called for shared libraries that have been loaded
  44                 before this code runs.
  45
  46    %rsp         The stack contains the arguments and environment:
  47                 0(%rsp)                 argc
  48                 8(%rsp)                 argv[0]
  49                 ...
  50                 (8*argc)(%rsp)          NULL
  51                 (8*(argc+1))(%rsp)      envp[0]
  52                 ...
  53                                         NULL
  54 */
  55
  56 #include "bp-sym.h"
  57
  58         .text
  59         .globl _start
  60         .type _start,@function
  61 _start:
  62         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  63            the outermost frame obviously.  */
  64         xorl %ebp, %ebp
  65
  66         /* Extract the arguments as encoded on the stack and set up
  67            the arguments for __libc_start_main (int (*main) (int, char **, char **),
  68                    int argc, char *argv,
  69                    void (*init) (void), void (*fini) (void),
  70                    void (*rtld_fini) (void), void *stack_end).
  71            The arguments are passed via registers and on the stack:
  72         main:           %rdi
  73         argc:           %rsi
  74         argv:           %rdx
  75         init:           %rcx
  76         fini:           %r8
  77         rtld_fini:      %r9
  78         stack_end:      stack.  */
  79
  80         movq %rdx, %r9          /* Address of the shared library termination
  81                                    function.  */
  82         popq %rsi               /* Pop the argument count.  */
  83         movq %rsp, %rdx         /* argv starts just at the current stack top.  */
  84         /* Align the stack to a 16 byte boundary to follow the ABI.  */
  85         andq  $~15, %rsp
  86
  87         pushq %rax              /* Push garbage because we push 8 more bytes.  */
  88
  89         /* Provide the highest stack address to the user code (for stacks
  90            which grow downwards).  */
  91         pushq %rsp
  92
  93 #ifdef SHARED
  94         /* Pass address of our own entry points to .fini and .init.  */
  95         movq __libc_csu_fini@GOTPCREL(%rip), %r8
  96         movq __libc_csu_init@GOTPCREL(%rip), %rcx
  97
  98         movq BP_SYM (main)@GOTPCREL(%rip), %rdi
  99
 100         /* Call the user's main function, and exit with its value.
 101            But let the libc call main.    */
 102         call BP_SYM (__libc_start_main)@PLT
 103 #else
 104         /* Pass address of our own entry points to .fini and .init.  */
 105         movq $__libc_csu_fini, %r8
 106         movq $__libc_csu_init, %rcx
 107
 108         movq $BP_SYM (main), %rdi
 109
 110         /* Call the user's main function, and exit with its value.
 111            But let the libc call main.    */
 112         call BP_SYM (__libc_start_main)
 113 #endif
 114
 115         hlt                     /* Crash if somehow `exit' does return.  */
 116
 117 /* Define a symbol for the first piece of initialized data.  */
 118         .data
 119         .globl __data_start
 120 __data_start:
 121         .long 0
 122         .weak data_start
 123         data_start = __data_start