sysdeps/m68k/m68020/add_n.S

   1 /* mc68020 __mpn_add_n -- Add two limb vectors of the same length > 0 and store
   2    sum in a third limb vector.
   3
   4 Copyright (C) 1992, 1994 Free Software Foundation, Inc.
   5
   6 This file is part of the GNU MP Library.
   7
   8 The GNU MP Library is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU Library General Public License as published by
  10 the Free Software Foundation; either version 2 of the License, or (at your
  11 option) any later version.
  12
  13 The GNU MP Library is distributed in the hope that it will be useful, but
  14 WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  16 License for more details.
  17
  18 You should have received a copy of the GNU Library General Public License
  19 along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA. */
  21
  22 /*
  23   INPUT PARAMETERS
  24   res_ptr       (sp + 4)
  25   s1_ptr        (sp + 8)
  26   s2_ptr        (sp + 16)
  27   size          (sp + 12)
  28 */
  29
  30 #include "asm-syntax.h"
  31
  32         TEXT
  33         ALIGN
  34         GLOBL   ___mpn_add_n
  35
  36 LAB(___mpn_add_n)
  37 /* Save used registers on the stack.  */
  38         INSN2(move,l    ,MEM_PREDEC(sp),d2)
  39         INSN2(move,l    ,MEM_PREDEC(sp),a2)
  40
  41 /* Copy the arguments to registers.  Better use movem?  */
  42         INSN2(move,l    ,a2,MEM_DISP(sp,12))
  43         INSN2(move,l    ,a0,MEM_DISP(sp,16))
  44         INSN2(move,l    ,a1,MEM_DISP(sp,20))
  45         INSN2(move,l    ,d2,MEM_DISP(sp,24))
  46
  47         INSN2(eor,w     ,d2,#1)
  48         INSN2(lsr,l     ,d2,#1)
  49         bcc L1
  50         INSN2(subq,l    ,d2,#1)         /* clears cy as side effect */
  51
  52 LAB(Loop)
  53         INSN2(move,l    ,d0,MEM_POSTINC(a0))
  54         INSN2(move,l    ,d1,MEM_POSTINC(a1))
  55         INSN2(addx,l    ,d0,d1)
  56         INSN2(move,l    ,MEM_POSTINC(a2),d0)
  57 LAB(L1) INSN2(move,l    ,d0,MEM_POSTINC(a0))
  58         INSN2(move,l    ,d1,MEM_POSTINC(a1))
  59         INSN2(addx,l    ,d0,d1)
  60         INSN2(move,l    ,MEM_POSTINC(a2),d0)
  61
  62         dbf d2,Loop                     /* loop until 16 lsb of %4 == -1 */
  63         INSN2(subx,l    ,d0,d0)         /* d0 <= -cy; save cy as 0 or -1 in d0 */
  64         INSN2(sub,l     ,d2,#0x10000)
  65         bcs L2
  66         INSN2(add,l     ,d0,d0)         /* restore cy */
  67         bra Loop
  68
  69 LAB(L2)
  70         INSN1(neg,l     ,d0)
  71
  72 /* Restore used registers from stack frame.  */
  73         INSN2(move,l    ,a2,MEM_POSTINC(sp))
  74         INSN2(move,l    ,d2,MEM_POSTINC(sp))
  75
  76         rts