git-gui/git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86         if {[tk windowingsystem] eq "win32"} { console show }
  87 }
  88
  89 ######################################################################
  90 ##
  91 ## Internationalization (i18n) through msgcat and gettext. See
  92 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  93
  94 package require msgcat
  95
  96 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
  97 if {[tk windowingsystem] eq "win32"
  98         && [package vcompare [package provide msgcat] 1.4.4] < 0
  99 } then {
 100         proc _mc_update_locale {} {
 101                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 102                 if {![catch {
 103                         package require registry
 104                         set uilocale [registry get $key "PreferredUILanguages"]
 105                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 106                 } uilocale]} {
 107                         if {[string length $uilocale] > 0} {
 108                                 msgcat::mclocale $uilocale
 109                         }
 110                 }
 111         }
 112         _mc_update_locale
 113 }
 114
 115 proc _mc_trim {fmt} {
 116         set cmk [string first @@ $fmt]
 117         if {$cmk > 0} {
 118                 return [string range $fmt 0 [expr {$cmk - 1}]]
 119         }
 120         return $fmt
 121 }
 122
 123 proc mc {en_fmt args} {
 124         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 125         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 126                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 127         }
 128         return $msg
 129 }
 130
 131 proc strcat {args} {
 132         return [join $args {}]
 133 }
 134
 135 ::msgcat::mcload $oguimsg
 136 unset oguimsg
 137
 138 ######################################################################
 139 ##
 140 ## On Mac, bring the current Wish process window to front
 141
 142 if {[tk windowingsystem] eq "aqua"} {
 143         catch {
 144                 exec osascript -e [format {
 145                         tell application "System Events"
 146                                 set frontmost of processes whose unix id is %d to true
 147                         end tell
 148                 } [pid]]
 149         }
 150 }
 151
 152 ######################################################################
 153 ##
 154 ## read only globals
 155
 156 set _appname {Git Gui}
 157 set _gitdir {}
 158 set _gitworktree {}
 159 set _isbare {}
 160 set _gitexec {}
 161 set _githtmldir {}
 162 set _reponame {}
 163 set _iscygwin {}
 164 set _search_path {}
 165 set _shellpath {@@SHELL_PATH@@}
 166
 167 set _trace [lsearch -exact $argv --trace]
 168 if {$_trace >= 0} {
 169         set argv [lreplace $argv $_trace $_trace]
 170         set _trace 1
 171         if {[tk windowingsystem] eq "win32"} { console show }
 172 } else {
 173         set _trace 0
 174 }
 175
 176 # variable for the last merged branch (useful for a default when deleting
 177 # branches).
 178 set _last_merged_branch {}
 179
 180 proc shellpath {} {
 181         global _shellpath env
 182         if {[string match @@* $_shellpath]} {
 183                 if {[info exists env(SHELL)]} {
 184                         return $env(SHELL)
 185                 } else {
 186                         return /bin/sh
 187                 }
 188         }
 189         return $_shellpath
 190 }
 191
 192 proc appname {} {
 193         global _appname
 194         return $_appname
 195 }
 196
 197 proc gitdir {args} {
 198         global _gitdir
 199         if {$args eq {}} {
 200                 return $_gitdir
 201         }
 202         return [eval [list file join $_gitdir] $args]
 203 }
 204
 205 proc gitexec {args} {
 206         global _gitexec
 207         if {$_gitexec eq {}} {
 208                 if {[catch {set _gitexec [git --exec-path]} err]} {
 209                         error "Git not installed?\n\n$err"
 210                 }
 211                 if {[is_Cygwin]} {
 212                         set _gitexec [exec cygpath \
 213                                 --windows \
 214                                 --absolute \
 215                                 $_gitexec]
 216                 } else {
 217                         set _gitexec [file normalize $_gitexec]
 218                 }
 219         }
 220         if {$args eq {}} {
 221                 return $_gitexec
 222         }
 223         return [eval [list file join $_gitexec] $args]
 224 }
 225
 226 proc githtmldir {args} {
 227         global _githtmldir
 228         if {$_githtmldir eq {}} {
 229                 if {[catch {set _githtmldir [git --html-path]}]} {
 230                         # Git not installed or option not yet supported
 231                         return {}
 232                 }
 233                 if {[is_Cygwin]} {
 234                         set _githtmldir [exec cygpath \
 235                                 --windows \
 236                                 --absolute \
 237                                 $_githtmldir]
 238                 } else {
 239                         set _githtmldir [file normalize $_githtmldir]
 240                 }
 241         }
 242         if {$args eq {}} {
 243                 return $_githtmldir
 244         }
 245         return [eval [list file join $_githtmldir] $args]
 246 }
 247
 248 proc reponame {} {
 249         return $::_reponame
 250 }
 251
 252 proc is_MacOSX {} {
 253         if {[tk windowingsystem] eq {aqua}} {
 254                 return 1
 255         }
 256         return 0
 257 }
 258
 259 proc is_Windows {} {
 260         if {$::tcl_platform(platform) eq {windows}} {
 261                 return 1
 262         }
 263         return 0
 264 }
 265
 266 proc is_Cygwin {} {
 267         global _iscygwin
 268         if {$_iscygwin eq {}} {
 269                 if {$::tcl_platform(platform) eq {windows}} {
 270                         if {[catch {set p [exec cygpath --windir]} err]} {
 271                                 set _iscygwin 0
 272                         } else {
 273                                 set _iscygwin 1
 274                         }
 275                 } else {
 276                         set _iscygwin 0
 277                 }
 278         }
 279         return $_iscygwin
 280 }
 281
 282 proc is_enabled {option} {
 283         global enabled_options
 284         if {[catch {set on $enabled_options($option)}]} {return 0}
 285         return $on
 286 }
 287
 288 proc enable_option {option} {
 289         global enabled_options
 290         set enabled_options($option) 1
 291 }
 292
 293 proc disable_option {option} {
 294         global enabled_options
 295         set enabled_options($option) 0
 296 }
 297
 298 ######################################################################
 299 ##
 300 ## config
 301
 302 proc is_many_config {name} {
 303         switch -glob -- $name {
 304         gui.recentrepo -
 305         remote.*.fetch -
 306         remote.*.push
 307                 {return 1}
 308         *
 309                 {return 0}
 310         }
 311 }
 312
 313 proc is_config_true {name} {
 314         global repo_config
 315         if {[catch {set v $repo_config($name)}]} {
 316                 return 0
 317         }
 318         set v [string tolower $v]
 319         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 320                 return 1
 321         } else {
 322                 return 0
 323         }
 324 }
 325
 326 proc is_config_false {name} {
 327         global repo_config
 328         if {[catch {set v $repo_config($name)}]} {
 329                 return 0
 330         }
 331         set v [string tolower $v]
 332         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 333                 return 1
 334         } else {
 335                 return 0
 336         }
 337 }
 338
 339 proc get_config {name} {
 340         global repo_config
 341         if {[catch {set v $repo_config($name)}]} {
 342                 return {}
 343         } else {
 344                 return $v
 345         }
 346 }
 347
 348 proc is_bare {} {
 349         global _isbare
 350         global _gitdir
 351         global _gitworktree
 352
 353         if {$_isbare eq {}} {
 354                 if {[catch {
 355                         set _bare [git rev-parse --is-bare-repository]
 356                         switch  -- $_bare {
 357                         true { set _isbare 1 }
 358                         false { set _isbare 0}
 359                         default { throw }
 360                         }
 361                 }]} {
 362                         if {[is_config_true core.bare]
 363                                 || ($_gitworktree eq {}
 364                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 365                                 set _isbare 1
 366                         } else {
 367                                 set _isbare 0
 368                         }
 369                 }
 370         }
 371         return $_isbare
 372 }
 373
 374 ######################################################################
 375 ##
 376 ## handy utils
 377
 378 proc _trace_exec {cmd} {
 379         if {!$::_trace} return
 380         set d {}
 381         foreach v $cmd {
 382                 if {$d ne {}} {
 383                         append d { }
 384                 }
 385                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 386                         set v [sq $v]
 387                 }
 388                 append d $v
 389         }
 390         puts stderr $d
 391 }
 392
 393 #'"  fix poor old emacs font-lock mode
 394
 395 proc _git_cmd {name} {
 396         global _git_cmd_path
 397
 398         if {[catch {set v $_git_cmd_path($name)}]} {
 399                 switch -- $name {
 400                   version   -
 401                 --version   -
 402                 --exec-path { return [list $::_git $name] }
 403                 }
 404
 405                 set p [gitexec git-$name$::_search_exe]
 406                 if {[file exists $p]} {
 407                         set v [list $p]
 408                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 409                         # Try to determine what sort of magic will make
 410                         # git-$name go and do its thing, because native
 411                         # Tcl on Windows doesn't know it.
 412                         #
 413                         set p [gitexec git-$name]
 414                         set f [open $p r]
 415                         set s [gets $f]
 416                         close $f
 417
 418                         switch -glob -- [lindex $s 0] {
 419                         #!*sh     { set i sh     }
 420                         #!*perl   { set i perl   }
 421                         #!*python { set i python }
 422                         default   { error "git-$name is not supported: $s" }
 423                         }
 424
 425                         upvar #0 _$i interp
 426                         if {![info exists interp]} {
 427                                 set interp [_which $i]
 428                         }
 429                         if {$interp eq {}} {
 430                                 error "git-$name requires $i (not in PATH)"
 431                         }
 432                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 433                 } else {
 434                         # Assume it is builtin to git somehow and we
 435                         # aren't actually able to see a file for it.
 436                         #
 437                         set v [list $::_git $name]
 438                 }
 439                 set _git_cmd_path($name) $v
 440         }
 441         return $v
 442 }
 443
 444 proc _which {what args} {
 445         global env _search_exe _search_path
 446
 447         if {$_search_path eq {}} {
 448                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 449                         set _search_path [split [exec cygpath \
 450                                 --windows \
 451                                 --path \
 452                                 --absolute \
 453                                 $env(PATH)] {;}]
 454                         set _search_exe .exe
 455                 } elseif {[is_Windows]} {
 456                         set gitguidir [file dirname [info script]]
 457                         regsub -all ";" $gitguidir "\\;" gitguidir
 458                         set env(PATH) "$gitguidir;$env(PATH)"
 459                         set _search_path [split $env(PATH) {;}]
 460                         set _search_exe .exe
 461                 } else {
 462                         set _search_path [split $env(PATH) :]
 463                         set _search_exe {}
 464                 }
 465         }
 466
 467         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 468                 set suffix {}
 469         } else {
 470                 set suffix $_search_exe
 471         }
 472
 473         foreach p $_search_path {
 474                 set p [file join $p $what$suffix]
 475                 if {[file exists $p]} {
 476                         return [file normalize $p]
 477                 }
 478         }
 479         return {}
 480 }
 481
 482 # Test a file for a hashbang to identify executable scripts on Windows.
 483 proc is_shellscript {filename} {
 484         if {![file exists $filename]} {return 0}
 485         set f [open $filename r]
 486         fconfigure $f -encoding binary
 487         set magic [read $f 2]
 488         close $f
 489         return [expr {$magic eq "#!"}]
 490 }
 491
 492 # Run a command connected via pipes on stdout.
 493 # This is for use with textconv filters and uses sh -c "..." to allow it to
 494 # contain a command with arguments. On windows we must check for shell
 495 # scripts specifically otherwise just call the filter command.
 496 proc open_cmd_pipe {cmd path} {
 497         global env
 498         if {![file executable [shellpath]]} {
 499                 set exe [auto_execok [lindex $cmd 0]]
 500                 if {[is_shellscript [lindex $exe 0]]} {
 501                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 502                 } else {
 503                         set run [concat $exe [lrange $cmd 1 end] $path]
 504                 }
 505         } else {
 506                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 507         }
 508         return [open |$run r]
 509 }
 510
 511 proc _lappend_nice {cmd_var} {
 512         global _nice
 513         upvar $cmd_var cmd
 514
 515         if {![info exists _nice]} {
 516                 set _nice [_which nice]
 517                 if {[catch {exec $_nice git version}]} {
 518                         set _nice {}
 519                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 520                         set _nice {}
 521                 }
 522         }
 523         if {$_nice ne {}} {
 524                 lappend cmd $_nice
 525         }
 526 }
 527
 528 proc git {args} {
 529         set opt [list]
 530
 531         while {1} {
 532                 switch -- [lindex $args 0] {
 533                 --nice {
 534                         _lappend_nice opt
 535                 }
 536
 537                 default {
 538                         break
 539                 }
 540
 541                 }
 542
 543                 set args [lrange $args 1 end]
 544         }
 545
 546         set cmdp [_git_cmd [lindex $args 0]]
 547         set args [lrange $args 1 end]
 548
 549         _trace_exec [concat $opt $cmdp $args]
 550         set result [eval exec $opt $cmdp $args]
 551         if {[encoding system] != "utf-8"} {
 552                 set result [encoding convertfrom utf-8 [encoding convertto $result]]
 553         }
 554         if {$::_trace} {
 555                 puts stderr "< $result"
 556         }
 557         return $result
 558 }
 559
 560 proc _open_stdout_stderr {cmd} {
 561         _trace_exec $cmd
 562         if {[catch {
 563                         set fd [open [concat [list | ] $cmd] r]
 564                 } err]} {
 565                 if {   [lindex $cmd end] eq {2>@1}
 566                     && $err eq {can not find channel named "1"}
 567                         } {
 568                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 569                         # redirect operator.  Fallback to |& cat for those.
 570                         # The command was not actually started, so its safe
 571                         # to try to start it a second time.
 572                         #
 573                         set fd [open [concat \
 574                                 [list | ] \
 575                                 [lrange $cmd 0 end-1] \
 576                                 [list |& cat] \
 577                                 ] r]
 578                 } else {
 579                         error $err
 580                 }
 581         }
 582         fconfigure $fd -eofchar {}
 583         return $fd
 584 }
 585
 586 proc git_read {args} {
 587         set opt [list]
 588
 589         while {1} {
 590                 switch -- [lindex $args 0] {
 591                 --nice {
 592                         _lappend_nice opt
 593                 }
 594
 595                 --stderr {
 596                         lappend args 2>@1
 597                 }
 598
 599                 default {
 600                         break
 601                 }
 602
 603                 }
 604
 605                 set args [lrange $args 1 end]
 606         }
 607
 608         set cmdp [_git_cmd [lindex $args 0]]
 609         set args [lrange $args 1 end]
 610
 611         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 612 }
 613
 614 proc git_write {args} {
 615         set opt [list]
 616
 617         while {1} {
 618                 switch -- [lindex $args 0] {
 619                 --nice {
 620                         _lappend_nice opt
 621                 }
 622
 623                 default {
 624                         break
 625                 }
 626
 627                 }
 628
 629                 set args [lrange $args 1 end]
 630         }
 631
 632         set cmdp [_git_cmd [lindex $args 0]]
 633         set args [lrange $args 1 end]
 634
 635         _trace_exec [concat $opt $cmdp $args]
 636         return [open [concat [list | ] $opt $cmdp $args] w]
 637 }
 638
 639 proc githook_read {hook_name args} {
 640         set pchook [gitdir hooks $hook_name]
 641         lappend args 2>@1
 642
 643         # On Windows [file executable] might lie so we need to ask
 644         # the shell if the hook is executable.  Yes that's annoying.
 645         #
 646         if {[is_Windows]} {
 647                 upvar #0 _sh interp
 648                 if {![info exists interp]} {
 649                         set interp [_which sh]
 650                 }
 651                 if {$interp eq {}} {
 652                         error "hook execution requires sh (not in PATH)"
 653                 }
 654
 655                 set scr {if test -x "$1";then exec "$@";fi}
 656                 set sh_c [list $interp -c $scr $interp $pchook]
 657                 return [_open_stdout_stderr [concat $sh_c $args]]
 658         }
 659
 660         if {[file executable $pchook]} {
 661                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 662         }
 663
 664         return {}
 665 }
 666
 667 proc kill_file_process {fd} {
 668         set process [pid $fd]
 669
 670         catch {
 671                 if {[is_Windows]} {
 672                         # Use a Cygwin-specific flag to allow killing
 673                         # native Windows processes
 674                         exec kill -f $process
 675                 } else {
 676                         exec kill $process
 677                 }
 678         }
 679 }
 680
 681 proc gitattr {path attr default} {
 682         if {[catch {set r [git check-attr $attr -- $path]}]} {
 683                 set r unspecified
 684         } else {
 685                 set r [join [lrange [split $r :] 2 end] :]
 686                 regsub {^ } $r {} r
 687         }
 688         if {$r eq {unspecified}} {
 689                 return $default
 690         }
 691         return $r
 692 }
 693
 694 proc sq {value} {
 695         regsub -all ' $value "'\\''" value
 696         return "'$value'"
 697 }
 698
 699 proc load_current_branch {} {
 700         global current_branch is_detached
 701
 702         set fd [open [gitdir HEAD] r]
 703         if {[gets $fd ref] < 1} {
 704                 set ref {}
 705         }
 706         close $fd
 707
 708         set pfx {ref: refs/heads/}
 709         set len [string length $pfx]
 710         if {[string equal -length $len $pfx $ref]} {
 711                 # We're on a branch.  It might not exist.  But
 712                 # HEAD looks good enough to be a branch.
 713                 #
 714                 set current_branch [string range $ref $len end]
 715                 set is_detached 0
 716         } else {
 717                 # Assume this is a detached head.
 718                 #
 719                 set current_branch HEAD
 720                 set is_detached 1
 721         }
 722 }
 723
 724 auto_load tk_optionMenu
 725 rename tk_optionMenu real__tkOptionMenu
 726 proc tk_optionMenu {w varName args} {
 727         set m [eval real__tkOptionMenu $w $varName $args]
 728         $m configure -font font_ui
 729         $w configure -font font_ui
 730         return $m
 731 }
 732
 733 proc rmsel_tag {text} {
 734         $text tag conf sel \
 735                 -background [$text cget -background] \
 736                 -foreground [$text cget -foreground] \
 737                 -borderwidth 0
 738         $text tag conf in_sel -background lightgray
 739         bind $text <Motion> break
 740         return $text
 741 }
 742
 743 wm withdraw .
 744 set root_exists 0
 745 bind . <Visibility> {
 746         bind . <Visibility> {}
 747         set root_exists 1
 748 }
 749
 750 if {[is_Windows]} {
 751         wm iconbitmap . -default $oguilib/git-gui.ico
 752         set ::tk::AlwaysShowSelection 1
 753         bind . <Control-F2> {console show}
 754
 755         # Spoof an X11 display for SSH
 756         if {![info exists env(DISPLAY)]} {
 757                 set env(DISPLAY) :9999
 758         }
 759 } else {
 760         catch {
 761                 image create photo gitlogo -width 16 -height 16
 762
 763                 gitlogo put #33CC33 -to  7  0  9  2
 764                 gitlogo put #33CC33 -to  4  2 12  4
 765                 gitlogo put #33CC33 -to  7  4  9  6
 766                 gitlogo put #CC3333 -to  4  6 12  8
 767                 gitlogo put gray26  -to  4  9  6 10
 768                 gitlogo put gray26  -to  3 10  6 12
 769                 gitlogo put gray26  -to  8  9 13 11
 770                 gitlogo put gray26  -to  8 11 10 12
 771                 gitlogo put gray26  -to 11 11 13 14
 772                 gitlogo put gray26  -to  3 12  5 14
 773                 gitlogo put gray26  -to  5 13
 774                 gitlogo put gray26  -to 10 13
 775                 gitlogo put gray26  -to  4 14 12 15
 776                 gitlogo put gray26  -to  5 15 11 16
 777                 gitlogo redither
 778
 779                 image create photo gitlogo32 -width 32 -height 32
 780                 gitlogo32 copy gitlogo -zoom 2 2
 781
 782                 wm iconphoto . -default gitlogo gitlogo32
 783         }
 784 }
 785
 786 ######################################################################
 787 ##
 788 ## config defaults
 789
 790 set cursor_ptr arrow
 791 font create font_ui
 792 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 793         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 794         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 795 } else {
 796         font create font_diff -family Courier -size 10
 797         catch {
 798                 label .dummy
 799                 eval font configure font_ui [font actual [.dummy cget -font]]
 800                 destroy .dummy
 801         }
 802 }
 803
 804 font create font_uiitalic
 805 font create font_uibold
 806 font create font_diffbold
 807 font create font_diffitalic
 808
 809 foreach class {Button Checkbutton Entry Label
 810                 Labelframe Listbox Message
 811                 Radiobutton Spinbox Text} {
 812         option add *$class.font font_ui
 813 }
 814 if {![is_MacOSX]} {
 815         option add *Menu.font font_ui
 816         option add *Entry.borderWidth 1 startupFile
 817         option add *Entry.relief sunken startupFile
 818         option add *RadioButton.anchor w startupFile
 819 }
 820 unset class
 821
 822 if {[is_Windows] || [is_MacOSX]} {
 823         option add *Menu.tearOff 0
 824 }
 825
 826 if {[is_MacOSX]} {
 827         set M1B M1
 828         set M1T Cmd
 829 } else {
 830         set M1B Control
 831         set M1T Ctrl
 832 }
 833
 834 proc bind_button3 {w cmd} {
 835         bind $w <Any-Button-3> $cmd
 836         if {[is_MacOSX]} {
 837                 # Mac OS X sends Button-2 on right click through three-button mouse,
 838                 # or through trackpad right-clicking (two-finger touch + click).
 839                 bind $w <Any-Button-2> $cmd
 840                 bind $w <Control-Button-1> $cmd
 841         }
 842 }
 843
 844 proc apply_config {} {
 845         global repo_config font_descs
 846
 847         foreach option $font_descs {
 848                 set name [lindex $option 0]
 849                 set font [lindex $option 1]
 850                 if {[catch {
 851                         set need_weight 1
 852                         foreach {cn cv} $repo_config(gui.$name) {
 853                                 if {$cn eq {-weight}} {
 854                                         set need_weight 0
 855                                 }
 856                                 font configure $font $cn $cv
 857                         }
 858                         if {$need_weight} {
 859                                 font configure $font -weight normal
 860                         }
 861                         } err]} {
 862                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 863                 }
 864                 foreach {cn cv} [font configure $font] {
 865                         font configure ${font}bold $cn $cv
 866                         font configure ${font}italic $cn $cv
 867                 }
 868                 font configure ${font}bold -weight bold
 869                 font configure ${font}italic -slant italic
 870         }
 871
 872         global use_ttk NS
 873         set use_ttk 0
 874         set NS {}
 875         if {$repo_config(gui.usettk)} {
 876                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 877                 if {$use_ttk} {
 878                         set NS ttk
 879                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 880                         pave_toplevel .
 881                 }
 882         }
 883 }
 884
 885 set default_config(branch.autosetupmerge) true
 886 set default_config(merge.tool) {}
 887 set default_config(mergetool.keepbackup) true
 888 set default_config(merge.diffstat) true
 889 set default_config(merge.summary) false
 890 set default_config(merge.verbosity) 2
 891 set default_config(user.name) {}
 892 set default_config(user.email) {}
 893
 894 set default_config(gui.encoding) [encoding system]
 895 set default_config(gui.matchtrackingbranch) false
 896 set default_config(gui.textconv) true
 897 set default_config(gui.pruneduringfetch) false
 898 set default_config(gui.trustmtime) false
 899 set default_config(gui.fastcopyblame) false
 900 set default_config(gui.maxrecentrepo) 10
 901 set default_config(gui.copyblamethreshold) 40
 902 set default_config(gui.blamehistoryctx) 7
 903 set default_config(gui.diffcontext) 5
 904 set default_config(gui.diffopts) {}
 905 set default_config(gui.commitmsgwidth) 75
 906 set default_config(gui.newbranchtemplate) {}
 907 set default_config(gui.spellingdictionary) {}
 908 set default_config(gui.fontui) [font configure font_ui]
 909 set default_config(gui.fontdiff) [font configure font_diff]
 910 # TODO: this option should be added to the git-config documentation
 911 set default_config(gui.maxfilesdisplayed) 5000
 912 set default_config(gui.usettk) 1
 913 set default_config(gui.warndetachedcommit) 1
 914 set font_descs {
 915         {fontui   font_ui   {mc "Main Font"}}
 916         {fontdiff font_diff {mc "Diff/Console Font"}}
 917 }
 918 set default_config(gui.stageuntracked) ask
 919 set default_config(gui.displayuntracked) true
 920
 921 ######################################################################
 922 ##
 923 ## find git
 924
 925 set _git  [_which git]
 926 if {$_git eq {}} {
 927         catch {wm withdraw .}
 928         tk_messageBox \
 929                 -icon error \
 930                 -type ok \
 931                 -title [mc "git-gui: fatal error"] \
 932                 -message [mc "Cannot find git in PATH."]
 933         exit 1
 934 }
 935
 936 ######################################################################
 937 ##
 938 ## version check
 939
 940 if {[catch {set _git_version [git --version]} err]} {
 941         catch {wm withdraw .}
 942         tk_messageBox \
 943                 -icon error \
 944                 -type ok \
 945                 -title [mc "git-gui: fatal error"] \
 946                 -message "Cannot determine Git version:
 947
 948 $err
 949
 950 [appname] requires Git 1.5.0 or later."
 951         exit 1
 952 }
 953 if {![regsub {^git version } $_git_version {} _git_version]} {
 954         catch {wm withdraw .}
 955         tk_messageBox \
 956                 -icon error \
 957                 -type ok \
 958                 -title [mc "git-gui: fatal error"] \
 959                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 960         exit 1
 961 }
 962
 963 proc get_trimmed_version {s} {
 964     set r {}
 965     foreach x [split $s -._] {
 966         if {[string is integer -strict $x]} {
 967             lappend r $x
 968         } else {
 969             break
 970         }
 971     }
 972     return [join $r .]
 973 }
 974 set _real_git_version $_git_version
 975 set _git_version [get_trimmed_version $_git_version]
 976
 977 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 978         catch {wm withdraw .}
 979         if {[tk_messageBox \
 980                 -icon warning \
 981                 -type yesno \
 982                 -default no \
 983                 -title "[appname]: warning" \
 984                  -message [mc "Git version cannot be determined.
 985
 986 %s claims it is version '%s'.
 987
 988 %s requires at least Git 1.5.0 or later.
 989
 990 Assume '%s' is version 1.5.0?
 991 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 992                 set _git_version 1.5.0
 993         } else {
 994                 exit 1
 995         }
 996 }
 997 unset _real_git_version
 998
 999 proc git-version {args} {
1000         global _git_version
1001
1002         switch [llength $args] {
1003         0 {
1004                 return $_git_version
1005         }
1006
1007         2 {
1008                 set op [lindex $args 0]
1009                 set vr [lindex $args 1]
1010                 set cm [package vcompare $_git_version $vr]
1011                 return [expr $cm $op 0]
1012         }
1013
1014         4 {
1015                 set type [lindex $args 0]
1016                 set name [lindex $args 1]
1017                 set parm [lindex $args 2]
1018                 set body [lindex $args 3]
1019
1020                 if {($type ne {proc} && $type ne {method})} {
1021                         error "Invalid arguments to git-version"
1022                 }
1023                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1024                         error "Last arm of $type $name must be default"
1025                 }
1026
1027                 foreach {op vr cb} [lrange $body 0 end-2] {
1028                         if {[git-version $op $vr]} {
1029                                 return [uplevel [list $type $name $parm $cb]]
1030                         }
1031                 }
1032
1033                 return [uplevel [list $type $name $parm [lindex $body end]]]
1034         }
1035
1036         default {
1037                 error "git-version >= x"
1038         }
1039
1040         }
1041 }
1042
1043 if {[git-version < 1.5]} {
1044         catch {wm withdraw .}
1045         tk_messageBox \
1046                 -icon error \
1047                 -type ok \
1048                 -title [mc "git-gui: fatal error"] \
1049                 -message "[appname] requires Git 1.5.0 or later.
1050
1051 You are using [git-version]:
1052
1053 [git --version]"
1054         exit 1
1055 }
1056
1057 ######################################################################
1058 ##
1059 ## configure our library
1060
1061 set idx [file join $oguilib tclIndex]
1062 if {[catch {set fd [open $idx r]} err]} {
1063         catch {wm withdraw .}
1064         tk_messageBox \
1065                 -icon error \
1066                 -type ok \
1067                 -title [mc "git-gui: fatal error"] \
1068                 -message $err
1069         exit 1
1070 }
1071 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1072         set idx [list]
1073         while {[gets $fd n] >= 0} {
1074                 if {$n ne {} && ![string match #* $n]} {
1075                         lappend idx $n
1076                 }
1077         }
1078 } else {
1079         set idx {}
1080 }
1081 close $fd
1082
1083 if {$idx ne {}} {
1084         set loaded [list]
1085         foreach p $idx {
1086                 if {[lsearch -exact $loaded $p] >= 0} continue
1087                 source [file join $oguilib $p]
1088                 lappend loaded $p
1089         }
1090         unset loaded p
1091 } else {
1092         set auto_path [concat [list $oguilib] $auto_path]
1093 }
1094 unset -nocomplain idx fd
1095
1096 ######################################################################
1097 ##
1098 ## config file parsing
1099
1100 git-version proc _parse_config {arr_name args} {
1101         >= 1.5.3 {
1102                 upvar $arr_name arr
1103                 array unset arr
1104                 set buf {}
1105                 catch {
1106                         set fd_rc [eval \
1107                                 [list git_read config] \
1108                                 $args \
1109                                 [list --null --list]]
1110                         fconfigure $fd_rc -translation binary -encoding utf-8
1111                         set buf [read $fd_rc]
1112                         close $fd_rc
1113                 }
1114                 foreach line [split $buf "\0"] {
1115                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1116                                 if {[is_many_config $name]} {
1117                                         lappend arr($name) $value
1118                                 } else {
1119                                         set arr($name) $value
1120                                 }
1121                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1122                                 # no value given, but interpreting them as
1123                                 # boolean will be handled as true
1124                                 set arr($name) {}
1125                         }
1126                 }
1127         }
1128         default {
1129                 upvar $arr_name arr
1130                 array unset arr
1131                 catch {
1132                         set fd_rc [eval [list git_read config --list] $args]
1133                         while {[gets $fd_rc line] >= 0} {
1134                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1135                                         if {[is_many_config $name]} {
1136                                                 lappend arr($name) $value
1137                                         } else {
1138                                                 set arr($name) $value
1139                                         }
1140                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1141                                         # no value given, but interpreting them as
1142                                         # boolean will be handled as true
1143                                         set arr($name) {}
1144                                 }
1145                         }
1146                         close $fd_rc
1147                 }
1148         }
1149 }
1150
1151 proc load_config {include_global} {
1152         global repo_config global_config system_config default_config
1153
1154         if {$include_global} {
1155                 _parse_config system_config --system
1156                 _parse_config global_config --global
1157         }
1158         _parse_config repo_config
1159
1160         foreach name [array names default_config] {
1161                 if {[catch {set v $system_config($name)}]} {
1162                         set system_config($name) $default_config($name)
1163                 }
1164         }
1165         foreach name [array names system_config] {
1166                 if {[catch {set v $global_config($name)}]} {
1167                         set global_config($name) $system_config($name)
1168                 }
1169                 if {[catch {set v $repo_config($name)}]} {
1170                         set repo_config($name) $system_config($name)
1171                 }
1172         }
1173 }
1174
1175 ######################################################################
1176 ##
1177 ## feature option selection
1178
1179 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1180         unset _junk
1181 } else {
1182         set subcommand gui
1183 }
1184 if {$subcommand eq {gui.sh}} {
1185         set subcommand gui
1186 }
1187 if {$subcommand eq {gui} && [llength $argv] > 0} {
1188         set subcommand [lindex $argv 0]
1189         set argv [lrange $argv 1 end]
1190 }
1191
1192 enable_option multicommit
1193 enable_option branch
1194 enable_option transport
1195 disable_option bare
1196
1197 switch -- $subcommand {
1198 browser -
1199 blame {
1200         enable_option bare
1201
1202         disable_option multicommit
1203         disable_option branch
1204         disable_option transport
1205 }
1206 citool {
1207         enable_option singlecommit
1208         enable_option retcode
1209
1210         disable_option multicommit
1211         disable_option branch
1212         disable_option transport
1213
1214         while {[llength $argv] > 0} {
1215                 set a [lindex $argv 0]
1216                 switch -- $a {
1217                 --amend {
1218                         enable_option initialamend
1219                 }
1220                 --nocommit {
1221                         enable_option nocommit
1222                         enable_option nocommitmsg
1223                 }
1224                 --commitmsg {
1225                         disable_option nocommitmsg
1226                 }
1227                 default {
1228                         break
1229                 }
1230                 }
1231
1232                 set argv [lrange $argv 1 end]
1233         }
1234 }
1235 }
1236
1237 ######################################################################
1238 ##
1239 ## execution environment
1240
1241 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1242
1243 # Suggest our implementation of askpass, if none is set
1244 if {![info exists env(SSH_ASKPASS)]} {
1245         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1246 }
1247 if {![info exists env(GIT_ASKPASS)]} {
1248         set env(GIT_ASKPASS) [gitexec git-gui--askpass]
1249 }
1250 if {![info exists env(GIT_ASK_YESNO)]} {
1251         set env(GIT_ASK_YESNO) [gitexec git-gui--askyesno]
1252 }
1253
1254 ######################################################################
1255 ##
1256 ## repository setup
1257
1258 set picked 0
1259 if {[catch {
1260                 set _gitdir $env(GIT_DIR)
1261                 set _prefix {}
1262                 }]
1263         && [catch {
1264                 # beware that from the .git dir this sets _gitdir to .
1265                 # and _prefix to the empty string
1266                 set _gitdir [git rev-parse --git-dir]
1267                 set _prefix [git rev-parse --show-prefix]
1268         } err]} {
1269         load_config 1
1270         apply_config
1271         choose_repository::pick
1272         set picked 1
1273 }
1274
1275 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1276 # run from the .git dir itself) lest the routines to find the worktree
1277 # get confused
1278 if {$_gitdir eq "."} {
1279         set _gitdir [pwd]
1280 }
1281
1282 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1283         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1284 }
1285 if {![file isdirectory $_gitdir]} {
1286         catch {wm withdraw .}
1287         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1288         exit 1
1289 }
1290 # _gitdir exists, so try loading the config
1291 load_config 0
1292 apply_config
1293
1294 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1295 if {[package vsatisfies $_git_version 1.7.0-]} {
1296         if { [is_Cygwin] } {
1297                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1298         } else {
1299                 set _gitworktree [git rev-parse --show-toplevel]
1300         }
1301 } else {
1302         # try to set work tree from environment, core.worktree or use
1303         # cdup to obtain a relative path to the top of the worktree. If
1304         # run from the top, the ./ prefix ensures normalize expands pwd.
1305         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1306                 set _gitworktree [get_config core.worktree]
1307                 if {$_gitworktree eq ""} {
1308                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1309                 }
1310         }
1311 }
1312
1313 if {$_prefix ne {}} {
1314         if {$_gitworktree eq {}} {
1315                 regsub -all {[^/]+/} $_prefix ../ cdup
1316         } else {
1317                 set cdup $_gitworktree
1318         }
1319         if {[catch {cd $cdup} err]} {
1320                 catch {wm withdraw .}
1321                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1322                 exit 1
1323         }
1324         set _gitworktree [pwd]
1325         unset cdup
1326 } elseif {![is_enabled bare]} {
1327         if {[is_bare]} {
1328                 catch {wm withdraw .}
1329                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1330                 exit 1
1331         }
1332         if {$_gitworktree eq {}} {
1333                 set _gitworktree [file dirname $_gitdir]
1334         }
1335         if {[catch {cd $_gitworktree} err]} {
1336                 catch {wm withdraw .}
1337                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1338                 exit 1
1339         }
1340         set _gitworktree [pwd]
1341 }
1342 set _reponame [file split [file normalize $_gitdir]]
1343 if {[lindex $_reponame end] eq {.git}} {
1344         set _reponame [lindex $_reponame end-1]
1345 } else {
1346         set _reponame [lindex $_reponame end]
1347 }
1348
1349 ######################################################################
1350 ##
1351 ## global init
1352
1353 set current_diff_path {}
1354 set current_diff_side {}
1355 set diff_actions [list]
1356
1357 set HEAD {}
1358 set PARENT {}
1359 set MERGE_HEAD [list]
1360 set commit_type {}
1361 set empty_tree {}
1362 set current_branch {}
1363 set is_detached 0
1364 set current_diff_path {}
1365 set is_3way_diff 0
1366 set is_submodule_diff 0
1367 set is_conflict_diff 0
1368 set selected_commit_type new
1369 set diff_empty_count 0
1370
1371 set nullid "0000000000000000000000000000000000000000"
1372 set nullid2 "0000000000000000000000000000000000000001"
1373
1374 ######################################################################
1375 ##
1376 ## task management
1377
1378 set rescan_active 0
1379 set diff_active 0
1380 set last_clicked {}
1381
1382 set disable_on_lock [list]
1383 set index_lock_type none
1384
1385 proc lock_index {type} {
1386         global index_lock_type disable_on_lock
1387
1388         if {$index_lock_type eq {none}} {
1389                 set index_lock_type $type
1390                 foreach w $disable_on_lock {
1391                         uplevel #0 $w disabled
1392                 }
1393                 return 1
1394         } elseif {$index_lock_type eq "begin-$type"} {
1395                 set index_lock_type $type
1396                 return 1
1397         }
1398         return 0
1399 }
1400
1401 proc unlock_index {} {
1402         global index_lock_type disable_on_lock
1403
1404         set index_lock_type none
1405         foreach w $disable_on_lock {
1406                 uplevel #0 $w normal
1407         }
1408 }
1409
1410 ######################################################################
1411 ##
1412 ## status
1413
1414 proc repository_state {ctvar hdvar mhvar} {
1415         global current_branch
1416         upvar $ctvar ct $hdvar hd $mhvar mh
1417
1418         set mh [list]
1419
1420         load_current_branch
1421         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1422                 set hd {}
1423                 set ct initial
1424                 return
1425         }
1426
1427         set merge_head [gitdir MERGE_HEAD]
1428         if {[file exists $merge_head]} {
1429                 set ct merge
1430                 set fd_mh [open $merge_head r]
1431                 while {[gets $fd_mh line] >= 0} {
1432                         lappend mh $line
1433                 }
1434                 close $fd_mh
1435                 return
1436         }
1437
1438         set ct normal
1439 }
1440
1441 proc PARENT {} {
1442         global PARENT empty_tree
1443
1444         set p [lindex $PARENT 0]
1445         if {$p ne {}} {
1446                 return $p
1447         }
1448         if {$empty_tree eq {}} {
1449                 set empty_tree [git mktree << {}]
1450         }
1451         return $empty_tree
1452 }
1453
1454 proc force_amend {} {
1455         global selected_commit_type
1456         global HEAD PARENT MERGE_HEAD commit_type
1457
1458         repository_state newType newHEAD newMERGE_HEAD
1459         set HEAD $newHEAD
1460         set PARENT $newHEAD
1461         set MERGE_HEAD $newMERGE_HEAD
1462         set commit_type $newType
1463
1464         set selected_commit_type amend
1465         do_select_commit_type
1466 }
1467
1468 proc rescan {after {honor_trustmtime 1}} {
1469         global HEAD PARENT MERGE_HEAD commit_type
1470         global ui_index ui_workdir ui_comm
1471         global rescan_active file_states
1472         global repo_config
1473
1474         if {$rescan_active > 0 || ![lock_index read]} return
1475
1476         repository_state newType newHEAD newMERGE_HEAD
1477         if {[string match amend* $commit_type]
1478                 && $newType eq {normal}
1479                 && $newHEAD eq $HEAD} {
1480         } else {
1481                 set HEAD $newHEAD
1482                 set PARENT $newHEAD
1483                 set MERGE_HEAD $newMERGE_HEAD
1484                 set commit_type $newType
1485         }
1486
1487         array unset file_states
1488
1489         if {!$::GITGUI_BCK_exists &&
1490                 (![$ui_comm edit modified]
1491                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1492                 if {[string match amend* $commit_type]} {
1493                 } elseif {[load_message GITGUI_MSG utf-8]} {
1494                 } elseif {[run_prepare_commit_msg_hook]} {
1495                 } elseif {[load_message MERGE_MSG]} {
1496                 } elseif {[load_message SQUASH_MSG]} {
1497                 }
1498                 $ui_comm edit reset
1499                 $ui_comm edit modified false
1500         }
1501
1502         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1503                 rescan_stage2 {} $after
1504         } else {
1505                 set rescan_active 1
1506                 ui_status [mc "Refreshing file status..."]
1507                 set fd_rf [git_read update-index \
1508                         -q \
1509                         --unmerged \
1510                         --ignore-missing \
1511                         --refresh \
1512                         ]
1513                 fconfigure $fd_rf -blocking 0 -translation binary
1514                 fileevent $fd_rf readable \
1515                         [list rescan_stage2 $fd_rf $after]
1516         }
1517 }
1518
1519 if {[is_Cygwin]} {
1520         set is_git_info_exclude {}
1521         proc have_info_exclude {} {
1522                 global is_git_info_exclude
1523
1524                 if {$is_git_info_exclude eq {}} {
1525                         if {[catch {exec test -f [gitdir info exclude]}]} {
1526                                 set is_git_info_exclude 0
1527                         } else {
1528                                 set is_git_info_exclude 1
1529                         }
1530                 }
1531                 return $is_git_info_exclude
1532         }
1533 } else {
1534         proc have_info_exclude {} {
1535                 return [file readable [gitdir info exclude]]
1536         }
1537 }
1538
1539 proc rescan_stage2 {fd after} {
1540         global rescan_active buf_rdi buf_rdf buf_rlo
1541
1542         if {$fd ne {}} {
1543                 read $fd
1544                 if {![eof $fd]} return
1545                 close $fd
1546         }
1547
1548         if {[package vsatisfies $::_git_version 1.6.3-]} {
1549                 set ls_others [list --exclude-standard]
1550         } else {
1551                 set ls_others [list --exclude-per-directory=.gitignore]
1552                 if {[have_info_exclude]} {
1553                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1554                 }
1555                 set user_exclude [get_config core.excludesfile]
1556                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1557                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1558                 }
1559         }
1560
1561         set buf_rdi {}
1562         set buf_rdf {}
1563         set buf_rlo {}
1564
1565         set rescan_active 2
1566         ui_status [mc "Scanning for modified files ..."]
1567         if {[git-version >= "1.7.2"]} {
1568                 set fd_di [git_read diff-index --cached --ignore-submodules=dirty -z [PARENT]]
1569         } else {
1570                 set fd_di [git_read diff-index --cached -z [PARENT]]
1571         }
1572         set fd_df [git_read diff-files -z]
1573
1574         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1575         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1576
1577         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1578         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1579
1580         if {[is_config_true gui.displayuntracked]} {
1581                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1582                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1583                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1584                 incr rescan_active
1585         }
1586 }
1587
1588 proc load_message {file {encoding {}}} {
1589         global ui_comm
1590
1591         set f [gitdir $file]
1592         if {[file isfile $f]} {
1593                 if {[catch {set fd [open $f r]}]} {
1594                         return 0
1595                 }
1596                 fconfigure $fd -eofchar {}
1597                 if {$encoding ne {}} {
1598                         fconfigure $fd -encoding $encoding
1599                 }
1600                 set content [string trim [read $fd]]
1601                 close $fd
1602                 regsub -all -line {[ \r\t]+$} $content {} content
1603                 $ui_comm delete 0.0 end
1604                 $ui_comm insert end $content
1605                 return 1
1606         }
1607         return 0
1608 }
1609
1610 proc run_prepare_commit_msg_hook {} {
1611         global pch_error
1612
1613         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1614         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1615         # empty file but existent file.
1616
1617         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1618
1619         if {[file isfile [gitdir MERGE_MSG]]} {
1620                 set pcm_source "merge"
1621                 set fd_mm [open [gitdir MERGE_MSG] r]
1622                 puts -nonewline $fd_pcm [read $fd_mm]
1623                 close $fd_mm
1624         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1625                 set pcm_source "squash"
1626                 set fd_sm [open [gitdir SQUASH_MSG] r]
1627                 puts -nonewline $fd_pcm [read $fd_sm]
1628                 close $fd_sm
1629         } else {
1630                 set pcm_source ""
1631         }
1632
1633         close $fd_pcm
1634
1635         set fd_ph [githook_read prepare-commit-msg \
1636                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1637         if {$fd_ph eq {}} {
1638                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1639                 return 0;
1640         }
1641
1642         ui_status [mc "Calling prepare-commit-msg hook..."]
1643         set pch_error {}
1644
1645         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1646         fileevent $fd_ph readable \
1647                 [list prepare_commit_msg_hook_wait $fd_ph]
1648
1649         return 1;
1650 }
1651
1652 proc prepare_commit_msg_hook_wait {fd_ph} {
1653         global pch_error
1654
1655         append pch_error [read $fd_ph]
1656         fconfigure $fd_ph -blocking 1
1657         if {[eof $fd_ph]} {
1658                 if {[catch {close $fd_ph}]} {
1659                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1660                         hook_failed_popup prepare-commit-msg $pch_error
1661                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1662                         exit 1
1663                 } else {
1664                         load_message PREPARE_COMMIT_MSG
1665                 }
1666                 set pch_error {}
1667                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1668                 return
1669         }
1670         fconfigure $fd_ph -blocking 0
1671         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1672 }
1673
1674 proc read_diff_index {fd after} {
1675         global buf_rdi
1676
1677         append buf_rdi [read $fd]
1678         set c 0
1679         set n [string length $buf_rdi]
1680         while {$c < $n} {
1681                 set z1 [string first "\0" $buf_rdi $c]
1682                 if {$z1 == -1} break
1683                 incr z1
1684                 set z2 [string first "\0" $buf_rdi $z1]
1685                 if {$z2 == -1} break
1686
1687                 incr c
1688                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1689                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1690                 merge_state \
1691                         [encoding convertfrom utf-8 $p] \
1692                         [lindex $i 4]? \
1693                         [list [lindex $i 0] [lindex $i 2]] \
1694                         [list]
1695                 set c $z2
1696                 incr c
1697         }
1698         if {$c < $n} {
1699                 set buf_rdi [string range $buf_rdi $c end]
1700         } else {
1701                 set buf_rdi {}
1702         }
1703
1704         rescan_done $fd buf_rdi $after
1705 }
1706
1707 proc read_diff_files {fd after} {
1708         global buf_rdf
1709
1710         append buf_rdf [read $fd]
1711         set c 0
1712         set n [string length $buf_rdf]
1713         while {$c < $n} {
1714                 set z1 [string first "\0" $buf_rdf $c]
1715                 if {$z1 == -1} break
1716                 incr z1
1717                 set z2 [string first "\0" $buf_rdf $z1]
1718                 if {$z2 == -1} break
1719
1720                 incr c
1721                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1722                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1723                 merge_state \
1724                         [encoding convertfrom utf-8 $p] \
1725                         ?[lindex $i 4] \
1726                         [list] \
1727                         [list [lindex $i 0] [lindex $i 2]]
1728                 set c $z2
1729                 incr c
1730         }
1731         if {$c < $n} {
1732                 set buf_rdf [string range $buf_rdf $c end]
1733         } else {
1734                 set buf_rdf {}
1735         }
1736
1737         rescan_done $fd buf_rdf $after
1738 }
1739
1740 proc read_ls_others {fd after} {
1741         global buf_rlo
1742
1743         append buf_rlo [read $fd]
1744         set pck [split $buf_rlo "\0"]
1745         set buf_rlo [lindex $pck end]
1746         foreach p [lrange $pck 0 end-1] {
1747                 set p [encoding convertfrom utf-8 $p]
1748                 if {[string index $p end] eq {/}} {
1749                         set p [string range $p 0 end-1]
1750                 }
1751                 merge_state $p ?O
1752         }
1753         rescan_done $fd buf_rlo $after
1754 }
1755
1756 proc rescan_done {fd buf after} {
1757         global rescan_active current_diff_path
1758         global file_states repo_config
1759         upvar $buf to_clear
1760
1761         if {![eof $fd]} return
1762         set to_clear {}
1763         close $fd
1764         if {[incr rescan_active -1] > 0} return
1765
1766         prune_selection
1767         unlock_index
1768         display_all_files
1769         if {$current_diff_path ne {}} { reshow_diff $after }
1770         if {$current_diff_path eq {}} { select_first_diff $after }
1771 }
1772
1773 proc prune_selection {} {
1774         global file_states selected_paths
1775
1776         foreach path [array names selected_paths] {
1777                 if {[catch {set still_here $file_states($path)}]} {
1778                         unset selected_paths($path)
1779                 }
1780         }
1781 }
1782
1783 ######################################################################
1784 ##
1785 ## ui helpers
1786
1787 proc mapicon {w state path} {
1788         global all_icons
1789
1790         if {[catch {set r $all_icons($state$w)}]} {
1791                 puts "error: no icon for $w state={$state} $path"
1792                 return file_plain
1793         }
1794         return $r
1795 }
1796
1797 proc mapdesc {state path} {
1798         global all_descs
1799
1800         if {[catch {set r $all_descs($state)}]} {
1801                 puts "error: no desc for state={$state} $path"
1802                 return $state
1803         }
1804         return $r
1805 }
1806
1807 proc ui_status {msg} {
1808         global main_status
1809         if {[info exists main_status]} {
1810                 $main_status show $msg
1811         }
1812 }
1813
1814 proc ui_ready {{test {}}} {
1815         global main_status
1816         if {[info exists main_status]} {
1817                 $main_status show [mc "Ready."] $test
1818         }
1819 }
1820
1821 proc escape_path {path} {
1822         regsub -all {\\} $path "\\\\" path
1823         regsub -all "\n" $path "\\n" path
1824         return $path
1825 }
1826
1827 proc short_path {path} {
1828         return [escape_path [lindex [file split $path] end]]
1829 }
1830
1831 set next_icon_id 0
1832 set null_sha1 [string repeat 0 40]
1833
1834 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1835         global file_states next_icon_id null_sha1
1836
1837         set s0 [string index $new_state 0]
1838         set s1 [string index $new_state 1]
1839
1840         if {[catch {set info $file_states($path)}]} {
1841                 set state __
1842                 set icon n[incr next_icon_id]
1843         } else {
1844                 set state [lindex $info 0]
1845                 set icon [lindex $info 1]
1846                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1847                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1848         }
1849
1850         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1851         elseif {$s0 eq {_}} {set s0 _}
1852
1853         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1854         elseif {$s1 eq {_}} {set s1 _}
1855
1856         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1857                 set head_info [list 0 $null_sha1]
1858         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1859                 && $head_info eq {}} {
1860                 set head_info $index_info
1861         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1862                 set index_info $head_info
1863                 set head_info {}
1864         }
1865
1866         set file_states($path) [list $s0$s1 $icon \
1867                 $head_info $index_info \
1868                 ]
1869         return $state
1870 }
1871
1872 proc display_file_helper {w path icon_name old_m new_m} {
1873         global file_lists
1874
1875         if {$new_m eq {_}} {
1876                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1877                 if {$lno >= 0} {
1878                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1879                         incr lno
1880                         $w conf -state normal
1881                         $w delete $lno.0 [expr {$lno + 1}].0
1882                         $w conf -state disabled
1883                 }
1884         } elseif {$old_m eq {_} && $new_m ne {_}} {
1885                 lappend file_lists($w) $path
1886                 set file_lists($w) [lsort -unique $file_lists($w)]
1887                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1888                 incr lno
1889                 $w conf -state normal
1890                 $w image create $lno.0 \
1891                         -align center -padx 5 -pady 1 \
1892                         -name $icon_name \
1893                         -image [mapicon $w $new_m $path]
1894                 $w insert $lno.1 "[escape_path $path]\n"
1895                 $w conf -state disabled
1896         } elseif {$old_m ne $new_m} {
1897                 $w conf -state normal
1898                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1899                 $w conf -state disabled
1900         }
1901 }
1902
1903 proc display_file {path state} {
1904         global file_states selected_paths
1905         global ui_index ui_workdir
1906
1907         set old_m [merge_state $path $state]
1908         set s $file_states($path)
1909         set new_m [lindex $s 0]
1910         set icon_name [lindex $s 1]
1911
1912         set o [string index $old_m 0]
1913         set n [string index $new_m 0]
1914         if {$o eq {U}} {
1915                 set o _
1916         }
1917         if {$n eq {U}} {
1918                 set n _
1919         }
1920         display_file_helper     $ui_index $path $icon_name $o $n
1921
1922         if {[string index $old_m 0] eq {U}} {
1923                 set o U
1924         } else {
1925                 set o [string index $old_m 1]
1926         }
1927         if {[string index $new_m 0] eq {U}} {
1928                 set n U
1929         } else {
1930                 set n [string index $new_m 1]
1931         }
1932         display_file_helper     $ui_workdir $path $icon_name $o $n
1933
1934         if {$new_m eq {__}} {
1935                 unset file_states($path)
1936                 catch {unset selected_paths($path)}
1937         }
1938 }
1939
1940 proc display_all_files_helper {w path icon_name m} {
1941         global file_lists
1942
1943         lappend file_lists($w) $path
1944         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1945         $w image create end \
1946                 -align center -padx 5 -pady 1 \
1947                 -name $icon_name \
1948                 -image [mapicon $w $m $path]
1949         $w insert end "[escape_path $path]\n"
1950 }
1951
1952 set files_warning 0
1953 proc display_all_files {} {
1954         global ui_index ui_workdir
1955         global file_states file_lists
1956         global last_clicked
1957         global files_warning
1958
1959         $ui_index conf -state normal
1960         $ui_workdir conf -state normal
1961
1962         $ui_index delete 0.0 end
1963         $ui_workdir delete 0.0 end
1964         set last_clicked {}
1965
1966         set file_lists($ui_index) [list]
1967         set file_lists($ui_workdir) [list]
1968
1969         set to_display [lsort [array names file_states]]
1970         set display_limit [get_config gui.maxfilesdisplayed]
1971         if {[llength $to_display] > $display_limit} {
1972                 if {!$files_warning} {
1973                         # do not repeatedly warn:
1974                         set files_warning 1
1975                         info_popup [mc "Displaying only %s of %s files." \
1976                                 $display_limit [llength $to_display]]
1977                 }
1978                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1979         }
1980         foreach path $to_display {
1981                 set s $file_states($path)
1982                 set m [lindex $s 0]
1983                 set icon_name [lindex $s 1]
1984
1985                 set s [string index $m 0]
1986                 if {$s ne {U} && $s ne {_}} {
1987                         display_all_files_helper $ui_index $path \
1988                                 $icon_name $s
1989                 }
1990
1991                 if {[string index $m 0] eq {U}} {
1992                         set s U
1993                 } else {
1994                         set s [string index $m 1]
1995                 }
1996                 if {$s ne {_}} {
1997                         display_all_files_helper $ui_workdir $path \
1998                                 $icon_name $s
1999                 }
2000         }
2001
2002         $ui_index conf -state disabled
2003         $ui_workdir conf -state disabled
2004 }
2005
2006 ######################################################################
2007 ##
2008 ## icons
2009
2010 set filemask {
2011 #define mask_width 14
2012 #define mask_height 15
2013 static unsigned char mask_bits[] = {
2014    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2015    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2016    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2017 }
2018
2019 image create bitmap file_plain -background white -foreground black -data {
2020 #define plain_width 14
2021 #define plain_height 15
2022 static unsigned char plain_bits[] = {
2023    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2024    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2025    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2026 } -maskdata $filemask
2027
2028 image create bitmap file_mod -background white -foreground blue -data {
2029 #define mod_width 14
2030 #define mod_height 15
2031 static unsigned char mod_bits[] = {
2032    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2033    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2034    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2035 } -maskdata $filemask
2036
2037 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2038 #define file_fulltick_width 14
2039 #define file_fulltick_height 15
2040 static unsigned char file_fulltick_bits[] = {
2041    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2042    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2043    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2044 } -maskdata $filemask
2045
2046 image create bitmap file_question -background white -foreground black -data {
2047 #define file_question_width 14
2048 #define file_question_height 15
2049 static unsigned char file_question_bits[] = {
2050    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2051    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2052    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2053 } -maskdata $filemask
2054
2055 image create bitmap file_removed -background white -foreground red -data {
2056 #define file_removed_width 14
2057 #define file_removed_height 15
2058 static unsigned char file_removed_bits[] = {
2059    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2060    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2061    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2062 } -maskdata $filemask
2063
2064 image create bitmap file_merge -background white -foreground blue -data {
2065 #define file_merge_width 14
2066 #define file_merge_height 15
2067 static unsigned char file_merge_bits[] = {
2068    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2069    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2070    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2071 } -maskdata $filemask
2072
2073 image create bitmap file_statechange -background white -foreground green -data {
2074 #define file_statechange_width 14
2075 #define file_statechange_height 15
2076 static unsigned char file_statechange_bits[] = {
2077    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2078    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2079    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2080 } -maskdata $filemask
2081
2082 set ui_index .vpane.files.index.list
2083 set ui_workdir .vpane.files.workdir.list
2084
2085 set all_icons(_$ui_index)   file_plain
2086 set all_icons(A$ui_index)   file_plain
2087 set all_icons(M$ui_index)   file_fulltick
2088 set all_icons(D$ui_index)   file_removed
2089 set all_icons(U$ui_index)   file_merge
2090 set all_icons(T$ui_index)   file_statechange
2091
2092 set all_icons(_$ui_workdir) file_plain
2093 set all_icons(M$ui_workdir) file_mod
2094 set all_icons(D$ui_workdir) file_question
2095 set all_icons(U$ui_workdir) file_merge
2096 set all_icons(O$ui_workdir) file_plain
2097 set all_icons(T$ui_workdir) file_statechange
2098
2099 set max_status_desc 0
2100 foreach i {
2101                 {__ {mc "Unmodified"}}
2102
2103                 {_M {mc "Modified, not staged"}}
2104                 {M_ {mc "Staged for commit"}}
2105                 {MM {mc "Portions staged for commit"}}
2106                 {MD {mc "Staged for commit, missing"}}
2107
2108                 {_T {mc "File type changed, not staged"}}
2109                 {MT {mc "File type changed, old type staged for commit"}}
2110                 {AT {mc "File type changed, old type staged for commit"}}
2111                 {T_ {mc "File type changed, staged"}}
2112                 {TM {mc "File type change staged, modification not staged"}}
2113                 {TD {mc "File type change staged, file missing"}}
2114
2115                 {_O {mc "Untracked, not staged"}}
2116                 {A_ {mc "Staged for commit"}}
2117                 {AM {mc "Portions staged for commit"}}
2118                 {AD {mc "Staged for commit, missing"}}
2119
2120                 {_D {mc "Missing"}}
2121                 {D_ {mc "Staged for removal"}}
2122                 {DO {mc "Staged for removal, still present"}}
2123
2124                 {_U {mc "Requires merge resolution"}}
2125                 {U_ {mc "Requires merge resolution"}}
2126                 {UU {mc "Requires merge resolution"}}
2127                 {UM {mc "Requires merge resolution"}}
2128                 {UD {mc "Requires merge resolution"}}
2129                 {UT {mc "Requires merge resolution"}}
2130         } {
2131         set text [eval [lindex $i 1]]
2132         if {$max_status_desc < [string length $text]} {
2133                 set max_status_desc [string length $text]
2134         }
2135         set all_descs([lindex $i 0]) $text
2136 }
2137 unset i
2138
2139 ######################################################################
2140 ##
2141 ## util
2142
2143 proc scrollbar2many {list mode args} {
2144         foreach w $list {eval $w $mode $args}
2145 }
2146
2147 proc many2scrollbar {list mode sb top bottom} {
2148         $sb set $top $bottom
2149         foreach w $list {$w $mode moveto $top}
2150 }
2151
2152 proc incr_font_size {font {amt 1}} {
2153         set sz [font configure $font -size]
2154         incr sz $amt
2155         font configure $font -size $sz
2156         font configure ${font}bold -size $sz
2157         font configure ${font}italic -size $sz
2158 }
2159
2160 ######################################################################
2161 ##
2162 ## ui commands
2163
2164 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2165
2166 proc do_gitk {revs {is_submodule false}} {
2167         global current_diff_path file_states current_diff_side ui_index
2168         global _gitworktree
2169
2170         # -- Always start gitk through whatever we were loaded with.  This
2171         #    lets us bypass using shell process on Windows systems.
2172         #
2173         set exe [_which gitk -script]
2174         set cmd [list [info nameofexecutable] $exe]
2175         if {$exe eq {}} {
2176                 error_popup [mc "Couldn't find gitk in PATH"]
2177         } else {
2178                 global env
2179
2180                 if {[info exists env(GIT_DIR)]} {
2181                         set old_GIT_DIR $env(GIT_DIR)
2182                 } else {
2183                         set old_GIT_DIR {}
2184                 }
2185
2186                 set pwd [pwd]
2187
2188                 if {!$is_submodule} {
2189                         if {![is_bare]} {
2190                                 cd $_gitworktree
2191                         }
2192                         set env(GIT_DIR) [file normalize [gitdir]]
2193                 } else {
2194                         cd $current_diff_path
2195                         if {$revs eq {--}} {
2196                                 set s $file_states($current_diff_path)
2197                                 set old_sha1 {}
2198                                 set new_sha1 {}
2199                                 switch -glob -- [lindex $s 0] {
2200                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2201                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2202                                 MM {
2203                                         if {$current_diff_side eq $ui_index} {
2204                                                 set old_sha1 [lindex [lindex $s 2] 1]
2205                                                 set new_sha1 [lindex [lindex $s 3] 1]
2206                                         } else {
2207                                                 set old_sha1 [lindex [lindex $s 3] 1]
2208                                         }
2209                                 }
2210                                 }
2211                                 set revs $old_sha1...$new_sha1
2212                         }
2213                         if {[info exists env(GIT_DIR)]} {
2214                                 unset env(GIT_DIR)
2215                         }
2216                 }
2217                 eval exec $cmd $revs "--" "--" &
2218
2219                 if {$old_GIT_DIR ne {}} {
2220                         set env(GIT_DIR) $old_GIT_DIR
2221                 }
2222                 cd $pwd
2223
2224                 ui_status $::starting_gitk_msg
2225                 after 10000 {
2226                         ui_ready $starting_gitk_msg
2227                 }
2228         }
2229 }
2230
2231 proc do_git_gui {} {
2232         global current_diff_path
2233
2234         # -- Always start git gui through whatever we were loaded with.  This
2235         #    lets us bypass using shell process on Windows systems.
2236         #
2237         set exe [list [_which git]]
2238         if {$exe eq {}} {
2239                 error_popup [mc "Couldn't find git gui in PATH"]
2240         } else {
2241                 global env
2242
2243                 if {[info exists env(GIT_DIR)]} {
2244                         set old_GIT_DIR $env(GIT_DIR)
2245                         unset env(GIT_DIR)
2246                 } else {
2247                         set old_GIT_DIR {}
2248                 }
2249
2250                 set pwd [pwd]
2251                 cd $current_diff_path
2252
2253                 eval exec $exe gui &
2254
2255                 if {$old_GIT_DIR ne {}} {
2256                         set env(GIT_DIR) $old_GIT_DIR
2257                 }
2258                 cd $pwd
2259
2260                 ui_status $::starting_gitk_msg
2261                 after 10000 {
2262                         ui_ready $starting_gitk_msg
2263                 }
2264         }
2265 }
2266
2267 proc do_explore {} {
2268         global _gitworktree
2269         set explorer {}
2270         if {[is_Cygwin] || [is_Windows]} {
2271                 set explorer "explorer.exe"
2272         } elseif {[is_MacOSX]} {
2273                 set explorer "open"
2274         } else {
2275                 # freedesktop.org-conforming system is our best shot
2276                 set explorer "xdg-open"
2277         }
2278         eval exec $explorer [list [file nativename $_gitworktree]] &
2279 }
2280
2281 set is_quitting 0
2282 set ret_code    1
2283
2284 proc terminate_me {win} {
2285         global ret_code
2286         if {$win ne {.}} return
2287         exit $ret_code
2288 }
2289
2290 proc do_quit {{rc {1}}} {
2291         global ui_comm is_quitting repo_config commit_type
2292         global GITGUI_BCK_exists GITGUI_BCK_i
2293         global ui_comm_spell
2294         global ret_code use_ttk
2295
2296         if {$is_quitting} return
2297         set is_quitting 1
2298
2299         if {[winfo exists $ui_comm]} {
2300                 # -- Stash our current commit buffer.
2301                 #
2302                 set save [gitdir GITGUI_MSG]
2303                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2304                         file rename -force [gitdir GITGUI_BCK] $save
2305                         set GITGUI_BCK_exists 0
2306                 } else {
2307                         set msg [string trim [$ui_comm get 0.0 end]]
2308                         regsub -all -line {[ \r\t]+$} $msg {} msg
2309                         if {(![string match amend* $commit_type]
2310                                 || [$ui_comm edit modified])
2311                                 && $msg ne {}} {
2312                                 catch {
2313                                         set fd [open $save w]
2314                                         fconfigure $fd -encoding utf-8
2315                                         puts -nonewline $fd $msg
2316                                         close $fd
2317                                 }
2318                         } else {
2319                                 catch {file delete $save}
2320                         }
2321                 }
2322
2323                 # -- Cancel our spellchecker if its running.
2324                 #
2325                 if {[info exists ui_comm_spell]} {
2326                         $ui_comm_spell stop
2327                 }
2328
2329                 # -- Remove our editor backup, its not needed.
2330                 #
2331                 after cancel $GITGUI_BCK_i
2332                 if {$GITGUI_BCK_exists} {
2333                         catch {file delete [gitdir GITGUI_BCK]}
2334                 }
2335
2336                 # -- Stash our current window geometry into this repository.
2337                 #
2338                 set cfg_wmstate [wm state .]
2339                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2340                         set rc_wmstate {}
2341                 }
2342                 if {$cfg_wmstate ne $rc_wmstate} {
2343                         catch {git config gui.wmstate $cfg_wmstate}
2344                 }
2345                 if {$cfg_wmstate eq {zoomed}} {
2346                         # on Windows wm geometry will lie about window
2347                         # position (but not size) when window is zoomed
2348                         # restore the window before querying wm geometry
2349                         wm state . normal
2350                 }
2351                 set cfg_geometry [list]
2352                 lappend cfg_geometry [wm geometry .]
2353                 if {$use_ttk} {
2354                         lappend cfg_geometry [.vpane sashpos 0]
2355                         lappend cfg_geometry [.vpane.files sashpos 0]
2356                 } else {
2357                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2358                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2359                 }
2360                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2361                         set rc_geometry {}
2362                 }
2363                 if {$cfg_geometry ne $rc_geometry} {
2364                         catch {git config gui.geometry $cfg_geometry}
2365                 }
2366         }
2367
2368         set ret_code $rc
2369
2370         # Briefly enable send again, working around Tk bug
2371         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2372         tk appname [appname]
2373
2374         destroy .
2375 }
2376
2377 proc do_rescan {} {
2378         rescan ui_ready
2379 }
2380
2381 proc ui_do_rescan {} {
2382         rescan {force_first_diff ui_ready}
2383 }
2384
2385 proc do_commit {} {
2386         commit_tree
2387 }
2388
2389 proc next_diff {{after {}}} {
2390         global next_diff_p next_diff_w next_diff_i
2391         show_diff $next_diff_p $next_diff_w {} {} $after
2392 }
2393
2394 proc find_anchor_pos {lst name} {
2395         set lid [lsearch -sorted -exact $lst $name]
2396
2397         if {$lid == -1} {
2398                 set lid 0
2399                 foreach lname $lst {
2400                         if {$lname >= $name} break
2401                         incr lid
2402                 }
2403         }
2404
2405         return $lid
2406 }
2407
2408 proc find_file_from {flist idx delta path mmask} {
2409         global file_states
2410
2411         set len [llength $flist]
2412         while {$idx >= 0 && $idx < $len} {
2413                 set name [lindex $flist $idx]
2414
2415                 if {$name ne $path && [info exists file_states($name)]} {
2416                         set state [lindex $file_states($name) 0]
2417
2418                         if {$mmask eq {} || [regexp $mmask $state]} {
2419                                 return $idx
2420                         }
2421                 }
2422
2423                 incr idx $delta
2424         }
2425
2426         return {}
2427 }
2428
2429 proc find_next_diff {w path {lno {}} {mmask {}}} {
2430         global next_diff_p next_diff_w next_diff_i
2431         global file_lists ui_index ui_workdir
2432
2433         set flist $file_lists($w)
2434         if {$lno eq {}} {
2435                 set lno [find_anchor_pos $flist $path]
2436         } else {
2437                 incr lno -1
2438         }
2439
2440         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2441                 if {$w eq $ui_index} {
2442                         set mmask "^$mmask"
2443                 } else {
2444                         set mmask "$mmask\$"
2445                 }
2446         }
2447
2448         set idx [find_file_from $flist $lno 1 $path $mmask]
2449         if {$idx eq {}} {
2450                 incr lno -1
2451                 set idx [find_file_from $flist $lno -1 $path $mmask]
2452         }
2453
2454         if {$idx ne {}} {
2455                 set next_diff_w $w
2456                 set next_diff_p [lindex $flist $idx]
2457                 set next_diff_i [expr {$idx+1}]
2458                 return 1
2459         } else {
2460                 return 0
2461         }
2462 }
2463
2464 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2465         global current_diff_path
2466
2467         if {$path ne $current_diff_path} {
2468                 return {}
2469         } elseif {[find_next_diff $w $path $lno $mmask]} {
2470                 return {next_diff;}
2471         } else {
2472                 return {reshow_diff;}
2473         }
2474 }
2475
2476 proc select_first_diff {after} {
2477         global ui_workdir
2478
2479         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2480             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2481                 next_diff $after
2482         } else {
2483                 uplevel #0 $after
2484         }
2485 }
2486
2487 proc force_first_diff {after} {
2488         global ui_workdir current_diff_path file_states
2489
2490         if {[info exists file_states($current_diff_path)]} {
2491                 set state [lindex $file_states($current_diff_path) 0]
2492         } else {
2493                 set state {OO}
2494         }
2495
2496         set reselect 0
2497         if {[string first {U} $state] >= 0} {
2498                 # Already a conflict, do nothing
2499         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2500                 set reselect 1
2501         } elseif {[string index $state 1] ne {O}} {
2502                 # Already a diff & no conflicts, do nothing
2503         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2504                 set reselect 1
2505         }
2506
2507         if {$reselect} {
2508                 next_diff $after
2509         } else {
2510                 uplevel #0 $after
2511         }
2512 }
2513
2514 proc toggle_or_diff {w x y} {
2515         global file_states file_lists current_diff_path ui_index ui_workdir
2516         global last_clicked selected_paths
2517
2518         set pos [split [$w index @$x,$y] .]
2519         set lno [lindex $pos 0]
2520         set col [lindex $pos 1]
2521         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2522         if {$path eq {}} {
2523                 set last_clicked {}
2524                 return
2525         }
2526
2527         set last_clicked [list $w $lno]
2528         array unset selected_paths
2529         $ui_index tag remove in_sel 0.0 end
2530         $ui_workdir tag remove in_sel 0.0 end
2531
2532         # Determine the state of the file
2533         if {[info exists file_states($path)]} {
2534                 set state [lindex $file_states($path) 0]
2535         } else {
2536                 set state {__}
2537         }
2538
2539         # Restage the file, or simply show the diff
2540         if {$col == 0 && $y > 1} {
2541                 # Conflicts need special handling
2542                 if {[string first {U} $state] >= 0} {
2543                         # $w must always be $ui_workdir, but...
2544                         if {$w ne $ui_workdir} { set lno {} }
2545                         merge_stage_workdir $path $lno
2546                         return
2547                 }
2548
2549                 if {[string index $state 1] eq {O}} {
2550                         set mmask {}
2551                 } else {
2552                         set mmask {[^O]}
2553                 }
2554
2555                 set after [next_diff_after_action $w $path $lno $mmask]
2556
2557                 if {$w eq $ui_index} {
2558                         update_indexinfo \
2559                                 "Unstaging [short_path $path] from commit" \
2560                                 [list $path] \
2561                                 [concat $after [list ui_ready]]
2562                 } elseif {$w eq $ui_workdir} {
2563                         update_index \
2564                                 "Adding [short_path $path]" \
2565                                 [list $path] \
2566                                 [concat $after [list ui_ready]]
2567                 }
2568         } else {
2569                 set selected_paths($path) 1
2570                 show_diff $path $w $lno
2571         }
2572 }
2573
2574 proc add_one_to_selection {w x y} {
2575         global file_lists last_clicked selected_paths
2576
2577         set lno [lindex [split [$w index @$x,$y] .] 0]
2578         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2579         if {$path eq {}} {
2580                 set last_clicked {}
2581                 return
2582         }
2583
2584         if {$last_clicked ne {}
2585                 && [lindex $last_clicked 0] ne $w} {
2586                 array unset selected_paths
2587                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2588         }
2589
2590         set last_clicked [list $w $lno]
2591         if {[catch {set in_sel $selected_paths($path)}]} {
2592                 set in_sel 0
2593         }
2594         if {$in_sel} {
2595                 unset selected_paths($path)
2596                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2597         } else {
2598                 set selected_paths($path) 1
2599                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2600         }
2601 }
2602
2603 proc add_range_to_selection {w x y} {
2604         global file_lists last_clicked selected_paths
2605
2606         if {[lindex $last_clicked 0] ne $w} {
2607                 toggle_or_diff $w $x $y
2608                 return
2609         }
2610
2611         set lno [lindex [split [$w index @$x,$y] .] 0]
2612         set lc [lindex $last_clicked 1]
2613         if {$lc < $lno} {
2614                 set begin $lc
2615                 set end $lno
2616         } else {
2617                 set begin $lno
2618                 set end $lc
2619         }
2620
2621         foreach path [lrange $file_lists($w) \
2622                 [expr {$begin - 1}] \
2623                 [expr {$end - 1}]] {
2624                 set selected_paths($path) 1
2625         }
2626         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2627 }
2628
2629 proc show_more_context {} {
2630         global repo_config
2631         if {$repo_config(gui.diffcontext) < 99} {
2632                 incr repo_config(gui.diffcontext)
2633                 reshow_diff
2634         }
2635 }
2636
2637 proc show_less_context {} {
2638         global repo_config
2639         if {$repo_config(gui.diffcontext) > 1} {
2640                 incr repo_config(gui.diffcontext) -1
2641                 reshow_diff
2642         }
2643 }
2644
2645 ######################################################################
2646 ##
2647 ## ui construction
2648
2649 set ui_comm {}
2650
2651 # -- Menu Bar
2652 #
2653 menu .mbar -tearoff 0
2654 if {[is_MacOSX]} {
2655         # -- Apple Menu (Mac OS X only)
2656         #
2657         .mbar add cascade -label Apple -menu .mbar.apple
2658         menu .mbar.apple
2659 }
2660 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2661 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2662 if {[is_enabled branch]} {
2663         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2664 }
2665 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2666         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2667 }
2668 if {[is_enabled transport]} {
2669         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2670         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2671 }
2672 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2673         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2674 }
2675
2676 # -- Repository Menu
2677 #
2678 menu .mbar.repository
2679
2680 if {![is_bare]} {
2681         .mbar.repository add command \
2682                 -label [mc "Explore Working Copy"] \
2683                 -command {do_explore}
2684 }
2685
2686 if {[is_Windows]} {
2687         .mbar.repository add command \
2688                 -label [mc "Git Bash"] \
2689                 -command {eval exec [auto_execok start] \
2690                                           [list "Git Bash" bash --login -l &]}
2691 }
2692
2693 if {[is_Windows] || ![is_bare]} {
2694         .mbar.repository add separator
2695 }
2696
2697 .mbar.repository add command \
2698         -label [mc "Browse Current Branch's Files"] \
2699         -command {browser::new $current_branch}
2700 set ui_browse_current [.mbar.repository index last]
2701 .mbar.repository add command \
2702         -label [mc "Browse Branch Files..."] \
2703         -command browser_open::dialog
2704 .mbar.repository add separator
2705
2706 .mbar.repository add command \
2707         -label [mc "Visualize Current Branch's History"] \
2708         -command {do_gitk $current_branch}
2709 set ui_visualize_current [.mbar.repository index last]
2710 .mbar.repository add command \
2711         -label [mc "Visualize All Branch History"] \
2712         -command {do_gitk --all}
2713 .mbar.repository add separator
2714
2715 proc current_branch_write {args} {
2716         global current_branch
2717         .mbar.repository entryconf $::ui_browse_current \
2718                 -label [mc "Browse %s's Files" $current_branch]
2719         .mbar.repository entryconf $::ui_visualize_current \
2720                 -label [mc "Visualize %s's History" $current_branch]
2721 }
2722 trace add variable current_branch write current_branch_write
2723
2724 if {[is_enabled multicommit]} {
2725         .mbar.repository add command -label [mc "Database Statistics"] \
2726                 -command do_stats
2727
2728         .mbar.repository add command -label [mc "Compress Database"] \
2729                 -command do_gc
2730
2731         .mbar.repository add command -label [mc "Verify Database"] \
2732                 -command do_fsck_objects
2733
2734         .mbar.repository add separator
2735
2736         if {[is_Cygwin]} {
2737                 .mbar.repository add command \
2738                         -label [mc "Create Desktop Icon"] \
2739                         -command do_cygwin_shortcut
2740         } elseif {[is_Windows]} {
2741                 .mbar.repository add command \
2742                         -label [mc "Create Desktop Icon"] \
2743                         -command do_windows_shortcut
2744         } elseif {[is_MacOSX]} {
2745                 .mbar.repository add command \
2746                         -label [mc "Create Desktop Icon"] \
2747                         -command do_macosx_app
2748         }
2749 }
2750
2751 if {[is_MacOSX]} {
2752         proc ::tk::mac::Quit {args} { do_quit }
2753 } else {
2754         .mbar.repository add command -label [mc Quit] \
2755                 -command do_quit \
2756                 -accelerator $M1T-Q
2757 }
2758
2759 # -- Edit Menu
2760 #
2761 menu .mbar.edit
2762 .mbar.edit add command -label [mc Undo] \
2763         -command {catch {[focus] edit undo}} \
2764         -accelerator $M1T-Z
2765 .mbar.edit add command -label [mc Redo] \
2766         -command {catch {[focus] edit redo}} \
2767         -accelerator $M1T-Y
2768 .mbar.edit add separator
2769 .mbar.edit add command -label [mc Cut] \
2770         -command {catch {tk_textCut [focus]}} \
2771         -accelerator $M1T-X
2772 .mbar.edit add command -label [mc Copy] \
2773         -command {catch {tk_textCopy [focus]}} \
2774         -accelerator $M1T-C
2775 .mbar.edit add command -label [mc Paste] \
2776         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2777         -accelerator $M1T-V
2778 .mbar.edit add command -label [mc Delete] \
2779         -command {catch {[focus] delete sel.first sel.last}} \
2780         -accelerator Del
2781 .mbar.edit add separator
2782 .mbar.edit add command -label [mc "Select All"] \
2783         -command {catch {[focus] tag add sel 0.0 end}} \
2784         -accelerator $M1T-A
2785
2786 # -- Branch Menu
2787 #
2788 if {[is_enabled branch]} {
2789         menu .mbar.branch
2790
2791         .mbar.branch add command -label [mc "Create..."] \
2792                 -command branch_create::dialog \
2793                 -accelerator $M1T-N
2794         lappend disable_on_lock [list .mbar.branch entryconf \
2795                 [.mbar.branch index last] -state]
2796
2797         .mbar.branch add command -label [mc "Checkout..."] \
2798                 -command branch_checkout::dialog \
2799                 -accelerator $M1T-O
2800         lappend disable_on_lock [list .mbar.branch entryconf \
2801                 [.mbar.branch index last] -state]
2802
2803         .mbar.branch add command -label [mc "Rename..."] \
2804                 -command branch_rename::dialog
2805         lappend disable_on_lock [list .mbar.branch entryconf \
2806                 [.mbar.branch index last] -state]
2807
2808         .mbar.branch add command -label [mc "Delete..."] \
2809                 -command branch_delete::dialog
2810         lappend disable_on_lock [list .mbar.branch entryconf \
2811                 [.mbar.branch index last] -state]
2812
2813         .mbar.branch add command -label [mc "Reset..."] \
2814                 -command merge::reset_hard
2815         lappend disable_on_lock [list .mbar.branch entryconf \
2816                 [.mbar.branch index last] -state]
2817 }
2818
2819 # -- Commit Menu
2820 #
2821 proc commit_btn_caption {} {
2822         if {[is_enabled nocommit]} {
2823                 return [mc "Done"]
2824         } else {
2825                 return [mc Commit@@verb]
2826         }
2827 }
2828
2829 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2830         menu .mbar.commit
2831
2832         if {![is_enabled nocommit]} {
2833                 .mbar.commit add radiobutton \
2834                         -label [mc "New Commit"] \
2835                         -command do_select_commit_type \
2836                         -variable selected_commit_type \
2837                         -value new
2838                 lappend disable_on_lock \
2839                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2840
2841                 .mbar.commit add radiobutton \
2842                         -label [mc "Amend Last Commit"] \
2843                         -command do_select_commit_type \
2844                         -variable selected_commit_type \
2845                         -value amend
2846                 lappend disable_on_lock \
2847                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2848
2849                 .mbar.commit add separator
2850         }
2851
2852         .mbar.commit add command -label [mc Rescan] \
2853                 -command ui_do_rescan \
2854                 -accelerator F5
2855         lappend disable_on_lock \
2856                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2857
2858         .mbar.commit add command -label [mc "Stage To Commit"] \
2859                 -command do_add_selection \
2860                 -accelerator $M1T-T
2861         lappend disable_on_lock \
2862                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2863
2864         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2865                 -command do_add_all \
2866                 -accelerator $M1T-I
2867         lappend disable_on_lock \
2868                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2869
2870         .mbar.commit add command -label [mc "Unstage From Commit"] \
2871                 -command do_unstage_selection \
2872                 -accelerator $M1T-U
2873         lappend disable_on_lock \
2874                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2875
2876         .mbar.commit add command -label [mc "Revert Changes"] \
2877                 -command do_revert_selection \
2878                 -accelerator $M1T-J
2879         lappend disable_on_lock \
2880                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2881
2882         .mbar.commit add separator
2883
2884         .mbar.commit add command -label [mc "Show Less Context"] \
2885                 -command show_less_context \
2886                 -accelerator $M1T-\-
2887
2888         .mbar.commit add command -label [mc "Show More Context"] \
2889                 -command show_more_context \
2890                 -accelerator $M1T-=
2891
2892         .mbar.commit add separator
2893
2894         if {![is_enabled nocommitmsg]} {
2895                 .mbar.commit add command -label [mc "Sign Off"] \
2896                         -command do_signoff \
2897                         -accelerator $M1T-S
2898         }
2899
2900         .mbar.commit add command -label [commit_btn_caption] \
2901                 -command do_commit \
2902                 -accelerator $M1T-Return
2903         lappend disable_on_lock \
2904                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2905 }
2906
2907 # -- Merge Menu
2908 #
2909 if {[is_enabled branch]} {
2910         menu .mbar.merge
2911         .mbar.merge add command -label [mc "Local Merge..."] \
2912                 -command merge::dialog \
2913                 -accelerator $M1T-M
2914         lappend disable_on_lock \
2915                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2916         .mbar.merge add command -label [mc "Abort Merge..."] \
2917                 -command merge::reset_hard
2918         lappend disable_on_lock \
2919                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2920 }
2921
2922 # -- Transport Menu
2923 #
2924 if {[is_enabled transport]} {
2925         menu .mbar.remote
2926
2927         .mbar.remote add command \
2928                 -label [mc "Add..."] \
2929                 -command remote_add::dialog \
2930                 -accelerator $M1T-A
2931         .mbar.remote add command \
2932                 -label [mc "Push..."] \
2933                 -command do_push_anywhere \
2934                 -accelerator $M1T-P
2935         .mbar.remote add command \
2936                 -label [mc "Delete Branch..."] \
2937                 -command remote_branch_delete::dialog
2938 }
2939
2940 if {[is_MacOSX]} {
2941         proc ::tk::mac::ShowPreferences {} {do_options}
2942 } else {
2943         # -- Edit Menu
2944         #
2945         .mbar.edit add separator
2946         .mbar.edit add command -label [mc "Options..."] \
2947                 -command do_options
2948 }
2949
2950 # -- Tools Menu
2951 #
2952 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2953         set tools_menubar .mbar.tools
2954         menu $tools_menubar
2955         $tools_menubar add separator
2956         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2957         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2958         set tools_tailcnt 3
2959         if {[array names repo_config guitool.*.cmd] ne {}} {
2960                 tools_populate_all
2961         }
2962 }
2963
2964 # -- Help Menu
2965 #
2966 .mbar add cascade -label [mc Help] -menu .mbar.help
2967 menu .mbar.help
2968
2969 if {[is_MacOSX]} {
2970         .mbar.apple add command -label [mc "About %s" [appname]] \
2971                 -command do_about
2972         .mbar.apple add separator
2973 } else {
2974         .mbar.help add command -label [mc "About %s" [appname]] \
2975                 -command do_about
2976 }
2977 . configure -menu .mbar
2978
2979 set doc_path [githtmldir]
2980 if {$doc_path ne {}} {
2981         set doc_path [file join $doc_path index.html]
2982
2983         if {[is_Cygwin]} {
2984                 set doc_path [exec cygpath --mixed $doc_path]
2985         }
2986 }
2987
2988 if {[file isfile $doc_path]} {
2989         set doc_url "file:$doc_path"
2990 } else {
2991         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
2992 }
2993
2994 proc start_browser {url} {
2995         git "web--browse" $url
2996 }
2997
2998 .mbar.help add command -label [mc "Online Documentation"] \
2999         -command [list start_browser $doc_url]
3000
3001 .mbar.help add command -label [mc "Show SSH Key"] \
3002         -command do_ssh_key
3003
3004 unset doc_path doc_url
3005
3006 # -- Standard bindings
3007 #
3008 wm protocol . WM_DELETE_WINDOW do_quit
3009 bind all <$M1B-Key-q> do_quit
3010 bind all <$M1B-Key-Q> do_quit
3011 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3012 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3013
3014 set subcommand_args {}
3015 proc usage {} {
3016         set s "usage: $::argv0 $::subcommand $::subcommand_args"
3017         if {[tk windowingsystem] eq "win32"} {
3018                 wm withdraw .
3019                 tk_messageBox -icon info -message $s \
3020                         -title [mc "Usage"]
3021         } else {
3022                 puts stderr $s
3023         }
3024         exit 1
3025 }
3026
3027 proc normalize_relpath {path} {
3028         set elements {}
3029         foreach item [file split $path] {
3030                 if {$item eq {.}} continue
3031                 if {$item eq {..} && [llength $elements] > 0
3032                     && [lindex $elements end] ne {..}} {
3033                         set elements [lrange $elements 0 end-1]
3034                         continue
3035                 }
3036                 lappend elements $item
3037         }
3038         return [eval file join $elements]
3039 }
3040
3041 # -- Not a normal commit type invocation?  Do that instead!
3042 #
3043 switch -- $subcommand {
3044 browser -
3045 blame {
3046         if {$subcommand eq "blame"} {
3047                 set subcommand_args {[--line=<num>] rev? path}
3048         } else {
3049                 set subcommand_args {rev? path}
3050         }
3051         if {$argv eq {}} usage
3052         set head {}
3053         set path {}
3054         set jump_spec {}
3055         set is_path 0
3056         foreach a $argv {
3057                 set p [file join $_prefix $a]
3058
3059                 if {$is_path || [file exists $p]} {
3060                         if {$path ne {}} usage
3061                         set path [normalize_relpath $p]
3062                         break
3063                 } elseif {$a eq {--}} {
3064                         if {$path ne {}} {
3065                                 if {$head ne {}} usage
3066                                 set head $path
3067                                 set path {}
3068                         }
3069                         set is_path 1
3070                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3071                         if {$jump_spec ne {} || $head ne {}} usage
3072                         set jump_spec [list $lnum]
3073                 } elseif {$head eq {}} {
3074                         if {$head ne {}} usage
3075                         set head $a
3076                         set is_path 1
3077                 } else {
3078                         usage
3079                 }
3080         }
3081         unset is_path
3082
3083         if {$head ne {} && $path eq {}} {
3084                 if {[string index $head 0] eq {/}} {
3085                         set path [normalize_relpath $head]
3086                         set head {}
3087                 } else {
3088                         set path [normalize_relpath $_prefix$head]
3089                         set head {}
3090                 }
3091         }
3092
3093         if {$head eq {}} {
3094                 load_current_branch
3095         } else {
3096                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3097                         if {[catch {
3098                                         set head [git rev-parse --verify $head]
3099                                 } err]} {
3100                                 if {[tk windowingsystem] eq "win32"} {
3101                                         tk_messageBox -icon error -title [mc Error] -message $err
3102                                 } else {
3103                                         puts stderr $err
3104                                 }
3105                                 exit 1
3106                         }
3107                 }
3108                 set current_branch $head
3109         }
3110
3111         wm deiconify .
3112         switch -- $subcommand {
3113         browser {
3114                 if {$jump_spec ne {}} usage
3115                 if {$head eq {}} {
3116                         if {$path ne {} && [file isdirectory $path]} {
3117                                 set head $current_branch
3118                         } else {
3119                                 set head $path
3120                                 set path {}
3121                         }
3122                 }
3123                 browser::new $head $path
3124         }
3125         blame   {
3126                 if {$head eq {} && ![file exists $path]} {
3127                         catch {wm withdraw .}
3128                         tk_messageBox \
3129                                 -icon error \
3130                                 -type ok \
3131                                 -title [mc "git-gui: fatal error"] \
3132                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3133                         exit 1
3134                 }
3135                 blame::new $head $path $jump_spec
3136         }
3137         }
3138         return
3139 }
3140 citool -
3141 gui {
3142         if {[llength $argv] != 0} {
3143                 usage
3144         }
3145         # fall through to setup UI for commits
3146 }
3147 default {
3148         set err "usage: $argv0 \[{blame|browser|citool}\]"
3149         if {[tk windowingsystem] eq "win32"} {
3150                 wm withdraw .
3151                 tk_messageBox -icon error -message $err \
3152                         -title [mc "Usage"]
3153         } else {
3154                 puts stderr $err
3155         }
3156         exit 1
3157 }
3158 }
3159
3160 # -- Branch Control
3161 #
3162 ${NS}::frame .branch
3163 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3164 ${NS}::label .branch.l1 \
3165         -text [mc "Current Branch:"] \
3166         -anchor w \
3167         -justify left
3168 ${NS}::label .branch.cb \
3169         -textvariable current_branch \
3170         -anchor w \
3171         -justify left
3172 pack .branch.l1 -side left
3173 pack .branch.cb -side left -fill x
3174 pack .branch -side top -fill x
3175
3176 # -- Main Window Layout
3177 #
3178 ${NS}::panedwindow .vpane -orient horizontal
3179 ${NS}::panedwindow .vpane.files -orient vertical
3180 if {$use_ttk} {
3181         .vpane add .vpane.files
3182 } else {
3183         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3184 }
3185 pack .vpane -anchor n -side top -fill both -expand 1
3186
3187 # -- Index File List
3188 #
3189 ${NS}::frame .vpane.files.index -height 100 -width 200
3190 tlabel .vpane.files.index.title \
3191         -text [mc "Staged Changes (Will Commit)"] \
3192         -background lightgreen -foreground black
3193 text $ui_index -background white -foreground black \
3194         -borderwidth 0 \
3195         -width 20 -height 10 \
3196         -wrap none \
3197         -cursor $cursor_ptr \
3198         -xscrollcommand {.vpane.files.index.sx set} \
3199         -yscrollcommand {.vpane.files.index.sy set} \
3200         -state disabled
3201 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3202 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3203 pack .vpane.files.index.title -side top -fill x
3204 pack .vpane.files.index.sx -side bottom -fill x
3205 pack .vpane.files.index.sy -side right -fill y
3206 pack $ui_index -side left -fill both -expand 1
3207
3208 # -- Working Directory File List
3209 #
3210 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3211 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3212         -background lightsalmon -foreground black
3213 text $ui_workdir -background white -foreground black \
3214         -borderwidth 0 \
3215         -width 20 -height 10 \
3216         -wrap none \
3217         -cursor $cursor_ptr \
3218         -xscrollcommand {.vpane.files.workdir.sx set} \
3219         -yscrollcommand {.vpane.files.workdir.sy set} \
3220         -state disabled
3221 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3222 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3223 pack .vpane.files.workdir.title -side top -fill x
3224 pack .vpane.files.workdir.sx -side bottom -fill x
3225 pack .vpane.files.workdir.sy -side right -fill y
3226 pack $ui_workdir -side left -fill both -expand 1
3227
3228 .vpane.files add .vpane.files.workdir
3229 .vpane.files add .vpane.files.index
3230 if {!$use_ttk} {
3231         .vpane.files paneconfigure .vpane.files.workdir -sticky news
3232         .vpane.files paneconfigure .vpane.files.index -sticky news
3233 }
3234
3235 foreach i [list $ui_index $ui_workdir] {
3236         rmsel_tag $i
3237         $i tag conf in_diff -background [$i tag cget in_sel -background]
3238 }
3239 unset i
3240
3241 # -- Diff and Commit Area
3242 #
3243 if {$have_tk85} {
3244         ${NS}::panedwindow .vpane.lower -orient vertical
3245         ${NS}::frame .vpane.lower.commarea
3246         ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3247         .vpane.lower add .vpane.lower.diff
3248         .vpane.lower add .vpane.lower.commarea
3249         .vpane add .vpane.lower
3250         if {$use_ttk} {
3251                 .vpane.lower pane .vpane.lower.diff -weight 1
3252                 .vpane.lower pane .vpane.lower.commarea -weight 0
3253         } else {
3254                 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3255                 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3256         }
3257 } else {
3258         frame .vpane.lower -height 300 -width 400
3259         frame .vpane.lower.commarea
3260         frame .vpane.lower.diff -relief sunken -borderwidth 1
3261         pack .vpane.lower.diff -fill both -expand 1
3262         pack .vpane.lower.commarea -side bottom -fill x
3263         .vpane add .vpane.lower
3264         .vpane paneconfigure .vpane.lower -sticky nsew
3265 }
3266
3267 # -- Commit Area Buttons
3268 #
3269 ${NS}::frame .vpane.lower.commarea.buttons
3270 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3271         -anchor w \
3272         -justify left
3273 pack .vpane.lower.commarea.buttons.l -side top -fill x
3274 pack .vpane.lower.commarea.buttons -side left -fill y
3275
3276 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3277         -command ui_do_rescan
3278 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3279 lappend disable_on_lock \
3280         {.vpane.lower.commarea.buttons.rescan conf -state}
3281
3282 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3283         -command do_add_all
3284 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3285 lappend disable_on_lock \
3286         {.vpane.lower.commarea.buttons.incall conf -state}
3287
3288 if {![is_enabled nocommitmsg]} {
3289         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3290                 -command do_signoff
3291         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3292 }
3293
3294 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3295         -command do_commit
3296 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3297 lappend disable_on_lock \
3298         {.vpane.lower.commarea.buttons.commit conf -state}
3299
3300 if {![is_enabled nocommit]} {
3301         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3302                 -command do_push_anywhere
3303         pack .vpane.lower.commarea.buttons.push -side top -fill x
3304 }
3305
3306 # -- Commit Message Buffer
3307 #
3308 ${NS}::frame .vpane.lower.commarea.buffer
3309 ${NS}::frame .vpane.lower.commarea.buffer.header
3310 set ui_comm .vpane.lower.commarea.buffer.t
3311 set ui_coml .vpane.lower.commarea.buffer.header.l
3312
3313 if {![is_enabled nocommit]} {
3314         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3315                 -text [mc "New Commit"] \
3316                 -command do_select_commit_type \
3317                 -variable selected_commit_type \
3318                 -value new
3319         lappend disable_on_lock \
3320                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3321         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3322                 -text [mc "Amend Last Commit"] \
3323                 -command do_select_commit_type \
3324                 -variable selected_commit_type \
3325                 -value amend
3326         lappend disable_on_lock \
3327                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3328 }
3329
3330 ${NS}::label $ui_coml \
3331         -anchor w \
3332         -justify left
3333 proc trace_commit_type {varname args} {
3334         global ui_coml commit_type
3335         switch -glob -- $commit_type {
3336         initial       {set txt [mc "Initial Commit Message:"]}
3337         amend         {set txt [mc "Amended Commit Message:"]}
3338         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3339         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3340         merge         {set txt [mc "Merge Commit Message:"]}
3341         *             {set txt [mc "Commit Message:"]}
3342         }
3343         $ui_coml conf -text $txt
3344 }
3345 trace add variable commit_type write trace_commit_type
3346 pack $ui_coml -side left -fill x
3347
3348 if {![is_enabled nocommit]} {
3349         pack .vpane.lower.commarea.buffer.header.amend -side right
3350         pack .vpane.lower.commarea.buffer.header.new -side right
3351 }
3352
3353 text $ui_comm -background white -foreground black \
3354         -borderwidth 1 \
3355         -undo true \
3356         -maxundo 20 \
3357         -autoseparators true \
3358         -relief sunken \
3359         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3360         -font font_diff \
3361         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3362 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3363         -command [list $ui_comm yview]
3364 pack .vpane.lower.commarea.buffer.header -side top -fill x
3365 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3366 pack $ui_comm -side left -fill y
3367 pack .vpane.lower.commarea.buffer -side left -fill y
3368
3369 # -- Commit Message Buffer Context Menu
3370 #
3371 set ctxm .vpane.lower.commarea.buffer.ctxm
3372 menu $ctxm -tearoff 0
3373 $ctxm add command \
3374         -label [mc Cut] \
3375         -command {tk_textCut $ui_comm}
3376 $ctxm add command \
3377         -label [mc Copy] \
3378         -command {tk_textCopy $ui_comm}
3379 $ctxm add command \
3380         -label [mc Paste] \
3381         -command {tk_textPaste $ui_comm}
3382 $ctxm add command \
3383         -label [mc Delete] \
3384         -command {catch {$ui_comm delete sel.first sel.last}}
3385 $ctxm add separator
3386 $ctxm add command \
3387         -label [mc "Select All"] \
3388         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3389 $ctxm add command \
3390         -label [mc "Copy All"] \
3391         -command {
3392                 $ui_comm tag add sel 0.0 end
3393                 tk_textCopy $ui_comm
3394                 $ui_comm tag remove sel 0.0 end
3395         }
3396 $ctxm add separator
3397 $ctxm add command \
3398         -label [mc "Sign Off"] \
3399         -command do_signoff
3400 set ui_comm_ctxm $ctxm
3401
3402 # -- Diff Header
3403 #
3404 proc trace_current_diff_path {varname args} {
3405         global current_diff_path diff_actions file_states
3406         if {$current_diff_path eq {}} {
3407                 set s {}
3408                 set f {}
3409                 set p {}
3410                 set o disabled
3411         } else {
3412                 set p $current_diff_path
3413                 set s [mapdesc [lindex $file_states($p) 0] $p]
3414                 set f [mc "File:"]
3415                 set p [escape_path $p]
3416                 set o normal
3417         }
3418
3419         .vpane.lower.diff.header.status configure -text $s
3420         .vpane.lower.diff.header.file configure -text $f
3421         .vpane.lower.diff.header.path configure -text $p
3422         foreach w $diff_actions {
3423                 uplevel #0 $w $o
3424         }
3425 }
3426 trace add variable current_diff_path write trace_current_diff_path
3427
3428 gold_frame .vpane.lower.diff.header
3429 tlabel .vpane.lower.diff.header.status \
3430         -background gold \
3431         -foreground black \
3432         -width $max_status_desc \
3433         -anchor w \
3434         -justify left
3435 tlabel .vpane.lower.diff.header.file \
3436         -background gold \
3437         -foreground black \
3438         -anchor w \
3439         -justify left
3440 tlabel .vpane.lower.diff.header.path \
3441         -background gold \
3442         -foreground black \
3443         -anchor w \
3444         -justify left
3445 pack .vpane.lower.diff.header.status -side left
3446 pack .vpane.lower.diff.header.file -side left
3447 pack .vpane.lower.diff.header.path -fill x
3448 set ctxm .vpane.lower.diff.header.ctxm
3449 menu $ctxm -tearoff 0
3450 $ctxm add command \
3451         -label [mc Copy] \
3452         -command {
3453                 clipboard clear
3454                 clipboard append \
3455                         -format STRING \
3456                         -type STRING \
3457                         -- $current_diff_path
3458         }
3459 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3460 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
3461
3462 # -- Diff Body
3463 #
3464 ${NS}::frame .vpane.lower.diff.body
3465 set ui_diff .vpane.lower.diff.body.t
3466 text $ui_diff -background white -foreground black \
3467         -borderwidth 0 \
3468         -width 80 -height 5 -wrap none \
3469         -font font_diff \
3470         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3471         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3472         -state disabled
3473 catch {$ui_diff configure -tabstyle wordprocessor}
3474 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3475         -command [list $ui_diff xview]
3476 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3477         -command [list $ui_diff yview]
3478 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3479 pack .vpane.lower.diff.body.sby -side right -fill y
3480 pack $ui_diff -side left -fill both -expand 1
3481 pack .vpane.lower.diff.header -side top -fill x
3482 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3483
3484 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3485         $ui_diff tag configure clr4$n -background $c
3486         $ui_diff tag configure clri4$n -foreground $c
3487         $ui_diff tag configure clr3$n -foreground $c
3488         $ui_diff tag configure clri3$n -background $c
3489 }
3490 $ui_diff tag configure clr1 -font font_diffbold
3491 $ui_diff tag configure clr4 -underline 1
3492
3493 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3494
3495 $ui_diff tag conf d_cr -elide true
3496 $ui_diff tag conf d_@ -font font_diffbold
3497 $ui_diff tag conf d_+ -foreground {#00a000}
3498 $ui_diff tag conf d_- -foreground red
3499
3500 $ui_diff tag conf d_++ -foreground {#00a000}
3501 $ui_diff tag conf d_-- -foreground red
3502 $ui_diff tag conf d_+s \
3503         -foreground {#00a000} \
3504         -background {#e2effa}
3505 $ui_diff tag conf d_-s \
3506         -foreground red \
3507         -background {#e2effa}
3508 $ui_diff tag conf d_s+ \
3509         -foreground {#00a000} \
3510         -background ivory1
3511 $ui_diff tag conf d_s- \
3512         -foreground red \
3513         -background ivory1
3514
3515 $ui_diff tag conf d< \
3516         -foreground orange \
3517         -font font_diffbold
3518 $ui_diff tag conf d= \
3519         -foreground orange \
3520         -font font_diffbold
3521 $ui_diff tag conf d> \
3522         -foreground orange \
3523         -font font_diffbold
3524
3525 $ui_diff tag raise sel
3526
3527 # -- Diff Body Context Menu
3528 #
3529
3530 proc create_common_diff_popup {ctxm} {
3531         $ctxm add command \
3532                 -label [mc Refresh] \
3533                 -command reshow_diff
3534         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3535         $ctxm add command \
3536                 -label [mc Copy] \
3537                 -command {tk_textCopy $ui_diff}
3538         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3539         $ctxm add command \
3540                 -label [mc "Select All"] \
3541                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3542         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3543         $ctxm add command \
3544                 -label [mc "Copy All"] \
3545                 -command {
3546                         $ui_diff tag add sel 0.0 end
3547                         tk_textCopy $ui_diff
3548                         $ui_diff tag remove sel 0.0 end
3549                 }
3550         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3551         $ctxm add separator
3552         $ctxm add command \
3553                 -label [mc "Decrease Font Size"] \
3554                 -command {incr_font_size font_diff -1}
3555         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3556         $ctxm add command \
3557                 -label [mc "Increase Font Size"] \
3558                 -command {incr_font_size font_diff 1}
3559         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3560         $ctxm add separator
3561         set emenu $ctxm.enc
3562         menu $emenu
3563         build_encoding_menu $emenu [list force_diff_encoding]
3564         $ctxm add cascade \
3565                 -label [mc "Encoding"] \
3566                 -menu $emenu
3567         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3568         $ctxm add separator
3569         $ctxm add command -label [mc "Options..."] \
3570                 -command do_options
3571 }
3572
3573 set ctxm .vpane.lower.diff.body.ctxm
3574 menu $ctxm -tearoff 0
3575 $ctxm add command \
3576         -label [mc "Apply/Reverse Hunk"] \
3577         -command {apply_hunk $cursorX $cursorY}
3578 set ui_diff_applyhunk [$ctxm index last]
3579 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
3580 $ctxm add command \
3581         -label [mc "Apply/Reverse Line"] \
3582         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3583 set ui_diff_applyline [$ctxm index last]
3584 lappend diff_actions [list $ctxm entryconf $ui_diff_applyline -state]
3585 $ctxm add separator
3586 $ctxm add command \
3587         -label [mc "Show Less Context"] \
3588         -command show_less_context
3589 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3590 $ctxm add command \
3591         -label [mc "Show More Context"] \
3592         -command show_more_context
3593 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3594 $ctxm add separator
3595 create_common_diff_popup $ctxm
3596
3597 set ctxmmg .vpane.lower.diff.body.ctxmmg
3598 menu $ctxmmg -tearoff 0
3599 $ctxmmg add command \
3600         -label [mc "Run Merge Tool"] \
3601         -command {merge_resolve_tool}
3602 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3603 $ctxmmg add separator
3604 $ctxmmg add command \
3605         -label [mc "Use Remote Version"] \
3606         -command {merge_resolve_one 3}
3607 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3608 $ctxmmg add command \
3609         -label [mc "Use Local Version"] \
3610         -command {merge_resolve_one 2}
3611 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3612 $ctxmmg add command \
3613         -label [mc "Revert To Base"] \
3614         -command {merge_resolve_one 1}
3615 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3616 $ctxmmg add separator
3617 $ctxmmg add command \
3618         -label [mc "Show Less Context"] \
3619         -command show_less_context
3620 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3621 $ctxmmg add command \
3622         -label [mc "Show More Context"] \
3623         -command show_more_context
3624 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3625 $ctxmmg add separator
3626 create_common_diff_popup $ctxmmg
3627
3628 set ctxmsm .vpane.lower.diff.body.ctxmsm
3629 menu $ctxmsm -tearoff 0
3630 $ctxmsm add command \
3631         -label [mc "Visualize These Changes In The Submodule"] \
3632         -command {do_gitk -- true}
3633 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3634 $ctxmsm add command \
3635         -label [mc "Visualize Current Branch History In The Submodule"] \
3636         -command {do_gitk {} true}
3637 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3638 $ctxmsm add command \
3639         -label [mc "Visualize All Branch History In The Submodule"] \
3640         -command {do_gitk --all true}
3641 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3642 $ctxmsm add separator
3643 $ctxmsm add command \
3644         -label [mc "Start git gui In The Submodule"] \
3645         -command {do_git_gui}
3646 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3647 $ctxmsm add separator
3648 create_common_diff_popup $ctxmsm
3649
3650 proc has_textconv {path} {
3651         if {[is_config_false gui.textconv]} {
3652                 return 0
3653         }
3654         set filter [gitattr $path diff set]
3655         set textconv [get_config [join [list diff $filter textconv] .]]
3656         if {$filter ne {set} && $textconv ne {}} {
3657                 return 1
3658         } else {
3659                 return 0
3660         }
3661 }
3662
3663 proc popup_diff_menu {ctxm ctxmmg ctxmsm x y X Y} {
3664         global current_diff_path file_states
3665         set ::cursorX $x
3666         set ::cursorY $y
3667         if {[info exists file_states($current_diff_path)]} {
3668                 set state [lindex $file_states($current_diff_path) 0]
3669         } else {
3670                 set state {__}
3671         }
3672         if {[string first {U} $state] >= 0} {
3673                 tk_popup $ctxmmg $X $Y
3674         } elseif {$::is_submodule_diff} {
3675                 tk_popup $ctxmsm $X $Y
3676         } else {
3677                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3678                 if {$::ui_index eq $::current_diff_side} {
3679                         set l [mc "Unstage Hunk From Commit"]
3680                         if {$has_range} {
3681                                 set t [mc "Unstage Lines From Commit"]
3682                         } else {
3683                                 set t [mc "Unstage Line From Commit"]
3684                         }
3685                 } else {
3686                         set l [mc "Stage Hunk For Commit"]
3687                         if {$has_range} {
3688                                 set t [mc "Stage Lines For Commit"]
3689                         } else {
3690                                 set t [mc "Stage Line For Commit"]
3691                         }
3692                 }
3693                 if {$::is_3way_diff
3694                         || $current_diff_path eq {}
3695                         || {__} eq $state
3696                         || {_O} eq $state
3697                         || [string match {?T} $state]
3698                         || [string match {T?} $state]
3699                         || [has_textconv $current_diff_path]} {
3700                         set s disabled
3701                 } else {
3702                         set s normal
3703                 }
3704                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3705                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3706                 tk_popup $ctxm $X $Y
3707         }
3708 }
3709 bind_button3 $ui_diff [list popup_diff_menu $ctxm $ctxmmg $ctxmsm %x %y %X %Y]
3710
3711 # -- Status Bar
3712 #
3713 set main_status [::status_bar::new .status]
3714 pack .status -anchor w -side bottom -fill x
3715 $main_status show [mc "Initializing..."]
3716
3717 # -- Load geometry
3718 #
3719 proc on_ttk_pane_mapped {w pane pos} {
3720         bind $w <Map> {}
3721         after 0 [list after idle [list $w sashpos $pane $pos]]
3722 }
3723 proc on_tk_pane_mapped {w pane x y} {
3724         bind $w <Map> {}
3725         after 0 [list after idle [list $w sash place $pane $x $y]]
3726 }
3727 proc on_application_mapped {} {
3728         global repo_config use_ttk
3729         bind . <Map> {}
3730         set gm $repo_config(gui.geometry)
3731         if {$use_ttk} {
3732                 bind .vpane <Map> \
3733                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3734                 bind .vpane.files <Map> \
3735                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3736         } else {
3737                 bind .vpane <Map> \
3738                     [list on_tk_pane_mapped %W 0 \
3739                          [lindex $gm 1] \
3740                          [lindex [.vpane sash coord 0] 1]]
3741                 bind .vpane.files <Map> \
3742                     [list on_tk_pane_mapped %W 0 \
3743                          [lindex [.vpane.files sash coord 0] 0] \
3744                          [lindex $gm 2]]
3745         }
3746         wm geometry . [lindex $gm 0]
3747 }
3748 if {[info exists repo_config(gui.geometry)]} {
3749         bind . <Map> [list on_application_mapped]
3750         wm geometry . [lindex $repo_config(gui.geometry) 0]
3751 }
3752
3753 # -- Load window state
3754 #
3755 if {[info exists repo_config(gui.wmstate)]} {
3756         catch {wm state . $repo_config(gui.wmstate)}
3757 }
3758
3759 # -- Key Bindings
3760 #
3761 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3762 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3763 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3764 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3765 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3766 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3767 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3768 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3769 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3770 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3771 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3772 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3773 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3774 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3775 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3776 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3777 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3778 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3779 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3780 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3781 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3782 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3783
3784 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3785 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3786 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3787 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3788 bind $ui_diff <$M1B-Key-v> {break}
3789 bind $ui_diff <$M1B-Key-V> {break}
3790 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3791 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3792 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3793 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3794 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3795 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3796 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3797 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3798 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3799 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3800 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3801 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3802 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3803 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3804 bind $ui_diff <Button-1>   {focus %W}
3805
3806 if {[is_enabled branch]} {
3807         bind . <$M1B-Key-n> branch_create::dialog
3808         bind . <$M1B-Key-N> branch_create::dialog
3809         bind . <$M1B-Key-o> branch_checkout::dialog
3810         bind . <$M1B-Key-O> branch_checkout::dialog
3811         bind . <$M1B-Key-m> merge::dialog
3812         bind . <$M1B-Key-M> merge::dialog
3813 }
3814 if {[is_enabled transport]} {
3815         bind . <$M1B-Key-p> do_push_anywhere
3816         bind . <$M1B-Key-P> do_push_anywhere
3817 }
3818
3819 bind .   <Key-F5>     ui_do_rescan
3820 bind .   <$M1B-Key-r> ui_do_rescan
3821 bind .   <$M1B-Key-R> ui_do_rescan
3822 bind .   <$M1B-Key-s> do_signoff
3823 bind .   <$M1B-Key-S> do_signoff
3824 bind .   <$M1B-Key-t> do_add_selection
3825 bind .   <$M1B-Key-T> do_add_selection
3826 bind .   <$M1B-Key-u> do_unstage_selection
3827 bind .   <$M1B-Key-U> do_unstage_selection
3828 bind .   <$M1B-Key-j> do_revert_selection
3829 bind .   <$M1B-Key-J> do_revert_selection
3830 bind .   <$M1B-Key-i> do_add_all
3831 bind .   <$M1B-Key-I> do_add_all
3832 bind .   <$M1B-Key-minus> {show_less_context;break}
3833 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3834 bind .   <$M1B-Key-equal> {show_more_context;break}
3835 bind .   <$M1B-Key-plus> {show_more_context;break}
3836 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3837 bind .   <$M1B-Key-Return> do_commit
3838 foreach i [list $ui_index $ui_workdir] {
3839         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3840         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3841         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3842 }
3843 unset i
3844
3845 set file_lists($ui_index) [list]
3846 set file_lists($ui_workdir) [list]
3847
3848 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3849 focus -force $ui_comm
3850
3851 # -- Warn the user about environmental problems.  Cygwin's Tcl
3852 #    does *not* pass its env array onto any processes it spawns.
3853 #    This means that git processes get none of our environment.
3854 #
3855 if {[is_Cygwin]} {
3856         set ignored_env 0
3857         set suggest_user {}
3858         set msg [mc "Possible environment issues exist.
3859
3860 The following environment variables are probably
3861 going to be ignored by any Git subprocess run
3862 by %s:
3863
3864 " [appname]]
3865         foreach name [array names env] {
3866                 switch -regexp -- $name {
3867                 {^GIT_INDEX_FILE$} -
3868                 {^GIT_OBJECT_DIRECTORY$} -
3869                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3870                 {^GIT_DIFF_OPTS$} -
3871                 {^GIT_EXTERNAL_DIFF$} -
3872                 {^GIT_PAGER$} -
3873                 {^GIT_TRACE$} -
3874                 {^GIT_CONFIG$} -
3875                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3876                         append msg " - $name\n"
3877                         incr ignored_env
3878                 }
3879                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3880                         append msg " - $name\n"
3881                         incr ignored_env
3882                         set suggest_user $name
3883                 }
3884                 }
3885         }
3886         if {$ignored_env > 0} {
3887                 append msg [mc "
3888 This is due to a known issue with the
3889 Tcl binary distributed by Cygwin."]
3890
3891                 if {$suggest_user ne {}} {
3892                         append msg [mc "
3893
3894 A good replacement for %s
3895 is placing values for the user.name and
3896 user.email settings into your personal
3897 ~/.gitconfig file.
3898 " $suggest_user]
3899                 }
3900                 warn_popup $msg
3901         }
3902         unset ignored_env msg suggest_user name
3903 }
3904
3905 # -- Only initialize complex UI if we are going to stay running.
3906 #
3907 if {[is_enabled transport]} {
3908         load_all_remotes
3909
3910         set n [.mbar.remote index end]
3911         populate_remotes_menu
3912         set n [expr {[.mbar.remote index end] - $n}]
3913         if {$n > 0} {
3914                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3915                 .mbar.remote insert $n separator
3916         }
3917         unset n
3918 }
3919
3920 if {[winfo exists $ui_comm]} {
3921         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
3922
3923         # -- If both our backup and message files exist use the
3924         #    newer of the two files to initialize the buffer.
3925         #
3926         if {$GITGUI_BCK_exists} {
3927                 set m [gitdir GITGUI_MSG]
3928                 if {[file isfile $m]} {
3929                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
3930                                 catch {file delete [gitdir GITGUI_MSG]}
3931                         } else {
3932                                 $ui_comm delete 0.0 end
3933                                 $ui_comm edit reset
3934                                 $ui_comm edit modified false
3935                                 catch {file delete [gitdir GITGUI_BCK]}
3936                                 set GITGUI_BCK_exists 0
3937                         }
3938                 }
3939                 unset m
3940         }
3941
3942         proc backup_commit_buffer {} {
3943                 global ui_comm GITGUI_BCK_exists
3944
3945                 set m [$ui_comm edit modified]
3946                 if {$m || $GITGUI_BCK_exists} {
3947                         set msg [string trim [$ui_comm get 0.0 end]]
3948                         regsub -all -line {[ \r\t]+$} $msg {} msg
3949
3950                         if {$msg eq {}} {
3951                                 if {$GITGUI_BCK_exists} {
3952                                         catch {file delete [gitdir GITGUI_BCK]}
3953                                         set GITGUI_BCK_exists 0
3954                                 }
3955                         } elseif {$m} {
3956                                 catch {
3957                                         set fd [open [gitdir GITGUI_BCK] w]
3958                                         fconfigure $fd -encoding utf-8
3959                                         puts -nonewline $fd $msg
3960                                         close $fd
3961                                         set GITGUI_BCK_exists 1
3962                                 }
3963                         }
3964
3965                         $ui_comm edit modified false
3966                 }
3967
3968                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
3969         }
3970
3971         backup_commit_buffer
3972
3973         # -- If the user has aspell available we can drive it
3974         #    in pipe mode to spellcheck the commit message.
3975         #
3976         set spell_cmd [list |]
3977         set spell_dict [get_config gui.spellingdictionary]
3978         lappend spell_cmd aspell
3979         if {$spell_dict ne {}} {
3980                 lappend spell_cmd --master=$spell_dict
3981         }
3982         lappend spell_cmd --mode=none
3983         lappend spell_cmd --encoding=utf-8
3984         lappend spell_cmd pipe
3985         if {$spell_dict eq {none}
3986          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
3987                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
3988         } else {
3989                 set ui_comm_spell [spellcheck::init \
3990                         $spell_fd \
3991                         $ui_comm \
3992                         $ui_comm_ctxm \
3993                 ]
3994         }
3995         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
3996 }
3997
3998 lock_index begin-read
3999 if {![winfo ismapped .]} {
4000         wm deiconify .
4001 }
4002 after 1 {
4003         if {[is_enabled initialamend]} {
4004                 force_amend
4005         } else {
4006                 do_rescan
4007         }
4008
4009         if {[is_enabled nocommitmsg]} {
4010                 $ui_comm configure -state disabled -background gray
4011         }
4012 }
4013 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4014         after 1000 hint_gc
4015 }
4016 if {[is_enabled retcode]} {
4017         bind . <Destroy> {+terminate_me %W}
4018 }
4019 if {$picked && [is_config_true gui.autoexplore]} {
4020         do_explore
4021 }
4022
4023 # Local variables:
4024 # mode: tcl
4025 # indent-tabs-mode: t
4026 # tab-width: 4
4027 # End: