powerpc-cpu/sysdeps/powerpc/powerpc32/powerpc64/fpu/s_llround.S

   1 /* llround function.  PowerPC32 on PowerPC64 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21 #include <math_ldbl_opt.h>
  22
  23         .section        .rodata.cst8,"aM",@progbits,8
  24         .align  2
  25 .LC0:   /* 0.0 */
  26         .long 0x00000000
  27 .LC1:   /* 0.5 */
  28         .long 0x3f000000
  29
  30         .section        ".text"
  31
  32 /* long [r3] lround (float x [fp1])
  33    IEEE 1003.1 lround function.  IEEE specifies "round to the nearest
  34    integer value, rounding halfway cases away from zero, regardless of
  35    the current rounding mode."  However PowerPC Architecture defines
  36    "round to Nearest" as "Choose the best approximation. In case of a
  37    tie, choose the one that is even (least significant bit o).".
  38    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  39    "round toward Zero" mode and round by adding +-0.5 before rounding
  40    to the integer value.  */
  41
  42 ENTRY (__llround)
  43         stwu    r1,-16(r1)
  44         cfi_adjust_cfa_offset (16)
  45 #ifdef SHARED
  46         mflr    r11
  47         cfi_register(lr,r11)
  48 # ifdef HAVE_ASM_PPC_REL16
  49         bcl     20,31,1f
  50 1:      mflr    r9
  51         addis   r9,r9,.LC0-1b@ha
  52         addi    r9,r9,.LC0-1b@l
  53 # else
  54         bl      _GLOBAL_OFFSET_TABLE_@local-4
  55         mflr    r10
  56         lwz     r9,.LC0@got(10)
  57 # endif
  58         mtlr    r11
  59         cfi_same_value (lr)
  60         lfs     fp12,0(r9)
  61         lfs     fp10,.LC1-.LC0(r9)
  62 #else
  63         lis     r9,.LC0@ha
  64         lis     r10,.LC1@ha
  65         lfs     fp12,.LC0@l(r9)
  66         lfs     fp10,.LC1@l(r10)
  67 #endif
  68         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  69         ble-    cr6,.L4
  70         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  71 .L9:
  72         fctidz  fp2,fp1         /* Convert To Integer DW round toward 0.  */
  73         stfd    fp2,8(r1)
  74         nop     /* Ensure the following load is in a different dispatch  */
  75         nop     /* group to avoid pipe stall on POWER4&5.  */
  76         nop
  77         lwz     r4,12(r1)
  78         lwz     r3,8(r1)
  79         addi    r1,r1,16
  80         blr
  81 .L4:
  82         fsub    fp1,fp1,fp10    /* x-= 0.5;  */
  83         b       .L9
  84         END (__llround)
  85
  86 weak_alias (__llround, llround)
  87
  88 strong_alias (__llround, __llroundf)
  89 weak_alias (__llround, llroundf)
  90
  91 #ifdef NO_LONG_DOUBLE
  92 weak_alias (__llround, llroundl)
  93 strong_alias (__llround, __llroundl)
  94 #endif
  95 #if LONG_DOUBLE_COMPAT(libm, GLIBC_2_1)
  96 compat_symbol (libm, __llround, llroundl, GLIBC_2_1)
  97 #endif