sysdeps/powerpc/powerpc32/fpu/s_floor.S

   1 /* Floor function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        .rodata.cst4,"aM",@progbits,4
  24         .align  2
  25 .LC0:   /* 2**52 */
  26         .long 0x59800000
  27
  28         .section        ".text"
  29 ENTRY (__floor)
  30         mffs    fp11            /* Save current FPU rounding mode.  */
  31 #ifdef SHARED
  32         mflr    r11
  33         cfi_register(lr,r11)
  34         bcl     20,31,1f
  35 1:      mflr    r9
  36         addis   r9,r9,.LC0-1b@ha
  37         lfs     fp13,.LC0-1b@l(r9)
  38         mtlr    r11
  39         cfi_same_value (lr)
  40 #else
  41         lis     r9,.LC0@ha
  42         lfs     fp13,.LC0@l(r9)
  43 #endif
  44         fabs    fp0,fp1
  45         fsub    fp12,fp13,fp13  /* generate 0.0  */
  46         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  47         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  48         bnllr-  cr7
  49         mtfsfi  7,3             /* Set rounding mode toward -inf.  */
  50         ble-    cr6,.L4
  51         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  52         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  53         fabs    fp1,fp1         /* if (x == 0.0)  */
  54                                 /* x = 0.0; */
  55         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  56         blr
  57 .L4:
  58         bge-    cr6,.L9         /* if (x < 0.0)  */
  59         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  60         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  61         fnabs   fp1,fp1         /* if (x == 0.0)  */
  62                                 /* x = -0.0; */
  63 .L9:
  64         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  65         blr
  66         END (__floor)
  67
  68 weak_alias (__floor, floor)
  69
  70 #ifdef NO_LONG_DOUBLE
  71 weak_alias (__floor, floorl)
  72 strong_alias (__floor, __floorl)
  73 #endif
  74 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_0)
  75 compat_symbol (libm, __floor, floorl, GLIBC_2_0)
  76 #endif