sysdeps/unix/sysv/linux/sh/sh3/swapcontext.S

   1 /* Save current context and install the given one.
   2    Copyright (C) 2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22 #include "ucontext_i.h"
  23
  24 /*  int __swapcontext (ucontext_t *ouc, const ucontext_t *uc);  */
  25
  26         .text
  27         .align  5
  28 ENTRY(__swapcontext)
  29
  30         /* Return value of getcontext.  R0 is the only register whose
  31            value is not preserved.  */
  32         mov     #0, r0
  33         mov.l   r0, @(oR0,r4)
  34         mov.l   r1, @(oR1,r4)
  35         mov.l   r2, @(oR2,r4)
  36         mov.l   r3, @(oR3,r4)
  37         mov.l   r4, @(oR4,r4)
  38         mov.l   r5, @(oR5,r4)
  39         mov.l   r6, @(oR6,r4)
  40         mov.l   r7, @(oR7,r4)
  41         mov     r4, r0
  42         add     #(oMACL+4), r0
  43         sts.l   macl, @-r0
  44         sts.l   mach, @-r0
  45         stc.l   gbr, @-r0
  46
  47         /* Save T flag to SR.  */
  48         movt    r1
  49         mov.l   r1, @-r0
  50         sts.l   pr, @-r0
  51
  52         /* The return address of getcontext is the restart pc.  */
  53         sts.l   pr, @-r0
  54
  55         mov.l   r15, @-r0
  56         mov.l   r14, @-r0
  57         mov.l   r13, @-r0
  58         mov.l   r12, @-r0
  59         mov.l   r11, @-r0
  60         mov.l   r10, @-r0
  61         mov.l   r9, @-r0
  62         mov.l   r8, @-r0
  63
  64         mov     r5, r8
  65
  66         /* sigprocmask (SIG_SETMASK, &uc->uc_sigmask, &ouc->uc_sigmask).  */
  67         add     #oSIGMASK, r5
  68         mov     r4, r6
  69         add     #oSIGMASK, r6
  70         mov     #SIG_SETMASK, r4
  71         mov     #+SYS_ify(sigprocmask), r3
  72         trapa   #0x13
  73         mov     r0, r1
  74         mov     #-12, r2
  75         shad    r2, r1
  76         not     r1, r1                  // r1=0 means r0 = -1 to -4095
  77         tst     r1, r1                  // i.e. error in linux
  78         bf      .Lswapcontext_restore
  79 .Lsyscall_error:
  80         SYSCALL_ERROR_HANDLER
  81 .Lpseudo_end:
  82         rts
  83          nop
  84 .Lswapcontext_restore:
  85         mov     r8, r0
  86         add     #(oPC), r0
  87         mov.l   @r0+, r2
  88         lds.l   @r0+, pr
  89
  90         /* Restore T frag.  */
  91         mov.l   @r0+, r1
  92         shlr    r1
  93         /* Skip GBR which is used for thread pointer.  */
  94         add     #4, r0
  95
  96         lds.l   @r0+, mach
  97         lds.l   @r0+, macl
  98
  99         mov     r8, r0
 100         add     #(oR9), r0
 101         mov.l   @r0+, r9
 102         mov.l   @r0+, r10
 103         mov.l   @r0+, r11
 104         mov.l   @r0+, r12
 105         mov.l   @r0+, r13
 106         mov.l   @r0+, r14
 107         mov.l   @r0+, r15
 108
 109         mov     r8, r0
 110         mov.l   @(oR0,r0), r1
 111         mov.l   r1, @-r15
 112         cfi_adjust_cfa_offset(4)
 113         cfi_rel_offset (r1, 0)
 114         mov.l   r2, @-r15
 115         cfi_adjust_cfa_offset(4)
 116         cfi_rel_offset (r2, 0)
 117
 118         mov.l   @(oR1,r0), r1
 119         mov.l   @(oR2,r0), r2
 120         mov.l   @(oR3,r0), r3
 121         mov.l   @(oR4,r0), r4
 122         mov.l   @(oR5,r0), r5
 123         mov.l   @(oR6,r0), r6
 124         mov.l   @(oR7,r0), r7
 125         mov.l   @(oR8,r0), r8
 126         mov.l   @r15+, r0
 127         jmp     @r0
 128          mov.l  @r15+, r0
 129
 130 PSEUDO_END(__swapcontext)
 131
 132 weak_alias (__swapcontext, swapcontext)