sysdeps/powerpc/powerpc32/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24 #include <math_ldbl_opt.h>
  25
  26         .section        .rodata.cst4,"aM",@progbits,4
  27         .align  2
  28 .LC0:   /* 2**52 */
  29         .long 0x59800000
  30
  31         .section        ".text"
  32 ENTRY (__rint)
  33 #ifdef SHARED
  34         mflr    r11
  35         cfi_register(lr,r11)
  36         bcl     20,31,1f
  37 1:      mflr    r9
  38         addis   r9,r9,.LC0-1b@ha
  39         lfs     fp13,.LC0-1b@l(r9)
  40         mtlr    r11
  41         cfi_same_value (lr)
  42 #else
  43         lis     r9,.LC0@ha
  44         lfs     fp13,.LC0@l(r9)
  45 #endif
  46         fabs    fp0,fp1
  47         fsub    fp12,fp13,fp13  /* generate 0.0  */
  48         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  49         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  50         bnllr-  cr7
  51         bng-    cr6,.L4
  52         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  53         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  54         fabs    fp1,fp1         /* if (x == 0.0)  */
  55         blr                     /* x = 0.0; */
  56 .L4:
  57         bnllr-  cr6             /* if (x < 0.0)  */
  58         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  59         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  60         fnabs   fp1,fp1         /* if (x == 0.0)  */
  61         blr                     /* x = -0.0; */
  62         END (__rint)
  63
  64 weak_alias (__rint, rint)
  65
  66 #ifdef NO_LONG_DOUBLE
  67 weak_alias (__rint, rintl)
  68 strong_alias (__rint, __rintl)
  69 #endif
  70 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  71 compat_symbol (libm, __rint, rintl, GLIBC_2_0)
  72 #endif