configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/],
   4   [glibc], [https://www.gnu.org/software/glibc/])
   5 AC_CONFIG_SRCDIR([include/features.h])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_AUX_DIR([scripts])
   8
   9 ACX_PKGVERSION([GNU libc])
  10 ACX_BUGURL([https://www.gnu.org/software/libc/bugs.html])
  11 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  12                    [Package description])
  13 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  14                    [Bug reporting address])
  15
  16 # Glibc should not depend on any header files
  17 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  18   [m4_divert_text([DEFAULTS],
  19     [ac_includes_default='/* none */'])])
  20
  21 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  22 # here to work around the Autoconf issue discussed in
  23 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  24 AC_DEFUN([AC_PROG_CPP],
  25 [AC_REQUIRE([AC_PROG_CC])dnl
  26 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  27 _AC_ARG_VAR_CPPFLAGS()dnl
  28 # On Suns, sometimes $CPP names a directory.
  29 if test -n "$CPP" && test -d "$CPP"; then
  30   CPP=
  31 fi
  32 if test -z "$CPP"; then
  33   CPP="$CC -E"
  34 fi
  35 AC_SUBST(CPP)dnl
  36 ])# AC_PROG_CPP
  37
  38 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  39 # issue discussed in
  40 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  41 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  42
  43 dnl This is here so we can set $subdirs directly based on configure fragments.
  44 AC_CONFIG_SUBDIRS()
  45
  46 AC_CANONICAL_HOST
  47
  48 AC_PROG_CC
  49 if test $host != $build; then
  50   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  51 fi
  52 AC_SUBST(cross_compiling)
  53 AC_PROG_CPP
  54 AC_CHECK_TOOL(READELF, readelf, false)
  55
  56 # We need the C++ compiler only for testing.
  57 AC_PROG_CXX
  58 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  59 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  60 AC_LANG_PUSH([C++])
  61 # Default, dynamic case.
  62 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  63                [libc_cv_cxx_link_ok=yes],
  64                [libc_cv_cxx_link_ok=no])
  65 # Static case.
  66 old_LDFLAGS="$LDFLAGS"
  67 LDFLAGS="$LDFLAGS -static"
  68 AC_LINK_IFELSE([AC_LANG_SOURCE([
  69 #include <iostream>
  70
  71 int
  72 main()
  73 {
  74   std::cout << "Hello, world!";
  75   return 0;
  76 }
  77 ])],
  78                [],
  79                [libc_cv_cxx_link_ok=no])
  80 LDFLAGS="$old_LDFLAGS"
  81 AC_LANG_POP([C++])])
  82 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  83
  84 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  85   AC_MSG_ERROR([you must configure in a separate build directory])
  86 fi
  87
  88 # This will get text that should go into config.make.
  89 config_vars=
  90
  91 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  92 AC_ARG_WITH([gd],
  93             AC_HELP_STRING([--with-gd=DIR],
  94                            [find libgd include dir and library with prefix DIR]),
  95             [dnl
  96 case "$with_gd" in
  97 yes|''|no) ;;
  98 *) libgd_include="-I$withval/include"
  99    libgd_ldflags="-L$withval/lib" ;;
 100 esac
 101 ])
 102 AC_ARG_WITH([gd-include],
 103             AC_HELP_STRING([--with-gd-include=DIR],
 104                            [find libgd include files in DIR]),
 105             [dnl
 106 case "$with_gd_include" in
 107 ''|no) ;;
 108 *) libgd_include="-I$withval" ;;
 109 esac
 110 ])
 111 AC_ARG_WITH([gd-lib],
 112             AC_HELP_STRING([--with-gd-lib=DIR],
 113                            [find libgd library files in DIR]),
 114             [dnl
 115 case "$with_gd_lib" in
 116 ''|no) ;;
 117 *) libgd_ldflags="-L$withval" ;;
 118 esac
 119 ])
 120
 121 if test -n "$libgd_include"; then
 122   config_vars="$config_vars
 123 CFLAGS-memusagestat.c = $libgd_include"
 124 fi
 125 if test -n "$libgd_ldflags"; then
 126   config_vars="$config_vars
 127 libgd-LDFLAGS = $libgd_ldflags"
 128 fi
 129
 130 dnl Arguments to specify presence of other packages/features.
 131 AC_ARG_WITH([binutils],
 132             AC_HELP_STRING([--with-binutils=PATH],
 133                            [specify location of binutils (as and ld)]),
 134             [path_binutils=$withval],
 135             [path_binutils=''])
 136 AC_ARG_WITH([selinux],
 137             AC_HELP_STRING([--with-selinux],
 138                            [if building with SELinux support]),
 139             [with_selinux=$withval],
 140             [with_selinux=auto])
 141
 142 AC_ARG_WITH([headers],
 143             AC_HELP_STRING([--with-headers=PATH],
 144                            [location of system headers to use
 145                             (for example /usr/src/linux/include)
 146                             @<:@default=compiler default@:>@]),
 147             [sysheaders=$withval],
 148             [sysheaders=''])
 149 AC_SUBST(sysheaders)
 150
 151 AC_SUBST(use_default_link)
 152 AC_ARG_WITH([default-link],
 153             AC_HELP_STRING([--with-default-link],
 154                            [do not use explicit linker scripts]),
 155             [use_default_link=$withval],
 156             [use_default_link=default])
 157
 158 dnl Additional build flags injection.
 159 AC_ARG_WITH([nonshared-cflags],
 160             AC_HELP_STRING([--with-nonshared-cflags=CFLAGS],
 161                            [build nonshared libraries with additional CFLAGS]),
 162             [extra_nonshared_cflags=$withval],
 163             [extra_nonshared_cflags=])
 164 AC_SUBST(extra_nonshared_cflags)
 165
 166 AC_ARG_ENABLE([sanity-checks],
 167               AC_HELP_STRING([--disable-sanity-checks],
 168                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 169               [enable_sanity=$enableval],
 170               [enable_sanity=yes])
 171
 172 AC_ARG_ENABLE([shared],
 173               AC_HELP_STRING([--enable-shared],
 174                              [build shared library @<:@default=yes if GNU ld@:>@]),
 175               [shared=$enableval],
 176               [shared=yes])
 177 AC_ARG_ENABLE([profile],
 178               AC_HELP_STRING([--enable-profile],
 179                              [build profiled library @<:@default=no@:>@]),
 180               [profile=$enableval],
 181               [profile=no])
 182 AC_ARG_ENABLE([static-pie],
 183               AC_HELP_STRING([--enable-static-pie],
 184                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 185               [static_pie=$enableval],
 186               [static_pie=no])
 187 AC_ARG_ENABLE([timezone-tools],
 188               AC_HELP_STRING([--disable-timezone-tools],
 189                              [do not install timezone tools @<:@default=install@:>@]),
 190               [enable_timezone_tools=$enableval],
 191               [enable_timezone_tools=yes])
 192 AC_SUBST(enable_timezone_tools)
 193
 194 AC_ARG_ENABLE([hardcoded-path-in-tests],
 195               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 196                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 197               [hardcoded_path_in_tests=$enableval],
 198               [hardcoded_path_in_tests=no])
 199 AC_SUBST(hardcoded_path_in_tests)
 200
 201 AC_ARG_ENABLE([stackguard-randomization],
 202               AC_HELP_STRING([--enable-stackguard-randomization],
 203                              [initialize __stack_chk_guard canary with a random number at program start]),
 204               [enable_stackguard_randomize=$enableval],
 205               [enable_stackguard_randomize=no])
 206 if test "$enable_stackguard_randomize" = yes; then
 207   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 208 fi
 209
 210 AC_ARG_ENABLE([hidden-plt],
 211               AC_HELP_STRING([--disable-hidden-plt],
 212                              [do not hide internal function calls to avoid PLT]),
 213               [hidden=$enableval],
 214               [hidden=yes])
 215 if test "x$hidden" = xno; then
 216   AC_DEFINE(NO_HIDDEN)
 217 fi
 218
 219 AC_ARG_ENABLE([bind-now],
 220               AC_HELP_STRING([--enable-bind-now],
 221                              [disable lazy relocations in DSOs]),
 222               [bindnow=$enableval],
 223               [bindnow=no])
 224 AC_SUBST(bindnow)
 225 if test "x$bindnow" = xyes; then
 226   AC_DEFINE(BIND_NOW)
 227 fi
 228
 229 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 230 dnl -fstack-protector-strong.
 231 AC_ARG_ENABLE([stack-protector],
 232               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 233                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 234               [enable_stack_protector=$enableval],
 235               [enable_stack_protector=no])
 236 case "$enable_stack_protector" in
 237 all|yes|no|strong) ;;
 238 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 239 esac
 240
 241 dnl On some platforms we cannot use dynamic loading.  We must provide
 242 dnl static NSS modules.
 243 AC_ARG_ENABLE([static-nss],
 244               AC_HELP_STRING([--enable-static-nss],
 245                              [build static NSS modules @<:@default=no@:>@]),
 246               [static_nss=$enableval],
 247               [static_nss=no])
 248 dnl Enable static NSS also if we build no shared objects.
 249 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 250   static_nss=yes
 251   AC_DEFINE(DO_STATIC_NSS)
 252 fi
 253
 254 AC_ARG_ENABLE([force-install],
 255               AC_HELP_STRING([--disable-force-install],
 256                              [don't force installation of files from this package, even if they are older than the installed files]),
 257               [force_install=$enableval],
 258               [force_install=yes])
 259 AC_SUBST(force_install)
 260
 261 AC_ARG_ENABLE([maintainer-mode],
 262               AC_HELP_STRING([--enable-maintainer-mode],
 263                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 264               [maintainer=$enableval],
 265               [maintainer=no])
 266
 267 dnl On some platforms we allow dropping compatibility with all kernel
 268 dnl versions.
 269 AC_ARG_ENABLE([kernel],
 270               AC_HELP_STRING([--enable-kernel=VERSION],
 271                              [compile for compatibility with kernel not older than VERSION]),
 272               [minimum_kernel=$enableval],
 273               [])
 274 dnl Prevent unreasonable values.
 275 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 276   # Better nothing than this.
 277   minimum_kernel=""
 278 else
 279   if test "$minimum_kernel" = current; then
 280     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 281   fi
 282 fi
 283
 284 dnl For the development we sometimes want gcc to issue even more warnings.
 285 dnl This is not the default since many of the extra warnings are not
 286 dnl appropriate.
 287 AC_ARG_ENABLE([all-warnings],
 288               AC_HELP_STRING([--enable-all-warnings],
 289                              [enable all useful warnings gcc can issue]),
 290               [all_warnings=$enableval],
 291               [])
 292 AC_SUBST(all_warnings)
 293
 294 AC_ARG_ENABLE([werror],
 295               AC_HELP_STRING([--disable-werror],
 296                              [do not build with -Werror]),
 297               [enable_werror=$enableval],
 298               [enable_werror=yes])
 299 AC_SUBST(enable_werror)
 300
 301 AC_ARG_ENABLE([multi-arch],
 302               AC_HELP_STRING([--enable-multi-arch],
 303                              [enable single DSO with optimizations for multiple architectures]),
 304               [multi_arch=$enableval],
 305               [multi_arch=default])
 306
 307 AC_ARG_ENABLE([experimental-malloc],
 308               AC_HELP_STRING([--disable-experimental-malloc],
 309                              [disable experimental malloc features]),
 310               [experimental_malloc=$enableval],
 311               [experimental_malloc=yes])
 312 AC_SUBST(experimental_malloc)
 313
 314 AC_ARG_ENABLE([crypt],
 315               AC_HELP_STRING([--disable-crypt],
 316                              [do not build nor install the passphrase hashing library, libcrypt]),
 317               [build_crypt=$enableval],
 318               [build_crypt=yes])
 319 AC_SUBST(build_crypt)
 320
 321 AC_ARG_ENABLE([nss-crypt],
 322               AC_HELP_STRING([--enable-nss-crypt],
 323                              [enable libcrypt to use nss]),
 324               [nss_crypt=$enableval],
 325               [nss_crypt=no])
 326 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 327   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 328   nss_crypt=no
 329 fi
 330 if test x$nss_crypt = xyes; then
 331   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 332   if test $? -ne 0; then
 333     AC_MSG_ERROR([cannot find include directory with nss-config])
 334   fi
 335   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 336   if test $? -ne 0; then
 337     AC_MSG_ERROR([cannot find include directory with nspr-config])
 338   fi
 339   old_CFLAGS="$CFLAGS"
 340   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 341   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 342 #include <hasht.h>
 343 #include <nsslowhash.h>
 344 void f (void) { NSSLOW_Init (); }])],
 345              libc_cv_nss_crypt=yes,
 346              AC_MSG_ERROR([
 347 cannot find NSS headers with lowlevel hash function interfaces]))
 348   old_LIBS="$LIBS"
 349   old_LDFLAGS="$LDFLAGS"
 350   LIBS="$LIBS -lfreebl3"
 351   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 352 #include <hasht.h>
 353 #include <nsslowhash.h>],
 354                                   [NSSLOW_Init();])],
 355                  libc_cv_nss_crypt=yes,
 356                  AC_MSG_ERROR([
 357 cannot link program using lowlevel NSS hash functions]))
 358   # Check to see if there is a static NSS cryptographic library.
 359   # If there isn't then we can't link anything with libcrypt.a,
 360   # and that might mean disabling some static tests.
 361   LDFLAGS="$LDFLAGS -static"
 362   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 363 #include <hasht.h>
 364 #include <nsslowhash.h>],
 365                                   [NSSLOW_Init();])],
 366                  libc_cv_static_nss_crypt=yes,
 367                  libc_cv_static_nss_crypt=no)
 368   LDFLAGS="$old_LDFLAGS"
 369   CFLAGS="$old_CFLAGS"
 370   LIBS="$old_LIBS"
 371 else
 372   libc_cv_nss_crypt=no
 373   libc_cv_static_nss_crypt=no
 374 fi
 375 AC_SUBST(libc_cv_nss_crypt)
 376 AC_SUBST(libc_cv_static_nss_crypt)
 377
 378
 379 AC_ARG_ENABLE([obsolete-rpc],
 380               AC_HELP_STRING([--enable-obsolete-rpc],
 381                              [build and install the obsolete RPC code for link-time usage]),
 382               [link_obsolete_rpc=$enableval],
 383               [link_obsolete_rpc=no])
 384 AC_SUBST(link_obsolete_rpc)
 385
 386 if test "$link_obsolete_rpc" = yes; then
 387   AC_DEFINE(LINK_OBSOLETE_RPC)
 388 fi
 389
 390 AC_ARG_ENABLE([obsolete-nsl],
 391               AC_HELP_STRING([--enable-obsolete-nsl],
 392                              [build and install the obsolete libnsl library and depending NSS modules]),
 393               [build_obsolete_nsl=$enableval],
 394               [build_obsolete_nsl=no])
 395 AC_SUBST(build_obsolete_nsl)
 396
 397 if test "$build_obsolete_nsl" = yes; then
 398   AC_DEFINE(LINK_OBSOLETE_NSL)
 399 fi
 400
 401 AC_ARG_ENABLE([systemtap],
 402               [AS_HELP_STRING([--enable-systemtap],
 403                [enable systemtap static probe points @<:@default=no@:>@])],
 404               [systemtap=$enableval],
 405               [systemtap=no])
 406 if test "x$systemtap" != xno; then
 407   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 408   old_CFLAGS="$CFLAGS"
 409   CFLAGS="-std=gnu11 $CFLAGS"
 410   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 411 void foo (int i, void *p)
 412 {
 413   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 414        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 415 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 416   CFLAGS="$old_CFLAGS"])
 417   if test $libc_cv_sdt = yes; then
 418     AC_DEFINE([USE_STAP_PROBE])
 419   elif test "x$systemtap" != xauto; then
 420     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 421   fi
 422 fi
 423
 424 AC_ARG_ENABLE([build-nscd],
 425               [AS_HELP_STRING([--disable-build-nscd],
 426                [disable building and installing the nscd daemon])],
 427               [build_nscd=$enableval],
 428               [build_nscd=default])
 429 AC_SUBST(build_nscd)
 430
 431 # Note the use of $use_nscd is near the bottom of the file.
 432 AC_ARG_ENABLE([nscd],
 433               [AS_HELP_STRING([--disable-nscd],
 434                [library functions will not contact the nscd daemon])],
 435               [use_nscd=$enableval],
 436               [use_nscd=yes])
 437
 438 AC_ARG_ENABLE([pt_chown],
 439               [AS_HELP_STRING([--enable-pt_chown],
 440                [Enable building and installing pt_chown])],
 441               [build_pt_chown=$enableval],
 442               [build_pt_chown=no])
 443 AC_SUBST(build_pt_chown)
 444 if test "$build_pt_chown" = yes; then
 445   AC_DEFINE(HAVE_PT_CHOWN)
 446 fi
 447
 448 AC_ARG_ENABLE([tunables],
 449               [AS_HELP_STRING([--enable-tunables],
 450                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 451               [have_tunables=$enableval],
 452               [have_tunables=yes])
 453 AC_SUBST(have_tunables)
 454 if test "$have_tunables" = yes; then
 455   AC_DEFINE(HAVE_TUNABLES)
 456 fi
 457
 458 # The abi-tags file uses a fairly simplistic model for name recognition that
 459 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 460 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 461 # This doesn't get used much beyond that, so it's fairly safe.
 462 case "$host_os" in
 463 linux*)
 464   ;;
 465 gnu*)
 466   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 467   ;;
 468 esac
 469
 470 AC_ARG_ENABLE([mathvec],
 471               [AS_HELP_STRING([--enable-mathvec],
 472               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 473               [build_mathvec=$enableval],
 474               [build_mathvec=notset])
 475
 476 AC_TRY_COMPILE([], [
 477 #ifndef __CET__
 478 # error no CET compiler support
 479 #endif],
 480                [libc_cv_compiler_default_cet=yes],
 481                [libc_cv_compiler_default_cet=no])
 482
 483 AC_ARG_ENABLE([cet],
 484               AC_HELP_STRING([--enable-cet],
 485                              [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
 486               [enable_cet=$enableval],
 487               [enable_cet=$libc_cv_compiler_default_cet])
 488
 489 # We keep the original values in `$config_*' and never modify them, so we
 490 # can write them unchanged into config.make.  Everything else uses
 491 # $machine, $vendor, and $os, and changes them whenever convenient.
 492 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 493
 494 # Don't allow vendor == "unknown"
 495 test "$config_vendor" = unknown && config_vendor=
 496 config_os="`echo $config_os | sed 's/^unknown-//'`"
 497
 498 # Some configurations imply other options.
 499 elf=yes
 500
 501 # The configure fragment of a port can modify these to supplement
 502 # or override the table in the case statement below.  No fragment should
 503 # ever change the config_* variables, however.
 504 machine=$config_machine
 505 vendor=$config_vendor
 506 os=$config_os
 507 base_os=''
 508
 509 submachine=
 510 AC_ARG_WITH([cpu],
 511             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 512             [dnl
 513   case "$withval" in
 514   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 515   no) ;;
 516   *) submachine="$withval" ;;
 517   esac
 518 ])
 519
 520 # An preconfigure script can set this when it wants to disable the sanity
 521 # check below.
 522 libc_config_ok=no
 523
 524 # A preconfigure script for a system that may or may not use fpu
 525 # sysdeps directories sets this to a preprocessor conditional for
 526 # whether to use such directories.
 527 with_fp_cond=1
 528
 529 dnl Let sysdeps/*/preconfigure act here.
 530 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 531
 532
 533 ###
 534 ### By using the undocumented --enable-hacker-mode option for configure
 535 ### one can skip this test to make the configuration not fail for unsupported
 536 ### platforms.
 537 ###
 538 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 539   case "$machine-$host_os" in
 540   *-linux* | *-gnu*)
 541     ;;
 542   *)
 543     AC_MSG_ERROR([
 544 *** The GNU C library is currently unavailable for this platform.
 545 *** If you are interested in seeing glibc on this platform visit
 546 *** the "How to submit a new port" in the wiki:
 547 ***   https://sourceware.org/glibc/wiki/#Development
 548 *** and join the community!])
 549     ;;
 550   esac
 551 fi
 552
 553 # Set base_machine if not set by a preconfigure fragment.
 554 test -n "$base_machine" || base_machine=$machine
 555 AC_SUBST(base_machine)
 556
 557 # Determine whether to use fpu or nofpu sysdeps directories.
 558 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 559                libc_cv_with_fp, [dnl
 560 cat > conftest.c <<EOF
 561 #if $with_fp_cond
 562 int dummy;
 563 #else
 564 # error "no hardware floating point"
 565 #endif
 566 EOF
 567 libc_cv_with_fp=no
 568 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 569    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 570   libc_cv_with_fp=yes
 571 fi
 572 rm -f conftest*])
 573 AC_SUBST(libc_cv_with_fp)
 574
 575 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 576 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 577                    [libc_cv_ssp=yes],
 578                    [libc_cv_ssp=no])
 579 ])
 580
 581 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 582 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 583                    [libc_cv_ssp_strong=yes],
 584                    [libc_cv_ssp_strong=no])
 585 ])
 586
 587 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 588 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 589                    [libc_cv_ssp_all=yes],
 590                    [libc_cv_ssp_all=no])
 591 ])
 592
 593 stack_protector=
 594 no_stack_protector=
 595 if test "$libc_cv_ssp" = yes; then
 596   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 597   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 598 fi
 599
 600 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 601   stack_protector="-fstack-protector"
 602   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 603 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 604   stack_protector="-fstack-protector-all"
 605   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 606 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 607   stack_protector="-fstack-protector-strong"
 608   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 609 else
 610   stack_protector="-fno-stack-protector"
 611   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 612 fi
 613 AC_SUBST(libc_cv_ssp)
 614 AC_SUBST(stack_protector)
 615 AC_SUBST(no_stack_protector)
 616
 617 if test -n "$stack_protector"; then
 618   dnl Don't run configure tests with stack-protection on, to avoid problems with
 619   dnl bootstrapping.
 620   no_ssp=-fno-stack-protector
 621 else
 622   no_ssp=
 623
 624   if test "$enable_stack_protector" != no; then
 625     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 626   fi
 627 fi
 628
 629 # For the multi-arch option we need support in the assembler & linker.
 630 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 631                libc_cv_ld_gnu_indirect_function, [dnl
 632 cat > conftest.S <<EOF
 633 .type foo,%gnu_indirect_function
 634 foo:
 635 .globl _start
 636 _start:
 637 .globl __start
 638 __start:
 639 .data
 640 #ifdef _LP64
 641 .quad foo
 642 #else
 643 .long foo
 644 #endif
 645 EOF
 646 libc_cv_ld_gnu_indirect_function=no
 647 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 648             -nostartfiles -nostdlib $no_ssp \
 649             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 650   # Do a link to see if the backend supports IFUNC relocs.
 651   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 652   LC_ALL=C $READELF -Wr conftest | grep -q 'IRELATIVE\|R_SPARC_JMP_IREL' && {
 653     libc_cv_ld_gnu_indirect_function=yes
 654   }
 655 fi
 656 rm -f conftest*])
 657
 658 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 659 AC_CACHE_CHECK([for gcc attribute ifunc support],
 660                libc_cv_gcc_indirect_function, [dnl
 661 cat > conftest.c <<EOF
 662 extern int func (int);
 663 int used_func (int a)
 664 {
 665   return a;
 666 }
 667 static void *resolver ()
 668 {
 669   return &used_func;
 670 }
 671 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 672 EOF
 673 libc_cv_gcc_indirect_function=no
 674 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 675    2>&AS_MESSAGE_LOG_FD ; then
 676   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 677     libc_cv_gcc_indirect_function=yes
 678   fi
 679 fi
 680 rm -f conftest*])
 681
 682 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
 683 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
 684 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
 685                libc_cv_textrel_ifunc, [dnl
 686 cat > conftest.S <<EOF
 687 .type foo,%gnu_indirect_function
 688 foo:
 689 .globl _start
 690 _start:
 691 .globl __start
 692 __start:
 693 .data
 694 #ifdef _LP64
 695 .quad foo
 696 #else
 697 .long foo
 698 #endif
 699 .text
 700 .globl address
 701 address:
 702 #ifdef _LP64
 703 .quad address
 704 #else
 705 .long address
 706 #endif
 707 EOF
 708 libc_cv_textrel_ifunc=no
 709 if test $libc_cv_ld_gnu_indirect_function = yes; then
 710    if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
 711      libc_cv_textrel_ifunc=yes
 712    fi
 713 fi
 714 rm -f conftest*])
 715 AC_SUBST(libc_cv_textrel_ifunc)
 716
 717 # Check if gcc warns about alias for function with incompatible types.
 718 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 719                libc_cv_gcc_incompatible_alias, [dnl
 720 cat > conftest.c <<EOF
 721 int __redirect_foo (const void *s, int c);
 722
 723 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 724 __typeof (__redirect_foo) *foo_impl (void)
 725 {
 726   return 0;
 727 }
 728
 729 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 730 EOF
 731 libc_cv_gcc_incompatible_alias=yes
 732 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 733   libc_cv_gcc_incompatible_alias=no
 734 fi
 735 rm -f conftest*])
 736
 737 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 738   if test x"$multi_arch" = xyes; then
 739     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 740   else
 741     multi_arch=no
 742   fi
 743 fi
 744 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 745   # GCC 8+ emits a warning for alias with incompatible types and it might
 746   # fail to build ifunc resolvers aliases to either weak or internal
 747   # symbols.  Disables multiarch build in this case.
 748   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 749     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 750     if test x"$multi_arch" = xyes; then
 751       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 752     fi
 753     AC_MSG_WARN([Multi-arch is disabled.])
 754     multi_arch=no
 755   elif test x"$multi_arch" = xyes; then
 756     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 757 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 758   fi
 759 fi
 760 multi_arch_d=
 761 if test x"$multi_arch" != xno; then
 762   multi_arch_d=/multiarch
 763 fi
 764
 765 # Compute the list of sysdep directories for this configuration.
 766 # This can take a while to compute.
 767 sysdep_dir=$srcdir/sysdeps
 768 AC_MSG_CHECKING(sysdep dirs)
 769 dnl We need to use [ and ] for other purposes for a while now.
 770 changequote(,)dnl
 771 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 772 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 773
 774 test "x$base_os" != x || case "$os" in
 775 gnu*)
 776   base_os=mach/hurd ;;
 777 linux*)
 778   base_os=unix/sysv ;;
 779 esac
 780
 781 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 782 tail=$os
 783 ostry=$os
 784 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 785   ostry="$ostry /$o"
 786   tail=$o
 787 done
 788 o=`echo $tail | sed 's/[0-9]*$//'`
 789 if test $o != $tail; then
 790   ostry="$ostry /$o"
 791 fi
 792 # For linux-gnu, try linux-gnu, then linux.
 793 o=`echo $tail | sed 's/-.*$//'`
 794 if test $o != $tail; then
 795   ostry="$ostry /$o"
 796 fi
 797
 798 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 799 base=
 800 tail=$base_os
 801 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 802   set $b
 803   base="$base /$1"
 804   tail="$2"
 805 done
 806
 807 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 808 mach=
 809 tail=$machine${submachine:+/$submachine}
 810 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 811   set $m
 812   # Prepend the machine's FPU directory unless the architecture specific
 813   # preconfigure disables it.
 814   if test "$libc_cv_with_fp" = yes; then
 815     maybe_fpu=/fpu
 816   else
 817     maybe_fpu=/nofpu
 818   fi
 819   # For each machine term, try it with and then without /multiarch.
 820   for try_fpu in $maybe_fpu ''; do
 821     for try_multi in $multi_arch_d ''; do
 822       mach="$mach /$1$try_fpu$try_multi"
 823     done
 824   done
 825   tail="$2"
 826 done
 827
 828 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 829 changequote([,])dnl
 830
 831 # Find what sysdep directories exist.
 832 sysnames=
 833 for b in $base ''; do
 834   for m0 in $mach ''; do
 835     for v in /$vendor ''; do
 836       test "$v" = / && continue
 837       for o in /$ostry ''; do
 838         test "$o" = / && continue
 839         for m in $mach ''; do
 840           try_suffix="$m0$b$v$o$m"
 841           if test -n "$try_suffix"; then
 842             try_srcdir="${srcdir}/"
 843             try="sysdeps$try_suffix"
 844             test -n "$enable_debug_configure" &&
 845             echo "$0 [DEBUG]: try $try" >&2
 846             if test -d "$try_srcdir$try"; then
 847               sysnames="$sysnames $try"
 848               { test -n "$o" || test -n "$b"; } && os_used=t
 849               { test -n "$m" || test -n "$m0"; } && machine_used=t
 850               case x${m0:-$m} in
 851               x*/$submachine) submachine_used=t ;;
 852               esac
 853             fi
 854           fi
 855         done
 856       done
 857     done
 858   done
 859 done
 860
 861 # If the assembler supports gnu_indirect_function symbol type and the
 862 # architecture supports multi-arch, we enable multi-arch by default.
 863 case $sysnames in
 864 *"$multi_arch_d"*)
 865   ;;
 866 *)
 867   test x"$multi_arch" = xdefault && multi_arch=no
 868   ;;
 869 esac
 870 if test x"$multi_arch" != xno; then
 871   AC_DEFINE(USE_MULTIARCH)
 872 fi
 873 AC_SUBST(multi_arch)
 874
 875 if test -z "$os_used" && test "$os" != none; then
 876   AC_MSG_ERROR(Operating system $os is not supported.)
 877 fi
 878 if test -z "$machine_used" && test "$machine" != none; then
 879   AC_MSG_ERROR(The $machine is not supported.)
 880 fi
 881 if test -z "$submachine_used" && test -n "$submachine"; then
 882   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 883 fi
 884 AC_SUBST(submachine)
 885
 886 # We have now validated the configuration.
 887
 888 # Expand the list of system names into a full list of directories
 889 # from each element's parent name and Implies file (if present).
 890 set $sysnames
 891 names=
 892 while test $# -gt 0; do
 893   name=$1
 894   shift
 895
 896   case " $names " in *" $name "*)
 897     # Already in the list.
 898     continue
 899   esac
 900
 901   # Report each name as we discover it, so there is no long pause in output.
 902   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 903
 904   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 905
 906   case $name in
 907     /*) xsrcdir= ;;
 908     *)  xsrcdir=$srcdir/ ;;
 909   esac
 910   test -n "$enable_debug_configure" &&
 911   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 912
 913   for implies_file in Implies Implies-before Implies-after; do
 914     implies_type=`echo $implies_file | sed s/-/_/`
 915     eval ${implies_type}=
 916     if test -f $xsrcdir$name/$implies_file; then
 917       # Collect more names from the `Implies' file (removing comments).
 918       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 919       for x in $implied_candidate; do
 920         found=no
 921         if test -d $xsrcdir$name_base/$x; then
 922           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 923           found=yes
 924         fi
 925         try="sysdeps/$x"
 926         try_srcdir=$srcdir/
 927         test -n "$enable_debug_configure" &&
 928          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 929         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 930         then
 931           eval "${implies_type}=\"\$${implies_type} \$try\""
 932           found=yes
 933         fi
 934         if test $found = no; then
 935           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 936         fi
 937       done
 938     fi
 939   done
 940
 941   # Add NAME to the list of names.
 942   names="$names $name"
 943
 944   # Find the parent of NAME, using the empty string if it has none.
 945 changequote(,)dnl
 946   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 947 changequote([,])dnl
 948
 949   test -n "$enable_debug_configure" &&
 950     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 951 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 952
 953   # Add the names implied by NAME, and NAME's parent (if it has one), to
 954   # the list of names to be processed (the argument list).  We prepend the
 955   # implied names to the list and append the parent.  We want implied
 956   # directories to come before further directories inferred from the
 957   # configuration components; this ensures that for sysv4, unix/common
 958   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 959   # after sysv4).
 960   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 961   test -n "$sysnames" && set $sysnames
 962 done
 963
 964 # Add the default directories.
 965 default_sysnames="sysdeps/generic"
 966 sysnames="$names $default_sysnames"
 967 AC_SUBST(sysnames)
 968 # The other names were emitted during the scan.
 969 AC_MSG_RESULT($default_sysnames)
 970
 971
 972 ### Locate tools.
 973
 974 AC_PROG_INSTALL
 975 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 976   # The makefiles need to use a different form to find it in $srcdir.
 977   INSTALL='\$(..)./scripts/install-sh -c'
 978 fi
 979 AC_PROG_LN_S
 980
 981 LIBC_PROG_BINUTILS
 982
 983 # Accept binutils 2.25 or newer.
 984 AC_CHECK_PROG_VER(AS, $AS, --version,
 985                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 986                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 987                   AS=: critic_missing="$critic_missing as")
 988
 989 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 990   # Accept gold 1.14 or higher
 991   AC_CHECK_PROG_VER(LD, $LD, --version,
 992                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 993                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 994                     LD=: critic_missing="$critic_missing GNU gold")
 995 else
 996   AC_CHECK_PROG_VER(LD, $LD, --version,
 997                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 998                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 999                     LD=: critic_missing="$critic_missing GNU ld")
1000 fi
1001
1002 # These programs are version sensitive.
1003 AC_CHECK_TOOL_PREFIX
1004 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1005   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1006   [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1007
1008 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1009   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1010   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1011   MSGFMT=: aux_missing="$aux_missing msgfmt")
1012 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1013   [GNU texinfo.* \([0-9][0-9.]*\)],
1014   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1015   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1016 AC_CHECK_PROG_VER(SED, sed, --version,
1017   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1018   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1019   SED=: aux_missing="$aux_missing sed")
1020 AC_CHECK_PROG_VER(AWK, gawk, --version,
1021   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1022   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1023 AC_CHECK_PROG_VER(BISON, bison, --version,
1024   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1025   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1026
1027 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1028 AC_TRY_COMPILE([], [
1029 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1030 #error insufficient compiler
1031 #endif],
1032                [libc_cv_compiler_ok=yes],
1033                [libc_cv_compiler_ok=no])])
1034 AS_IF([test $libc_cv_compiler_ok != yes],
1035       [critic_missing="$critic_missing compiler"])
1036
1037 AC_CHECK_TOOL(NM, nm, false)
1038
1039 if test "x$maintainer" = "xyes"; then
1040   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1041   case "x$AUTOCONF" in
1042   xno|x|x:) AUTOCONF=no ;;
1043   *)
1044     AC_CACHE_CHECK(dnl
1045   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1046     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1047       libc_cv_autoconf_works=yes
1048     else
1049       libc_cv_autoconf_works=no
1050     fi])
1051     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1052     ;;
1053   esac
1054   if test "x$AUTOCONF" = xno; then
1055     aux_missing="$aux_missing autoconf"
1056   fi
1057 else
1058   AUTOCONF=no
1059 fi
1060
1061 # Check for python3 if available, or else python.
1062 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1063   [Python \([0-9][0-9.]*\)],
1064   [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1065   critic_missing="$critic_missing python")
1066 PYTHON="$PYTHON_PROG -B"
1067 AC_SUBST(PYTHON)
1068
1069 test -n "$critic_missing" && AC_MSG_ERROR([
1070 *** These critical programs are missing or too old:$critic_missing
1071 *** Check the INSTALL file for required versions.])
1072
1073 test -n "$aux_missing" && AC_MSG_WARN([
1074 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1075 *** some features or tests will be disabled.
1076 *** Check the INSTALL file for required versions.])
1077
1078 # if using special system headers, find out the compiler's sekrit
1079 # header directory and add that to the list.  NOTE: Only does the right
1080 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1081 if test -n "$sysheaders"; then
1082   SYSINCLUDES=-nostdinc
1083   for d in include include-fixed; do
1084     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1085     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1086   done
1087   SYSINCLUDES="$SYSINCLUDES \
1088 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1089   if test -n "$CXX"; then
1090     CXX_SYSINCLUDES=
1091     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1092     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1093       test "x$cxxheaders" != x &&
1094       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1095     done
1096   fi
1097 fi
1098 AC_SUBST(SYSINCLUDES)
1099 AC_SUBST(CXX_SYSINCLUDES)
1100
1101 # Obtain some C++ header file paths.  This is used to make a local
1102 # copy of those headers in Makerules.
1103 if test -n "$CXX"; then
1104   find_cxx_header () {
1105     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1106          | sed -n "\,$1:,{s/:\$//;p}"
1107   }
1108   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1109   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1110   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1111 fi
1112 AC_SUBST(CXX_CSTDLIB_HEADER)
1113 AC_SUBST(CXX_CMATH_HEADER)
1114 AC_SUBST(CXX_BITS_STD_ABS_H)
1115
1116 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1117 # since this would lead to problems installing/building glibc.
1118 # LD_LIBRARY_PATH contains the current directory if one of the following
1119 # is true:
1120 # - one of the terminals (":" and ";") is the first or last sign
1121 # - two terminals occur directly after each other
1122 # - the path contains an element with a dot in it
1123 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1124 changequote(,)dnl
1125 case ${LD_LIBRARY_PATH} in
1126   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1127     ld_library_path_setting="contains current directory"
1128     ;;
1129   *)
1130     ld_library_path_setting="ok"
1131     ;;
1132 esac
1133 changequote([,])dnl
1134 AC_MSG_RESULT($ld_library_path_setting)
1135 if test "$ld_library_path_setting" != "ok"; then
1136 AC_MSG_ERROR([
1137 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1138 *** building glibc. Please change the environment variable
1139 *** and run configure again.])
1140 fi
1141
1142 AC_PATH_PROG(BASH_SHELL, bash, no)
1143
1144 AC_PATH_PROG(PERL, perl, no)
1145 if test "$PERL" != no &&
1146    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1147   PERL=no
1148 fi
1149 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1150              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1151
1152 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1153 cat > conftest.s <<EOF
1154 .text
1155 foo:
1156 .set glibc_conftest_frobozz,foo
1157 .globl glibc_conftest_frobozz
1158 EOF
1159 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1160 # (but it doesn't work), so we must do a linking check to be sure.
1161 cat > conftest1.c <<\EOF
1162 extern int glibc_conftest_frobozz;
1163 void _start() { glibc_conftest_frobozz = 1; }
1164 EOF
1165 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1166             -nostartfiles -nostdlib $no_ssp \
1167             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1168   libc_cv_asm_set_directive=yes
1169 else
1170   libc_cv_asm_set_directive=no
1171 fi
1172 rm -f conftest*])
1173 if test $libc_cv_asm_set_directive = yes; then
1174   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1175 fi
1176
1177 AC_CACHE_CHECK(linker support for protected data symbol,
1178                libc_cv_protected_data,
1179                [cat > conftest.c <<EOF
1180                 int bar __attribute__ ((visibility ("protected"))) = 1;
1181 EOF
1182                 libc_cv_protected_data=no
1183                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1184                   cat > conftest.c <<EOF
1185                   extern int bar;
1186                   int main (void) { return bar; }
1187 EOF
1188                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1189                     libc_cv_protected_data=yes
1190                   fi
1191                 fi
1192                 rm -f conftest.*
1193                ])
1194 AC_SUBST(libc_cv_protected_data)
1195
1196 AC_CACHE_CHECK(linker support for INSERT in linker script,
1197                libc_cv_insert,
1198                [cat > conftest.c <<EOF
1199                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1200                 int test (void) { return bar; }
1201 EOF
1202                 cat > conftest.t <<EOF
1203                 SECTIONS
1204                 {
1205                   .bar : { *(.bar) }
1206                 }
1207                 INSERT AFTER .rela.dyn;
1208 EOF
1209                 libc_cv_insert=no
1210                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1211                   libc_cv_insert=yes
1212                 fi
1213                 rm -f conftest.*
1214                ])
1215 AC_SUBST(libc_cv_insert)
1216
1217 AC_CACHE_CHECK(for broken __attribute__((alias())),
1218                libc_cv_broken_alias_attribute,
1219                [cat > conftest.c <<EOF
1220                extern int foo (int x) __asm ("xyzzy");
1221                int bar (int x) { return x; }
1222                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1223                extern int dfoo;
1224                extern __typeof (dfoo) dfoo __asm ("abccb");
1225                int dfoo = 1;
1226 EOF
1227                libc_cv_broken_alias_attribute=yes
1228                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1229                  if grep 'xyzzy' conftest.s >/dev/null &&
1230                     grep 'abccb' conftest.s >/dev/null; then
1231                    libc_cv_broken_alias_attribute=no
1232                  fi
1233                fi
1234                rm -f conftest.c conftest.s
1235                ])
1236 if test $libc_cv_broken_alias_attribute = yes; then
1237   AC_MSG_ERROR(working alias attribute support required)
1238 fi
1239
1240 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1241                libc_cv_have_sdata_section,
1242                [echo "int i;" > conftest.c
1243                 libc_cv_have_sdata_section=no
1244                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1245                    | grep '\.sdata' >/dev/null; then
1246                   libc_cv_have_sdata_section=yes
1247                 fi
1248                 rm -f conftest.c conftest.so
1249                ])
1250 if test $libc_cv_have_sdata_section = yes; then
1251   AC_DEFINE(HAVE_SDATA_SECTION)
1252 fi
1253
1254 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1255                libc_cv_ctors_header, [dnl
1256   libc_cv_ctors_header=yes
1257   LIBC_TRY_LINK_STATIC([
1258 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1259 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1260 ],
1261               [dnl
1262       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1263         { gsub(/\@<:@ */, "@<:@") }
1264         $2 == ".ctors" || $2 == ".dtors" {
1265           size = strtonum("0x" $6)
1266           align = strtonum("0x" $NF)
1267           seen@<:@$2@:>@ = 1
1268           stub@<:@$2@:>@ = size == align * 2
1269         }
1270         END {
1271           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1272           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1273           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1274         }
1275       '], [libc_cv_ctors_header=no])
1276     ], [dnl
1277       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1278     ])
1279 ])
1280 if test $libc_cv_ctors_header = no; then
1281   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1282 fi
1283
1284 AC_CACHE_CHECK(for libunwind-support in compiler,
1285                libc_cv_cc_with_libunwind, [
1286   cat > conftest.c <<EOF
1287 int main (void) { return 0; }
1288 EOF
1289   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1290      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1291     libc_cv_cc_with_libunwind=yes
1292   else
1293     libc_cv_cc_with_libunwind=no
1294   fi
1295   rm -f conftest*])
1296 AC_SUBST(libc_cv_cc_with_libunwind)
1297 if test $libc_cv_cc_with_libunwind = yes; then
1298   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1299 fi
1300
1301 ASFLAGS_config=
1302 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1303                libc_cv_as_noexecstack, [dnl
1304 cat > conftest.c <<EOF
1305 void foo (void) { }
1306 EOF
1307 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1308                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1309    && grep .note.GNU-stack conftest.s >/dev/null \
1310    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1311                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1312 then
1313   libc_cv_as_noexecstack=yes
1314 else
1315   libc_cv_as_noexecstack=no
1316 fi
1317 rm -f conftest*])
1318 if test $libc_cv_as_noexecstack = yes; then
1319   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1320 fi
1321 AC_SUBST(ASFLAGS_config)
1322
1323 AC_CACHE_CHECK(for -z combreloc,
1324                libc_cv_z_combreloc, [dnl
1325 cat > conftest.c <<EOF
1326 extern int bar (int);
1327 extern int mumble;
1328 int foo (void) { return bar (mumble); }
1329 EOF
1330 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1331                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1332                         -nostdlib -nostartfiles
1333                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1334 then
1335 dnl The following test is a bit weak.  We must use a tool which can test
1336 dnl cross-platform since the gcc used can be a cross compiler.  Without
1337 dnl introducing new options this is not easily doable.  Instead use a tool
1338 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1339 dnl look for a section named .rel.dyn or .rela.dyn.
1340   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1341     libc_cv_z_combreloc=yes
1342   else
1343     libc_cv_z_combreloc=no
1344   fi
1345 else
1346   libc_cv_z_combreloc=no
1347 fi
1348 rm -f conftest*])
1349 if test "$libc_cv_z_combreloc" = yes; then
1350   AC_DEFINE(HAVE_Z_COMBRELOC)
1351 fi
1352 AC_SUBST(libc_cv_z_combreloc)
1353
1354 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1355                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1356 AC_SUBST(libc_cv_z_execstack)
1357
1358 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1359                     [-Wl,--no-dynamic-linker],
1360                     [libc_cv_no_dynamic_linker=yes],
1361                     [libc_cv_no_dynamic_linker=no])
1362 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1363
1364 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1365 LIBC_TRY_CC_OPTION([-static-pie],
1366                    [libc_cv_static_pie=yes],
1367                    [libc_cv_static_pie=no])
1368 ])
1369 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1370
1371 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1372 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1373 ])
1374
1375 AC_SUBST(libc_cv_fpie)
1376
1377 AC_CACHE_CHECK(for --hash-style option,
1378                libc_cv_hashstyle, [dnl
1379 cat > conftest.c <<EOF
1380 int _start (void) { return 42; }
1381 EOF
1382 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1383                             -fPIC -shared -o conftest.so conftest.c
1384                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1385 then
1386   libc_cv_hashstyle=yes
1387 else
1388   libc_cv_hashstyle=no
1389 fi
1390 rm -f conftest*])
1391 AC_SUBST(libc_cv_hashstyle)
1392
1393 # The linker's default -shared behavior is good enough if it
1394 # does these things that our custom linker scripts ensure that
1395 # all allocated NOTE sections come first.
1396 if test "$use_default_link" = default; then
1397   AC_CACHE_CHECK([for sufficient default -shared layout],
1398                   libc_cv_use_default_link, [dnl
1399   libc_cv_use_default_link=no
1400   cat > conftest.s <<\EOF
1401           .section .note.a,"a",%note
1402           .balign 4
1403           .long 4,4,9
1404           .string "GNU"
1405           .string "foo"
1406           .section .note.b,"a",%note
1407           .balign 4
1408           .long 4,4,9
1409           .string "GNU"
1410           .string "bar"
1411 EOF
1412   if AC_TRY_COMMAND([dnl
1413   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1414        ac_try=`$READELF -S conftest.so | sed -n \
1415          ['${x;p;}
1416           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1417           t a
1418           b
1419           : a
1420           H']`
1421   then
1422     libc_seen_a=no libc_seen_b=no
1423     set -- $ac_try
1424     while test $# -ge 2 -a "$1" = NOTE; do
1425       case "$2" in
1426       .note.a) libc_seen_a=yes ;;
1427       .note.b) libc_seen_b=yes ;;
1428       esac
1429       shift 2
1430     done
1431     case "$libc_seen_a$libc_seen_b" in
1432     yesyes)
1433       libc_cv_use_default_link=yes
1434       ;;
1435     *)
1436       echo >&AS_MESSAGE_LOG_FD "\
1437 $libc_seen_a$libc_seen_b from:
1438 $ac_try"
1439       ;;
1440     esac
1441   fi
1442   rm -f conftest*])
1443   use_default_link=$libc_cv_use_default_link
1444 fi
1445
1446 AC_CACHE_CHECK(for GLOB_DAT reloc,
1447                libc_cv_has_glob_dat, [dnl
1448 cat > conftest.c <<EOF
1449 extern int mumble;
1450 int foo (void) { return mumble; }
1451 EOF
1452 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1453                         -fPIC -shared -o conftest.so conftest.c
1454                         -nostdlib -nostartfiles $no_ssp
1455                         1>&AS_MESSAGE_LOG_FD])
1456 then
1457 dnl look for GLOB_DAT relocation.
1458   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1459     libc_cv_has_glob_dat=yes
1460   else
1461     libc_cv_has_glob_dat=no
1462   fi
1463 else
1464   libc_cv_has_glob_dat=no
1465 fi
1466 rm -f conftest*])
1467 AC_SUBST(libc_cv_has_glob_dat)
1468
1469 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1470 if libc_cv_output_format=`
1471 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1472 then
1473   :
1474 else
1475   libc_cv_output_format=
1476 fi
1477 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1478 AC_SUBST(libc_cv_output_format)
1479
1480 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1481 cat > conftest.c <<EOF
1482 int foo;
1483 EOF
1484 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1485                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1486 then
1487   libc_cv_fno_toplevel_reorder=yes
1488 else
1489   libc_cv_fno_toplevel_reorder=no
1490 fi
1491 rm -f conftest*])
1492 if test $libc_cv_fno_toplevel_reorder = yes; then
1493   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1494 else
1495   fno_unit_at_a_time=-fno-unit-at-a-time
1496 fi
1497 AC_SUBST(fno_unit_at_a_time)
1498
1499 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1500 [dnl
1501 cat > conftest.c <<EOF
1502 __thread int i;
1503 void foo (void)
1504 {
1505   i = 10;
1506 }
1507 EOF
1508 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1509                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1510 then
1511   libc_cv_mtls_dialect_gnu2=yes
1512 else
1513   libc_cv_mtls_dialect_gnu2=no
1514 fi
1515 rm -f conftest*])
1516 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1517 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1518
1519 AC_CACHE_CHECK(whether cc puts quotes around section names,
1520                libc_cv_have_section_quotes,
1521                [cat > conftest.c <<EOF
1522                 static const int foo
1523                 __attribute__ ((section ("bar"))) = 1;
1524 EOF
1525                 if ${CC-cc} -S conftest.c -o conftest.s; then
1526                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1527                     libc_cv_have_section_quotes=yes
1528                   else
1529                     libc_cv_have_section_quotes=no
1530                   fi
1531                 else
1532                   libc_cv_have_section_quotes=unknown
1533                 fi
1534                 rm -f conftest.{c,s}
1535                 ])
1536 if test $libc_cv_have_section_quotes = yes; then
1537   AC_DEFINE(HAVE_SECTION_QUOTES)
1538 fi
1539
1540 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1541 cat > conftest.c <<\EOF
1542 void zero (void *x)
1543 {
1544   __builtin_memset (x, 0, 1000);
1545 }
1546 EOF
1547 dnl
1548 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1549 then
1550   libc_cv_gcc_builtin_memset=no
1551 else
1552   libc_cv_gcc_builtin_memset=yes
1553 fi
1554 rm -f conftest* ])
1555 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1556   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1557 fi
1558
1559 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1560 cat > conftest.c <<\EOF
1561 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1562 char *foo (const char *a, const char *b)
1563 {
1564   return __builtin_strstr (a, b);
1565 }
1566 EOF
1567 dnl
1568 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1569 then
1570   libc_cv_gcc_builtin_redirection=yes
1571 else
1572   libc_cv_gcc_builtin_redirection=no
1573 fi
1574 rm -f conftest* ])
1575 if test "$libc_cv_gcc_builtin_redirection" = no; then
1576   AC_MSG_ERROR([support for the symbol redirection needed])
1577 fi
1578
1579 dnl Determine how to disable generation of FMA instructions.
1580 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1581                libc_cv_cc_nofma, [dnl
1582 libc_cv_cc_nofma=
1583 for opt in -ffp-contract=off -mno-fused-madd; do
1584   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1585 done])
1586 AC_SUBST(libc_cv_cc_nofma)
1587
1588 if test -n "$submachine"; then
1589   AC_CACHE_CHECK([for compiler option for CPU variant],
1590                  libc_cv_cc_submachine, [dnl
1591   libc_cv_cc_submachine=no
1592   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1593     LIBC_TRY_CC_OPTION([$opt], [
1594       libc_cv_cc_submachine="$opt"
1595       break], [])
1596   done])
1597   if test "x$libc_cv_cc_submachine" = xno; then
1598     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1599   fi
1600 fi
1601 AC_SUBST(libc_cv_cc_submachine)
1602
1603 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1604 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1605 cat > conftest.c <<EOF
1606 void
1607 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1608 foo (void) {}
1609 EOF
1610 libc_cv_cc_loop_to_function=no
1611 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1612 then
1613   libc_cv_cc_loop_to_function=yes
1614 fi
1615 rm -f conftest*])
1616 if test $libc_cv_cc_loop_to_function = yes; then
1617   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1618 fi
1619 AC_SUBST(libc_cv_cc_loop_to_function)
1620
1621 dnl Check whether we have the gd library available.
1622 AC_MSG_CHECKING(for libgd)
1623 if test "$with_gd" != "no"; then
1624   old_CFLAGS="$CFLAGS"
1625   CFLAGS="$CFLAGS $libgd_include"
1626   old_LDFLAGS="$LDFLAGS"
1627   LDFLAGS="$LDFLAGS $libgd_ldflags"
1628   old_LIBS="$LIBS"
1629   LIBS="$LIBS -lgd -lpng -lz -lm"
1630   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1631   CFLAGS="$old_CFLAGS"
1632   LDFLAGS="$old_LDFLAGS"
1633   LIBS="$old_LIBS"
1634 else
1635   LIBGD=no
1636 fi
1637 AC_MSG_RESULT($LIBGD)
1638 AC_SUBST(LIBGD)
1639
1640 # SELinux detection
1641 if test x$with_selinux = xno ; then
1642   have_selinux=no;
1643 else
1644   # See if we have the SELinux library
1645   AC_CHECK_LIB(selinux, is_selinux_enabled,
1646                have_selinux=yes, have_selinux=no)
1647   if test x$with_selinux = xyes ; then
1648     if test x$have_selinux = xno ; then
1649       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1650     fi
1651   fi
1652 fi
1653 # Check if we're building with SELinux support.
1654 if test "x$have_selinux" = xyes; then
1655   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1656
1657   # See if we have the libaudit library
1658   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1659                have_libaudit=yes, have_libaudit=no)
1660   if test "x$have_libaudit" = xyes; then
1661     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1662   fi
1663   AC_SUBST(have_libaudit)
1664
1665   # See if we have the libcap library
1666   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1667   if test "x$have_libcap" = xyes; then
1668     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1669   fi
1670   AC_SUBST(have_libcap)
1671 fi
1672 AC_SUBST(have_selinux)
1673
1674 CPPUNDEFS=
1675 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1676 dnl Since we are building the implementations of the fortified functions here,
1677 dnl having the macro defined interacts very badly.
1678 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1679 [AC_TRY_COMPILE([], [
1680 #ifdef _FORTIFY_SOURCE
1681 # error bogon
1682 #endif],
1683                 [libc_cv_predef_fortify_source=no],
1684                 [libc_cv_predef_fortify_source=yes])])
1685 if test $libc_cv_predef_fortify_source = yes; then
1686   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1687 fi
1688 AC_SUBST(CPPUNDEFS)
1689
1690 # Some linkers on some architectures support __ehdr_start but with
1691 # bugs.  Make sure usage of it does not create relocations in the
1692 # output (as the linker should resolve them all for us).
1693 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1694                libc_cv_ehdr_start, [
1695 old_CFLAGS="$CFLAGS"
1696 old_LDFLAGS="$LDFLAGS"
1697 old_LIBS="$LIBS"
1698 CFLAGS="$CFLAGS -fPIC"
1699 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1700 LIBS=
1701 AC_LINK_IFELSE([AC_LANG_SOURCE([
1702 typedef struct {
1703   char foo;
1704   long val;
1705 } Ehdr;
1706 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1707 long ehdr (void) { return __ehdr_start.val; }
1708 ])],
1709                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1710                   libc_cv_ehdr_start=broken
1711                 else
1712                   libc_cv_ehdr_start=yes
1713                 fi], [libc_cv_ehdr_start=no])
1714 CFLAGS="$old_CFLAGS"
1715 LDFLAGS="$old_LDFLAGS"
1716 LIBS="$old_LIBS"
1717 ])
1718 if test "$libc_cv_ehdr_start" = yes; then
1719   AC_DEFINE([HAVE_EHDR_START])
1720 elif test "$libc_cv_ehdr_start" = broken; then
1721   AC_MSG_WARN([linker is broken -- you should upgrade])
1722 fi
1723
1724 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1725                libc_cv_builtin_trap, [dnl
1726 libc_cv_builtin_trap=no
1727 AC_TRY_COMPILE([], [__builtin_trap ()], [
1728 libc_undefs=`$NM -u conftest.o |
1729   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1730     2>&AS_MESSAGE_LOG_FD` || {
1731   AC_MSG_ERROR([confusing output from $NM -u])
1732 }
1733 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1734 if test -z "$libc_undefs"; then
1735   libc_cv_builtin_trap=yes
1736 fi])])
1737 if test $libc_cv_builtin_trap = yes; then
1738   AC_DEFINE([HAVE_BUILTIN_TRAP])
1739 fi
1740
1741 dnl C++ feature tests.
1742 AC_LANG_PUSH([C++])
1743
1744 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1745                libc_cv_cxx_thread_local, [
1746 old_CXXFLAGS="$CXXFLAGS"
1747 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1748 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1749 #include <thread>
1750
1751 // Compiler support.
1752 struct S
1753 {
1754   S ();
1755   ~S ();
1756 };
1757 thread_local S s;
1758 S * get () { return &s; }
1759
1760 // libstdc++ support.
1761 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1762 #error __cxa_thread_atexit_impl not supported
1763 #endif
1764 ])],
1765                [libc_cv_cxx_thread_local=yes],
1766                [libc_cv_cxx_thread_local=no])
1767 CXXFLAGS="$old_CXXFLAGS"
1768 ])
1769 AC_SUBST(libc_cv_cxx_thread_local)
1770
1771 AC_LANG_POP([C++])
1772 dnl End of C++ feature tests.
1773
1774 ### End of automated tests.
1775 ### Now run sysdeps configure fragments.
1776
1777 # They also can set these variables.
1778 use_ldconfig=no
1779 ldd_rewrite_script=no
1780 libc_cv_sysconfdir=$sysconfdir
1781 libc_cv_localstatedir=$localstatedir
1782 libc_cv_gcc_unwind_find_fde=no
1783 libc_cv_idn=no
1784
1785 # Iterate over all the sysdep directories we will use, running their
1786 # configure fragments.
1787 for dir in $sysnames; do
1788   case $dir in
1789     /*) dest=$dir ;;
1790     *)  dest=$srcdir/$dir ;;
1791   esac
1792   if test -r $dest/configure; then
1793     AC_MSG_RESULT(running configure fragment for $dir)
1794     . $dest/configure
1795   fi
1796 done
1797
1798 if test x"$build_mathvec" = xnotset; then
1799   build_mathvec=no
1800 fi
1801 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1802
1803 AC_SUBST(libc_extra_cflags)
1804 AC_SUBST(libc_extra_cppflags)
1805
1806 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1807   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1808 fi
1809 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1810
1811 # A sysdeps configure fragment can reset this if IFUNC is not actually
1812 # usable even though the assembler knows how to generate the symbol type.
1813 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1814   AC_DEFINE(HAVE_IFUNC)
1815 fi
1816 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1817
1818 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1819   AC_DEFINE(HAVE_GCC_IFUNC)
1820 fi
1821
1822 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1823 # configure fragment can override the value to prevent this AC_DEFINE.
1824 AC_SUBST(use_nscd)
1825 if test "x$use_nscd" != xno; then
1826   AC_DEFINE([USE_NSCD])
1827 fi
1828 if test "x$build_nscd" = xdefault; then
1829   build_nscd=$use_nscd
1830 fi
1831
1832 AC_SUBST(libc_cv_slibdir)
1833 AC_SUBST(libc_cv_rtlddir)
1834 AC_SUBST(libc_cv_complocaledir)
1835 AC_SUBST(libc_cv_sysconfdir)
1836 AC_SUBST(libc_cv_localstatedir)
1837 AC_SUBST(libc_cv_rootsbindir)
1838
1839 if test x$use_ldconfig = xyes; then
1840   AC_DEFINE(USE_LDCONFIG)
1841 fi
1842 AC_SUBST(use_ldconfig)
1843 AC_SUBST(ldd_rewrite_script)
1844
1845 AC_SUBST(static)
1846 AC_SUBST(shared)
1847
1848 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1849 [libc_cv_pic_default=yes
1850 cat > conftest.c <<EOF
1851 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1852 # error PIC is default.
1853 #endif
1854 EOF
1855 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1856   libc_cv_pic_default=no
1857 fi
1858 rm -f conftest.*])
1859 AC_SUBST(libc_cv_pic_default)
1860
1861 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1862 [libc_cv_cc_pie_default=yes
1863 cat > conftest.c <<EOF
1864 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1865 # error PIE is default.
1866 #endif
1867 EOF
1868 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1869   libc_cv_cc_pie_default=no
1870 fi
1871 rm -f conftest.*])
1872 libc_cv_pie_default=$libc_cv_cc_pie_default
1873 AC_SUBST(libc_cv_cc_pie_default)
1874 AC_SUBST(libc_cv_pie_default)
1875
1876 # Set the `multidir' variable by grabbing the variable from the compiler.
1877 # We do it once and save the result in a generated makefile.
1878 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1879 AC_SUBST(libc_cv_multidir)
1880
1881 if test "$static_pie" = yes; then
1882   # The linker must support --no-dynamic-linker.
1883   if test "$libc_cv_no_dynamic_linker" != yes; then
1884     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1885   fi
1886   # Default to PIE.
1887   libc_cv_pie_default=yes
1888   AC_DEFINE(ENABLE_STATIC_PIE)
1889 fi
1890 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1891
1892 AC_SUBST(profile)
1893 AC_SUBST(static_nss)
1894
1895 AC_SUBST(DEFINES)
1896
1897 dnl See sysdeps/mach/configure.ac for this variable.
1898 AC_SUBST(mach_interface_list)
1899
1900 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1901 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1902 AC_SUBST(VERSION)
1903 AC_SUBST(RELEASE)
1904
1905 AC_CONFIG_FILES([config.make Makefile])
1906 AC_CONFIG_COMMANDS([default],[[
1907 case $CONFIG_FILES in *config.make*)
1908 echo "$config_vars" >> config.make;;
1909 esac
1910 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1911 AC_OUTPUT