| blob | 890ef61235fa0fb0824e46a87fb85f4e2a06100d |
1 # -*- Autoconf -*-
2 # Process this file with autoconf to produce a configure script.
4 ## Definitions of private macros.
6 # GIT_CONF_SUBST(VAL, VAR)
7 # ------------------------
8 # Cause the line "VAR=VAL" to be eventually appended to ${config_file}.
9 AC_DEFUN([GIT_CONF_SUBST],
10 [AC_REQUIRE([GIT_CONF_SUBST_INIT])
11 config_appended_defs="$config_appended_defs${newline}dnl
12 $1=m4_if([$#],[1],[${$1}],[$2])"])
14 # GIT_CONF_SUBST_INIT
15 # -------------------
16 # Prepare shell variables and autoconf machine required by later calls
17 # to GIT_CONF_SUBST.
18 AC_DEFUN([GIT_CONF_SUBST_INIT],
19 [config_appended_defs=; newline='
20 '
21 AC_CONFIG_COMMANDS([$config_file],
22 [echo "$config_appended_defs" >> "$config_file"],
23 [config_file=$config_file
24 config_appended_defs="$config_appended_defs"])])
26 # GIT_ARG_SET_PATH(PROGRAM)
27 # -------------------------
28 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
29 # Optional second argument allows setting NO_PROGRAM=YesPlease if
30 # --without-PROGRAM version used.
31 AC_DEFUN([GIT_ARG_SET_PATH],
32 [AC_ARG_WITH([$1],
33 [AS_HELP_STRING([--with-$1=PATH],
34 [provide PATH to $1])],
35 [GIT_CONF_APPEND_PATH([$1], [$2])],
36 [])])
38 # GIT_CONF_APPEND_PATH(PROGRAM)
39 # -----------------------------
40 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
41 # Used by GIT_ARG_SET_PATH(PROGRAM)
42 # Optional second argument allows setting NO_PROGRAM=YesPlease if
43 # --without-PROGRAM is used.
44 AC_DEFUN([GIT_CONF_APPEND_PATH],
45 [m4_pushdef([GIT_UC_PROGRAM], m4_toupper([$1]))dnl
46 if test "$withval" = "no"; then
47 if test -n "$2"; then
48 GIT_UC_PROGRAM[]_PATH=$withval
49 AC_MSG_NOTICE([Disabling use of GIT_UC_PROGRAM])
50 GIT_CONF_SUBST([NO_]GIT_UC_PROGRAM, [YesPlease])
51 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [])
52 else
53 AC_MSG_ERROR([You cannot use git without $1])
54 fi
55 else
56 if test "$withval" = "yes"; then
57 AC_MSG_WARN([You should provide path for --with-$1=PATH])
58 else
59 GIT_UC_PROGRAM[]_PATH=$withval
60 AC_MSG_NOTICE([Setting GIT_UC_PROGRAM[]_PATH to $withval])
61 GIT_CONF_SUBST(GIT_UC_PROGRAM[]_PATH, [$withval])
62 fi
63 fi
64 m4_popdef([GIT_UC_PROGRAM])])
66 # GIT_PARSE_WITH(PACKAGE)
67 # -----------------------
68 # For use in AC_ARG_WITH action-if-found, for packages default ON.
69 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
70 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
71 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
72 AC_DEFUN([GIT_PARSE_WITH],
73 [m4_pushdef([GIT_UC_PACKAGE], m4_toupper([$1]))dnl
74 if test "$withval" = "no"; then
75 NO_[]GIT_UC_PACKAGE=YesPlease
76 elif test "$withval" = "yes"; then
77 NO_[]GIT_UC_PACKAGE=
78 else
79 NO_[]GIT_UC_PACKAGE=
80 GIT_UC_PACKAGE[]DIR=$withval
81 AC_MSG_NOTICE([Setting GIT_UC_PACKAGE[]DIR to $withval])
82 GIT_CONF_SUBST(GIT_UC_PACKAGE[DIR], [$withval])
83 fi
84 m4_popdef([GIT_UC_PACKAGE])])
86 # GIT_PARSE_WITH_SET_MAKE_VAR(WITHNAME, VAR, HELP_TEXT)
87 # -----------------------------------------------------
88 # Set VAR to the value specied by --with-WITHNAME.
89 # No verification of arguments is performed, but warnings are issued
90 # if either 'yes' or 'no' is specified.
91 # HELP_TEXT is presented when --help is called.
92 # This is a direct way to allow setting variables in the Makefile.
93 AC_DEFUN([GIT_PARSE_WITH_SET_MAKE_VAR],
94 [AC_ARG_WITH([$1],
95 [AS_HELP_STRING([--with-$1=VALUE], $3)],
96 if test -n "$withval"; then
97 if test "$withval" = "yes" -o "$withval" = "no"; then
98 AC_MSG_WARN([You likely do not want either 'yes' or 'no' as]
99 [a value for $1 ($2). Maybe you do...?])
100 fi
101 AC_MSG_NOTICE([Setting $2 to $withval])
102 GIT_CONF_SUBST([$2], [$withval])
103 fi)])# GIT_PARSE_WITH_SET_MAKE_VAR
105 #
106 # GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
107 # -----------------------------------------
108 # Similar to AC_CHECK_FUNC, but on systems that do not generate
109 # warnings for missing prototypes (e.g. FreeBSD when compiling without
110 # -Wall), it does not work. By looking for function definition in
111 # libraries, this problem can be worked around.
112 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
113 AC_SEARCH_LIBS([$1],,
114 [$2],[$3])
115 ],[$3])])
117 #
118 # GIT_STASH_FLAGS(BASEPATH_VAR)
119 # -----------------------------
120 # Allow for easy stashing of LDFLAGS and CPPFLAGS before running
121 # tests that may want to take user settings into account.
122 AC_DEFUN([GIT_STASH_FLAGS],[
123 if test -n "$1"; then
124 old_CPPFLAGS="$CPPFLAGS"
125 old_LDFLAGS="$LDFLAGS"
126 CPPFLAGS="-I$1/include $CPPFLAGS"
127 LDFLAGS="-L$1/$lib $LDFLAGS"
128 fi
129 ])
131 dnl
132 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
133 dnl -----------------------------
134 dnl Restore the stashed *FLAGS values.
135 AC_DEFUN([GIT_UNSTASH_FLAGS],[
136 if test -n "$1"; then
137 CPPFLAGS="$old_CPPFLAGS"
138 LDFLAGS="$old_LDFLAGS"
139 fi
140 ])
142 ## Configure body starts here.
144 AC_PREREQ(2.59)
145 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
147 AC_CONFIG_SRCDIR([git.c])
149 config_file=config.mak.autogen
150 config_in=config.mak.in
152 GIT_CONF_SUBST([AUTOCONFIGURED], [YesPlease])
154 # Directories holding "saner" versions of common or POSIX binaries.
155 AC_ARG_WITH([sane-tool-path],
156 [AS_HELP_STRING(
157 [--with-sane-tool-path=DIR-1[[:DIR-2...:DIR-n]]],
158 [Directories to prepend to PATH in build system and generated scripts])],
159 [if test "$withval" = "no"; then
160 withval=''
161 else
162 AC_MSG_NOTICE([Setting SANE_TOOL_PATH to '$withval'])
163 fi
164 GIT_CONF_SUBST([SANE_TOOL_PATH], [$withval])],
165 [# If the "--with-sane-tool-path" option was not given, don't touch
166 # SANE_TOOL_PATH here, but let defaults in Makefile take care of it.
167 # This should minimize spurious differences in the behaviour of the
168 # Git build system when configure is used w.r.t. when it is not.
169 :])
171 ## Site configuration related to programs (before tests)
172 ## --with-PACKAGE[=ARG] and --without-PACKAGE
173 #
174 # Set lib to alternative name of lib directory (e.g. lib64)
175 AC_ARG_WITH([lib],
176 [AS_HELP_STRING([--with-lib=ARG],
177 [ARG specifies alternative name for lib directory])],
178 [if test "$withval" = "no" || test "$withval" = "yes"; then
179 AC_MSG_WARN([You should provide name for --with-lib=ARG])
180 else
181 lib=$withval
182 AC_MSG_NOTICE([Setting lib to '$lib'])
183 GIT_CONF_SUBST([lib])
184 fi])
186 if test -z "$lib"; then
187 AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
188 lib=lib
189 fi
191 AC_ARG_ENABLE([pthreads],
192 [AS_HELP_STRING([--enable-pthreads=FLAGS],
193 [FLAGS is the value to pass to the compiler to enable POSIX Threads.]
194 [The default if FLAGS is not specified is to try first -pthread]
195 [and then -lpthread.]
196 [--disable-pthreads will disable threading.])],
197 [
198 if test "x$enableval" = "xyes"; then
199 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads])
200 elif test "x$enableval" != "xno"; then
201 PTHREAD_CFLAGS=$enableval
202 AC_MSG_NOTICE([Setting '$PTHREAD_CFLAGS' as the FLAGS to enable POSIX Threads])
203 else
204 AC_MSG_NOTICE([POSIX Threads will be disabled.])
205 NO_PTHREADS=YesPlease
206 USER_NOPTHREAD=1
207 fi],
208 [
209 AC_MSG_NOTICE([Will try -pthread then -lpthread to enable POSIX Threads.])
210 ])
212 # Define option to enable JavaScript minification
213 AC_ARG_ENABLE([jsmin],
214 [AS_HELP_STRING([--enable-jsmin=PATH],
215 [PATH is the name of a JavaScript minifier or the absolute path to one.])],
216 [
217 JSMIN=$enableval;
218 AC_MSG_NOTICE([Setting JSMIN to '$JSMIN' to enable JavaScript minifying])
219 GIT_CONF_SUBST([JSMIN])
220 ])
222 # Define option to enable CSS minification
223 AC_ARG_ENABLE([cssmin],
224 [AS_HELP_STRING([--enable-cssmin=PATH],
225 [PATH is the name of a CSS minifier or the absolute path to one.])],
226 [
227 CSSMIN=$enableval;
228 AC_MSG_NOTICE([Setting CSSMIN to '$CSSMIN' to enable CSS minifying])
229 GIT_CONF_SUBST([CSSMIN])
230 ])
232 ## Site configuration (override autodetection)
233 ## --with-PACKAGE[=ARG] and --without-PACKAGE
234 AC_MSG_NOTICE([CHECKS for site configuration])
235 #
236 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
237 # tests. These tests take up a significant amount of the total test time
238 # but are not needed unless you plan to talk to SVN repos.
239 #
240 # Define PPC_SHA1 environment variable when running make to make use of
241 # a bundled SHA1 routine optimized for PowerPC.
242 #
243 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
244 # This also implies BLK_SHA1.
245 #
246 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
247 # /foo/bar/include and /foo/bar/lib directories.
248 AC_ARG_WITH(openssl,
249 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
250 AS_HELP_STRING([], [ARG can be prefix for openssl library and headers]),
251 GIT_PARSE_WITH([openssl]))
253 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
254 # able to use Perl-compatible regular expressions.
255 #
256 # Define LIBPCREDIR=/foo/bar if your libpcre header and library files are in
257 # /foo/bar/include and /foo/bar/lib directories.
258 #
259 AC_ARG_WITH(libpcre,
260 AS_HELP_STRING([--with-libpcre],[support Perl-compatible regexes (default is NO)])
261 AS_HELP_STRING([], [ARG can be also prefix for libpcre library and headers]),
262 if test "$withval" = "no"; then
263 USE_LIBPCRE=
264 elif test "$withval" = "yes"; then
265 USE_LIBPCRE=YesPlease
266 else
267 USE_LIBPCRE=YesPlease
268 LIBPCREDIR=$withval
269 AC_MSG_NOTICE([Setting LIBPCREDIR to $LIBPCREDIR])
270 dnl USE_LIBPCRE can still be modified below, so don't substitute
271 dnl it yet.
272 GIT_CONF_SUBST([LIBPCREDIR])
273 fi)
274 #
275 # Define HAVE_ALLOCA_H if you have working alloca(3) defined in that header.
276 AC_FUNC_ALLOCA
277 case $ac_cv_working_alloca_h in
278 yes) HAVE_ALLOCA_H=YesPlease;;
279 *) HAVE_ALLOCA_H='';;
280 esac
281 GIT_CONF_SUBST([HAVE_ALLOCA_H])
282 #
283 # Define NO_CURL if you do not have curl installed. git-http-pull and
284 # git-http-push are not built, and you cannot use http:// and https://
285 # transports.
286 #
287 # Define CURLDIR=/foo/bar if your curl header and library files are in
288 # /foo/bar/include and /foo/bar/lib directories.
289 AC_ARG_WITH(curl,
290 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
291 AS_HELP_STRING([], [ARG can be also prefix for curl library and headers]),
292 GIT_PARSE_WITH(curl))
293 #
294 # Define NO_EXPAT if you do not have expat installed. git-http-push is
295 # not built, and you cannot push using http:// and https:// transports.
296 #
297 # Define EXPATDIR=/foo/bar if your expat header and library files are in
298 # /foo/bar/include and /foo/bar/lib directories.
299 AC_ARG_WITH(expat,
300 AS_HELP_STRING([--with-expat],
301 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
302 AS_HELP_STRING([], [ARG can be also prefix for expat library and headers]),
303 GIT_PARSE_WITH(expat))
304 #
305 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
306 # installed in /sw, but don't want GIT to link against any libraries
307 # installed there. If defined you may specify your own (or Fink's)
308 # include directories and library directories by defining CFLAGS
309 # and LDFLAGS appropriately.
310 #
311 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
312 # have DarwinPorts installed in /opt/local, but don't want GIT to
313 # link against any libraries installed there. If defined you may
314 # specify your own (or DarwinPort's) include directories and
315 # library directories by defining CFLAGS and LDFLAGS appropriately.
316 #
317 # Define NO_MMAP if you want to avoid mmap.
318 #
319 # Define NO_ICONV if your libc does not properly support iconv.
320 AC_ARG_WITH(iconv,
321 AS_HELP_STRING([--without-iconv],
322 [if your architecture doesn't properly support iconv])
323 AS_HELP_STRING([--with-iconv=PATH],
324 [PATH is prefix for libiconv library and headers])
325 AS_HELP_STRING([],
326 [used only if you need linking with libiconv]),
327 GIT_PARSE_WITH(iconv))
329 ## --enable-FEATURE[=ARG] and --disable-FEATURE
330 #
331 # Define USE_NSEC below if you want git to care about sub-second file mtimes
332 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
333 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
334 # randomly break unless your underlying filesystem supports those sub-second
335 # times (my ext3 doesn't).
336 #
337 # Define USE_STDEV below if you want git to care about the underlying device
338 # change being considered an inode change from the update-index perspective.
340 #
341 # Allow user to set ETC_GITCONFIG variable
342 GIT_PARSE_WITH_SET_MAKE_VAR(gitconfig, ETC_GITCONFIG,
343 Use VALUE instead of /etc/gitconfig as the
344 global git configuration file.
345 If VALUE is not fully qualified it will be interpreted
346 as a path relative to the computed prefix at runtime.)
348 #
349 # Allow user to set ETC_GITATTRIBUTES variable
350 GIT_PARSE_WITH_SET_MAKE_VAR(gitattributes, ETC_GITATTRIBUTES,
351 Use VALUE instead of /etc/gitattributes as the
352 global git attributes file.
353 If VALUE is not fully qualified it will be interpreted
354 as a path relative to the computed prefix at runtime.)
356 #
357 # Allow user to set the default pager
358 GIT_PARSE_WITH_SET_MAKE_VAR(pager, DEFAULT_PAGER,
359 Use VALUE as the fall-back pager instead of 'less'.
360 This is used by things like 'git log' when the user
361 does not specify a pager to use through alternate
362 methods. eg: /usr/bin/pager)
363 #
364 # Allow user to set the default editor
365 GIT_PARSE_WITH_SET_MAKE_VAR(editor, DEFAULT_EDITOR,
366 Use VALUE as the fall-back editor instead of 'vi'.
367 This is used by things like 'git commit' when the user
368 does not specify a preferred editor through other
369 methods. eg: /usr/bin/editor)
371 #
372 # Define SHELL_PATH to provide path to shell.
373 GIT_ARG_SET_PATH(shell)
374 #
375 # Define PERL_PATH to provide path to Perl.
376 GIT_ARG_SET_PATH(perl)
377 #
378 # Define PYTHON_PATH to provide path to Python.
379 GIT_ARG_SET_PATH(python, allow-without)
380 #
381 # Define ZLIB_PATH to provide path to zlib.
382 GIT_ARG_SET_PATH(zlib)
383 #
384 # Declare the with-tcltk/without-tcltk options.
385 AC_ARG_WITH(tcltk,
386 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
387 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
388 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
389 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),
390 GIT_PARSE_WITH(tcltk))
391 #
394 ## Checks for programs.
395 AC_MSG_NOTICE([CHECKS for programs])
396 #
397 AC_PROG_CC([cc gcc])
398 AC_C_INLINE
399 case $ac_cv_c_inline in
400 inline | yes | no) INLINE='';;
401 *) INLINE=$ac_cv_c_inline ;;
402 esac
403 GIT_CONF_SUBST([INLINE])
405 # which switch to pass runtime path to dynamic libraries to the linker
406 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
407 SAVE_LDFLAGS="${LDFLAGS}"
408 LDFLAGS="${SAVE_LDFLAGS} -R /"
409 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
410 LDFLAGS="${SAVE_LDFLAGS}"
411 ])
412 if test "$git_cv_ld_dashr" = "yes"; then
413 CC_LD_DYNPATH=-R
414 else
415 AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
416 SAVE_LDFLAGS="${LDFLAGS}"
417 LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
418 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
419 LDFLAGS="${SAVE_LDFLAGS}"
420 ])
421 if test "$git_cv_ld_wl_rpath" = "yes"; then
422 CC_LD_DYNPATH=-Wl,-rpath,
423 else
424 AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
425 SAVE_LDFLAGS="${LDFLAGS}"
426 LDFLAGS="${SAVE_LDFLAGS} -rpath /"
427 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])], [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
428 LDFLAGS="${SAVE_LDFLAGS}"
429 ])
430 if test "$git_cv_ld_rpath" = "yes"; then
431 CC_LD_DYNPATH=-rpath
432 else
433 CC_LD_DYNPATH=
434 AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
435 fi
436 fi
437 fi
438 GIT_CONF_SUBST([CC_LD_DYNPATH])
439 #AC_PROG_INSTALL # needs install-sh or install.sh in sources
440 AC_CHECK_TOOLS(AR, [gar ar], :)
441 AC_CHECK_PROGS(TAR, [gtar tar])
442 AC_CHECK_PROGS(DIFF, [gnudiff gdiff diff])
443 # TCLTK_PATH will be set to some value if we want Tcl/Tk
444 # or will be empty otherwise.
445 if test -n "$NO_TCLTK"; then
446 TCLTK_PATH=
447 else
448 if test "$with_tcltk" = ""; then
449 # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
450 TCLTK_PATH=wish
451 elif test "$with_tcltk" = "yes"; then
452 # Tcl/Tk check requested.
453 AC_CHECK_PROGS(TCLTK_PATH, [wish], )
454 else
455 AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
456 TCLTK_PATH="$with_tcltk"
457 fi
458 fi
459 GIT_CONF_SUBST([TCLTK_PATH])
460 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
461 if test -n "$ASCIIDOC"; then
462 AC_MSG_CHECKING([for asciidoc version])
463 asciidoc_version=`$ASCIIDOC --version 2>/dev/null`
464 case "${asciidoc_version}" in
465 asciidoc' '8*)
466 AC_MSG_RESULT([${asciidoc_version}])
467 ;;
468 *)
469 AC_MSG_RESULT([${asciidoc_version} (unknown)])
470 ;;
471 esac
472 fi
475 ## Checks for libraries.
476 AC_MSG_NOTICE([CHECKS for libraries])
477 #
478 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
479 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
481 GIT_STASH_FLAGS($OPENSSLDIR)
483 AC_CHECK_LIB([crypto], [SHA1_Init],
484 [NEEDS_SSL_WITH_CRYPTO=],
485 [AC_CHECK_LIB([ssl], [SHA1_Init],
486 [NEEDS_SSL_WITH_CRYPTO=YesPlease NO_OPENSSL=],
487 [NEEDS_SSL_WITH_CRYPTO= NO_OPENSSL=YesPlease])])
489 GIT_UNSTASH_FLAGS($OPENSSLDIR)
491 GIT_CONF_SUBST([NEEDS_SSL_WITH_CRYPTO])
492 GIT_CONF_SUBST([NO_OPENSSL])
494 #
495 # Define USE_LIBPCRE if you have and want to use libpcre. git-grep will be
496 # able to use Perl-compatible regular expressions.
497 #
499 if test -n "$USE_LIBPCRE"; then
501 GIT_STASH_FLAGS($LIBPCREDIR)
503 AC_CHECK_LIB([pcre], [pcre_version],
504 [USE_LIBPCRE=YesPlease],
505 [USE_LIBPCRE=])
507 GIT_UNSTASH_FLAGS($LIBPCREDIR)
509 GIT_CONF_SUBST([USE_LIBPCRE])
511 fi
513 #
514 # Define NO_CURL if you do not have libcurl installed. git-http-pull and
515 # git-http-push are not built, and you cannot use http:// and https://
516 # transports.
518 GIT_STASH_FLAGS($CURLDIR)
520 AC_CHECK_LIB([curl], [curl_global_init],
521 [NO_CURL=],
522 [NO_CURL=YesPlease])
524 if test -z "$NO_CURL"; then
526 AC_CHECK_DECLS([curl_multi_init],
527 [NO_CURL_MULTI=],
528 [NO_CURL_MULTI=UnfortunatelyYes],
529 [[#include <curl/curl.h>]])
531 GIT_CONF_SUBST([NO_CURL_MULTI])
533 fi
535 GIT_UNSTASH_FLAGS($CURLDIR)
537 GIT_CONF_SUBST([NO_CURL])
539 #
540 # Define NO_EXPAT if you do not have expat installed. git-http-push is
541 # not built, and you cannot push using http:// and https:// transports.
543 GIT_STASH_FLAGS($EXPATDIR)
545 AC_CHECK_LIB([expat], [XML_ParserCreate],
546 [NO_EXPAT=],
547 [NO_EXPAT=YesPlease])
549 GIT_UNSTASH_FLAGS($EXPATDIR)
551 GIT_CONF_SUBST([NO_EXPAT])
553 #
554 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
555 # some Solaris installations).
556 # Define NO_ICONV if neither libc nor libiconv support iconv.
558 if test -z "$NO_ICONV"; then
560 GIT_STASH_FLAGS($ICONVDIR)
562 AC_DEFUN([ICONVTEST_SRC],
563 [AC_LANG_PROGRAM([#include <iconv.h>],
564 [iconv_open("", "");])])
566 if test -n "$ICONVDIR"; then
567 lib_order="-liconv -lc"
568 else
569 lib_order="-lc -liconv"
570 fi
572 NO_ICONV=YesPlease
574 for l in $lib_order; do
575 if test "$l" = "-liconv"; then
576 NEEDS_LIBICONV=YesPlease
577 else
578 NEEDS_LIBICONV=
579 fi
581 old_LIBS="$LIBS"
582 LIBS="$LIBS $l"
583 AC_MSG_CHECKING([for iconv in $l])
584 AC_LINK_IFELSE([ICONVTEST_SRC],
585 [AC_MSG_RESULT([yes])
586 NO_ICONV=
587 break],
588 [AC_MSG_RESULT([no])])
589 LIBS="$old_LIBS"
590 done
592 #in case of break
593 LIBS="$old_LIBS"
595 GIT_UNSTASH_FLAGS($ICONVDIR)
597 GIT_CONF_SUBST([NEEDS_LIBICONV])
598 GIT_CONF_SUBST([NO_ICONV])
600 if test -n "$NO_ICONV"; then
601 NEEDS_LIBICONV=
602 fi
604 fi
606 #
607 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
609 GIT_STASH_FLAGS($ZLIB_PATH)
611 AC_DEFUN([ZLIBTEST_SRC], [
612 AC_LANG_PROGRAM([#include <zlib.h>],
613 [deflateBound(0, 0);])])
614 AC_MSG_CHECKING([for deflateBound in -lz])
615 old_LIBS="$LIBS"
616 LIBS="$LIBS -lz"
617 AC_LINK_IFELSE([ZLIBTEST_SRC],
618 [AC_MSG_RESULT([yes])],
619 [AC_MSG_RESULT([no])
620 NO_DEFLATE_BOUND=yes])
621 LIBS="$old_LIBS"
623 GIT_UNSTASH_FLAGS($ZLIB_PATH)
625 GIT_CONF_SUBST([NO_DEFLATE_BOUND])
627 #
628 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
629 # Patrick Mauritz).
630 AC_CHECK_LIB([c], [socket],
631 [NEEDS_SOCKET=],
632 [NEEDS_SOCKET=YesPlease])
633 GIT_CONF_SUBST([NEEDS_SOCKET])
634 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
636 #
637 # The next few tests will define NEEDS_RESOLV if linking with
638 # libresolv provides some of the functions we would normally get
639 # from libc.
640 NEEDS_RESOLV=
641 #
642 # Define NO_INET_NTOP if linking with -lresolv is not enough.
643 # Solaris 2.7 in particular hos inet_ntop in -lresolv.
644 NO_INET_NTOP=
645 AC_CHECK_FUNC([inet_ntop],
646 [],
647 [AC_CHECK_LIB([resolv], [inet_ntop],
648 [NEEDS_RESOLV=YesPlease],
649 [NO_INET_NTOP=YesPlease])
650 ])
651 GIT_CONF_SUBST([NO_INET_NTOP])
652 #
653 # Define NO_INET_PTON if linking with -lresolv is not enough.
654 # Solaris 2.7 in particular hos inet_pton in -lresolv.
655 NO_INET_PTON=
656 AC_CHECK_FUNC([inet_pton],
657 [],
658 [AC_CHECK_LIB([resolv], [inet_pton],
659 [NEEDS_RESOLV=YesPlease],
660 [NO_INET_PTON=YesPlease])
661 ])
662 GIT_CONF_SUBST([NO_INET_PTON])
663 #
664 # Define NO_HSTRERROR if linking with -lresolv is not enough.
665 # Solaris 2.6 in particular has no hstrerror, even in -lresolv.
666 NO_HSTRERROR=
667 AC_CHECK_FUNC([hstrerror],
668 [],
669 [AC_CHECK_LIB([resolv], [hstrerror],
670 [NEEDS_RESOLV=YesPlease],
671 [NO_HSTRERROR=YesPlease])
672 ])
673 GIT_CONF_SUBST([NO_HSTRERROR])
675 dnl This must go after all the possible places for its initialization,
676 dnl in the AC_CHECK_FUNC invocations above.
677 GIT_CONF_SUBST([NEEDS_RESOLV])
678 #
679 # If any of the above tests determined that -lresolv is needed at
680 # build-time, also set it here for remaining configure-time checks.
681 test -n "$NEEDS_RESOLV" && LIBS="$LIBS -lresolv"
683 AC_CHECK_LIB([c], [basename],
684 [NEEDS_LIBGEN=],
685 [NEEDS_LIBGEN=YesPlease])
686 GIT_CONF_SUBST([NEEDS_LIBGEN])
687 test -n "$NEEDS_LIBGEN" && LIBS="$LIBS -lgen"
689 AC_CHECK_LIB([c], [gettext],
690 [LIBC_CONTAINS_LIBINTL=YesPlease],
691 [LIBC_CONTAINS_LIBINTL=])
692 GIT_CONF_SUBST([LIBC_CONTAINS_LIBINTL])
694 #
695 # Define NO_GETTEXT if you don't want Git output to be translated.
696 # A translated Git requires GNU libintl or another gettext implementation
697 AC_CHECK_HEADER([libintl.h],
698 [NO_GETTEXT=],
699 [NO_GETTEXT=YesPlease])
700 GIT_CONF_SUBST([NO_GETTEXT])
702 if test -z "$NO_GETTEXT"; then
703 test -n "$LIBC_CONTAINS_LIBINTL" || LIBS="$LIBS -lintl"
704 fi
706 ## Checks for header files.
707 AC_MSG_NOTICE([CHECKS for header files])
708 #
709 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
710 AC_CHECK_HEADER([sys/select.h],
711 [NO_SYS_SELECT_H=],
712 [NO_SYS_SELECT_H=UnfortunatelyYes])
713 GIT_CONF_SUBST([NO_SYS_SELECT_H])
714 #
715 # Define NO_SYS_POLL_H if you don't have sys/poll.h
716 AC_CHECK_HEADER([sys/poll.h],
717 [NO_SYS_POLL_H=],
718 [NO_SYS_POLL_H=UnfortunatelyYes])
719 GIT_CONF_SUBST([NO_SYS_POLL_H])
720 #
721 # Define NO_INTTYPES_H if you don't have inttypes.h
722 AC_CHECK_HEADER([inttypes.h],
723 [NO_INTTYPES_H=],
724 [NO_INTTYPES_H=UnfortunatelyYes])
725 GIT_CONF_SUBST([NO_INTTYPES_H])
726 #
727 # Define OLD_ICONV if your library has an old iconv(), where the second
728 # (input buffer pointer) parameter is declared with type (const char **).
729 AC_DEFUN([OLDICONVTEST_SRC], [
730 AC_LANG_PROGRAM([[
731 #include <iconv.h>
733 extern size_t iconv(iconv_t cd,
734 char **inbuf, size_t *inbytesleft,
735 char **outbuf, size_t *outbytesleft);
736 ]], [])])
738 GIT_STASH_FLAGS($ICONVDIR)
740 AC_MSG_CHECKING([for old iconv()])
741 AC_COMPILE_IFELSE([OLDICONVTEST_SRC],
742 [AC_MSG_RESULT([no])],
743 [AC_MSG_RESULT([yes])
744 OLD_ICONV=UnfortunatelyYes])
746 GIT_UNSTASH_FLAGS($ICONVDIR)
748 GIT_CONF_SUBST([OLD_ICONV])
750 ## Checks for typedefs, structures, and compiler characteristics.
751 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
752 #
753 TYPE_SOCKLEN_T
754 case $ac_cv_type_socklen_t in
755 yes) SOCKLEN_T='';;
756 *) SOCKLEN_T=$git_cv_socklen_t_equiv;;
757 esac
758 GIT_CONF_SUBST([SOCKLEN_T])
760 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
761 AC_CHECK_MEMBER(struct dirent.d_ino,
762 [NO_D_INO_IN_DIRENT=],
763 [NO_D_INO_IN_DIRENT=YesPlease],
764 [#include <dirent.h>])
765 GIT_CONF_SUBST([NO_D_INO_IN_DIRENT])
766 #
767 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
768 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
769 AC_CHECK_MEMBER(struct dirent.d_type,
770 [NO_D_TYPE_IN_DIRENT=],
771 [NO_D_TYPE_IN_DIRENT=YesPlease],
772 [#include <dirent.h>])
773 GIT_CONF_SUBST([NO_D_TYPE_IN_DIRENT])
774 #
775 # Define NO_GECOS_IN_PWENT if you don't have pw_gecos in struct passwd
776 # in the C library.
777 AC_CHECK_MEMBER(struct passwd.pw_gecos,
778 [NO_GECOS_IN_PWENT=],
779 [NO_GECOS_IN_PWENT=YesPlease],
780 [#include <pwd.h>])
781 GIT_CONF_SUBST([NO_GECOS_IN_PWENT])
782 #
783 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
784 # sockaddr_storage.
785 AC_CHECK_TYPE(struct sockaddr_storage,
786 [NO_SOCKADDR_STORAGE=],
787 [NO_SOCKADDR_STORAGE=YesPlease],[
788 #include <sys/types.h>
789 #include <sys/socket.h>
790 ])
791 GIT_CONF_SUBST([NO_SOCKADDR_STORAGE])
792 #
793 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
794 AC_CHECK_TYPE([struct addrinfo],[
795 GIT_CHECK_FUNC([getaddrinfo],
796 [NO_IPV6=],
797 [NO_IPV6=YesPlease])
798 ],[NO_IPV6=YesPlease],[
799 #include <sys/types.h>
800 #include <sys/socket.h>
801 #include <netdb.h>
802 ])
803 GIT_CONF_SUBST([NO_IPV6])
804 #
805 # Define NO_REGEX if you have no or inferior regex support in your C library.
806 AC_CACHE_CHECK([whether the platform regex can handle null bytes],
807 [ac_cv_c_excellent_regex], [
808 AC_EGREP_CPP(yippeeyeswehaveit,
809 AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
810 #include <regex.h>
811 ],
812 [#ifdef REG_STARTEND
813 yippeeyeswehaveit
814 #endif
815 ]),
816 [ac_cv_c_excellent_regex=yes],
817 [ac_cv_c_excellent_regex=no])
818 ])
819 if test $ac_cv_c_excellent_regex = yes; then
820 NO_REGEX=
821 else
822 NO_REGEX=YesPlease
823 fi
824 GIT_CONF_SUBST([NO_REGEX])
825 #
826 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
827 # when attempting to read from an fopen'ed directory.
828 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
829 [ac_cv_fread_reads_directories],
830 [
831 AC_RUN_IFELSE(
832 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
833 [[char c;
834 FILE *f = fopen(".", "r");
835 return f && fread(&c, 1, 1, f)]])],
836 [ac_cv_fread_reads_directories=no],
837 [ac_cv_fread_reads_directories=yes])
838 ])
839 if test $ac_cv_fread_reads_directories = yes; then
840 FREAD_READS_DIRECTORIES=UnfortunatelyYes
841 else
842 FREAD_READS_DIRECTORIES=
843 fi
844 GIT_CONF_SUBST([FREAD_READS_DIRECTORIES])
845 #
846 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
847 # or vsnprintf() return -1 instead of number of characters which would
848 # have been written to the final string if enough space had been available.
849 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
850 [ac_cv_snprintf_returns_bogus],
851 [
852 AC_RUN_IFELSE(
853 [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
854 #include "stdarg.h"
856 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
857 {
858 int ret;
859 va_list ap;
860 va_start(ap, format);
861 ret = vsnprintf(str, maxsize, format, ap);
862 va_end(ap);
863 return ret;
864 }],
865 [[char buf[6];
866 if (test_vsnprintf(buf, 3, "%s", "12345") != 5
867 || strcmp(buf, "12")) return 1;
868 if (snprintf(buf, 3, "%s", "12345") != 5
869 || strcmp(buf, "12")) return 1]])],
870 [ac_cv_snprintf_returns_bogus=no],
871 [ac_cv_snprintf_returns_bogus=yes])
872 ])
873 if test $ac_cv_snprintf_returns_bogus = yes; then
874 SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
875 else
876 SNPRINTF_RETURNS_BOGUS=
877 fi
878 GIT_CONF_SUBST([SNPRINTF_RETURNS_BOGUS])
881 ## Checks for library functions.
882 ## (in default C library and libraries checked by AC_CHECK_LIB)
883 AC_MSG_NOTICE([CHECKS for library functions])
884 #
885 # Define NO_LIBGEN_H if you don't have libgen.h.
886 AC_CHECK_HEADER([libgen.h],
887 [NO_LIBGEN_H=],
888 [NO_LIBGEN_H=YesPlease])
889 GIT_CONF_SUBST([NO_LIBGEN_H])
890 #
891 # Define HAVE_PATHS_H if you have paths.h.
892 AC_CHECK_HEADER([paths.h],
893 [HAVE_PATHS_H=YesPlease],
894 [HAVE_PATHS_H=])
895 GIT_CONF_SUBST([HAVE_PATHS_H])
896 #
897 # Define HAVE_LIBCHARSET_H if have libcharset.h
898 AC_CHECK_HEADER([libcharset.h],
899 [HAVE_LIBCHARSET_H=YesPlease],
900 [HAVE_LIBCHARSET_H=])
901 GIT_CONF_SUBST([HAVE_LIBCHARSET_H])
902 #
903 # Define HAVE_STRINGS_H if you have strings.h
904 AC_CHECK_HEADER([strings.h],
905 [HAVE_STRINGS_H=YesPlease],
906 [HAVE_STRINGS_H=])
907 GIT_CONF_SUBST([HAVE_STRINGS_H])
908 # Define CHARSET_LIB if libiconv does not export the locale_charset symbol
909 # and libcharset does
910 CHARSET_LIB=
911 AC_CHECK_LIB([iconv], [locale_charset],
912 [CHARSET_LIB=-liconv],
913 [AC_CHECK_LIB([charset], [locale_charset],
914 [CHARSET_LIB=-lcharset])])
915 GIT_CONF_SUBST([CHARSET_LIB])
916 #
917 # Define NO_STRCASESTR if you don't have strcasestr.
918 GIT_CHECK_FUNC(strcasestr,
919 [NO_STRCASESTR=],
920 [NO_STRCASESTR=YesPlease])
921 GIT_CONF_SUBST([NO_STRCASESTR])
922 #
923 # Define NO_MEMMEM if you don't have memmem.
924 GIT_CHECK_FUNC(memmem,
925 [NO_MEMMEM=],
926 [NO_MEMMEM=YesPlease])
927 GIT_CONF_SUBST([NO_MEMMEM])
928 #
929 # Define NO_STRLCPY if you don't have strlcpy.
930 GIT_CHECK_FUNC(strlcpy,
931 [NO_STRLCPY=],
932 [NO_STRLCPY=YesPlease])
933 GIT_CONF_SUBST([NO_STRLCPY])
934 #
935 # Define NO_UINTMAX_T if your platform does not have uintmax_t
936 AC_CHECK_TYPE(uintmax_t,
937 [NO_UINTMAX_T=],
938 [NO_UINTMAX_T=YesPlease],[
939 #include <inttypes.h>
940 ])
941 GIT_CONF_SUBST([NO_UINTMAX_T])
942 #
943 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
944 GIT_CHECK_FUNC(strtoumax,
945 [NO_STRTOUMAX=],
946 [NO_STRTOUMAX=YesPlease])
947 GIT_CONF_SUBST([NO_STRTOUMAX])
948 #
949 # Define NO_SETENV if you don't have setenv in the C library.
950 GIT_CHECK_FUNC(setenv,
951 [NO_SETENV=],
952 [NO_SETENV=YesPlease])
953 GIT_CONF_SUBST([NO_SETENV])
954 #
955 # Define NO_UNSETENV if you don't have unsetenv in the C library.
956 GIT_CHECK_FUNC(unsetenv,
957 [NO_UNSETENV=],
958 [NO_UNSETENV=YesPlease])
959 GIT_CONF_SUBST([NO_UNSETENV])
960 #
961 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
962 GIT_CHECK_FUNC(mkdtemp,
963 [NO_MKDTEMP=],
964 [NO_MKDTEMP=YesPlease])
965 GIT_CONF_SUBST([NO_MKDTEMP])
966 #
967 # Define NO_MKSTEMPS if you don't have mkstemps in the C library.
968 GIT_CHECK_FUNC(mkstemps,
969 [NO_MKSTEMPS=],
970 [NO_MKSTEMPS=YesPlease])
971 GIT_CONF_SUBST([NO_MKSTEMPS])
972 #
973 # Define NO_INITGROUPS if you don't have initgroups in the C library.
974 GIT_CHECK_FUNC(initgroups,
975 [NO_INITGROUPS=],
976 [NO_INITGROUPS=YesPlease])
977 GIT_CONF_SUBST([NO_INITGROUPS])
978 #
979 #
980 # Define NO_MMAP if you want to avoid mmap.
981 #
982 # Define NO_ICONV if your libc does not properly support iconv.
985 ## Other checks.
986 # Define USE_PIC if you need the main git objects to be built with -fPIC
987 # in order to build and link perl/Git.so. x86-64 seems to need this.
988 #
989 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
990 # Enable it on Windows. By default, symrefs are still used.
991 #
992 # Define NO_PTHREADS if we do not have pthreads.
993 #
994 # Define PTHREAD_LIBS to the linker flag used for Pthread support.
995 AC_DEFUN([PTHREADTEST_SRC], [
996 AC_LANG_PROGRAM([[
997 #include <pthread.h>
998 ]], [[
999 pthread_mutex_t test_mutex;
1000 pthread_key_t test_key;
1001 int retcode = 0;
1002 retcode |= pthread_key_create(&test_key, (void *)0);
1003 retcode |= pthread_mutex_init(&test_mutex,(void *)0);
1004 retcode |= pthread_mutex_lock(&test_mutex);
1005 retcode |= pthread_mutex_unlock(&test_mutex);
1006 return retcode;
1007 ]])])
1009 dnl AC_LANG_CONFTEST([AC_LANG_PROGRAM(
1010 dnl [[#include <pthread.h>]],
1011 dnl [[pthread_mutex_t test_mutex;]]
1012 dnl )])
1014 NO_PTHREADS=UnfortunatelyYes
1015 PTHREAD_LIBS=
1017 if test -n "$USER_NOPTHREAD"; then
1018 AC_MSG_NOTICE([Skipping POSIX Threads at user request.])
1019 # handle these separately since PTHREAD_CFLAGS could be '-lpthreads
1020 # -D_REENTRANT' or some such.
1021 elif test -z "$PTHREAD_CFLAGS"; then
1022 threads_found=no
1023 # Attempt to compile and link some code using pthreads to determine
1024 # required linker flags. The order is somewhat important here: We
1025 # first try it without any extra flags, to catch systems where
1026 # pthreads are part of the C library, then go on testing various other
1027 # flags. We do so to avoid false positives. For example, on Mac OS X
1028 # pthreads are part of the C library; moreover, the compiler allows us
1029 # to add "-mt" to the CFLAGS (although it will do nothing except
1030 # trigger a warning about an unused flag). Hence if we checked for
1031 # "-mt" before "" we would end up picking it. But unfortunately this
1032 # would then trigger compiler warnings on every single file we compile.
1033 for opt in "" -mt -pthread -lpthread; do
1034 old_CFLAGS="$CFLAGS"
1035 CFLAGS="$opt $CFLAGS"
1036 AC_MSG_CHECKING([for POSIX Threads with '$opt'])
1037 AC_LINK_IFELSE([PTHREADTEST_SRC],
1038 [AC_MSG_RESULT([yes])
1039 NO_PTHREADS=
1040 PTHREAD_LIBS="$opt"
1041 PTHREAD_CFLAGS="$opt"
1042 threads_found=yes
1043 break
1044 ],
1045 [AC_MSG_RESULT([no])])
1046 CFLAGS="$old_CFLAGS"
1047 done
1048 if test $threads_found != yes; then
1049 AC_CHECK_LIB([pthread], [pthread_create],
1050 [PTHREAD_LIBS="-lpthread"],
1051 [NO_PTHREADS=UnfortunatelyYes])
1052 fi
1053 else
1054 old_CFLAGS="$CFLAGS"
1055 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1056 AC_MSG_CHECKING([for POSIX Threads with '$PTHREAD_CFLAGS'])
1057 AC_LINK_IFELSE([PTHREADTEST_SRC],
1058 [AC_MSG_RESULT([yes])
1059 NO_PTHREADS=
1060 PTHREAD_LIBS="$PTHREAD_CFLAGS"
1061 ],
1062 [AC_MSG_RESULT([no])])
1064 CFLAGS="$old_CFLAGS"
1065 fi
1067 CFLAGS="$old_CFLAGS"
1069 GIT_CONF_SUBST([PTHREAD_CFLAGS])
1070 GIT_CONF_SUBST([PTHREAD_LIBS])
1071 GIT_CONF_SUBST([NO_PTHREADS])
1073 ## Output files
1074 AC_CONFIG_FILES(["${config_file}":"${config_in}"])
1075 AC_OUTPUT