sysdeps/unix/arm/sysdep.S

   1 /* Copyright (C) 1991,92,93,94,95,96,97,98 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Library General Public License as
   6    published by the Free Software Foundation; either version 2 of the
   7    License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Library General Public License for more details.
  13
  14    You should have received a copy of the GNU Library General Public
  15    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  16    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  17    Boston, MA 02111-1307, USA.  */
  18
  19 #include <sysdep.h>
  20 #define _ERRNO_H
  21 #include <bits/errno.h>
  22
  23 .globl C_SYMBOL_NAME(errno)
  24 .globl syscall_error
  25
  26 #undef syscall_error
  27 #ifdef NO_UNDERSCORES
  28 __syscall_error:
  29 #else
  30 syscall_error:
  31 #endif
  32 #if defined (EWOULDBLOCK_sys) && EWOULDBLOCK_sys != EAGAIN
  33         /* We translate the system's EWOULDBLOCK error into EAGAIN.
  34            The GNU C library always defines EWOULDBLOCK==EAGAIN.
  35            EWOULDBLOCK_sys is the original number.  */
  36         cmp r0, $EWOULDBLOCK_sys /* Is it the old EWOULDBLOCK?  */
  37         moveq r0, $EAGAIN       /* Yes; translate it to EAGAIN.  */
  38 #endif
  39
  40 #ifndef PIC
  41         ldr r1, _errno_loc
  42         str r0, [r1]
  43 #ifdef _LIBC_REENTRANT
  44         stmdb sp!, {r0, lr}
  45         /* put another copy of r0 at a specific errno location */
  46         bl C_SYMBOL_NAME(__errno_location)
  47         ldmia sp!, {r1, lr}
  48         str r1, [r0]
  49 #endif
  50 #else
  51         stmdb sp!,{r10, lr}
  52         @ we have to establish our PIC register
  53         ldr r10, 1f
  54         add r10, pc, r10
  55 0:      ldr r1, 2f
  56         ldr r1, [r10, r1]
  57         @ store a copy in _errno_loc
  58         str r0, [r1]
  59 #ifdef _LIBC_REENTRANT
  60         @ and another copy in thread copy of _errno_loc
  61         mov r10, r0
  62         bl __errno_location(PLT)
  63         str r10, [r0]
  64 #endif
  65         ldmia sp!, {r10, lr}
  66         b 4f
  67 1:      .word _GLOBAL_OFFSET_TABLE_ - 0b - 4
  68 2:      .word C_SYMBOL_NAME(errno)(GOT)
  69 4:
  70 #endif
  71         mvn r0, $0
  72         RETINSTR(mov, pc, r14)
  73
  74 #ifndef PIC
  75 _errno_loc:     .long C_SYMBOL_NAME(errno)
  76 #endif
  77
  78 #undef  __syscall_error
  79 END (__syscall_error)