configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 # Glibc should not depend on any header files
   9 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  10   [m4_divert_text([DEFAULTS],
  11     [ac_includes_default='/* none */'])])
  12
  13 dnl This is here so we can set $subdirs directly based on configure fragments.
  14 AC_CONFIG_SUBDIRS()
  15
  16 AC_CANONICAL_HOST
  17
  18 AC_PROG_CC
  19 if test $host != $build; then
  20   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  21 fi
  22 AC_SUBST(cross_compiling)
  23 AC_PROG_CPP
  24 # We need the C++ compiler only for testing.
  25 AC_PROG_CXX
  26
  27 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  28   AC_MSG_ERROR([you must configure in a separate build directory])
  29 fi
  30
  31 # This will get text that should go into config.make.
  32 config_vars=
  33
  34 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  35 AC_ARG_WITH([gd],
  36             AC_HELP_STRING([--with-gd=DIR],
  37                            [find libgd include dir and library with prefix DIR]),
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH([gd-include],
  46             AC_HELP_STRING([--with-gd-include=DIR],
  47                            [find libgd include files in DIR]),
  48             [dnl
  49 case "$with_gd_include" in
  50 ''|no) ;;
  51 *) libgd_include="-I$withval" ;;
  52 esac
  53 ])
  54 AC_ARG_WITH([gd-lib],
  55             AC_HELP_STRING([--with-gd-lib=DIR],
  56                            [find libgd library files in DIR]),
  57             [dnl
  58 case "$with_gd_lib" in
  59 ''|no) ;;
  60 *) libgd_ldflags="-L$withval" ;;
  61 esac
  62 ])
  63
  64 if test -n "$libgd_include"; then
  65   config_vars="$config_vars
  66 CFLAGS-memusagestat.c = $libgd_include"
  67 fi
  68 if test -n "$libgd_ldflags"; then
  69   config_vars="$config_vars
  70 libgd-LDFLAGS = $libgd_ldflags"
  71 fi
  72
  73 dnl Arguments to specify presence of other packages/features.
  74 AC_ARG_WITH([fp],
  75             AC_HELP_STRING([--with-fp],
  76                            [if using floating-point hardware @<:@default=yes@:>@]),
  77             [with_fp=$withval],
  78             [with_fp=yes])
  79 AC_SUBST(with_fp)
  80 AC_ARG_WITH([binutils],
  81             AC_HELP_STRING([--with-binutils=PATH],
  82                            [specify location of binutils (as and ld)]),
  83             [path_binutils=$withval],
  84             [path_binutils=''])
  85 AC_ARG_WITH([selinux],
  86             AC_HELP_STRING([--with-selinux],
  87                            [if building with SELinux support]),
  88             [with_selinux=$withval],
  89             [with_selinux=auto])
  90
  91 AC_ARG_WITH([headers],
  92             AC_HELP_STRING([--with-headers=PATH],
  93                            [location of system headers to use
  94                             (for example /usr/src/linux/include)
  95                             @<:@default=compiler default@:>@]),
  96             [sysheaders=$withval],
  97             [sysheaders=''])
  98 AC_SUBST(sysheaders)
  99
 100 AC_SUBST(use_default_link)
 101 AC_ARG_WITH([default-link],
 102             AC_HELP_STRING([--with-default-link],
 103                            [do not use explicit linker scripts]),
 104             [use_default_link=$withval],
 105             [use_default_link=default])
 106
 107 AC_ARG_ENABLE([sanity-checks],
 108               AC_HELP_STRING([--disable-sanity-checks],
 109                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 110               [enable_sanity=$enableval],
 111               [enable_sanity=yes])
 112
 113 AC_ARG_ENABLE([shared],
 114               AC_HELP_STRING([--enable-shared],
 115                              [build shared library @<:@default=yes if GNU ld@:>@]),
 116               [shared=$enableval],
 117               [shared=yes])
 118 AC_ARG_ENABLE([profile],
 119               AC_HELP_STRING([--enable-profile],
 120                              [build profiled library @<:@default=no@:>@]),
 121               [profile=$enableval],
 122               [profile=no])
 123 AC_ARG_ENABLE([versioning],
 124               AC_HELP_STRING([--disable-versioning],
 125                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 126               [enable_versioning=$enableval],
 127               [enable_versioning=yes])
 128
 129 AC_ARG_ENABLE([oldest-abi],
 130               AC_HELP_STRING([--enable-oldest-abi=ABI],
 131                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 132               [oldest_abi=$enableval],
 133               [oldest_abi=no])
 134 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 135   oldest_abi=default
 136 else
 137   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 138 fi
 139 AC_SUBST(oldest_abi)
 140
 141 AC_ARG_ENABLE([stackguard-randomization],
 142               AC_HELP_STRING([--enable-stackguard-randomization],
 143                              [initialize __stack_chk_guard canary with a random number at program start]),
 144               [enable_stackguard_randomize=$enableval],
 145               [enable_stackguard_randomize=no])
 146 if test "$enable_stackguard_randomize" = yes; then
 147   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 148 fi
 149
 150 dnl Generic infrastructure for drop-in additions to libc.
 151 AC_ARG_ENABLE([add-ons],
 152               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 153                              [configure and build add-ons in DIR1,DIR2,...
 154                               search for add-ons if no parameter given]),
 155                              , [enable_add_ons=yes])
 156
 157 AC_ARG_ENABLE([hidden-plt],
 158               AC_HELP_STRING([--disable-hidden-plt],
 159                              [do not hide internal function calls to avoid PLT]),
 160               [hidden=$enableval],
 161               [hidden=yes])
 162 if test "x$hidden" = xno; then
 163   AC_DEFINE(NO_HIDDEN)
 164 fi
 165
 166 AC_ARG_ENABLE([bind-now],
 167               AC_HELP_STRING([--enable-bind-now],
 168                              [disable lazy relocations in DSOs]),
 169               [bindnow=$enableval],
 170               [bindnow=no])
 171 AC_SUBST(bindnow)
 172
 173 dnl On some platforms we cannot use dynamic loading.  We must provide
 174 dnl static NSS modules.
 175 AC_ARG_ENABLE([static-nss],
 176               AC_HELP_STRING([--enable-static-nss],
 177                              [build static NSS modules @<:@default=no@:>@]),
 178               [static_nss=$enableval],
 179               [static_nss=no])
 180 dnl Enable static NSS also if we build no shared objects.
 181 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 182   static_nss=yes
 183   AC_DEFINE(DO_STATIC_NSS)
 184 fi
 185
 186 AC_ARG_ENABLE([force-install],
 187               AC_HELP_STRING([--disable-force-install],
 188                              [don't force installation of files from this package, even if they are older than the installed files]),
 189               [force_install=$enableval],
 190               [force_install=yes])
 191 AC_SUBST(force_install)
 192
 193 dnl On some platforms we allow dropping compatibility with all kernel
 194 dnl versions.
 195 AC_ARG_ENABLE([kernel],
 196               AC_HELP_STRING([--enable-kernel=VERSION],
 197                              [compile for compatibility with kernel not older than VERSION]),
 198               [minimum_kernel=$enableval],
 199               [])
 200 dnl Prevent unreasonable values.
 201 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 202   # Better nothing than this.
 203   minimum_kernel=""
 204 else
 205   if test "$minimum_kernel" = current; then
 206     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 207   fi
 208 fi
 209
 210 dnl For the development we sometimes want gcc to issue even more warnings.
 211 dnl This is not the default since many of the extra warnings are not
 212 dnl appropriate.
 213 AC_ARG_ENABLE([all-warnings],
 214               AC_HELP_STRING([--enable-all-warnings],
 215                              [enable all useful warnings gcc can issue]),
 216               [all_warnings=$enableval],
 217               [])
 218 AC_SUBST(all_warnings)
 219
 220 AC_ARG_ENABLE([multi-arch],
 221               AC_HELP_STRING([--enable-multi-arch],
 222                              [enable single DSO with optimizations for multiple architectures]),
 223               [multi_arch=$enableval],
 224               [multi_arch=default])
 225
 226 AC_ARG_ENABLE([nss-crypt],
 227               AC_HELP_STRING([--enable-nss-crypt],
 228                              [enable libcrypt to use nss]),
 229               [nss_crypt=$enableval],
 230               [nss_crypt=no])
 231 if test x$nss_crypt = xyes; then
 232   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 233   if test $? -ne 0; then
 234     AC_MSG_ERROR([cannot find include directory with nss-config])
 235   fi
 236   old_CFLAGS="$CFLAGS"
 237   CFLAGS="$CFLAGS $nss_includes"
 238   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 239 #include <hasht.h>
 240 #include <nsslowhash.h>
 241 void f (void) { NSSLOW_Init (); }])],
 242              libc_cv_nss_crypt=yes,
 243              AC_MSG_ERROR([
 244 cannot find NSS headers with lowlevel hash function interfaces]))
 245   old_LIBS="$LIBS"
 246   LIBS="$LIBS -lfreebl3"
 247   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 248 #include <hasht.h>
 249 #include <nsslowhash.h>],
 250                                   [NSSLOW_Init();])],
 251                  libc_cv_nss_crypt=yes,
 252                  AC_MSG_ERROR([
 253 cannot link program using lowlevel NSS hash functions]))
 254   CFLAGS="$old_CFLAGS"
 255   LIBS="$old_LIBS"
 256 else
 257   libc_cv_nss_crypt=no
 258 fi
 259 AC_SUBST(libc_cv_nss_crypt)
 260
 261
 262 AC_ARG_ENABLE([obsolete-rpc],
 263               AC_HELP_STRING([--enable-obsolete-rpc],
 264                              [build and install the obsolete RPC code for link-time usage]),
 265               [link_obsolete_rpc=$enableval],
 266               [link_obsolete_rpc=no])
 267 AC_SUBST(link_obsolete_rpc)
 268
 269 if test "$link_obsolete_rpc" = yes; then
 270   AC_DEFINE(LINK_OBSOLETE_RPC)
 271 fi
 272
 273 AC_ARG_ENABLE([systemtap],
 274               [AS_HELP_STRING([--enable-systemtap],
 275                [enable systemtap static probe points @<:@default=no@:>@])],
 276               [systemtap=$enableval],
 277               [systemtap=no])
 278 if test "x$systemtap" != xno; then
 279   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 280   old_CFLAGS="$CFLAGS"
 281   CFLAGS="-std=gnu99 $CFLAGS"
 282   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 283 void foo (int i, void *p)
 284 {
 285   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 286        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 287 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 288   CFLAGS="$old_CFLAGS"])
 289   if test $libc_cv_sdt = yes; then
 290     AC_DEFINE([USE_STAP_PROBE])
 291   elif test "x$systemtap" != xauto; then
 292     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 293   fi
 294 fi
 295
 296 AC_ARG_ENABLE([build-nscd],
 297               [AS_HELP_STRING([--disable-build-nscd],
 298                [disable building and installing the nscd daemon])],
 299               [build_nscd=$enableval],
 300               [build_nscd=default])
 301 AC_SUBST(build_nscd)
 302
 303 # Note the use of $use_nscd is near the bottom of the file.
 304 AC_ARG_ENABLE([nscd],
 305               [AS_HELP_STRING([--disable-nscd],
 306                [library functions will not contact the nscd daemon])],
 307               [use_nscd=$enableval],
 308               [use_nscd=yes])
 309
 310 # The way shlib-versions is used to generate soversions.mk uses a
 311 # fairly simplistic model for name recognition that can't distinguish
 312 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 313 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 314 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 315 case "$host_os" in
 316 linux*)
 317   ;;
 318 gnu*)
 319   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 320   ;;
 321 esac
 322
 323 # We keep the original values in `$config_*' and never modify them, so we
 324 # can write them unchanged into config.make.  Everything else uses
 325 # $machine, $vendor, and $os, and changes them whenever convenient.
 326 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 327
 328 # Don't allow vendor == "unknown"
 329 test "$config_vendor" = unknown && config_vendor=
 330 config_os="`echo $config_os | sed 's/^unknown-//'`"
 331
 332 # Some configurations imply other options.
 333 elf=yes
 334
 335 # The configure fragment of an add-on port can modify these to supplement
 336 # or override the table in the case statement below.  No fragment should
 337 # ever change the config_* variables, however.
 338 machine=$config_machine
 339 vendor=$config_vendor
 340 os=$config_os
 341 base_os=''
 342
 343 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 344 # Unify this here.
 345 if test "$machine" = rs6000; then
 346   machine="powerpc"
 347 fi
 348
 349 # Braindead PowerPC box with absolutely no FPU.
 350 case "$machine-$host_os" in
 351   powerpc*-*soft)
 352     with_fp=no
 353     ;;
 354 esac
 355
 356 submachine=
 357 AC_ARG_WITH([cpu],
 358             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 359             [dnl
 360   case "$withval" in
 361   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 362   no) ;;
 363   *) submachine="$withval" ;;
 364   esac
 365 ])
 366
 367 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
 368 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 369
 370 # An add-on can set this when it wants to disable the sanity check below.
 371 libc_config_ok=no
 372
 373 dnl Having this here, though empty, makes sure that if add-ons' fragments
 374 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 375 dnl our AC_OUTPUT will actually use it.
 376 AC_CONFIG_SUBDIRS()
 377
 378 case "$enable_add_ons" in
 379 ''|no) add_ons= ;;
 380 yes|'*')
 381  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 382           sed 's@/[[^/]]*$@@' | sort | uniq`
 383          add_ons_automatic=yes
 384          ;;
 385 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 386        add_ons_automatic=no ;;
 387 esac
 388
 389 configured_add_ons=
 390 add_ons_sfx=
 391 add_ons_pfx=
 392 if test x"$add_ons" != x; then
 393   for f in $add_ons; do
 394     # Some sanity checks
 395     case "$f" in
 396     crypt)
 397       AC_MSG_ERROR([
 398 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 399 *** part of glibc and using the old add-on will not work with this
 400 *** release.  Start again with fresh sources and without the old
 401 *** \`crypt' add-on.])
 402     ;;
 403     localedata)
 404       AC_MSG_ERROR([
 405 *** It seems that you're using an old \`localedata' add-on.  localedata
 406 *** is now part of glibc and using the old add-on will not work with
 407 *** this release.  Start again with fresh sources and without the old
 408 *** \`localedata' add-on.])
 409     ;;
 410     esac
 411   done
 412
 413   # Now source each add-on's configure fragment.
 414   # The fragments can use $srcdir/$libc_add_on to find themselves,
 415   # and test $add_ons_automatic to see if they were explicitly requested.
 416   # A fragment can clear (or even change) $libc_add_on to affect
 417   # whether it goes into the list to be actually used in the build.
 418   use_add_ons=
 419   for libc_add_on in $add_ons; do
 420     # Test whether such a directory really exists.
 421     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 422     case "$libc_add_on" in
 423     /*)
 424       libc_add_on_srcdir=$libc_add_on
 425       ;;
 426     *)
 427       test -d "$srcdir/$libc_add_on" || {
 428         if test -d "$libc_add_on"; then
 429           libc_add_on="`pwd`/$libc_add_on"
 430         else
 431           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 432         fi
 433       }
 434       libc_add_on_srcdir=$srcdir/$libc_add_on
 435       ;;
 436     esac
 437
 438     libc_add_on_frag=$libc_add_on_srcdir/configure
 439     libc_add_on_canonical=
 440     libc_add_on_config_subdirs=
 441     if test -r "$libc_add_on_frag"; then
 442       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 443       libc_add_on_canonical=unknown
 444       libc_add_on_subdirs=
 445       . "$libc_add_on_frag"
 446       test -z "$libc_add_on" || {
 447         configured_add_ons="$configured_add_ons $libc_add_on"
 448         if test "x$libc_add_on_canonical" = xunknown; then
 449           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 450         fi
 451         for d in $libc_add_on_subdirs; do
 452           case "$libc_add_on" in
 453           /*) subdir_srcdir="$libc_add_on" ;;
 454           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 455           esac
 456           case "$d" in
 457           .)
 458             d="${libc_add_on_canonical:-$libc_add_on}"
 459             ;;
 460           /*)
 461             subdir_srcdir="$d"
 462             ;;
 463           *)
 464             subdir_srcdir="$subdir_srcdir/$d"
 465             ;;
 466           esac
 467           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 468           add_on_subdirs="$add_on_subdirs $d"
 469           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 470 $d-srcdir = $subdir_srcdir"
 471         done
 472         for d in $libc_add_on_config_subdirs; do
 473           case "$d" in
 474           /*) AC_MSG_ERROR(dnl
 475 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 476           esac
 477           if test ! -d "$libc_add_on_srcdir/$d"; then
 478             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 479           fi
 480           case "$libc_add_on" in
 481           /*) AC_MSG_ERROR(dnl
 482 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 483           esac
 484           subdirs="$subdirs $libc_add_on/$d"
 485         done
 486       }
 487     fi
 488     if test -n "$libc_add_on"; then
 489       LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
 490       use_add_ons="$use_add_ons $libc_add_on"
 491       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 492       test -z "$libc_add_on_canonical" ||
 493       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 494     fi
 495   done
 496   # Use echo to strip excess whitespace.
 497   add_ons="`echo $use_add_ons`"
 498 fi
 499 AC_SUBST(add_ons)
 500 AC_SUBST(add_on_subdirs)
 501
 502
 503 ###
 504 ### I put this here to prevent those annoying emails from people who cannot
 505 ### read and try to compile glibc on unsupported platforms.  --drepper
 506 ###
 507 ### By using the undocumented --enable-hacker-mode option for configure
 508 ### one can skip this test to make the configuration not fail for unsupported
 509 ### platforms.
 510 ###
 511 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 512   case "$machine-$host_os" in
 513   *-linux* | *-gnu*)
 514     ;;
 515   *)
 516     echo "*** The GNU C library is currently not available for this platform."
 517     echo "*** So far nobody cared to port it and if there is no volunteer it"
 518     echo "*** might never happen.  So, if you have interest to see glibc on"
 519     echo "*** this platform visit"
 520     echo "***   http://www.gnu.org/software/libc/porting.html"
 521     echo "*** and join the group of porters"
 522     exit 1
 523     ;;
 524   esac
 525 fi
 526
 527 dnl We need to use [ and ] for other purposes for a while now.
 528 changequote(,)dnl
 529 # Expand the configuration machine name into a subdirectory by architecture
 530 # type and particular chip.  If an add-on configure fragment already set
 531 # base_machine, we don't change it.
 532 test -n "$base_machine" || case "$machine" in
 533 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 534 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 535 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 536 s390)           base_machine=s390 machine=s390/s390-32 ;;
 537 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 538 sh3*)           base_machine=sh machine=sh/sh3 ;;
 539 sh4*)           base_machine=sh machine=sh/sh4 ;;
 540 sparc | sparcv[67])
 541                 base_machine=sparc machine=sparc/sparc32 ;;
 542 sparcv8 | supersparc | hypersparc)
 543                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 544 sparcv8plus | sparcv8plusa | sparcv9)
 545                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 546 sparcv8plusb | sparcv9b)
 547                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 548 sparcv9v)
 549                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 550 sparcv9v2)
 551                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 552 sparc64)
 553                 base_machine=sparc machine=sparc/sparc64 ;;
 554 sparc64b)
 555                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 556 sparc64v)
 557                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 558 sparc64v2)
 559                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 560 *)              base_machine=$machine ;;
 561 esac
 562 changequote([,])dnl
 563 AC_SUBST(base_machine)
 564
 565 if test "$base_machine" = "i386"; then
 566   AC_DEFINE(USE_REGPARMS)
 567 fi
 568
 569 # For the multi-arch option we need support in the assembler.
 570 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
 571                libc_cv_asm_gnu_indirect_function, [dnl
 572 cat > conftest.s <<EOF
 573 .type foo,%gnu_indirect_function
 574 EOF
 575 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 576 then
 577   libc_cv_asm_gnu_indirect_function=yes
 578 else
 579   libc_cv_asm_gnu_indirect_function=no
 580 fi
 581 rm -f conftest*])
 582
 583 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 584 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 585 cat > conftest.s <<EOF
 586 .text
 587 EOF
 588 libc_cv_dot_text=
 589 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 590   libc_cv_dot_text=.text
 591 fi
 592 rm -f conftest*])
 593 if test -z "$libc_cv_dot_text"; then
 594   AC_MSG_RESULT(no)
 595 else
 596   AC_MSG_RESULT(yes)
 597 fi
 598
 599 if test x"$libc_cv_asm_gnu_indirect_function" != xyes; then
 600   if test x"$multi_arch" = xyes; then
 601     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 602   else
 603     multi_arch=no
 604   fi
 605 fi
 606 if test x"$multi_arch" != xno; then
 607   multi_arch_d=/multiarch
 608 fi
 609
 610 # Compute the list of sysdep directories for this configuration.
 611 # This can take a while to compute.
 612 sysdep_dir=$srcdir/sysdeps
 613 AC_MSG_CHECKING(sysdep dirs)
 614 dnl We need to use [ and ] for other purposes for a while now.
 615 changequote(,)dnl
 616 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 617 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 618
 619 test "x$base_os" != x || case "$os" in
 620 gnu*)
 621   base_os=mach/hurd ;;
 622 linux*)
 623   base_os=unix/sysv ;;
 624 esac
 625
 626 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 627 tail=$os
 628 ostry=$os
 629 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 630   ostry="$ostry /$o"
 631   tail=$o
 632 done
 633 o=`echo $tail | sed 's/[0-9]*$//'`
 634 if test $o != $tail; then
 635   ostry="$ostry /$o"
 636 fi
 637 # For linux-gnu, try linux-gnu, then linux.
 638 o=`echo $tail | sed 's/-.*$//'`
 639 if test $o != $tail; then
 640   ostry="$ostry /$o"
 641 fi
 642
 643 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 644 base=
 645 tail=$base_os
 646 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 647   set $b
 648   base="$base /$1"
 649   tail="$2"
 650 done
 651
 652 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 653 mach=
 654 tail=$machine${submachine:+/$submachine}
 655 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 656   set $m
 657   # Prepend the machine's FPU directory unless --without-fp.
 658   if test "$with_fp" = yes; then
 659     mach="$mach /$1/fpu"
 660   else
 661     mach="$mach /$1/nofpu"
 662   fi
 663   mach="$mach /$1"
 664   tail="$2"
 665 done
 666
 667 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 668 changequote([,])dnl
 669
 670 # Find what sysdep directories exist.
 671 sysnames_add_ons=
 672 sysnames=
 673 for b in $base ''; do
 674   for m0 in $mach ''; do
 675     for v in /$vendor ''; do
 676       test "$v" = / && continue
 677       for o in /$ostry ''; do
 678         test "$o" = / && continue
 679         for m in $multi_arch_d $mach ''; do
 680           for d in $add_ons_pfx ''; do
 681             for a in $add_ons_sfx ''; do
 682               if test -n "$m0$m0sub$b$v$o$m$msub"; then
 683                 try_srcdir="${srcdir}/"
 684                 case "$d" in
 685                 /*) try_srcdir= ;;
 686                 esac
 687                 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
 688                 test -n "$enable_debug_configure" &&
 689                 echo "$0 [DEBUG]: try $try" >&2
 690                 if test -d "$try_srcdir$try"; then
 691                   sysnames="$sysnames $try"
 692                   { test -n "$o" || test -n "$b"; } && os_used=t
 693                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 694                   case x${m0:-$m} in
 695                   x*/$submachine) submachine_used=t ;;
 696                   esac
 697                   if test -n "$d"; then
 698                     case "$sysnames_add_ons" in
 699                     *" $d "*) ;;
 700                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 701                     esac
 702                   fi
 703                 fi
 704               fi
 705             done
 706           done
 707         done
 708       done
 709     done
 710   done
 711 done
 712
 713 # If the assembler supports gnu_indirect_function symbol type and the
 714 # architecture supports multi-arch, we enable multi-arch by default.
 715 case $sysnames_add_ons$sysnames in
 716 *"$multi_arch_d"*)
 717   ;;
 718 *)
 719   test x"$multi_arch" = xdefault && multi_arch=no
 720   ;;
 721 esac
 722 if test x"$multi_arch" != xno; then
 723   AC_DEFINE(USE_MULTIARCH)
 724 fi
 725 AC_SUBST(multi_arch)
 726
 727 if test -z "$os_used" && test "$os" != none; then
 728   AC_MSG_ERROR(Operating system $os is not supported.)
 729 fi
 730 if test -z "$machine_used" && test "$machine" != none; then
 731   AC_MSG_ERROR(The $machine is not supported.)
 732 fi
 733 if test -z "$submachine_used" && test -n "$submachine"; then
 734   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 735 fi
 736 AC_SUBST(submachine)
 737
 738 # We have now validated the configuration.
 739
 740 # Expand the list of system names into a full list of directories
 741 # from each element's parent name and Implies file (if present).
 742 set $sysnames
 743 names=
 744 while test $# -gt 0; do
 745   name=$1
 746   shift
 747
 748   case " $names " in *" $name "*)
 749     # Already in the list.
 750     continue
 751   esac
 752
 753   # Report each name as we discover it, so there is no long pause in output.
 754   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 755
 756   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 757
 758   case $name in
 759     /*) xsrcdir= ;;
 760     *)  xsrcdir=$srcdir/ ;;
 761   esac
 762   test -n "$enable_debug_configure" &&
 763   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 764
 765   for implies_file in Implies Implies-before Implies-after; do
 766     implies_type=`echo $implies_file | sed s/-/_/`
 767     eval ${implies_type}=
 768     if test -f $xsrcdir$name/$implies_file; then
 769       # Collect more names from the `Implies' file (removing comments).
 770       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 771       for x in $implied_candidate; do
 772         found=no
 773         if test -d $xsrcdir$name_base/$x; then
 774           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 775           found=yes
 776         fi
 777         for d in $add_ons_pfx ''; do
 778           try="${d}sysdeps/$x"
 779           case $d in
 780            /*) try_srcdir= ;;
 781            *) try_srcdir=$srcdir/ ;;
 782           esac
 783           test -n "$enable_debug_configure" &&
 784            echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
 785           if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 786           then
 787             eval "${implies_type}=\"\$${implies_type} \$try\""
 788             found=yes
 789             case "$sysnames_add_ons" in
 790             *" $d "*) ;;
 791             *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 792             esac
 793           fi
 794         done
 795         if test $found = no; then
 796           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 797         fi
 798       done
 799     fi
 800   done
 801
 802   # Add NAME to the list of names.
 803   names="$names $name"
 804
 805   # Find the parent of NAME, using the empty string if it has none.
 806 changequote(,)dnl
 807   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 808 changequote([,])dnl
 809
 810   test -n "$enable_debug_configure" &&
 811     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 812 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 813
 814   # Add the names implied by NAME, and NAME's parent (if it has one), to
 815   # the list of names to be processed (the argument list).  We prepend the
 816   # implied names to the list and append the parent.  We want implied
 817   # directories to come before further directories inferred from the
 818   # configuration components; this ensures that for sysv4, unix/common
 819   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 820   # after sysv4).
 821   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 822   test -n "$sysnames" && set $sysnames
 823 done
 824
 825 # Add the default directories.
 826 default_sysnames="sysdeps/generic"
 827 sysnames="$names $default_sysnames"
 828 AC_SUBST(sysnames)
 829 # The other names were emitted during the scan.
 830 AC_MSG_RESULT($default_sysnames)
 831
 832 # Collect the list of add-ons that supply partial sysdeps trees.
 833 sysdeps_add_ons=
 834 for add_on in $add_ons; do
 835   case "$add_on" in
 836   /*) xsrcdir= ;;
 837   *) xsrcdir="$srcdir/" ;;
 838   esac
 839
 840   test -d "$xsrcdir$add_on/sysdeps" || {
 841     case "$configured_add_ons " in
 842     *" $add_on "*) ;;
 843     *|'')
 844       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 845       ;;
 846     esac
 847     continue
 848   }
 849
 850   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 851   case "$sysnames_add_ons" in
 852   *" $add_on/ "*) ;;
 853   *|'')
 854     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 855     continue ;;
 856   esac
 857
 858   found=no
 859   for d in $sysnames; do
 860     case "$d" in
 861     $add_on/sysdeps/*) ;;
 862     *) continue ;;
 863     esac
 864     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 865        case "$f" in
 866        sys|bits)
 867          for ff in $f/*.h; do
 868            test -d "$ff" || { test -e "$ff" && exit 88; }
 869          done
 870          ;;
 871        *)
 872          test -d "$f" || { test -e "$f" && exit 88; }
 873          ;;
 874        esac
 875      done)
 876     if test $? -eq 88; then
 877       found=yes
 878       break
 879     fi
 880   done
 881   if test $found = no; then
 882     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 883   fi
 884 done
 885 AC_SUBST(sysdeps_add_ons)
 886
 887
 888 ### Locate tools.
 889
 890 AC_PROG_INSTALL
 891 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 892   # The makefiles need to use a different form to find it in $srcdir.
 893   INSTALL='\$(..)./scripts/install-sh -c'
 894 fi
 895 AC_PROG_LN_S
 896
 897 LIBC_PROG_BINUTILS
 898 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 899
 900 # Accept binutils 2.20 or newer.
 901 AC_CHECK_PROG_VER(AS, $AS, --version,
 902                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 903                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 904 AC_CHECK_PROG_VER(LD, $LD, --version,
 905                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 906                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 907
 908 # These programs are version sensitive.
 909 AC_CHECK_TOOL_PREFIX
 910 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 911   [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
 912   critic_missing="$critic_missing gcc")
 913 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 914   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 915   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 916
 917 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 918   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 919   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 920   MSGFMT=: aux_missing="$aux_missing msgfmt")
 921 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 922   [GNU texinfo.* \([0-9][0-9.]*\)],
 923   [4.[5-9]*|4.[1-9][0-9]*|[5-9].*],
 924   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 925 AC_CHECK_PROG_VER(SED, sed, --version,
 926   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 927   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 928   SED=: aux_missing="$aux_missing sed")
 929 AC_CHECK_PROG_VER(AWK, gawk, --version,
 930   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 931   [[3-9].*], critic_missing="$critic_missing gawk")
 932
 933 AC_CHECK_TOOL(READELF, readelf, false)
 934 AC_CHECK_TOOL(NM, nm, false)
 935
 936 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 937 case "x$AUTOCONF" in
 938 xno|x|x:) AUTOCONF=no ;;
 939 *)
 940   AC_CACHE_CHECK(dnl
 941 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 942   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 943     libc_cv_autoconf_works=yes
 944   else
 945     libc_cv_autoconf_works=no
 946   fi])
 947   test $libc_cv_autoconf_works = yes || AUTOCONF=no
 948   ;;
 949 esac
 950 if test "x$AUTOCONF" = xno; then
 951   aux_missing="$aux_missing autoconf"
 952 fi
 953
 954 test -n "$critic_missing" && AC_MSG_ERROR([
 955 *** These critical programs are missing or too old:$critic_missing
 956 *** Check the INSTALL file for required versions.])
 957
 958 test -n "$aux_missing" && AC_MSG_WARN([
 959 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 960 *** some features will be disabled.
 961 *** Check the INSTALL file for required versions.])
 962
 963 # if using special system headers, find out the compiler's sekrit
 964 # header directory and add that to the list.  NOTE: Only does the right
 965 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 966 if test -n "$sysheaders"; then
 967   SYSINCLUDES=-nostdinc
 968   for d in include include-fixed; do
 969     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
 970     SYSINCLUDES="$SYSINCLUDES -isystem $i"
 971   done
 972   SYSINCLUDES="$SYSINCLUDES \
 973 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
 974   if test -n "$CXX"; then
 975     CXX_SYSINCLUDES=
 976     cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
 977     cxxheaders=`$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
 978         | sed -n -e '1,/#include/d' -e '/^ \//{p;q;}' | sed 's/ //'`
 979     test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
 980     CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
 981 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
 982   fi
 983 fi
 984 AC_SUBST(SYSINCLUDES)
 985 AC_SUBST(CXX_SYSINCLUDES)
 986
 987 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 988 # since this would lead to problems installing/building glibc.
 989 # LD_LIBRARY_PATH contains the current directory if one of the following
 990 # is true:
 991 # - one of the terminals (":" and ";") is the first or last sign
 992 # - two terminals occur directly after each other
 993 # - the path contains an element with a dot in it
 994 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 995 changequote(,)dnl
 996 case ${LD_LIBRARY_PATH} in
 997   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 998     ld_library_path_setting="contains current directory"
 999     ;;
1000   *)
1001     ld_library_path_setting="ok"
1002     ;;
1003 esac
1004 changequote([,])dnl
1005 AC_MSG_RESULT($ld_library_path_setting)
1006 if test "$ld_library_path_setting" != "ok"; then
1007 AC_MSG_ERROR([
1008 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1009 *** building glibc. Please change the environment variable
1010 *** and run configure again.])
1011 fi
1012
1013 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1014 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1015   libc_cv_gcc_static_libgcc=
1016 else
1017   libc_cv_gcc_static_libgcc=-static-libgcc
1018 fi])
1019 AC_SUBST(libc_cv_gcc_static_libgcc)
1020
1021 AC_PATH_PROG(BASH_SHELL, bash, no)
1022 if test "$BASH_SHELL" != no &&
1023    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1024              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1025   libc_cv_have_bash2=yes
1026 else
1027   libc_cv_have_bash2=no
1028 fi
1029 AC_SUBST(libc_cv_have_bash2)
1030
1031 dnl We need a ksh compatible shell for tzselect.
1032 if test "$BASH_SHELL" = no; then
1033   AC_PATH_PROG(KSH, ksh, no)
1034   if test "$KSH" = no; then
1035     libc_cv_have_ksh=no
1036   else
1037     libc_cv_have_ksh=yes
1038   fi
1039 else
1040   KSH="$BASH_SHELL"
1041   AC_SUBST(KSH)
1042   libc_cv_have_ksh=yes
1043 fi
1044 AC_SUBST(libc_cv_have_ksh)
1045
1046 AC_PATH_PROG(PERL, perl, no)
1047 if test "$PERL" != no &&
1048    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1049   PERL=no
1050 fi
1051 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1052              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1053 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1054
1055 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1056 AC_TRY_COMPILE(dnl
1057 [#define __need_size_t
1058 #define __need_wchar_t
1059 #include <stddef.h>
1060 #define __need_NULL
1061 #include <stddef.h>], [size_t size; wchar_t wchar;
1062 #ifdef offsetof
1063 #error stddef.h ignored __need_*
1064 #endif
1065 if (&size == NULL || &wchar == NULL) abort ();],
1066                libc_cv_friendly_stddef=yes,
1067                libc_cv_friendly_stddef=no)])
1068 if test $libc_cv_friendly_stddef = yes; then
1069   config_vars="$config_vars
1070 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1071 fi
1072
1073 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1074                libc_cv_need_minus_P, [dnl
1075 cat > conftest.S <<EOF
1076 #include "confdefs.h"
1077 /* Nothing whatsoever.  */
1078 EOF
1079 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1080   libc_cv_need_minus_P=no
1081 else
1082   libc_cv_need_minus_P=yes
1083 fi
1084 rm -f conftest*])
1085 if test $libc_cv_need_minus_P = yes; then
1086   config_vars="$config_vars
1087 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1088 fi
1089
1090 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1091 cat > conftest.s <<EOF
1092 ${libc_cv_dot_text}
1093 foo:
1094 .set glibc_conftest_frobozz,foo
1095 .globl glibc_conftest_frobozz
1096 EOF
1097 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1098 # (but it doesn't work), so we must do a linking check to be sure.
1099 cat > conftest1.c <<\EOF
1100 extern int glibc_conftest_frobozz;
1101 void _start() { glibc_conftest_frobozz = 1; }
1102 EOF
1103 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1104             -nostartfiles -nostdlib \
1105             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1106   libc_cv_asm_set_directive=yes
1107 else
1108   libc_cv_asm_set_directive=no
1109 fi
1110 rm -f conftest*])
1111 if test $libc_cv_asm_set_directive = yes; then
1112   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1113 fi
1114
1115 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1116                libc_cv_asm_unique_object, [dnl
1117 cat > conftest.s <<EOF
1118 ${libc_cv_dot_text}
1119 _sym:
1120 .type _sym, %gnu_unique_object
1121 EOF
1122 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1123   libc_cv_asm_unique_object=yes
1124 else
1125   libc_cv_asm_unique_object=no
1126 fi
1127 rm -f conftest*])
1128 if test $libc_cv_asm_unique_object = yes; then
1129   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1130 fi
1131
1132 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1133 [cat > conftest.s <<EOF
1134 ${libc_cv_dot_text}
1135 _sym:
1136 .symver _sym,sym@VERS
1137 EOF
1138 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1139   libc_cv_asm_symver_directive=yes
1140 else
1141   libc_cv_asm_symver_directive=no
1142 fi
1143 rm -f conftest*])
1144 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1145 if test $libc_cv_asm_symver_directive = yes; then
1146   cat > conftest.s <<EOF
1147 ${libc_cv_dot_text}
1148 _sym:
1149 .symver _sym,sym@VERS
1150 EOF
1151   cat > conftest.map <<EOF
1152 VERS_1 {
1153         global: sym;
1154 };
1155
1156 VERS_2 {
1157         global: sym;
1158 } VERS_1;
1159 EOF
1160   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1161     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1162                                 -o conftest.so conftest.o
1163                                 -nostartfiles -nostdlib
1164                                 -Wl,--version-script,conftest.map
1165                        1>&AS_MESSAGE_LOG_FD]);
1166     then
1167       libc_cv_ld_version_script_option=yes
1168     else
1169       libc_cv_ld_version_script_option=no
1170     fi
1171   else
1172     libc_cv_ld_version_script_option=no
1173   fi
1174 else
1175   libc_cv_ld_version_script_option=no
1176 fi
1177 rm -f conftest*])
1178 if test $shared != no &&
1179    test $libc_cv_asm_symver_directive = yes &&
1180    test $libc_cv_ld_version_script_option = yes &&
1181    test $enable_versioning = yes; then
1182   VERSIONING=yes
1183   AC_DEFINE(DO_VERSIONING)
1184 else
1185   VERSIONING=no
1186 fi
1187 AC_SUBST(VERSIONING)
1188
1189 if test $shared != no && test $VERSIONING = no; then
1190   echo "\
1191 *** WARNING: You should not compile GNU libc without versioning. Not using
1192 *** versioning will introduce incompatibilities so that old binaries
1193 *** will not run anymore.
1194 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1195 fi
1196 AC_CACHE_CHECK(for .previous assembler directive,
1197                libc_cv_asm_previous_directive, [dnl
1198 cat > conftest.s <<EOF
1199 .section foo_section
1200 .previous
1201 EOF
1202 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1203   libc_cv_asm_previous_directive=yes
1204 else
1205   libc_cv_asm_previous_directive=no
1206 fi
1207 rm -f conftest*])
1208 if test $libc_cv_asm_previous_directive = yes; then
1209   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1210 else
1211   AC_CACHE_CHECK(for .popsection assembler directive,
1212                  libc_cv_asm_popsection_directive, [dnl
1213   cat > conftest.s <<EOF
1214 .pushsection foo_section
1215 .popsection
1216 EOF
1217   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1218     libc_cv_asm_popsection_directive=yes
1219   else
1220     libc_cv_asm_popsection_directive=no
1221   fi
1222   rm -f conftest*])
1223   if test $libc_cv_asm_popsection_directive = yes; then
1224     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1225   fi
1226 fi
1227 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1228                libc_cv_asm_protected_directive, [dnl
1229 cat > conftest.s <<EOF
1230 .protected foo
1231 foo:
1232 .hidden bar
1233 bar:
1234 EOF
1235 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1236   libc_cv_asm_protected_directive=yes
1237 else
1238   AC_MSG_ERROR(assembler support for symbol visibility is required)
1239 fi
1240 rm -f conftest*])
1241
1242 if test $libc_cv_asm_protected_directive = yes; then
1243   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1244                  libc_cv_visibility_attribute,
1245                  [cat > conftest.c <<EOF
1246                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1247                   int bar __attribute__ ((visibility ("protected"))) = 1;
1248 EOF
1249                   libc_cv_visibility_attribute=no
1250                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1251                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1252                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1253                         libc_cv_visibility_attribute=yes
1254                       fi
1255                     fi
1256                   fi
1257                   rm -f conftest.{c,s}
1258                  ])
1259   if test $libc_cv_visibility_attribute != yes; then
1260     AC_MSG_ERROR(compiler support for visibility attribute is required)
1261   fi
1262 fi
1263
1264 if test $libc_cv_visibility_attribute = yes; then
1265   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1266                  libc_cv_broken_visibility_attribute,
1267                  [cat > conftest.c <<EOF
1268                   int foo (int x);
1269                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1270                   int bar (int x) { return x; }
1271 EOF
1272                   libc_cv_broken_visibility_attribute=yes
1273                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1274 changequote(,)dnl
1275                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1276 changequote([,])dnl
1277                       libc_cv_broken_visibility_attribute=no
1278                     fi
1279                   fi
1280                   rm -f conftest.c conftest.s
1281                  ])
1282   if test $libc_cv_broken_visibility_attribute = yes; then
1283     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1284   fi
1285 fi
1286
1287 AC_CACHE_CHECK(for broken __attribute__((alias())),
1288                libc_cv_broken_alias_attribute,
1289                [cat > conftest.c <<EOF
1290                extern int foo (int x) __asm ("xyzzy");
1291                int bar (int x) { return x; }
1292                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1293                extern int dfoo;
1294                extern __typeof (dfoo) dfoo __asm ("abccb");
1295                int dfoo = 1;
1296 EOF
1297                libc_cv_broken_alias_attribute=yes
1298                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1299                  if grep 'xyzzy' conftest.s >/dev/null &&
1300                     grep 'abccb' conftest.s >/dev/null; then
1301                    libc_cv_broken_alias_attribute=no
1302                  fi
1303                fi
1304                rm -f conftest.c conftest.s
1305                ])
1306 if test $libc_cv_broken_alias_attribute = yes; then
1307   AC_MSG_ERROR(working alias attribute support required)
1308 fi
1309
1310 if test $libc_cv_visibility_attribute = yes; then
1311   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1312                  libc_cv_have_sdata_section,
1313                  [echo "int i;" > conftest.c
1314                   libc_cv_have_sdata_section=no
1315                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1316                      | grep '\.sdata' >/dev/null; then
1317                     libc_cv_have_sdata_section=yes
1318                   fi
1319                   rm -f conftest.c conftest.so
1320                  ])
1321   if test $libc_cv_have_sdata_section = yes; then
1322     AC_DEFINE(HAVE_SDATA_SECTION)
1323   fi
1324 fi
1325
1326 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1327                libc_cv_initfini_array, [dnl
1328 LIBC_TRY_LINK_STATIC([
1329 int foo (void) { return 1; }
1330 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1331 ],
1332   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1333     libc_cv_initfini_array=yes
1334   else
1335     libc_cv_initfini_array=no
1336   fi],
1337   [libc_cv_initfini_array=no])
1338 ])
1339 if test $libc_cv_initfini_array != yes; then
1340   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1341 fi
1342
1343 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1344                libc_cv_ctors_header, [dnl
1345   libc_cv_ctors_header=yes
1346   LIBC_TRY_LINK_STATIC([
1347 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1348 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1349 ],
1350               [dnl
1351       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1352         { gsub(/\@<:@ */, "@<:@") }
1353         $2 == ".ctors" || $2 == ".dtors" {
1354           size = strtonum("0x" $6)
1355           align = strtonum("0x" $NF)
1356           seen@<:@$2@:>@ = 1
1357           stub@<:@$2@:>@ = size == align * 2
1358         }
1359         END {
1360           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1361           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1362           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1363         }
1364       '], [libc_cv_ctors_header=no])
1365     ], [dnl
1366       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1367     ])
1368 ])
1369 if test $libc_cv_ctors_header = no; then
1370   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1371 fi
1372
1373 AC_CACHE_CHECK(for libunwind-support in compiler,
1374                libc_cv_cc_with_libunwind, [
1375   cat > conftest.c <<EOF
1376 int main (void) { return 0; }
1377 EOF
1378   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1379      conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1380     libc_cv_cc_with_libunwind=yes
1381   else
1382     libc_cv_cc_with_libunwind=no
1383   fi
1384   rm -f conftest*])
1385 AC_SUBST(libc_cv_cc_with_libunwind)
1386 if test $libc_cv_cc_with_libunwind = yes; then
1387   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1388 fi
1389
1390 AC_CACHE_CHECK(for -z nodelete option,
1391                libc_cv_z_nodelete, [dnl
1392 cat > conftest.c <<EOF
1393 int _start (void) { return 42; }
1394 EOF
1395 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1396                    -fPIC -shared -o conftest.so conftest.c
1397                    -nostartfiles -nostdlib
1398                    -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1399 then
1400   libc_cv_z_nodelete=yes
1401 else
1402   AC_MSG_ERROR(linker with -z nodelete support required)
1403 fi
1404 rm -f conftest*])
1405
1406 AC_CACHE_CHECK(for -z nodlopen option,
1407                libc_cv_z_nodlopen, [dnl
1408 cat > conftest.c <<EOF
1409 int _start (void) { return 42; }
1410 EOF
1411 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1412                         -fPIC -shared -o conftest.so conftest.c
1413                         -nostartfiles -nostdlib
1414                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1415 then
1416   libc_cv_z_nodlopen=yes
1417 else
1418   AC_MSG_ERROR(linker with -z nodlopen support required)
1419 fi
1420 rm -f conftest*])
1421
1422 AC_CACHE_CHECK(for -z initfirst option,
1423                libc_cv_z_initfirst, [dnl
1424 cat > conftest.c <<EOF
1425 int _start (void) { return 42; }
1426 EOF
1427 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1428                         -fPIC -shared -o conftest.so conftest.c
1429                         -nostartfiles -nostdlib
1430                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1431 then
1432   libc_cv_z_initfirst=yes
1433 else
1434   AC_MSG_ERROR(linker with -z initfirst support required)
1435 fi
1436 rm -f conftest*])
1437
1438 # Add-on fragments can set these for other machines.
1439 libc_commonpagesize=${libc_commonpagesize:-no}
1440 libc_relro_required=${libc_relro_required:-no}
1441 case "$base_machine" in
1442   i[[34567]]86 | x86_64 | powerpc* | s390*)
1443     libc_commonpagesize=0x1000
1444     libc_relro_required=yes
1445     ;;
1446   sparc*)
1447     libc_commonpagesize=0x2000
1448     libc_relro_required=yes
1449     ;;
1450 esac
1451
1452 if test $libc_commonpagesize != no; then
1453   AC_CACHE_CHECK(for -z relro option,
1454                  libc_cv_z_relro, [dnl
1455   libc_cv_z_relro=no
1456   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1457 int _start (void) { return 42; }
1458 extern void _exit (int);
1459 /* Since these pointers are const, they should go in rodata.
1460    Since they refer to functions that have to be resolved by
1461    dynamic linking, they should instead go in RELRO data.  */
1462 const void *const relro[] = { &_start, &_exit, 0 };
1463 /* GNU ld fails to produce RELRO data when it's very small and there is no
1464    normal writable data following it, or if only uninitialized (.bss) data
1465    follows it, or only very small writable data.  */
1466 int data[0x10000] = { 1, };
1467 ]])])
1468   cat > conftest.awk <<\EOF
1469 BEGIN {
1470   result = "no"
1471   commonpagesize = strtonum(commonpagesize)
1472 }
1473 { print "LINE:", $0 > "/dev/stderr" }
1474 $1 == "GNU_RELRO" {
1475   vaddr = strtonum($3)
1476   memsz = strtonum($6)
1477   end = vaddr + memsz
1478   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1479     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1480   result = (end % commonpagesize == 0) ? "yes" : "broken"
1481 }
1482 END { print result }
1483 EOF
1484   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1485                     -fPIC -shared -o conftest.so conftest.c
1486                     -nostartfiles -nostdlib
1487                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1488   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1489   AC_TRY_COMMAND([
1490       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1491            conftest.ph > conftest.cps
1492     ]) &&
1493   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1494   rm -f conftest*])
1495   if { test "x$libc_relro_required" = xyes &&
1496        test "x$libc_cv_z_relro" != xyes
1497      }
1498   then
1499     AC_MSG_ERROR(linker with -z relro support required)
1500   fi
1501 else
1502   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1503 fi
1504
1505 AC_CACHE_CHECK(for -Bgroup option,
1506                libc_cv_Bgroup, [dnl
1507 cat > conftest.c <<EOF
1508 int _start (void) { return 42; }
1509 EOF
1510 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1511                             -fPIC -shared -o conftest.so conftest.c
1512                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1513 then
1514   libc_cv_Bgroup=yes
1515 else
1516   libc_cv_Bgroup=no
1517 fi
1518 rm -f conftest*])
1519 AC_SUBST(libc_cv_Bgroup)
1520
1521 ASFLAGS_config=
1522 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1523                libc_cv_as_noexecstack, [dnl
1524 cat > conftest.c <<EOF
1525 void foo (void) { }
1526 EOF
1527 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1528                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1529    && grep -q .note.GNU-stack conftest.s \
1530    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1531                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1532 then
1533   libc_cv_as_noexecstack=yes
1534 else
1535   libc_cv_as_noexecstack=no
1536 fi
1537 rm -f conftest*])
1538 if test $libc_cv_as_noexecstack = yes; then
1539   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1540 fi
1541 AC_SUBST(ASFLAGS_config)
1542
1543 AC_CACHE_CHECK(for -z combreloc,
1544                libc_cv_z_combreloc, [dnl
1545 cat > conftest.c <<EOF
1546 extern int bar (int);
1547 extern int mumble;
1548 int foo (void) { return bar (mumble); }
1549 EOF
1550 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1551                         -fPIC -shared -o conftest.so conftest.c
1552                         -nostdlib -nostartfiles
1553                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1554 then
1555 dnl The following test is a bit weak.  We must use a tool which can test
1556 dnl cross-platform since the gcc used can be a cross compiler.  Without
1557 dnl introducing new options this is not easily doable.  Instead use a tool
1558 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1559 dnl look for a section named .rel.dyn.
1560   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1561     libc_cv_z_combreloc=yes
1562   else
1563     libc_cv_z_combreloc=no
1564   fi
1565 else
1566   libc_cv_z_combreloc=no
1567 fi
1568 rm -f conftest*])
1569 if test "$libc_cv_z_combreloc" = yes; then
1570   AC_DEFINE(HAVE_Z_COMBRELOC)
1571 fi
1572 AC_SUBST(libc_cv_z_combreloc)
1573
1574 AC_CACHE_CHECK(for -z execstack,
1575                libc_cv_z_execstack, [dnl
1576 cat > conftest.c <<EOF
1577 int _start (void) { return 42; }
1578 EOF
1579 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1580                             -fPIC -shared -o conftest.so conftest.c
1581                             -Wl,-z,execstack -nostdlib
1582                             1>&AS_MESSAGE_LOG_FD])
1583 then
1584   libc_cv_z_execstack=yes
1585 else
1586   libc_cv_z_execstack=no
1587 fi
1588 rm -f conftest*])
1589 AC_SUBST(libc_cv_z_execstack)
1590
1591 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1592 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1593 ])
1594
1595 AC_SUBST(libc_cv_fpie)
1596
1597 AC_CACHE_CHECK(for --hash-style option,
1598                libc_cv_hashstyle, [dnl
1599 cat > conftest.c <<EOF
1600 int _start (void) { return 42; }
1601 EOF
1602 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1603                             -fPIC -shared -o conftest.so conftest.c
1604                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1605 then
1606   libc_cv_hashstyle=yes
1607 else
1608   libc_cv_hashstyle=no
1609 fi
1610 rm -f conftest*])
1611 AC_SUBST(libc_cv_hashstyle)
1612
1613 # The linker's default -shared behavior is good enough if it
1614 # does these things that our custom linker scripts ensure that
1615 # all allocated NOTE sections come first.
1616 if test "$use_default_link" = default; then
1617   AC_CACHE_CHECK([for sufficient default -shared layout],
1618                   libc_cv_use_default_link, [dnl
1619   libc_cv_use_default_link=no
1620   cat > conftest.s <<\EOF
1621           .section .note.a,"a",%note
1622           .balign 4
1623           .long 4,4,9
1624           .string "GNU"
1625           .string "foo"
1626           .section .note.b,"a",%note
1627           .balign 4
1628           .long 4,4,9
1629           .string "GNU"
1630           .string "bar"
1631 EOF
1632   if AC_TRY_COMMAND([dnl
1633   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1634        ac_try=`$READELF -S conftest.so | sed -n \
1635          ['${x;p;}
1636           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1637           t a
1638           b
1639           : a
1640           H']`
1641   then
1642     libc_seen_a=no libc_seen_b=no
1643     set -- $ac_try
1644     while test $# -ge 2 -a "$1" = NOTE; do
1645       case "$2" in
1646       .note.a) libc_seen_a=yes ;;
1647       .note.b) libc_seen_b=yes ;;
1648       esac
1649       shift 2
1650     done
1651     case "$libc_seen_a$libc_seen_b" in
1652     yesyes)
1653       libc_cv_use_default_link=yes
1654       ;;
1655     *)
1656       echo >&AS_MESSAGE_LOG_FD "\
1657 $libc_seen_a$libc_seen_b from:
1658 $ac_try"
1659       ;;
1660     esac
1661   fi
1662   rm -f conftest*])
1663   use_default_link=$libc_cv_use_default_link
1664 fi
1665
1666 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1667 if libc_cv_output_format=`
1668 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1669 then
1670   :
1671 else
1672   libc_cv_output_format=
1673 fi
1674 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1675 AC_SUBST(libc_cv_output_format)
1676
1677 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1678 cat > conftest.c <<EOF
1679 int foo;
1680 EOF
1681 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1682                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1683 then
1684   libc_cv_fno_toplevel_reorder=yes
1685 else
1686   libc_cv_fno_toplevel_reorder=no
1687 fi
1688 rm -f conftest*])
1689 if test $libc_cv_fno_toplevel_reorder = yes; then
1690   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1691 else
1692   fno_unit_at_a_time=-fno-unit-at-a-time
1693 fi
1694 AC_SUBST(fno_unit_at_a_time)
1695
1696 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1697 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1698                    [libc_cv_ssp=yes],
1699                    [libc_cv_ssp=no])
1700 ])
1701 AC_SUBST(libc_cv_ssp)
1702
1703 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1704 cat > conftest.c <<EOF
1705 int foo;
1706 #ifdef __GNUC_GNU_INLINE__
1707 main () { return 0;}
1708 #else
1709 #error
1710 #endif
1711 EOF
1712 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1713                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1714 then
1715   libc_cv_gnu89_inline=yes
1716 else
1717   libc_cv_gnu89_inline=no
1718 fi
1719 rm -f conftest*])
1720 if test $libc_cv_gnu89_inline = yes; then
1721   gnu89_inline=-fgnu89-inline
1722 else
1723   gnu89_inline=
1724 fi
1725 AC_SUBST(gnu89_inline)
1726
1727 AC_CACHE_CHECK(whether cc puts quotes around section names,
1728                libc_cv_have_section_quotes,
1729                [cat > conftest.c <<EOF
1730                 static const int foo
1731                 __attribute__ ((section ("bar"))) = 1;
1732 EOF
1733                 if ${CC-cc} -S conftest.c -o conftest.s; then
1734                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1735                     libc_cv_have_section_quotes=yes
1736                   else
1737                     libc_cv_have_section_quotes=no
1738                   fi
1739                 else
1740                   libc_cv_have_section_quotes=unknown
1741                 fi
1742                 rm -f conftest.{c,s}
1743                 ])
1744 if test $libc_cv_have_section_quotes = yes; then
1745   AC_DEFINE(HAVE_SECTION_QUOTES)
1746 fi
1747
1748 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1749                [dnl
1750 cat > conftest.s <<EOF
1751 ${libc_cv_dot_text}
1752 .globl foo
1753 foo:
1754 .weak foo
1755 .weak bar; bar = foo
1756 EOF
1757 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1758   libc_cv_asm_weak_directive=yes
1759 else
1760   libc_cv_asm_weak_directive=no
1761 fi
1762 rm -f conftest*])
1763
1764 if test $libc_cv_asm_weak_directive = no; then
1765   AC_CACHE_CHECK(for assembler .weakext directive,
1766                  libc_cv_asm_weakext_directive,
1767                  [dnl
1768 cat > conftest.s <<EOF
1769 ${libc_cv_dot_text}
1770 .globl foo
1771 foo:
1772 .weakext bar foo
1773 .weakext baz
1774 .globl baz
1775 baz:
1776 EOF
1777   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1778     libc_cv_asm_weakext_directive=yes
1779   else
1780     libc_cv_asm_weakext_directive=no
1781   fi
1782   rm -f conftest*])
1783
1784 fi # no .weak
1785
1786 if test $libc_cv_asm_weak_directive = yes; then
1787   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1788 elif test $libc_cv_asm_weakext_directive = yes; then
1789   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1790 fi
1791
1792 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1793 case $machine in
1794   sparc/sparc64*) cfi_offset=2047;;
1795   *) cfi_offset=0;;
1796 esac
1797 cat > conftest.s <<EOF
1798         .text
1799         .type   func,%function
1800 func:
1801         .cfi_startproc
1802         .cfi_remember_state
1803         .cfi_rel_offset 1, $cfi_offset
1804         .cfi_endproc
1805 EOF
1806 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1807   libc_cv_asm_cfi_directives=yes
1808 else
1809   libc_cv_asm_cfi_directives=no
1810 fi
1811 rm -f conftest*])
1812 if test $libc_cv_asm_cfi_directives = yes; then
1813   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1814 fi
1815
1816 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1817 cat > conftest.c <<\EOF
1818 _start () {}
1819 int __eh_pc;
1820 __throw () {}
1821 EOF
1822 dnl No \ in command here because it ends up inside ''.
1823 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1824                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1825                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1826   libc_cv_ld_no_whole_archive=yes
1827 else
1828   libc_cv_ld_no_whole_archive=no
1829 fi
1830 rm -f conftest*])
1831 if test $libc_cv_ld_no_whole_archive = no; then
1832   AC_MSG_ERROR([support for --no-whole-archive is needed])
1833 fi
1834
1835 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1836 cat > conftest.c <<\EOF
1837 _start () {}
1838 int __eh_pc;
1839 __throw () {}
1840 EOF
1841 dnl No \ in command here because it ends up inside ''.
1842 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1843                             -nostdlib -nostartfiles -fexceptions
1844                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1845   libc_cv_gcc_exceptions=yes
1846 else
1847   libc_cv_gcc_exceptions=no
1848 fi
1849 rm -f conftest*])
1850 if test $libc_cv_gcc_exceptions = yes; then
1851   exceptions=-fexceptions
1852 fi
1853 AC_SUBST(exceptions)dnl
1854
1855 if test "$host_cpu" = powerpc ; then
1856 # Check for a bug present in at least versions 2.8.x of GCC
1857 # and versions 1.0.x of EGCS.
1858 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1859 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1860                libc_cv_c_asmcr0_bug='no',
1861                libc_cv_c_asmcr0_bug='yes')])
1862 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1863   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1864 fi
1865 fi
1866
1867 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1868 cat > conftest.c <<\EOF
1869 void zero (void *x)
1870 {
1871   __builtin_memset (x, 0, 1000);
1872 }
1873 EOF
1874 dnl
1875 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1876 then
1877   libc_cv_gcc_builtin_memset=no
1878 else
1879   libc_cv_gcc_builtin_memset=yes
1880 fi
1881 rm -f conftest* ])
1882 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1883   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1884 fi
1885
1886 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1887 cat > conftest.c <<\EOF
1888 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1889 char *foo (const char *a, const char *b)
1890 {
1891   return __builtin_strstr (a, b);
1892 }
1893 EOF
1894 dnl
1895 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1896 then
1897   libc_cv_gcc_builtin_redirection=yes
1898 else
1899   libc_cv_gcc_builtin_redirection=no
1900 fi
1901 rm -f conftest* ])
1902 if test "$libc_cv_gcc_builtin_redirection" = no; then
1903   AC_MSG_ERROR([support for the symbol redirection needed])
1904 fi
1905
1906 dnl Check whether the compiler supports the __thread keyword.
1907 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1908 [cat > conftest.c <<\EOF
1909 __thread int a = 42;
1910 EOF
1911 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1912   libc_cv_gcc___thread=yes
1913 else
1914   libc_cv_gcc___thread=no
1915 fi
1916 rm -f conftest*])
1917 if test "$libc_cv_gcc___thread" = no; then
1918   AC_MSG_ERROR([support for the __thread keyword is required])
1919 fi
1920
1921 dnl Check whether the compiler supports the tls_model attribute.
1922 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1923 cat > conftest.c <<\EOF
1924 extern __thread int a __attribute__((tls_model ("initial-exec")));
1925 EOF
1926 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1927   libc_cv_gcc_tls_model_attr=yes
1928 else
1929   libc_cv_gcc_tls_model_attr=no
1930 fi
1931 rm -f conftest*])
1932 if test "$libc_cv_gcc_tls_model_attr" = no; then
1933   AC_MSG_ERROR([support for the tls_model attribute is required])
1934 fi
1935
1936 dnl Determine how to disable generation of FMA instructions.
1937 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1938                libc_cv_cc_nofma, [dnl
1939 libc_cv_cc_nofma=
1940 for opt in -ffp-contract=off -mno-fused-madd; do
1941   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1942 done])
1943
1944 if test -n "$submachine"; then
1945   AC_CACHE_CHECK([for compiler option for CPU variant],
1946                  libc_cv_cc_submachine, [dnl
1947   libc_cv_cc_submachine=no
1948   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1949     LIBC_TRY_CC_OPTION([$opt], [
1950       libc_cv_cc_submachine="$opt"
1951       break], [])
1952   done])
1953   if test "x$libc_cv_cc_submachine" = xno; then
1954     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1955   fi
1956 fi
1957 AC_SUBST(libc_cv_cc_submachine)
1958
1959 dnl Check whether we have the gd library available.
1960 AC_MSG_CHECKING(for libgd)
1961 if test "$with_gd" != "no"; then
1962   old_CFLAGS="$CFLAGS"
1963   CFLAGS="$CFLAGS $libgd_include"
1964   old_LDFLAGS="$LDFLAGS"
1965   LDFLAGS="$LDFLAGS $libgd_ldflags"
1966   old_LIBS="$LIBS"
1967   LIBS="$LIBS -lgd -lpng -lz -lm"
1968   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1969   CFLAGS="$old_CFLAGS"
1970   LDFLAGS="$old_LDFLAGS"
1971   LIBS="$old_LIBS"
1972 else
1973   LIBGD=no
1974 fi
1975 AC_MSG_RESULT($LIBGD)
1976 AC_SUBST(LIBGD)
1977
1978 # SELinux detection
1979 if test x$with_selinux = xno ; then
1980   have_selinux=no;
1981 else
1982   # See if we have the SELinux library
1983   AC_CHECK_LIB(selinux, is_selinux_enabled,
1984                have_selinux=yes, have_selinux=no)
1985   # See if we have the SELinux header with the NSCD permissions in it.
1986   if test x$have_selinux = xyes ; then
1987     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1988     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1989                     [#ifdef NSCD__SHMEMHOST
1990                      return 0;
1991                      #else
1992                      #error NSCD__SHMEMHOST not defined
1993                      #endif],
1994                     have_selinux=yes, have_selinux=no)
1995     AC_MSG_RESULT($have_selinux)
1996   fi
1997
1998   if test x$with_selinux = xyes ; then
1999     if test x$have_selinux = xno ; then
2000       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2001     fi
2002   fi
2003 fi
2004 # Check if we're building with SELinux support.
2005 if test "x$have_selinux" = xyes; then
2006   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2007
2008   # See if we have the libaudit library
2009   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2010                have_libaudit=yes, have_libaudit=no)
2011   if test "x$have_libaudit" = xyes; then
2012     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2013   fi
2014   AC_SUBST(have_libaudit)
2015
2016   # See if we have the libcap library
2017   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2018   if test "x$have_libcap" = xyes; then
2019     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2020   fi
2021   AC_SUBST(have_libcap)
2022 fi
2023 AC_SUBST(have_selinux)
2024
2025 dnl check for the size of 'long double'.
2026 AC_CHECK_SIZEOF(long double, 0)
2027 sizeof_long_double=$ac_cv_sizeof_long_double
2028 AC_SUBST(sizeof_long_double)
2029
2030 CPPUNDEFS=
2031 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
2032 dnl Since we are building the implementations of the fortified functions here,
2033 dnl having the macro defined interacts very badly.
2034 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
2035 [AC_TRY_COMPILE([], [
2036 #ifdef _FORTIFY_SOURCE
2037 # error bogon
2038 #endif],
2039                 [libc_cv_predef_fortify_source=no],
2040                 [libc_cv_predef_fortify_source=yes])])
2041 if test $libc_cv_predef_fortify_source = yes; then
2042   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
2043 fi
2044 AC_SUBST(CPPUNDEFS)
2045
2046 dnl Check for silly hacked compilers inserting -fstack-protector.
2047 dnl This breaks badly for the early startup code we compile, since
2048 dnl the compiled code can refer to a magic machine-dependent location
2049 dnl for the canary value before we have sufficient setup for that to
2050 dnl work.  It's also questionable to build all of libc with this flag
2051 dnl even when you're doing that for most applications you build, since
2052 dnl libc's code is so heavily-used and performance-sensitive.  If we
2053 dnl ever really want to make that work, it should be enabled explicitly
2054 dnl in the libc build, not inherited from implicit compiler settings.
2055 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
2056                libc_cv_predef_stack_protector, [
2057 AC_TRY_COMPILE([extern void foobar (char *);],
2058                [char large_array[2048]; foobar (large_array);], [
2059 libc_undefs=`$NM -u conftest.o |
2060   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
2061     2>&AS_MESSAGE_LOG_FD` || {
2062   AC_MSG_ERROR([confusing output from $NM -u])
2063 }
2064 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
2065 # On some architectures, there are architecture-specific undefined
2066 # symbols (resolved by the linker), so filter out unknown symbols.
2067 # This will fail to produce the correct result if the compiler
2068 # defaults to -fstack-protector but this produces an undefined symbol
2069 # other than __stack_chk_fail.  However, compilers like that have not
2070 # been encountered in practice.
2071 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
2072 case "$libc_undefs" in
2073 foobar) libc_cv_predef_stack_protector=no ;;
2074 '__stack_chk_fail
2075 foobar') libc_cv_predef_stack_protector=yes ;;
2076 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
2077 esac],
2078                [AC_MSG_ERROR([test compilation failed])])
2079 ])
2080 libc_extra_cflags=
2081 if test $libc_cv_predef_stack_protector = yes; then
2082   libc_extra_cflags=-fno-stack-protector
2083 fi
2084 AC_SUBST(libc_extra_cflags)
2085
2086 ### End of automated tests.
2087 ### Now run sysdeps configure fragments.
2088
2089 # They also can set these variables.
2090 use_ldconfig=no
2091 ldd_rewrite_script=no
2092 libc_cv_sysconfdir=$sysconfdir
2093 libc_cv_localstatedir=$localstatedir
2094 libc_cv_gcc_unwind_find_fde=no
2095 libc_cv_idn=no
2096
2097 # Iterate over all the sysdep directories we will use, running their
2098 # configure fragments.
2099 for dir in $sysnames; do
2100   case $dir in
2101     /*) dest=$dir ;;
2102     *)  dest=$srcdir/$dir ;;
2103   esac
2104   if test -r $dest/configure; then
2105     AC_MSG_RESULT(running configure fragment for $dir)
2106     . $dest/configure
2107   fi
2108 done
2109
2110 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2111   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2112 fi
2113 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2114
2115 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2116 # configure fragment can override the value to prevent this AC_DEFINE.
2117 AC_SUBST(use_nscd)
2118 if test "x$use_nscd" != xno; then
2119   AC_DEFINE([USE_NSCD])
2120 fi
2121 if test "x$build_nscd" = xdefault; then
2122   build_nscd=$use_nscd
2123 fi
2124
2125 # Test for old glibc 2.0.x headers so that they can be removed properly
2126 # Search only in includedir.
2127 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2128 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2129 then
2130   old_glibc_headers=yes
2131 else
2132   old_glibc_headers=no
2133 fi
2134 AC_MSG_RESULT($old_glibc_headers)
2135 if test ${old_glibc_headers} = yes; then
2136   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2137   AC_MSG_WARN(*** be removed.)
2138 fi
2139 AC_SUBST(old_glibc_headers)
2140
2141 AC_SUBST(libc_cv_slibdir)
2142 AC_SUBST(libc_cv_localedir)
2143 AC_SUBST(libc_cv_sysconfdir)
2144 AC_SUBST(libc_cv_localstatedir)
2145 AC_SUBST(libc_cv_rootsbindir)
2146 AC_SUBST(libc_cv_forced_unwind)
2147
2148 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2149 AC_SUBST(libc_cv_cc_sse4)
2150 AC_SUBST(libc_cv_cc_avx)
2151 AC_SUBST(libc_cv_cc_sse2avx)
2152 AC_SUBST(libc_cv_cc_novzeroupper)
2153 AC_SUBST(libc_cv_cc_fma4)
2154 AC_SUBST(libc_cv_cc_nofma)
2155 AC_SUBST(libc_cv_as_i686)
2156 AC_SUBST(libc_cv_sparc_as_vis3)
2157
2158 if test x$use_ldconfig = xyes; then
2159   AC_DEFINE(USE_LDCONFIG)
2160 fi
2161 AC_SUBST(use_ldconfig)
2162 AC_SUBST(ldd_rewrite_script)
2163
2164 AC_SUBST(static)
2165 AC_SUBST(shared)
2166
2167 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2168 [libc_cv_pic_default=yes
2169 cat > conftest.c <<EOF
2170 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2171 # error PIC is default.
2172 #endif
2173 EOF
2174 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2175   libc_cv_pic_default=no
2176 fi
2177 rm -f conftest.*])
2178 AC_SUBST(libc_cv_pic_default)
2179
2180 AC_SUBST(profile)
2181 AC_SUBST(static_nss)
2182
2183 AC_SUBST(DEFINES)
2184
2185 dnl See sysdeps/mach/configure.in for this variable.
2186 AC_SUBST(mach_interface_list)
2187
2188 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2189 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2190 AC_SUBST(VERSION)
2191 AC_SUBST(RELEASE)
2192
2193 AC_CONFIG_FILES([config.make Makefile])
2194 AC_CONFIG_COMMANDS([default],[[
2195 case $CONFIG_FILES in *config.make*)
2196 echo "$config_vars" >> config.make;;
2197 esac
2198 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2199 AC_OUTPUT