configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.4.2)dnl             dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware,
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52 AC_ARG_WITH(weak-symbols, dnl
  53   --with-weak-symbols     if weak symbols are available in as and ld,
  54             weak=$withval, weak=no)
  55
  56 AC_ARG_ENABLE(libio, dnl
  57 [  --enable-libio          build in GNU libio instead of GNU stdio],
  58               stdio=libio, stdio=stdio)
  59
  60 dnl Arguments to enable or disable building the shared, profiled, and
  61 dnl -fomit-frame-pointer libraries.
  62 AC_ARG_ENABLE(shared, dnl
  63 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  64             shared=$enableval, shared=default)
  65 AC_ARG_ENABLE(profile, dnl
  66 [  --enable-profile        build profiled library [default=yes]],
  67             profile=$enableval, profile=yes)
  68 AC_ARG_ENABLE(omitfp, dnl
  69 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  70             omitfp=$enableval, omitfp=no)
  71
  72 AC_MSG_CHECKING(stdio selection)
  73 AC_SUBST(stdio)
  74 if test $stdio = libio; then
  75   AC_DEFINE(USE_IN_LIBIO)
  76 fi
  77 AC_MSG_RESULT($stdio)
  78
  79 AC_CANONICAL_HOST
  80 # We keep the original values in `$config_*' and never modify them, so we
  81 # can write them unchanged into config.make.  Everything else uses
  82 # $machine, $vendor, and $os, and changes them whenever convenient.
  83 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  84
  85 # Some configurations imply other options.
  86 case "$host_os" in
  87 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  88   # These systems always use GNU tools.
  89   gnu_ld=yes gnu_as=yes
  90 esac
  91 case "$host_os" in
  92 gnu* | linux* | sysv4* | solaris2*)
  93   # These systems always use the ELF format.
  94   elf=yes
  95 esac
  96
  97 # Compute the list of sysdep directories for this configuration.
  98 sysdep_dir=$srcdir/sysdeps
  99 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
 100 machine=$config_machine
 101 vendor=$config_vendor
 102 os=$config_os
 103
 104 dnl We need to use [ and ] for other purposes for a while now.
 105 changequote(,)dnl
 106 # Expand the configuration machine name into a subdirectory by architecture
 107 # type and particular chip.
 108 case "$machine" in
 109 a29k | am29000) machine=a29k ;;
 110 alpha*)         machine=alpha/$machine ;;
 111 hppa*)          machine=hppa/$machine ;;
 112 i[345]86)       machine=i386/$machine ;;
 113 m680?0)         machine=m68k/$machine ;;
 114 m68k)           machine=m68k/m68020 ;;
 115 m88???)         machine=m88k/$machine ;;
 116 m88k)           machine=m88k/m88100 ;;
 117 mips*)          machine=mips/$machine ;;
 118 mips64*)        machine=mips/mips64/$machine ;;
 119 sparc[6789])    machine=sparc/$machine ;;
 120 supersparc)     machine=sparc/sparc8 ;;
 121 esac
 122
 123 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 124 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 125
 126 case "$os" in
 127 gnu*)
 128   base_os=mach/hurd ;;
 129 netbsd* | 386bsd* | freebsd* | bsdi*)
 130   base_os=unix/bsd/bsd4.4 ;;
 131 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 132   base_os=unix/bsd ;;
 133 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 134   base_os=unix/sysv ;;
 135 solaris[2-9]*)
 136   base_os=unix/sysv/sysv4 ;;
 137 none)
 138   base_os=standalone ;;
 139 *)
 140   base_os='' ;;
 141 esac
 142
 143 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 144 tail=$os
 145 ostry=$os
 146 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 147   ostry="$ostry /$o"
 148   tail=$o
 149 done
 150 o=`echo $tail | sed 's/[0-9]*$//'`
 151 if test $o != $tail; then
 152   ostry="$ostry /$o"
 153 fi
 154
 155 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 156 base=
 157 tail=$base_os
 158 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 159   set $b
 160   base="$base /$1"
 161   tail="$2"
 162 done
 163
 164 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 165 mach=
 166 tail=$machine
 167 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 168   set $m
 169   # Prepend the machine's FPU directory unless --without-fp.
 170   if test "$with_fp" = yes; then
 171     mach="$mach /$1/fpu"
 172   fi
 173   mach="$mach /$1"
 174   tail="$2"
 175 done
 176
 177 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 178 changequote([,])dnl
 179
 180 # Find what sysdep directories exist.
 181 sysnames=
 182 for b in $base ''; do
 183   for m0 in $mach ''; do
 184     for v in /$vendor ''; do
 185       for o in /$ostry ''; do
 186         for m in $mach ''; do
 187           try="$m0$b$v$o$m"
 188           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 189           if test -d $sysdep_dir$try; then
 190             sysnames="$sysnames $try"
 191             { test -n "$o" || test -n "$b"; } && os_used=t
 192             { test -n "$m" || test -n "$m0"; } && machine_used=t
 193           fi
 194         done
 195       done
 196     done
 197   done
 198 done
 199
 200 if test -z "$os_used" && test "$os" != none; then
 201   AC_MSG_ERROR(Operating system $os is not supported.)
 202 fi
 203 if test -z "$machine_used" && test "$machine" != none; then
 204   AC_MSG_ERROR(The $machine is not supported.)
 205 fi
 206
 207 # We have now validated the configuration.
 208
 209
 210 # If using ELF, look for an `elf' subdirectory of each machine directory.
 211 # We prepend these rather than inserting them whereever the machine appears
 212 # because things specified by the machine's ELF ABI should override
 213 # OS-specific things, and should always be the same for any OS on the
 214 # machine (otherwise what's the point of an ABI?).
 215 if test "$elf" = yes; then
 216   elf_dirs=
 217   for m in $mach; do
 218     if test -d $sysdep_dir$m/elf; then
 219       elf_dirs="$elf_dirs $m/elf"
 220     fi
 221   done
 222   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 223 fi
 224
 225
 226 # Remove the leading slashes.
 227 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 228
 229
 230 # Expand the list of system names into a full list of directories
 231 # from each element's parent name and Implies file (if present).
 232 set $sysnames
 233 while test $# -gt 0; do
 234   name=$1
 235   shift
 236
 237   if test -f $sysdep_dir/$name/Implies; then
 238     # Collect more names from the `Implies' file (removing comments).
 239     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 240     for x in $implied; do
 241       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 242     done
 243   else
 244     implied=
 245   fi
 246
 247   # Add NAME to the list of names.
 248   names="$names $name"
 249
 250   # Find the parent of NAME, using the empty string if it has none.
 251 changequote(,)dnl
 252   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 253 changequote([,])dnl
 254
 255   # Add the names implied by NAME, and NAME's parent (if it has one), to
 256   # the list of names to be processed (the argument list).  We prepend the
 257   # implied names to the list and append the parent.  We want implied
 258   # directories to come before further directories inferred from the
 259   # configuration components; this ensures that for sysv4, unix/common
 260   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 261   # after sysv4).
 262   sysnames="`echo $implied $* $parent`"
 263   test -n "$sysnames" && set $sysnames
 264 done
 265
 266 # Add the default directories.
 267 names="$names generic stub"
 268
 269 # Now uniquize the list.
 270 seen=
 271 sysnames=
 272 for name in $names; do
 273   if echo "$seen" | fgrep -x $name >/dev/null; then
 274     # Already in the list.
 275     true;
 276   else
 277     # A new one.
 278     if test -z "$seen"; then
 279       seen="$name" sysnames="$name"
 280     else
 281       seen="$seen
 282 $name"
 283       sysnames="$sysnames $name"
 284     fi
 285   fi
 286 done
 287 libc_cv_sysdirs="$sysnames"])
 288 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 289
 290 AC_PROG_INSTALL
 291 if test "$INSTALL" = "${srcdir}/install-sh"; then
 292   # The makefiles need to use a different form to find it in $srcdir.
 293   INSTALL='$(..)./install-sh'
 294 fi
 295
 296 AC_CHECK_TOOL(CC, gcc)
 297 AC_CHECK_TOOL(AR, ar)
 298 AC_CHECK_TOOL(RANLIB, ranlib, :)
 299 AC_PROG_CPP
 300
 301 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 302 echo '#include <stddef.h>
 303 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 304 if eval "$ac_cpp conftest.c 2>/dev/null" \
 305 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 306   libc_cv_signed_size_t=no
 307 else
 308   libc_cv_signed_size_t=yes
 309 fi
 310 rm -f conftest*])
 311 if test $libc_cv_signed_size_t = yes; then
 312   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 313   cat >> confdefs.h <<\EOF
 314 #undef __SIZE_TYPE__
 315 #define __SIZE_TYPE__ unsigned
 316 EOF
 317 fi
 318
 319 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 320 AC_TRY_COMPILE(dnl
 321 [#define __need_size_t
 322 #define __need_wchar_t
 323 #include <stddef.h>
 324 #define __need_NULL
 325 #include <stddef.h>], [size_t size; wchar_t wchar;
 326 #ifdef offsetof
 327 #error stddef.h ignored __need_*
 328 #endif
 329 if (&size == NULL || &wchar == NULL) abort ();],
 330                libc_cv_friendly_stddef=yes,
 331                libc_cv_friendly_stddef=no)])
 332 if test $libc_cv_friendly_stddef = yes; then
 333   config_vars="$config_vars
 334 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 335 fi
 336
 337 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 338                libc_cv_need_minus_P, [dnl
 339 cat > conftest.S <<EOF
 340 #include "confdefs.h"
 341 /* Nothing whatsoever.  */
 342 EOF
 343 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 344   libc_cv_need_minus_P=no
 345 else
 346   libc_cv_need_minus_P=yes
 347 fi
 348 rm -f conftest*])
 349 if test $libc_cv_need_minus_P = yes; then
 350   config_vars="$config_vars
 351 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 352 fi
 353
 354 AC_CACHE_CHECK(for assembler global-symbol directive,
 355                libc_cv_asm_global_directive, [dnl
 356 libc_cv_asm_global_directive=UNKNOWN
 357 for ac_globl in .globl .global; do
 358   cat > conftest.s <<EOF
 359 .text
 360 ${ac_globl} foo
 361 foo: .long 0
 362 EOF
 363   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 364     libc_cv_asm_global_directive=${ac_globl}
 365   fi
 366   rm -f conftest*
 367   test $libc_cv_asm_global_directive != UNKNOWN && break
 368 done])
 369 if test $libc_cv_asm_global_directive = UNKNOWN; then
 370   AC_MSG_ERROR(cannot determine asm global directive)
 371 else
 372   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 373 fi
 374
 375 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 376 cat > conftest.s <<EOF
 377 .text
 378 foo: .long 0
 379 .set glibc_conftest_frobozz,foo
 380 $libc_cv_asm_global_directive glibc_conftest_frobozz
 381 EOF
 382 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 383 # (but it doesn't work), so we must do a linking check to be sure.
 384 cat > conftest1.c <<\EOF
 385 extern int glibc_conftest_frobozz;
 386 main () { printf ("%d\n", glibc_conftest_frobozz); }
 387 EOF
 388 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 389             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 390   libc_cv_asm_set_directive=yes
 391 else
 392   libc_cv_asm_set_directive=no
 393 fi
 394 rm -f conftest*])
 395 if test $libc_cv_asm_set_directive = yes; then
 396   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 397 fi
 398
 399 if test $elf != yes; then
 400   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 401                  [AC_TRY_COMPILE(, [asm (".section .init");
 402                                     asm (".section .fini");],
 403                                  libc_cv_have_initfini=yes,
 404                                  libc_cv_have_initfini=no)])
 405   AC_SUBST(libc_cv_have_initfini)dnl
 406   if test $libc_cv_have_initfini = yes; then
 407     AC_DEFINE(HAVE_INITFINI)
 408   fi
 409 fi
 410
 411 # sysdeps configure fragments may set these with files to be linked below.
 412 libc_link_dests=
 413 libc_link_sources=
 414
 415 # Iterate over all the sysdep directories we will use, running their
 416 # configure fragments, and looking for a uname implementation.
 417 uname=
 418 for dir in $sysnames; do
 419   if test -r $sysdep_dir/$dir/configure; then
 420     AC_MSG_RESULT(running configure fragment for $dir)
 421     . $sysdep_dir/$dir/configure
 422   fi
 423   if test -z "$uname"; then
 424     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
 425     && uname=$dir
 426   fi
 427 done
 428
 429 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 430
 431 # If we will use the generic uname implementation, we must figure out what
 432 # it will say by examining the system, and write the results in config-name.h.
 433 if test "$uname" = generic; then
 434
 435 changequote(,)dnl
 436   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 437 changequote([,])dnl
 438   if test $uname_sysname != $config_os; then
 439     config_release=`echo $config_os | sed s/$uname_sysname//`
 440   fi
 441 dnl
 442 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 443     if test -r /vmunix; then
 444       kernel_id=`strings /vmunix | grep UNIX`
 445     elif test -r /dynix; then
 446       kernel_id=`strings /dynix | grep DYNIX`
 447     else
 448       kernel_id=
 449     fi
 450 ])dnl
 451
 452   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 453 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 454 changequote(,)dnl
 455   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 456 changequote([,])dnl
 457   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 458          != x$config_release; then
 459     # The configuration release is a substring of the kernel release.
 460     libc_cv_uname_release=$kernel_release
 461   elif test x$config_release != x; then
 462     libc_cv_uname_release=$config_release
 463   elif test x$kernel_release != x; then
 464     libc_cv_uname_release=$kernel_release
 465   else
 466     libc_cv_uname_release=unknown
 467   fi])
 468   uname_release="$libc_cv_uname_release"
 469
 470   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 471 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 472 changequote(,)dnl
 473   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 474 changequote([,])dnl
 475   if test -n "$kernel_version"; then
 476     libc_cv_uname_version="$kernel_version"
 477   else
 478     libc_cv_uname_version=unknown
 479   fi])
 480   uname_version="$libc_cv_uname_version"
 481
 482 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 483   config_uname=config-name.h:config-name.in
 484 else
 485   # For non-generic uname, we don't need to create config-name.h at all.
 486   config_uname=
 487 fi
 488
 489 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
 490 if test $gnu_ld = yes; then
 491   AC_DEFINE(HAVE_GNU_LD)
 492 fi
 493 if test $gnu_as = yes; then
 494   AC_DEFINE(HAVE_GNU_AS)
 495 fi
 496 if test $elf = yes; then
 497   AC_DEFINE(HAVE_ELF)
 498 fi
 499 if test $weak = yes; then
 500   AC_DEFINE(HAVE_WEAK_SYMBOLS)
 501 fi
 502
 503 AC_SUBST(shared)
 504 if test $shared = default; then
 505   if test $gnu_ld = yes; then
 506     shared=$elf
 507   fi
 508 fi
 509 AC_SUBST(profile)
 510 AC_SUBST(omitfp)
 511
 512 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 513   config_makefile=
 514 else
 515   config_makefile=Makefile
 516 fi
 517
 518 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 519           [echo '$config_vars' >> config.make])