sysdeps/mach/hurd/errnos.awk

   1 # Copyright (C) 1991, 92, 93, 94, 95, 96 Free Software Foundation, Inc.
   2 # This file is part of the GNU C Library.
   3
   4 # The GNU C Library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Library General Public License
   6 # as published by the Free Software Foundation; either version 2 of
   7 # the License, or (at your option) any later version.
   8
   9 # The GNU C Library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Library General Public License for more details.
  13
  14 # You should have received a copy of the GNU Library General Public
  15 # License along with the GNU C Library; see the file COPYING.LIB.  If
  16 # not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  17 # Cambridge, MA 02139, USA.
  18
  19 # errno.texinfo contains lines like:
  20 # @comment errno.h
  21 # @comment POSIX.1: Function not implemented
  22 # @deftypevr Macro int ENOSYS
  23 # @comment errno 123
  24
  25 BEGIN {
  26     print "/* This file generated by errnos.awk.  */";
  27     print "";
  28     print "/* The Hurd uses Mach error system 0x10, currently only subsystem 0. */";
  29     print "#ifndef _HURD_ERRNO";
  30     print "#define _HURD_ERRNO(n)\t((0x10 << 26) | ((n) & 0x3fff))";
  31     print "#endif";
  32     print "";
  33     print "#ifdef _ERRNO_H\n";
  34     print "enum __error_t_codes\n{";
  35     errnoh = 0;
  36     maxerrno = 0;
  37     in_mach_errors = "";
  38     in_math = 0;
  39     edom = erange = "";
  40     print "#undef EDOM\n#undef ERANGE";
  41   }
  42
  43 $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  44 $1 == "@comment" && errnoh == 1 \
  45   {
  46     ++errnoh;
  47     etext = "";
  48     for (i = 3; i <= NF; ++i)
  49       etext = etext " " $i;
  50     next;
  51   }
  52
  53 errnoh == 2 && $1 == "@deftypevr"  && $2 == "Macro" && $3 == "int" \
  54   { ++errnoh; e = $4; next; }
  55
  56 errnoh == 3 && $1 == "@comment" && $2 == "errno" {
  57     if (e == "EWOULDBLOCK")
  58       {
  59         print "#define EWOULDBLOCK EAGAIN /* Operation would block */";
  60         next;
  61       }
  62     errno = $3 + 0;
  63     if (errno == 0)
  64       next;
  65     if (errno > maxerrno) maxerrno = errno;
  66     x = sprintf ("%-40s/*%s */", sprintf ("%-24s%s", "#define\t" e,
  67                                           "_HURD_ERRNO (" errno ")"),
  68                  etext);
  69     if (e == "EDOM")
  70       edom = x;
  71     else if (e == "ERANGE")
  72       erange = x;
  73     printf "\t%-16s= _HURD_ERRNO (%d),\n", e, errno;
  74     print x;
  75     next;
  76   }
  77 { errnoh=0 }
  78
  79 NF == 3 && $1 == "#define" && $2 == "MACH_SEND_IN_PROGRESS" \
  80   {
  81     in_mach_errors = FILENAME;
  82     print "\n\t/* Errors from <mach/message.h>.  */";
  83   }
  84 NF == 3 && $1 == "#define" && $2 == "KERN_SUCCESS" \
  85   {
  86     in_mach_errors = FILENAME;
  87     print "\n\t/* Errors from <mach/kern_return.h>.  */";
  88     next;
  89   }
  90
  91 in_mach_errors != "" && $2 == "MACH_IPC_COMPAT" \
  92   {
  93     in_mach_errors = "";
  94   }
  95
  96 in_mach_errors == FILENAME && NF == 3 && $1 == "#define" \
  97   {
  98     printf "\t%-32s= %s,\n", "E" $2, $3;
  99   }
 100
 101 $1 == "#define" && $2 == "_MACH_MIG_ERRORS_H_" \
 102   {
 103     in_mig_errors = 1;
 104     print "\n\t/* Errors from <mach/mig_errors.h>.  */";
 105     next;
 106   }
 107 in_mig_errors && $1 == "#endif" && $3 == "_MACH_MIG_ERRORS_H_" \
 108   {
 109     in_mig_errors = 0;
 110   }
 111
 112 (in_mig_errors && $1 == "#define" && $3 <= -300) || \
 113 (in_device_errors && $1 == "#define") \
 114   {
 115     printf "%-32s", sprintf ("\t%-24s= %s,", "E" $2, $3);
 116     for (i = 4; i <= NF; ++i)
 117       printf " %s", $i;
 118     printf "\n";
 119   }
 120
 121 $1 == "#define" && $2 == "D_SUCCESS" \
 122   {
 123     in_device_errors = 1;
 124     print "\n\t/* Errors from <device/device_types.h>.  */";
 125     next;
 126   }
 127 in_device_errors && $1 == "#endif" \
 128   {
 129     in_device_errors = 0;
 130   }
 131
 132
 133 END \
 134   {
 135     print "";
 136     print "};";
 137     print "";
 138     printf "#define\t_HURD_ERRNOS\t%d\n", maxerrno+1;
 139     print "";
 140     print "\
 141 /* User-visible type of error codes.  It is ok to use `int' or\n\
 142    `kern_return_t' for these, but with `error_t' the debugger prints\n\
 143    symbolic values.  */";
 144     print "#ifdef __USE_GNU";
 145     print "typedef enum __error_t_codes error_t;"
 146     print "#define __error_t_defined\t1"
 147     print "#endif";
 148     print "";
 149     print "/* errno is a per-thread variable.  */";
 150     print "#include <hurd/threadvar.h>";
 151     print "#define errno        (*__hurd_errno_location ())";
 152     print "";
 153     print "#endif /* <errno.h> included.  */";
 154     print "";
 155     print "#if !defined (_ERRNO_H) && defined (__need_Emath)";
 156     print edom; print erange;
 157     print "#endif /* <errno.h> not included and need math error codes.  */";
 158   }