sysdeps/i386/i586/memset.S

   1 /* memset/bzero -- set memory area to CH/0
   2    Highly optimized version for ix86, x>=5.
   3    Copyright (C) 1996-2013 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Torbjorn Granlund, <tege@matematik.su.se>
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <http://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include "asm-syntax.h"
  23 #include "bp-sym.h"
  24 #include "bp-asm.h"
  25
  26 /* BEWARE: `#ifdef memset' means that memset is redefined as `bzero' */
  27 #define BZERO_P (defined memset)
  28
  29 #define PARMS   LINKAGE+4       /* space for 1 saved reg */
  30 #define RTN     PARMS
  31 #define DEST    RTN+RTN_SIZE
  32 #if BZERO_P
  33 # define LEN    DEST+PTR_SIZE
  34 #else
  35 # define CHR    DEST+PTR_SIZE
  36 # define LEN    CHR+4
  37 #endif
  38
  39         .text
  40 #if defined PIC && !defined NOT_IN_libc && !BZERO_P
  41 ENTRY (__memset_chk)
  42         movl    12(%esp), %eax
  43         cmpl    %eax, 16(%esp)
  44         jb      HIDDEN_JUMPTARGET (__chk_fail)
  45 END (__memset_chk)
  46 #endif
  47 ENTRY (BP_SYM (memset))
  48         ENTER
  49
  50         pushl   %edi
  51         cfi_adjust_cfa_offset (4)
  52
  53         movl    DEST(%esp), %edi
  54         cfi_rel_offset (edi, 0)
  55         movl    LEN(%esp), %edx
  56         CHECK_BOUNDS_BOTH_WIDE (%edi, DEST(%esp), %edx)
  57 #if BZERO_P
  58         xorl    %eax, %eax      /* we fill with 0 */
  59 #else
  60         movb    CHR(%esp), %al
  61         movb    %al, %ah
  62         movl    %eax, %ecx
  63         shll    $16, %eax
  64         movw    %cx, %ax
  65 #endif
  66         cld
  67
  68 /* If less than 36 bytes to write, skip tricky code (it wouldn't work).  */
  69         cmpl    $36, %edx
  70         movl    %edx, %ecx      /* needed when branch is taken! */
  71         jl      L(2)
  72
  73 /* First write 0-3 bytes to make the pointer 32-bit aligned.  */
  74         movl    %edi, %ecx      /* Copy ptr to ecx... */
  75         negl    %ecx            /* ...and negate that and... */
  76         andl    $3, %ecx        /* ...mask to get byte count.  */
  77         subl    %ecx, %edx      /* adjust global byte count */
  78         rep
  79         stosb
  80
  81         subl    $32, %edx       /* offset count for unrolled loop */
  82         movl    (%edi), %ecx    /* Fetch destination cache line */
  83
  84         .align  2, 0x90         /* supply 0x90 for broken assemblers */
  85 L(1):   movl    28(%edi), %ecx  /* allocate cache line for destination */
  86         subl    $32, %edx       /* decr loop count */
  87         movl    %eax, 0(%edi)   /* store words pairwise */
  88         movl    %eax, 4(%edi)
  89         movl    %eax, 8(%edi)
  90         movl    %eax, 12(%edi)
  91         movl    %eax, 16(%edi)
  92         movl    %eax, 20(%edi)
  93         movl    %eax, 24(%edi)
  94         movl    %eax, 28(%edi)
  95         leal    32(%edi), %edi  /* update destination pointer */
  96         jge     L(1)
  97
  98         leal    32(%edx), %ecx  /* reset offset count */
  99
 100 /* Write last 0-7 full 32-bit words (up to 8 words if loop was skipped).  */
 101 L(2):   shrl    $2, %ecx        /* convert byte count to longword count */
 102         rep
 103         stosl
 104
 105 /* Finally write the last 0-3 bytes.  */
 106         movl    %edx, %ecx
 107         andl    $3, %ecx
 108         rep
 109         stosb
 110
 111 #if !BZERO_P
 112         /* Load result (only if used as memset).  */
 113         movl DEST(%esp), %eax   /* start address of destination is result */
 114         RETURN_BOUNDED_POINTER (DEST(%esp))
 115 #endif
 116         popl    %edi
 117         cfi_adjust_cfa_offset (-4)
 118         cfi_restore (edi)
 119
 120         LEAVE
 121 #if BZERO_P
 122         ret
 123 #else
 124         RET_PTR
 125 #endif
 126 END (BP_SYM (memset))
 127 libc_hidden_builtin_def (memset)