sysdeps/unix/sysv/linux/s390/s390-32/mmap64.S

   1 /* Copyright (C) 2000-2014 Free Software Foundation, Inc.
   2    Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21 #define EINVAL  22
  22 #define ENOSYS  38
  23
  24         .text
  25 ENTRY(__mmap64)
  26         /* Save registers and setup stack frame.  */
  27         stm     %r6,%r15,24(%r15)
  28         cfi_offset (%r15, -36)
  29         cfi_offset (%r14, -40)
  30         cfi_offset (%r13, -44)
  31         cfi_offset (%r12, -48)
  32         cfi_offset (%r11, -52)
  33         cfi_offset (%r10, -56)
  34         cfi_offset (%r9, -60)
  35         cfi_offset (%r8, -64)
  36         cfi_offset (%r7, -68)
  37         cfi_offset (%r6, -72)
  38         lr      %r1,%r15
  39         ahi     %r15,-120               /* Buy stack space.   */
  40         cfi_adjust_cfa_offset (120)
  41         st      %r1,0(%r15)             /* Store back chain.  */
  42
  43         /* Store parameters on stack, because mmap2
  44          * takes only one parameter: a pointer to the parameter area.  */
  45         st      %r6,0x70(%r15)          /* Store 'fd'.      */
  46         st      %r5,0x6C(%r15)          /* Store 'flags'.   */
  47         st      %r4,0x68(%r15)          /* Store 'prot'.    */
  48         st      %r3,0x64(%r15)          /* Store 'length'.  */
  49         st      %r2,0x60(%r15)          /* Store 'start'.   */
  50
  51         lm      %r0,%r1,216(%r15)       /* Load 64 bit offset.  */
  52         tml     %r1,0x0fff              /* Offset page aligned ?  */
  53         jnz     2f                      /* No -> EINVAL.  */
  54         srdl    %r0,12                  /* mmap2 takes the offset in pages.  */
  55         ltr     %r0,%r0                 /* Offset > 2^44 ?  */
  56         jnz     2f
  57         st      %r1,0x74(%r15)          /* Store page offset.  */
  58
  59         la      %r2,0x60(%r15)          /* Load address of parameter list.  */
  60         svc     SYS_ify(mmap2)          /* Do the system call trap.  */
  61
  62         l       %r15,0(%r15)            /* Load back chain.  */
  63         cfi_adjust_cfa_offset (-120)
  64         lm      %r6,%r15,24(%r15)       /* Load registers.  */
  65
  66         /* Check gpr 2 for error.  */
  67         lhi     %r0,-4096
  68         clr     %r2,%r0
  69         jnl     SYSCALL_ERROR_LABEL
  70
  71         /* Successful; return the syscall's value.  */
  72         br      %r14
  73
  74 2:      lhi     %r2,-EINVAL
  75         l       %r15,0(%r15)            /* Load back chain.  */
  76         lm      %r6,%r15,24(%r15)       /* Load registers.  */
  77         j       SYSCALL_ERROR_LABEL
  78
  79 PSEUDO_END (__mmap64)
  80
  81 weak_alias (__mmap64, mmap64)