sysdeps/i386/lshift.S

   1 /* i80386 __mpn_lshift --
   2    Copyright (C) 1992,1994,1997-2000,2005,2010 Free Software Foundation, Inc.
   3    This file is part of the GNU MP Library.
   4
   5    The GNU MP Library is free software; you can redistribute it and/or modify
   6    it under the terms of the GNU Lesser General Public License as published by
   7    the Free Software Foundation; either version 2.1 of the License, or (at your
   8    option) any later version.
   9
  10    The GNU MP Library is distributed in the hope that it will be useful, but
  11    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  12    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  13    License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public License
  16    along with the GNU MP Library; see the file COPYING.LIB.  If not,
  17    see <http://www.gnu.org/licenses/>.  */
  18
  19 #include "sysdep.h"
  20 #include "asm-syntax.h"
  21 #include "bp-sym.h"
  22 #include "bp-asm.h"
  23
  24 #define PARMS   LINKAGE+12              /* space for 3 saved regs */
  25 #define RES     PARMS
  26 #define S       RES+PTR_SIZE
  27 #define SIZE    S+PTR_SIZE
  28 #define CNT     SIZE+4
  29
  30         .text
  31 ENTRY (BP_SYM (__mpn_lshift))
  32         ENTER
  33
  34         pushl   %edi
  35         cfi_adjust_cfa_offset (4)
  36         pushl   %esi
  37         cfi_adjust_cfa_offset (4)
  38         pushl   %ebx
  39         cfi_adjust_cfa_offset (4)
  40
  41         movl    RES(%esp),%edi
  42         cfi_rel_offset (edi, 8)
  43         movl    S(%esp),%esi
  44         cfi_rel_offset (esi, 4)
  45         movl    SIZE(%esp),%edx
  46         movl    CNT(%esp),%ecx
  47 #if __BOUNDED_POINTERS__
  48         shll    $2, %edx                /* convert limbs to bytes */
  49         CHECK_BOUNDS_BOTH_WIDE (%edi, RES(%esp), %edx)
  50         CHECK_BOUNDS_BOTH_WIDE (%esi, S(%esp), %edx)
  51         shrl    $2, %edx
  52 #endif
  53         subl    $4,%esi                 /* adjust s_ptr */
  54
  55         movl    (%esi,%edx,4),%ebx      /* read most significant limb */
  56         cfi_rel_offset (ebx, 0)
  57         cfi_remember_state
  58         xorl    %eax,%eax
  59         shldl   %cl,%ebx,%eax           /* compute carry limb */
  60         decl    %edx
  61         jz      L(end)
  62         pushl   %eax                    /* push carry limb onto stack */
  63         cfi_adjust_cfa_offset (4)
  64         testb   $1,%dl
  65         jnz     L(1)                    /* enter loop in the middle */
  66         movl    %ebx,%eax
  67
  68         ALIGN (3)
  69 L(oop): movl    (%esi,%edx,4),%ebx      /* load next lower limb */
  70         shldl   %cl,%ebx,%eax           /* compute result limb */
  71         movl    %eax,(%edi,%edx,4)      /* store it */
  72         decl    %edx
  73 L(1):   movl    (%esi,%edx,4),%eax
  74         shldl   %cl,%eax,%ebx
  75         movl    %ebx,(%edi,%edx,4)
  76         decl    %edx
  77         jnz     L(oop)
  78
  79         shll    %cl,%eax                /* compute least significant limb */
  80         movl    %eax,(%edi)             /* store it */
  81
  82         popl    %eax                    /* pop carry limb */
  83         cfi_adjust_cfa_offset (-4)
  84
  85         popl    %ebx
  86         cfi_adjust_cfa_offset (-4)
  87         cfi_restore (ebx)
  88         popl    %esi
  89         cfi_adjust_cfa_offset (-4)
  90         cfi_restore (esi)
  91         popl    %edi
  92         cfi_adjust_cfa_offset (-4)
  93         cfi_restore (edi)
  94
  95         LEAVE
  96         ret
  97
  98         cfi_restore_state
  99 L(end): shll    %cl,%ebx                /* compute least significant limb */
 100         movl    %ebx,(%edi)             /* store it */
 101
 102         popl    %ebx
 103         cfi_adjust_cfa_offset (-4)
 104         cfi_restore (ebx)
 105         popl    %esi
 106         cfi_adjust_cfa_offset (-4)
 107         cfi_restore (esi)
 108         popl    %edi
 109         cfi_adjust_cfa_offset (-4)
 110         cfi_restore (edi)
 111
 112         LEAVE
 113         ret
 114 END (BP_SYM (__mpn_lshift))