sysdeps/sparc/sparc64/sparcv9v/memset.S

   1 /* Set a block of memory to some byte value.  For SUN4V Niagara.
   2    Copyright (C) 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by David S. Miller (davem@davemloft.net)
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22
  23 #define ASI_BLK_INIT_QUAD_LDD_P 0xe2
  24 #define ASI_P                   0x80
  25 #define ASI_PNF                 0x82
  26
  27 #ifndef XCC
  28 #define USE_BPR
  29 #define XCC xcc
  30 #endif
  31
  32         .register       %g2,#scratch
  33
  34         .text
  35         .align          32
  36
  37 ENTRY(memset)
  38         /* %o0=buf, %o1=pat, %o2=len */
  39         and             %o1, 0xff, %o3
  40         mov             %o2, %o1
  41         sllx            %o3, 8, %g1
  42         or              %g1, %o3, %o2
  43         sllx            %o2, 16, %g1
  44         or              %g1, %o2, %o2
  45         sllx            %o2, 32, %g1
  46         ba,pt           %XCC, 1f
  47          or             %g1, %o2, %o2
  48 END(memset)
  49
  50 ENTRY(__bzero)
  51         clr             %o2
  52 1:      brz,pn          %o1, 90f
  53          mov            %o0, %o3
  54
  55         wr              %g0, ASI_P, %asi
  56
  57         cmp             %o1, 15
  58         bl,pn           %icc, 70f
  59          andcc          %o0, 0x7, %g1
  60         be,pt           %XCC, 2f
  61          mov            8, %g2
  62         sub             %g2, %g1, %g1
  63         sub             %o1, %g1, %o1
  64 1:      stba            %o2, [%o0 + 0x00] %asi
  65         subcc           %g1, 1, %g1
  66         bne,pt          %XCC, 1b
  67          add            %o0, 1, %o0
  68 2:      cmp             %o1, 128
  69         bl,pn           %icc, 60f
  70          andcc          %o0, (64 - 1), %g1
  71         be,pt           %XCC, 40f
  72          mov            64, %g2
  73         sub             %g2, %g1, %g1
  74         sub             %o1, %g1, %o1
  75 1:      stxa            %o2, [%o0 + 0x00] %asi
  76         subcc           %g1, 8, %g1
  77         bne,pt          %XCC, 1b
  78          add            %o0, 8, %o0
  79
  80 40:
  81         wr              %g0, ASI_BLK_INIT_QUAD_LDD_P, %asi
  82         andn            %o1, (64 - 1), %g1
  83         sub             %o1, %g1, %o1
  84 50:
  85         stxa            %o2, [%o0 + 0x00] %asi
  86         stxa            %o2, [%o0 + 0x08] %asi
  87         stxa            %o2, [%o0 + 0x10] %asi
  88         stxa            %o2, [%o0 + 0x18] %asi
  89         stxa            %o2, [%o0 + 0x20] %asi
  90         stxa            %o2, [%o0 + 0x28] %asi
  91         stxa            %o2, [%o0 + 0x30] %asi
  92         stxa            %o2, [%o0 + 0x38] %asi
  93         subcc           %g1, 64, %g1
  94         bne,pt          %XCC, 50b
  95          add            %o0, 64, %o0
  96
  97         wr              %g0, ASI_P, %asi
  98         brz,pn          %o1, 80f
  99 60:
 100          andncc         %o1, 0x7, %g1
 101         be,pn           %XCC, 2f
 102          sub            %o1, %g1, %o1
 103 1:      stxa            %o2, [%o0 + 0x00] %asi
 104         subcc           %g1, 8, %g1
 105         bne,pt          %XCC, 1b
 106          add            %o0, 8, %o0
 107 2:      brz,pt          %o1, 80f
 108          nop
 109
 110 70:
 111 1:      stba            %o2, [%o0 + 0x00] %asi
 112         subcc           %o1, 1, %o1
 113         bne,pt          %icc, 1b
 114          add            %o0, 1, %o0
 115
 116         /* fallthrough */
 117
 118 80:
 119         wr              %g0, ASI_PNF, %asi
 120
 121 90:
 122         retl
 123          mov            %o3, %o0
 124 END(__bzero)
 125
 126 libc_hidden_builtin_def (memset)
 127 weak_alias (__bzero, bzero)