sysdeps/i386/i586/memset.S

   1 /* memset/bzero -- set memory area to CH/0
   2    Highly optimized version for ix86, x>=5.
   3    Copyright (C) 1996, 1997, 2000, 2003, 2005 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Torbjorn Granlund, <tege@matematik.su.se>
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <sysdep.h>
  23 #include "asm-syntax.h"
  24 #include "bp-sym.h"
  25 #include "bp-asm.h"
  26
  27 /* BEWARE: `#ifdef memset' means that memset is redefined as `bzero' */
  28 #define BZERO_P (defined memset)
  29
  30 #define PARMS   LINKAGE+4       /* space for 1 saved reg */
  31 #define RTN     PARMS
  32 #define DEST    RTN+RTN_SIZE
  33 #if BZERO_P
  34 # define LEN    DEST+PTR_SIZE
  35 #else
  36 # define CHR    DEST+PTR_SIZE
  37 # define LEN    CHR+4
  38 #endif
  39
  40         .text
  41 ENTRY (BP_SYM (memset))
  42         ENTER
  43
  44         pushl   %edi
  45         cfi_adjust_cfa_offset (4)
  46
  47         movl    DEST(%esp), %edi
  48         cfi_rel_offset (edi, 0)
  49         movl    LEN(%esp), %edx
  50         CHECK_BOUNDS_BOTH_WIDE (%edi, DEST(%esp), %edx)
  51 #if BZERO_P
  52         xorl    %eax, %eax      /* we fill with 0 */
  53 #else
  54         movb    CHR(%esp), %al
  55         movb    %al, %ah
  56         movl    %eax, %ecx
  57         shll    $16, %eax
  58         movw    %cx, %ax
  59 #endif
  60         cld
  61
  62 /* If less than 36 bytes to write, skip tricky code (it wouldn't work).  */
  63         cmpl    $36, %edx
  64         movl    %edx, %ecx      /* needed when branch is taken! */
  65         jl      L(2)
  66
  67 /* First write 0-3 bytes to make the pointer 32-bit aligned.  */
  68         movl    %edi, %ecx      /* Copy ptr to ecx... */
  69         negl    %ecx            /* ...and negate that and... */
  70         andl    $3, %ecx        /* ...mask to get byte count.  */
  71         subl    %ecx, %edx      /* adjust global byte count */
  72         rep
  73         stosb
  74
  75         subl    $32, %edx       /* offset count for unrolled loop */
  76         movl    (%edi), %ecx    /* Fetch destination cache line */
  77
  78         .align  2, 0x90         /* supply 0x90 for broken assemblers */
  79 L(1):   movl    28(%edi), %ecx  /* allocate cache line for destination */
  80         subl    $32, %edx       /* decr loop count */
  81         movl    %eax, 0(%edi)   /* store words pairwise */
  82         movl    %eax, 4(%edi)
  83         movl    %eax, 8(%edi)
  84         movl    %eax, 12(%edi)
  85         movl    %eax, 16(%edi)
  86         movl    %eax, 20(%edi)
  87         movl    %eax, 24(%edi)
  88         movl    %eax, 28(%edi)
  89         leal    32(%edi), %edi  /* update destination pointer */
  90         jge     L(1)
  91
  92         leal    32(%edx), %ecx  /* reset offset count */
  93
  94 /* Write last 0-7 full 32-bit words (up to 8 words if loop was skipped).  */
  95 L(2):   shrl    $2, %ecx        /* convert byte count to longword count */
  96         rep
  97         stosl
  98
  99 /* Finally write the last 0-3 bytes.  */
 100         movl    %edx, %ecx
 101         andl    $3, %ecx
 102         rep
 103         stosb
 104
 105 #if !BZERO_P
 106         /* Load result (only if used as memset).  */
 107         movl DEST(%esp), %eax   /* start address of destination is result */
 108         RETURN_BOUNDED_POINTER (DEST(%esp))
 109 #endif
 110         popl    %edi
 111         cfi_adjust_cfa_offset (-4)
 112         cfi_restore (edi)
 113
 114         LEAVE
 115 #if BZERO_P
 116         ret
 117 #else
 118         RET_PTR
 119 #endif
 120 END (BP_SYM (memset))
 121 libc_hidden_builtin_def (memset)