sysdeps/unix/bsd/ultrix4/mips/start.S

   1 /* Copyright (C) 1993, 1995 Free Software Foundation, Inc.
   2    Contributed by Brendan Kehoe (brendan@zen.org).
   3
   4 The GNU C Library is free software; you can redistribute it and/or
   5 modify it under the terms of the GNU Library General Public License as
   6 published by the Free Software Foundation; either version 2 of the
   7 License, or (at your option) any later version.
   8
   9 The GNU C Library is distributed in the hope that it will be useful,
  10 but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 Library General Public License for more details.
  13
  14 You should have received a copy of the GNU Library General Public
  15 License along with the GNU C Library; see the file COPYING.LIB.  If
  16 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  17 Cambridge, MA 02139, USA.  */
  18
  19 #include <sysdep.h>
  20
  21 #ifndef HAVE_WEAK_SYMBOLS
  22 #define __environ environ
  23 #else
  24 weak_alias (__environ, environ)
  25 #endif
  26
  27 .comm __environ,        4
  28 .comm errno,            4
  29
  30 ENTRY(__start)
  31   .set noreorder
  32
  33   /* The first thing on the stack is argc.  */
  34   lw s0, 0(sp)
  35   nop
  36
  37   /* Set up the global pointer.  */
  38   la gp, _gp
  39
  40   /* Then set up argv.  */
  41   addiu s1, sp, 4
  42
  43   /* To compute where envp is, first we have to jump ahead four
  44      bytes from what argv was.  This will bring us ahead, so we don't
  45      need to compute the NULL at the end of argv later.  */
  46   addiu v1, s1, 4
  47
  48   /* Now, compute the space to skip given the number of arguments
  49      we've got.  We do this by multiplying argc by 4.  */
  50   sll v0, s0, 2
  51
  52   /* Now, add (argv+4) with the space to skip...that's envp.  */
  53   addu s2, v1, v0
  54
  55   /* __environ = envp; */
  56   sw s2, __environ
  57
  58   addiu sp, sp, -24
  59
  60   /* __libc_init (argc, argv, envp); */
  61   move a0, s0
  62   move a1, s1
  63   jal __libc_init
  64   move a2, s2
  65
  66   /* errno = 0; */
  67   sw zero, errno
  68
  69   /* exit (main (argc, argv, envp)); */
  70   move a0, s0
  71   move a1, s1
  72   jal main
  73   move a2, s2
  74
  75   /* Make the value returned by main be the argument to exit.  */
  76   jal exit
  77   move a0, v0