sysdeps/s390/s390-32/elf/start.S

   1 /* Startup code compliant to the ELF s390 ABI.
   2    Copyright (C) 2000, 2001, 2002, 2003, 2004, 2006
   3    Free Software Foundation, Inc.
   4    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    In addition to the permissions in the GNU Lesser General Public
  13    License, the Free Software Foundation gives you unlimited
  14    permission to link the compiled version of this file with other
  15    programs, and to distribute those programs without any restriction
  16    coming from the use of this file. (The GNU Lesser General Public
  17    License restrictions do apply in other respects; for example, they
  18    cover modification of the file, and distribution when not linked
  19    into another program.)
  20
  21    Note that people who make modified versions of this file are not
  22    obligated to grant this special exception for their modified
  23    versions; it is their choice whether to do so. The GNU Lesser
  24    General Public License gives permission to release a modified
  25    version without this exception; this exception also makes it
  26    possible to release a modified version which carries forward this
  27    exception.
  28
  29    The GNU C Library is distributed in the hope that it will be useful,
  30    but WITHOUT ANY WARRANTY; without even the implied warranty of
  31    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  32    Lesser General Public License for more details.
  33
  34    You should have received a copy of the GNU Lesser General Public
  35    License along with the GNU C Library; if not, see
  36    <http://www.gnu.org/licenses/>.  */
  37
  38 /*
  39    This is the canonical entry point, usually the first thing in the text
  40    segment. Most registers' values are unspecified, except for:
  41
  42    %r14         Contains a function pointer to be registered with `atexit'.
  43                 This is how the dynamic linker arranges to have DT_FINI
  44                 functions called for shared libraries that have been loaded
  45                 before this code runs.
  46
  47    %r15         The stack contains the arguments and environment:
  48                 0(%r15)                 argc
  49                 4(%r15)                 argv[0]
  50                 ...
  51                 (4*argc)(%r15)          NULL
  52                 (4*(argc+1))(%r15)      envp[0]
  53                 ...
  54                                         NULL
  55 */
  56
  57         .text
  58         .globl _start
  59         .type _start,@function
  60 _start:
  61         /* Check if the kernel provides highgprs facility if needed by
  62            the binary.  */
  63
  64         lr      %r6,%r15
  65         la      %r6,4(%r6)     /* Skip the argument counter.  */
  66
  67 .L11:   l       %r5,0(%r6)     /* Skip the argument vector.  */
  68         la      %r6,4(%r6)
  69         ltr     %r5,%r5
  70         jne     .L11
  71
  72 .L12:   l       %r5,0(%r6)     /* Skip the environment vector.  */
  73         la      %r6,4(%r6)
  74         ltr     %r5,%r5
  75         jne     .L12
  76
  77         /* Usually the auxiliary vector can be expected directly after
  78            the environment variables.  But we have to skip extra zeros
  79            because the loader might have removed unsecure variables for
  80            setuid programs.  */
  81
  82 .L26:   l       %r5,0(%r6)
  83         la      %r6,4(%r6)
  84         ltr     %r5,%r5
  85         jz      .L26
  86
  87         ahi     %r6,-4
  88
  89         /* Obtain the needed values from the auxiliary vector.  */
  90
  91         lhi     %r7,16         /* AT_HWCAP */
  92         lhi     %r8,3          /* AT_PHDR */
  93         lhi     %r9,5          /* AT_PHNUM */
  94         lhi     %r2,4          /* AT_PHENT */
  95 .L13:   l       %r5,0(%r6)
  96         clr     %r5,%r7
  97         jne     .L15
  98         l       %r10,4(%r6)    /* r10 = AT_HWCAP value.  */
  99 .L15:   clr     %r5,%r8
 100         jne     .L16
 101         l       %r11,4(%r6)    /* r11 = AT_PHDR value.  */
 102 .L16:   clr     %r5,%r9
 103         jne     .L17
 104         l       %r12,4(%r6)    /* r12 = AT_PHNUM value.  */
 105 .L17:   clr     %r5,%r2
 106         jne     .L18
 107         l       %r0,4(%r6)     /* r0 = AT_PHENT value.  */
 108 .L18:   ltr     %r5,%r5
 109         la      %r6,8(%r6)
 110         jnz     .L13
 111
 112         /* Locate the ELF header by looking for the first PT_LOAD
 113            segment with a p_offset of zero.  */
 114
 115         lr      %r4,%r11       /* Backup AT_PHDR.  */
 116         lhi     %r7,1          /* PT_LOAD id */
 117         lhi     %r8,0
 118 .L19:   cl      %r7,0(%r4)     /* p_type == PT_LOAD? */
 119         jne     .L20
 120         cl      %r8,4(%r4)     /* p_offset == 0? */
 121         jne     .L20
 122         l       %r9,8(%r4)     /* r9 = PT_LOAD.p_vaddr <- ELF header address  */
 123         j       .L24
 124 .L20:   alr     %r4,%r0        /* r4 += AT_PHENT value */
 125         brct    %r12,.L19
 126
 127         j       .+2            /* Trap, there must be such a phdr.  */
 128
 129 .L24:   lr      %r4,%r11       /* Backup AT_PHDR.  */
 130         lhi     %r2,6          /* PT_PHDR id */
 131 .L23:   cl      %r2,0(%r4)
 132         jne     .L22
 133         l       %r3,8(%r4)     /* r3 = PT_PHDR p_vaddr */
 134         j       .L25
 135 .L22:   alr     %r4,%r0        /* r4 += AT_PHENT value */
 136         brct    %r12,.L23
 137
 138         j       .L14           /* No PT_PHDR found - skip checking.  */
 139
 140 .L25:   slr     %r11,%r3       /* AT_PHDR - PT_PHDR.p_vaddr (relocation offset)*/
 141         alr     %r9,%r11       /* PT_LOAD.p_vaddr += relocation offset */
 142
 143         l       %r5,36(%r9)    /* Load the e_flags field.  */
 144         tml     %r5,1
 145         jz      .L14           /* Binary does not require highgprs facility.  */
 146
 147         tml     %r10,512       /* Check the AT_HWCAP value.  */
 148         jz      2              /* Trap if no highgprs facility available.  */
 149 .L14:
 150
 151         /* Setup pointer to literal pool of _start */
 152         basr    %r13,0
 153 .L0:    ahi     %r13,.Llit-.L0
 154
 155         /* load argc and argv from stack */
 156         la      %r4,4(%r15)             # get argv
 157         l       %r3,0(%r15)             # get argc
 158
 159         /* align the stack to a double word boundary */
 160         lhi     %r0,-8
 161         nr      %r15,%r0
 162
 163         /* Setup a stack frame and a parameter area */
 164         ahi     %r15,-104               # make room on stack
 165         xc      0(4,%r15),0(%r15)       # clear back-chain
 166
 167         /* set up arguments for __libc_start_main:
 168            main, argc, argv, envp, _init, _fini, rtld_fini, stack_end
 169            Note that envp will be determined later in __libc_start_main
 170          */
 171         stm     %r14,%r15,96(%r15)      # store rtld_fini/stack_end to parameter area
 172         la      %r7,96(%r15)
 173         l       %r6,.L2-.Llit(%r13)     # load pointer to __libc_csu_fini
 174         l       %r5,.L1-.Llit(%r13)     # load pointer to __libc_csu_init
 175         l       %r2,.L3-.Llit(%r13)     # load pointer to main
 176         l       %r1,.L4-.Llit(%r13)     # load pointer to __libc_start_main
 177 #ifdef PIC
 178         l       %r12,.L5-.Llit(%r13)    # load .got pointer
 179         la      %r6,0(%r13,%r6)
 180         la      %r5,0(%r13,%r5)
 181         la      %r12,0(%r13,%r12)
 182         l       %r2,0(%r12,%r2)
 183         la      %r1,0(%r13,%r1)
 184 #endif
 185
 186         /* ok, now branch to the libc main routine */
 187         basr    %r14,%r1
 188
 189         /* crash if __libc_start_main returns */
 190         .word   0
 191
 192 .Llit:
 193 #ifndef PIC
 194 .L1:    .long  __libc_csu_init
 195 .L2:    .long  __libc_csu_fini
 196 .L3:    .long  main
 197 .L4:    .long  __libc_start_main
 198 #else
 199 .L1:    .long  __libc_csu_init-.Llit
 200 .L2:    .long  __libc_csu_fini-.Llit
 201 .L3:    .long  main@GOT
 202 .L4:    .long  __libc_start_main@plt-.Llit
 203 .L5:    .long  _GLOBAL_OFFSET_TABLE_-.Llit
 204 #endif
 205
 206 /* Define a symbol for the first piece of initialized data.  */
 207         .data
 208         .globl __data_start
 209 __data_start:
 210         .long 0
 211         .weak data_start
 212         data_start = __data_start