sysdeps/i386/i686/multiarch/mempcpy.S

   1 /* Multiple versions of mempcpy
   2    Copyright (C) 2010, 2012 Free Software Foundation, Inc.
   3    Contributed by Intel Corporation.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <init-arch.h>
  22
  23 /* Define multiple versions only for the definition in lib and for
  24    DSO.  In static binaries we need mempcpy before the initialization
  25    happened.  */
  26 #if defined SHARED && !defined NOT_IN_libc
  27         .text
  28 ENTRY(__mempcpy)
  29         .type   __mempcpy, @gnu_indirect_function
  30         pushl   %ebx
  31         cfi_adjust_cfa_offset (4)
  32         cfi_rel_offset (ebx, 0)
  33         LOAD_PIC_REG(bx)
  34         cmpl    $0, KIND_OFFSET+__cpu_features@GOTOFF(%ebx)
  35         jne     1f
  36         call    __init_cpu_features
  37 1:      leal    __mempcpy_ia32@GOTOFF(%ebx), %eax
  38         testl   $bit_SSSE3, CPUID_OFFSET+index_SSSE3+__cpu_features@GOTOFF(%ebx)
  39         jz      2f
  40         leal    __mempcpy_ssse3@GOTOFF(%ebx), %eax
  41         testl   $bit_Fast_Rep_String, FEATURE_OFFSET+index_Fast_Rep_String+__cpu_features@GOTOFF(%ebx)
  42         jz      2f
  43         leal    __mempcpy_ssse3_rep@GOTOFF(%ebx), %eax
  44 2:      popl    %ebx
  45         cfi_adjust_cfa_offset (-4)
  46         cfi_restore (ebx)
  47         ret
  48 END(__mempcpy)
  49
  50 # undef ENTRY
  51 # define ENTRY(name) \
  52         .type __mempcpy_ia32, @function; \
  53         .p2align 4; \
  54         __mempcpy_ia32: cfi_startproc; \
  55         CALL_MCOUNT
  56 # undef END
  57 # define END(name) \
  58         cfi_endproc; .size __mempcpy_ia32, .-__mempcpy_ia32
  59
  60 # undef ENTRY_CHK
  61 # define ENTRY_CHK(name) \
  62         .type __mempcpy_chk_ia32, @function; \
  63         .globl __mempcpy_chk_ia32; \
  64         .p2align 4; \
  65         __mempcpy_chk_ia32: cfi_startproc; \
  66         CALL_MCOUNT
  67 # undef END_CHK
  68 # define END_CHK(name) \
  69         cfi_endproc; .size __mempcpy_chk_ia32, .-__mempcpy_chk_ia32
  70
  71 # undef libc_hidden_def
  72 # undef libc_hidden_builtin_def
  73 /* IFUNC doesn't work with the hidden functions in shared library since
  74    they will be called without setting up EBX needed for PLT which is
  75    used by IFUNC.  */
  76 # define libc_hidden_def(name) \
  77         .globl __GI_mempcpy; __GI_mempcpy = __mempcpy_ia32
  78 # define libc_hidden_builtin_def(name) \
  79         .globl __GI___mempcpy; __GI___mempcpy = __mempcpy_ia32
  80 #endif
  81
  82 #include "../mempcpy.S"