sysdeps/sparc/sparc64/elf/start.S

   1 /* Startup code for elf64-sparc
   2    Copyright (C) 1997, 1998, 2002, 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Richard Henderson <richard@gnu.ai.mit.edu>, 1997.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    In addition to the permissions in the GNU Lesser General Public
  12    License, the Free Software Foundation gives you unlimited
  13    permission to link the compiled version of this file with other
  14    programs, and to distribute those programs without any restriction
  15    coming from the use of this file. (The GNU Lesser General Public
  16    License restrictions do apply in other respects; for example, they
  17    cover modification of the file, and distribution when not linked
  18    into another program.)
  19
  20    Note that people who make modified versions of this file are not
  21    obligated to grant this special exception for their modified
  22    versions; it is their choice whether to do so. The GNU Lesser
  23    General Public License gives permission to release a modified
  24    version without this exception; this exception also makes it
  25    possible to release a modified version which carries forward this
  26    exception.
  27
  28    The GNU C Library is distributed in the hope that it will be useful,
  29    but WITHOUT ANY WARRANTY; without even the implied warranty of
  30    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  31    Lesser General Public License for more details.
  32
  33    You should have received a copy of the GNU Lesser General Public
  34    License along with the GNU C Library; if not, write to the Free
  35    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  36    02111-1307 USA.  */
  37
  38 #include <sysdep.h>
  39
  40
  41         .section ".text"
  42         .align 4
  43 #ifdef SHARED
  44 .LLGETPC0:
  45         retl
  46          add    %o7, %l7, %l7
  47 #endif
  48         .global _start
  49         .type _start,#function
  50 _start:
  51         cfi_startproc
  52
  53 #ifdef SHARED
  54         sethi   %hi(_GLOBAL_OFFSET_TABLE_-4), %l7
  55         call    .LLGETPC0
  56          add    %l7, %lo(_GLOBAL_OFFSET_TABLE_+4), %l7
  57 #endif
  58
  59   /* Terminate the stack frame, and reserve space for functions to
  60      drop their arguments.  */
  61         mov     %g0, %fp
  62         sub     %sp, 6*8, %sp
  63         cfi_adjust_cfa_offset(6*8)
  64
  65   /* Extract the arguments and environment as encoded on the stack.  The
  66      argument info starts after one register window (16 words) past the SP,
  67      plus the bias we added, plus the magic v9 STACK_BIAS.  */
  68         ldx     [%sp+STACK_BIAS+22*8], %o1
  69         add     %sp, STACK_BIAS+23*8, %o2
  70
  71   /* Load the addresses of the user entry points.  */
  72         sethi   %hi(main), %o0
  73         sethi   %hi(__libc_csu_init), %o3
  74         sethi   %hi(__libc_csu_fini), %o4
  75         or      %o0, %lo(main), %o0
  76         or      %o3, %lo(__libc_csu_init), %o3
  77         or      %o4, %lo(__libc_csu_fini), %o4
  78 #ifdef SHARED
  79         ldx     [%l7 + %o0], %o0
  80         ldx     [%l7 + %o3], %o3
  81         ldx     [%l7 + %o4], %o4
  82 #endif
  83
  84   /* When starting a binary via the dynamic linker, %g1 contains the
  85      address of the shared library termination function, which will be
  86      registered with atexit().  If we are statically linked, this will
  87      be NULL.  */
  88         mov     %g1, %o5
  89
  90   /* Let libc do the rest of the initialization, and call main.  */
  91         call    __libc_start_main
  92          nop
  93
  94   /* Die very horribly if exit returns.  */
  95         illtrap 0
  96
  97         cfi_endproc
  98
  99         .size _start, .-_start
 100
 101 /* Define a symbol for the first piece of initialized data.  */
 102         .data
 103         .globl  __data_start
 104 __data_start:
 105 weak_alias (__data_start, data_start)