configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([git], [@@GIT_VERSION@@], [git@vger.kernel.org])
   6
   7 AC_CONFIG_SRCDIR([git.c])
   8
   9 config_file=config.mak.autogen
  10 config_append=config.mak.append
  11 config_in=config.mak.in
  12
  13 echo "# ${config_append}.  Generated by configure." > "${config_append}"
  14
  15
  16 ## Definitions of macros
  17 # GIT_CONF_APPEND_LINE(LINE)
  18 # --------------------------
  19 # Append LINE to file ${config_append}
  20 AC_DEFUN([GIT_CONF_APPEND_LINE],
  21 [echo "$1" >> "${config_append}"])# GIT_CONF_APPEND_LINE
  22 #
  23 # GIT_ARG_SET_PATH(PROGRAM)
  24 # -------------------------
  25 # Provide --with-PROGRAM=PATH option to set PATH to PROGRAM
  26 AC_DEFUN([GIT_ARG_SET_PATH],
  27 [AC_ARG_WITH([$1],
  28  [AS_HELP_STRING([--with-$1=PATH],
  29                  [provide PATH to $1])],
  30  [GIT_CONF_APPEND_PATH($1)],[])
  31 ])# GIT_ARG_SET_PATH
  32 #
  33 # GIT_CONF_APPEND_PATH(PROGRAM)
  34 # ------------------------------
  35 # Parse --with-PROGRAM=PATH option to set PROGRAM_PATH=PATH
  36 # Used by GIT_ARG_SET_PATH(PROGRAM)
  37 AC_DEFUN([GIT_CONF_APPEND_PATH],
  38 [PROGRAM=m4_toupper($1); \
  39 if test "$withval" = "no"; then \
  40         AC_MSG_ERROR([You cannot use git without $1]); \
  41 else \
  42         if test "$withval" = "yes"; then \
  43                 AC_MSG_WARN([You should provide path for --with-$1=PATH]); \
  44         else \
  45                 m4_toupper($1)_PATH=$withval; \
  46                 AC_MSG_NOTICE([Setting m4_toupper($1)_PATH to $withval]); \
  47                 GIT_CONF_APPEND_LINE(${PROGRAM}_PATH=$withval); \
  48         fi; \
  49 fi; \
  50 ]) # GIT_CONF_APPEND_PATH
  51 #
  52 # GIT_PARSE_WITH(PACKAGE)
  53 # -----------------------
  54 # For use in AC_ARG_WITH action-if-found, for packages default ON.
  55 # * Set NO_PACKAGE=YesPlease for --without-PACKAGE
  56 # * Set PACKAGEDIR=PATH for --with-PACKAGE=PATH
  57 # * Unset NO_PACKAGE for --with-PACKAGE without ARG
  58 AC_DEFUN([GIT_PARSE_WITH],
  59 [PACKAGE=m4_toupper($1); \
  60 if test "$withval" = "no"; then \
  61         m4_toupper(NO_$1)=YesPlease; \
  62 elif test "$withval" = "yes"; then \
  63         m4_toupper(NO_$1)=; \
  64 else \
  65         m4_toupper(NO_$1)=; \
  66         m4_toupper($1)DIR=$withval; \
  67         AC_MSG_NOTICE([Setting m4_toupper($1)DIR to $withval]); \
  68         GIT_CONF_APPEND_LINE(${PACKAGE}DIR=$withval); \
  69 fi \
  70 ])# GIT_PARSE_WITH
  71
  72 dnl
  73 dnl GIT_CHECK_FUNC(FUNCTION, IFTRUE, IFFALSE)
  74 dnl -----------------------------------------
  75 dnl Similar to AC_CHECK_FUNC, but on systems that do not generate
  76 dnl warnings for missing prototypes (e.g. FreeBSD when compiling without
  77 dnl -Wall), it does not work.  By looking for function definition in
  78 dnl libraries, this problem can be worked around.
  79 AC_DEFUN([GIT_CHECK_FUNC],[AC_CHECK_FUNC([$1],[
  80   AC_SEARCH_LIBS([$1],,
  81   [$2],[$3])
  82 ],[$3])])
  83
  84 dnl
  85 dnl GIT_STASH_FLAGS(BASEPATH_VAR)
  86 dnl -----------------------------
  87 dnl Allow for easy stashing of LDFLAGS and CPPFLAGS before running
  88 dnl tests that may want to take user settings into account.
  89 AC_DEFUN([GIT_STASH_FLAGS],[
  90 if test -n "$1"; then
  91    old_CPPFLAGS="$CPPFLAGS"
  92    old_LDFLAGS="$LDFLAGS"
  93    CPPFLAGS="-I$1/include $CPPFLAGS"
  94    LDFLAGS="-L$1/$lib $LDFLAGS"
  95 fi
  96 ])
  97
  98 dnl
  99 dnl GIT_UNSTASH_FLAGS(BASEPATH_VAR)
 100 dnl -----------------------------
 101 dnl Restore the stashed *FLAGS values.
 102 AC_DEFUN([GIT_UNSTASH_FLAGS],[
 103 if test -n "$1"; then
 104    CPPFLAGS="$old_CPPFLAGS"
 105    LDFLAGS="$old_LDFLAGS"
 106 fi
 107 ])
 108
 109 ## Site configuration related to programs (before tests)
 110 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 111 #
 112 # Set lib to alternative name of lib directory (e.g. lib64)
 113 AC_ARG_WITH([lib],
 114  [AS_HELP_STRING([--with-lib=ARG],
 115                  [ARG specifies alternative name for lib directory])],
 116  [if test "$withval" = "no" || test "$withval" = "yes"; then \
 117         AC_MSG_WARN([You should provide name for --with-lib=ARG]); \
 118 else \
 119         lib=$withval; \
 120         AC_MSG_NOTICE([Setting lib to '$lib']); \
 121         GIT_CONF_APPEND_LINE(lib=$withval); \
 122 fi; \
 123 ],[])
 124
 125 if test -z "$lib"; then
 126    AC_MSG_NOTICE([Setting lib to 'lib' (the default)])
 127    lib=lib
 128 fi
 129
 130 ## Site configuration (override autodetection)
 131 ## --with-PACKAGE[=ARG] and --without-PACKAGE
 132 AC_MSG_NOTICE([CHECKS for site configuration])
 133 #
 134 # Define NO_SVN_TESTS if you want to skip time-consuming SVN interoperability
 135 # tests.  These tests take up a significant amount of the total test time
 136 # but are not needed unless you plan to talk to SVN repos.
 137 #
 138 # Define MOZILLA_SHA1 environment variable when running make to make use of
 139 # a bundled SHA1 routine coming from Mozilla. It is GPL'd and should be fast
 140 # on non-x86 architectures (e.g. PowerPC), while the OpenSSL version (default
 141 # choice) has very fast version optimized for i586.
 142 #
 143 # Define PPC_SHA1 environment variable when running make to make use of
 144 # a bundled SHA1 routine optimized for PowerPC.
 145 #
 146 # Define ARM_SHA1 environment variable when running make to make use of
 147 # a bundled SHA1 routine optimized for ARM.
 148 #
 149 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 150 # This also implies MOZILLA_SHA1.
 151 #
 152 # Define OPENSSLDIR=/foo/bar if your openssl header and library files are in
 153 # /foo/bar/include and /foo/bar/lib directories.
 154 AC_ARG_WITH(openssl,
 155 AS_HELP_STRING([--with-openssl],[use OpenSSL library (default is YES)])
 156 AS_HELP_STRING([],              [ARG can be prefix for openssl library and headers]),\
 157 GIT_PARSE_WITH(openssl))
 158 #
 159 # Define NO_CURL if you do not have curl installed.  git-http-pull and
 160 # git-http-push are not built, and you cannot use http:// and https://
 161 # transports.
 162 #
 163 # Define CURLDIR=/foo/bar if your curl header and library files are in
 164 # /foo/bar/include and /foo/bar/lib directories.
 165 AC_ARG_WITH(curl,
 166 AS_HELP_STRING([--with-curl],[support http(s):// transports (default is YES)])
 167 AS_HELP_STRING([],           [ARG can be also prefix for curl library and headers]),
 168 GIT_PARSE_WITH(curl))
 169 #
 170 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 171 # not built, and you cannot push using http:// and https:// transports.
 172 #
 173 # Define EXPATDIR=/foo/bar if your expat header and library files are in
 174 # /foo/bar/include and /foo/bar/lib directories.
 175 AC_ARG_WITH(expat,
 176 AS_HELP_STRING([--with-expat],
 177 [support git-push using http:// and https:// transports via WebDAV (default is YES)])
 178 AS_HELP_STRING([],            [ARG can be also prefix for expat library and headers]),
 179 GIT_PARSE_WITH(expat))
 180 #
 181 # Define NO_FINK if you are building on Darwin/Mac OS X, have Fink
 182 # installed in /sw, but don't want GIT to link against any libraries
 183 # installed there.  If defined you may specify your own (or Fink's)
 184 # include directories and library directories by defining CFLAGS
 185 # and LDFLAGS appropriately.
 186 #
 187 # Define NO_DARWIN_PORTS if you are building on Darwin/Mac OS X,
 188 # have DarwinPorts installed in /opt/local, but don't want GIT to
 189 # link against any libraries installed there.  If defined you may
 190 # specify your own (or DarwinPort's) include directories and
 191 # library directories by defining CFLAGS and LDFLAGS appropriately.
 192 #
 193 # Define NO_MMAP if you want to avoid mmap.
 194 #
 195 # Define NO_ICONV if your libc does not properly support iconv.
 196 AC_ARG_WITH(iconv,
 197 AS_HELP_STRING([--without-iconv],
 198 [if your architecture doesn't properly support iconv])
 199 AS_HELP_STRING([--with-iconv=PATH],
 200 [PATH is prefix for libiconv library and headers])
 201 AS_HELP_STRING([],
 202 [used only if you need linking with libiconv]),
 203 GIT_PARSE_WITH(iconv))
 204
 205 ## --enable-FEATURE[=ARG] and --disable-FEATURE
 206 #
 207 # Define USE_NSEC below if you want git to care about sub-second file mtimes
 208 # and ctimes. Note that you need recent glibc (at least 2.2.4) for this, and
 209 # it will BREAK YOUR LOCAL DIFFS! show-diff and anything using it will likely
 210 # randomly break unless your underlying filesystem supports those sub-second
 211 # times (my ext3 doesn't).
 212 #
 213 # Define USE_STDEV below if you want git to care about the underlying device
 214 # change being considered an inode change from the update-index perspective.
 215
 216 #
 217 # Define SHELL_PATH to provide path to shell.
 218 GIT_ARG_SET_PATH(shell)
 219 #
 220 # Define PERL_PATH to provide path to Perl.
 221 GIT_ARG_SET_PATH(perl)
 222 #
 223 # Define ZLIB_PATH to provide path to zlib.
 224 GIT_ARG_SET_PATH(zlib)
 225 #
 226 # Declare the with-tcltk/without-tcltk options.
 227 AC_ARG_WITH(tcltk,
 228 AS_HELP_STRING([--with-tcltk],[use Tcl/Tk GUI (default is YES)])
 229 AS_HELP_STRING([],[ARG is the full path to the Tcl/Tk interpreter.])
 230 AS_HELP_STRING([],[Bare --with-tcltk will make the GUI part only if])
 231 AS_HELP_STRING([],[Tcl/Tk interpreter will be found in a system.]),\
 232 GIT_PARSE_WITH(tcltk))
 233 #
 234
 235
 236 ## Checks for programs.
 237 AC_MSG_NOTICE([CHECKS for programs])
 238 #
 239 AC_PROG_CC([cc gcc])
 240 # which switch to pass runtime path to dynamic libraries to the linker
 241 AC_CACHE_CHECK([if linker supports -R], git_cv_ld_dashr, [
 242    SAVE_LDFLAGS="${LDFLAGS}"
 243    LDFLAGS="${SAVE_LDFLAGS} -R /"
 244    AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_dashr=yes], [git_cv_ld_dashr=no])
 245    LDFLAGS="${SAVE_LDFLAGS}"
 246 ])
 247 if test "$git_cv_ld_dashr" = "yes"; then
 248    AC_SUBST(CC_LD_DYNPATH, [-R])
 249 else
 250    AC_CACHE_CHECK([if linker supports -Wl,-rpath,], git_cv_ld_wl_rpath, [
 251       SAVE_LDFLAGS="${LDFLAGS}"
 252       LDFLAGS="${SAVE_LDFLAGS} -Wl,-rpath,/"
 253       AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_wl_rpath=yes], [git_cv_ld_wl_rpath=no])
 254       LDFLAGS="${SAVE_LDFLAGS}"
 255    ])
 256    if test "$git_cv_ld_wl_rpath" = "yes"; then
 257       AC_SUBST(CC_LD_DYNPATH, [-Wl,-rpath,])
 258    else
 259       AC_CACHE_CHECK([if linker supports -rpath], git_cv_ld_rpath, [
 260          SAVE_LDFLAGS="${LDFLAGS}"
 261          LDFLAGS="${SAVE_LDFLAGS} -rpath /"
 262          AC_LINK_IFELSE(AC_LANG_PROGRAM([], []), [git_cv_ld_rpath=yes], [git_cv_ld_rpath=no])
 263          LDFLAGS="${SAVE_LDFLAGS}"
 264       ])
 265       if test "$git_cv_ld_rpath" = "yes"; then
 266          AC_SUBST(CC_LD_DYNPATH, [-rpath])
 267       else
 268          AC_MSG_WARN([linker does not support runtime path to dynamic libraries])
 269       fi
 270    fi
 271 fi
 272 #AC_PROG_INSTALL                # needs install-sh or install.sh in sources
 273 AC_CHECK_TOOLS(AR, [gar ar], :)
 274 AC_CHECK_PROGS(TAR, [gtar tar])
 275 # TCLTK_PATH will be set to some value if we want Tcl/Tk
 276 # or will be empty otherwise.
 277 if test -z "$NO_TCLTK"; then
 278   if test "$with_tcltk" = ""; then
 279   # No Tcl/Tk switches given. Do not check for Tcl/Tk, use bare 'wish'.
 280     TCLTK_PATH=wish
 281     AC_SUBST(TCLTK_PATH)
 282   elif test "$with_tcltk" = "yes"; then
 283   # Tcl/Tk check requested.
 284     AC_CHECK_PROGS(TCLTK_PATH, [wish], )
 285   else
 286     AC_MSG_RESULT([Using Tcl/Tk interpreter $with_tcltk])
 287     TCLTK_PATH="$with_tcltk"
 288     AC_SUBST(TCLTK_PATH)
 289   fi
 290 fi
 291 AC_CHECK_PROGS(ASCIIDOC, [asciidoc])
 292 if test -n "$ASCIIDOC"; then
 293         AC_MSG_CHECKING([for asciidoc version])
 294         asciidoc_version=`$ASCIIDOC --version 2>&1`
 295         case "${asciidoc_version}" in
 296         asciidoc' '8*)
 297                 ASCIIDOC8=YesPlease
 298                 AC_MSG_RESULT([${asciidoc_version} > 7])
 299                 ;;
 300         asciidoc' '7*)
 301                 ASCIIDOC8=
 302                 AC_MSG_RESULT([${asciidoc_version}])
 303                 ;;
 304         *)
 305                 ASCIIDOC8=
 306                 AC_MSG_RESULT([${asciidoc_version} (unknown)])
 307                 ;;
 308         esac
 309 fi
 310 AC_SUBST(ASCIIDOC8)
 311
 312
 313 ## Checks for libraries.
 314 AC_MSG_NOTICE([CHECKS for libraries])
 315 #
 316 # Define NO_OPENSSL environment variable if you do not have OpenSSL.
 317 # Define NEEDS_SSL_WITH_CRYPTO if you need -lcrypto with -lssl (Darwin).
 318
 319 GIT_STASH_FLAGS($OPENSSLDIR)
 320
 321 AC_CHECK_LIB([crypto], [SHA1_Init],
 322 [NEEDS_SSL_WITH_CRYPTO=],
 323 [AC_CHECK_LIB([ssl], [SHA1_Init],
 324  [NEEDS_SSL_WITH_CRYPTO=YesPlease
 325   NEEDS_SSL_WITH_CRYPTO=],
 326  [NO_OPENSSL=YesPlease])])
 327
 328 GIT_UNSTASH_FLAGS($OPENSSLDIR)
 329
 330 AC_SUBST(NEEDS_SSL_WITH_CRYPTO)
 331 AC_SUBST(NO_OPENSSL)
 332
 333 #
 334 # Define NO_CURL if you do not have libcurl installed.  git-http-pull and
 335 # git-http-push are not built, and you cannot use http:// and https://
 336 # transports.
 337
 338 GIT_STASH_FLAGS($CURLDIR)
 339
 340 AC_CHECK_LIB([curl], [curl_global_init],
 341 [NO_CURL=],
 342 [NO_CURL=YesPlease])
 343
 344 GIT_UNSTASH_FLAGS($CURLDIR)
 345
 346 AC_SUBST(NO_CURL)
 347
 348 #
 349 # Define NO_EXPAT if you do not have expat installed.  git-http-push is
 350 # not built, and you cannot push using http:// and https:// transports.
 351
 352 GIT_STASH_FLAGS($EXPATDIR)
 353
 354 AC_CHECK_LIB([expat], [XML_ParserCreate],
 355 [NO_EXPAT=],
 356 [NO_EXPAT=YesPlease])
 357
 358 GIT_UNSTASH_FLAGS($EXPATDIR)
 359
 360 AC_SUBST(NO_EXPAT)
 361
 362 #
 363 # Define NEEDS_LIBICONV if linking with libc is not enough (Darwin and
 364 # some Solaris installations).
 365 # Define NO_ICONV if neither libc nor libiconv support iconv.
 366
 367 GIT_STASH_FLAGS($ICONVDIR)
 368
 369 AC_DEFUN([ICONVTEST_SRC], [
 370 #include <iconv.h>
 371
 372 int main(void)
 373 {
 374         iconv_open("", "");
 375         return 0;
 376 }
 377 ])
 378 AC_MSG_CHECKING([for iconv in -lc])
 379 AC_LINK_IFELSE(ICONVTEST_SRC,
 380         [AC_MSG_RESULT([yes])
 381         NEEDS_LIBICONV=],
 382         [AC_MSG_RESULT([no])
 383         old_LIBS="$LIBS"
 384         LIBS="$LIBS -liconv"
 385         AC_MSG_CHECKING([for iconv in -liconv])
 386         AC_LINK_IFELSE(ICONVTEST_SRC,
 387                 [AC_MSG_RESULT([yes])
 388                 NEEDS_LIBICONV=YesPlease],
 389                 [AC_MSG_RESULT([no])
 390                 NO_ICONV=YesPlease])
 391         LIBS="$old_LIBS"])
 392
 393 GIT_UNSTASH_FLAGS($ICONVDIR)
 394
 395 AC_SUBST(NEEDS_LIBICONV)
 396 AC_SUBST(NO_ICONV)
 397
 398 #
 399 # Define NO_DEFLATE_BOUND if deflateBound is missing from zlib.
 400
 401 GIT_STASH_FLAGS($ZLIB_PATH)
 402
 403 AC_DEFUN([ZLIBTEST_SRC], [
 404 #include <zlib.h>
 405
 406 int main(void)
 407 {
 408         deflateBound(0, 0);
 409         return 0;
 410 }
 411 ])
 412 AC_MSG_CHECKING([for deflateBound in -lz])
 413 old_LIBS="$LIBS"
 414 LIBS="$LIBS -lz"
 415 AC_LINK_IFELSE(ZLIBTEST_SRC,
 416         [AC_MSG_RESULT([yes])],
 417         [AC_MSG_RESULT([no])
 418         NO_DEFLATE_BOUND=yes])
 419 LIBS="$old_LIBS"
 420
 421 GIT_UNSTASH_FLAGS($ZLIB_PATH)
 422
 423 AC_SUBST(NO_DEFLATE_BOUND)
 424
 425 #
 426 # Define NEEDS_SOCKET if linking with libc is not enough (SunOS,
 427 # Patrick Mauritz).
 428 AC_CHECK_LIB([c], [socket],
 429 [NEEDS_SOCKET=],
 430 [NEEDS_SOCKET=YesPlease])
 431 AC_SUBST(NEEDS_SOCKET)
 432 test -n "$NEEDS_SOCKET" && LIBS="$LIBS -lsocket"
 433
 434
 435 ## Checks for header files.
 436 AC_MSG_NOTICE([CHECKS for header files])
 437 #
 438 # Define NO_SYS_SELECT_H if you don't have sys/select.h.
 439 AC_CHECK_HEADER([sys/select.h],
 440 [NO_SYS_SELECT_H=],
 441 [NO_SYS_SELECT_H=UnfortunatelyYes])
 442 AC_SUBST(NO_SYS_SELECT_H)
 443 #
 444 # Define OLD_ICONV if your library has an old iconv(), where the second
 445 # (input buffer pointer) parameter is declared with type (const char **).
 446 AC_DEFUN([OLDICONVTEST_SRC], [[
 447 #include <iconv.h>
 448
 449 extern size_t iconv(iconv_t cd,
 450                     char **inbuf, size_t *inbytesleft,
 451                     char **outbuf, size_t *outbytesleft);
 452
 453 int main(void)
 454 {
 455         return 0;
 456 }
 457 ]])
 458 AC_MSG_CHECKING([for old iconv()])
 459 AC_COMPILE_IFELSE(OLDICONVTEST_SRC,
 460         [AC_MSG_RESULT([no])],
 461         [AC_MSG_RESULT([yes])
 462         OLD_ICONV=UnfortunatelyYes])
 463 AC_SUBST(OLD_ICONV)
 464
 465
 466 ## Checks for typedefs, structures, and compiler characteristics.
 467 AC_MSG_NOTICE([CHECKS for typedefs, structures, and compiler characteristics])
 468 #
 469 # Define NO_D_INO_IN_DIRENT if you don't have d_ino in your struct dirent.
 470 AC_CHECK_MEMBER(struct dirent.d_ino,
 471 [NO_D_INO_IN_DIRENT=],
 472 [NO_D_INO_IN_DIRENT=YesPlease],
 473 [#include <dirent.h>])
 474 AC_SUBST(NO_D_INO_IN_DIRENT)
 475 #
 476 # Define NO_D_TYPE_IN_DIRENT if your platform defines DT_UNKNOWN but lacks
 477 # d_type in struct dirent (latest Cygwin -- will be fixed soonish).
 478 AC_CHECK_MEMBER(struct dirent.d_type,
 479 [NO_D_TYPE_IN_DIRENT=],
 480 [NO_D_TYPE_IN_DIRENT=YesPlease],
 481 [#include <dirent.h>])
 482 AC_SUBST(NO_D_TYPE_IN_DIRENT)
 483 #
 484 # Define NO_SOCKADDR_STORAGE if your platform does not have struct
 485 # sockaddr_storage.
 486 AC_CHECK_TYPE(struct sockaddr_storage,
 487 [NO_SOCKADDR_STORAGE=],
 488 [NO_SOCKADDR_STORAGE=YesPlease],[
 489 #include <sys/types.h>
 490 #include <sys/socket.h>
 491 ])
 492 AC_SUBST(NO_SOCKADDR_STORAGE)
 493 #
 494 # Define NO_IPV6 if you lack IPv6 support and getaddrinfo().
 495 AC_CHECK_TYPE([struct addrinfo],[
 496  GIT_CHECK_FUNC([getaddrinfo],
 497   [NO_IPV6=],
 498   [NO_IPV6=YesPlease])
 499 ],[NO_IPV6=YesPlease],[
 500 #include <sys/types.h>
 501 #include <sys/socket.h>
 502 #include <netdb.h>
 503 ])
 504 AC_SUBST(NO_IPV6)
 505 #
 506 # Define NO_C99_FORMAT if your formatted IO functions (printf/scanf et.al.)
 507 # do not support the 'size specifiers' introduced by C99, namely ll, hh,
 508 # j, z, t. (representing long long int, char, intmax_t, size_t, ptrdiff_t).
 509 # some C compilers supported these specifiers prior to C99 as an extension.
 510 AC_CACHE_CHECK([whether formatted IO functions support C99 size specifiers],
 511  [ac_cv_c_c99_format],
 512 [# Actually git uses only %z (%zu) in alloc.c, and %t (%td) in mktag.c
 513 AC_RUN_IFELSE(
 514         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 515                 [[char buf[64];
 516                 if (sprintf(buf, "%lld%hhd%jd%zd%td", (long long int)1, (char)2, (intmax_t)3, (size_t)4, (ptrdiff_t)5) != 5)
 517                   return 1;
 518                 else if (strcmp(buf, "12345"))
 519                   return 2;]])],
 520         [ac_cv_c_c99_format=yes],
 521         [ac_cv_c_c99_format=no])
 522 ])
 523 if test $ac_cv_c_c99_format = no; then
 524         NO_C99_FORMAT=YesPlease
 525 else
 526         NO_C99_FORMAT=
 527 fi
 528 AC_SUBST(NO_C99_FORMAT)
 529 #
 530 # Define FREAD_READS_DIRECTORIES if your are on a system which succeeds
 531 # when attempting to read from an fopen'ed directory.
 532 AC_CACHE_CHECK([whether system succeeds to read fopen'ed directory],
 533  [ac_cv_fread_reads_directories],
 534 [
 535 AC_RUN_IFELSE(
 536         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
 537                 [[char c;
 538                 FILE *f = fopen(".", "r");
 539                 return f && fread(&c, 1, 1, f)]])],
 540         [ac_cv_fread_reads_directories=no],
 541         [ac_cv_fread_reads_directories=yes])
 542 ])
 543 if test $ac_cv_fread_reads_directories = yes; then
 544         FREAD_READS_DIRECTORIES=UnfortunatelyYes
 545 else
 546         FREAD_READS_DIRECTORIES=
 547 fi
 548 AC_SUBST(FREAD_READS_DIRECTORIES)
 549 #
 550 # Define SNPRINTF_RETURNS_BOGUS if your are on a system which snprintf()
 551 # or vsnprintf() return -1 instead of number of characters which would
 552 # have been written to the final string if enough space had been available.
 553 AC_CACHE_CHECK([whether snprintf() and/or vsnprintf() return bogus value],
 554  [ac_cv_snprintf_returns_bogus],
 555 [
 556 AC_RUN_IFELSE(
 557         [AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT
 558                 #include "stdarg.h"
 559
 560                 int test_vsnprintf(char *str, size_t maxsize, const char *format, ...)
 561                 {
 562                   int ret;
 563                   va_list ap;
 564                   va_start(ap, format);
 565                   ret = vsnprintf(str, maxsize, format, ap);
 566                   va_end(ap);
 567                   return ret;
 568                 }],
 569                 [[char buf[6];
 570                   if (test_vsnprintf(buf, 3, "%s", "12345") != 5
 571                       || strcmp(buf, "12")) return 1;
 572                   if (snprintf(buf, 3, "%s", "12345") != 5
 573                       || strcmp(buf, "12")) return 1]])],
 574         [ac_cv_snprintf_returns_bogus=no],
 575         [ac_cv_snprintf_returns_bogus=yes])
 576 ])
 577 if test $ac_cv_snprintf_returns_bogus = yes; then
 578         SNPRINTF_RETURNS_BOGUS=UnfortunatelyYes
 579 else
 580         SNPRINTF_RETURNS_BOGUS=
 581 fi
 582 AC_SUBST(SNPRINTF_RETURNS_BOGUS)
 583
 584
 585 ## Checks for library functions.
 586 ## (in default C library and libraries checked by AC_CHECK_LIB)
 587 AC_MSG_NOTICE([CHECKS for library functions])
 588 #
 589 # Define NO_STRCASESTR if you don't have strcasestr.
 590 GIT_CHECK_FUNC(strcasestr,
 591 [NO_STRCASESTR=],
 592 [NO_STRCASESTR=YesPlease])
 593 AC_SUBST(NO_STRCASESTR)
 594 #
 595 # Define NO_MEMMEM if you don't have memmem.
 596 GIT_CHECK_FUNC(memmem,
 597 [NO_MEMMEM=],
 598 [NO_MEMMEM=YesPlease])
 599 AC_SUBST(NO_MEMMEM)
 600 #
 601 # Define NO_STRLCPY if you don't have strlcpy.
 602 GIT_CHECK_FUNC(strlcpy,
 603 [NO_STRLCPY=],
 604 [NO_STRLCPY=YesPlease])
 605 AC_SUBST(NO_STRLCPY)
 606 #
 607 # Define NO_UINTMAX_T if your platform does not have uintmax_t
 608 AC_CHECK_TYPE(uintmax_t,
 609 [NO_UINTMAX_T=],
 610 [NO_UINTMAX_T=YesPlease],[
 611 #include <inttypes.h>
 612 ])
 613 AC_SUBST(NO_UINTMAX_T)
 614 #
 615 # Define NO_STRTOUMAX if you don't have strtoumax in the C library.
 616 GIT_CHECK_FUNC(strtoumax,
 617 [NO_STRTOUMAX=],
 618 [NO_STRTOUMAX=YesPlease])
 619 AC_SUBST(NO_STRTOUMAX)
 620 #
 621 # Define NO_SETENV if you don't have setenv in the C library.
 622 GIT_CHECK_FUNC(setenv,
 623 [NO_SETENV=],
 624 [NO_SETENV=YesPlease])
 625 AC_SUBST(NO_SETENV)
 626 #
 627 # Define NO_UNSETENV if you don't have unsetenv in the C library.
 628 GIT_CHECK_FUNC(unsetenv,
 629 [NO_UNSETENV=],
 630 [NO_UNSETENV=YesPlease])
 631 AC_SUBST(NO_UNSETENV)
 632 #
 633 # Define NO_MKDTEMP if you don't have mkdtemp in the C library.
 634 GIT_CHECK_FUNC(mkdtemp,
 635 [NO_MKDTEMP=],
 636 [NO_MKDTEMP=YesPlease])
 637 AC_SUBST(NO_MKDTEMP)
 638 #
 639 # Define NO_MMAP if you want to avoid mmap.
 640 #
 641 # Define NO_ICONV if your libc does not properly support iconv.
 642
 643
 644 ## Other checks.
 645 # Define USE_PIC if you need the main git objects to be built with -fPIC
 646 # in order to build and link perl/Git.so.  x86-64 seems to need this.
 647 #
 648 # Define NO_SYMLINK_HEAD if you never want .git/HEAD to be a symbolic link.
 649 # Enable it on Windows.  By default, symrefs are still used.
 650 #
 651 # Define NO_PTHREADS if we do not have pthreads
 652 #
 653 # Define PTHREAD_LIBS to the linker flag used for Pthread support and define
 654 # THREADED_DELTA_SEARCH if Pthreads are available.
 655 AC_LANG_CONFTEST([AC_LANG_PROGRAM(
 656   [[#include <pthread.h>]],
 657   [[pthread_mutex_t test_mutex;]]
 658 )])
 659 ${CC} -pthread conftest.c -o conftest.o > /dev/null 2>&1
 660 if test $? -eq 0;then
 661  PTHREAD_LIBS="-pthread"
 662  THREADED_DELTA_SEARCH=YesPlease
 663 else
 664  ${CC} -lpthread conftest.c -o conftest.o > /dev/null 2>&1
 665  if test $? -eq 0;then
 666   PTHREAD_LIBS="-lpthread"
 667   THREADED_DELTA_SEARCH=YesPlease
 668  else
 669   NO_PTHREADS=UnfortunatelyYes
 670  fi
 671 fi
 672 AC_SUBST(PTHREAD_LIBS)
 673 AC_SUBST(NO_PTHREADS)
 674 AC_SUBST(THREADED_DELTA_SEARCH)
 675
 676 ## Output files
 677 AC_CONFIG_FILES(["${config_file}":"${config_in}":"${config_append}"])
 678 AC_OUTPUT
 679
 680
 681 ## Cleanup
 682 rm -f "${config_append}"