| blob | 5a3d531f88a9c00a89d5d6d25f6212f3d99dc831 |
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 ## Definitions of private macros.
6 # GIT_CONF_SUBST(VAL, VAR)
7 # ------------------------
8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
9 AC_DEFUN([GIT_CONF_SUBST],
10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
11 config_appended_defs="$config_appended_defs${newline}dnl
12 $1=m4_if([$#],[1],[${$1}],[$2])"])
14 # GIT_CONF_SUBST_INIT
15 # -------------------
16 # Prepare shell variables and autoconf machine required by later calls
17 # to GIT_CONF_SUBST.
18 AC_DEFUN([GIT_CONF_SUBST_INIT],
19 [config_appended_defs=; newline='
20 '
21 AC_CONFIG_COMMANDS([$config_file],
22 [echo "$config_appended_defs" >> "$config_file"],
23 [config_file=$config_file
24 config_appended_defs="$config_appended_defs"])])
26 # GIT_ARG_SET_PATH(PROGRAM)
27 # -------------------------
28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
30 # --without-PROGRAM version used.
31 AC_DEFUN([GIT_ARG_SET_PATH],
32 [AC_ARG_WITH([$1],
33 [AS_HELP_STRING([--with-$1=PATH],
34 [provide PATH to $1])],
35 [GIT_CONF_APPEND_PATH([$1], [$2])],
36 [])])
38 # GIT_CONF_APPEND_PATH(PROGRAM)
39 # -----------------------------
40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
41 # Used by GIT_ARG_SET_PATH(PROGRAM)
42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
43 # --without-PROGRAM is used.
44 AC_DEFUN([GIT_CONF_APPEND_PATH],
45 [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
46 if test "$withval" = "no"; then
47 if test -n "$2"; then
48 GIT_UC_PROGRAM[]_PATH=$withval
49 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
50 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
51 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
52 else
53 AC_MSG_ERROR([You cannot use git without $1])
54 fi
55 else
56 if test "$withval" = "yes"; then
57 AC_MSG_WARN([You should provide path for --with-$1=PATH])
58 else
59 GIT_UC_PROGRAM[]_PATH=$withval
60 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
61 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
62 fi
63 fi
64 m4_popdef([GIT_UC_PROGRAM])])
66 # GIT_PARSE_WITH(PACKAGE)
67 # -----------------------
68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
72 AC_DEFUN([GIT_PARSE_WITH],
73 [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
74 if test "$withval" = "no"; then
75 NO_[]GIT_UC_PACKAGE=YesPlease
76 elif test "$withval" = "yes"; then
77 NO_[]GIT_UC_PACKAGE=
78 else
79 NO_[]GIT_UC_PACKAGE=
80 GIT_UC_PACKAGE[]DIR=$withval
81 AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
82 GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
83 fi
84 m4_popdef([GIT_UC_PACKAGE])])
86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
87 # -----------------------------------------------------
88 # Set VAR to the value specied by --with-WITHNAME.
89 # No verification of arguments is performed, but warnings are issued
90 # if either 'yes' or 'no' is specified.
91 # HELP_TEXT is presented when --help is called.
92 # This is a direct way to allow setting variables in the Makefile.
93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
94 [AC_ARG_WITH([$1],
95 [AS_HELP_STRING([--with-$1=VALUE], $3)],
96 if test -n "$withval"; then
97 if test "$withval" = "yes" -o "$withval" = "no"; then
98 AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
99 [a value for $1 ($2). Maybe you do...?])
100 fi
101 AC_MSG_NOTICE([Setting $2 to $withval])
102 GIT_CONF_SUBST([$2], [$withval])
103 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
105 #
106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
107 # -----------------------------------------
108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
110 # -Wall), it does not work. By looking for function definition in
111 # libraries, this problem can be worked around.
112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
113 AC_SEARCH_LIBS([$1],,
114 [$2],[$3])
115 ],[$3])])
117 #
118 # GIT_STASH_FLAGS(BASEPATH_VAR)
119 # -----------------------------
120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
121 # tests that may want to take user settings into account.
122 AC_DEFUN([GIT_STASH_FLAGS],[
123 if test -n "$1"; then
124 old_CPPFLAGS="$CPPFLAGS"
125 old_LDFLAGS="$LDFLAGS"
126 CPPFLAGS="-I$1/include $CPPFLAGS"
127 LDFLAGS="-L$1/$lib $LDFLAGS"
128 fi
129 ])
131 dnl
132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
133 dnl -----------------------------
134 dnl Restore the stashed *FLAGS values.
135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
136 if test -n "$1"; then
137 CPPFLAGS="$old_CPPFLAGS"
138 LDFLAGS="$old_LDFLAGS"
139 fi
140 ])
142 ## Configure body starts here.
144 AC_PREREQ(2.59)
145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
147 AC_CONFIG_SRCDIR([git.c])
149 config_file=config.mak.autogen
150 config_in=config.mak.in
152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
154 # Directories holding "saner" versions of common or POSIX binaries.
155 AC_ARG_WITH([sane-tool-path],
156 [AS_HELP_STRING(
157 [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
158 [Directories to prepend to PATH in build system and generated scripts])],
159 [if test "$withval" = "no"; then
160 withval=''
161 else
162 AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
163 fi
164 GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
165 [# If the "--with-sane-tool-path" option was not given, don't touch
166 # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
167 # This should minimize spurious differences in the behaviour of the
168 # Git build system when configure is used w.r.t. when it is not.
169 :])
171 ## Site configuration related to programs (before tests)
172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
173 #
174 # Set lib to alternative name of lib directory (e.g. lib64)
175 AC_ARG_WITH([lib],
176 [AS_HELP_STRING([--with-lib=ARG],
177 [ARG specifies alternative name for lib directory])],
178 [if test "$withval" = "no" || test "$withval" = "yes"; then
179 AC_MSG_WARN([You should provide name for --with-lib=ARG])
180 else
181 lib=$withval
182 AC_MSG_NOTICE([Setting lib to '$lib'])
183 GIT_CONF_SUBST([lib])
184 fi])
186 if test -z "$lib"; then
187 AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
188 lib=lib
189 fi
191 AC_ARG_ENABLE([pthreads],
192 [AS_HELP_STRING([--enable-pthreads=FLAGS],
193 [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
194 [The default if FLAGS is not specified is to try first -pthread]
195 [and then -lpthread.]
196 [--disable-pthreads will disable threading.])],
197 [
198 if test "x$enableval" = "xyes"; then
199 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
200 elif test "x$enableval" != "xno"; then
201 PTHREAD_CFLAGS=$enableval
202 AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
203 else
204 AC_MSG_NOTICE([POSIX Threads will be disabled.])
205 NO_PTHREADS=YesPlease
206 USER_NOPTHREAD=1
207 fi],
208 [
209 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
210 ])
212 # Define option to enable JavaScript minification
213 AC_ARG_ENABLE([jsmin],
214 [AS_HELP_STRING([--enable-jsmin=PATH],
215 [PATH is the name of a JavaScript minifier or the absolute path to one.])],
216 [
217 JSMIN=$enableval;
218 AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
219 GIT_CONF_SUBST([JSMIN])
220 ])
222 # Define option to enable CSS minification
223 AC_ARG_ENABLE([cssmin],
224 [AS_HELP_STRING([--enable-cssmin=PATH],
225 [PATH is the name of a CSS minifier or the absolute path to one.])],
226 [
227 CSSMIN=$enableval;
228 AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
229 GIT_CONF_SUBST([CSSMIN])
230 ])
232 ## Site configuration (override autodetection)
233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
234 AC_MSG_NOTICE([CHECKS for site configuration])
235 #
236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
237 # tests. These tests take up a significant amount of the total test time
238 # but are not needed unless you plan to talk to SVN repos.
239 #
240 # Define PPC_SHA1 environment variable when running make to make use of
241 # a bundled SHA1 routine optimized for PowerPC.
242 #
243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
244 # This also implies BLK_SHA1.
245 #
246 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
247 # /foo/bar/include and /foo/bar/lib directories.
248 AC_ARG_WITH(openssl,
249 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
250 AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]),
251 GIT_PARSE_WITH([openssl]))
253 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
254 # able to use Perl-compatible regular expressions.
255 #
256 # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
257 # /foo/bar/include and /foo/bar/lib directories.
258 #
259 AC_ARG_WITH(libpcre,
260 AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
261 AS_HELP_STRING([], [ARG can be also prefix for libpcre library and headers]),
262 if test "$withval" = "no"; then
263 USE_LIBPCRE=
264 elif test "$withval" = "yes"; then
265 USE_LIBPCRE=YesPlease
266 else
267 USE_LIBPCRE=YesPlease
268 LIBPCREDIR=$withval
269 AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
270 dnl USE_LIBPCRE can still be modified below, so don't substitute
271 dnl it yet.
272 GIT_CONF_SUBST([LIBPCREDIR])
273 fi)
274 #
275 # Define NO_CURL if you do not have curl installed. git-http-pull and
276 # git-http-push are not built, and you cannot use http:// and https://
277 # transports.
278 #
279 # Define CURLDIR=/foo/bar if your curl header and library files are in
280 # /foo/bar/include and /foo/bar/lib directories.
281 AC_ARG_WITH(curl,
282 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
283 AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]),
284 GIT_PARSE_WITH(curl))
285 #
286 # Define NO_EXPAT if you do not have expat installed. git-http-push is
287 # not built, and you cannot push using http:// and https:// transports.
288 #
289 # Define EXPATDIR=/foo/bar if your expat header and library files are in
290 # /foo/bar/include and /foo/bar/lib directories.
291 AC_ARG_WITH(expat,
292 AS_HELP_STRING([--with-expat],
293 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
294 AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]),
295 GIT_PARSE_WITH(expat))
296 #
297 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
298 # installed in /sw, but don't want GIT to link against any libraries
299 # installed there. If defined you may specify your own (or Fink's)
300 # include directories and library directories by defining CFLAGS
301 # and LDFLAGS appropriately.
302 #
303 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
304 # have DarwinPorts installed in /opt/local, but don't want GIT to
305 # link against any libraries installed there. If defined you may
306 # specify your own (or DarwinPort's) include directories and
307 # library directories by defining CFLAGS and LDFLAGS appropriately.
308 #
309 # Define NO_MMAP if you want to avoid mmap.
310 #
311 # Define NO_ICONV if your libc does not properly support iconv.
312 AC_ARG_WITH(iconv,
313 AS_HELP_STRING([--without-iconv],
314 [if your architecture doesn't properly support iconv])
315 AS_HELP_STRING([--with-iconv=PATH],
316 [PATH is prefix for libiconv library and headers])
317 AS_HELP_STRING([],
318 [used only if you need linking with libiconv]),
319 GIT_PARSE_WITH(iconv))
321 ## --enable-FEATURE[=ARG] and --disable-FEATURE
322 #
323 # Define USE_NSEC below if you want git to care about sub-second file mtimes
324 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
325 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
326 # randomly break unless your underlying filesystem supports those sub-second
327 # times (my ext3 doesn't).
328 #
329 # Define USE_STDEV below if you want git to care about the underlying device
330 # change being considered an inode change from the update-index perspective.
332 #
333 # Allow user to set ETC_GITCONFIG variable
334 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
335 Use VALUE instead of /etc/gitconfig as the
336 global git configuration file.
337 If VALUE is not fully qualified it will be interpreted
338 as a path relative to the computed prefix at runtime.)
340 #
341 # Allow user to set ETC_GITATTRIBUTES variable
342 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
343 Use VALUE instead of /etc/gitattributes as the
344 global git attributes file.
345 If VALUE is not fully qualified it will be interpreted
346 as a path relative to the computed prefix at runtime.)
348 #
349 # Allow user to set the default pager
350 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
351 Use VALUE as the fall-back pager instead of 'less'.
352 This is used by things like 'git log' when the user
353 does not specify a pager to use through alternate
354 methods. eg: /usr/bin/pager)
355 #
356 # Allow user to set the default editor
357 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
358 Use VALUE as the fall-back editor instead of 'vi'.
359 This is used by things like 'git commit' when the user
360 does not specify a preferred editor through other
361 methods. eg: /usr/bin/editor)
363 #
364 # Define SHELL_PATH to provide path to shell.
365 GIT_ARG_SET_PATH(shell)
366 #
367 # Define PERL_PATH to provide path to Perl.
368 GIT_ARG_SET_PATH(perl)
369 #
370 # Define PYTHON_PATH to provide path to Python.
371 GIT_ARG_SET_PATH(python, allow-without)
372 #
373 # Define ZLIB_PATH to provide path to zlib.
374 GIT_ARG_SET_PATH(zlib)
375 #
376 # Declare the with-tcltk/without-tcltk options.
377 AC_ARG_WITH(tcltk,
378 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
379 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
380 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
381 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
382 GIT_PARSE_WITH(tcltk))
383 #
386 ## Checks for programs.
387 AC_MSG_NOTICE([CHECKS for programs])
388 #
389 AC_PROG_CC([cc gcc])
390 AC_C_INLINE
391 case $ac_cv_c_inline in
392 inline | yes | no) INLINE='';;
393 *) INLINE=$ac_cv_c_inline ;;
394 esac
395 GIT_CONF_SUBST([INLINE])
397 # which switch to pass runtime path to dynamic libraries to the linker
398 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
399 SAVE_LDFLAGS="${LDFLAGS}"
400 LDFLAGS="${SAVE_LDFLAGS} -R /"
401 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
402 LDFLAGS="${SAVE_LDFLAGS}"
403 ])
404 if test "$git_cv_ld_dashr" = "yes"; then
405 CC_LD_DYNPATH=-R
406 else
407 AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
408 SAVE_LDFLAGS="${LDFLAGS}"
409 LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
410 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
411 LDFLAGS="${SAVE_LDFLAGS}"
412 ])
413 if test "$git_cv_ld_wl_rpath" = "yes"; then
414 CC_LD_DYNPATH=-Wl,-rpath,
415 else
416 AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
417 SAVE_LDFLAGS="${LDFLAGS}"
418 LDFLAGS="${SAVE_LDFLAGS} -rpath /"
419 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
420 LDFLAGS="${SAVE_LDFLAGS}"
421 ])
422 if test "$git_cv_ld_rpath" = "yes"; then
423 CC_LD_DYNPATH=-rpath
424 else
425 CC_LD_DYNPATH=
426 AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
427 fi
428 fi
429 fi
430 GIT_CONF_SUBST([CC_LD_DYNPATH])
431 #AC_PROG_INSTALL # needs install-sh or install.sh in sources
432 AC_CHECK_TOOLS(AR, [gar ar], :)
433 AC_CHECK_PROGS(TAR, [gtar tar])
434 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
435 # TCLTK_PATH will be set to some value if we want Tcl/Tk
436 # or will be empty otherwise.
437 if test -n "$NO_TCLTK"; then
438 TCLTK_PATH=
439 else
440 if test "$with_tcltk" = ""; then
441 # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
442 TCLTK_PATH=wish
443 elif test "$with_tcltk" = "yes"; then
444 # Tcl/Tk check requested.
445 AC_CHECK_PROGS(TCLTK_PATH, [wish], )
446 else
447 AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
448 TCLTK_PATH="$with_tcltk"
449 fi
450 fi
451 GIT_CONF_SUBST([TCLTK_PATH])
452 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
453 if test -n "$ASCIIDOC"; then
454 AC_MSG_CHECKING([for asciidoc version])
455 asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
456 case "${asciidoc_version}" in
457 asciidoc' '8*)
458 AC_MSG_RESULT([${asciidoc_version}])
459 ;;
460 *)
461 AC_MSG_RESULT([${asciidoc_version} (unknown)])
462 ;;
463 esac
464 fi
467 ## Checks for libraries.
468 AC_MSG_NOTICE([CHECKS for libraries])
469 #
470 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
471 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
473 GIT_STASH_FLAGS($OPENSSLDIR)
475 AC_CHECK_LIB([crypto], [SHA1_Init],
476 [NEEDS_SSL_WITH_CRYPTO=],
477 [AC_CHECK_LIB([ssl], [SHA1_Init],
478 [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
479 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
481 GIT_UNSTASH_FLAGS($OPENSSLDIR)
483 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
484 GIT_CONF_SUBST([NO_OPENSSL])
486 #
487 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
488 # able to use Perl-compatible regular expressions.
489 #
491 if test -n "$USE_LIBPCRE"; then
493 GIT_STASH_FLAGS($LIBPCREDIR)
495 AC_CHECK_LIB([pcre], [pcre_version],
496 [USE_LIBPCRE=YesPlease],
497 [USE_LIBPCRE=])
499 GIT_UNSTASH_FLAGS($LIBPCREDIR)
501 GIT_CONF_SUBST([USE_LIBPCRE])
503 fi
505 #
506 # Define NO_CURL if you do not have libcurl installed. git-http-pull and
507 # git-http-push are not built, and you cannot use http:// and https://
508 # transports.
510 GIT_STASH_FLAGS($CURLDIR)
512 AC_CHECK_LIB([curl], [curl_global_init],
513 [NO_CURL=],
514 [NO_CURL=YesPlease])
516 if test -z "$NO_CURL"; then
518 AC_CHECK_DECLS([curl_multi_init],
519 [NO_CURL_MULTI=],
520 [NO_CURL_MULTI=UnfortunatelyYes],
521 [[#include <curl/curl.h>]])
523 GIT_CONF_SUBST([NO_CURL_MULTI])
525 fi
527 GIT_UNSTASH_FLAGS($CURLDIR)
529 GIT_CONF_SUBST([NO_CURL])
531 #
532 # Define NO_EXPAT if you do not have expat installed. git-http-push is
533 # not built, and you cannot push using http:// and https:// transports.
535 GIT_STASH_FLAGS($EXPATDIR)
537 AC_CHECK_LIB([expat], [XML_ParserCreate],
538 [NO_EXPAT=],
539 [NO_EXPAT=YesPlease])
541 GIT_UNSTASH_FLAGS($EXPATDIR)
543 GIT_CONF_SUBST([NO_EXPAT])
545 #
546 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
547 # some Solaris installations).
548 # Define NO_ICONV if neither libc nor libiconv support iconv.
550 if test -z "$NO_ICONV"; then
552 GIT_STASH_FLAGS($ICONVDIR)
554 AC_DEFUN([ICONVTEST_SRC],
555 [AC_LANG_PROGRAM([#include <iconv.h>],
556 [iconv_open("", "");])])
558 if test -n "$ICONVDIR"; then
559 lib_order="-liconv -lc"
560 else
561 lib_order="-lc -liconv"
562 fi
564 NO_ICONV=YesPlease
566 for l in $lib_order; do
567 if test "$l" = "-liconv"; then
568 NEEDS_LIBICONV=YesPlease
569 else
570 NEEDS_LIBICONV=
571 fi
573 old_LIBS="$LIBS"
574 LIBS="$LIBS $l"
575 AC_MSG_CHECKING([for iconv in $l])
576 AC_LINK_IFELSE([ICONVTEST_SRC],
577 [AC_MSG_RESULT([yes])
578 NO_ICONV=
579 break],
580 [AC_MSG_RESULT([no])])
581 LIBS="$old_LIBS"
582 done
584 #in case of break
585 LIBS="$old_LIBS"
587 GIT_UNSTASH_FLAGS($ICONVDIR)
589 GIT_CONF_SUBST([NEEDS_LIBICONV])
590 GIT_CONF_SUBST([NO_ICONV])
592 if test -n "$NO_ICONV"; then
593 NEEDS_LIBICONV=
594 fi
596 fi
598 #
599 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
601 GIT_STASH_FLAGS($ZLIB_PATH)
603 AC_DEFUN([ZLIBTEST_SRC], [
604 AC_LANG_PROGRAM([#include <zlib.h>],
605 [deflateBound(0, 0);])])
606 AC_MSG_CHECKING([for deflateBound in -lz])
607 old_LIBS="$LIBS"
608 LIBS="$LIBS -lz"
609 AC_LINK_IFELSE([ZLIBTEST_SRC],
610 [AC_MSG_RESULT([yes])],
611 [AC_MSG_RESULT([no])
612 NO_DEFLATE_BOUND=yes])
613 LIBS="$old_LIBS"
615 GIT_UNSTASH_FLAGS($ZLIB_PATH)
617 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
619 #
620 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
621 # Patrick Mauritz).
622 AC_CHECK_LIB([c], [socket],
623 [NEEDS_SOCKET=],
624 [NEEDS_SOCKET=YesPlease])
625 GIT_CONF_SUBST([NEEDS_SOCKET])
626 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
628 #
629 # The next few tests will define NEEDS_RESOLV if linking with
630 # libresolv provides some of the functions we would normally get
631 # from libc.
632 NEEDS_RESOLV=
633 #
634 # Define NO_INET_NTOP if linking with -lresolv is not enough.
635 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
636 NO_INET_NTOP=
637 AC_CHECK_FUNC([inet_ntop],
638 [],
639 [AC_CHECK_LIB([resolv], [inet_ntop],
640 [NEEDS_RESOLV=YesPlease],
641 [NO_INET_NTOP=YesPlease])
642 ])
643 GIT_CONF_SUBST([NO_INET_NTOP])
644 #
645 # Define NO_INET_PTON if linking with -lresolv is not enough.
646 # Solaris 2.7 in particular hos inet_pton in -lresolv.
647 NO_INET_PTON=
648 AC_CHECK_FUNC([inet_pton],
649 [],
650 [AC_CHECK_LIB([resolv], [inet_pton],
651 [NEEDS_RESOLV=YesPlease],
652 [NO_INET_PTON=YesPlease])
653 ])
654 GIT_CONF_SUBST([NO_INET_PTON])
655 #
656 # Define NO_HSTRERROR if linking with -lresolv is not enough.
657 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
658 NO_HSTRERROR=
659 AC_CHECK_FUNC([hstrerror],
660 [],
661 [AC_CHECK_LIB([resolv], [hstrerror],
662 [NEEDS_RESOLV=YesPlease],
663 [NO_HSTRERROR=YesPlease])
664 ])
665 GIT_CONF_SUBST([NO_HSTRERROR])
667 dnl This must go after all the possible places for its initialization,
668 dnl in the AC_CHECK_FUNC invocations above.
669 GIT_CONF_SUBST([NEEDS_RESOLV])
670 #
671 # If any of the above tests determined that -lresolv is needed at
672 # build-time, also set it here for remaining configure-time checks.
673 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
675 AC_CHECK_LIB([c], [basename],
676 [NEEDS_LIBGEN=],
677 [NEEDS_LIBGEN=YesPlease])
678 GIT_CONF_SUBST([NEEDS_LIBGEN])
679 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
681 AC_CHECK_LIB([c], [gettext],
682 [LIBC_CONTAINS_LIBINTL=YesPlease],
683 [LIBC_CONTAINS_LIBINTL=])
684 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
686 #
687 # Define NO_GETTEXT if you don't want Git output to be translated.
688 # A translated Git requires GNU libintl or another gettext implementation
689 AC_CHECK_HEADER([libintl.h],
690 [NO_GETTEXT=],
691 [NO_GETTEXT=YesPlease])
692 GIT_CONF_SUBST([NO_GETTEXT])
694 if test -z "$NO_GETTEXT"; then
695 test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
696 fi
698 ## Checks for header files.
699 AC_MSG_NOTICE([CHECKS for header files])
700 #
701 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
702 AC_CHECK_HEADER([sys/select.h],
703 [NO_SYS_SELECT_H=],
704 [NO_SYS_SELECT_H=UnfortunatelyYes])
705 GIT_CONF_SUBST([NO_SYS_SELECT_H])
706 #
707 # Define NO_SYS_POLL_H if you don't have sys/poll.h
708 AC_CHECK_HEADER([sys/poll.h],
709 [NO_SYS_POLL_H=],
710 [NO_SYS_POLL_H=UnfortunatelyYes])
711 GIT_CONF_SUBST([NO_SYS_POLL_H])
712 #
713 # Define NO_INTTYPES_H if you don't have inttypes.h
714 AC_CHECK_HEADER([inttypes.h],
715 [NO_INTTYPES_H=],
716 [NO_INTTYPES_H=UnfortunatelyYes])
717 GIT_CONF_SUBST([NO_INTTYPES_H])
718 #
719 # Define OLD_ICONV if your library has an old iconv(), where the second
720 # (input buffer pointer) parameter is declared with type (const char **).
721 AC_DEFUN([OLDICONVTEST_SRC], [
722 AC_LANG_PROGRAM([[
723 #include <iconv.h>
725 extern size_t iconv(iconv_t cd,
726 char **inbuf, size_t *inbytesleft,
727 char **outbuf, size_t *outbytesleft);
728 ]], [])])
730 GIT_STASH_FLAGS($ICONVDIR)
732 AC_MSG_CHECKING([for old iconv()])
733 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
734 [AC_MSG_RESULT([no])],
735 [AC_MSG_RESULT([yes])
736 OLD_ICONV=UnfortunatelyYes])
738 GIT_UNSTASH_FLAGS($ICONVDIR)
740 GIT_CONF_SUBST([OLD_ICONV])
742 ## Checks for typedefs, structures, and compiler characteristics.
743 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
744 #
745 TYPE_SOCKLEN_T
746 case $ac_cv_type_socklen_t in
747 yes) SOCKLEN_T='';;
748 *) SOCKLEN_T=$git_cv_socklen_t_equiv;;
749 esac
750 GIT_CONF_SUBST([SOCKLEN_T])
752 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
753 AC_CHECK_MEMBER(struct dirent.d_ino,
754 [NO_D_INO_IN_DIRENT=],
755 [NO_D_INO_IN_DIRENT=YesPlease],
756 [#include <dirent.h>])
757 GIT_CONF_SUBST([NO_D_INO_IN_DIRENT])
758 #
759 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
760 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
761 AC_CHECK_MEMBER(struct dirent.d_type,
762 [NO_D_TYPE_IN_DIRENT=],
763 [NO_D_TYPE_IN_DIRENT=YesPlease],
764 [#include <dirent.h>])
765 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
766 #
767 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
768 # in the C library.
769 AC_CHECK_MEMBER(struct passwd.pw_gecos,
770 [NO_GECOS_IN_PWENT=],
771 [NO_GECOS_IN_PWENT=YesPlease],
772 [#include <pwd.h>])
773 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
774 #
775 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
776 # sockaddr_storage.
777 AC_CHECK_TYPE(struct sockaddr_storage,
778 [NO_SOCKADDR_STORAGE=],
779 [NO_SOCKADDR_STORAGE=YesPlease],[
780 #include <sys/types.h>
781 #include <sys/socket.h>
782 ])
783 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
784 #
785 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
786 AC_CHECK_TYPE([struct addrinfo],[
787 GIT_CHECK_FUNC([getaddrinfo],
788 [NO_IPV6=],
789 [NO_IPV6=YesPlease])
790 ],[NO_IPV6=YesPlease],[
791 #include <sys/types.h>
792 #include <sys/socket.h>
793 #include <netdb.h>
794 ])
795 GIT_CONF_SUBST([NO_IPV6])
796 #
797 # Define NO_REGEX if you have no or inferior regex support in your C library.
798 AC_CACHE_CHECK([whether the platform regex can handle null bytes],
799 [ac_cv_c_excellent_regex], [
800 AC_EGREP_CPP(yippeeyeswehaveit,
801 AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
802 #include <regex.h>
803 ],
804 [#ifdef REG_STARTEND
805 yippeeyeswehaveit
806 #endif
807 ]),
808 [ac_cv_c_excellent_regex=yes],
809 [ac_cv_c_excellent_regex=no])
810 ])
811 if test $ac_cv_c_excellent_regex = yes; then
812 NO_REGEX=
813 else
814 NO_REGEX=YesPlease
815 fi
816 GIT_CONF_SUBST([NO_REGEX])
817 #
818 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
819 # when attempting to read from an fopen'ed directory.
820 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
821 [ac_cv_fread_reads_directories],
822 [
823 AC_RUN_IFELSE(
824 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
825 [[char c;
826 FILE *f = fopen(".", "r");
827 return f && fread(&c, 1, 1, f)]])],
828 [ac_cv_fread_reads_directories=no],
829 [ac_cv_fread_reads_directories=yes])
830 ])
831 if test $ac_cv_fread_reads_directories = yes; then
832 FREAD_READS_DIRECTORIES=UnfortunatelyYes
833 else
834 FREAD_READS_DIRECTORIES=
835 fi
836 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
837 #
838 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
839 # or vsnprintf() return -1 instead of number of characters which would
840 # have been written to the final string if enough space had been available.
841 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
842 [ac_cv_snprintf_returns_bogus],
843 [
844 AC_RUN_IFELSE(
845 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
846 #include "stdarg.h"
848 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
849 {
850 int ret;
851 va_list ap;
852 va_start(ap, format);
853 ret = vsnprintf(str, maxsize, format, ap);
854 va_end(ap);
855 return ret;
856 }],
857 [[char buf[6];
858 if (test_vsnprintf(buf, 3, "%s", "12345") != 5
859 || strcmp(buf, "12")) return 1;
860 if (snprintf(buf, 3, "%s", "12345") != 5
861 || strcmp(buf, "12")) return 1]])],
862 [ac_cv_snprintf_returns_bogus=no],
863 [ac_cv_snprintf_returns_bogus=yes])
864 ])
865 if test $ac_cv_snprintf_returns_bogus = yes; then
866 SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
867 else
868 SNPRINTF_RETURNS_BOGUS=
869 fi
870 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
873 ## Checks for library functions.
874 ## (in default C library and libraries checked by AC_CHECK_LIB)
875 AC_MSG_NOTICE([CHECKS for library functions])
876 #
877 # Define NO_LIBGEN_H if you don't have libgen.h.
878 AC_CHECK_HEADER([libgen.h],
879 [NO_LIBGEN_H=],
880 [NO_LIBGEN_H=YesPlease])
881 GIT_CONF_SUBST([NO_LIBGEN_H])
882 #
883 # Define HAVE_PATHS_H if you have paths.h.
884 AC_CHECK_HEADER([paths.h],
885 [HAVE_PATHS_H=YesPlease],
886 [HAVE_PATHS_H=])
887 GIT_CONF_SUBST([HAVE_PATHS_H])
888 #
889 # Define HAVE_LIBCHARSET_H if have libcharset.h
890 AC_CHECK_HEADER([libcharset.h],
891 [HAVE_LIBCHARSET_H=YesPlease],
892 [HAVE_LIBCHARSET_H=])
893 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
894 #
895 # Define HAVE_STRINGS_H if you have strings.h
896 AC_CHECK_HEADER([strings.h],
897 [HAVE_STRINGS_H=YesPlease],
898 [HAVE_STRINGS_H=])
899 GIT_CONF_SUBST([HAVE_STRINGS_H])
900 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
901 # and libcharset does
902 CHARSET_LIB=
903 AC_CHECK_LIB([iconv], [locale_charset],
904 [CHARSET_LIB=-liconv],
905 [AC_CHECK_LIB([charset], [locale_charset],
906 [CHARSET_LIB=-lcharset])])
907 GIT_CONF_SUBST([CHARSET_LIB])
908 #
909 # Define NO_STRCASESTR if you don't have strcasestr.
910 GIT_CHECK_FUNC(strcasestr,
911 [NO_STRCASESTR=],
912 [NO_STRCASESTR=YesPlease])
913 GIT_CONF_SUBST([NO_STRCASESTR])
914 #
915 # Define NO_MEMMEM if you don't have memmem.
916 GIT_CHECK_FUNC(memmem,
917 [NO_MEMMEM=],
918 [NO_MEMMEM=YesPlease])
919 GIT_CONF_SUBST([NO_MEMMEM])
920 #
921 # Define NO_STRLCPY if you don't have strlcpy.
922 GIT_CHECK_FUNC(strlcpy,
923 [NO_STRLCPY=],
924 [NO_STRLCPY=YesPlease])
925 GIT_CONF_SUBST([NO_STRLCPY])
926 #
927 # Define NO_UINTMAX_T if your platform does not have uintmax_t
928 AC_CHECK_TYPE(uintmax_t,
929 [NO_UINTMAX_T=],
930 [NO_UINTMAX_T=YesPlease],[
931 #include <inttypes.h>
932 ])
933 GIT_CONF_SUBST([NO_UINTMAX_T])
934 #
935 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
936 GIT_CHECK_FUNC(strtoumax,
937 [NO_STRTOUMAX=],
938 [NO_STRTOUMAX=YesPlease])
939 GIT_CONF_SUBST([NO_STRTOUMAX])
940 #
941 # Define NO_SETENV if you don't have setenv in the C library.
942 GIT_CHECK_FUNC(setenv,
943 [NO_SETENV=],
944 [NO_SETENV=YesPlease])
945 GIT_CONF_SUBST([NO_SETENV])
946 #
947 # Define NO_UNSETENV if you don't have unsetenv in the C library.
948 GIT_CHECK_FUNC(unsetenv,
949 [NO_UNSETENV=],
950 [NO_UNSETENV=YesPlease])
951 GIT_CONF_SUBST([NO_UNSETENV])
952 #
953 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
954 GIT_CHECK_FUNC(mkdtemp,
955 [NO_MKDTEMP=],
956 [NO_MKDTEMP=YesPlease])
957 GIT_CONF_SUBST([NO_MKDTEMP])
958 #
959 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
960 GIT_CHECK_FUNC(mkstemps,
961 [NO_MKSTEMPS=],
962 [NO_MKSTEMPS=YesPlease])
963 GIT_CONF_SUBST([NO_MKSTEMPS])
964 #
965 # Define NO_INITGROUPS if you don't have initgroups in the C library.
966 GIT_CHECK_FUNC(initgroups,
967 [NO_INITGROUPS=],
968 [NO_INITGROUPS=YesPlease])
969 GIT_CONF_SUBST([NO_INITGROUPS])
970 #
971 #
972 # Define NO_MMAP if you want to avoid mmap.
973 #
974 # Define NO_ICONV if your libc does not properly support iconv.
977 ## Other checks.
978 # Define USE_PIC if you need the main git objects to be built with -fPIC
979 # in order to build and link perl/Git.so. x86-64 seems to need this.
980 #
981 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
982 # Enable it on Windows. By default, symrefs are still used.
983 #
984 # Define NO_PTHREADS if we do not have pthreads.
985 #
986 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
987 AC_DEFUN([PTHREADTEST_SRC], [
988 AC_LANG_PROGRAM([[
989 #include <pthread.h>
990 ]], [[
991 pthread_mutex_t test_mutex;
992 pthread_key_t test_key;
993 int retcode = 0;
994 retcode |= pthread_key_create(&test_key, (void *)0);
995 retcode |= pthread_mutex_init(&test_mutex,(void *)0);
996 retcode |= pthread_mutex_lock(&test_mutex);
997 retcode |= pthread_mutex_unlock(&test_mutex);
998 return retcode;
999 ]])])
1001 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1002 dnl [[#include <pthread.h>]],
1003 dnl [[pthread_mutex_t test_mutex;]]
1004 dnl )])
1006 NO_PTHREADS=UnfortunatelyYes
1007 PTHREAD_LIBS=
1009 if test -n "$USER_NOPTHREAD"; then
1010 AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1011 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1012 # -D_REENTRANT' or some such.
1013 elif test -z "$PTHREAD_CFLAGS"; then
1014 threads_found=no
1015 # Attempt to compile and link some code using pthreads to determine
1016 # required linker flags. The order is somewhat important here: We
1017 # first try it without any extra flags, to catch systems where
1018 # pthreads are part of the C library, then go on testing various other
1019 # flags. We do so to avoid false positives. For example, on Mac OS X
1020 # pthreads are part of the C library; moreover, the compiler allows us
1021 # to add "-mt" to the CFLAGS (although it will do nothing except
1022 # trigger a warning about an unused flag). Hence if we checked for
1023 # "-mt" before "" we would end up picking it. But unfortunately this
1024 # would then trigger compiler warnings on every single file we compile.
1025 for opt in "" -mt -pthread -lpthread; do
1026 old_CFLAGS="$CFLAGS"
1027 CFLAGS="$opt $CFLAGS"
1028 AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1029 AC_LINK_IFELSE([PTHREADTEST_SRC],
1030 [AC_MSG_RESULT([yes])
1031 NO_PTHREADS=
1032 PTHREAD_LIBS="$opt"
1033 PTHREAD_CFLAGS="$opt"
1034 threads_found=yes
1035 break
1036 ],
1037 [AC_MSG_RESULT([no])])
1038 CFLAGS="$old_CFLAGS"
1039 done
1040 if test $threads_found != yes; then
1041 AC_CHECK_LIB([pthread], [pthread_create],
1042 [PTHREAD_LIBS="-lpthread"],
1043 [NO_PTHREADS=UnfortunatelyYes])
1044 fi
1045 else
1046 old_CFLAGS="$CFLAGS"
1047 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1048 AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1049 AC_LINK_IFELSE([PTHREADTEST_SRC],
1050 [AC_MSG_RESULT([yes])
1051 NO_PTHREADS=
1052 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1053 ],
1054 [AC_MSG_RESULT([no])])
1056 CFLAGS="$old_CFLAGS"
1057 fi
1059 CFLAGS="$old_CFLAGS"
1061 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1062 GIT_CONF_SUBST([PTHREAD_LIBS])
1063 GIT_CONF_SUBST([NO_PTHREADS])
1065 ## Output files
1066 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1067 AC_OUTPUT