| blob | ee5e856306223c4cf43a6abbfa0bfa24727079db |
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.53)dnl dnl Minimum Autoconf version required.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 dnl This is here so we can set $subdirs directly based on configure fragments.
9 AC_CONFIG_SUBDIRS()
11 AC_CANONICAL_HOST
13 AC_PROG_CC
14 if test $host != $build; then
15 AC_CHECK_PROGS(BUILD_CC, gcc cc)
16 fi
17 AC_SUBST(cross_compiling)
18 AC_PROG_CPP
19 # We need the C++ compiler only for testing.
20 AC_PROG_CXX
22 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
23 AC_MSG_ERROR([you must configure in a separate build directory])
24 fi
26 # This will get text that should go into config.make.
27 config_vars=
29 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
30 AC_ARG_WITH([gd],
31 AC_HELP_STRING([--with-gd=DIR],
32 [find libgd include dir and library with prefix DIR]),
33 [dnl
34 case "$with_gd" in
35 yes|''|no) ;;
36 *) libgd_include="-I$withval/include"
37 libgd_ldflags="-L$withval/lib" ;;
38 esac
39 ])
40 AC_ARG_WITH([gd-include],
41 AC_HELP_STRING([--with-gd-include=DIR],
42 [find libgd include files in DIR]),
43 [dnl
44 case "$with_gd_include" in
45 ''|no) ;;
46 *) libgd_include="-I$withval" ;;
47 esac
48 ])
49 AC_ARG_WITH([gd-lib],
50 AC_HELP_STRING([--with-gd-lib=DIR],
51 [find libgd library files in DIR]),
52 [dnl
53 case "$with_gd_lib" in
54 ''|no) ;;
55 *) libgd_ldflags="-L$withval" ;;
56 esac
57 ])
59 if test -n "$libgd_include"; then
60 config_vars="$config_vars
61 CFLAGS-memusagestat.c = $libgd_include"
62 fi
63 if test -n "$libgd_ldflags"; then
64 config_vars="$config_vars
65 libgd-LDFLAGS = $libgd_ldflags"
66 fi
68 dnl Arguments to specify presence of other packages/features.
69 AC_ARG_WITH([fp],
70 AC_HELP_STRING([--with-fp],
71 [if using floating-point hardware @<:@default=yes@:>@]),
72 [with_fp=$withval],
73 [with_fp=yes])
74 AC_SUBST(with_fp)
75 AC_ARG_WITH([binutils],
76 AC_HELP_STRING([--with-binutils=PATH],
77 [specify location of binutils (as and ld)]),
78 [path_binutils=$withval],
79 [path_binutils=''])
80 AC_ARG_WITH([selinux],
81 AC_HELP_STRING([--with-selinux],
82 [if building with SELinux support]),
83 [with_selinux=$withval],
84 [with_selinux=auto])
86 AC_ARG_WITH([headers],
87 AC_HELP_STRING([--with-headers=PATH],
88 [location of system headers to use
89 (for example /usr/src/linux/include)
90 @<:@default=compiler default@:>@]),
91 [sysheaders=$withval],
92 [sysheaders=''])
94 AC_SUBST(use_default_link)
95 AC_ARG_WITH([default-link],
96 AC_HELP_STRING([--with-default-link],
97 [do not use explicit linker scripts]),
98 [use_default_link=$withval],
99 [use_default_link=default])
101 AC_ARG_ENABLE([sanity-checks],
102 AC_HELP_STRING([--disable-sanity-checks],
103 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
104 [enable_sanity=$enableval],
105 [enable_sanity=yes])
107 AC_SUBST(enable_check_abi)
108 AC_ARG_ENABLE([check-abi],
109 AC_HELP_STRING([--enable-check-abi],
110 [do "make check-abi" in "make check" (no/warn/yes)
111 @<:@default=no@:>@]),
112 [enable_check_abi=$enableval],
113 [enable_check_abi=no])
115 AC_ARG_ENABLE([shared],
116 AC_HELP_STRING([--enable-shared],
117 [build shared library @<:@default=yes if GNU ld@:>@]),
118 [shared=$enableval],
119 [shared=yes])
120 AC_ARG_ENABLE([profile],
121 AC_HELP_STRING([--enable-profile],
122 [build profiled library @<:@default=no@:>@]),
123 [profile=$enableval],
124 [profile=no])
125 AC_ARG_ENABLE([versioning],
126 AC_HELP_STRING([--disable-versioning],
127 [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
128 [enable_versioning=$enableval],
129 [enable_versioning=yes])
131 AC_ARG_ENABLE([oldest-abi],
132 AC_HELP_STRING([--enable-oldest-abi=ABI],
133 [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
134 [oldest_abi=$enableval],
135 [oldest_abi=no])
136 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
137 oldest_abi=default
138 else
139 AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
140 fi
141 AC_SUBST(oldest_abi)
143 AC_ARG_ENABLE([stackguard-randomization],
144 AC_HELP_STRING([--enable-stackguard-randomization],
145 [initialize __stack_chk_guard canary with a random number at program start]),
146 [enable_stackguard_randomize=$enableval],
147 [enable_stackguard_randomize=no])
148 if test "$enable_stackguard_randomize" = yes; then
149 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
150 fi
152 dnl Generic infrastructure for drop-in additions to libc.
153 AC_ARG_ENABLE([add-ons],
154 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
155 [configure and build add-ons in DIR1,DIR2,...
156 search for add-ons if no parameter given]),
157 , [enable_add_ons=yes])
159 AC_ARG_ENABLE([hidden-plt],
160 AC_HELP_STRING([--disable-hidden-plt],
161 [do not hide internal function calls to avoid PLT]),
162 [hidden=$enableval],
163 [hidden=yes])
164 if test "x$hidden" = xno; then
165 AC_DEFINE(NO_HIDDEN)
166 fi
168 AC_ARG_ENABLE([bind-now],
169 AC_HELP_STRING([--enable-bind-now],
170 [disable lazy relocations in DSOs]),
171 [bindnow=$enableval],
172 [bindnow=no])
173 AC_SUBST(bindnow)
175 dnl On some platforms we cannot use dynamic loading. We must provide
176 dnl static NSS modules.
177 AC_ARG_ENABLE([static-nss],
178 AC_HELP_STRING([--enable-static-nss],
179 [build static NSS modules @<:@default=no@:>@]),
180 [static_nss=$enableval],
181 [static_nss=no])
182 dnl Enable static NSS also if we build no shared objects.
183 if test x"$static_nss" = xyes || test x"$shared" = xno; then
184 static_nss=yes
185 AC_DEFINE(DO_STATIC_NSS)
186 fi
188 AC_ARG_ENABLE([force-install],
189 AC_HELP_STRING([--disable-force-install],
190 [don't force installation of files from this package, even if they are older than the installed files]),
191 [force_install=$enableval],
192 [force_install=yes])
193 AC_SUBST(force_install)
195 dnl On some platforms we allow dropping compatibility with all kernel
196 dnl versions.
197 AC_ARG_ENABLE([kernel],
198 AC_HELP_STRING([--enable-kernel=VERSION],
199 [compile for compatibility with kernel not older than VERSION]),
200 [minimum_kernel=$enableval],
201 [])
202 dnl Prevent unreasonable values.
203 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
204 # Better nothing than this.
205 minimum_kernel=""
206 else
207 if test "$minimum_kernel" = current; then
208 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
209 fi
210 fi
212 dnl For the development we sometimes want gcc to issue even more warnings.
213 dnl This is not the default since many of the extra warnings are not
214 dnl appropriate.
215 AC_ARG_ENABLE([all-warnings],
216 AC_HELP_STRING([--enable-all-warnings],
217 [enable all useful warnings gcc can issue]),
218 [all_warnings=$enableval],
219 [])
220 AC_SUBST(all_warnings)
222 AC_ARG_ENABLE([multi-arch],
223 AC_HELP_STRING([--enable-multi-arch],
224 [enable single DSO with optimizations for multiple architectures]),
225 [multi_arch=$enableval],
226 [multi_arch=default])
228 AC_ARG_ENABLE([nss-crypt],
229 AC_HELP_STRING([--enable-nss-crypt],
230 [enable libcrypt to use nss]),
231 [nss_crypt=$enableval],
232 [nss_crypt=no])
233 if test x$nss_crypt = xyes; then
234 nss_includes=-I$(nss-config --includedir 2>/dev/null)
235 if test $? -ne 0; then
236 AC_MSG_ERROR([cannot find include directory with nss-config])
237 fi
238 old_CFLAGS="$CFLAGS"
239 CFLAGS="$CFLAGS $nss_includes"
240 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
241 #include <hasht.h>
242 #include <nsslowhash.h>
243 void f (void) { NSSLOW_Init (); }])],
244 libc_cv_nss_crypt=yes,
245 AC_MSG_ERROR([
246 cannot find NSS headers with lowlevel hash function interfaces]))
247 old_LIBS="$LIBS"
248 LIBS="$LIBS -lfreebl3"
249 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
250 #include <hasht.h>
251 #include <nsslowhash.h>],
252 [NSSLOW_Init();])],
253 libc_cv_nss_crypt=yes,
254 AC_MSG_ERROR([
255 cannot link program using lowlevel NSS hash functions]))
256 CFLAGS="$old_CFLAGS"
257 LIBS="$old_LIBS"
258 else
259 libc_cv_nss_crypt=no
260 fi
261 AC_SUBST(libc_cv_nss_crypt)
263 # The way shlib-versions is used to generate soversions.mk uses a
264 # fairly simplistic model for name recognition that can't distinguish
265 # i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a $host_os
266 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
267 # tell. This doesn't get used much beyond that, so it's fairly safe.
268 case "$host_os" in
269 linux*)
270 ;;
271 gnu*)
272 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
273 ;;
274 esac
276 # We keep the original values in `$config_*' and never modify them, so we
277 # can write them unchanged into config.make. Everything else uses
278 # $machine, $vendor, and $os, and changes them whenever convenient.
279 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
281 # Don't allow vendor == "unknown"
282 test "$config_vendor" = unknown && config_vendor=
283 config_os="`echo $config_os | sed 's/^unknown-//'`"
285 # Some configurations imply other options.
286 elf=yes
288 # The configure fragment of an add-on port can modify these to supplement
289 # or override the table in the case statement below. No fragment should
290 # ever change the config_* variables, however.
291 machine=$config_machine
292 vendor=$config_vendor
293 os=$config_os
294 base_os=''
296 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
297 # Unify this here.
298 if test "$machine" = rs6000; then
299 machine="powerpc"
300 fi
302 # Braindead PowerPC box with absolutely no FPU.
303 case "$machine-$host_os" in
304 powerpc*-*soft)
305 with_fp=no
306 ;;
307 esac
309 submachine=
310 AC_ARG_WITH([cpu],
311 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
312 [dnl
313 case "$withval" in
314 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
315 no) ;;
316 *) submachine="$withval" ;;
317 esac
318 ])
320 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
321 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
323 # An add-on can set this when it wants to disable the sanity check below.
324 libc_config_ok=no
326 dnl Having this here, though empty, makes sure that if add-ons' fragments
327 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
328 dnl our AC_OUTPUT will actually use it.
329 AC_CONFIG_SUBDIRS()
331 case "$enable_add_ons" in
332 ''|no) add_ons= ;;
333 yes|'*')
334 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
335 sed 's@/[[^/]]*$@@' | sort | uniq`
336 add_ons_automatic=yes
337 ;;
338 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
339 add_ons_automatic=no ;;
340 esac
342 configured_add_ons=
343 add_ons_sfx=
344 add_ons_pfx=
345 if test x"$add_ons" != x; then
346 for f in $add_ons; do
347 # Some sanity checks
348 case "$f" in
349 crypt)
350 AC_MSG_ERROR([
351 *** It seems that you're using an old \`crypt' add-on. crypt is now
352 *** part of glibc and using the old add-on will not work with this
353 *** release. Start again with fresh sources and without the old
354 *** \`crypt' add-on.])
355 ;;
356 localedata)
357 AC_MSG_ERROR([
358 *** It seems that you're using an old \`localedata' add-on. localedata
359 *** is now part of glibc and using the old add-on will not work with
360 *** this release. Start again with fresh sources and without the old
361 *** \`localedata' add-on.])
362 ;;
363 esac
364 done
366 # Now source each add-on's configure fragment.
367 # The fragments can use $srcdir/$libc_add_on to find themselves,
368 # and test $add_ons_automatic to see if they were explicitly requested.
369 # A fragment can clear (or even change) $libc_add_on to affect
370 # whether it goes into the list to be actually used in the build.
371 use_add_ons=
372 for libc_add_on in $add_ons; do
373 # Test whether such a directory really exists.
374 # It can be absolute, or relative to $srcdir, or relative to the build dir.
375 case "$libc_add_on" in
376 /*)
377 libc_add_on_srcdir=$libc_add_on
378 ;;
379 *)
380 test -d "$srcdir/$libc_add_on" || {
381 if test -d "$libc_add_on"; then
382 libc_add_on="`pwd`/$libc_add_on"
383 else
384 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
385 fi
386 }
387 libc_add_on_srcdir=$srcdir/$libc_add_on
388 ;;
389 esac
391 libc_add_on_frag=$libc_add_on_srcdir/configure
392 libc_add_on_canonical=
393 libc_add_on_config_subdirs=
394 if test -r "$libc_add_on_frag"; then
395 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
396 libc_add_on_canonical=unknown
397 libc_add_on_subdirs=
398 . "$libc_add_on_frag"
399 test -z "$libc_add_on" || {
400 configured_add_ons="$configured_add_ons $libc_add_on"
401 if test "x$libc_add_on_canonical" = xunknown; then
402 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
403 fi
404 for d in $libc_add_on_subdirs; do
405 case "$libc_add_on" in
406 /*) subdir_srcdir="$libc_add_on" ;;
407 *) subdir_srcdir="\$(..)$libc_add_on" ;;
408 esac
409 case "$d" in
410 .)
411 d="${libc_add_on_canonical:-$libc_add_on}"
412 ;;
413 /*)
414 subdir_srcdir="$d"
415 ;;
416 *)
417 subdir_srcdir="$subdir_srcdir/$d"
418 ;;
419 esac
420 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
421 add_on_subdirs="$add_on_subdirs $d"
422 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
423 $d-srcdir = $subdir_srcdir"
424 done
425 for d in $libc_add_on_config_subdirs; do
426 case "$d" in
427 /*) AC_MSG_ERROR(dnl
428 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
429 esac
430 if test ! -d "$libc_add_on_srcdir/$d"; then
431 AC_MSG_ERROR(fragment wants to configure missing directory $d)
432 fi
433 case "$libc_add_on" in
434 /*) AC_MSG_ERROR(dnl
435 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
436 esac
437 subdirs="$subdirs $libc_add_on/$d"
438 done
439 }
440 fi
441 if test -n "$libc_add_on"; then
442 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
443 use_add_ons="$use_add_ons $libc_add_on"
444 add_ons_pfx="$add_ons_pfx $libc_add_on/"
445 test -z "$libc_add_on_canonical" ||
446 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
447 fi
448 done
449 # Use echo to strip excess whitespace.
450 add_ons="`echo $use_add_ons`"
451 fi
452 AC_SUBST(add_ons)
453 AC_SUBST(add_on_subdirs)
456 ###
457 ### I put this here to prevent those annoying emails from people who cannot
458 ### read and try to compile glibc on unsupported platforms. --drepper
459 ###
460 ### By using the undocumented --enable-hacker-mode option for configure
461 ### one can skip this test to make the configuration not fail for unsupported
462 ### platforms.
463 ###
464 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
465 case "$machine-$host_os" in
466 *-linux* | *-gnu* | arm*-none*)
467 ;;
468 *)
469 echo "*** The GNU C library is currently not available for this platform."
470 echo "*** So far nobody cared to port it and if there is no volunteer it"
471 echo "*** might never happen. So, if you have interest to see glibc on"
472 echo "*** this platform visit"
473 echo "*** http://www.gnu.org/software/libc/porting.html"
474 echo "*** and join the group of porters"
475 exit 1
476 ;;
477 esac
478 fi
480 dnl We need to use [ and ] for other purposes for a while now.
481 changequote(,)dnl
482 # Expand the configuration machine name into a subdirectory by architecture
483 # type and particular chip. If an add-on configure fragment already set
484 # base_machine, we don't change it.
485 test -n "$base_machine" || case "$machine" in
486 i[34567]86) base_machine=i386 machine=i386/$machine ;;
487 powerpc) base_machine=powerpc machine=powerpc/powerpc32 ;;
488 powerpc64) base_machine=powerpc machine=powerpc/powerpc64 ;;
489 s390) base_machine=s390 machine=s390/s390-32 ;;
490 s390x) base_machine=s390 machine=s390/s390-64 ;;
491 sh3*) base_machine=sh machine=sh/sh3 ;;
492 sh4*) base_machine=sh machine=sh/sh4 ;;
493 sparc | sparcv[67])
494 base_machine=sparc machine=sparc/sparc32 ;;
495 sparcv8 | supersparc | hypersparc)
496 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
497 sparcv8plus | sparcv8plusa | sparcv9)
498 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
499 sparcv8plusb | sparcv9b)
500 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
501 sparcv9v)
502 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
503 sparcv9v2)
504 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
505 sparc64)
506 base_machine=sparc machine=sparc/sparc64 ;;
507 sparc64b)
508 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
509 sparc64v)
510 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
511 sparc64v2)
512 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
513 *) base_machine=$machine ;;
514 esac
515 changequote([,])dnl
516 AC_SUBST(base_machine)
518 if test "$base_machine" = "i386"; then
519 AC_DEFINE(USE_REGPARMS)
520 fi
522 # For the multi-arch option we need support in the assembler.
523 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
524 libc_cv_asm_gnu_indirect_function, [dnl
525 cat > conftest.s <<EOF
526 .type foo,%gnu_indirect_function
527 EOF
528 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
529 then
530 libc_cv_asm_gnu_indirect_function=yes
531 else
532 libc_cv_asm_gnu_indirect_function=no
533 fi
534 rm -f conftest*])
536 AC_MSG_CHECKING(whether .text pseudo-op must be used)
537 AC_CACHE_VAL(libc_cv_dot_text, [dnl
538 cat > conftest.s <<EOF
539 .text
540 EOF
541 libc_cv_dot_text=
542 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
543 libc_cv_dot_text=.text
544 fi
545 rm -f conftest*])
546 if test -z "$libc_cv_dot_text"; then
547 AC_MSG_RESULT(no)
548 else
549 AC_MSG_RESULT(yes)
550 fi
552 AC_CACHE_CHECK(for assembler global-symbol directive,
553 libc_cv_asm_global_directive, [dnl
554 libc_cv_asm_global_directive=UNKNOWN
555 for ac_globl in .globl .global .EXPORT; do
556 cat > conftest.s <<EOF
557 ${libc_cv_dot_text}
558 ${ac_globl} foo
559 foo:
560 EOF
561 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
562 libc_cv_asm_global_directive=${ac_globl}
563 fi
564 rm -f conftest*
565 test $libc_cv_asm_global_directive != UNKNOWN && break
566 done])
567 if test $libc_cv_asm_global_directive = UNKNOWN; then
568 AC_MSG_ERROR(cannot determine asm global directive)
569 else
570 AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
571 fi
573 AC_CACHE_CHECK(for assembler .type directive prefix,
574 libc_cv_asm_type_prefix, [dnl
575 libc_cv_asm_type_prefix=no
576 for ac_try_prefix in '@' '%' '#'; do
577 cat > conftest.s <<EOF
578 ${libc_cv_dot_text}
579 ${libc_cv_asm_global_directive} foo
580 .type foo, ${ac_try_prefix}object
581 .size foo, 1
582 foo:
583 .byte 1
584 EOF
585 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
586 libc_cv_asm_type_prefix=${ac_try_prefix}
587 fi
588 rm -f conftest*
589 test "x$libc_cv_asm_type_prefix" != xno && break
590 done])
591 if test "x$libc_cv_asm_type_prefix" != xno; then
592 AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
593 fi
595 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -o x"$libc_cv_asm_type_prefix" = xno; then
596 if test x"$multi_arch" = xyes; then
597 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
598 else
599 multi_arch=no
600 fi
601 fi
602 if test x"$multi_arch" != xno; then
603 multi_arch_d=/multiarch
604 fi
606 # Compute the list of sysdep directories for this configuration.
607 # This can take a while to compute.
608 sysdep_dir=$srcdir/sysdeps
609 AC_MSG_CHECKING(sysdep dirs)
610 dnl We need to use [ and ] for other purposes for a while now.
611 changequote(,)dnl
612 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
613 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
615 test "x$base_os" != x || case "$os" in
616 gnu*)
617 base_os=mach/hurd ;;
618 netbsd* | 386bsd* | freebsd* | bsdi*)
619 base_os=unix/bsd/bsd4.4 ;;
620 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
621 base_os=unix/bsd ;;
622 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
623 base_os=unix/sysv ;;
624 irix6*)
625 base_os=unix/sysv/irix6/$os ;;
626 solaris[2-9]*)
627 base_os=unix/sysv/sysv4 ;;
628 none)
629 base_os=standalone ;;
630 esac
632 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
633 tail=$os
634 ostry=$os
635 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
636 ostry="$ostry /$o"
637 tail=$o
638 done
639 o=`echo $tail | sed 's/[0-9]*$//'`
640 if test $o != $tail; then
641 ostry="$ostry /$o"
642 fi
643 # For linux-gnu, try linux-gnu, then linux.
644 o=`echo $tail | sed 's/-.*$//'`
645 if test $o != $tail; then
646 ostry="$ostry /$o"
647 fi
649 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
650 base=
651 tail=$base_os
652 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
653 set $b
654 base="$base /$1"
655 tail="$2"
656 done
658 # For sparc/sparc32, try sparc/sparc32 and then sparc.
659 mach=
660 tail=$machine${submachine:+/$submachine}
661 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
662 set $m
663 # Prepend the machine's FPU directory unless --without-fp.
664 if test "$with_fp" = yes; then
665 mach="$mach /$1/fpu"
666 else
667 mach="$mach /$1/nofpu"
668 fi
669 mach="$mach /$1"
670 tail="$2"
671 done
673 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
674 changequote([,])dnl
676 # Find what sysdep directories exist.
677 sysnames_add_ons=
678 sysnames=
679 for b in $base ''; do
680 for m0 in $mach ''; do
681 for v in /$vendor ''; do
682 test "$v" = / && continue
683 for o in /$ostry ''; do
684 test "$o" = / && continue
685 for m in $multi_arch_d $mach ''; do
686 for d in $add_ons_pfx ''; do
687 for a in $add_ons_sfx ''; do
688 if test -n "$m0$m0sub$b$v$o$m$msub"; then
689 try_srcdir="${srcdir}/"
690 case "$d" in
691 /*) try_srcdir= ;;
692 esac
693 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
694 test -n "$enable_debug_configure" &&
695 echo "$0 [DEBUG]: try $try" >&2
696 if test -d "$try_srcdir$try"; then
697 sysnames="$sysnames $try"
698 { test -n "$o" || test -n "$b"; } && os_used=t
699 { test -n "$m" || test -n "$m0"; } && machine_used=t
700 case x${m0:-$m} in
701 x*/$submachine) submachine_used=t ;;
702 esac
703 if test -n "$d"; then
704 case "$sysnames_add_ons" in
705 *" $d "*) ;;
706 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
707 esac
708 fi
709 fi
710 fi
711 done
712 done
713 done
714 done
715 done
716 done
717 done
719 # If the assembler supports gnu_indirect_function symbol type and the
720 # architecture supports multi-arch, we enable multi-arch by default.
721 case $sysnames_add_ons$sysnames in
722 *"$multi_arch_d"*)
723 ;;
724 *)
725 test x"$multi_arch" = xdefault && multi_arch=no
726 ;;
727 esac
728 if test x"$multi_arch" != xno; then
729 AC_DEFINE(USE_MULTIARCH)
730 fi
731 AC_SUBST(multi_arch)
733 if test -z "$os_used" && test "$os" != none; then
734 AC_MSG_ERROR(Operating system $os is not supported.)
735 fi
736 if test -z "$machine_used" && test "$machine" != none; then
737 AC_MSG_ERROR(The $machine is not supported.)
738 fi
739 if test -z "$submachine_used" && test -n "$submachine"; then
740 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
741 fi
742 AC_SUBST(submachine)
744 # We have now validated the configuration.
747 # Look for an `elf' subdirectory of each machine directory.
748 # We prepend these rather than inserting them whereever the machine appears
749 # because things specified by the machine's ELF ABI should override
750 # OS-specific things, and should always be the same for any OS on the
751 # machine (otherwise what's the point of an ABI?).
752 elf_dirs=
753 for d in $add_ons_pfx ''; do
754 for m in $mach; do
755 if test -d $srcdir/${d}sysdeps$m/elf; then
756 elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
757 fi
758 done
759 done
760 sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
763 # Expand the list of system names into a full list of directories
764 # from each element's parent name and Implies file (if present).
765 set $sysnames
766 names=
767 while test $# -gt 0; do
768 name=$1
769 shift
771 case " $names " in *" $name "*)
772 # Already in the list.
773 continue
774 esac
776 # Report each name as we discover it, so there is no long pause in output.
777 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
779 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
781 case $name in
782 /*) xsrcdir= ;;
783 *) xsrcdir=$srcdir/ ;;
784 esac
785 test -n "$enable_debug_configure" &&
786 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
788 if test -f $xsrcdir$name/Implies; then
789 # Collect more names from the `Implies' file (removing comments).
790 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
791 implied=
792 for x in $implied_candidate; do
793 found=no
794 if test -d $xsrcdir$name_base/$x; then
795 implied="$implied $name_base/$x";
796 found=yes
797 fi
798 for d in $add_ons_pfx ''; do
799 try="${d}sysdeps/$x"
800 case $d in
801 /*) try_srcdir= ;;
802 *) try_srcdir=$srcdir/ ;;
803 esac
804 test -n "$enable_debug_configure" &&
805 echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
806 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
807 then
808 implied="$implied $try"
809 found=yes
810 case "$sysnames_add_ons" in
811 *" $d "*) ;;
812 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
813 esac
814 fi
815 done
816 if test $found = no; then
817 AC_MSG_WARN($name/Implies specifies nonexistent $x)
818 fi
819 done
820 else
821 implied=
822 fi
824 # Add NAME to the list of names.
825 names="$names $name"
827 # Find the parent of NAME, using the empty string if it has none.
828 changequote(,)dnl
829 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
830 changequote([,])dnl
832 # Add the names implied by NAME, and NAME's parent (if it has one), to
833 # the list of names to be processed (the argument list). We prepend the
834 # implied names to the list and append the parent. We want implied
835 # directories to come before further directories inferred from the
836 # configuration components; this ensures that for sysv4, unix/common
837 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
838 # after sysv4).
839 sysnames="`echo $implied $* $parent`"
840 test -n "$sysnames" && set $sysnames
841 done
843 # Add the default directories.
844 default_sysnames="sysdeps/generic/elf sysdeps/generic"
845 sysnames="$names $default_sysnames"
846 AC_SUBST(sysnames)
847 # The other names were emitted during the scan.
848 AC_MSG_RESULT($default_sysnames)
850 # Collect the list of add-ons that supply partial sysdeps trees.
851 sysdeps_add_ons=
852 for add_on in $add_ons; do
853 case "$add_on" in
854 /*) xsrcdir= ;;
855 *) xsrcdir="$srcdir/" ;;
856 esac
858 test -d "$xsrcdir$add_on/sysdeps" || {
859 case "$configured_add_ons " in
860 *" $add_on "*) ;;
861 *|'')
862 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
863 ;;
864 esac
865 continue
866 }
868 sysdeps_add_ons="$sysdeps_add_ons $add_on"
869 case "$sysnames_add_ons" in
870 *" $add_on/ "*) ;;
871 *|'')
872 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
873 continue ;;
874 esac
876 found=no
877 for d in $sysnames; do
878 case "$d" in
879 $add_on/sysdeps/*) ;;
880 *) continue ;;
881 esac
882 (cd "$xsrcdir$d" && for f in *[[!~]]; do
883 case "$f" in
884 sys|bits)
885 for ff in $f/*.h; do
886 test -d "$ff" || { test -e "$ff" && exit 88; }
887 done
888 ;;
889 *)
890 test -d "$f" || { test -e "$f" && exit 88; }
891 ;;
892 esac
893 done)
894 if test $? -eq 88; then
895 found=yes
896 break
897 fi
898 done
899 if test $found = no; then
900 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
901 fi
902 done
903 AC_SUBST(sysdeps_add_ons)
906 ### Locate tools.
908 AC_PROG_INSTALL
909 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
910 # The makefiles need to use a different form to find it in $srcdir.
911 INSTALL='\$(..)./scripts/install-sh -c'
912 fi
913 AC_PROG_LN_S
915 LIBC_PROG_BINUTILS
916 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
918 # Accept binutils 2.20 or newer.
919 AC_CHECK_PROG_VER(AS, $AS, --version,
920 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
921 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
922 AC_CHECK_PROG_VER(LD, $LD, --version,
923 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
924 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
926 # These programs are version sensitive.
927 AC_CHECK_TOOL_PREFIX
928 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
929 [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
930 critic_missing="$critic_missing gcc")
931 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
932 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
933 [3.79* | 3.[89]*], critic_missing="$critic_missing make")
935 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
936 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
937 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
938 MSGFMT=: aux_missing="$aux_missing msgfmt")
939 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
940 [GNU texinfo.* \([0-9][0-9.]*\)],
941 [4.*],
942 MAKEINFO=: aux_missing="$aux_missing makeinfo")
943 AC_CHECK_PROG_VER(SED, sed, --version,
944 [GNU sed version \([0-9]*\.[0-9.]*\)],
945 [3.0[2-9]*|3.[1-9]*|[4-9]*],
946 SED=: aux_missing="$aux_missing sed")
948 AC_CHECK_TOOL(READELF, readelf, false)
950 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
951 case "x$AUTOCONF" in
952 xno|x|x:) AUTOCONF=no ;;
953 *)
954 AC_CACHE_CHECK(dnl
955 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
956 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
957 libc_cv_autoconf_works=yes
958 else
959 libc_cv_autoconf_works=no
960 fi])
961 test $libc_cv_autoconf_works = yes || AUTOCONF=no
962 ;;
963 esac
964 if test "x$AUTOCONF" = xno; then
965 aux_missing="$aux_missing autoconf"
966 fi
968 test -n "$critic_missing" && AC_MSG_ERROR([
969 *** These critical programs are missing or too old:$critic_missing
970 *** Check the INSTALL file for required versions.])
972 test -n "$aux_missing" && AC_MSG_WARN([
973 *** These auxiliary programs are missing or incompatible versions:$aux_missing
974 *** some features will be disabled.
975 *** Check the INSTALL file for required versions.])
977 # if using special system headers, find out the compiler's sekrit
978 # header directory and add that to the list. NOTE: Only does the right
979 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
980 if test -n "$sysheaders"; then
981 SYSINCLUDES=-nostdinc
982 for d in include include-fixed; do
983 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
984 SYSINCLUDES="$SYSINCLUDES -isystem $i"
985 done
986 SYSINCLUDES="$SYSINCLUDES \
987 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
988 if test -n "$CXX"; then
989 CXX_SYSINCLUDES=
990 cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
991 cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
992 for d in include "$cxxmachine/include"; do
993 i=../../../../$d/c++/$cxxversion
994 cxxheaders=`$CXX -print-file-name="$i"` &&
995 test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
996 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
997 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
998 done
999 fi
1000 fi
1001 AC_SUBST(SYSINCLUDES)
1002 AC_SUBST(CXX_SYSINCLUDES)
1004 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1005 # since this would lead to problems installing/building glibc.
1006 # LD_LIBRARY_PATH contains the current directory if one of the following
1007 # is true:
1008 # - one of the terminals (":" and ";") is the first or last sign
1009 # - two terminals occur directly after each other
1010 # - the path contains an element with a dot in it
1011 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1012 changequote(,)dnl
1013 case ${LD_LIBRARY_PATH} in
1014 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1015 ld_library_path_setting="contains current directory"
1016 ;;
1017 *)
1018 ld_library_path_setting="ok"
1019 ;;
1020 esac
1021 changequote([,])dnl
1022 AC_MSG_RESULT($ld_library_path_setting)
1023 if test "$ld_library_path_setting" != "ok"; then
1024 AC_MSG_ERROR([
1025 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1026 *** building glibc. Please change the environment variable
1027 *** and run configure again.])
1028 fi
1030 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1031 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1032 libc_cv_gcc_static_libgcc=
1033 else
1034 libc_cv_gcc_static_libgcc=-static-libgcc
1035 fi])
1036 AC_SUBST(libc_cv_gcc_static_libgcc)
1038 AC_PATH_PROG(BASH_SHELL, bash, no)
1039 if test "$BASH_SHELL" != no &&
1040 $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1041 && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1042 libc_cv_have_bash2=yes
1043 else
1044 libc_cv_have_bash2=no
1045 fi
1046 AC_SUBST(libc_cv_have_bash2)
1048 dnl We need a ksh compatible shell for tzselect.
1049 if test "$BASH_SHELL" = no; then
1050 AC_PATH_PROG(KSH, ksh, no)
1051 if test "$KSH" = no; then
1052 libc_cv_have_ksh=no
1053 else
1054 libc_cv_have_ksh=yes
1055 fi
1056 else
1057 KSH="$BASH_SHELL"
1058 AC_SUBST(KSH)
1059 libc_cv_have_ksh=yes
1060 fi
1061 AC_SUBST(libc_cv_have_ksh)
1063 AC_PROG_AWK
1064 AC_PATH_PROG(PERL, perl, no)
1065 if test "$PERL" != no &&
1066 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1067 PERL=no
1068 fi
1069 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1070 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1071 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1073 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1074 AC_TRY_COMPILE(dnl
1075 [#define __need_size_t
1076 #define __need_wchar_t
1077 #include <stddef.h>
1078 #define __need_NULL
1079 #include <stddef.h>], [size_t size; wchar_t wchar;
1080 #ifdef offsetof
1081 #error stddef.h ignored __need_*
1082 #endif
1083 if (&size == NULL || &wchar == NULL) abort ();],
1084 libc_cv_friendly_stddef=yes,
1085 libc_cv_friendly_stddef=no)])
1086 if test $libc_cv_friendly_stddef = yes; then
1087 config_vars="$config_vars
1088 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1089 fi
1091 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1092 libc_cv_need_minus_P, [dnl
1093 cat > conftest.S <<EOF
1094 #include "confdefs.h"
1095 /* Nothing whatsoever. */
1096 EOF
1097 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1098 libc_cv_need_minus_P=no
1099 else
1100 libc_cv_need_minus_P=yes
1101 fi
1102 rm -f conftest*])
1103 if test $libc_cv_need_minus_P = yes; then
1104 config_vars="$config_vars
1105 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1106 fi
1108 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1109 cat > conftest.s <<EOF
1110 ${libc_cv_dot_text}
1111 foo:
1112 .set glibc_conftest_frobozz,foo
1113 $libc_cv_asm_global_directive glibc_conftest_frobozz
1114 EOF
1115 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1116 # (but it doesn't work), so we must do a linking check to be sure.
1117 cat > conftest1.c <<\EOF
1118 extern int glibc_conftest_frobozz;
1119 void _start() { glibc_conftest_frobozz = 1; }
1120 EOF
1121 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1122 -nostartfiles -nostdlib \
1123 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1124 libc_cv_asm_set_directive=yes
1125 else
1126 libc_cv_asm_set_directive=no
1127 fi
1128 rm -f conftest*])
1129 if test $libc_cv_asm_set_directive = yes; then
1130 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1131 fi
1133 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1134 libc_cv_asm_unique_object, [dnl
1135 cat > conftest.s <<EOF
1136 ${libc_cv_dot_text}
1137 _sym:
1138 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1139 EOF
1140 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1141 libc_cv_asm_unique_object=yes
1142 else
1143 libc_cv_asm_unique_object=no
1144 fi
1145 rm -f conftest*])
1146 if test $libc_cv_asm_unique_object = yes; then
1147 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1148 fi
1150 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1151 [cat > conftest.s <<EOF
1152 ${libc_cv_dot_text}
1153 _sym:
1154 .symver _sym,sym@VERS
1155 EOF
1156 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1157 libc_cv_asm_symver_directive=yes
1158 else
1159 libc_cv_asm_symver_directive=no
1160 fi
1161 rm -f conftest*])
1162 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1163 if test $libc_cv_asm_symver_directive = yes; then
1164 cat > conftest.s <<EOF
1165 ${libc_cv_dot_text}
1166 _sym:
1167 .symver _sym,sym@VERS
1168 EOF
1169 cat > conftest.map <<EOF
1170 VERS_1 {
1171 global: sym;
1172 };
1174 VERS_2 {
1175 global: sym;
1176 } VERS_1;
1177 EOF
1178 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1179 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1180 -o conftest.so conftest.o
1181 -nostartfiles -nostdlib
1182 -Wl,--version-script,conftest.map
1183 1>&AS_MESSAGE_LOG_FD]);
1184 then
1185 libc_cv_ld_version_script_option=yes
1186 else
1187 libc_cv_ld_version_script_option=no
1188 fi
1189 else
1190 libc_cv_ld_version_script_option=no
1191 fi
1192 else
1193 libc_cv_ld_version_script_option=no
1194 fi
1195 rm -f conftest*])
1196 if test $shared != no &&
1197 test $libc_cv_asm_symver_directive = yes &&
1198 test $libc_cv_ld_version_script_option = yes &&
1199 test $enable_versioning = yes; then
1200 VERSIONING=yes
1201 AC_DEFINE(DO_VERSIONING)
1202 else
1203 VERSIONING=no
1204 fi
1205 AC_SUBST(VERSIONING)
1207 if test $shared != no && test $VERSIONING = no; then
1208 echo "\
1209 *** WARNING: You should not compile GNU libc without versioning. Not using
1210 *** versioning will introduce incompatibilities so that old binaries
1211 *** will not run anymore.
1212 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1213 fi
1214 AC_CACHE_CHECK(for .previous assembler directive,
1215 libc_cv_asm_previous_directive, [dnl
1216 cat > conftest.s <<EOF
1217 .section foo_section
1218 .previous
1219 EOF
1220 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1221 libc_cv_asm_previous_directive=yes
1222 else
1223 libc_cv_asm_previous_directive=no
1224 fi
1225 rm -f conftest*])
1226 if test $libc_cv_asm_previous_directive = yes; then
1227 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1228 else
1229 AC_CACHE_CHECK(for .popsection assembler directive,
1230 libc_cv_asm_popsection_directive, [dnl
1231 cat > conftest.s <<EOF
1232 .pushsection foo_section
1233 .popsection
1234 EOF
1235 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1236 libc_cv_asm_popsection_directive=yes
1237 else
1238 libc_cv_asm_popsection_directive=no
1239 fi
1240 rm -f conftest*])
1241 if test $libc_cv_asm_popsection_directive = yes; then
1242 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1243 fi
1244 fi
1245 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1246 libc_cv_asm_protected_directive, [dnl
1247 cat > conftest.s <<EOF
1248 .protected foo
1249 foo:
1250 .hidden bar
1251 bar:
1252 EOF
1253 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1254 libc_cv_asm_protected_directive=yes
1255 else
1256 AC_MSG_ERROR(assembler support for symbol visibility is required)
1257 fi
1258 rm -f conftest*])
1260 if test $libc_cv_asm_protected_directive = yes; then
1261 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1262 libc_cv_visibility_attribute,
1263 [cat > conftest.c <<EOF
1264 int foo __attribute__ ((visibility ("hidden"))) = 1;
1265 int bar __attribute__ ((visibility ("protected"))) = 1;
1266 EOF
1267 libc_cv_visibility_attribute=no
1268 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1269 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1270 if grep '\.protected.*bar' conftest.s >/dev/null; then
1271 libc_cv_visibility_attribute=yes
1272 fi
1273 fi
1274 fi
1275 rm -f conftest.{c,s}
1276 ])
1277 if test $libc_cv_visibility_attribute != yes; then
1278 AC_MSG_ERROR(compiler support for visibility attribute is required)
1279 fi
1280 fi
1282 if test $libc_cv_visibility_attribute = yes; then
1283 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1284 libc_cv_broken_visibility_attribute,
1285 [cat > conftest.c <<EOF
1286 int foo (int x);
1287 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1288 int bar (int x) { return x; }
1289 EOF
1290 libc_cv_broken_visibility_attribute=yes
1291 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1292 changequote(,)dnl
1293 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1294 changequote([,])dnl
1295 libc_cv_broken_visibility_attribute=no
1296 fi
1297 fi
1298 rm -f conftest.c conftest.s
1299 ])
1300 if test $libc_cv_broken_visibility_attribute = yes; then
1301 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1302 fi
1303 fi
1305 AC_CACHE_CHECK(for broken __attribute__((alias())),
1306 libc_cv_broken_alias_attribute,
1307 [cat > conftest.c <<EOF
1308 extern int foo (int x) __asm ("xyzzy");
1309 int bar (int x) { return x; }
1310 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1311 extern int dfoo;
1312 extern __typeof (dfoo) dfoo __asm ("abccb");
1313 int dfoo = 1;
1314 EOF
1315 libc_cv_broken_alias_attribute=yes
1316 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1317 if grep 'xyzzy' conftest.s >/dev/null &&
1318 grep 'abccb' conftest.s >/dev/null; then
1319 libc_cv_broken_alias_attribute=no
1320 fi
1321 fi
1322 rm -f conftest.c conftest.s
1323 ])
1324 if test $libc_cv_broken_alias_attribute = yes; then
1325 AC_MSG_ERROR(working alias attribute support required)
1326 fi
1328 if test $libc_cv_visibility_attribute = yes; then
1329 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1330 libc_cv_have_sdata_section,
1331 [echo "int i;" > conftest.c
1332 libc_cv_have_sdata_section=no
1333 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1334 | grep '\.sdata' >/dev/null; then
1335 libc_cv_have_sdata_section=yes
1336 fi
1337 rm -f conftest.c conftest.so
1338 ])
1339 if test $libc_cv_have_sdata_section = yes; then
1340 AC_DEFINE(HAVE_SDATA_SECTION)
1341 fi
1342 fi
1344 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1345 libc_cv_initfini_array, [dnl
1346 LIBC_TRY_LINK_STATIC([
1347 int foo (void) { return 1; }
1348 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1349 ],
1350 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1351 libc_cv_initfini_array=yes
1352 else
1353 libc_cv_initfini_array=no
1354 fi],
1355 [libc_cv_initfini_array=no])
1356 ])
1357 if test $libc_cv_initfini_array != yes; then
1358 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1359 fi
1361 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1362 libc_cv_ctors_header, [dnl
1363 libc_cv_ctors_header=yes
1364 LIBC_TRY_LINK_STATIC([
1365 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1366 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1367 ],
1368 [dnl
1369 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1370 { gsub(/\@<:@ */, "@<:@") }
1371 $2 == ".ctors" || $2 == ".dtors" {
1372 size = strtonum("0x" $6)
1373 align = strtonum("0x" $NF)
1374 seen@<:@$2@:>@ = 1
1375 stub@<:@$2@:>@ = size == align * 2
1376 }
1377 END {
1378 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1379 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1380 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1381 }
1382 '], [libc_cv_ctors_header=no])
1383 ], [dnl
1384 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1385 ])
1386 ])
1387 if test $libc_cv_ctors_header = no; then
1388 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1389 fi
1391 AC_CACHE_CHECK(for libunwind-support in compiler,
1392 libc_cv_cc_with_libunwind, [
1393 cat > conftest.c <<EOF
1394 int main (void) { return 0; }
1395 EOF
1396 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1397 conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1398 libc_cv_cc_with_libunwind=yes
1399 else
1400 libc_cv_cc_with_libunwind=no
1401 fi
1402 rm -f conftest*])
1403 AC_SUBST(libc_cv_cc_with_libunwind)
1404 if test $libc_cv_cc_with_libunwind = yes; then
1405 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1406 fi
1408 AC_CACHE_CHECK(for -z nodelete option,
1409 libc_cv_z_nodelete, [dnl
1410 cat > conftest.c <<EOF
1411 int _start (void) { return 42; }
1412 EOF
1413 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1414 -fPIC -shared -o conftest.so conftest.c
1415 -nostartfiles -nostdlib
1416 -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1417 then
1418 libc_cv_z_nodelete=yes
1419 else
1420 AC_MSG_ERROR(linker with -z nodelete support required)
1421 fi
1422 rm -f conftest*])
1424 AC_CACHE_CHECK(for -z nodlopen option,
1425 libc_cv_z_nodlopen, [dnl
1426 cat > conftest.c <<EOF
1427 int _start (void) { return 42; }
1428 EOF
1429 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1430 -fPIC -shared -o conftest.so conftest.c
1431 -nostartfiles -nostdlib
1432 -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1433 then
1434 libc_cv_z_nodlopen=yes
1435 else
1436 AC_MSG_ERROR(linker with -z nodlopen support required)
1437 fi
1438 rm -f conftest*])
1440 AC_CACHE_CHECK(for -z initfirst option,
1441 libc_cv_z_initfirst, [dnl
1442 cat > conftest.c <<EOF
1443 int _start (void) { return 42; }
1444 EOF
1445 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1446 -fPIC -shared -o conftest.so conftest.c
1447 -nostartfiles -nostdlib
1448 -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1449 then
1450 libc_cv_z_initfirst=yes
1451 else
1452 AC_MSG_ERROR(linker with -z initfirst support required)
1453 fi
1454 rm -f conftest*])
1456 # Add-on fragments can set these for other machines.
1457 libc_commonpagesize=${libc_commonpagesize:-no}
1458 libc_relro_required=${libc_relro_required:-no}
1459 case "$base_machine" in
1460 i[[34567]]86 | x86_64 | powerpc* | s390*)
1461 libc_commonpagesize=0x1000
1462 libc_relro_required=yes
1463 ;;
1464 sparc*)
1465 libc_commonpagesize=0x2000
1466 libc_relro_required=yes
1467 ;;
1468 esac
1470 if test $libc_commonpagesize != no; then
1471 AC_CACHE_CHECK(for -z relro option,
1472 libc_cv_z_relro, [dnl
1473 libc_cv_z_relro=no
1474 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1475 int _start (void) { return 42; }
1476 extern void _exit (int);
1477 /* Since these pointers are const, they should go in rodata.
1478 Since they refer to functions that have to be resolved by
1479 dynamic linking, they should instead go in RELRO data. */
1480 const void *const relro[] = { &_start, &_exit, 0 };
1481 /* GNU ld fails to produce RELRO data when it's very small and there is no
1482 normal writable data following it, or if only uninitialized (.bss) data
1483 follows it, or only very small writable data. */
1484 int data[0x10000] = { 1, };
1485 ]])])
1486 cat > conftest.awk <<\EOF
1487 BEGIN {
1488 result = "no"
1489 commonpagesize = strtonum(commonpagesize)
1490 }
1491 { print "LINE:", $0 > "/dev/stderr" }
1492 $1 == "GNU_RELRO" {
1493 vaddr = strtonum($3)
1494 memsz = strtonum($6)
1495 end = vaddr + memsz
1496 printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1497 vaddr, memsz, end, commonpagesize > "/dev/stderr"
1498 result = (end % commonpagesize == 0) ? "yes" : "broken"
1499 }
1500 END { print result }
1501 EOF
1502 AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1503 -fPIC -shared -o conftest.so conftest.c
1504 -nostartfiles -nostdlib
1505 -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1506 AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1507 AC_TRY_COMMAND([
1508 $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1509 conftest.ph > conftest.cps
1510 ]) &&
1511 libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1512 rm -f conftest*])
1513 if { test "x$libc_relro_required" = xyes &&
1514 test "x$libc_cv_z_relro" != xyes
1515 }
1516 then
1517 AC_MSG_ERROR(linker with -z relro support required)
1518 fi
1519 else
1520 AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1521 fi
1523 AC_CACHE_CHECK(for -Bgroup option,
1524 libc_cv_Bgroup, [dnl
1525 cat > conftest.c <<EOF
1526 int _start (void) { return 42; }
1527 EOF
1528 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1529 -fPIC -shared -o conftest.so conftest.c
1530 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1531 then
1532 libc_cv_Bgroup=yes
1533 else
1534 libc_cv_Bgroup=no
1535 fi
1536 rm -f conftest*])
1537 AC_SUBST(libc_cv_Bgroup)
1539 AC_CACHE_CHECK(for libgcc_s suffix,
1540 libc_cv_libgcc_s_suffix, [dnl
1541 cat > conftest.c <<EOF
1542 int main (void) { return 0; }
1543 EOF
1544 changequote(,)dnl
1545 libc_cv_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1546 -fPIC -shared -shared-libgcc -o conftest.so \
1547 conftest.c -v 2>&1 >/dev/null \
1548 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1549 changequote([,])dnl
1550 rm -f conftest*])
1551 AC_SUBST(libc_cv_libgcc_s_suffix)
1553 AC_CACHE_CHECK(for --as-needed option,
1554 libc_cv_as_needed, [dnl
1555 cat > conftest.c <<EOF
1556 int main (void) { return 0; }
1557 EOF
1558 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1559 -fPIC -shared -o conftest.so conftest.c
1560 -lgcc_s$libc_cv_libgcc_s_suffix -Wl,--as-needed
1561 -nostdlib 1>&AS_MESSAGE_LOG_FD])
1562 then
1563 libc_cv_as_needed=yes
1564 else
1565 libc_cv_as_needed=no
1566 fi
1567 rm -f conftest*])
1568 AC_SUBST(libc_cv_as_needed)
1570 ASFLAGS_config=
1571 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1572 libc_cv_as_noexecstack, [dnl
1573 cat > conftest.c <<EOF
1574 void foo (void) { }
1575 EOF
1576 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1577 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1578 && grep -q .note.GNU-stack conftest.s \
1579 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1580 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1581 then
1582 libc_cv_as_noexecstack=yes
1583 else
1584 libc_cv_as_noexecstack=no
1585 fi
1586 rm -f conftest*])
1587 if test $libc_cv_as_noexecstack = yes; then
1588 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1589 fi
1590 AC_SUBST(ASFLAGS_config)
1592 AC_CACHE_CHECK(for -z combreloc,
1593 libc_cv_z_combreloc, [dnl
1594 cat > conftest.c <<EOF
1595 extern int bar (int);
1596 extern int mumble;
1597 int foo (void) { return bar (mumble); }
1598 EOF
1599 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1600 -fPIC -shared -o conftest.so conftest.c
1601 -nostdlib -nostartfiles
1602 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1603 then
1604 dnl The following test is a bit weak. We must use a tool which can test
1605 dnl cross-platform since the gcc used can be a cross compiler. Without
1606 dnl introducing new options this is not easily doable. Instead use a tool
1607 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1608 dnl look for a section named .rel.dyn.
1609 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1610 libc_cv_z_combreloc=yes
1611 else
1612 libc_cv_z_combreloc=no
1613 fi
1614 else
1615 libc_cv_z_combreloc=no
1616 fi
1617 rm -f conftest*])
1618 if test "$libc_cv_z_combreloc" = yes; then
1619 AC_DEFINE(HAVE_Z_COMBRELOC)
1620 fi
1621 AC_SUBST(libc_cv_z_combreloc)
1623 AC_CACHE_CHECK(for -z execstack,
1624 libc_cv_z_execstack, [dnl
1625 cat > conftest.c <<EOF
1626 int _start (void) { return 42; }
1627 EOF
1628 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1629 -fPIC -shared -o conftest.so conftest.c
1630 -Wl,-z,execstack -nostdlib
1631 1>&AS_MESSAGE_LOG_FD])
1632 then
1633 libc_cv_z_execstack=yes
1634 else
1635 libc_cv_z_execstack=no
1636 fi
1637 rm -f conftest*])
1638 AC_SUBST(libc_cv_z_execstack)
1640 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1641 cat > conftest.c <<EOF
1642 int foo;
1643 main () { return 0;}
1644 EOF
1645 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1646 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1647 then
1648 libc_cv_fpie=yes
1649 else
1650 libc_cv_fpie=no
1651 fi
1652 rm -f conftest*])
1654 AC_SUBST(libc_cv_fpie)
1656 AC_CACHE_CHECK(for --hash-style option,
1657 libc_cv_hashstyle, [dnl
1658 cat > conftest.c <<EOF
1659 int _start (void) { return 42; }
1660 EOF
1661 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1662 -fPIC -shared -o conftest.so conftest.c
1663 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1664 then
1665 libc_cv_hashstyle=yes
1666 else
1667 libc_cv_hashstyle=no
1668 fi
1669 rm -f conftest*])
1670 AC_SUBST(libc_cv_hashstyle)
1672 # The linker's default -shared behavior is good enough if it
1673 # does these things that our custom linker scripts ensure that
1674 # all allocated NOTE sections come first.
1675 if test "$use_default_link" = default; then
1676 AC_CACHE_CHECK([for sufficient default -shared layout],
1677 libc_cv_use_default_link, [dnl
1678 libc_cv_use_default_link=no
1679 cat > conftest.s <<\EOF
1680 .section .note.a,"a",%note
1681 .balign 4
1682 .long 4,4,9
1683 .string "GNU"
1684 .string "foo"
1685 .section .note.b,"a",%note
1686 .balign 4
1687 .long 4,4,9
1688 .string "GNU"
1689 .string "bar"
1690 EOF
1691 if AC_TRY_COMMAND([dnl
1692 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1693 ac_try=`$READELF -S conftest.so | sed -n \
1694 ['${x;p;}
1695 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1696 t a
1697 b
1698 : a
1699 H']`
1700 then
1701 libc_seen_a=no libc_seen_b=no
1702 set -- $ac_try
1703 while test $# -ge 2 -a "$1" = NOTE; do
1704 case "$2" in
1705 .note.a) libc_seen_a=yes ;;
1706 .note.b) libc_seen_b=yes ;;
1707 esac
1708 shift 2
1709 done
1710 case "$libc_seen_a$libc_seen_b" in
1711 yesyes)
1712 libc_cv_use_default_link=yes
1713 ;;
1714 *)
1715 echo >&AS_MESSAGE_LOG_FD "\
1716 $libc_seen_a$libc_seen_b from:
1717 $ac_try"
1718 ;;
1719 esac
1720 fi
1721 rm -f conftest*])
1722 use_default_link=$libc_cv_use_default_link
1723 fi
1725 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1726 if libc_cv_output_format=`
1727 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1728 then
1729 :
1730 else
1731 libc_cv_output_format=
1732 fi
1733 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1734 AC_SUBST(libc_cv_output_format)
1736 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1737 cat > conftest.c <<EOF
1738 int foo;
1739 EOF
1740 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1741 conftest.c 1>&AS_MESSAGE_LOG_FD])
1742 then
1743 libc_cv_fno_toplevel_reorder=yes
1744 else
1745 libc_cv_fno_toplevel_reorder=no
1746 fi
1747 rm -f conftest*])
1748 if test $libc_cv_fno_toplevel_reorder = yes; then
1749 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1750 else
1751 fno_unit_at_a_time=-fno-unit-at-a-time
1752 fi
1753 AC_SUBST(fno_unit_at_a_time)
1755 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1756 cat > conftest.c <<EOF
1757 int foo;
1758 main () { return 0;}
1759 EOF
1760 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -Werror -fstack-protector
1761 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1762 then
1763 libc_cv_ssp=yes
1764 else
1765 libc_cv_ssp=no
1766 fi
1767 rm -f conftest*])
1768 AC_SUBST(libc_cv_ssp)
1770 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1771 cat > conftest.c <<EOF
1772 int foo;
1773 #ifdef __GNUC_GNU_INLINE__
1774 main () { return 0;}
1775 #else
1776 #error
1777 #endif
1778 EOF
1779 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1780 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1781 then
1782 libc_cv_gnu89_inline=yes
1783 else
1784 libc_cv_gnu89_inline=no
1785 fi
1786 rm -f conftest*])
1787 if test $libc_cv_gnu89_inline = yes; then
1788 gnu89_inline=-fgnu89-inline
1789 else
1790 gnu89_inline=
1791 fi
1792 AC_SUBST(gnu89_inline)
1794 AC_CACHE_CHECK(whether cc puts quotes around section names,
1795 libc_cv_have_section_quotes,
1796 [cat > conftest.c <<EOF
1797 static const int foo
1798 __attribute__ ((section ("bar"))) = 1;
1799 EOF
1800 if ${CC-cc} -S conftest.c -o conftest.s; then
1801 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1802 libc_cv_have_section_quotes=yes
1803 else
1804 libc_cv_have_section_quotes=no
1805 fi
1806 else
1807 libc_cv_have_section_quotes=unknown
1808 fi
1809 rm -f conftest.{c,s}
1810 ])
1811 if test $libc_cv_have_section_quotes = yes; then
1812 AC_DEFINE(HAVE_SECTION_QUOTES)
1813 fi
1815 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1816 [dnl
1817 cat > conftest.s <<EOF
1818 ${libc_cv_dot_text}
1819 ${libc_cv_asm_global_directive} foo
1820 foo:
1821 .weak foo
1822 .weak bar; bar = foo
1823 EOF
1824 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1825 libc_cv_asm_weak_directive=yes
1826 else
1827 libc_cv_asm_weak_directive=no
1828 fi
1829 rm -f conftest*])
1831 if test $libc_cv_asm_weak_directive = no; then
1832 AC_CACHE_CHECK(for assembler .weakext directive,
1833 libc_cv_asm_weakext_directive,
1834 [dnl
1835 cat > conftest.s <<EOF
1836 ${libc_cv_dot_text}
1837 ${libc_cv_asm_global_directive} foo
1838 foo:
1839 .weakext bar foo
1840 .weakext baz
1841 ${libc_cv_asm_global_directive} baz
1842 baz:
1843 EOF
1844 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1845 libc_cv_asm_weakext_directive=yes
1846 else
1847 libc_cv_asm_weakext_directive=no
1848 fi
1849 rm -f conftest*])
1851 fi # no .weak
1853 if test $libc_cv_asm_weak_directive = yes; then
1854 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1855 elif test $libc_cv_asm_weakext_directive = yes; then
1856 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1857 fi
1859 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1860 case $machine in
1861 sparc/sparc64*) cfi_offset=2047;;
1862 *) cfi_offset=0;;
1863 esac
1864 cat > conftest.s <<EOF
1865 .text
1866 .type func,%function
1867 func:
1868 .cfi_startproc
1869 .cfi_remember_state
1870 .cfi_rel_offset 1, $cfi_offset
1871 .cfi_endproc
1872 EOF
1873 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1874 libc_cv_asm_cfi_directives=yes
1875 else
1876 libc_cv_asm_cfi_directives=no
1877 fi
1878 rm -f conftest*])
1879 if test $libc_cv_asm_cfi_directives = yes; then
1880 AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1881 fi
1883 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1884 cat > conftest.c <<\EOF
1885 _start () {}
1886 int __eh_pc;
1887 __throw () {}
1888 EOF
1889 dnl No \ in command here because it ends up inside ''.
1890 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1891 -nostdlib -nostartfiles -Wl,--no-whole-archive
1892 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1893 libc_cv_ld_no_whole_archive=yes
1894 else
1895 libc_cv_ld_no_whole_archive=no
1896 fi
1897 rm -f conftest*])
1898 if test $libc_cv_ld_no_whole_archive = no; then
1899 AC_MSG_ERROR([support for --no-whole-archive is needed])
1900 fi
1902 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1903 cat > conftest.c <<\EOF
1904 _start () {}
1905 int __eh_pc;
1906 __throw () {}
1907 EOF
1908 dnl No \ in command here because it ends up inside ''.
1909 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1910 -nostdlib -nostartfiles -fexceptions
1911 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1912 libc_cv_gcc_exceptions=yes
1913 else
1914 libc_cv_gcc_exceptions=no
1915 fi
1916 rm -f conftest*])
1917 if test $libc_cv_gcc_exceptions = yes; then
1918 exceptions=-fexceptions
1919 fi
1920 AC_SUBST(exceptions)dnl
1922 if test "$host_cpu" = powerpc ; then
1923 # Check for a bug present in at least versions 2.8.x of GCC
1924 # and versions 1.0.x of EGCS.
1925 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1926 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1927 libc_cv_c_asmcr0_bug='no',
1928 libc_cv_c_asmcr0_bug='yes')])
1929 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1930 AC_DEFINE(BROKEN_PPC_ASM_CR0)
1931 fi
1932 fi
1934 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1935 cat > conftest.c <<\EOF
1936 void zero (void *x)
1937 {
1938 __builtin_memset (x, 0, 1000);
1939 }
1940 EOF
1941 dnl
1942 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1943 then
1944 libc_cv_gcc_builtin_memset=no
1945 else
1946 libc_cv_gcc_builtin_memset=yes
1947 fi
1948 rm -f conftest* ])
1949 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1950 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1951 fi
1953 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1954 cat > conftest.c <<\EOF
1955 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1956 char *foo (const char *a, const char *b)
1957 {
1958 return __builtin_strstr (a, b);
1959 }
1960 EOF
1961 dnl
1962 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1963 then
1964 libc_cv_gcc_builtin_redirection=yes
1965 else
1966 libc_cv_gcc_builtin_redirection=no
1967 fi
1968 rm -f conftest* ])
1969 if test "$libc_cv_gcc_builtin_redirection" = no; then
1970 AC_MSG_ERROR([support for the symbol redirection needed])
1971 fi
1973 dnl Check whether the compiler supports the __thread keyword.
1974 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1975 [cat > conftest.c <<\EOF
1976 __thread int a = 42;
1977 EOF
1978 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1979 libc_cv_gcc___thread=yes
1980 else
1981 libc_cv_gcc___thread=no
1982 fi
1983 rm -f conftest*])
1984 if test "$libc_cv_gcc___thread" = no; then
1985 AC_MSG_ERROR([support for the __thread keyword is required])
1986 fi
1988 dnl Check whether the compiler supports the tls_model attribute.
1989 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1990 cat > conftest.c <<\EOF
1991 extern __thread int a __attribute__((tls_model ("initial-exec")));
1992 EOF
1993 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1994 libc_cv_gcc_tls_model_attr=yes
1995 else
1996 libc_cv_gcc_tls_model_attr=no
1997 fi
1998 rm -f conftest*])
1999 if test "$libc_cv_gcc_tls_model_attr" = no; then
2000 AC_MSG_ERROR([support for the tls_model attribute is required])
2001 fi
2003 if test -n "$submachine"; then
2004 AC_CACHE_CHECK([for compiler option for CPU variant],
2005 libc_cv_cc_submachine, [dnl
2006 libc_cv_cc_submachine=no
2007 for opt in "-march=$submachine" "-mcpu=$submachine"; do
2008 if AC_TRY_COMMAND([${CC-cc} $opt -xc /dev/null -S -o /dev/null]); then
2009 libc_cv_cc_submachine="$opt"
2010 break
2011 fi
2012 done])
2013 if test "x$libc_cv_cc_submachine" = xno; then
2014 AC_MSG_ERROR([${CC-cc} does not support $submachine])
2015 fi
2016 fi
2017 AC_SUBST(libc_cv_cc_submachine)
2019 dnl Check whether we have the gd library available.
2020 AC_MSG_CHECKING(for libgd)
2021 if test "$with_gd" != "no"; then
2022 old_CFLAGS="$CFLAGS"
2023 CFLAGS="$CFLAGS $libgd_include"
2024 old_LDFLAGS="$LDFLAGS"
2025 LDFLAGS="$LDFLAGS $libgd_ldflags"
2026 old_LIBS="$LIBS"
2027 LIBS="$LIBS -lgd -lpng -lz -lm"
2028 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
2029 CFLAGS="$old_CFLAGS"
2030 LDFLAGS="$old_LDFLAGS"
2031 LIBS="$old_LIBS"
2032 else
2033 LIBGD=no
2034 fi
2035 AC_MSG_RESULT($LIBGD)
2036 AC_SUBST(LIBGD)
2038 # SELinux detection
2039 if test x$with_selinux = xno ; then
2040 have_selinux=no;
2041 else
2042 # See if we have the SELinux library
2043 AC_CHECK_LIB(selinux, is_selinux_enabled,
2044 have_selinux=yes, have_selinux=no)
2045 # See if we have the SELinux header with the NSCD permissions in it.
2046 if test x$have_selinux = xyes ; then
2047 AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2048 AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2049 [#ifdef NSCD__SHMEMHOST
2050 return 0;
2051 #else
2052 #error NSCD__SHMEMHOST not defined
2053 #endif],
2054 have_selinux=yes, have_selinux=no)
2055 AC_MSG_RESULT($have_selinux)
2056 fi
2058 if test x$with_selinux = xyes ; then
2059 if test x$have_selinux = xno ; then
2060 AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2061 fi
2062 fi
2063 fi
2064 # Check if we're building with SELinux support.
2065 if test "x$have_selinux" = xyes; then
2066 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2068 # See if we have the libaudit library
2069 AC_CHECK_LIB(audit, audit_log_user_avc_message,
2070 have_libaudit=yes, have_libaudit=no)
2071 if test "x$have_libaudit" = xyes; then
2072 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2073 fi
2074 AC_SUBST(have_libaudit)
2076 # See if we have the libcap library
2077 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2078 if test "x$have_libcap" = xyes; then
2079 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2080 fi
2081 AC_SUBST(have_libcap)
2082 fi
2083 AC_SUBST(have_selinux)
2085 dnl check for the size of 'long double'.
2086 AC_CHECK_SIZEOF(long double, 0)
2087 sizeof_long_double=$ac_cv_sizeof_long_double
2088 AC_SUBST(sizeof_long_double)
2090 ### End of automated tests.
2091 ### Now run sysdeps configure fragments.
2093 # They also can set these variables.
2094 use_ldconfig=no
2095 ldd_rewrite_script=no
2096 libc_cv_sysconfdir=$sysconfdir
2097 libc_cv_gcc_unwind_find_fde=no
2098 libc_cv_idn=no
2100 # Iterate over all the sysdep directories we will use, running their
2101 # configure fragments.
2102 for dir in $sysnames; do
2103 case $dir in
2104 /*) dest=$dir ;;
2105 *) dest=$srcdir/$dir ;;
2106 esac
2107 if test -r $dest/configure; then
2108 AC_MSG_RESULT(running configure fragment for $dir)
2109 . $dest/configure
2110 fi
2111 done
2113 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2114 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2115 fi
2116 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2118 # Test for old glibc 2.0.x headers so that they can be removed properly
2119 # Search only in includedir.
2120 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2121 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2122 then
2123 old_glibc_headers=yes
2124 else
2125 old_glibc_headers=no
2126 fi
2127 AC_MSG_RESULT($old_glibc_headers)
2128 if test ${old_glibc_headers} = yes; then
2129 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2130 AC_MSG_WARN(*** be removed.)
2131 fi
2132 AC_SUBST(old_glibc_headers)
2134 AC_SUBST(libc_cv_slibdir)
2135 AC_SUBST(libc_cv_localedir)
2136 AC_SUBST(libc_cv_sysconfdir)
2137 AC_SUBST(libc_cv_rootsbindir)
2138 AC_SUBST(libc_cv_forced_unwind)
2140 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2141 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2142 AC_SUBST(libc_cv_cc_sse4)
2143 AC_SUBST(libc_cv_cc_avx)
2144 AC_SUBST(libc_cv_cc_sse2avx)
2145 AC_SUBST(libc_cv_cc_novzeroupper)
2146 AC_SUBST(libc_cv_cc_fma4)
2147 AC_SUBST(libc_cv_as_i686)
2148 AC_SUBST(libc_cv_sparc_as_vis3)
2150 AC_SUBST(use_ldconfig)
2151 AC_SUBST(ldd_rewrite_script)
2153 AC_SUBST(static)
2154 AC_SUBST(shared)
2156 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2157 [libc_cv_pic_default=yes
2158 cat > conftest.c <<EOF
2159 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2160 # error PIC is default.
2161 #endif
2162 EOF
2163 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2164 libc_cv_pic_default=no
2165 fi
2166 rm -f conftest.*])
2167 AC_SUBST(libc_cv_pic_default)
2169 AC_SUBST(profile)
2170 AC_SUBST(static_nss)
2172 AC_SUBST(DEFINES)
2174 dnl See sysdeps/mach/configure.in for this variable.
2175 AC_SUBST(mach_interface_list)
2177 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2178 config_makefile=
2179 else
2180 config_makefile=Makefile
2181 fi
2183 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2184 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2185 AC_SUBST(VERSION)
2186 AC_SUBST(RELEASE)
2188 AC_CONFIG_FILES([config.make ${config_makefile}])
2189 AC_CONFIG_COMMANDS([default],[[
2190 case $CONFIG_FILES in *config.make*)
2191 echo "$config_vars" >> config.make;;
2192 esac
2193 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2194 AC_OUTPUT