sysdeps/unix/sysv/linux/s390/s390-32/setcontext.S

   1 /* Copyright (C) 2001 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <features.h>
  21
  22 #include "ucontext_i.h"
  23
  24 /*  __setcontext (const ucontext_t *ucp)
  25
  26   Restores the machine context in UCP and thereby resumes execution
  27   in that context.
  28
  29   This implementation is intended to be used for *synchronous* context
  30   switches only.  Therefore, it does not have to restore anything
  31   other than the PRESERVED state.  */
  32
  33 ENTRY(__setcontext)
  34         lr      %r5,%r2
  35
  36         /* sigprocmask (SIG_SETMASK, &sc->sc_mask, NULL).  */
  37         la      %r2,SIG_BLOCK
  38         la      %r3,SC_MASK(%r5)
  39         slr     %r4,%r4
  40         svc     SYS_ify(rt_sigprocmask)
  41
  42         /* Load fpu context.  */
  43         lfpc    SC_FPC(%r5)
  44         ld      %f0,SC_FPRS(%r5)
  45         ld      %f1,SC_FPRS+8(%r5)
  46         ld      %f2,SC_FPRS+16(%r5)
  47         ld      %f3,SC_FPRS+24(%r5)
  48         ld      %f4,SC_FPRS+32(%r5)
  49         ld      %f5,SC_FPRS+40(%r5)
  50         ld      %f6,SC_FPRS+48(%r5)
  51         ld      %f7,SC_FPRS+56(%r5)
  52         ld      %f8,SC_FPRS+64(%r5)
  53         ld      %f9,SC_FPRS+72(%r5)
  54         ld      %f10,SC_FPRS+80(%r5)
  55         ld      %f11,SC_FPRS+88(%r5)
  56         ld      %f12,SC_FPRS+96(%r5)
  57         ld      %f13,SC_FPRS+104(%r5)
  58         ld      %f14,SC_FPRS+112(%r5)
  59         ld      %f15,SC_FPRS+120(%r5)
  60
  61         /* Don't touch %a0, used for thread purposes.  */
  62         lam     %a1,%a15,SC_ACRS+4(%r5)
  63
  64         /* Load general purpose registers.  */
  65         lm      %r0,%r15,SC_GPRS(%r5)
  66
  67         /* Return.  */
  68         br      %r14
  69 END(__setcontext)
  70
  71 weak_alias (__setcontext, setcontext)