sysdeps/powerpc/powerpc32/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24
  25         .section        .rodata.cst4,"aM",@progbits,4
  26         .align  2
  27 .LC0:   /* 2**52 */
  28         .long 0x59800000
  29
  30         .section        ".text"
  31 ENTRY (__rint)
  32 #ifdef SHARED
  33         mflr    r11
  34 # ifdef HAVE_ASM_PPC_REL16
  35         bcl     20,31,1f
  36 1:      mflr    r9
  37         addis   r9,r9,.LC0-1b@ha
  38         mtlr    r11
  39         lfs     fp13,.LC0-1b@l(r9)
  40 # else
  41         bl      _GLOBAL_OFFSET_TABLE_@local-4
  42         mflr    r10
  43         lwz     r9,.LC0@got(10)
  44         mtlr    r11
  45         lfs     fp13,0(r9)
  46 # endif
  47 #else
  48         lis     r9,.LC0@ha
  49         lfs     fp13,.LC0@l(r9)
  50 #endif
  51         fabs    fp0,fp1
  52         fsub    fp12,fp13,fp13  /* generate 0.0  */
  53         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  54         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  55         bnllr-  cr7
  56         bng-    cr6,.L4
  57         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  58         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  59         fabs    fp1,fp1         /* if (x == 0.0)  */
  60         blr                     /* x = 0.0; */
  61 .L4:
  62         bnllr-  cr6             /* if (x < 0.0)  */
  63         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  64         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  65         fnabs   fp1,fp1         /* if (x == 0.0)  */
  66         blr                     /* x = -0.0; */
  67         END (__rint)
  68
  69 weak_alias (__rint, rint)
  70
  71 #ifdef NO_LONG_DOUBLE
  72 weak_alias (__rint, rintl)
  73 strong_alias (__rint, __rintl)
  74 #endif