sysdeps/powerpc/powerpc32/power4/fpu/s_llround.S

   1 /* llround function.  PowerPC32 on PowerPC64 version.
   2    Copyright (C) 2004, 2006, 2007, 2008, 2011 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <math_ldbl_opt.h>
  21
  22  .section .rodata.cst12,"aM",@progbits,12
  23  .align 3
  24  .LC0:   /* 0x1.0000000000000p+52 == 2^52 */
  25         .long 0x43300000
  26         .long 0x00000000
  27         .long 0x3f000000 /* Use this for 0.5  */
  28
  29         .section        ".text"
  30
  31 /* long [r3] lround (float x [fp1])
  32    IEEE 1003.1 lround function.  IEEE specifies "round to the nearest
  33    integer value, rounding halfway cases away from zero, regardless of
  34    the current rounding mode."  However PowerPC Architecture defines
  35    "round to Nearest" as "Choose the best approximation. In case of a
  36    tie, choose the one that is even (least significant bit o).".
  37    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  38    "round toward Zero" mode and round by adding +-0.5 before rounding
  39    to the integer value.
  40
  41    It is necessary to detect when x is (+-)0x1.fffffffffffffp-2
  42    because adding +-0.5 in this case will cause an erroneous shift,
  43    carry and round.  We simply return 0 if 0.5 > x > -0.5.  Likewise
  44    if x is and odd number between +-(2^52 and 2^53-1) a shift and
  45    carry will erroneously round if biased with +-0.5.  Therefore if x
  46    is greater/less than +-2^52 we don't need to bias the number with
  47    +-0.5.  */
  48
  49 ENTRY (__llround)
  50         stwu    r1,-16(r1)
  51         cfi_adjust_cfa_offset (16)
  52 #ifdef SHARED
  53         mflr    r11
  54         cfi_register(lr,r11)
  55         SETUP_GOT_ACCESS(r9,got_label)
  56         addis   r9,r9,.LC0-got_label@ha
  57         addi    r9,r9,.LC0-got_label@l
  58         mtlr    r11
  59         cfi_same_value (lr)
  60         lfd     fp9,0(r9)
  61         lfs     fp10,8(r9)
  62 #else
  63         lis r9,.LC0@ha
  64         lfd fp9,.LC0@l(r9)      /* Load 2^52 into fpr9.  */
  65         lfs fp10,.LC0@l+8(r9)   /* Load 0.5 into fpr10.  */
  66 #endif
  67         fabs    fp2,fp1         /* Get the absolute value of x.  */
  68         fsub    fp12,fp10,fp10  /* Compute 0.0 into fpr12.  */
  69         fcmpu   cr6,fp2,fp10    /* if |x| < 0.5  */
  70         fcmpu   cr7,fp2,fp9     /* if |x| >= 2^52  */
  71         fcmpu   cr1,fp1,fp12    /* x is negative? x < 0.0  */
  72         blt-    cr6,.Lretzero   /* 0.5 > x < -0.5 so just return 0.  */
  73         bge-    cr7,.Lnobias    /* 2^52 > x < -2^52 just convert with no bias.  */
  74         fadd    fp3,fp2,fp10    /* |x|+=0.5 bias to prepare to round.  */
  75         bge     cr1,.Lconvert   /* x is positive so don't negate x.  */
  76         fnabs   fp3,fp3         /* -(|x|+=0.5)  */
  77 .Lconvert:
  78         fctidz  fp4,fp3         /* Convert to Integer double word round toward 0.  */
  79         stfd    fp4,8(r1)
  80         nop
  81         nop
  82         nop
  83         lwz     r4,12(r1)       /* Load return as integer.  */
  84         lwz     r3,8(r1)
  85 .Lout:
  86         addi    r1,r1,16
  87         blr
  88 .Lretzero:                      /* 0.5 > x > -0.5  */
  89         li      r3,0            /* return 0.  */
  90         li      r4,0
  91         b       .Lout
  92 .Lnobias:
  93         fmr     fp3,fp1
  94         b       .Lconvert
  95         END (__llround)
  96
  97 weak_alias (__llround, llround)
  98
  99 strong_alias (__llround, __llroundf)
 100 weak_alias (__llround, llroundf)
 101
 102 #ifdef NO_LONG_DOUBLE
 103 weak_alias (__llround, llroundl)
 104 strong_alias (__llround, __llroundl)
 105 #endif
 106 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
 107 compat_symbol (libm, __llround, llroundl, GLIBC_2_1)
 108 #endif