intl/po2test.sed

   1 # po2test.sed - Convert Uniforum style .po file to C code for testing.
   2 # Copyright (C) 2000,2003 Free Software Foundation, Inc.
   3 # Ulrich Drepper <drepper@cygnus.com>, 2000.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, see <http://www.gnu.org/licenses/>.
  17 #
  18
  19 #
  20 # We copy the original message as a comment into the .msg file.  But enclose
  21 # them with INPUT ( ).
  22 #
  23 s/^msgid[       ]*"\(.*\)"/INPUT ("\1")/
  24 # Clear flag from last substitution and jump if matching
  25 tb
  26
  27 #
  28 # Copy the translations as well and enclose them with OUTPUT ( ).
  29 #
  30 s/^msgstr[      ]*"\(.*\)"/OUTPUT ("\1")/
  31 # Clear flag from last substitution and jump if matching
  32 tb
  33
  34 d
  35
  36 :b
  37 # Append the next line.
  38 $!N
  39 # Check whether second part is a continuation line.  If so, before printing
  40 # insert '\'.
  41 s/\(.*\)")\(\n\)"\(.*\)"/\1\\\2\3")/
  42 P
  43 ta
  44 # No, go to the top and process it. Note that `D' includes a jump to the start!!
  45 D
  46 # Yes, we found a continuation line.
  47 :a
  48 # We cannot use the sed command `D' here
  49 s/[^\n]*\n//
  50 # Clear the substitution flag and do the next line.
  51 tb