git-send-email.perl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2002,2005 Greg Kroah-Hartman <greg@kroah.com>
   4 # Copyright 2005 Ryan Anderson <ryan@michonline.com>
   5 #
   6 # GPL v2 (See COPYING)
   7 #
   8 # Ported to support git "mbox" format files by Ryan Anderson <ryan@michonline.com>
   9 #
  10 # Sends a collection of emails to the given email addresses, disturbingly fast.
  11 #
  12 # Supports two formats:
  13 # 1. mbox format files (ignoring most headers and MIME formatting - this is designed for sending patches)
  14 # 2. The original format support by Greg's script:
  15 #    first line of the message is who to CC,
  16 #    and second line is the subject of the message.
  17 #
  18
  19 use strict;
  20 use warnings;
  21 use Term::ReadLine;
  22 use Getopt::Long;
  23 use Text::ParseWords;
  24 use Data::Dumper;
  25 use Term::ANSIColor;
  26 use File::Temp qw/ tempdir tempfile /;
  27 use Error qw(:try);
  28 use Git;
  29
  30 Getopt::Long::Configure qw/ pass_through /;
  31
  32 package FakeTerm;
  33 sub new {
  34         my ($class, $reason) = @_;
  35         return bless \$reason, shift;
  36 }
  37 sub readline {
  38         my $self = shift;
  39         die "Cannot use readline on FakeTerm: $$self";
  40 }
  41 package main;
  42
  43
  44 sub usage {
  45         print <<EOT;
  46 git send-email [options] <file | directory | rev-list options >
  47
  48   Composing:
  49     --from                  <str>  * Email From:
  50     --to                    <str>  * Email To:
  51     --cc                    <str>  * Email Cc:
  52     --bcc                   <str>  * Email Bcc:
  53     --subject               <str>  * Email "Subject:"
  54     --in-reply-to           <str>  * Email "In-Reply-To:"
  55     --annotate                     * Review each patch that will be sent in an editor.
  56     --compose                      * Open an editor for introduction.
  57
  58   Sending:
  59     --envelope-sender       <str>  * Email envelope sender.
  60     --smtp-server       <str:int>  * Outgoing SMTP server to use. The port
  61                                      is optional. Default 'localhost'.
  62     --smtp-server-port      <int>  * Outgoing SMTP server port.
  63     --smtp-user             <str>  * Username for SMTP-AUTH.
  64     --smtp-pass             <str>  * Password for SMTP-AUTH; not necessary.
  65     --smtp-encryption       <str>  * tls or ssl; anything else disables.
  66     --smtp-ssl                     * Deprecated. Use '--smtp-encryption ssl'.
  67
  68   Automating:
  69     --identity              <str>  * Use the sendemail.<id> options.
  70     --cc-cmd                <str>  * Email Cc: via `<str> \$patch_path`
  71     --suppress-cc           <str>  * author, self, sob, cc, cccmd, body, bodycc, all.
  72     --[no-]signed-off-by-cc        * Send to Signed-off-by: addresses. Default on.
  73     --[no-]suppress-from           * Send to self. Default off.
  74     --[no-]chain-reply-to          * Chain In-Reply-To: fields. Default on.
  75     --[no-]thread                  * Use In-Reply-To: field. Default on.
  76
  77   Administering:
  78     --confirm               <str>  * Confirm recipients before sending;
  79                                      auto, cc, compose, always, or never.
  80     --quiet                        * Output one line of info per email.
  81     --dry-run                      * Don't actually send the emails.
  82     --[no-]validate                * Perform patch sanity checks. Default on.
  83     --[no-]format-patch            * understand any non optional arguments as
  84                                      `git format-patch` ones.
  85
  86 EOT
  87         exit(1);
  88 }
  89
  90 # most mail servers generate the Date: header, but not all...
  91 sub format_2822_time {
  92         my ($time) = @_;
  93         my @localtm = localtime($time);
  94         my @gmttm = gmtime($time);
  95         my $localmin = $localtm[1] + $localtm[2] * 60;
  96         my $gmtmin = $gmttm[1] + $gmttm[2] * 60;
  97         if ($localtm[0] != $gmttm[0]) {
  98                 die "local zone differs from GMT by a non-minute interval\n";
  99         }
 100         if ((($gmttm[6] + 1) % 7) == $localtm[6]) {
 101                 $localmin += 1440;
 102         } elsif ((($gmttm[6] - 1) % 7) == $localtm[6]) {
 103                 $localmin -= 1440;
 104         } elsif ($gmttm[6] != $localtm[6]) {
 105                 die "local time offset greater than or equal to 24 hours\n";
 106         }
 107         my $offset = $localmin - $gmtmin;
 108         my $offhour = $offset / 60;
 109         my $offmin = abs($offset % 60);
 110         if (abs($offhour) >= 24) {
 111                 die ("local time offset greater than or equal to 24 hours\n");
 112         }
 113
 114         return sprintf("%s, %2d %s %d %02d:%02d:%02d %s%02d%02d",
 115                        qw(Sun Mon Tue Wed Thu Fri Sat)[$localtm[6]],
 116                        $localtm[3],
 117                        qw(Jan Feb Mar Apr May Jun
 118                           Jul Aug Sep Oct Nov Dec)[$localtm[4]],
 119                        $localtm[5]+1900,
 120                        $localtm[2],
 121                        $localtm[1],
 122                        $localtm[0],
 123                        ($offset >= 0) ? '+' : '-',
 124                        abs($offhour),
 125                        $offmin,
 126                        );
 127 }
 128
 129 my $have_email_valid = eval { require Email::Valid; 1 };
 130 my $have_mail_address = eval { require Mail::Address; 1 };
 131 my $smtp;
 132 my $auth;
 133
 134 sub unique_email_list(@);
 135 sub cleanup_compose_files();
 136
 137 # Variables we fill in automatically, or via prompting:
 138 my (@to,@cc,@initial_cc,@bcclist,@xh,
 139         $initial_reply_to,$initial_subject,@files,
 140         $author,$sender,$smtp_authpass,$annotate,$compose,$time);
 141
 142 my $envelope_sender;
 143
 144 # Example reply to:
 145 #$initial_reply_to = ''; #<20050203173208.GA23964@foobar.com>';
 146
 147 my $repo = eval { Git->repository() };
 148 my @repo = $repo ? ($repo) : ();
 149 my $term = eval {
 150         $ENV{"GIT_SEND_EMAIL_NOTTY"}
 151                 ? new Term::ReadLine 'git-send-email', \*STDIN, \*STDOUT
 152                 : new Term::ReadLine 'git-send-email';
 153 };
 154 if ($@) {
 155         $term = new FakeTerm "$@: going non-interactive";
 156 }
 157
 158 # Behavior modification variables
 159 my ($quiet, $dry_run) = (0, 0);
 160 my $format_patch;
 161 my $compose_filename;
 162
 163 # Handle interactive edition of files.
 164 my $multiedit;
 165 my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 166 sub do_edit {
 167         if (defined($multiedit) && !$multiedit) {
 168                 map {
 169                         system('sh', '-c', $editor.' "$@"', $editor, $_);
 170                         if (($? & 127) || ($? >> 8)) {
 171                                 die("the editor exited uncleanly, aborting everything");
 172                         }
 173                 } @_;
 174         } else {
 175                 system('sh', '-c', $editor.' "$@"', $editor, @_);
 176                 if (($? & 127) || ($? >> 8)) {
 177                         die("the editor exited uncleanly, aborting everything");
 178                 }
 179         }
 180 }
 181
 182 # Variables with corresponding config settings
 183 my ($thread, $chain_reply_to, $suppress_from, $signed_off_by_cc, $cc_cmd);
 184 my ($smtp_server, $smtp_server_port, $smtp_authuser, $smtp_encryption);
 185 my ($identity, $aliasfiletype, @alias_files, @smtp_host_parts);
 186 my ($validate, $confirm);
 187 my (@suppress_cc);
 188
 189 my %config_bool_settings = (
 190     "thread" => [\$thread, 1],
 191     "chainreplyto" => [\$chain_reply_to, 1],
 192     "suppressfrom" => [\$suppress_from, undef],
 193     "signedoffbycc" => [\$signed_off_by_cc, undef],
 194     "signedoffcc" => [\$signed_off_by_cc, undef],      # Deprecated
 195     "validate" => [\$validate, 1],
 196 );
 197
 198 my %config_settings = (
 199     "smtpserver" => \$smtp_server,
 200     "smtpserverport" => \$smtp_server_port,
 201     "smtpuser" => \$smtp_authuser,
 202     "smtppass" => \$smtp_authpass,
 203     "to" => \@to,
 204     "cc" => \@initial_cc,
 205     "cccmd" => \$cc_cmd,
 206     "aliasfiletype" => \$aliasfiletype,
 207     "bcc" => \@bcclist,
 208     "aliasesfile" => \@alias_files,
 209     "suppresscc" => \@suppress_cc,
 210     "envelopesender" => \$envelope_sender,
 211     "multiedit" => \$multiedit,
 212     "confirm"   => \$confirm,
 213 );
 214
 215 # Handle Uncouth Termination
 216 sub signal_handler {
 217
 218         # Make text normal
 219         print color("reset"), "\n";
 220
 221         # SMTP password masked
 222         system "stty echo";
 223
 224         # tmp files from --compose
 225         if (defined $compose_filename) {
 226                 if (-e $compose_filename) {
 227                         print "'$compose_filename' contains an intermediate version of the email you were composing.\n";
 228                 }
 229                 if (-e ($compose_filename . ".final")) {
 230                         print "'$compose_filename.final' contains the composed email.\n"
 231                 }
 232         }
 233
 234         exit;
 235 };
 236
 237 $SIG{TERM} = \&signal_handler;
 238 $SIG{INT}  = \&signal_handler;
 239
 240 # Begin by accumulating all the variables (defined above), that we will end up
 241 # needing, first, from the command line:
 242
 243 my $rc = GetOptions("sender|from=s" => \$sender,
 244                     "in-reply-to=s" => \$initial_reply_to,
 245                     "subject=s" => \$initial_subject,
 246                     "to=s" => \@to,
 247                     "cc=s" => \@initial_cc,
 248                     "bcc=s" => \@bcclist,
 249                     "chain-reply-to!" => \$chain_reply_to,
 250                     "smtp-server=s" => \$smtp_server,
 251                     "smtp-server-port=s" => \$smtp_server_port,
 252                     "smtp-user=s" => \$smtp_authuser,
 253                     "smtp-pass:s" => \$smtp_authpass,
 254                     "smtp-ssl" => sub { $smtp_encryption = 'ssl' },
 255                     "smtp-encryption=s" => \$smtp_encryption,
 256                     "identity=s" => \$identity,
 257                     "annotate" => \$annotate,
 258                     "compose" => \$compose,
 259                     "quiet" => \$quiet,
 260                     "cc-cmd=s" => \$cc_cmd,
 261                     "suppress-from!" => \$suppress_from,
 262                     "suppress-cc=s" => \@suppress_cc,
 263                     "signed-off-cc|signed-off-by-cc!" => \$signed_off_by_cc,
 264                     "confirm=s" => \$confirm,
 265                     "dry-run" => \$dry_run,
 266                     "envelope-sender=s" => \$envelope_sender,
 267                     "thread!" => \$thread,
 268                     "validate!" => \$validate,
 269                     "format-patch!" => \$format_patch,
 270          );
 271
 272 unless ($rc) {
 273     usage();
 274 }
 275
 276 die "Cannot run git format-patch from outside a repository\n"
 277         if $format_patch and not $repo;
 278
 279 # Now, let's fill any that aren't set in with defaults:
 280
 281 sub read_config {
 282         my ($prefix) = @_;
 283
 284         foreach my $setting (keys %config_bool_settings) {
 285                 my $target = $config_bool_settings{$setting}->[0];
 286                 $$target = Git::config_bool(@repo, "$prefix.$setting") unless (defined $$target);
 287         }
 288
 289         foreach my $setting (keys %config_settings) {
 290                 my $target = $config_settings{$setting};
 291                 if (ref($target) eq "ARRAY") {
 292                         unless (@$target) {
 293                                 my @values = Git::config(@repo, "$prefix.$setting");
 294                                 @$target = @values if (@values && defined $values[0]);
 295                         }
 296                 }
 297                 else {
 298                         $$target = Git::config(@repo, "$prefix.$setting") unless (defined $$target);
 299                 }
 300         }
 301
 302         if (!defined $smtp_encryption) {
 303                 my $enc = Git::config(@repo, "$prefix.smtpencryption");
 304                 if (defined $enc) {
 305                         $smtp_encryption = $enc;
 306                 } elsif (Git::config_bool(@repo, "$prefix.smtpssl")) {
 307                         $smtp_encryption = 'ssl';
 308                 }
 309         }
 310 }
 311
 312 # read configuration from [sendemail "$identity"], fall back on [sendemail]
 313 $identity = Git::config(@repo, "sendemail.identity") unless (defined $identity);
 314 read_config("sendemail.$identity") if (defined $identity);
 315 read_config("sendemail");
 316
 317 # fall back on builtin bool defaults
 318 foreach my $setting (values %config_bool_settings) {
 319         ${$setting->[0]} = $setting->[1] unless (defined (${$setting->[0]}));
 320 }
 321
 322 # 'default' encryption is none -- this only prevents a warning
 323 $smtp_encryption = '' unless (defined $smtp_encryption);
 324
 325 # Set CC suppressions
 326 my(%suppress_cc);
 327 if (@suppress_cc) {
 328         foreach my $entry (@suppress_cc) {
 329                 die "Unknown --suppress-cc field: '$entry'\n"
 330                         unless $entry =~ /^(all|cccmd|cc|author|self|sob|body|bodycc)$/;
 331                 $suppress_cc{$entry} = 1;
 332         }
 333 }
 334
 335 if ($suppress_cc{'all'}) {
 336         foreach my $entry (qw (ccmd cc author self sob body bodycc)) {
 337                 $suppress_cc{$entry} = 1;
 338         }
 339         delete $suppress_cc{'all'};
 340 }
 341
 342 # If explicit old-style ones are specified, they trump --suppress-cc.
 343 $suppress_cc{'self'} = $suppress_from if defined $suppress_from;
 344 $suppress_cc{'sob'} = !$signed_off_by_cc if defined $signed_off_by_cc;
 345
 346 if ($suppress_cc{'body'}) {
 347         foreach my $entry (qw (sob bodycc)) {
 348                 $suppress_cc{$entry} = 1;
 349         }
 350         delete $suppress_cc{'body'};
 351 }
 352
 353 # Set confirm's default value
 354 my $confirm_unconfigured = !defined $confirm;
 355 if ($confirm_unconfigured) {
 356         $confirm = scalar %suppress_cc ? 'compose' : 'auto';
 357 };
 358 die "Unknown --confirm setting: '$confirm'\n"
 359         unless $confirm =~ /^(?:auto|cc|compose|always|never)/;
 360
 361 # Debugging, print out the suppressions.
 362 if (0) {
 363         print "suppressions:\n";
 364         foreach my $entry (keys %suppress_cc) {
 365                 printf "  %-5s -> $suppress_cc{$entry}\n", $entry;
 366         }
 367 }
 368
 369 my ($repoauthor, $repocommitter);
 370 ($repoauthor) = Git::ident_person(@repo, 'author');
 371 ($repocommitter) = Git::ident_person(@repo, 'committer');
 372
 373 # Verify the user input
 374
 375 foreach my $entry (@to) {
 376         die "Comma in --to entry: $entry'\n" unless $entry !~ m/,/;
 377 }
 378
 379 foreach my $entry (@initial_cc) {
 380         die "Comma in --cc entry: $entry'\n" unless $entry !~ m/,/;
 381 }
 382
 383 foreach my $entry (@bcclist) {
 384         die "Comma in --bcclist entry: $entry'\n" unless $entry !~ m/,/;
 385 }
 386
 387 sub parse_address_line {
 388         if ($have_mail_address) {
 389                 return map { $_->format } Mail::Address->parse($_[0]);
 390         } else {
 391                 return split_addrs($_[0]);
 392         }
 393 }
 394
 395 sub split_addrs {
 396         return quotewords('\s*,\s*', 1, @_);
 397 }
 398
 399 my %aliases;
 400 my %parse_alias = (
 401         # multiline formats can be supported in the future
 402         mutt => sub { my $fh = shift; while (<$fh>) {
 403                 if (/^\s*alias\s+(\S+)\s+(.*)$/) {
 404                         my ($alias, $addr) = ($1, $2);
 405                         $addr =~ s/#.*$//; # mutt allows # comments
 406                          # commas delimit multiple addresses
 407                         $aliases{$alias} = [ split_addrs($addr) ];
 408                 }}},
 409         mailrc => sub { my $fh = shift; while (<$fh>) {
 410                 if (/^alias\s+(\S+)\s+(.*)$/) {
 411                         # spaces delimit multiple addresses
 412                         $aliases{$1} = [ split(/\s+/, $2) ];
 413                 }}},
 414         pine => sub { my $fh = shift; my $f='\t[^\t]*';
 415                 for (my $x = ''; defined($x); $x = $_) {
 416                         chomp $x;
 417                         $x .= $1 while(defined($_ = <$fh>) && /^ +(.*)$/);
 418                         $x =~ /^(\S+)$f\t\(?([^\t]+?)\)?(:?$f){0,2}$/ or next;
 419                         $aliases{$1} = [ split_addrs($2) ];
 420                 }},
 421         elm => sub  { my $fh = shift;
 422                       while (<$fh>) {
 423                           if (/^(\S+)\s+=\s+[^=]+=\s(\S+)/) {
 424                               my ($alias, $addr) = ($1, $2);
 425                                $aliases{$alias} = [ split_addrs($addr) ];
 426                           }
 427                       } },
 428
 429         gnus => sub { my $fh = shift; while (<$fh>) {
 430                 if (/\(define-mail-alias\s+"(\S+?)"\s+"(\S+?)"\)/) {
 431                         $aliases{$1} = [ $2 ];
 432                 }}}
 433 );
 434
 435 if (@alias_files and $aliasfiletype and defined $parse_alias{$aliasfiletype}) {
 436         foreach my $file (@alias_files) {
 437                 open my $fh, '<', $file or die "opening $file: $!\n";
 438                 $parse_alias{$aliasfiletype}->($fh);
 439                 close $fh;
 440         }
 441 }
 442
 443 ($sender) = expand_aliases($sender) if defined $sender;
 444
 445 # returns 1 if the conflict must be solved using it as a format-patch argument
 446 sub check_file_rev_conflict($) {
 447         return unless $repo;
 448         my $f = shift;
 449         try {
 450                 $repo->command('rev-parse', '--verify', '--quiet', $f);
 451                 if (defined($format_patch)) {
 452                         return $format_patch;
 453                 }
 454                 die(<<EOF);
 455 File '$f' exists but it could also be the range of commits
 456 to produce patches for.  Please disambiguate by...
 457
 458     * Saying "./$f" if you mean a file; or
 459     * Giving --format-patch option if you mean a range.
 460 EOF
 461         } catch Git::Error::Command with {
 462                 return 0;
 463         }
 464 }
 465
 466 # Now that all the defaults are set, process the rest of the command line
 467 # arguments and collect up the files that need to be processed.
 468 my @rev_list_opts;
 469 while (defined(my $f = shift @ARGV)) {
 470         if ($f eq "--") {
 471                 push @rev_list_opts, "--", @ARGV;
 472                 @ARGV = ();
 473         } elsif (-d $f and !check_file_rev_conflict($f)) {
 474                 opendir(DH,$f)
 475                         or die "Failed to opendir $f: $!";
 476
 477                 push @files, grep { -f $_ } map { +$f . "/" . $_ }
 478                                 sort readdir(DH);
 479                 closedir(DH);
 480         } elsif ((-f $f or -p $f) and !check_file_rev_conflict($f)) {
 481                 push @files, $f;
 482         } else {
 483                 push @rev_list_opts, $f;
 484         }
 485 }
 486
 487 if (@rev_list_opts) {
 488         die "Cannot run git format-patch from outside a repository\n"
 489                 unless $repo;
 490         push @files, $repo->command('format-patch', '-o', tempdir(CLEANUP => 1), @rev_list_opts);
 491 }
 492
 493 if ($validate) {
 494         foreach my $f (@files) {
 495                 unless (-p $f) {
 496                         my $error = validate_patch($f);
 497                         $error and die "fatal: $f: $error\nwarning: no patches were sent\n";
 498                 }
 499         }
 500 }
 501
 502 if (@files) {
 503         unless ($quiet) {
 504                 print $_,"\n" for (@files);
 505         }
 506 } else {
 507         print STDERR "\nNo patch files specified!\n\n";
 508         usage();
 509 }
 510
 511 sub get_patch_subject($) {
 512         my $fn = shift;
 513         open (my $fh, '<', $fn);
 514         while (my $line = <$fh>) {
 515                 next unless ($line =~ /^Subject: (.*)$/);
 516                 close $fh;
 517                 return "GIT: $1\n";
 518         }
 519         close $fh;
 520         die "No subject line in $fn ?";
 521 }
 522
 523 if ($compose) {
 524         # Note that this does not need to be secure, but we will make a small
 525         # effort to have it be unique
 526         $compose_filename = ($repo ?
 527                 tempfile(".gitsendemail.msg.XXXXXX", DIR => $repo->repo_path()) :
 528                 tempfile(".gitsendemail.msg.XXXXXX", DIR => "."))[1];
 529         open(C,">",$compose_filename)
 530                 or die "Failed to open for writing $compose_filename: $!";
 531
 532
 533         my $tpl_sender = $sender || $repoauthor || $repocommitter || '';
 534         my $tpl_subject = $initial_subject || '';
 535         my $tpl_reply_to = $initial_reply_to || '';
 536
 537         print C <<EOT;
 538 From $tpl_sender # This line is ignored.
 539 GIT: Lines beginning in "GIT: " will be removed.
 540 GIT: Consider including an overall diffstat or table of contents
 541 GIT: for the patch you are writing.
 542 GIT:
 543 GIT: Clear the body content if you don't wish to send a summary.
 544 From: $tpl_sender
 545 Subject: $tpl_subject
 546 In-Reply-To: $tpl_reply_to
 547
 548 EOT
 549         for my $f (@files) {
 550                 print C get_patch_subject($f);
 551         }
 552         close(C);
 553
 554         my $editor = $ENV{GIT_EDITOR} || Git::config(@repo, "core.editor") || $ENV{VISUAL} || $ENV{EDITOR} || "vi";
 555
 556         if ($annotate) {
 557                 do_edit($compose_filename, @files);
 558         } else {
 559                 do_edit($compose_filename);
 560         }
 561
 562         open(C2,">",$compose_filename . ".final")
 563                 or die "Failed to open $compose_filename.final : " . $!;
 564
 565         open(C,"<",$compose_filename)
 566                 or die "Failed to open $compose_filename : " . $!;
 567
 568         my $need_8bit_cte = file_has_nonascii($compose_filename);
 569         my $in_body = 0;
 570         my $summary_empty = 1;
 571         while(<C>) {
 572                 next if m/^GIT: /;
 573                 if ($in_body) {
 574                         $summary_empty = 0 unless (/^\n$/);
 575                 } elsif (/^\n$/) {
 576                         $in_body = 1;
 577                         if ($need_8bit_cte) {
 578                                 print C2 "MIME-Version: 1.0\n",
 579                                          "Content-Type: text/plain; ",
 580                                            "charset=utf-8\n",
 581                                          "Content-Transfer-Encoding: 8bit\n";
 582                         }
 583                 } elsif (/^MIME-Version:/i) {
 584                         $need_8bit_cte = 0;
 585                 } elsif (/^Subject:\s*(.+)\s*$/i) {
 586                         $initial_subject = $1;
 587                         my $subject = $initial_subject;
 588                         $_ = "Subject: " .
 589                                 ($subject =~ /[^[:ascii:]]/ ?
 590                                  quote_rfc2047($subject) :
 591                                  $subject) .
 592                                 "\n";
 593                 } elsif (/^In-Reply-To:\s*(.+)\s*$/i) {
 594                         $initial_reply_to = $1;
 595                         next;
 596                 } elsif (/^From:\s*(.+)\s*$/i) {
 597                         $sender = $1;
 598                         next;
 599                 } elsif (/^(?:To|Cc|Bcc):/i) {
 600                         print "To/Cc/Bcc fields are not interpreted yet, they have been ignored\n";
 601                         next;
 602                 }
 603                 print C2 $_;
 604         }
 605         close(C);
 606         close(C2);
 607
 608         if ($summary_empty) {
 609                 print "Summary email is empty, skipping it\n";
 610                 $compose = -1;
 611         }
 612 } elsif ($annotate) {
 613         do_edit(@files);
 614 }
 615
 616 sub ask {
 617         my ($prompt, %arg) = @_;
 618         my $valid_re = $arg{valid_re};
 619         my $default = $arg{default};
 620         my $resp;
 621         my $i = 0;
 622         return defined $default ? $default : undef
 623                 unless defined $term->IN and defined fileno($term->IN) and
 624                        defined $term->OUT and defined fileno($term->OUT);
 625         while ($i++ < 10) {
 626                 $resp = $term->readline($prompt);
 627                 if (!defined $resp) { # EOF
 628                         print "\n";
 629                         return defined $default ? $default : undef;
 630                 }
 631                 if ($resp eq '' and defined $default) {
 632                         return $default;
 633                 }
 634                 if (!defined $valid_re or $resp =~ /$valid_re/) {
 635                         return $resp;
 636                 }
 637         }
 638         return undef;
 639 }
 640
 641 my $prompting = 0;
 642 if (!defined $sender) {
 643         $sender = $repoauthor || $repocommitter || '';
 644         $sender = ask("Who should the emails appear to be from? [$sender] ",
 645                       default => $sender);
 646         print "Emails will be sent from: ", $sender, "\n";
 647         $prompting++;
 648 }
 649
 650 if (!@to) {
 651         my $to = ask("Who should the emails be sent to? ");
 652         push @to, parse_address_line($to) if defined $to; # sanitized/validated later
 653         $prompting++;
 654 }
 655
 656 sub expand_aliases {
 657         my @cur = @_;
 658         my @last;
 659         do {
 660                 @last = @cur;
 661                 @cur = map { $aliases{$_} ? @{$aliases{$_}} : $_ } @last;
 662         } while (join(',',@cur) ne join(',',@last));
 663         return @cur;
 664 }
 665
 666 @to = expand_aliases(@to);
 667 @to = (map { sanitize_address($_) } @to);
 668 @initial_cc = expand_aliases(@initial_cc);
 669 @bcclist = expand_aliases(@bcclist);
 670
 671 if ($thread && !defined $initial_reply_to && $prompting) {
 672         $initial_reply_to = ask(
 673                 "Message-ID to be used as In-Reply-To for the first email? ");
 674 }
 675 if (defined $initial_reply_to) {
 676         $initial_reply_to =~ s/^\s*<?//;
 677         $initial_reply_to =~ s/>?\s*$//;
 678         $initial_reply_to = "<$initial_reply_to>" if $initial_reply_to ne '';
 679 }
 680
 681 if (!defined $smtp_server) {
 682         foreach (qw( /usr/sbin/sendmail /usr/lib/sendmail )) {
 683                 if (-x $_) {
 684                         $smtp_server = $_;
 685                         last;
 686                 }
 687         }
 688         $smtp_server ||= 'localhost'; # could be 127.0.0.1, too... *shrug*
 689 }
 690
 691 if ($compose && $compose > 0) {
 692         @files = ($compose_filename . ".final", @files);
 693 }
 694
 695 # Variables we set as part of the loop over files
 696 our ($message_id, %mail, $subject, $reply_to, $references, $message,
 697         $needs_confirm, $message_num, $ask_default);
 698
 699 sub extract_valid_address {
 700         my $address = shift;
 701         my $local_part_regexp = '[^<>"\s@]+';
 702         my $domain_regexp = '[^.<>"\s@]+(?:\.[^.<>"\s@]+)+';
 703
 704         # check for a local address:
 705         return $address if ($address =~ /^($local_part_regexp)$/);
 706
 707         $address =~ s/^\s*<(.*)>\s*$/$1/;
 708         if ($have_email_valid) {
 709                 return scalar Email::Valid->address($address);
 710         } else {
 711                 # less robust/correct than the monster regexp in Email::Valid,
 712                 # but still does a 99% job, and one less dependency
 713                 $address =~ /($local_part_regexp\@$domain_regexp)/;
 714                 return $1;
 715         }
 716 }
 717
 718 # Usually don't need to change anything below here.
 719
 720 # we make a "fake" message id by taking the current number
 721 # of seconds since the beginning of Unix time and tacking on
 722 # a random number to the end, in case we are called quicker than
 723 # 1 second since the last time we were called.
 724
 725 # We'll setup a template for the message id, using the "from" address:
 726
 727 my ($message_id_stamp, $message_id_serial);
 728 sub make_message_id
 729 {
 730         my $uniq;
 731         if (!defined $message_id_stamp) {
 732                 $message_id_stamp = sprintf("%s-%s", time, $$);
 733                 $message_id_serial = 0;
 734         }
 735         $message_id_serial++;
 736         $uniq = "$message_id_stamp-$message_id_serial";
 737
 738         my $du_part;
 739         for ($sender, $repocommitter, $repoauthor) {
 740                 $du_part = extract_valid_address(sanitize_address($_));
 741                 last if (defined $du_part and $du_part ne '');
 742         }
 743         if (not defined $du_part or $du_part eq '') {
 744                 use Sys::Hostname qw();
 745                 $du_part = 'user@' . Sys::Hostname::hostname();
 746         }
 747         my $message_id_template = "<%s-git-send-email-%s>";
 748         $message_id = sprintf($message_id_template, $uniq, $du_part);
 749         #print "new message id = $message_id\n"; # Was useful for debugging
 750 }
 751
 752
 753
 754 $time = time - scalar $#files;
 755
 756 sub unquote_rfc2047 {
 757         local ($_) = @_;
 758         my $encoding;
 759         if (s/=\?([^?]+)\?q\?(.*)\?=/$2/g) {
 760                 $encoding = $1;
 761                 s/_/ /g;
 762                 s/=([0-9A-F]{2})/chr(hex($1))/eg;
 763         }
 764         return wantarray ? ($_, $encoding) : $_;
 765 }
 766
 767 sub quote_rfc2047 {
 768         local $_ = shift;
 769         my $encoding = shift || 'utf-8';
 770         s/([^-a-zA-Z0-9!*+\/])/sprintf("=%02X", ord($1))/eg;
 771         s/(.*)/=\?$encoding\?q\?$1\?=/;
 772         return $_;
 773 }
 774
 775 # use the simplest quoting being able to handle the recipient
 776 sub sanitize_address
 777 {
 778         my ($recipient) = @_;
 779         my ($recipient_name, $recipient_addr) = ($recipient =~ /^(.*?)\s*(<.*)/);
 780
 781         if (not $recipient_name) {
 782                 return "$recipient";
 783         }
 784
 785         # if recipient_name is already quoted, do nothing
 786         if ($recipient_name =~ /^("[[:ascii:]]*"|=\?utf-8\?q\?.*\?=)$/) {
 787                 return $recipient;
 788         }
 789
 790         # rfc2047 is needed if a non-ascii char is included
 791         if ($recipient_name =~ /[^[:ascii:]]/) {
 792                 $recipient_name =~ s/^"(.*)"$/$1/;
 793                 $recipient_name = quote_rfc2047($recipient_name);
 794         }
 795
 796         # double quotes are needed if specials or CTLs are included
 797         elsif ($recipient_name =~ /[][()<>@,;:\\".\000-\037\177]/) {
 798                 $recipient_name =~ s/(["\\\r])/\\$1/g;
 799                 $recipient_name = "\"$recipient_name\"";
 800         }
 801
 802         return "$recipient_name $recipient_addr";
 803
 804 }
 805
 806 sub send_message
 807 {
 808         my @recipients = unique_email_list(@to);
 809         @cc = (grep { my $cc = extract_valid_address($_);
 810                       not grep { $cc eq $_ } @recipients
 811                     }
 812                map { sanitize_address($_) }
 813                @cc);
 814         my $to = join (",\n\t", @recipients);
 815         @recipients = unique_email_list(@recipients,@cc,@bcclist);
 816         @recipients = (map { extract_valid_address($_) } @recipients);
 817         my $date = format_2822_time($time++);
 818         my $gitversion = '@@GIT_VERSION@@';
 819         if ($gitversion =~ m/..GIT_VERSION../) {
 820             $gitversion = Git::version();
 821         }
 822
 823         my $cc = join(", ", unique_email_list(@cc));
 824         my $ccline = "";
 825         if ($cc ne '') {
 826                 $ccline = "\nCc: $cc";
 827         }
 828         my $sanitized_sender = sanitize_address($sender);
 829         make_message_id() unless defined($message_id);
 830
 831         my $header = "From: $sanitized_sender
 832 To: $to${ccline}
 833 Subject: $subject
 834 Date: $date
 835 Message-Id: $message_id
 836 X-Mailer: git-send-email $gitversion
 837 ";
 838         if ($reply_to) {
 839
 840                 $header .= "In-Reply-To: $reply_to\n";
 841                 $header .= "References: $references\n";
 842         }
 843         if (@xh) {
 844                 $header .= join("\n", @xh) . "\n";
 845         }
 846
 847         my @sendmail_parameters = ('-i', @recipients);
 848         my $raw_from = $sanitized_sender;
 849         $raw_from = $envelope_sender if (defined $envelope_sender);
 850         $raw_from = extract_valid_address($raw_from);
 851         unshift (@sendmail_parameters,
 852                         '-f', $raw_from) if(defined $envelope_sender);
 853
 854         if ($needs_confirm && !$dry_run) {
 855                 print "\n$header\n";
 856                 if ($needs_confirm eq "inform") {
 857                         $confirm_unconfigured = 0; # squelch this message for the rest of this run
 858                         $ask_default = "y"; # assume yes on EOF since user hasn't explicitly asked for confirmation
 859                         print "    The Cc list above has been expanded by additional\n";
 860                         print "    addresses found in the patch commit message. By default\n";
 861                         print "    send-email prompts before sending whenever this occurs.\n";
 862                         print "    This behavior is controlled by the sendemail.confirm\n";
 863                         print "    configuration setting.\n";
 864                         print "\n";
 865                         print "    For additional information, run 'git send-email --help'.\n";
 866                         print "    To retain the current behavior, but squelch this message,\n";
 867                         print "    run 'git config --global sendemail.confirm auto'.\n\n";
 868                 }
 869                 $_ = ask("Send this email? ([y]es|[n]o|[q]uit|[a]ll): ",
 870                          valid_re => qr/^(?:yes|y|no|n|quit|q|all|a)/i,
 871                          default => $ask_default);
 872                 die "Send this email reply required" unless defined $_;
 873                 if (/^n/i) {
 874                         return;
 875                 } elsif (/^q/i) {
 876                         cleanup_compose_files();
 877                         exit(0);
 878                 } elsif (/^a/i) {
 879                         $confirm = 'never';
 880                 }
 881         }
 882
 883         if ($dry_run) {
 884                 # We don't want to send the email.
 885         } elsif ($smtp_server =~ m#^/#) {
 886                 my $pid = open my $sm, '|-';
 887                 defined $pid or die $!;
 888                 if (!$pid) {
 889                         exec($smtp_server, @sendmail_parameters) or die $!;
 890                 }
 891                 print $sm "$header\n$message";
 892                 close $sm or die $?;
 893         } else {
 894
 895                 if (!defined $smtp_server) {
 896                         die "The required SMTP server is not properly defined."
 897                 }
 898
 899                 if ($smtp_encryption eq 'ssl') {
 900                         $smtp_server_port ||= 465; # ssmtp
 901                         require Net::SMTP::SSL;
 902                         $smtp ||= Net::SMTP::SSL->new($smtp_server, Port => $smtp_server_port);
 903                 }
 904                 else {
 905                         require Net::SMTP;
 906                         $smtp ||= Net::SMTP->new((defined $smtp_server_port)
 907                                                  ? "$smtp_server:$smtp_server_port"
 908                                                  : $smtp_server);
 909                         if ($smtp_encryption eq 'tls') {
 910                                 require Net::SMTP::SSL;
 911                                 $smtp->command('STARTTLS');
 912                                 $smtp->response();
 913                                 if ($smtp->code == 220) {
 914                                         $smtp = Net::SMTP::SSL->start_SSL($smtp)
 915                                                 or die "STARTTLS failed! ".$smtp->message;
 916                                         $smtp_encryption = '';
 917                                         # Send EHLO again to receive fresh
 918                                         # supported commands
 919                                         $smtp->hello();
 920                                 } else {
 921                                         die "Server does not support STARTTLS! ".$smtp->message;
 922                                 }
 923                         }
 924                 }
 925
 926                 if (!$smtp) {
 927                         die "Unable to initialize SMTP properly.  Is there something wrong with your config?";
 928                 }
 929
 930                 if (defined $smtp_authuser) {
 931
 932                         if (!defined $smtp_authpass) {
 933
 934                                 system "stty -echo";
 935
 936                                 do {
 937                                         print "Password: ";
 938                                         $_ = <STDIN>;
 939                                         print "\n";
 940                                 } while (!defined $_);
 941
 942                                 chomp($smtp_authpass = $_);
 943
 944                                 system "stty echo";
 945                         }
 946
 947                         $auth ||= $smtp->auth( $smtp_authuser, $smtp_authpass ) or die $smtp->message;
 948                 }
 949
 950                 $smtp->mail( $raw_from ) or die $smtp->message;
 951                 $smtp->to( @recipients ) or die $smtp->message;
 952                 $smtp->data or die $smtp->message;
 953                 $smtp->datasend("$header\n$message") or die $smtp->message;
 954                 $smtp->dataend() or die $smtp->message;
 955                 $smtp->ok or die "Failed to send $subject\n".$smtp->message;
 956         }
 957         if ($quiet) {
 958                 printf (($dry_run ? "Dry-" : "")."Sent %s\n", $subject);
 959         } else {
 960                 print (($dry_run ? "Dry-" : "")."OK. Log says:\n");
 961                 if ($smtp_server !~ m#^/#) {
 962                         print "Server: $smtp_server\n";
 963                         print "MAIL FROM:<$raw_from>\n";
 964                         print "RCPT TO:".join(',',(map { "<$_>" } @recipients))."\n";
 965                 } else {
 966                         print "Sendmail: $smtp_server ".join(' ',@sendmail_parameters)."\n";
 967                 }
 968                 print $header, "\n";
 969                 if ($smtp) {
 970                         print "Result: ", $smtp->code, ' ',
 971                                 ($smtp->message =~ /\n([^\n]+\n)$/s), "\n";
 972                 } else {
 973                         print "Result: OK\n";
 974                 }
 975         }
 976 }
 977
 978 $reply_to = $initial_reply_to;
 979 $references = $initial_reply_to || '';
 980 $subject = $initial_subject;
 981 $message_num = 0;
 982
 983 foreach my $t (@files) {
 984         open(F,"<",$t) or die "can't open file $t";
 985
 986         my $author = undef;
 987         my $author_encoding;
 988         my $has_content_type;
 989         my $body_encoding;
 990         @cc = ();
 991         @xh = ();
 992         my $input_format = undef;
 993         my @header = ();
 994         $message = "";
 995         $message_num++;
 996         # First unfold multiline header fields
 997         while(<F>) {
 998                 last if /^\s*$/;
 999                 if (/^\s+\S/ and @header) {
1000                         chomp($header[$#header]);
1001                         s/^\s+/ /;
1002                         $header[$#header] .= $_;
1003             } else {
1004                         push(@header, $_);
1005                 }
1006         }
1007         # Now parse the header
1008         foreach(@header) {
1009                 if (/^From /) {
1010                         $input_format = 'mbox';
1011                         next;
1012                 }
1013                 chomp;
1014                 if (!defined $input_format && /^[-A-Za-z]+:\s/) {
1015                         $input_format = 'mbox';
1016                 }
1017
1018                 if (defined $input_format && $input_format eq 'mbox') {
1019                         if (/^Subject:\s+(.*)$/) {
1020                                 $subject = $1;
1021                         }
1022                         elsif (/^From:\s+(.*)$/) {
1023                                 ($author, $author_encoding) = unquote_rfc2047($1);
1024                                 next if $suppress_cc{'author'};
1025                                 next if $suppress_cc{'self'} and $author eq $sender;
1026                                 printf("(mbox) Adding cc: %s from line '%s'\n",
1027                                         $1, $_) unless $quiet;
1028                                 push @cc, $1;
1029                         }
1030                         elsif (/^Cc:\s+(.*)$/) {
1031                                 foreach my $addr (parse_address_line($1)) {
1032                                         if (unquote_rfc2047($addr) eq $sender) {
1033                                                 next if ($suppress_cc{'self'});
1034                                         } else {
1035                                                 next if ($suppress_cc{'cc'});
1036                                         }
1037                                         printf("(mbox) Adding cc: %s from line '%s'\n",
1038                                                 $addr, $_) unless $quiet;
1039                                         push @cc, $addr;
1040                                 }
1041                         }
1042                         elsif (/^Content-type:/i) {
1043                                 $has_content_type = 1;
1044                                 if (/charset="?([^ "]+)/) {
1045                                         $body_encoding = $1;
1046                                 }
1047                                 push @xh, $_;
1048                         }
1049                         elsif (/^Message-Id: (.*)/i) {
1050                                 $message_id = $1;
1051                         }
1052                         elsif (!/^Date:\s/ && /^[-A-Za-z]+:\s+\S/) {
1053                                 push @xh, $_;
1054                         }
1055
1056                 } else {
1057                         # In the traditional
1058                         # "send lots of email" format,
1059                         # line 1 = cc
1060                         # line 2 = subject
1061                         # So let's support that, too.
1062                         $input_format = 'lots';
1063                         if (@cc == 0 && !$suppress_cc{'cc'}) {
1064                                 printf("(non-mbox) Adding cc: %s from line '%s'\n",
1065                                         $_, $_) unless $quiet;
1066                                 push @cc, $_;
1067                         } elsif (!defined $subject) {
1068                                 $subject = $_;
1069                         }
1070                 }
1071         }
1072         # Now parse the message body
1073         while(<F>) {
1074                 $message .=  $_;
1075                 if (/^(Signed-off-by|Cc): (.*)$/i) {
1076                         chomp;
1077                         my ($what, $c) = ($1, $2);
1078                         chomp $c;
1079                         if ($c eq $sender) {
1080                                 next if ($suppress_cc{'self'});
1081                         } else {
1082                                 next if $suppress_cc{'sob'} and $what =~ /Signed-off-by/i;
1083                                 next if $suppress_cc{'bodycc'} and $what =~ /Cc/i;
1084                         }
1085                         push @cc, $c;
1086                         printf("(body) Adding cc: %s from line '%s'\n",
1087                                 $c, $_) unless $quiet;
1088                 }
1089         }
1090         close F;
1091
1092         if (defined $cc_cmd && !$suppress_cc{'cccmd'}) {
1093                 open(F, "$cc_cmd $t |")
1094                         or die "(cc-cmd) Could not execute '$cc_cmd'";
1095                 while(<F>) {
1096                         my $c = $_;
1097                         $c =~ s/^\s*//g;
1098                         $c =~ s/\n$//g;
1099                         next if ($c eq $sender and $suppress_from);
1100                         push @cc, $c;
1101                         printf("(cc-cmd) Adding cc: %s from: '%s'\n",
1102                                 $c, $cc_cmd) unless $quiet;
1103                 }
1104                 close F
1105                         or die "(cc-cmd) failed to close pipe to '$cc_cmd'";
1106         }
1107
1108         if (defined $author and $author ne $sender) {
1109                 $message = "From: $author\n\n$message";
1110                 if (defined $author_encoding) {
1111                         if ($has_content_type) {
1112                                 if ($body_encoding eq $author_encoding) {
1113                                         # ok, we already have the right encoding
1114                                 }
1115                                 else {
1116                                         # uh oh, we should re-encode
1117                                 }
1118                         }
1119                         else {
1120                                 push @xh,
1121                                   'MIME-Version: 1.0',
1122                                   "Content-Type: text/plain; charset=$author_encoding",
1123                                   'Content-Transfer-Encoding: 8bit';
1124                         }
1125                 }
1126         }
1127
1128         $needs_confirm = (
1129                 $confirm eq "always" or
1130                 ($confirm =~ /^(?:auto|cc)$/ && @cc) or
1131                 ($confirm =~ /^(?:auto|compose)$/ && $compose && $message_num == 1));
1132         $needs_confirm = "inform" if ($needs_confirm && $confirm_unconfigured && @cc);
1133
1134         @cc = (@initial_cc, @cc);
1135
1136         send_message();
1137
1138         # set up for the next message
1139         if ($chain_reply_to || !defined $reply_to || length($reply_to) == 0) {
1140                 $reply_to = $message_id;
1141                 if (length $references > 0) {
1142                         $references .= "\n $message_id";
1143                 } else {
1144                         $references = "$message_id";
1145                 }
1146         }
1147         $message_id = undef;
1148 }
1149
1150 cleanup_compose_files();
1151
1152 sub cleanup_compose_files() {
1153         unlink($compose_filename, $compose_filename . ".final") if $compose;
1154 }
1155
1156 $smtp->quit if $smtp;
1157
1158 sub unique_email_list(@) {
1159         my %seen;
1160         my @emails;
1161
1162         foreach my $entry (@_) {
1163                 if (my $clean = extract_valid_address($entry)) {
1164                         $seen{$clean} ||= 0;
1165                         next if $seen{$clean}++;
1166                         push @emails, $entry;
1167                 } else {
1168                         print STDERR "W: unable to extract a valid address",
1169                                         " from: $entry\n";
1170                 }
1171         }
1172         return @emails;
1173 }
1174
1175 sub validate_patch {
1176         my $fn = shift;
1177         open(my $fh, '<', $fn)
1178                 or die "unable to open $fn: $!\n";
1179         while (my $line = <$fh>) {
1180                 if (length($line) > 998) {
1181                         return "$.: patch contains a line longer than 998 characters";
1182                 }
1183         }
1184         return undef;
1185 }
1186
1187 sub file_has_nonascii {
1188         my $fn = shift;
1189         open(my $fh, '<', $fn)
1190                 or die "unable to open $fn: $!\n";
1191         while (my $line = <$fh>) {
1192                 return 1 if $line =~ /[^[:ascii:]]/;
1193         }
1194         return 0;
1195 }