sysdeps/sparc/sparc64/fpu/multiarch/s_ceilf-vis3.S

   1 /* Float ceil function, sparc64 vis3 version.
   2    Copyright (C) 2012-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller <davem@davemloft.net>, 2012.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21
  22         /* Since changing the rounding mode is extremely expensive, we
  23            try to round up using a method that is rounding mode
  24            agnostic.
  25
  26            We add then subtract (or subtract than add if the initial
  27            value was negative) 2**23 to the value, then subtract it
  28            back out.
  29
  30            This will clear out the fractional portion of the value.
  31            One of two things will happen for non-whole initial values.
  32            Either the rounding mode will round it up, or it will be
  33            rounded down.  If the value started out whole, it will be
  34            equal after the addition and subtraction.  This means we
  35            can accurately detect with one test whether we need to add
  36            another 1.0 to round it up properly.
  37
  38            VIS instructions are used to facilitate the formation of
  39            easier constants, and the propagation of the sign bit.  */
  40
  41 #define TWO_TWENTYTHREE 0x4b000000              /* 2**23 */
  42 #define ONE_DOT_ZERO    0x3f800000              /* 1.0 */
  43
  44 #define ZERO            %f10                    /* 0.0 */
  45 #define SIGN_BIT        %f12                    /* -0.0 */
  46
  47 ENTRY (__ceilf_vis3)
  48         sethi   %hi(TWO_TWENTYTHREE), %o2
  49         sethi   %hi(ONE_DOT_ZERO), %o3
  50         fzeros  ZERO
  51
  52         fnegs   ZERO, SIGN_BIT
  53
  54         movwtos %o2, %f16
  55         fabss   %f1, %f14
  56
  57         fcmps   %fcc3, %f14, %f16
  58
  59         fmovsuge %fcc3, ZERO, %f16
  60         fands   %f1, SIGN_BIT, SIGN_BIT
  61
  62         fors    %f16, SIGN_BIT, %f16
  63         fadds   %f1, %f16, %f5
  64         fsubs   %f5, %f16, %f5
  65         fcmps   %fcc2, %f5, %f1
  66         movwtos %o3, %f9
  67
  68         fmovsuge %fcc2, ZERO, %f9
  69         fadds   %f5, %f9, %f0
  70         fabss   %f0, %f0
  71         retl
  72          fors   %f0, SIGN_BIT, %f0
  73 END (__ceilf_vis3)