sysdeps/unix/sysv/linux/s390/s390-32/getcontext.S

   1 /* Copyright (C) 2001 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <features.h>
  21
  22 #include "ucontext_i.h"
  23
  24 /*  __getcontext (const ucontext_t *ucp)
  25
  26   Saves the machine context in UCP such that when it is activated,
  27   it appears as if __getcontext() returned again.
  28
  29   This implementation is intended to be used for *synchronous* context
  30   switches only.  Therefore, it does not have to save anything
  31   other than the PRESERVED state.  */
  32
  33 ENTRY(__getcontext)
  34         lr      %r5,%r2
  35
  36         /* sigprocmask (SIG_BLOCK, NULL, &sc->sc_mask).  */
  37         la      %r2,SIG_BLOCK
  38         slr     %r3,%r3
  39         la      %r4,SC_MASK(%r5)
  40         svc     SYS_ify(rt_sigprocmask)
  41
  42         /* Store fpu context.  */
  43         stfpc   SC_FPC(%r5)
  44         std     %f0,SC_FPRS(%r5)
  45         std     %f1,SC_FPRS+8(%r5)
  46         std     %f2,SC_FPRS+16(%r5)
  47         std     %f3,SC_FPRS+24(%r5)
  48         std     %f4,SC_FPRS+32(%r5)
  49         std     %f5,SC_FPRS+40(%r5)
  50         std     %f6,SC_FPRS+48(%r5)
  51         std     %f7,SC_FPRS+56(%r5)
  52         std     %f8,SC_FPRS+64(%r5)
  53         std     %f9,SC_FPRS+72(%r5)
  54         std     %f10,SC_FPRS+80(%r5)
  55         std     %f11,SC_FPRS+88(%r5)
  56         std     %f12,SC_FPRS+96(%r5)
  57         std     %f13,SC_FPRS+104(%r5)
  58         std     %f14,SC_FPRS+112(%r5)
  59         std     %f15,SC_FPRS+120(%r5)
  60
  61         /* Set __getcontext return value to 0.  */
  62         slr     %r2,%r2
  63
  64         /* Store access registers.  */
  65         stam    %a0,%a15,SC_ACRS(%r5)
  66
  67         /* Store general purpose registers.  */
  68         stm     %r0,%r15,SC_GPRS(%r5)
  69
  70         /* Return.  */
  71         br      %r14
  72 END(__getcontext)
  73
  74 weak_alias (__getcontext, getcontext)