configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.2)dnl               dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21
  22 dnl Arguments to specify presence of other packages/features.
  23 AC_ARG_WITH(fp, dnl
  24   --with-fp               if using floating-point hardware,
  25             with_fp=$withval, with_fp=yes)
  26 AC_ARG_WITH(gnu-binutils, dnl
  27   --with-gnu-binutils     if using GNU binutils (as and ld),
  28             gnu_binutils=$withval, gnu_binutils=no)
  29 AC_ARG_WITH(gnu-ld, dnl
  30   --with-gnu-ld           if using GNU ld (in the binutils package),
  31             gnu_ld=$withval, gnu_ld=no)
  32 AC_ARG_WITH(gnu-as, dnl
  33   --with-gnu-as           if using GNU as (in the binutils package),
  34             gnu_as=$withval, gnu_as=no)
  35 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  36 AC_ARG_WITH(elf, dnl
  37   --with-elf              if using the ELF object format,
  38             elf=$withval, elf=no)
  39 AC_ARG_WITH(weak-symbols, dnl
  40   --with-weak-symbols     if weak symbols are available in as and ld,
  41             weak=$withval, weak=no)
  42
  43 dnl Arguments to enable or disable building the shared, profiled, and
  44 dnl -fomit-frame-pointer libraries.
  45 AC_ARG_ENABLE(shared, dnl
  46 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  47             shared=$enableval, shared=default)
  48 AC_ARG_ENABLE(profile, dnl
  49 [  --enable-profile        build profiled library [default=yes]],
  50             profile=$enableval, profile=yes)
  51 AC_ARG_ENABLE(omitfp, dnl
  52 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  53             omitfp=$enableval, omitfp=no)
  54
  55 AC_CANONICAL_HOST
  56 # We keep the original values in `$config_*' and never modify them, so we
  57 # can write them unchanged into config.make.  Everything else uses
  58 # $machine, $vendor, and $os, and changes them whenever convenient.
  59 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  60
  61 sysdep_dir=$srcdir/sysdeps
  62 AC_MSG_CHECKING(sysdep dirs)
  63 AC_CACHE_VAL(libc_cv_sysdirs, [dnl
  64 machine=$config_machine
  65 vendor=$config_vendor
  66 os=$config_os
  67
  68 dnl We need to use [ and ] for other purposes for a while now.
  69 changequote(,)dnl
  70 # Expand the configuration machine name into a subdirectory by architecture
  71 # type and particular chip.
  72 case "$machine" in
  73 i[345]86)
  74   machine=i386/$machine ;;
  75 sparc[6789])
  76   machine=sparc/$machine ;;
  77 m68k)
  78   machine=m68k/m68020 ;;
  79 m680?0)
  80   machine=m68k/$machine ;;
  81 m88k)
  82   machine=m88k/m88100 ;;
  83 m88???)
  84   machine=m88k/$machine ;;
  85 mips64*)
  86   machine=mips/mips64/$machine ;;
  87 mips*)
  88   machine=mips/$machine ;;
  89 esac
  90
  91 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
  92 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
  93
  94 case "$os" in
  95 gnu*)
  96   base_os=mach/hurd ;;
  97 netbsd* | 386bsd* | freebsd* | bsdi*)
  98   base_os=unix/bsd/bsd4.4 ;;
  99 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 100   base_os=unix/bsd ;;
 101 linux* | sysv* | isc* | esix* | sco* | minix* | irix4*)
 102   base_os=unix/sysv ;;
 103 solaris[2-9]*)
 104   base_os=unix/sysv/sysv4 ;;
 105 none)
 106   base_os=standalone ;;
 107 *)
 108   base_os='' ;;
 109 esac
 110
 111 # Some configurations imply other options.
 112 case "$os" in
 113 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 114   # These systems always use GNU tools.
 115   gnu_ld=yes gnu_as=yes
 116 esac
 117 case "$os" in
 118 gnu*elf* | linux* | sysv4* | solaris2*)
 119   # These systems always use the ELF format.
 120   elf=yes
 121 esac
 122
 123
 124 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 125 tail=$os
 126 ostry=$os
 127 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 128   ostry="$ostry /$o"
 129   tail=$o
 130 done
 131 o=`echo $tail | sed 's/[0-9]*$//'`
 132 if test $o != $tail; then
 133   ostry="$ostry /$o"
 134 fi
 135
 136 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 137 base=
 138 tail=$base_os
 139 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 140   set $b
 141   base="$base /$1"
 142   tail="$2"
 143 done
 144
 145 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 146 mach=
 147 tail=$machine
 148 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 149   set $m
 150   # If using ELF, look for an `elf' subdirectory of each machine directory.
 151   if test "$elf" = yes; then
 152     mach="$mach /$1/elf"
 153   fi
 154   mach="$mach /$1"
 155   tail="$2"
 156 done
 157
 158 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 159 changequote([,])dnl
 160
 161 # Find what sysdep directories exist.
 162 sysnames=
 163 for b in $base ''; do
 164   for m0 in $mach ''; do
 165     for v in /$vendor ''; do
 166       for o in /$ostry ''; do
 167         for m in $mach ''; do
 168           try="$m0$b$v$o$m"
 169           if test -d $sysdep_dir$try; then
 170             sysnames="$sysnames $try"
 171             { test -n "$o" || test -n "$b"; } && os_used=t
 172             { test -n "$m" || test -n "$m0"; } && machine_used=t
 173           fi
 174         done
 175       done
 176     done
 177   done
 178 done
 179
 180 if test -z "$os_used" && test "$os" != none; then
 181   AC_MSG_ERROR(Operating system $os is not supported.)
 182 fi
 183 if test -z "$machine_used" && test "$machine" != none; then
 184   AC_MSG_ERROR(The $machine is not supported.)
 185 fi
 186
 187 # We have now validated the configuration.
 188
 189
 190 # Remove the leading slashes.
 191 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 192
 193 # Prepend the machine's FPU directory unless --without-fp.
 194 if test "$with_fp" = yes; then
 195   fpu_dirs=
 196   for m in $mach; do
 197     if test -d $sysdep_dir$m/fpu; then
 198       fpu_dirs="$fpu_dirs $m/fpu"
 199     fi
 200   done
 201   sysnames="`echo $fpu_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 202 fi
 203
 204
 205
 206 # Expand the list of system names into a full list of directories
 207 # from each element's parent name and Implies file (if present).
 208 set $sysnames
 209 while test $# -gt 0; do
 210   name=$1
 211   shift
 212
 213   if test -f $sysdep_dir/$name/Implies; then
 214     # Collect more names from the `Implies' file (removing comments).
 215     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 216     for x in $implied; do
 217       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 218     done
 219   else
 220     implied=
 221   fi
 222
 223   # Add NAME to the list of names.
 224   names="$names $name"
 225
 226   # Find the parent of NAME, using the empty string if it has none.
 227 changequote(,)dnl
 228   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 229 changequote([,])dnl
 230
 231   # Add the names implied by NAME, and NAME's parent (if it has one), to
 232   # the list of names to be processed (the argument list).  We prepend the
 233   # implied names to the list and append the parent.  We want implied
 234   # directories to come before further directories inferred from the
 235   # configuration components; this ensures that for sysv4, unix/common
 236   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 237   # after sysv4).
 238   sysnames="`echo $implied $* $parent`"
 239   test -n "$sysnames" && set $sysnames
 240 done
 241
 242 # Add the default directories.
 243 names="$names generic stub"
 244
 245 # Now uniquize the list.
 246 seen=
 247 sysnames=
 248 for name in $names; do
 249   if echo "$seen" | fgrep -x $name >/dev/null; then
 250     # Already in the list.
 251     true;
 252   else
 253     # A new one.
 254     if test -z "$seen"; then
 255       seen="$name" sysnames="$name"
 256     else
 257       seen="$seen
 258 $name"
 259       sysnames="$sysnames $name"
 260     fi
 261   fi
 262 done
 263 libc_cv_sysdirs="$sysnames"])
 264 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 265 AC_MSG_RESULT(${sysnames})
 266
 267 AC_PROG_INSTALL
 268 if test "$INSTALL" = "${srcdir}/install-sh"; then
 269   # The makefiles need to use a different form to find it in $srcdir.
 270   INSTALL='$(..)./install-sh'
 271 fi
 272
 273 AC_CHECK_TOOL(CC, gcc)
 274 AC_CHECK_TOOL(AR, ar)
 275 AC_CHECK_TOOL(RANLIB, ranlib, :)
 276 AC_PROG_CPP
 277
 278 AC_MSG_CHECKING(signed size_t type)
 279 AC_CACHE_VAL(libc_cv_signed_size_t, [dnl
 280 echo '#include <stddef.h>
 281 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 282 if eval "$ac_cpp conftest.c 2>/dev/null" \
 283 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 284   libc_cv_signed_size_t=no
 285 else
 286   libc_cv_signed_size_t=yes
 287 fi
 288 rm -f conftest*])
 289 AC_MSG_RESULT($libc_cv_signed_size_t)
 290 if test $libc_cv_signed_size_t = yes; then
 291   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 292   cat >> confdefs.h <<\EOF
 293 #undef __SIZE_TYPE__
 294 #define __SIZE_TYPE__ unsigned
 295 EOF
 296 fi
 297
 298 AC_MSG_CHECKING(libc-friendly stddef.h)
 299 AC_CACHE_VAL(libc_cv_friendly_stddef, [dnl
 300 AC_TRY_COMPILE(dnl
 301 [#define __need_size_t
 302 #define __need_wchar_t
 303 #include <stddef.h>
 304 #define __need_NULL
 305 #include <stddef.h>], [size_t size; wchar_t wchar;
 306 #ifdef offsetof
 307 #error stddef.h ignored __need_*
 308 #endif
 309 if (&size == NULL || &wchar == NULL) abort ();],
 310                libc_cv_friendly_stddef=yes,
 311                libc_cv_friendly_stddef=no)])
 312 AC_MSG_RESULT($libc_cv_friendly_stddef)
 313 if test $libc_cv_friendly_stddef = yes; then
 314   config_vars="$config_vars
 315 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 316 fi
 317
 318 AC_MSG_CHECKING(whether we need to use -P to assemble .S files)
 319 AC_CACHE_VAL(libc_cv_need_minus_P, [dnl
 320 cat > conftest.S <<EOF
 321 #include "confdefs.h"
 322 /* Nothing whatsoever.  */
 323 EOF
 324 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 325   libc_cv_need_minus_P=no
 326 else
 327   libc_cv_need_minus_P=yes
 328 fi
 329 rm -f conftest*])
 330 AC_MSG_RESULT($libc_cv_need_minus_P)
 331 if test $libc_cv_need_minus_P = yes; then
 332   config_vars="$config_vars
 333 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 334 fi
 335
 336 AC_MSG_CHECKING(for .set assembler directive)
 337 AC_CACHE_VAL(libc_cv_asm_set_directive, [dnl
 338 cat > conftest.s <<\EOF
 339 .text
 340 foo: .long 0
 341 .set bar,foo
 342 EOF
 343 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 344   libc_cv_asm_set_directive=yes
 345 else
 346   libc_cv_asm_set_directive=no
 347 fi
 348 rm -f conftest*])
 349 AC_MSG_RESULT($libc_cv_asm_set_directive)
 350 if test $libc_cv_asm_set_directive = yes; then
 351   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 352 fi
 353
 354 AC_MSG_CHECKING(for assembler global-symbol directive)
 355 AC_CACHE_VAL(libc_cv_asm_global_directive, [dnl
 356 libc_cv_asm_global_directive=UNKNOWN
 357 for ac_globl in .globl .global; do
 358   cat > conftest.s <<EOF
 359 .text
 360 ${ac_globl} foo
 361 foo: .long 0
 362 EOF
 363   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 364     libc_cv_asm_global_directive=${ac_globl}
 365   fi
 366   rm -f conftest*
 367   test $libc_cv_asm_global_directive != UNKNOWN && break
 368 done])
 369 AC_MSG_RESULT($libc_cv_asm_global_directive)
 370 if test $libc_cv_asm_global_directive = UNKNOWN; then
 371   AC_MSG_ERROR(cannot determine asm global directive)
 372 else
 373   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 374 fi
 375
 376
 377 # sysdeps configure fragments may set these with files to be linked below.
 378 libc_link_dests=
 379 libc_link_sources=
 380
 381 # Iterate over all the sysdep directories we will use, running their
 382 # configure fragments, and looking for a uname implementation.
 383 uname=
 384 for dir in $sysnames; do
 385   if test -r $sysdep_dir/$dir/configure; then
 386     AC_MSG_RESULT(running configure fragment for $dir)
 387     . $sysdep_dir/$dir/configure
 388   fi
 389   if test -z "$uname"; then
 390     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
 391     && uname=$dir
 392   fi
 393 done
 394
 395 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 396
 397 # If we will use the generic uname implementation, we must figure out what
 398 # it will say by examining the system, and write the results in config-name.h.
 399 if test "$uname" = generic; then
 400
 401 changequote(,)dnl
 402   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 403 changequote([,])dnl
 404   if test $uname_sysname != $config_os; then
 405     config_release=`echo $config_os | sed s/$uname_sysname//`
 406   fi
 407 dnl
 408 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 409     if test -r /vmunix; then
 410       kernel_id=`strings /vmunix | grep UNIX`
 411     elif test -r /dynix; then
 412       kernel_id=`strings /dynix | grep DYNIX`
 413     else
 414       kernel_id=
 415     fi
 416 ])dnl
 417
 418   AC_MSG_CHECKING(OS release for uname)
 419   AC_CACHE_VAL(libc_cv_uname_release, [dnl
 420 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 421 changequote(,)dnl
 422   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 423 changequote([,])dnl
 424   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 425          != x$config_release; then
 426     # The configuration release is a substring of the kernel release.
 427     libc_cv_uname_release=$kernel_release
 428   elif test x$config_release != x; then
 429     libc_cv_uname_release=$config_release
 430   elif test x$kernel_release != x; then
 431     libc_cv_uname_release=$kernel_release
 432   else
 433     libc_cv_uname_release=unknown
 434   fi])
 435   AC_MSG_RESULT($libc_cv_uname_release)
 436   uname_release="$libc_cv_uname_release"
 437
 438   AC_MSG_CHECKING(OS version for uname)
 439   AC_CACHE_VAL(libc_cv_uname_version, [dnl
 440 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 441 changequote(,)dnl
 442   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 443 changequote([,])dnl
 444   if test -n "$kernel_version"; then
 445     libc_cv_uname_version="$kernel_version"
 446   else
 447     libc_cv_uname_version=unknown
 448   fi])
 449   AC_MSG_RESULT($libc_cv_uname_version)
 450   uname_version="$libc_cv_uname_version"
 451
 452 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 453   config_uname=config-name.h:config-name.in
 454 else
 455   # For non-generic uname, we don't need to create config-name.h at all.
 456   config_uname=
 457 fi
 458
 459 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
 460 if test $gnu_ld = yes; then
 461   AC_DEFINE(HAVE_GNU_LD)
 462 fi
 463 if test $gnu_as = yes; then
 464   AC_DEFINE(HAVE_GNU_AS)
 465 fi
 466 if test $elf = yes; then
 467   AC_DEFINE(HAVE_ELF)
 468 fi
 469 if test $weak = yes; then
 470   AC_DEFINE(HAVE_WEAK_SYMBOLS)
 471 fi
 472
 473 AC_SUBST(shared)
 474 if test $shared = default; then
 475   if test $gnu_ld = yes; then
 476     shared=$elf
 477   fi
 478 fi
 479 AC_SUBST(profile)
 480 AC_SUBST(omitfp)
 481
 482
 483 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 484   config_makefile=
 485 else
 486   config_makefile=Makefile
 487 fi
 488
 489 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 490           [echo '$config_vars' >> config.make])