sysdeps/powerpc/powerpc32/fpu/s_rintf.S

   1 /* Round float to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst4,"aM",@progbits,4
  23         .align  2
  24 .LC0:   /* 2**23 */
  25         .long 0x4b000000
  26
  27         .section        ".text"
  28 ENTRY (__rintf)
  29 #ifdef SHARED
  30         mflr    r11
  31         cfi_register(lr,r11)
  32         bcl     20,31,1f
  33 1:      mflr    r9
  34         addis   r9,r9,.LC0-1b@ha
  35         lfs     fp13,.LC0-1b@l(r9)
  36         mtlr    r11
  37         cfi_same_value (lr)
  38 #else
  39         lis     r9,.LC0@ha
  40         lfs     fp13,.LC0@l(r9)
  41 #endif
  42         fabs    fp0,fp1
  43         fsubs   fp12,fp13,fp13  /* generate 0.0  */
  44         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO23)  */
  45         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  46         bnllr-  cr7
  47         bng-    cr6,.L4
  48         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  49         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  50         fabs    fp1,fp1         /* if (x == 0.0)  */
  51         blr                     /* x = 0.0; */
  52 .L4:
  53         bnllr-  cr6             /* if (x < 0.0)  */
  54         fsubs   fp1,fp1,fp13    /* x-= TWO23;  */
  55         fadds   fp1,fp1,fp13    /* x+= TWO23;  */
  56         fnabs   fp1,fp1         /* if (x == 0.0)  */
  57         blr                     /* x = -0.0; */
  58         END (__rintf)
  59
  60 weak_alias (__rintf, rintf)
  61