gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # filename of html text to include at top of each page
  89 our $site_header = "++GITWEB_SITE_HEADER++";
  90 # html text to include at home page
  91 our $home_text = "++GITWEB_HOMETEXT++";
  92 # filename of html text to include at bottom of each page
  93 our $site_footer = "++GITWEB_SITE_FOOTER++";
  94
  95 # URI of stylesheets
  96 our @stylesheets = ("++GITWEB_CSS++");
  97 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  98 our $stylesheet = undef;
  99 # URI of GIT logo (72x27 size)
 100 our $logo = "++GITWEB_LOGO++";
 101 # URI of GIT favicon, assumed to be image/png type
 102 our $favicon = "++GITWEB_FAVICON++";
 103 # URI of gitweb.js (JavaScript code for gitweb)
 104 our $javascript = "++GITWEB_JS++";
 105
 106 # URI and label (title) of GIT logo link
 107 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 108 #our $logo_label = "git documentation";
 109 our $logo_url = "http://git-scm.com/";
 110 our $logo_label = "git homepage";
 111
 112 # source of projects list
 113 our $projects_list = "++GITWEB_LIST++";
 114
 115 # the width (in characters) of the projects list "Description" column
 116 our $projects_list_description_width = 25;
 117
 118 # group projects by category on the projects list
 119 # (enabled if this variable evaluates to true)
 120 our $projects_list_group_categories = 0;
 121
 122 # default category if none specified
 123 # (leave the empty string for no category)
 124 our $project_list_default_category = "";
 125
 126 # default order of projects list
 127 # valid values are none, project, descr, owner, and age
 128 our $default_projects_order = "project";
 129
 130 # show repository only if this file exists
 131 # (only effective if this variable evaluates to true)
 132 our $export_ok = "++GITWEB_EXPORT_OK++";
 133
 134 # show repository only if this subroutine returns true
 135 # when given the path to the project, for example:
 136 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 137 our $export_auth_hook = undef;
 138
 139 # only allow viewing of repositories also shown on the overview page
 140 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 141
 142 # list of git base URLs used for URL to where fetch project from,
 143 # i.e. full URL is "$git_base_url/$project"
 144 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 145
 146 # default blob_plain mimetype and default charset for text/plain blob
 147 our $default_blob_plain_mimetype = 'text/plain';
 148 our $default_text_plain_charset  = undef;
 149
 150 # file to use for guessing MIME types before trying /etc/mime.types
 151 # (relative to the current git repository)
 152 our $mimetypes_file = undef;
 153
 154 # assume this charset if line contains non-UTF-8 characters;
 155 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 156 # for which encoding all byte sequences are valid, for example
 157 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 158 # could be even 'utf-8' for the old behavior)
 159 our $fallback_encoding = 'latin1';
 160
 161 # rename detection options for git-diff and git-diff-tree
 162 # - default is '-M', with the cost proportional to
 163 #   (number of removed files) * (number of new files).
 164 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 165 #   (number of changed files + number of removed files) * (number of new files)
 166 # - even more costly is '-C', '--find-copies-harder' with cost
 167 #   (number of files in the original tree) * (number of new files)
 168 # - one might want to include '-B' option, e.g. '-B', '-M'
 169 our @diff_opts = ('-M'); # taken from git_commit
 170
 171 # Disables features that would allow repository owners to inject script into
 172 # the gitweb domain.
 173 our $prevent_xss = 0;
 174
 175 # Path to the highlight executable to use (must be the one from
 176 # http://www.andre-simon.de due to assumptions about parameters and output).
 177 # Useful if highlight is not installed on your webserver's PATH.
 178 # [Default: highlight]
 179 our $highlight_bin = "++HIGHLIGHT_BIN++";
 180
 181 # information about snapshot formats that gitweb is capable of serving
 182 our %known_snapshot_formats = (
 183         # name => {
 184         #       'display' => display name,
 185         #       'type' => mime type,
 186         #       'suffix' => filename suffix,
 187         #       'format' => --format for git-archive,
 188         #       'compressor' => [compressor command and arguments]
 189         #                       (array reference, optional)
 190         #       'disabled' => boolean (optional)}
 191         #
 192         'tgz' => {
 193                 'display' => 'tar.gz',
 194                 'type' => 'application/x-gzip',
 195                 'suffix' => '.tar.gz',
 196                 'format' => 'tar',
 197                 'compressor' => ['gzip', '-n']},
 198
 199         'tbz2' => {
 200                 'display' => 'tar.bz2',
 201                 'type' => 'application/x-bzip2',
 202                 'suffix' => '.tar.bz2',
 203                 'format' => 'tar',
 204                 'compressor' => ['bzip2']},
 205
 206         'txz' => {
 207                 'display' => 'tar.xz',
 208                 'type' => 'application/x-xz',
 209                 'suffix' => '.tar.xz',
 210                 'format' => 'tar',
 211                 'compressor' => ['xz'],
 212                 'disabled' => 1},
 213
 214         'zip' => {
 215                 'display' => 'zip',
 216                 'type' => 'application/x-zip',
 217                 'suffix' => '.zip',
 218                 'format' => 'zip'},
 219 );
 220
 221 # Aliases so we understand old gitweb.snapshot values in repository
 222 # configuration.
 223 our %known_snapshot_format_aliases = (
 224         'gzip'  => 'tgz',
 225         'bzip2' => 'tbz2',
 226         'xz'    => 'txz',
 227
 228         # backward compatibility: legacy gitweb config support
 229         'x-gzip' => undef, 'gz' => undef,
 230         'x-bzip2' => undef, 'bz2' => undef,
 231         'x-zip' => undef, '' => undef,
 232 );
 233
 234 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 235 # are changed, it may be appropriate to change these values too via
 236 # $GITWEB_CONFIG.
 237 our %avatar_size = (
 238         'default' => 16,
 239         'double'  => 32
 240 );
 241
 242 # Used to set the maximum load that we will still respond to gitweb queries.
 243 # If server load exceed this value then return "503 server busy" error.
 244 # If gitweb cannot determined server load, it is taken to be 0.
 245 # Leave it undefined (or set to 'undef') to turn off load checking.
 246 our $maxload = 300;
 247
 248 # configuration for 'highlight' (http://www.andre-simon.de/)
 249 # match by basename
 250 our %highlight_basename = (
 251         #'Program' => 'py',
 252         #'Library' => 'py',
 253         'SConstruct' => 'py', # SCons equivalent of Makefile
 254         'Makefile' => 'make',
 255 );
 256 # match by extension
 257 our %highlight_ext = (
 258         # main extensions, defining name of syntax;
 259         # see files in /usr/share/highlight/langDefs/ directory
 260         map { $_ => $_ }
 261                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 262         # alternate extensions, see /etc/highlight/filetypes.conf
 263         'h' => 'c',
 264         map { $_ => 'sh'  } qw(bash zsh ksh),
 265         map { $_ => 'cpp' } qw(cxx c++ cc),
 266         map { $_ => 'php' } qw(php3 php4 php5 phps),
 267         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 268         map { $_ => 'make'} qw(mak mk),
 269         map { $_ => 'xml' } qw(xhtml html htm),
 270 );
 271
 272 # You define site-wide feature defaults here; override them with
 273 # $GITWEB_CONFIG as necessary.
 274 our %feature = (
 275         # feature => {
 276         #       'sub' => feature-sub (subroutine),
 277         #       'override' => allow-override (boolean),
 278         #       'default' => [ default options...] (array reference)}
 279         #
 280         # if feature is overridable (it means that allow-override has true value),
 281         # then feature-sub will be called with default options as parameters;
 282         # return value of feature-sub indicates if to enable specified feature
 283         #
 284         # if there is no 'sub' key (no feature-sub), then feature cannot be
 285         # overridden
 286         #
 287         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 288         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 289         # is enabled
 290
 291         # Enable the 'blame' blob view, showing the last commit that modified
 292         # each line in the file. This can be very CPU-intensive.
 293
 294         # To enable system wide have in $GITWEB_CONFIG
 295         # $feature{'blame'}{'default'} = [1];
 296         # To have project specific config enable override in $GITWEB_CONFIG
 297         # $feature{'blame'}{'override'} = 1;
 298         # and in project config gitweb.blame = 0|1;
 299         'blame' => {
 300                 'sub' => sub { feature_bool('blame', @_) },
 301                 'override' => 0,
 302                 'default' => [0]},
 303
 304         # Enable the 'snapshot' link, providing a compressed archive of any
 305         # tree. This can potentially generate high traffic if you have large
 306         # project.
 307
 308         # Value is a list of formats defined in %known_snapshot_formats that
 309         # you wish to offer.
 310         # To disable system wide have in $GITWEB_CONFIG
 311         # $feature{'snapshot'}{'default'} = [];
 312         # To have project specific config enable override in $GITWEB_CONFIG
 313         # $feature{'snapshot'}{'override'} = 1;
 314         # and in project config, a comma-separated list of formats or "none"
 315         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 316         'snapshot' => {
 317                 'sub' => \&feature_snapshot,
 318                 'override' => 0,
 319                 'default' => ['tgz']},
 320
 321         # Enable text search, which will list the commits which match author,
 322         # committer or commit text to a given string.  Enabled by default.
 323         # Project specific override is not supported.
 324         #
 325         # Note that this controls all search features, which means that if
 326         # it is disabled, then 'grep' and 'pickaxe' search would also be
 327         # disabled.
 328         'search' => {
 329                 'override' => 0,
 330                 'default' => [1]},
 331
 332         # Enable grep search, which will list the files in currently selected
 333         # tree containing the given string. Enabled by default. This can be
 334         # potentially CPU-intensive, of course.
 335         # Note that you need to have 'search' feature enabled too.
 336
 337         # To enable system wide have in $GITWEB_CONFIG
 338         # $feature{'grep'}{'default'} = [1];
 339         # To have project specific config enable override in $GITWEB_CONFIG
 340         # $feature{'grep'}{'override'} = 1;
 341         # and in project config gitweb.grep = 0|1;
 342         'grep' => {
 343                 'sub' => sub { feature_bool('grep', @_) },
 344                 'override' => 0,
 345                 'default' => [1]},
 346
 347         # Enable the pickaxe search, which will list the commits that modified
 348         # a given string in a file. This can be practical and quite faster
 349         # alternative to 'blame', but still potentially CPU-intensive.
 350         # Note that you need to have 'search' feature enabled too.
 351
 352         # To enable system wide have in $GITWEB_CONFIG
 353         # $feature{'pickaxe'}{'default'} = [1];
 354         # To have project specific config enable override in $GITWEB_CONFIG
 355         # $feature{'pickaxe'}{'override'} = 1;
 356         # and in project config gitweb.pickaxe = 0|1;
 357         'pickaxe' => {
 358                 'sub' => sub { feature_bool('pickaxe', @_) },
 359                 'override' => 0,
 360                 'default' => [1]},
 361
 362         # Enable showing size of blobs in a 'tree' view, in a separate
 363         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 364
 365         # To disable system wide have in $GITWEB_CONFIG
 366         # $feature{'show-sizes'}{'default'} = [0];
 367         # To have project specific config enable override in $GITWEB_CONFIG
 368         # $feature{'show-sizes'}{'override'} = 1;
 369         # and in project config gitweb.showsizes = 0|1;
 370         'show-sizes' => {
 371                 'sub' => sub { feature_bool('showsizes', @_) },
 372                 'override' => 0,
 373                 'default' => [1]},
 374
 375         # Make gitweb use an alternative format of the URLs which can be
 376         # more readable and natural-looking: project name is embedded
 377         # directly in the path and the query string contains other
 378         # auxiliary information. All gitweb installations recognize
 379         # URL in either format; this configures in which formats gitweb
 380         # generates links.
 381
 382         # To enable system wide have in $GITWEB_CONFIG
 383         # $feature{'pathinfo'}{'default'} = [1];
 384         # Project specific override is not supported.
 385
 386         # Note that you will need to change the default location of CSS,
 387         # favicon, logo and possibly other files to an absolute URL. Also,
 388         # if gitweb.cgi serves as your indexfile, you will need to force
 389         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 390         'pathinfo' => {
 391                 'override' => 0,
 392                 'default' => [0]},
 393
 394         # Make gitweb consider projects in project root subdirectories
 395         # to be forks of existing projects. Given project $projname.git,
 396         # projects matching $projname/*.git will not be shown in the main
 397         # projects list, instead a '+' mark will be added to $projname
 398         # there and a 'forks' view will be enabled for the project, listing
 399         # all the forks. If project list is taken from a file, forks have
 400         # to be listed after the main project.
 401
 402         # To enable system wide have in $GITWEB_CONFIG
 403         # $feature{'forks'}{'default'} = [1];
 404         # Project specific override is not supported.
 405         'forks' => {
 406                 'override' => 0,
 407                 'default' => [0]},
 408
 409         # Insert custom links to the action bar of all project pages.
 410         # This enables you mainly to link to third-party scripts integrating
 411         # into gitweb; e.g. git-browser for graphical history representation
 412         # or custom web-based repository administration interface.
 413
 414         # The 'default' value consists of a list of triplets in the form
 415         # (label, link, position) where position is the label after which
 416         # to insert the link and link is a format string where %n expands
 417         # to the project name, %f to the project path within the filesystem,
 418         # %h to the current hash (h gitweb parameter) and %b to the current
 419         # hash base (hb gitweb parameter); %% expands to %.
 420
 421         # To enable system wide have in $GITWEB_CONFIG e.g.
 422         # $feature{'actions'}{'default'} = [('graphiclog',
 423         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 424         # Project specific override is not supported.
 425         'actions' => {
 426                 'override' => 0,
 427                 'default' => []},
 428
 429         # Allow gitweb scan project content tags of project repository,
 430         # and display the popular Web 2.0-ish "tag cloud" near the projects
 431         # list.  Note that this is something COMPLETELY different from the
 432         # normal Git tags.
 433
 434         # gitweb by itself can show existing tags, but it does not handle
 435         # tagging itself; you need to do it externally, outside gitweb.
 436         # The format is described in git_get_project_ctags() subroutine.
 437         # You may want to install the HTML::TagCloud Perl module to get
 438         # a pretty tag cloud instead of just a list of tags.
 439
 440         # To enable system wide have in $GITWEB_CONFIG
 441         # $feature{'ctags'}{'default'} = [1];
 442         # Project specific override is not supported.
 443
 444         # In the future whether ctags editing is enabled might depend
 445         # on the value, but using 1 should always mean no editing of ctags.
 446         'ctags' => {
 447                 'override' => 0,
 448                 'default' => [0]},
 449
 450         # The maximum number of patches in a patchset generated in patch
 451         # view. Set this to 0 or undef to disable patch view, or to a
 452         # negative number to remove any limit.
 453
 454         # To disable system wide have in $GITWEB_CONFIG
 455         # $feature{'patches'}{'default'} = [0];
 456         # To have project specific config enable override in $GITWEB_CONFIG
 457         # $feature{'patches'}{'override'} = 1;
 458         # and in project config gitweb.patches = 0|n;
 459         # where n is the maximum number of patches allowed in a patchset.
 460         'patches' => {
 461                 'sub' => \&feature_patches,
 462                 'override' => 0,
 463                 'default' => [16]},
 464
 465         # Avatar support. When this feature is enabled, views such as
 466         # shortlog or commit will display an avatar associated with
 467         # the email of the committer(s) and/or author(s).
 468
 469         # Currently available providers are gravatar and picon.
 470         # If an unknown provider is specified, the feature is disabled.
 471
 472         # Gravatar depends on Digest::MD5.
 473         # Picon currently relies on the indiana.edu database.
 474
 475         # To enable system wide have in $GITWEB_CONFIG
 476         # $feature{'avatar'}{'default'} = ['<provider>'];
 477         # where <provider> is either gravatar or picon.
 478         # To have project specific config enable override in $GITWEB_CONFIG
 479         # $feature{'avatar'}{'override'} = 1;
 480         # and in project config gitweb.avatar = <provider>;
 481         'avatar' => {
 482                 'sub' => \&feature_avatar,
 483                 'override' => 0,
 484                 'default' => ['']},
 485
 486         # Enable displaying how much time and how many git commands
 487         # it took to generate and display page.  Disabled by default.
 488         # Project specific override is not supported.
 489         'timed' => {
 490                 'override' => 0,
 491                 'default' => [0]},
 492
 493         # Enable turning some links into links to actions which require
 494         # JavaScript to run (like 'blame_incremental').  Not enabled by
 495         # default.  Project specific override is currently not supported.
 496         'javascript-actions' => {
 497                 'override' => 0,
 498                 'default' => [0]},
 499
 500         # Enable and configure ability to change common timezone for dates
 501         # in gitweb output via JavaScript.  Enabled by default.
 502         # Project specific override is not supported.
 503         'javascript-timezone' => {
 504                 'override' => 0,
 505                 'default' => [
 506                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 507                                      # or undef to turn off this feature
 508                         'gitweb_tz', # name of cookie where to store selected timezone
 509                         'datetime',  # CSS class used to mark up dates for manipulation
 510                 ]},
 511
 512         # Syntax highlighting support. This is based on Daniel Svensson's
 513         # and Sham Chukoury's work in gitweb-xmms2.git.
 514         # It requires the 'highlight' program present in $PATH,
 515         # and therefore is disabled by default.
 516
 517         # To enable system wide have in $GITWEB_CONFIG
 518         # $feature{'highlight'}{'default'} = [1];
 519
 520         'highlight' => {
 521                 'sub' => sub { feature_bool('highlight', @_) },
 522                 'override' => 0,
 523                 'default' => [0]},
 524
 525         # Enable displaying of remote heads in the heads list
 526
 527         # To enable system wide have in $GITWEB_CONFIG
 528         # $feature{'remote_heads'}{'default'} = [1];
 529         # To have project specific config enable override in $GITWEB_CONFIG
 530         # $feature{'remote_heads'}{'override'} = 1;
 531         # and in project config gitweb.remote_heads = 0|1;
 532         'remote_heads' => {
 533                 'sub' => sub { feature_bool('remote_heads', @_) },
 534                 'override' => 0,
 535                 'default' => [0]},
 536 );
 537
 538 sub gitweb_get_feature {
 539         my ($name) = @_;
 540         return unless exists $feature{$name};
 541         my ($sub, $override, @defaults) = (
 542                 $feature{$name}{'sub'},
 543                 $feature{$name}{'override'},
 544                 @{$feature{$name}{'default'}});
 545         # project specific override is possible only if we have project
 546         our $git_dir; # global variable, declared later
 547         if (!$override || !defined $git_dir) {
 548                 return @defaults;
 549         }
 550         if (!defined $sub) {
 551                 warn "feature $name is not overridable";
 552                 return @defaults;
 553         }
 554         return $sub->(@defaults);
 555 }
 556
 557 # A wrapper to check if a given feature is enabled.
 558 # With this, you can say
 559 #
 560 #   my $bool_feat = gitweb_check_feature('bool_feat');
 561 #   gitweb_check_feature('bool_feat') or somecode;
 562 #
 563 # instead of
 564 #
 565 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 566 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 567 #
 568 sub gitweb_check_feature {
 569         return (gitweb_get_feature(@_))[0];
 570 }
 571
 572
 573 sub feature_bool {
 574         my $key = shift;
 575         my ($val) = git_get_project_config($key, '--bool');
 576
 577         if (!defined $val) {
 578                 return ($_[0]);
 579         } elsif ($val eq 'true') {
 580                 return (1);
 581         } elsif ($val eq 'false') {
 582                 return (0);
 583         }
 584 }
 585
 586 sub feature_snapshot {
 587         my (@fmts) = @_;
 588
 589         my ($val) = git_get_project_config('snapshot');
 590
 591         if ($val) {
 592                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 593         }
 594
 595         return @fmts;
 596 }
 597
 598 sub feature_patches {
 599         my @val = (git_get_project_config('patches', '--int'));
 600
 601         if (@val) {
 602                 return @val;
 603         }
 604
 605         return ($_[0]);
 606 }
 607
 608 sub feature_avatar {
 609         my @val = (git_get_project_config('avatar'));
 610
 611         return @val ? @val : @_;
 612 }
 613
 614 # checking HEAD file with -e is fragile if the repository was
 615 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 616 # and then pruned.
 617 sub check_head_link {
 618         my ($dir) = @_;
 619         my $headfile = "$dir/HEAD";
 620         return ((-e $headfile) ||
 621                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 622 }
 623
 624 sub check_export_ok {
 625         my ($dir) = @_;
 626         return (check_head_link($dir) &&
 627                 (!$export_ok || -e "$dir/$export_ok") &&
 628                 (!$export_auth_hook || $export_auth_hook->($dir)));
 629 }
 630
 631 # process alternate names for backward compatibility
 632 # filter out unsupported (unknown) snapshot formats
 633 sub filter_snapshot_fmts {
 634         my @fmts = @_;
 635
 636         @fmts = map {
 637                 exists $known_snapshot_format_aliases{$_} ?
 638                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 639         @fmts = grep {
 640                 exists $known_snapshot_formats{$_} &&
 641                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 642 }
 643
 644 # If it is set to code reference, it is code that it is to be run once per
 645 # request, allowing updating configurations that change with each request,
 646 # while running other code in config file only once.
 647 #
 648 # Otherwise, if it is false then gitweb would process config file only once;
 649 # if it is true then gitweb config would be run for each request.
 650 our $per_request_config = 1;
 651
 652 # read and parse gitweb config file given by its parameter.
 653 # returns true on success, false on recoverable error, allowing
 654 # to chain this subroutine, using first file that exists.
 655 # dies on errors during parsing config file, as it is unrecoverable.
 656 sub read_config_file {
 657         my $filename = shift;
 658         return unless defined $filename;
 659         # die if there are errors parsing config file
 660         if (-e $filename) {
 661                 do $filename;
 662                 die $@ if $@;
 663                 return 1;
 664         }
 665         return;
 666 }
 667
 668 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 669 sub evaluate_gitweb_config {
 670         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 671         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 672         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 673
 674         # Protect agains duplications of file names, to not read config twice.
 675         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 676         # there possibility of duplication of filename there doesn't matter.
 677         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 678         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 679
 680         # Common system-wide settings for convenience.
 681         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 682         read_config_file($GITWEB_CONFIG_COMMON);
 683
 684         # Use first config file that exists.  This means use the per-instance
 685         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 686         read_config_file($GITWEB_CONFIG) and return;
 687         read_config_file($GITWEB_CONFIG_SYSTEM);
 688 }
 689
 690 # Get loadavg of system, to compare against $maxload.
 691 # Currently it requires '/proc/loadavg' present to get loadavg;
 692 # if it is not present it returns 0, which means no load checking.
 693 sub get_loadavg {
 694         if( -e '/proc/loadavg' ){
 695                 open my $fd, '<', '/proc/loadavg'
 696                         or return 0;
 697                 my @load = split(/\s+/, scalar <$fd>);
 698                 close $fd;
 699
 700                 # The first three columns measure CPU and IO utilization of the last one,
 701                 # five, and 10 minute periods.  The fourth column shows the number of
 702                 # currently running processes and the total number of processes in the m/n
 703                 # format.  The last column displays the last process ID used.
 704                 return $load[0] || 0;
 705         }
 706         # additional checks for load average should go here for things that don't export
 707         # /proc/loadavg
 708
 709         return 0;
 710 }
 711
 712 # version of the core git binary
 713 our $git_version;
 714 sub evaluate_git_version {
 715         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 716         $number_of_git_cmds++;
 717 }
 718
 719 sub check_loadavg {
 720         if (defined $maxload && get_loadavg() > $maxload) {
 721                 die_error(503, "The load average on the server is too high");
 722         }
 723 }
 724
 725 # ======================================================================
 726 # input validation and dispatch
 727
 728 # input parameters can be collected from a variety of sources (presently, CGI
 729 # and PATH_INFO), so we define an %input_params hash that collects them all
 730 # together during validation: this allows subsequent uses (e.g. href()) to be
 731 # agnostic of the parameter origin
 732
 733 our %input_params = ();
 734
 735 # input parameters are stored with the long parameter name as key. This will
 736 # also be used in the href subroutine to convert parameters to their CGI
 737 # equivalent, and since the href() usage is the most frequent one, we store
 738 # the name -> CGI key mapping here, instead of the reverse.
 739 #
 740 # XXX: Warning: If you touch this, check the search form for updating,
 741 # too.
 742
 743 our @cgi_param_mapping = (
 744         project => "p",
 745         action => "a",
 746         file_name => "f",
 747         file_parent => "fp",
 748         hash => "h",
 749         hash_parent => "hp",
 750         hash_base => "hb",
 751         hash_parent_base => "hpb",
 752         page => "pg",
 753         order => "o",
 754         searchtext => "s",
 755         searchtype => "st",
 756         snapshot_format => "sf",
 757         extra_options => "opt",
 758         search_use_regexp => "sr",
 759         ctag => "by_tag",
 760         diff_style => "ds",
 761         # this must be last entry (for manipulation from JavaScript)
 762         javascript => "js"
 763 );
 764 our %cgi_param_mapping = @cgi_param_mapping;
 765
 766 # we will also need to know the possible actions, for validation
 767 our %actions = (
 768         "blame" => \&git_blame,
 769         "blame_incremental" => \&git_blame_incremental,
 770         "blame_data" => \&git_blame_data,
 771         "blobdiff" => \&git_blobdiff,
 772         "blobdiff_plain" => \&git_blobdiff_plain,
 773         "blob" => \&git_blob,
 774         "blob_plain" => \&git_blob_plain,
 775         "commitdiff" => \&git_commitdiff,
 776         "commitdiff_plain" => \&git_commitdiff_plain,
 777         "commit" => \&git_commit,
 778         "forks" => \&git_forks,
 779         "heads" => \&git_heads,
 780         "history" => \&git_history,
 781         "log" => \&git_log,
 782         "patch" => \&git_patch,
 783         "patches" => \&git_patches,
 784         "remotes" => \&git_remotes,
 785         "rss" => \&git_rss,
 786         "atom" => \&git_atom,
 787         "search" => \&git_search,
 788         "search_help" => \&git_search_help,
 789         "shortlog" => \&git_shortlog,
 790         "summary" => \&git_summary,
 791         "tag" => \&git_tag,
 792         "tags" => \&git_tags,
 793         "tree" => \&git_tree,
 794         "snapshot" => \&git_snapshot,
 795         "object" => \&git_object,
 796         # those below don't need $project
 797         "opml" => \&git_opml,
 798         "project_list" => \&git_project_list,
 799         "project_index" => \&git_project_index,
 800 );
 801
 802 # finally, we have the hash of allowed extra_options for the commands that
 803 # allow them
 804 our %allowed_options = (
 805         "--no-merges" => [ qw(rss atom log shortlog history) ],
 806 );
 807
 808 # fill %input_params with the CGI parameters. All values except for 'opt'
 809 # should be single values, but opt can be an array. We should probably
 810 # build an array of parameters that can be multi-valued, but since for the time
 811 # being it's only this one, we just single it out
 812 sub evaluate_query_params {
 813         our $cgi;
 814
 815         while (my ($name, $symbol) = each %cgi_param_mapping) {
 816                 if ($symbol eq 'opt') {
 817                         $input_params{$name} = [ $cgi->param($symbol) ];
 818                 } else {
 819                         $input_params{$name} = $cgi->param($symbol);
 820                 }
 821         }
 822 }
 823
 824 # now read PATH_INFO and update the parameter list for missing parameters
 825 sub evaluate_path_info {
 826         return if defined $input_params{'project'};
 827         return if !$path_info;
 828         $path_info =~ s,^/+,,;
 829         return if !$path_info;
 830
 831         # find which part of PATH_INFO is project
 832         my $project = $path_info;
 833         $project =~ s,/+$,,;
 834         while ($project && !check_head_link("$projectroot/$project")) {
 835                 $project =~ s,/*[^/]*$,,;
 836         }
 837         return unless $project;
 838         $input_params{'project'} = $project;
 839
 840         # do not change any parameters if an action is given using the query string
 841         return if $input_params{'action'};
 842         $path_info =~ s,^\Q$project\E/*,,;
 843
 844         # next, check if we have an action
 845         my $action = $path_info;
 846         $action =~ s,/.*$,,;
 847         if (exists $actions{$action}) {
 848                 $path_info =~ s,^$action/*,,;
 849                 $input_params{'action'} = $action;
 850         }
 851
 852         # list of actions that want hash_base instead of hash, but can have no
 853         # pathname (f) parameter
 854         my @wants_base = (
 855                 'tree',
 856                 'history',
 857         );
 858
 859         # we want to catch, among others
 860         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 861         my ($parentrefname, $parentpathname, $refname, $pathname) =
 862                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 863
 864         # first, analyze the 'current' part
 865         if (defined $pathname) {
 866                 # we got "branch:filename" or "branch:dir/"
 867                 # we could use git_get_type(branch:pathname), but:
 868                 # - it needs $git_dir
 869                 # - it does a git() call
 870                 # - the convention of terminating directories with a slash
 871                 #   makes it superfluous
 872                 # - embedding the action in the PATH_INFO would make it even
 873                 #   more superfluous
 874                 $pathname =~ s,^/+,,;
 875                 if (!$pathname || substr($pathname, -1) eq "/") {
 876                         $input_params{'action'} ||= "tree";
 877                         $pathname =~ s,/$,,;
 878                 } else {
 879                         # the default action depends on whether we had parent info
 880                         # or not
 881                         if ($parentrefname) {
 882                                 $input_params{'action'} ||= "blobdiff_plain";
 883                         } else {
 884                                 $input_params{'action'} ||= "blob_plain";
 885                         }
 886                 }
 887                 $input_params{'hash_base'} ||= $refname;
 888                 $input_params{'file_name'} ||= $pathname;
 889         } elsif (defined $refname) {
 890                 # we got "branch". In this case we have to choose if we have to
 891                 # set hash or hash_base.
 892                 #
 893                 # Most of the actions without a pathname only want hash to be
 894                 # set, except for the ones specified in @wants_base that want
 895                 # hash_base instead. It should also be noted that hand-crafted
 896                 # links having 'history' as an action and no pathname or hash
 897                 # set will fail, but that happens regardless of PATH_INFO.
 898                 if (defined $parentrefname) {
 899                         # if there is parent let the default be 'shortlog' action
 900                         # (for http://git.example.com/repo.git/A..B links); if there
 901                         # is no parent, dispatch will detect type of object and set
 902                         # action appropriately if required (if action is not set)
 903                         $input_params{'action'} ||= "shortlog";
 904                 }
 905                 if ($input_params{'action'} &&
 906                     grep { $_ eq $input_params{'action'} } @wants_base) {
 907                         $input_params{'hash_base'} ||= $refname;
 908                 } else {
 909                         $input_params{'hash'} ||= $refname;
 910                 }
 911         }
 912
 913         # next, handle the 'parent' part, if present
 914         if (defined $parentrefname) {
 915                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 916                 # someproject/blobdiff/oldrev..newrev:/filename
 917                 if ($parentpathname) {
 918                         $parentpathname =~ s,^/+,,;
 919                         $parentpathname =~ s,/$,,;
 920                         $input_params{'file_parent'} ||= $parentpathname;
 921                 } else {
 922                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 923                 }
 924                 # we assume that hash_parent_base is wanted if a path was specified,
 925                 # or if the action wants hash_base instead of hash
 926                 if (defined $input_params{'file_parent'} ||
 927                         grep { $_ eq $input_params{'action'} } @wants_base) {
 928                         $input_params{'hash_parent_base'} ||= $parentrefname;
 929                 } else {
 930                         $input_params{'hash_parent'} ||= $parentrefname;
 931                 }
 932         }
 933
 934         # for the snapshot action, we allow URLs in the form
 935         # $project/snapshot/$hash.ext
 936         # where .ext determines the snapshot and gets removed from the
 937         # passed $refname to provide the $hash.
 938         #
 939         # To be able to tell that $refname includes the format extension, we
 940         # require the following two conditions to be satisfied:
 941         # - the hash input parameter MUST have been set from the $refname part
 942         #   of the URL (i.e. they must be equal)
 943         # - the snapshot format MUST NOT have been defined already (e.g. from
 944         #   CGI parameter sf)
 945         # It's also useless to try any matching unless $refname has a dot,
 946         # so we check for that too
 947         if (defined $input_params{'action'} &&
 948                 $input_params{'action'} eq 'snapshot' &&
 949                 defined $refname && index($refname, '.') != -1 &&
 950                 $refname eq $input_params{'hash'} &&
 951                 !defined $input_params{'snapshot_format'}) {
 952                 # We loop over the known snapshot formats, checking for
 953                 # extensions. Allowed extensions are both the defined suffix
 954                 # (which includes the initial dot already) and the snapshot
 955                 # format key itself, with a prepended dot
 956                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 957                         my $hash = $refname;
 958                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 959                                 next;
 960                         }
 961                         my $sfx = $1;
 962                         # a valid suffix was found, so set the snapshot format
 963                         # and reset the hash parameter
 964                         $input_params{'snapshot_format'} = $fmt;
 965                         $input_params{'hash'} = $hash;
 966                         # we also set the format suffix to the one requested
 967                         # in the URL: this way a request for e.g. .tgz returns
 968                         # a .tgz instead of a .tar.gz
 969                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 970                         last;
 971                 }
 972         }
 973 }
 974
 975 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 976      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 977      $searchtext, $search_regexp);
 978 sub evaluate_and_validate_params {
 979         our $action = $input_params{'action'};
 980         if (defined $action) {
 981                 if (!validate_action($action)) {
 982                         die_error(400, "Invalid action parameter");
 983                 }
 984         }
 985
 986         # parameters which are pathnames
 987         our $project = $input_params{'project'};
 988         if (defined $project) {
 989                 if (!validate_project($project)) {
 990                         undef $project;
 991                         die_error(404, "No such project");
 992                 }
 993         }
 994
 995         our $file_name = $input_params{'file_name'};
 996         if (defined $file_name) {
 997                 if (!validate_pathname($file_name)) {
 998                         die_error(400, "Invalid file parameter");
 999                 }
1000         }
1001
1002         our $file_parent = $input_params{'file_parent'};
1003         if (defined $file_parent) {
1004                 if (!validate_pathname($file_parent)) {
1005                         die_error(400, "Invalid file parent parameter");
1006                 }
1007         }
1008
1009         # parameters which are refnames
1010         our $hash = $input_params{'hash'};
1011         if (defined $hash) {
1012                 if (!validate_refname($hash)) {
1013                         die_error(400, "Invalid hash parameter");
1014                 }
1015         }
1016
1017         our $hash_parent = $input_params{'hash_parent'};
1018         if (defined $hash_parent) {
1019                 if (!validate_refname($hash_parent)) {
1020                         die_error(400, "Invalid hash parent parameter");
1021                 }
1022         }
1023
1024         our $hash_base = $input_params{'hash_base'};
1025         if (defined $hash_base) {
1026                 if (!validate_refname($hash_base)) {
1027                         die_error(400, "Invalid hash base parameter");
1028                 }
1029         }
1030
1031         our @extra_options = @{$input_params{'extra_options'}};
1032         # @extra_options is always defined, since it can only be (currently) set from
1033         # CGI, and $cgi->param() returns the empty array in array context if the param
1034         # is not set
1035         foreach my $opt (@extra_options) {
1036                 if (not exists $allowed_options{$opt}) {
1037                         die_error(400, "Invalid option parameter");
1038                 }
1039                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1040                         die_error(400, "Invalid option parameter for this action");
1041                 }
1042         }
1043
1044         our $hash_parent_base = $input_params{'hash_parent_base'};
1045         if (defined $hash_parent_base) {
1046                 if (!validate_refname($hash_parent_base)) {
1047                         die_error(400, "Invalid hash parent base parameter");
1048                 }
1049         }
1050
1051         # other parameters
1052         our $page = $input_params{'page'};
1053         if (defined $page) {
1054                 if ($page =~ m/[^0-9]/) {
1055                         die_error(400, "Invalid page parameter");
1056                 }
1057         }
1058
1059         our $searchtype = $input_params{'searchtype'};
1060         if (defined $searchtype) {
1061                 if ($searchtype =~ m/[^a-z]/) {
1062                         die_error(400, "Invalid searchtype parameter");
1063                 }
1064         }
1065
1066         our $search_use_regexp = $input_params{'search_use_regexp'};
1067
1068         our $searchtext = $input_params{'searchtext'};
1069         our $search_regexp;
1070         if (defined $searchtext) {
1071                 if (length($searchtext) < 2) {
1072                         die_error(403, "At least two characters are required for search parameter");
1073                 }
1074                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1075         }
1076
1077         $input_params{diff_style} ||= 'inline';
1078 }
1079
1080 # path to the current git repository
1081 our $git_dir;
1082 sub evaluate_git_dir {
1083         our $git_dir = "$projectroot/$project" if $project;
1084 }
1085
1086 our (@snapshot_fmts, $git_avatar);
1087 sub configure_gitweb_features {
1088         # list of supported snapshot formats
1089         our @snapshot_fmts = gitweb_get_feature('snapshot');
1090         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1091
1092         # check that the avatar feature is set to a known provider name,
1093         # and for each provider check if the dependencies are satisfied.
1094         # if the provider name is invalid or the dependencies are not met,
1095         # reset $git_avatar to the empty string.
1096         our ($git_avatar) = gitweb_get_feature('avatar');
1097         if ($git_avatar eq 'gravatar') {
1098                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1099         } elsif ($git_avatar eq 'picon') {
1100                 # no dependencies
1101         } else {
1102                 $git_avatar = '';
1103         }
1104 }
1105
1106 # custom error handler: 'die <message>' is Internal Server Error
1107 sub handle_errors_html {
1108         my $msg = shift; # it is already HTML escaped
1109
1110         # to avoid infinite loop where error occurs in die_error,
1111         # change handler to default handler, disabling handle_errors_html
1112         set_message("Error occured when inside die_error:\n$msg");
1113
1114         # you cannot jump out of die_error when called as error handler;
1115         # the subroutine set via CGI::Carp::set_message is called _after_
1116         # HTTP headers are already written, so it cannot write them itself
1117         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1118 }
1119 set_message(\&handle_errors_html);
1120
1121 # dispatch
1122 sub dispatch {
1123         if (!defined $action) {
1124                 if (defined $hash) {
1125                         $action = git_get_type($hash);
1126                 } elsif (defined $hash_base && defined $file_name) {
1127                         $action = git_get_type("$hash_base:$file_name");
1128                 } elsif (defined $project) {
1129                         $action = 'summary';
1130                 } else {
1131                         $action = 'project_list';
1132                 }
1133         }
1134         if (!defined($actions{$action})) {
1135                 die_error(400, "Unknown action");
1136         }
1137         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1138             !$project) {
1139                 die_error(400, "Project needed");
1140         }
1141         $actions{$action}->();
1142 }
1143
1144 sub reset_timer {
1145         our $t0 = [ gettimeofday() ]
1146                 if defined $t0;
1147         our $number_of_git_cmds = 0;
1148 }
1149
1150 our $first_request = 1;
1151 sub run_request {
1152         reset_timer();
1153
1154         evaluate_uri();
1155         if ($first_request) {
1156                 evaluate_gitweb_config();
1157                 evaluate_git_version();
1158         }
1159         if ($per_request_config) {
1160                 if (ref($per_request_config) eq 'CODE') {
1161                         $per_request_config->();
1162                 } elsif (!$first_request) {
1163                         evaluate_gitweb_config();
1164                 }
1165         }
1166         check_loadavg();
1167
1168         # $projectroot and $projects_list might be set in gitweb config file
1169         $projects_list ||= $projectroot;
1170
1171         evaluate_query_params();
1172         evaluate_path_info();
1173         evaluate_and_validate_params();
1174         evaluate_git_dir();
1175
1176         configure_gitweb_features();
1177
1178         dispatch();
1179 }
1180
1181 our $is_last_request = sub { 1 };
1182 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1183 our $CGI = 'CGI';
1184 our $cgi;
1185 sub configure_as_fcgi {
1186         require CGI::Fast;
1187         our $CGI = 'CGI::Fast';
1188
1189         my $request_number = 0;
1190         # let each child service 100 requests
1191         our $is_last_request = sub { ++$request_number > 100 };
1192 }
1193 sub evaluate_argv {
1194         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1195         configure_as_fcgi()
1196                 if $script_name =~ /\.fcgi$/;
1197
1198         return unless (@ARGV);
1199
1200         require Getopt::Long;
1201         Getopt::Long::GetOptions(
1202                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1203                 'nproc|n=i' => sub {
1204                         my ($arg, $val) = @_;
1205                         return unless eval { require FCGI::ProcManager; 1; };
1206                         my $proc_manager = FCGI::ProcManager->new({
1207                                 n_processes => $val,
1208                         });
1209                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1210                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1211                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1212                 },
1213         );
1214 }
1215
1216 sub run {
1217         evaluate_argv();
1218
1219         $first_request = 1;
1220         $pre_listen_hook->()
1221                 if $pre_listen_hook;
1222
1223  REQUEST:
1224         while ($cgi = $CGI->new()) {
1225                 $pre_dispatch_hook->()
1226                         if $pre_dispatch_hook;
1227
1228                 run_request();
1229
1230                 $post_dispatch_hook->()
1231                         if $post_dispatch_hook;
1232                 $first_request = 0;
1233
1234                 last REQUEST if ($is_last_request->());
1235         }
1236
1237  DONE_GITWEB:
1238         1;
1239 }
1240
1241 run();
1242
1243 if (defined caller) {
1244         # wrapped in a subroutine processing requests,
1245         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1246         return;
1247 } else {
1248         # pure CGI script, serving single request
1249         exit;
1250 }
1251
1252 ## ======================================================================
1253 ## action links
1254
1255 # possible values of extra options
1256 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1257 # -replay => 1      - start from a current view (replay with modifications)
1258 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1259 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1260 sub href {
1261         my %params = @_;
1262         # default is to use -absolute url() i.e. $my_uri
1263         my $href = $params{-full} ? $my_url : $my_uri;
1264
1265         # implicit -replay, must be first of implicit params
1266         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1267
1268         $params{'project'} = $project unless exists $params{'project'};
1269
1270         if ($params{-replay}) {
1271                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1272                         if (!exists $params{$name}) {
1273                                 $params{$name} = $input_params{$name};
1274                         }
1275                 }
1276         }
1277
1278         my $use_pathinfo = gitweb_check_feature('pathinfo');
1279         if (defined $params{'project'} &&
1280             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1281                 # try to put as many parameters as possible in PATH_INFO:
1282                 #   - project name
1283                 #   - action
1284                 #   - hash_parent or hash_parent_base:/file_parent
1285                 #   - hash or hash_base:/filename
1286                 #   - the snapshot_format as an appropriate suffix
1287
1288                 # When the script is the root DirectoryIndex for the domain,
1289                 # $href here would be something like http://gitweb.example.com/
1290                 # Thus, we strip any trailing / from $href, to spare us double
1291                 # slashes in the final URL
1292                 $href =~ s,/$,,;
1293
1294                 # Then add the project name, if present
1295                 $href .= "/".esc_path_info($params{'project'});
1296                 delete $params{'project'};
1297
1298                 # since we destructively absorb parameters, we keep this
1299                 # boolean that remembers if we're handling a snapshot
1300                 my $is_snapshot = $params{'action'} eq 'snapshot';
1301
1302                 # Summary just uses the project path URL, any other action is
1303                 # added to the URL
1304                 if (defined $params{'action'}) {
1305                         $href .= "/".esc_path_info($params{'action'})
1306                                 unless $params{'action'} eq 'summary';
1307                         delete $params{'action'};
1308                 }
1309
1310                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1311                 # stripping nonexistent or useless pieces
1312                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1313                         || $params{'hash_parent'} || $params{'hash'});
1314                 if (defined $params{'hash_base'}) {
1315                         if (defined $params{'hash_parent_base'}) {
1316                                 $href .= esc_path_info($params{'hash_parent_base'});
1317                                 # skip the file_parent if it's the same as the file_name
1318                                 if (defined $params{'file_parent'}) {
1319                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1320                                                 delete $params{'file_parent'};
1321                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1322                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1323                                                 delete $params{'file_parent'};
1324                                         }
1325                                 }
1326                                 $href .= "..";
1327                                 delete $params{'hash_parent'};
1328                                 delete $params{'hash_parent_base'};
1329                         } elsif (defined $params{'hash_parent'}) {
1330                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1331                                 delete $params{'hash_parent'};
1332                         }
1333
1334                         $href .= esc_path_info($params{'hash_base'});
1335                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1336                                 $href .= ":/".esc_path_info($params{'file_name'});
1337                                 delete $params{'file_name'};
1338                         }
1339                         delete $params{'hash'};
1340                         delete $params{'hash_base'};
1341                 } elsif (defined $params{'hash'}) {
1342                         $href .= esc_path_info($params{'hash'});
1343                         delete $params{'hash'};
1344                 }
1345
1346                 # If the action was a snapshot, we can absorb the
1347                 # snapshot_format parameter too
1348                 if ($is_snapshot) {
1349                         my $fmt = $params{'snapshot_format'};
1350                         # snapshot_format should always be defined when href()
1351                         # is called, but just in case some code forgets, we
1352                         # fall back to the default
1353                         $fmt ||= $snapshot_fmts[0];
1354                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1355                         delete $params{'snapshot_format'};
1356                 }
1357         }
1358
1359         # now encode the parameters explicitly
1360         my @result = ();
1361         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1362                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1363                 if (defined $params{$name}) {
1364                         if (ref($params{$name}) eq "ARRAY") {
1365                                 foreach my $par (@{$params{$name}}) {
1366                                         push @result, $symbol . "=" . esc_param($par);
1367                                 }
1368                         } else {
1369                                 push @result, $symbol . "=" . esc_param($params{$name});
1370                         }
1371                 }
1372         }
1373         $href .= "?" . join(';', @result) if scalar @result;
1374
1375         # final transformation: trailing spaces must be escaped (URI-encoded)
1376         $href =~ s/(\s+)$/CGI::escape($1)/e;
1377
1378         if ($params{-anchor}) {
1379                 $href .= "#".esc_param($params{-anchor});
1380         }
1381
1382         return $href;
1383 }
1384
1385
1386 ## ======================================================================
1387 ## validation, quoting/unquoting and escaping
1388
1389 sub validate_action {
1390         my $input = shift || return undef;
1391         return undef unless exists $actions{$input};
1392         return $input;
1393 }
1394
1395 sub validate_project {
1396         my $input = shift || return undef;
1397         if (!validate_pathname($input) ||
1398                 !(-d "$projectroot/$input") ||
1399                 !check_export_ok("$projectroot/$input") ||
1400                 ($strict_export && !project_in_list($input))) {
1401                 return undef;
1402         } else {
1403                 return $input;
1404         }
1405 }
1406
1407 sub validate_pathname {
1408         my $input = shift || return undef;
1409
1410         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1411         # at the beginning, at the end, and between slashes.
1412         # also this catches doubled slashes
1413         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1414                 return undef;
1415         }
1416         # no null characters
1417         if ($input =~ m!\0!) {
1418                 return undef;
1419         }
1420         return $input;
1421 }
1422
1423 sub validate_refname {
1424         my $input = shift || return undef;
1425
1426         # textual hashes are O.K.
1427         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1428                 return $input;
1429         }
1430         # it must be correct pathname
1431         $input = validate_pathname($input)
1432                 or return undef;
1433         # restrictions on ref name according to git-check-ref-format
1434         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1435                 return undef;
1436         }
1437         return $input;
1438 }
1439
1440 # decode sequences of octets in utf8 into Perl's internal form,
1441 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1442 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1443 sub to_utf8 {
1444         my $str = shift;
1445         return undef unless defined $str;
1446         if (utf8::valid($str)) {
1447                 utf8::decode($str);
1448                 return $str;
1449         } else {
1450                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1451         }
1452 }
1453
1454 # quote unsafe chars, but keep the slash, even when it's not
1455 # correct, but quoted slashes look too horrible in bookmarks
1456 sub esc_param {
1457         my $str = shift;
1458         return undef unless defined $str;
1459         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1460         $str =~ s/ /\+/g;
1461         return $str;
1462 }
1463
1464 # the quoting rules for path_info fragment are slightly different
1465 sub esc_path_info {
1466         my $str = shift;
1467         return undef unless defined $str;
1468
1469         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1470         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1471
1472         return $str;
1473 }
1474
1475 # quote unsafe chars in whole URL, so some characters cannot be quoted
1476 sub esc_url {
1477         my $str = shift;
1478         return undef unless defined $str;
1479         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1480         $str =~ s/ /\+/g;
1481         return $str;
1482 }
1483
1484 # quote unsafe characters in HTML attributes
1485 sub esc_attr {
1486
1487         # for XHTML conformance escaping '"' to '&quot;' is not enough
1488         return esc_html(@_);
1489 }
1490
1491 # replace invalid utf8 character with SUBSTITUTION sequence
1492 sub esc_html {
1493         my $str = shift;
1494         my %opts = @_;
1495
1496         return undef unless defined $str;
1497
1498         $str = to_utf8($str);
1499         $str = $cgi->escapeHTML($str);
1500         if ($opts{'-nbsp'}) {
1501                 $str =~ s/ /&nbsp;/g;
1502         }
1503         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1504         return $str;
1505 }
1506
1507 # quote control characters and escape filename to HTML
1508 sub esc_path {
1509         my $str = shift;
1510         my %opts = @_;
1511
1512         return undef unless defined $str;
1513
1514         $str = to_utf8($str);
1515         $str = $cgi->escapeHTML($str);
1516         if ($opts{'-nbsp'}) {
1517                 $str =~ s/ /&nbsp;/g;
1518         }
1519         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1520         return $str;
1521 }
1522
1523 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1524 sub sanitize {
1525         my $str = shift;
1526
1527         return undef unless defined $str;
1528
1529         $str = to_utf8($str);
1530         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1531         return $str;
1532 }
1533
1534 # Make control characters "printable", using character escape codes (CEC)
1535 sub quot_cec {
1536         my $cntrl = shift;
1537         my %opts = @_;
1538         my %es = ( # character escape codes, aka escape sequences
1539                 "\t" => '\t',   # tab            (HT)
1540                 "\n" => '\n',   # line feed      (LF)
1541                 "\r" => '\r',   # carrige return (CR)
1542                 "\f" => '\f',   # form feed      (FF)
1543                 "\b" => '\b',   # backspace      (BS)
1544                 "\a" => '\a',   # alarm (bell)   (BEL)
1545                 "\e" => '\e',   # escape         (ESC)
1546                 "\013" => '\v', # vertical tab   (VT)
1547                 "\000" => '\0', # nul character  (NUL)
1548         );
1549         my $chr = ( (exists $es{$cntrl})
1550                     ? $es{$cntrl}
1551                     : sprintf('\%2x', ord($cntrl)) );
1552         if ($opts{-nohtml}) {
1553                 return $chr;
1554         } else {
1555                 return "<span class=\"cntrl\">$chr</span>";
1556         }
1557 }
1558
1559 # Alternatively use unicode control pictures codepoints,
1560 # Unicode "printable representation" (PR)
1561 sub quot_upr {
1562         my $cntrl = shift;
1563         my %opts = @_;
1564
1565         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1566         if ($opts{-nohtml}) {
1567                 return $chr;
1568         } else {
1569                 return "<span class=\"cntrl\">$chr</span>";
1570         }
1571 }
1572
1573 # git may return quoted and escaped filenames
1574 sub unquote {
1575         my $str = shift;
1576
1577         sub unq {
1578                 my $seq = shift;
1579                 my %es = ( # character escape codes, aka escape sequences
1580                         't' => "\t",   # tab            (HT, TAB)
1581                         'n' => "\n",   # newline        (NL)
1582                         'r' => "\r",   # return         (CR)
1583                         'f' => "\f",   # form feed      (FF)
1584                         'b' => "\b",   # backspace      (BS)
1585                         'a' => "\a",   # alarm (bell)   (BEL)
1586                         'e' => "\e",   # escape         (ESC)
1587                         'v' => "\013", # vertical tab   (VT)
1588                 );
1589
1590                 if ($seq =~ m/^[0-7]{1,3}$/) {
1591                         # octal char sequence
1592                         return chr(oct($seq));
1593                 } elsif (exists $es{$seq}) {
1594                         # C escape sequence, aka character escape code
1595                         return $es{$seq};
1596                 }
1597                 # quoted ordinary character
1598                 return $seq;
1599         }
1600
1601         if ($str =~ m/^"(.*)"$/) {
1602                 # needs unquoting
1603                 $str = $1;
1604                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1605         }
1606         return $str;
1607 }
1608
1609 # escape tabs (convert tabs to spaces)
1610 sub untabify {
1611         my $line = shift;
1612
1613         while ((my $pos = index($line, "\t")) != -1) {
1614                 if (my $count = (8 - ($pos % 8))) {
1615                         my $spaces = ' ' x $count;
1616                         $line =~ s/\t/$spaces/;
1617                 }
1618         }
1619
1620         return $line;
1621 }
1622
1623 sub project_in_list {
1624         my $project = shift;
1625         my @list = git_get_projects_list();
1626         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1627 }
1628
1629 ## ----------------------------------------------------------------------
1630 ## HTML aware string manipulation
1631
1632 # Try to chop given string on a word boundary between position
1633 # $len and $len+$add_len. If there is no word boundary there,
1634 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1635 # (marking chopped part) would be longer than given string.
1636 sub chop_str {
1637         my $str = shift;
1638         my $len = shift;
1639         my $add_len = shift || 10;
1640         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1641
1642         # Make sure perl knows it is utf8 encoded so we don't
1643         # cut in the middle of a utf8 multibyte char.
1644         $str = to_utf8($str);
1645
1646         # allow only $len chars, but don't cut a word if it would fit in $add_len
1647         # if it doesn't fit, cut it if it's still longer than the dots we would add
1648         # remove chopped character entities entirely
1649
1650         # when chopping in the middle, distribute $len into left and right part
1651         # return early if chopping wouldn't make string shorter
1652         if ($where eq 'center') {
1653                 return $str if ($len + 5 >= length($str)); # filler is length 5
1654                 $len = int($len/2);
1655         } else {
1656                 return $str if ($len + 4 >= length($str)); # filler is length 4
1657         }
1658
1659         # regexps: ending and beginning with word part up to $add_len
1660         my $endre = qr/.{$len}\w{0,$add_len}/;
1661         my $begre = qr/\w{0,$add_len}.{$len}/;
1662
1663         if ($where eq 'left') {
1664                 $str =~ m/^(.*?)($begre)$/;
1665                 my ($lead, $body) = ($1, $2);
1666                 if (length($lead) > 4) {
1667                         $lead = " ...";
1668                 }
1669                 return "$lead$body";
1670
1671         } elsif ($where eq 'center') {
1672                 $str =~ m/^($endre)(.*)$/;
1673                 my ($left, $str)  = ($1, $2);
1674                 $str =~ m/^(.*?)($begre)$/;
1675                 my ($mid, $right) = ($1, $2);
1676                 if (length($mid) > 5) {
1677                         $mid = " ... ";
1678                 }
1679                 return "$left$mid$right";
1680
1681         } else {
1682                 $str =~ m/^($endre)(.*)$/;
1683                 my $body = $1;
1684                 my $tail = $2;
1685                 if (length($tail) > 4) {
1686                         $tail = "... ";
1687                 }
1688                 return "$body$tail";
1689         }
1690 }
1691
1692 # takes the same arguments as chop_str, but also wraps a <span> around the
1693 # result with a title attribute if it does get chopped. Additionally, the
1694 # string is HTML-escaped.
1695 sub chop_and_escape_str {
1696         my ($str) = @_;
1697
1698         my $chopped = chop_str(@_);
1699         if ($chopped eq $str) {
1700                 return esc_html($chopped);
1701         } else {
1702                 $str =~ s/[[:cntrl:]]/?/g;
1703                 return $cgi->span({-title=>$str}, esc_html($chopped));
1704         }
1705 }
1706
1707 ## ----------------------------------------------------------------------
1708 ## functions returning short strings
1709
1710 # CSS class for given age value (in seconds)
1711 sub age_class {
1712         my $age = shift;
1713
1714         if (!defined $age) {
1715                 return "noage";
1716         } elsif ($age < 60*60*2) {
1717                 return "age0";
1718         } elsif ($age < 60*60*24*2) {
1719                 return "age1";
1720         } else {
1721                 return "age2";
1722         }
1723 }
1724
1725 # convert age in seconds to "nn units ago" string
1726 sub age_string {
1727         my $age = shift;
1728         my $age_str;
1729
1730         if ($age > 60*60*24*365*2) {
1731                 $age_str = (int $age/60/60/24/365);
1732                 $age_str .= " years ago";
1733         } elsif ($age > 60*60*24*(365/12)*2) {
1734                 $age_str = int $age/60/60/24/(365/12);
1735                 $age_str .= " months ago";
1736         } elsif ($age > 60*60*24*7*2) {
1737                 $age_str = int $age/60/60/24/7;
1738                 $age_str .= " weeks ago";
1739         } elsif ($age > 60*60*24*2) {
1740                 $age_str = int $age/60/60/24;
1741                 $age_str .= " days ago";
1742         } elsif ($age > 60*60*2) {
1743                 $age_str = int $age/60/60;
1744                 $age_str .= " hours ago";
1745         } elsif ($age > 60*2) {
1746                 $age_str = int $age/60;
1747                 $age_str .= " min ago";
1748         } elsif ($age > 2) {
1749                 $age_str = int $age;
1750                 $age_str .= " sec ago";
1751         } else {
1752                 $age_str .= " right now";
1753         }
1754         return $age_str;
1755 }
1756
1757 use constant {
1758         S_IFINVALID => 0030000,
1759         S_IFGITLINK => 0160000,
1760 };
1761
1762 # submodule/subproject, a commit object reference
1763 sub S_ISGITLINK {
1764         my $mode = shift;
1765
1766         return (($mode & S_IFMT) == S_IFGITLINK)
1767 }
1768
1769 # convert file mode in octal to symbolic file mode string
1770 sub mode_str {
1771         my $mode = oct shift;
1772
1773         if (S_ISGITLINK($mode)) {
1774                 return 'm---------';
1775         } elsif (S_ISDIR($mode & S_IFMT)) {
1776                 return 'drwxr-xr-x';
1777         } elsif (S_ISLNK($mode)) {
1778                 return 'lrwxrwxrwx';
1779         } elsif (S_ISREG($mode)) {
1780                 # git cares only about the executable bit
1781                 if ($mode & S_IXUSR) {
1782                         return '-rwxr-xr-x';
1783                 } else {
1784                         return '-rw-r--r--';
1785                 };
1786         } else {
1787                 return '----------';
1788         }
1789 }
1790
1791 # convert file mode in octal to file type string
1792 sub file_type {
1793         my $mode = shift;
1794
1795         if ($mode !~ m/^[0-7]+$/) {
1796                 return $mode;
1797         } else {
1798                 $mode = oct $mode;
1799         }
1800
1801         if (S_ISGITLINK($mode)) {
1802                 return "submodule";
1803         } elsif (S_ISDIR($mode & S_IFMT)) {
1804                 return "directory";
1805         } elsif (S_ISLNK($mode)) {
1806                 return "symlink";
1807         } elsif (S_ISREG($mode)) {
1808                 return "file";
1809         } else {
1810                 return "unknown";
1811         }
1812 }
1813
1814 # convert file mode in octal to file type description string
1815 sub file_type_long {
1816         my $mode = shift;
1817
1818         if ($mode !~ m/^[0-7]+$/) {
1819                 return $mode;
1820         } else {
1821                 $mode = oct $mode;
1822         }
1823
1824         if (S_ISGITLINK($mode)) {
1825                 return "submodule";
1826         } elsif (S_ISDIR($mode & S_IFMT)) {
1827                 return "directory";
1828         } elsif (S_ISLNK($mode)) {
1829                 return "symlink";
1830         } elsif (S_ISREG($mode)) {
1831                 if ($mode & S_IXUSR) {
1832                         return "executable";
1833                 } else {
1834                         return "file";
1835                 };
1836         } else {
1837                 return "unknown";
1838         }
1839 }
1840
1841
1842 ## ----------------------------------------------------------------------
1843 ## functions returning short HTML fragments, or transforming HTML fragments
1844 ## which don't belong to other sections
1845
1846 # format line of commit message.
1847 sub format_log_line_html {
1848         my $line = shift;
1849
1850         $line = esc_html($line, -nbsp=>1);
1851         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1852                 $cgi->a({-href => href(action=>"object", hash=>$1),
1853                                         -class => "text"}, $1);
1854         }eg;
1855
1856         return $line;
1857 }
1858
1859 # format marker of refs pointing to given object
1860
1861 # the destination action is chosen based on object type and current context:
1862 # - for annotated tags, we choose the tag view unless it's the current view
1863 #   already, in which case we go to shortlog view
1864 # - for other refs, we keep the current view if we're in history, shortlog or
1865 #   log view, and select shortlog otherwise
1866 sub format_ref_marker {
1867         my ($refs, $id) = @_;
1868         my $markers = '';
1869
1870         if (defined $refs->{$id}) {
1871                 foreach my $ref (@{$refs->{$id}}) {
1872                         # this code exploits the fact that non-lightweight tags are the
1873                         # only indirect objects, and that they are the only objects for which
1874                         # we want to use tag instead of shortlog as action
1875                         my ($type, $name) = qw();
1876                         my $indirect = ($ref =~ s/\^\{\}$//);
1877                         # e.g. tags/v2.6.11 or heads/next
1878                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1879                                 $type = $1;
1880                                 $name = $2;
1881                         } else {
1882                                 $type = "ref";
1883                                 $name = $ref;
1884                         }
1885
1886                         my $class = $type;
1887                         $class .= " indirect" if $indirect;
1888
1889                         my $dest_action = "shortlog";
1890
1891                         if ($indirect) {
1892                                 $dest_action = "tag" unless $action eq "tag";
1893                         } elsif ($action =~ /^(history|(short)?log)$/) {
1894                                 $dest_action = $action;
1895                         }
1896
1897                         my $dest = "";
1898                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1899                         $dest .= $ref;
1900
1901                         my $link = $cgi->a({
1902                                 -href => href(
1903                                         action=>$dest_action,
1904                                         hash=>$dest
1905                                 )}, $name);
1906
1907                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1908                                 $link . "</span>";
1909                 }
1910         }
1911
1912         if ($markers) {
1913                 return ' <span class="refs">'. $markers . '</span>';
1914         } else {
1915                 return "";
1916         }
1917 }
1918
1919 # format, perhaps shortened and with markers, title line
1920 sub format_subject_html {
1921         my ($long, $short, $href, $extra) = @_;
1922         $extra = '' unless defined($extra);
1923
1924         if (length($short) < length($long)) {
1925                 $long =~ s/[[:cntrl:]]/?/g;
1926                 return $cgi->a({-href => $href, -class => "list subject",
1927                                 -title => to_utf8($long)},
1928                        esc_html($short)) . $extra;
1929         } else {
1930                 return $cgi->a({-href => $href, -class => "list subject"},
1931                        esc_html($long)) . $extra;
1932         }
1933 }
1934
1935 # Rather than recomputing the url for an email multiple times, we cache it
1936 # after the first hit. This gives a visible benefit in views where the avatar
1937 # for the same email is used repeatedly (e.g. shortlog).
1938 # The cache is shared by all avatar engines (currently gravatar only), which
1939 # are free to use it as preferred. Since only one avatar engine is used for any
1940 # given page, there's no risk for cache conflicts.
1941 our %avatar_cache = ();
1942
1943 # Compute the picon url for a given email, by using the picon search service over at
1944 # http://www.cs.indiana.edu/picons/search.html
1945 sub picon_url {
1946         my $email = lc shift;
1947         if (!$avatar_cache{$email}) {
1948                 my ($user, $domain) = split('@', $email);
1949                 $avatar_cache{$email} =
1950                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1951                         "$domain/$user/" .
1952                         "users+domains+unknown/up/single";
1953         }
1954         return $avatar_cache{$email};
1955 }
1956
1957 # Compute the gravatar url for a given email, if it's not in the cache already.
1958 # Gravatar stores only the part of the URL before the size, since that's the
1959 # one computationally more expensive. This also allows reuse of the cache for
1960 # different sizes (for this particular engine).
1961 sub gravatar_url {
1962         my $email = lc shift;
1963         my $size = shift;
1964         $avatar_cache{$email} ||=
1965                 "http://www.gravatar.com/avatar/" .
1966                         Digest::MD5::md5_hex($email) . "?s=";
1967         return $avatar_cache{$email} . $size;
1968 }
1969
1970 # Insert an avatar for the given $email at the given $size if the feature
1971 # is enabled.
1972 sub git_get_avatar {
1973         my ($email, %opts) = @_;
1974         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1975         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1976         $opts{-size} ||= 'default';
1977         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1978         my $url = "";
1979         if ($git_avatar eq 'gravatar') {
1980                 $url = gravatar_url($email, $size);
1981         } elsif ($git_avatar eq 'picon') {
1982                 $url = picon_url($email);
1983         }
1984         # Other providers can be added by extending the if chain, defining $url
1985         # as needed. If no variant puts something in $url, we assume avatars
1986         # are completely disabled/unavailable.
1987         if ($url) {
1988                 return $pre_white .
1989                        "<img width=\"$size\" " .
1990                             "class=\"avatar\" " .
1991                             "src=\"".esc_url($url)."\" " .
1992                             "alt=\"\" " .
1993                        "/>" . $post_white;
1994         } else {
1995                 return "";
1996         }
1997 }
1998
1999 sub format_search_author {
2000         my ($author, $searchtype, $displaytext) = @_;
2001         my $have_search = gitweb_check_feature('search');
2002
2003         if ($have_search) {
2004                 my $performed = "";
2005                 if ($searchtype eq 'author') {
2006                         $performed = "authored";
2007                 } elsif ($searchtype eq 'committer') {
2008                         $performed = "committed";
2009                 }
2010
2011                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2012                                 searchtext=>$author,
2013                                 searchtype=>$searchtype), class=>"list",
2014                                 title=>"Search for commits $performed by $author"},
2015                                 $displaytext);
2016
2017         } else {
2018                 return $displaytext;
2019         }
2020 }
2021
2022 # format the author name of the given commit with the given tag
2023 # the author name is chopped and escaped according to the other
2024 # optional parameters (see chop_str).
2025 sub format_author_html {
2026         my $tag = shift;
2027         my $co = shift;
2028         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2029         return "<$tag class=\"author\">" .
2030                format_search_author($co->{'author_name'}, "author",
2031                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2032                        $author) .
2033                "</$tag>";
2034 }
2035
2036 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2037 sub format_git_diff_header_line {
2038         my $line = shift;
2039         my $diffinfo = shift;
2040         my ($from, $to) = @_;
2041
2042         if ($diffinfo->{'nparents'}) {
2043                 # combined diff
2044                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2045                 if ($to->{'href'}) {
2046                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2047                                          esc_path($to->{'file'}));
2048                 } else { # file was deleted (no href)
2049                         $line .= esc_path($to->{'file'});
2050                 }
2051         } else {
2052                 # "ordinary" diff
2053                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2054                 if ($from->{'href'}) {
2055                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2056                                          'a/' . esc_path($from->{'file'}));
2057                 } else { # file was added (no href)
2058                         $line .= 'a/' . esc_path($from->{'file'});
2059                 }
2060                 $line .= ' ';
2061                 if ($to->{'href'}) {
2062                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2063                                          'b/' . esc_path($to->{'file'}));
2064                 } else { # file was deleted
2065                         $line .= 'b/' . esc_path($to->{'file'});
2066                 }
2067         }
2068
2069         return "<div class=\"diff header\">$line</div>\n";
2070 }
2071
2072 # format extended diff header line, before patch itself
2073 sub format_extended_diff_header_line {
2074         my $line = shift;
2075         my $diffinfo = shift;
2076         my ($from, $to) = @_;
2077
2078         # match <path>
2079         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2080                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2081                                        esc_path($from->{'file'}));
2082         }
2083         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2084                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2085                                  esc_path($to->{'file'}));
2086         }
2087         # match single <mode>
2088         if ($line =~ m/\s(\d{6})$/) {
2089                 $line .= '<span class="info"> (' .
2090                          file_type_long($1) .
2091                          ')</span>';
2092         }
2093         # match <hash>
2094         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2095                 # can match only for combined diff
2096                 $line = 'index ';
2097                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2098                         if ($from->{'href'}[$i]) {
2099                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2100                                                   -class=>"hash"},
2101                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2102                         } else {
2103                                 $line .= '0' x 7;
2104                         }
2105                         # separator
2106                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2107                 }
2108                 $line .= '..';
2109                 if ($to->{'href'}) {
2110                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2111                                          substr($diffinfo->{'to_id'},0,7));
2112                 } else {
2113                         $line .= '0' x 7;
2114                 }
2115
2116         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2117                 # can match only for ordinary diff
2118                 my ($from_link, $to_link);
2119                 if ($from->{'href'}) {
2120                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2121                                              substr($diffinfo->{'from_id'},0,7));
2122                 } else {
2123                         $from_link = '0' x 7;
2124                 }
2125                 if ($to->{'href'}) {
2126                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2127                                            substr($diffinfo->{'to_id'},0,7));
2128                 } else {
2129                         $to_link = '0' x 7;
2130                 }
2131                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2132                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2133         }
2134
2135         return $line . "<br/>\n";
2136 }
2137
2138 # format from-file/to-file diff header
2139 sub format_diff_from_to_header {
2140         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2141         my $line;
2142         my $result = '';
2143
2144         $line = $from_line;
2145         #assert($line =~ m/^---/) if DEBUG;
2146         # no extra formatting for "^--- /dev/null"
2147         if (! $diffinfo->{'nparents'}) {
2148                 # ordinary (single parent) diff
2149                 if ($line =~ m!^--- "?a/!) {
2150                         if ($from->{'href'}) {
2151                                 $line = '--- a/' .
2152                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2153                                                 esc_path($from->{'file'}));
2154                         } else {
2155                                 $line = '--- a/' .
2156                                         esc_path($from->{'file'});
2157                         }
2158                 }
2159                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2160
2161         } else {
2162                 # combined diff (merge commit)
2163                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2164                         if ($from->{'href'}[$i]) {
2165                                 $line = '--- ' .
2166                                         $cgi->a({-href=>href(action=>"blobdiff",
2167                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2168                                                              hash_parent_base=>$parents[$i],
2169                                                              file_parent=>$from->{'file'}[$i],
2170                                                              hash=>$diffinfo->{'to_id'},
2171                                                              hash_base=>$hash,
2172                                                              file_name=>$to->{'file'}),
2173                                                  -class=>"path",
2174                                                  -title=>"diff" . ($i+1)},
2175                                                 $i+1) .
2176                                         '/' .
2177                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2178                                                 esc_path($from->{'file'}[$i]));
2179                         } else {
2180                                 $line = '--- /dev/null';
2181                         }
2182                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2183                 }
2184         }
2185
2186         $line = $to_line;
2187         #assert($line =~ m/^\+\+\+/) if DEBUG;
2188         # no extra formatting for "^+++ /dev/null"
2189         if ($line =~ m!^\+\+\+ "?b/!) {
2190                 if ($to->{'href'}) {
2191                         $line = '+++ b/' .
2192                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2193                                         esc_path($to->{'file'}));
2194                 } else {
2195                         $line = '+++ b/' .
2196                                 esc_path($to->{'file'});
2197                 }
2198         }
2199         $result .= qq!<div class="diff to_file">$line</div>\n!;
2200
2201         return $result;
2202 }
2203
2204 # create note for patch simplified by combined diff
2205 sub format_diff_cc_simplified {
2206         my ($diffinfo, @parents) = @_;
2207         my $result = '';
2208
2209         $result .= "<div class=\"diff header\">" .
2210                    "diff --cc ";
2211         if (!is_deleted($diffinfo)) {
2212                 $result .= $cgi->a({-href => href(action=>"blob",
2213                                                   hash_base=>$hash,
2214                                                   hash=>$diffinfo->{'to_id'},
2215                                                   file_name=>$diffinfo->{'to_file'}),
2216                                     -class => "path"},
2217                                    esc_path($diffinfo->{'to_file'}));
2218         } else {
2219                 $result .= esc_path($diffinfo->{'to_file'});
2220         }
2221         $result .= "</div>\n" . # class="diff header"
2222                    "<div class=\"diff nodifferences\">" .
2223                    "Simple merge" .
2224                    "</div>\n"; # class="diff nodifferences"
2225
2226         return $result;
2227 }
2228
2229 sub diff_line_class {
2230         my ($line, $from, $to) = @_;
2231
2232         # ordinary diff
2233         my $num_sign = 1;
2234         # combined diff
2235         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2236                 $num_sign = scalar @{$from->{'href'}};
2237         }
2238
2239         my @diff_line_classifier = (
2240                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2241                 { regexp => qr/^\\/,               class => "incomplete"  },
2242                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2243                 # classifier for context must come before classifier add/rem,
2244                 # or we would have to use more complicated regexp, for example
2245                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2246                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2247                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2248         );
2249         for my $clsfy (@diff_line_classifier) {
2250                 return $clsfy->{'class'}
2251                         if ($line =~ $clsfy->{'regexp'});
2252         }
2253
2254         # fallback
2255         return "";
2256 }
2257
2258 # format patch (diff) line (not to be used for diff headers)
2259 sub process_diff_line {
2260         my $line = shift;
2261         my ($from, $to) = @_;
2262
2263         my $diff_class = diff_line_class($line, $from, $to);
2264         my $diff_classes = "diff";
2265         $diff_classes .= " $diff_class" if ($diff_class);
2266
2267         chomp $line;
2268         $line = untabify($line);
2269
2270         if ($from && $to && $line =~ m/^\@{2} /) {
2271                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2272                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2273
2274                 $from_lines = 0 unless defined $from_lines;
2275                 $to_lines   = 0 unless defined $to_lines;
2276
2277                 if ($from->{'href'}) {
2278                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2279                                              -class=>"list"}, $from_text);
2280                 }
2281                 if ($to->{'href'}) {
2282                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2283                                              -class=>"list"}, $to_text);
2284                 }
2285                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2286                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2287                 return $diff_class, "<div class=\"$diff_classes\">$line</div>\n";
2288         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2289                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2290                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2291
2292                 @from_text = split(' ', $ranges);
2293                 for (my $i = 0; $i < @from_text; ++$i) {
2294                         ($from_start[$i], $from_nlines[$i]) =
2295                                 (split(',', substr($from_text[$i], 1)), 0);
2296                 }
2297
2298                 $to_text   = pop @from_text;
2299                 $to_start  = pop @from_start;
2300                 $to_nlines = pop @from_nlines;
2301
2302                 $line = "<span class=\"chunk_info\">$prefix ";
2303                 for (my $i = 0; $i < @from_text; ++$i) {
2304                         if ($from->{'href'}[$i]) {
2305                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2306                                                   -class=>"list"}, $from_text[$i]);
2307                         } else {
2308                                 $line .= $from_text[$i];
2309                         }
2310                         $line .= " ";
2311                 }
2312                 if ($to->{'href'}) {
2313                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2314                                           -class=>"list"}, $to_text);
2315                 } else {
2316                         $line .= $to_text;
2317                 }
2318                 $line .= " $prefix</span>" .
2319                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2320                 return $diff_class, "<div class=\"$diff_classes\">$line</div>\n";
2321         }
2322         return $diff_class, "<div class=\"$diff_classes\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2323 }
2324
2325 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2326 # linked.  Pass the hash of the tree/commit to snapshot.
2327 sub format_snapshot_links {
2328         my ($hash) = @_;
2329         my $num_fmts = @snapshot_fmts;
2330         if ($num_fmts > 1) {
2331                 # A parenthesized list of links bearing format names.
2332                 # e.g. "snapshot (_tar.gz_ _zip_)"
2333                 return "snapshot (" . join(' ', map
2334                         $cgi->a({
2335                                 -href => href(
2336                                         action=>"snapshot",
2337                                         hash=>$hash,
2338                                         snapshot_format=>$_
2339                                 )
2340                         }, $known_snapshot_formats{$_}{'display'})
2341                 , @snapshot_fmts) . ")";
2342         } elsif ($num_fmts == 1) {
2343                 # A single "snapshot" link whose tooltip bears the format name.
2344                 # i.e. "_snapshot_"
2345                 my ($fmt) = @snapshot_fmts;
2346                 return
2347                         $cgi->a({
2348                                 -href => href(
2349                                         action=>"snapshot",
2350                                         hash=>$hash,
2351                                         snapshot_format=>$fmt
2352                                 ),
2353                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2354                         }, "snapshot");
2355         } else { # $num_fmts == 0
2356                 return undef;
2357         }
2358 }
2359
2360 ## ......................................................................
2361 ## functions returning values to be passed, perhaps after some
2362 ## transformation, to other functions; e.g. returning arguments to href()
2363
2364 # returns hash to be passed to href to generate gitweb URL
2365 # in -title key it returns description of link
2366 sub get_feed_info {
2367         my $format = shift || 'Atom';
2368         my %res = (action => lc($format));
2369
2370         # feed links are possible only for project views
2371         return unless (defined $project);
2372         # some views should link to OPML, or to generic project feed,
2373         # or don't have specific feed yet (so they should use generic)
2374         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2375
2376         my $branch;
2377         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2378         # from tag links; this also makes possible to detect branch links
2379         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2380             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2381                 $branch = $1;
2382         }
2383         # find log type for feed description (title)
2384         my $type = 'log';
2385         if (defined $file_name) {
2386                 $type  = "history of $file_name";
2387                 $type .= "/" if ($action eq 'tree');
2388                 $type .= " on '$branch'" if (defined $branch);
2389         } else {
2390                 $type = "log of $branch" if (defined $branch);
2391         }
2392
2393         $res{-title} = $type;
2394         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2395         $res{'file_name'} = $file_name;
2396
2397         return %res;
2398 }
2399
2400 ## ----------------------------------------------------------------------
2401 ## git utility subroutines, invoking git commands
2402
2403 # returns path to the core git executable and the --git-dir parameter as list
2404 sub git_cmd {
2405         $number_of_git_cmds++;
2406         return $GIT, '--git-dir='.$git_dir;
2407 }
2408
2409 # quote the given arguments for passing them to the shell
2410 # quote_command("command", "arg 1", "arg with ' and ! characters")
2411 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2412 # Try to avoid using this function wherever possible.
2413 sub quote_command {
2414         return join(' ',
2415                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2416 }
2417
2418 # get HEAD ref of given project as hash
2419 sub git_get_head_hash {
2420         return git_get_full_hash(shift, 'HEAD');
2421 }
2422
2423 sub git_get_full_hash {
2424         return git_get_hash(@_);
2425 }
2426
2427 sub git_get_short_hash {
2428         return git_get_hash(@_, '--short=7');
2429 }
2430
2431 sub git_get_hash {
2432         my ($project, $hash, @options) = @_;
2433         my $o_git_dir = $git_dir;
2434         my $retval = undef;
2435         $git_dir = "$projectroot/$project";
2436         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2437             '--verify', '-q', @options, $hash) {
2438                 $retval = <$fd>;
2439                 chomp $retval if defined $retval;
2440                 close $fd;
2441         }
2442         if (defined $o_git_dir) {
2443                 $git_dir = $o_git_dir;
2444         }
2445         return $retval;
2446 }
2447
2448 # get type of given object
2449 sub git_get_type {
2450         my $hash = shift;
2451
2452         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2453         my $type = <$fd>;
2454         close $fd or return;
2455         chomp $type;
2456         return $type;
2457 }
2458
2459 # repository configuration
2460 our $config_file = '';
2461 our %config;
2462
2463 # store multiple values for single key as anonymous array reference
2464 # single values stored directly in the hash, not as [ <value> ]
2465 sub hash_set_multi {
2466         my ($hash, $key, $value) = @_;
2467
2468         if (!exists $hash->{$key}) {
2469                 $hash->{$key} = $value;
2470         } elsif (!ref $hash->{$key}) {
2471                 $hash->{$key} = [ $hash->{$key}, $value ];
2472         } else {
2473                 push @{$hash->{$key}}, $value;
2474         }
2475 }
2476
2477 # return hash of git project configuration
2478 # optionally limited to some section, e.g. 'gitweb'
2479 sub git_parse_project_config {
2480         my $section_regexp = shift;
2481         my %config;
2482
2483         local $/ = "\0";
2484
2485         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2486                 or return;
2487
2488         while (my $keyval = <$fh>) {
2489                 chomp $keyval;
2490                 my ($key, $value) = split(/\n/, $keyval, 2);
2491
2492                 hash_set_multi(\%config, $key, $value)
2493                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2494         }
2495         close $fh;
2496
2497         return %config;
2498 }
2499
2500 # convert config value to boolean: 'true' or 'false'
2501 # no value, number > 0, 'true' and 'yes' values are true
2502 # rest of values are treated as false (never as error)
2503 sub config_to_bool {
2504         my $val = shift;
2505
2506         return 1 if !defined $val;             # section.key
2507
2508         # strip leading and trailing whitespace
2509         $val =~ s/^\s+//;
2510         $val =~ s/\s+$//;
2511
2512         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2513                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2514 }
2515
2516 # convert config value to simple decimal number
2517 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2518 # to be multiplied by 1024, 1048576, or 1073741824
2519 sub config_to_int {
2520         my $val = shift;
2521
2522         # strip leading and trailing whitespace
2523         $val =~ s/^\s+//;
2524         $val =~ s/\s+$//;
2525
2526         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2527                 $unit = lc($unit);
2528                 # unknown unit is treated as 1
2529                 return $num * ($unit eq 'g' ? 1073741824 :
2530                                $unit eq 'm' ?    1048576 :
2531                                $unit eq 'k' ?       1024 : 1);
2532         }
2533         return $val;
2534 }
2535
2536 # convert config value to array reference, if needed
2537 sub config_to_multi {
2538         my $val = shift;
2539
2540         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2541 }
2542
2543 sub git_get_project_config {
2544         my ($key, $type) = @_;
2545
2546         return unless defined $git_dir;
2547
2548         # key sanity check
2549         return unless ($key);
2550         # only subsection, if exists, is case sensitive,
2551         # and not lowercased by 'git config -z -l'
2552         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2553                 $key = join(".", lc($hi), $mi, lc($lo));
2554         } else {
2555                 $key = lc($key);
2556         }
2557         $key =~ s/^gitweb\.//;
2558         return if ($key =~ m/\W/);
2559
2560         # type sanity check
2561         if (defined $type) {
2562                 $type =~ s/^--//;
2563                 $type = undef
2564                         unless ($type eq 'bool' || $type eq 'int');
2565         }
2566
2567         # get config
2568         if (!defined $config_file ||
2569             $config_file ne "$git_dir/config") {
2570                 %config = git_parse_project_config('gitweb');
2571                 $config_file = "$git_dir/config";
2572         }
2573
2574         # check if config variable (key) exists
2575         return unless exists $config{"gitweb.$key"};
2576
2577         # ensure given type
2578         if (!defined $type) {
2579                 return $config{"gitweb.$key"};
2580         } elsif ($type eq 'bool') {
2581                 # backward compatibility: 'git config --bool' returns true/false
2582                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2583         } elsif ($type eq 'int') {
2584                 return config_to_int($config{"gitweb.$key"});
2585         }
2586         return $config{"gitweb.$key"};
2587 }
2588
2589 # get hash of given path at given ref
2590 sub git_get_hash_by_path {
2591         my $base = shift;
2592         my $path = shift || return undef;
2593         my $type = shift;
2594
2595         $path =~ s,/+$,,;
2596
2597         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2598                 or die_error(500, "Open git-ls-tree failed");
2599         my $line = <$fd>;
2600         close $fd or return undef;
2601
2602         if (!defined $line) {
2603                 # there is no tree or hash given by $path at $base
2604                 return undef;
2605         }
2606
2607         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2608         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2609         if (defined $type && $type ne $2) {
2610                 # type doesn't match
2611                 return undef;
2612         }
2613         return $3;
2614 }
2615
2616 # get path of entry with given hash at given tree-ish (ref)
2617 # used to get 'from' filename for combined diff (merge commit) for renames
2618 sub git_get_path_by_hash {
2619         my $base = shift || return;
2620         my $hash = shift || return;
2621
2622         local $/ = "\0";
2623
2624         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2625                 or return undef;
2626         while (my $line = <$fd>) {
2627                 chomp $line;
2628
2629                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2630                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2631                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2632                         close $fd;
2633                         return $1;
2634                 }
2635         }
2636         close $fd;
2637         return undef;
2638 }
2639
2640 ## ......................................................................
2641 ## git utility functions, directly accessing git repository
2642
2643 # get the value of config variable either from file named as the variable
2644 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2645 # configuration variable in the repository config file.
2646 sub git_get_file_or_project_config {
2647         my ($path, $name) = @_;
2648
2649         $git_dir = "$projectroot/$path";
2650         open my $fd, '<', "$git_dir/$name"
2651                 or return git_get_project_config($name);
2652         my $conf = <$fd>;
2653         close $fd;
2654         if (defined $conf) {
2655                 chomp $conf;
2656         }
2657         return $conf;
2658 }
2659
2660 sub git_get_project_description {
2661         my $path = shift;
2662         return git_get_file_or_project_config($path, 'description');
2663 }
2664
2665 sub git_get_project_category {
2666         my $path = shift;
2667         return git_get_file_or_project_config($path, 'category');
2668 }
2669
2670
2671 # supported formats:
2672 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2673 #   - if its contents is a number, use it as tag weight,
2674 #   - otherwise add a tag with weight 1
2675 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2676 #   the same value multiple times increases tag weight
2677 # * `gitweb.ctag' multi-valued repo config variable
2678 sub git_get_project_ctags {
2679         my $project = shift;
2680         my $ctags = {};
2681
2682         $git_dir = "$projectroot/$project";
2683         if (opendir my $dh, "$git_dir/ctags") {
2684                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2685                 foreach my $tagfile (@files) {
2686                         open my $ct, '<', $tagfile
2687                                 or next;
2688                         my $val = <$ct>;
2689                         chomp $val if $val;
2690                         close $ct;
2691
2692                         (my $ctag = $tagfile) =~ s#.*/##;
2693                         if ($val =~ /^\d+$/) {
2694                                 $ctags->{$ctag} = $val;
2695                         } else {
2696                                 $ctags->{$ctag} = 1;
2697                         }
2698                 }
2699                 closedir $dh;
2700
2701         } elsif (open my $fh, '<', "$git_dir/ctags") {
2702                 while (my $line = <$fh>) {
2703                         chomp $line;
2704                         $ctags->{$line}++ if $line;
2705                 }
2706                 close $fh;
2707
2708         } else {
2709                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2710                 foreach my $tag (@$taglist) {
2711                         $ctags->{$tag}++;
2712                 }
2713         }
2714
2715         return $ctags;
2716 }
2717
2718 # return hash, where keys are content tags ('ctags'),
2719 # and values are sum of weights of given tag in every project
2720 sub git_gather_all_ctags {
2721         my $projects = shift;
2722         my $ctags = {};
2723
2724         foreach my $p (@$projects) {
2725                 foreach my $ct (keys %{$p->{'ctags'}}) {
2726                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2727                 }
2728         }
2729
2730         return $ctags;
2731 }
2732
2733 sub git_populate_project_tagcloud {
2734         my $ctags = shift;
2735
2736         # First, merge different-cased tags; tags vote on casing
2737         my %ctags_lc;
2738         foreach (keys %$ctags) {
2739                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2740                 if (not $ctags_lc{lc $_}->{topcount}
2741                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2742                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2743                         $ctags_lc{lc $_}->{topname} = $_;
2744                 }
2745         }
2746
2747         my $cloud;
2748         my $matched = $cgi->param('by_tag');
2749         if (eval { require HTML::TagCloud; 1; }) {
2750                 $cloud = HTML::TagCloud->new;
2751                 foreach my $ctag (sort keys %ctags_lc) {
2752                         # Pad the title with spaces so that the cloud looks
2753                         # less crammed.
2754                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2755                         $title =~ s/ /&nbsp;/g;
2756                         $title =~ s/^/&nbsp;/g;
2757                         $title =~ s/$/&nbsp;/g;
2758                         if (defined $matched && $matched eq $ctag) {
2759                                 $title = qq(<span class="match">$title</span>);
2760                         }
2761                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2762                                     $ctags_lc{$ctag}->{count});
2763                 }
2764         } else {
2765                 $cloud = {};
2766                 foreach my $ctag (keys %ctags_lc) {
2767                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2768                         if (defined $matched && $matched eq $ctag) {
2769                                 $title = qq(<span class="match">$title</span>);
2770                         }
2771                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2772                         $cloud->{$ctag}{ctag} =
2773                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2774                 }
2775         }
2776         return $cloud;
2777 }
2778
2779 sub git_show_project_tagcloud {
2780         my ($cloud, $count) = @_;
2781         if (ref $cloud eq 'HTML::TagCloud') {
2782                 return $cloud->html_and_css($count);
2783         } else {
2784                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2785                 return
2786                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2787                         join (', ', map {
2788                                 $cloud->{$_}->{'ctag'}
2789                         } splice(@tags, 0, $count)) .
2790                         '</div>';
2791         }
2792 }
2793
2794 sub git_get_project_url_list {
2795         my $path = shift;
2796
2797         $git_dir = "$projectroot/$path";
2798         open my $fd, '<', "$git_dir/cloneurl"
2799                 or return wantarray ?
2800                 @{ config_to_multi(git_get_project_config('url')) } :
2801                    config_to_multi(git_get_project_config('url'));
2802         my @git_project_url_list = map { chomp; $_ } <$fd>;
2803         close $fd;
2804
2805         return wantarray ? @git_project_url_list : \@git_project_url_list;
2806 }
2807
2808 sub git_get_projects_list {
2809         my $filter = shift || '';
2810         my @list;
2811
2812         $filter =~ s/\.git$//;
2813
2814         if (-d $projects_list) {
2815                 # search in directory
2816                 my $dir = $projects_list;
2817                 # remove the trailing "/"
2818                 $dir =~ s!/+$!!;
2819                 my $pfxlen = length("$projects_list");
2820                 my $pfxdepth = ($projects_list =~ tr!/!!);
2821                 # when filtering, search only given subdirectory
2822                 if ($filter) {
2823                         $dir .= "/$filter";
2824                         $dir =~ s!/+$!!;
2825                 }
2826
2827                 File::Find::find({
2828                         follow_fast => 1, # follow symbolic links
2829                         follow_skip => 2, # ignore duplicates
2830                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2831                         wanted => sub {
2832                                 # global variables
2833                                 our $project_maxdepth;
2834                                 our $projectroot;
2835                                 # skip project-list toplevel, if we get it.
2836                                 return if (m!^[/.]$!);
2837                                 # only directories can be git repositories
2838                                 return unless (-d $_);
2839                                 # don't traverse too deep (Find is super slow on os x)
2840                                 # $project_maxdepth excludes depth of $projectroot
2841                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2842                                         $File::Find::prune = 1;
2843                                         return;
2844                                 }
2845
2846                                 my $path = substr($File::Find::name, $pfxlen + 1);
2847                                 # we check related file in $projectroot
2848                                 if (check_export_ok("$projectroot/$path")) {
2849                                         push @list, { path => $path };
2850                                         $File::Find::prune = 1;
2851                                 }
2852                         },
2853                 }, "$dir");
2854
2855         } elsif (-f $projects_list) {
2856                 # read from file(url-encoded):
2857                 # 'git%2Fgit.git Linus+Torvalds'
2858                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2859                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2860                 open my $fd, '<', $projects_list or return;
2861         PROJECT:
2862                 while (my $line = <$fd>) {
2863                         chomp $line;
2864                         my ($path, $owner) = split ' ', $line;
2865                         $path = unescape($path);
2866                         $owner = unescape($owner);
2867                         if (!defined $path) {
2868                                 next;
2869                         }
2870                         # if $filter is rpovided, check if $path begins with $filter
2871                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2872                                 next;
2873                         }
2874                         if (check_export_ok("$projectroot/$path")) {
2875                                 my $pr = {
2876                                         path => $path,
2877                                         owner => to_utf8($owner),
2878                                 };
2879                                 push @list, $pr;
2880                         }
2881                 }
2882                 close $fd;
2883         }
2884         return @list;
2885 }
2886
2887 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2888 # as side effects it sets 'forks' field to list of forks for forked projects
2889 sub filter_forks_from_projects_list {
2890         my $projects = shift;
2891
2892         my %trie; # prefix tree of directories (path components)
2893         # generate trie out of those directories that might contain forks
2894         foreach my $pr (@$projects) {
2895                 my $path = $pr->{'path'};
2896                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2897                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2898                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2899                 next unless (-d $path);   # containing directory exists
2900                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2901
2902                 # add to trie
2903                 my @dirs = split('/', $path);
2904                 # walk the trie, until either runs out of components or out of trie
2905                 my $ref = \%trie;
2906                 while (scalar @dirs &&
2907                        exists($ref->{$dirs[0]})) {
2908                         $ref = $ref->{shift @dirs};
2909                 }
2910                 # create rest of trie structure from rest of components
2911                 foreach my $dir (@dirs) {
2912                         $ref = $ref->{$dir} = {};
2913                 }
2914                 # create end marker, store $pr as a data
2915                 $ref->{''} = $pr if (!exists $ref->{''});
2916         }
2917
2918         # filter out forks, by finding shortest prefix match for paths
2919         my @filtered;
2920  PROJECT:
2921         foreach my $pr (@$projects) {
2922                 # trie lookup
2923                 my $ref = \%trie;
2924         DIR:
2925                 foreach my $dir (split('/', $pr->{'path'})) {
2926                         if (exists $ref->{''}) {
2927                                 # found [shortest] prefix, is a fork - skip it
2928                                 push @{$ref->{''}{'forks'}}, $pr;
2929                                 next PROJECT;
2930                         }
2931                         if (!exists $ref->{$dir}) {
2932                                 # not in trie, cannot have prefix, not a fork
2933                                 push @filtered, $pr;
2934                                 next PROJECT;
2935                         }
2936                         # If the dir is there, we just walk one step down the trie.
2937                         $ref = $ref->{$dir};
2938                 }
2939                 # we ran out of trie
2940                 # (shouldn't happen: it's either no match, or end marker)
2941                 push @filtered, $pr;
2942         }
2943
2944         return @filtered;
2945 }
2946
2947 # note: fill_project_list_info must be run first,
2948 # for 'descr_long' and 'ctags' to be filled
2949 sub search_projects_list {
2950         my ($projlist, %opts) = @_;
2951         my $tagfilter  = $opts{'tagfilter'};
2952         my $searchtext = $opts{'searchtext'};
2953
2954         return @$projlist
2955                 unless ($tagfilter || $searchtext);
2956
2957         my @projects;
2958  PROJECT:
2959         foreach my $pr (@$projlist) {
2960
2961                 if ($tagfilter) {
2962                         next unless ref($pr->{'ctags'}) eq 'HASH';
2963                         next unless
2964                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
2965                 }
2966
2967                 if ($searchtext) {
2968                         next unless
2969                                 $pr->{'path'} =~ /$searchtext/ ||
2970                                 $pr->{'descr_long'} =~ /$searchtext/;
2971                 }
2972
2973                 push @projects, $pr;
2974         }
2975
2976         return @projects;
2977 }
2978
2979 our $gitweb_project_owner = undef;
2980 sub git_get_project_list_from_file {
2981
2982         return if (defined $gitweb_project_owner);
2983
2984         $gitweb_project_owner = {};
2985         # read from file (url-encoded):
2986         # 'git%2Fgit.git Linus+Torvalds'
2987         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2988         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2989         if (-f $projects_list) {
2990                 open(my $fd, '<', $projects_list);
2991                 while (my $line = <$fd>) {
2992                         chomp $line;
2993                         my ($pr, $ow) = split ' ', $line;
2994                         $pr = unescape($pr);
2995                         $ow = unescape($ow);
2996                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2997                 }
2998                 close $fd;
2999         }
3000 }
3001
3002 sub git_get_project_owner {
3003         my $project = shift;
3004         my $owner;
3005
3006         return undef unless $project;
3007         $git_dir = "$projectroot/$project";
3008
3009         if (!defined $gitweb_project_owner) {
3010                 git_get_project_list_from_file();
3011         }
3012
3013         if (exists $gitweb_project_owner->{$project}) {
3014                 $owner = $gitweb_project_owner->{$project};
3015         }
3016         if (!defined $owner){
3017                 $owner = git_get_project_config('owner');
3018         }
3019         if (!defined $owner) {
3020                 $owner = get_file_owner("$git_dir");
3021         }
3022
3023         return $owner;
3024 }
3025
3026 sub git_get_last_activity {
3027         my ($path) = @_;
3028         my $fd;
3029
3030         $git_dir = "$projectroot/$path";
3031         open($fd, "-|", git_cmd(), 'for-each-ref',
3032              '--format=%(committer)',
3033              '--sort=-committerdate',
3034              '--count=1',
3035              'refs/heads') or return;
3036         my $most_recent = <$fd>;
3037         close $fd or return;
3038         if (defined $most_recent &&
3039             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3040                 my $timestamp = $1;
3041                 my $age = time - $timestamp;
3042                 return ($age, age_string($age));
3043         }
3044         return (undef, undef);
3045 }
3046
3047 # Implementation note: when a single remote is wanted, we cannot use 'git
3048 # remote show -n' because that command always work (assuming it's a remote URL
3049 # if it's not defined), and we cannot use 'git remote show' because that would
3050 # try to make a network roundtrip. So the only way to find if that particular
3051 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3052 # and when we find what we want.
3053 sub git_get_remotes_list {
3054         my $wanted = shift;
3055         my %remotes = ();
3056
3057         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3058         return unless $fd;
3059         while (my $remote = <$fd>) {
3060                 chomp $remote;
3061                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3062                 next if $wanted and not $remote eq $wanted;
3063                 my ($url, $key) = ($1, $2);
3064
3065                 $remotes{$remote} ||= { 'heads' => () };
3066                 $remotes{$remote}{$key} = $url;
3067         }
3068         close $fd or return;
3069         return wantarray ? %remotes : \%remotes;
3070 }
3071
3072 # Takes a hash of remotes as first parameter and fills it by adding the
3073 # available remote heads for each of the indicated remotes.
3074 sub fill_remote_heads {
3075         my $remotes = shift;
3076         my @heads = map { "remotes/$_" } keys %$remotes;
3077         my @remoteheads = git_get_heads_list(undef, @heads);
3078         foreach my $remote (keys %$remotes) {
3079                 $remotes->{$remote}{'heads'} = [ grep {
3080                         $_->{'name'} =~ s!^$remote/!!
3081                         } @remoteheads ];
3082         }
3083 }
3084
3085 sub git_get_references {
3086         my $type = shift || "";
3087         my %refs;
3088         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3089         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3090         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3091                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3092                 or return;
3093
3094         while (my $line = <$fd>) {
3095                 chomp $line;
3096                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3097                         if (defined $refs{$1}) {
3098                                 push @{$refs{$1}}, $2;
3099                         } else {
3100                                 $refs{$1} = [ $2 ];
3101                         }
3102                 }
3103         }
3104         close $fd or return;
3105         return \%refs;
3106 }
3107
3108 sub git_get_rev_name_tags {
3109         my $hash = shift || return undef;
3110
3111         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3112                 or return;
3113         my $name_rev = <$fd>;
3114         close $fd;
3115
3116         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3117                 return $1;
3118         } else {
3119                 # catches also '$hash undefined' output
3120                 return undef;
3121         }
3122 }
3123
3124 ## ----------------------------------------------------------------------
3125 ## parse to hash functions
3126
3127 sub parse_date {
3128         my $epoch = shift;
3129         my $tz = shift || "-0000";
3130
3131         my %date;
3132         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3133         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3134         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3135         $date{'hour'} = $hour;
3136         $date{'minute'} = $min;
3137         $date{'mday'} = $mday;
3138         $date{'day'} = $days[$wday];
3139         $date{'month'} = $months[$mon];
3140         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3141                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3142         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3143                              $mday, $months[$mon], $hour ,$min;
3144         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3145                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3146
3147         my ($tz_sign, $tz_hour, $tz_min) =
3148                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3149         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3150         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3151         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3152         $date{'hour_local'} = $hour;
3153         $date{'minute_local'} = $min;
3154         $date{'tz_local'} = $tz;
3155         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3156                                   1900+$year, $mon+1, $mday,
3157                                   $hour, $min, $sec, $tz);
3158         return %date;
3159 }
3160
3161 sub parse_tag {
3162         my $tag_id = shift;
3163         my %tag;
3164         my @comment;
3165
3166         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3167         $tag{'id'} = $tag_id;
3168         while (my $line = <$fd>) {
3169                 chomp $line;
3170                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3171                         $tag{'object'} = $1;
3172                 } elsif ($line =~ m/^type (.+)$/) {
3173                         $tag{'type'} = $1;
3174                 } elsif ($line =~ m/^tag (.+)$/) {
3175                         $tag{'name'} = $1;
3176                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3177                         $tag{'author'} = $1;
3178                         $tag{'author_epoch'} = $2;
3179                         $tag{'author_tz'} = $3;
3180                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3181                                 $tag{'author_name'}  = $1;
3182                                 $tag{'author_email'} = $2;
3183                         } else {
3184                                 $tag{'author_name'} = $tag{'author'};
3185                         }
3186                 } elsif ($line =~ m/--BEGIN/) {
3187                         push @comment, $line;
3188                         last;
3189                 } elsif ($line eq "") {
3190                         last;
3191                 }
3192         }
3193         push @comment, <$fd>;
3194         $tag{'comment'} = \@comment;
3195         close $fd or return;
3196         if (!defined $tag{'name'}) {
3197                 return
3198         };
3199         return %tag
3200 }
3201
3202 sub parse_commit_text {
3203         my ($commit_text, $withparents) = @_;
3204         my @commit_lines = split '\n', $commit_text;
3205         my %co;
3206
3207         pop @commit_lines; # Remove '\0'
3208
3209         if (! @commit_lines) {
3210                 return;
3211         }
3212
3213         my $header = shift @commit_lines;
3214         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3215                 return;
3216         }
3217         ($co{'id'}, my @parents) = split ' ', $header;
3218         while (my $line = shift @commit_lines) {
3219                 last if $line eq "\n";
3220                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3221                         $co{'tree'} = $1;
3222                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3223                         push @parents, $1;
3224                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3225                         $co{'author'} = to_utf8($1);
3226                         $co{'author_epoch'} = $2;
3227                         $co{'author_tz'} = $3;
3228                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3229                                 $co{'author_name'}  = $1;
3230                                 $co{'author_email'} = $2;
3231                         } else {
3232                                 $co{'author_name'} = $co{'author'};
3233                         }
3234                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3235                         $co{'committer'} = to_utf8($1);
3236                         $co{'committer_epoch'} = $2;
3237                         $co{'committer_tz'} = $3;
3238                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3239                                 $co{'committer_name'}  = $1;
3240                                 $co{'committer_email'} = $2;
3241                         } else {
3242                                 $co{'committer_name'} = $co{'committer'};
3243                         }
3244                 }
3245         }
3246         if (!defined $co{'tree'}) {
3247                 return;
3248         };
3249         $co{'parents'} = \@parents;
3250         $co{'parent'} = $parents[0];
3251
3252         foreach my $title (@commit_lines) {
3253                 $title =~ s/^    //;
3254                 if ($title ne "") {
3255                         $co{'title'} = chop_str($title, 80, 5);
3256                         # remove leading stuff of merges to make the interesting part visible
3257                         if (length($title) > 50) {
3258                                 $title =~ s/^Automatic //;
3259                                 $title =~ s/^merge (of|with) /Merge ... /i;
3260                                 if (length($title) > 50) {
3261                                         $title =~ s/(http|rsync):\/\///;
3262                                 }
3263                                 if (length($title) > 50) {
3264                                         $title =~ s/(master|www|rsync)\.//;
3265                                 }
3266                                 if (length($title) > 50) {
3267                                         $title =~ s/kernel.org:?//;
3268                                 }
3269                                 if (length($title) > 50) {
3270                                         $title =~ s/\/pub\/scm//;
3271                                 }
3272                         }
3273                         $co{'title_short'} = chop_str($title, 50, 5);
3274                         last;
3275                 }
3276         }
3277         if (! defined $co{'title'} || $co{'title'} eq "") {
3278                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3279         }
3280         # remove added spaces
3281         foreach my $line (@commit_lines) {
3282                 $line =~ s/^    //;
3283         }
3284         $co{'comment'} = \@commit_lines;
3285
3286         my $age = time - $co{'committer_epoch'};
3287         $co{'age'} = $age;
3288         $co{'age_string'} = age_string($age);
3289         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3290         if ($age > 60*60*24*7*2) {
3291                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3292                 $co{'age_string_age'} = $co{'age_string'};
3293         } else {
3294                 $co{'age_string_date'} = $co{'age_string'};
3295                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3296         }
3297         return %co;
3298 }
3299
3300 sub parse_commit {
3301         my ($commit_id) = @_;
3302         my %co;
3303
3304         local $/ = "\0";
3305
3306         open my $fd, "-|", git_cmd(), "rev-list",
3307                 "--parents",
3308                 "--header",
3309                 "--max-count=1",
3310                 $commit_id,
3311                 "--",
3312                 or die_error(500, "Open git-rev-list failed");
3313         %co = parse_commit_text(<$fd>, 1);
3314         close $fd;
3315
3316         return %co;
3317 }
3318
3319 sub parse_commits {
3320         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3321         my @cos;
3322
3323         $maxcount ||= 1;
3324         $skip ||= 0;
3325
3326         local $/ = "\0";
3327
3328         open my $fd, "-|", git_cmd(), "rev-list",
3329                 "--header",
3330                 @args,
3331                 ("--max-count=" . $maxcount),
3332                 ("--skip=" . $skip),
3333                 @extra_options,
3334                 $commit_id,
3335                 "--",
3336                 ($filename ? ($filename) : ())
3337                 or die_error(500, "Open git-rev-list failed");
3338         while (my $line = <$fd>) {
3339                 my %co = parse_commit_text($line);
3340                 push @cos, \%co;
3341         }
3342         close $fd;
3343
3344         return wantarray ? @cos : \@cos;
3345 }
3346
3347 # parse line of git-diff-tree "raw" output
3348 sub parse_difftree_raw_line {
3349         my $line = shift;
3350         my %res;
3351
3352         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3353         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3354         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3355                 $res{'from_mode'} = $1;
3356                 $res{'to_mode'} = $2;
3357                 $res{'from_id'} = $3;
3358                 $res{'to_id'} = $4;
3359                 $res{'status'} = $5;
3360                 $res{'similarity'} = $6;
3361                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3362                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3363                 } else {
3364                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3365                 }
3366         }
3367         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3368         # combined diff (for merge commit)
3369         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3370                 $res{'nparents'}  = length($1);
3371                 $res{'from_mode'} = [ split(' ', $2) ];
3372                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3373                 $res{'from_id'} = [ split(' ', $3) ];
3374                 $res{'to_id'} = pop @{$res{'from_id'}};
3375                 $res{'status'} = [ split('', $4) ];
3376                 $res{'to_file'} = unquote($5);
3377         }
3378         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3379         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3380                 $res{'commit'} = $1;
3381         }
3382
3383         return wantarray ? %res : \%res;
3384 }
3385
3386 # wrapper: return parsed line of git-diff-tree "raw" output
3387 # (the argument might be raw line, or parsed info)
3388 sub parsed_difftree_line {
3389         my $line_or_ref = shift;
3390
3391         if (ref($line_or_ref) eq "HASH") {
3392                 # pre-parsed (or generated by hand)
3393                 return $line_or_ref;
3394         } else {
3395                 return parse_difftree_raw_line($line_or_ref);
3396         }
3397 }
3398
3399 # parse line of git-ls-tree output
3400 sub parse_ls_tree_line {
3401         my $line = shift;
3402         my %opts = @_;
3403         my %res;
3404
3405         if ($opts{'-l'}) {
3406                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3407                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3408
3409                 $res{'mode'} = $1;
3410                 $res{'type'} = $2;
3411                 $res{'hash'} = $3;
3412                 $res{'size'} = $4;
3413                 if ($opts{'-z'}) {
3414                         $res{'name'} = $5;
3415                 } else {
3416                         $res{'name'} = unquote($5);
3417                 }
3418         } else {
3419                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3420                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3421
3422                 $res{'mode'} = $1;
3423                 $res{'type'} = $2;
3424                 $res{'hash'} = $3;
3425                 if ($opts{'-z'}) {
3426                         $res{'name'} = $4;
3427                 } else {
3428                         $res{'name'} = unquote($4);
3429                 }
3430         }
3431
3432         return wantarray ? %res : \%res;
3433 }
3434
3435 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3436 sub parse_from_to_diffinfo {
3437         my ($diffinfo, $from, $to, @parents) = @_;
3438
3439         if ($diffinfo->{'nparents'}) {
3440                 # combined diff
3441                 $from->{'file'} = [];
3442                 $from->{'href'} = [];
3443                 fill_from_file_info($diffinfo, @parents)
3444                         unless exists $diffinfo->{'from_file'};
3445                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3446                         $from->{'file'}[$i] =
3447                                 defined $diffinfo->{'from_file'}[$i] ?
3448                                         $diffinfo->{'from_file'}[$i] :
3449                                         $diffinfo->{'to_file'};
3450                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3451                                 $from->{'href'}[$i] = href(action=>"blob",
3452                                                            hash_base=>$parents[$i],
3453                                                            hash=>$diffinfo->{'from_id'}[$i],
3454                                                            file_name=>$from->{'file'}[$i]);
3455                         } else {
3456                                 $from->{'href'}[$i] = undef;
3457                         }
3458                 }
3459         } else {
3460                 # ordinary (not combined) diff
3461                 $from->{'file'} = $diffinfo->{'from_file'};
3462                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3463                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3464                                                hash=>$diffinfo->{'from_id'},
3465                                                file_name=>$from->{'file'});
3466                 } else {
3467                         delete $from->{'href'};
3468                 }
3469         }
3470
3471         $to->{'file'} = $diffinfo->{'to_file'};
3472         if (!is_deleted($diffinfo)) { # file exists in result
3473                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3474                                      hash=>$diffinfo->{'to_id'},
3475                                      file_name=>$to->{'file'});
3476         } else {
3477                 delete $to->{'href'};
3478         }
3479 }
3480
3481 ## ......................................................................
3482 ## parse to array of hashes functions
3483
3484 sub git_get_heads_list {
3485         my ($limit, @classes) = @_;
3486         @classes = ('heads') unless @classes;
3487         my @patterns = map { "refs/$_" } @classes;
3488         my @headslist;
3489
3490         open my $fd, '-|', git_cmd(), 'for-each-ref',
3491                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3492                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3493                 @patterns
3494                 or return;
3495         while (my $line = <$fd>) {
3496                 my %ref_item;
3497
3498                 chomp $line;
3499                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3500                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3501                 my ($committer, $epoch, $tz) =
3502                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3503                 $ref_item{'fullname'}  = $name;
3504                 $name =~ s!^refs/(?:head|remote)s/!!;
3505
3506                 $ref_item{'name'}  = $name;
3507                 $ref_item{'id'}    = $hash;
3508                 $ref_item{'title'} = $title || '(no commit message)';
3509                 $ref_item{'epoch'} = $epoch;
3510                 if ($epoch) {
3511                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3512                 } else {
3513                         $ref_item{'age'} = "unknown";
3514                 }
3515
3516                 push @headslist, \%ref_item;
3517         }
3518         close $fd;
3519
3520         return wantarray ? @headslist : \@headslist;
3521 }
3522
3523 sub git_get_tags_list {
3524         my $limit = shift;
3525         my @tagslist;
3526
3527         open my $fd, '-|', git_cmd(), 'for-each-ref',
3528                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3529                 '--format=%(objectname) %(objecttype) %(refname) '.
3530                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3531                 'refs/tags'
3532                 or return;
3533         while (my $line = <$fd>) {
3534                 my %ref_item;
3535
3536                 chomp $line;
3537                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3538                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3539                 my ($creator, $epoch, $tz) =
3540                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3541                 $ref_item{'fullname'} = $name;
3542                 $name =~ s!^refs/tags/!!;
3543
3544                 $ref_item{'type'} = $type;
3545                 $ref_item{'id'} = $id;
3546                 $ref_item{'name'} = $name;
3547                 if ($type eq "tag") {
3548                         $ref_item{'subject'} = $title;
3549                         $ref_item{'reftype'} = $reftype;
3550                         $ref_item{'refid'}   = $refid;
3551                 } else {
3552                         $ref_item{'reftype'} = $type;
3553                         $ref_item{'refid'}   = $id;
3554                 }
3555
3556                 if ($type eq "tag" || $type eq "commit") {
3557                         $ref_item{'epoch'} = $epoch;
3558                         if ($epoch) {
3559                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3560                         } else {
3561                                 $ref_item{'age'} = "unknown";
3562                         }
3563                 }
3564
3565                 push @tagslist, \%ref_item;
3566         }
3567         close $fd;
3568
3569         return wantarray ? @tagslist : \@tagslist;
3570 }
3571
3572 ## ----------------------------------------------------------------------
3573 ## filesystem-related functions
3574
3575 sub get_file_owner {
3576         my $path = shift;
3577
3578         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3579         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3580         if (!defined $gcos) {
3581                 return undef;
3582         }
3583         my $owner = $gcos;
3584         $owner =~ s/[,;].*$//;
3585         return to_utf8($owner);
3586 }
3587
3588 # assume that file exists
3589 sub insert_file {
3590         my $filename = shift;
3591
3592         open my $fd, '<', $filename;
3593         print map { to_utf8($_) } <$fd>;
3594         close $fd;
3595 }
3596
3597 ## ......................................................................
3598 ## mimetype related functions
3599
3600 sub mimetype_guess_file {
3601         my $filename = shift;
3602         my $mimemap = shift;
3603         -r $mimemap or return undef;
3604
3605         my %mimemap;
3606         open(my $mh, '<', $mimemap) or return undef;
3607         while (<$mh>) {
3608                 next if m/^#/; # skip comments
3609                 my ($mimetype, @exts) = split(/\s+/);
3610                 foreach my $ext (@exts) {
3611                         $mimemap{$ext} = $mimetype;
3612                 }
3613         }
3614         close($mh);
3615
3616         $filename =~ /\.([^.]*)$/;
3617         return $mimemap{$1};
3618 }
3619
3620 sub mimetype_guess {
3621         my $filename = shift;
3622         my $mime;
3623         $filename =~ /\./ or return undef;
3624
3625         if ($mimetypes_file) {
3626                 my $file = $mimetypes_file;
3627                 if ($file !~ m!^/!) { # if it is relative path
3628                         # it is relative to project
3629                         $file = "$projectroot/$project/$file";
3630                 }
3631                 $mime = mimetype_guess_file($filename, $file);
3632         }
3633         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3634         return $mime;
3635 }
3636
3637 sub blob_mimetype {
3638         my $fd = shift;
3639         my $filename = shift;
3640
3641         if ($filename) {
3642                 my $mime = mimetype_guess($filename);
3643                 $mime and return $mime;
3644         }
3645
3646         # just in case
3647         return $default_blob_plain_mimetype unless $fd;
3648
3649         if (-T $fd) {
3650                 return 'text/plain';
3651         } elsif (! $filename) {
3652                 return 'application/octet-stream';
3653         } elsif ($filename =~ m/\.png$/i) {
3654                 return 'image/png';
3655         } elsif ($filename =~ m/\.gif$/i) {
3656                 return 'image/gif';
3657         } elsif ($filename =~ m/\.jpe?g$/i) {
3658                 return 'image/jpeg';
3659         } else {
3660                 return 'application/octet-stream';
3661         }
3662 }
3663
3664 sub blob_contenttype {
3665         my ($fd, $file_name, $type) = @_;
3666
3667         $type ||= blob_mimetype($fd, $file_name);
3668         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3669                 $type .= "; charset=$default_text_plain_charset";
3670         }
3671
3672         return $type;
3673 }
3674
3675 # guess file syntax for syntax highlighting; return undef if no highlighting
3676 # the name of syntax can (in the future) depend on syntax highlighter used
3677 sub guess_file_syntax {
3678         my ($highlight, $mimetype, $file_name) = @_;
3679         return undef unless ($highlight && defined $file_name);
3680         my $basename = basename($file_name, '.in');
3681         return $highlight_basename{$basename}
3682                 if exists $highlight_basename{$basename};
3683
3684         $basename =~ /\.([^.]*)$/;
3685         my $ext = $1 or return undef;
3686         return $highlight_ext{$ext}
3687                 if exists $highlight_ext{$ext};
3688
3689         return undef;
3690 }
3691
3692 # run highlighter and return FD of its output,
3693 # or return original FD if no highlighting
3694 sub run_highlighter {
3695         my ($fd, $highlight, $syntax) = @_;
3696         return $fd unless ($highlight && defined $syntax);
3697
3698         close $fd;
3699         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3700                   quote_command($highlight_bin).
3701                   " --replace-tabs=8 --fragment --syntax $syntax |"
3702                 or die_error(500, "Couldn't open file or run syntax highlighter");
3703         return $fd;
3704 }
3705
3706 ## ======================================================================
3707 ## functions printing HTML: header, footer, error page
3708
3709 sub get_page_title {
3710         my $title = to_utf8($site_name);
3711
3712         return $title unless (defined $project);
3713         $title .= " - " . to_utf8($project);
3714
3715         return $title unless (defined $action);
3716         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3717
3718         return $title unless (defined $file_name);
3719         $title .= " - " . esc_path($file_name);
3720         if ($action eq "tree" && $file_name !~ m|/$|) {
3721                 $title .= "/";
3722         }
3723
3724         return $title;
3725 }
3726
3727 sub get_content_type_html {
3728         # require explicit support from the UA if we are to send the page as
3729         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3730         # we have to do this because MSIE sometimes globs '*/*', pretending to
3731         # support xhtml+xml but choking when it gets what it asked for.
3732         if (defined $cgi->http('HTTP_ACCEPT') &&
3733             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3734             $cgi->Accept('application/xhtml+xml') != 0) {
3735                 return 'application/xhtml+xml';
3736         } else {
3737                 return 'text/html';
3738         }
3739 }
3740
3741 sub print_feed_meta {
3742         if (defined $project) {
3743                 my %href_params = get_feed_info();
3744                 if (!exists $href_params{'-title'}) {
3745                         $href_params{'-title'} = 'log';
3746                 }
3747
3748                 foreach my $format (qw(RSS Atom)) {
3749                         my $type = lc($format);
3750                         my %link_attr = (
3751                                 '-rel' => 'alternate',
3752                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3753                                 '-type' => "application/$type+xml"
3754                         );
3755
3756                         $href_params{'action'} = $type;
3757                         $link_attr{'-href'} = href(%href_params);
3758                         print "<link ".
3759                               "rel=\"$link_attr{'-rel'}\" ".
3760                               "title=\"$link_attr{'-title'}\" ".
3761                               "href=\"$link_attr{'-href'}\" ".
3762                               "type=\"$link_attr{'-type'}\" ".
3763                               "/>\n";
3764
3765                         $href_params{'extra_options'} = '--no-merges';
3766                         $link_attr{'-href'} = href(%href_params);
3767                         $link_attr{'-title'} .= ' (no merges)';
3768                         print "<link ".
3769                               "rel=\"$link_attr{'-rel'}\" ".
3770                               "title=\"$link_attr{'-title'}\" ".
3771                               "href=\"$link_attr{'-href'}\" ".
3772                               "type=\"$link_attr{'-type'}\" ".
3773                               "/>\n";
3774                 }
3775
3776         } else {
3777                 printf('<link rel="alternate" title="%s projects list" '.
3778                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3779                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3780                 printf('<link rel="alternate" title="%s projects feeds" '.
3781                        'href="%s" type="text/x-opml" />'."\n",
3782                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3783         }
3784 }
3785
3786 sub print_header_links {
3787         my $status = shift;
3788
3789         # print out each stylesheet that exist, providing backwards capability
3790         # for those people who defined $stylesheet in a config file
3791         if (defined $stylesheet) {
3792                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3793         } else {
3794                 foreach my $stylesheet (@stylesheets) {
3795                         next unless $stylesheet;
3796                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3797                 }
3798         }
3799         print_feed_meta()
3800                 if ($status eq '200 OK');
3801         if (defined $favicon) {
3802                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3803         }
3804 }
3805
3806 sub print_nav_breadcrumbs {
3807         my %opts = @_;
3808
3809         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3810         if (defined $project) {
3811                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3812                 if (defined $action) {
3813                         my $action_print = $action ;
3814                         if (defined $opts{-action_extra}) {
3815                                 $action_print = $cgi->a({-href => href(action=>$action)},
3816                                         $action);
3817                         }
3818                         print " / $action_print";
3819                 }
3820                 if (defined $opts{-action_extra}) {
3821                         print " / $opts{-action_extra}";
3822                 }
3823                 print "\n";
3824         }
3825 }
3826
3827 sub print_search_form {
3828         if (!defined $searchtext) {
3829                 $searchtext = "";
3830         }
3831         my $search_hash;
3832         if (defined $hash_base) {
3833                 $search_hash = $hash_base;
3834         } elsif (defined $hash) {
3835                 $search_hash = $hash;
3836         } else {
3837                 $search_hash = "HEAD";
3838         }
3839         my $action = $my_uri;
3840         my $use_pathinfo = gitweb_check_feature('pathinfo');
3841         if ($use_pathinfo) {
3842                 $action .= "/".esc_url($project);
3843         }
3844         print $cgi->startform(-method => "get", -action => $action) .
3845               "<div class=\"search\">\n" .
3846               (!$use_pathinfo &&
3847               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3848               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3849               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3850               $cgi->popup_menu(-name => 'st', -default => 'commit',
3851                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3852               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3853               " search:\n",
3854               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3855               "<span title=\"Extended regular expression\">" .
3856               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3857                              -checked => $search_use_regexp) .
3858               "</span>" .
3859               "</div>" .
3860               $cgi->end_form() . "\n";
3861 }
3862
3863 sub git_header_html {
3864         my $status = shift || "200 OK";
3865         my $expires = shift;
3866         my %opts = @_;
3867
3868         my $title = get_page_title();
3869         my $content_type = get_content_type_html();
3870         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3871                            -status=> $status, -expires => $expires)
3872                 unless ($opts{'-no_http_header'});
3873         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3874         print <<EOF;
3875 <?xml version="1.0" encoding="utf-8"?>
3876 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3877 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3878 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3879 <!-- git core binaries version $git_version -->
3880 <head>
3881 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3882 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3883 <meta name="robots" content="index, nofollow"/>
3884 <title>$title</title>
3885 EOF
3886         # the stylesheet, favicon etc urls won't work correctly with path_info
3887         # unless we set the appropriate base URL
3888         if ($ENV{'PATH_INFO'}) {
3889                 print "<base href=\"".esc_url($base_url)."\" />\n";
3890         }
3891         print_header_links($status);
3892         print "</head>\n" .
3893               "<body>\n";
3894
3895         if (defined $site_header && -f $site_header) {
3896                 insert_file($site_header);
3897         }
3898
3899         print "<div class=\"page_header\">\n";
3900         if (defined $logo) {
3901                 print $cgi->a({-href => esc_url($logo_url),
3902                                -title => $logo_label},
3903                               $cgi->img({-src => esc_url($logo),
3904                                          -width => 72, -height => 27,
3905                                          -alt => "git",
3906                                          -class => "logo"}));
3907         }
3908         print_nav_breadcrumbs(%opts);
3909         print "</div>\n";
3910
3911         my $have_search = gitweb_check_feature('search');
3912         if (defined $project && $have_search) {
3913                 print_search_form();
3914         }
3915 }
3916
3917 sub git_footer_html {
3918         my $feed_class = 'rss_logo';
3919
3920         print "<div class=\"page_footer\">\n";
3921         if (defined $project) {
3922                 my $descr = git_get_project_description($project);
3923                 if (defined $descr) {
3924                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3925                 }
3926
3927                 my %href_params = get_feed_info();
3928                 if (!%href_params) {
3929                         $feed_class .= ' generic';
3930                 }
3931                 $href_params{'-title'} ||= 'log';
3932
3933                 foreach my $format (qw(RSS Atom)) {
3934                         $href_params{'action'} = lc($format);
3935                         print $cgi->a({-href => href(%href_params),
3936                                       -title => "$href_params{'-title'} $format feed",
3937                                       -class => $feed_class}, $format)."\n";
3938                 }
3939
3940         } else {
3941                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3942                               -class => $feed_class}, "OPML") . " ";
3943                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3944                               -class => $feed_class}, "TXT") . "\n";
3945         }
3946         print "</div>\n"; # class="page_footer"
3947
3948         if (defined $t0 && gitweb_check_feature('timed')) {
3949                 print "<div id=\"generating_info\">\n";
3950                 print 'This page took '.
3951                       '<span id="generating_time" class="time_span">'.
3952                       tv_interval($t0, [ gettimeofday() ]).
3953                       ' seconds </span>'.
3954                       ' and '.
3955                       '<span id="generating_cmd">'.
3956                       $number_of_git_cmds.
3957                       '</span> git commands '.
3958                       " to generate.\n";
3959                 print "</div>\n"; # class="page_footer"
3960         }
3961
3962         if (defined $site_footer && -f $site_footer) {
3963                 insert_file($site_footer);
3964         }
3965
3966         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3967         if (defined $action &&
3968             $action eq 'blame_incremental') {
3969                 print qq!<script type="text/javascript">\n!.
3970                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3971                       qq!           "!. href() .qq!");\n!.
3972                       qq!</script>\n!;
3973         } else {
3974                 my ($jstimezone, $tz_cookie, $datetime_class) =
3975                         gitweb_get_feature('javascript-timezone');
3976
3977                 print qq!<script type="text/javascript">\n!.
3978                       qq!window.onload = function () {\n!;
3979                 if (gitweb_check_feature('javascript-actions')) {
3980                         print qq!       fixLinks();\n!;
3981                 }
3982                 if ($jstimezone && $tz_cookie && $datetime_class) {
3983                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
3984                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
3985                 }
3986                 print qq!};\n!.
3987                       qq!</script>\n!;
3988         }
3989
3990         print "</body>\n" .
3991               "</html>";
3992 }
3993
3994 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3995 # Example: die_error(404, 'Hash not found')
3996 # By convention, use the following status codes (as defined in RFC 2616):
3997 # 400: Invalid or missing CGI parameters, or
3998 #      requested object exists but has wrong type.
3999 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4000 #      this server or project.
4001 # 404: Requested object/revision/project doesn't exist.
4002 # 500: The server isn't configured properly, or
4003 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4004 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4005 # 503: The server is currently unavailable (because it is overloaded,
4006 #      or down for maintenance).  Generally, this is a temporary state.
4007 sub die_error {
4008         my $status = shift || 500;
4009         my $error = esc_html(shift) || "Internal Server Error";
4010         my $extra = shift;
4011         my %opts = @_;
4012
4013         my %http_responses = (
4014                 400 => '400 Bad Request',
4015                 403 => '403 Forbidden',
4016                 404 => '404 Not Found',
4017                 500 => '500 Internal Server Error',
4018                 503 => '503 Service Unavailable',
4019         );
4020         git_header_html($http_responses{$status}, undef, %opts);
4021         print <<EOF;
4022 <div class="page_body">
4023 <br /><br />
4024 $status - $error
4025 <br />
4026 EOF
4027         if (defined $extra) {
4028                 print "<hr />\n" .
4029                       "$extra\n";
4030         }
4031         print "</div>\n";
4032
4033         git_footer_html();
4034         goto DONE_GITWEB
4035                 unless ($opts{'-error_handler'});
4036 }
4037
4038 ## ----------------------------------------------------------------------
4039 ## functions printing or outputting HTML: navigation
4040
4041 sub git_print_page_nav {
4042         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4043         $extra = '' if !defined $extra; # pager or formats
4044
4045         my @navs = qw(summary shortlog log commit commitdiff tree);
4046         if ($suppress) {
4047                 @navs = grep { $_ ne $suppress } @navs;
4048         }
4049
4050         my %arg = map { $_ => {action=>$_} } @navs;
4051         if (defined $head) {
4052                 for (qw(commit commitdiff)) {
4053                         $arg{$_}{'hash'} = $head;
4054                 }
4055                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4056                         for (qw(shortlog log)) {
4057                                 $arg{$_}{'hash'} = $head;
4058                         }
4059                 }
4060         }
4061
4062         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4063         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4064
4065         my @actions = gitweb_get_feature('actions');
4066         my %repl = (
4067                 '%' => '%',
4068                 'n' => $project,         # project name
4069                 'f' => $git_dir,         # project path within filesystem
4070                 'h' => $treehead || '',  # current hash ('h' parameter)
4071                 'b' => $treebase || '',  # hash base ('hb' parameter)
4072         );
4073         while (@actions) {
4074                 my ($label, $link, $pos) = splice(@actions,0,3);
4075                 # insert
4076                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4077                 # munch munch
4078                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4079                 $arg{$label}{'_href'} = $link;
4080         }
4081
4082         print "<div class=\"page_nav\">\n" .
4083                 (join " | ",
4084                  map { $_ eq $current ?
4085                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4086                  } @navs);
4087         print "<br/>\n$extra<br/>\n" .
4088               "</div>\n";
4089 }
4090
4091 # returns a submenu for the nagivation of the refs views (tags, heads,
4092 # remotes) with the current view disabled and the remotes view only
4093 # available if the feature is enabled
4094 sub format_ref_views {
4095         my ($current) = @_;
4096         my @ref_views = qw{tags heads};
4097         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4098         return join " | ", map {
4099                 $_ eq $current ? $_ :
4100                 $cgi->a({-href => href(action=>$_)}, $_)
4101         } @ref_views
4102 }
4103
4104 sub format_paging_nav {
4105         my ($action, $page, $has_next_link) = @_;
4106         my $paging_nav;
4107
4108
4109         if ($page > 0) {
4110                 $paging_nav .=
4111                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4112                         " &sdot; " .
4113                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4114                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4115         } else {
4116                 $paging_nav .= "first &sdot; prev";
4117         }
4118
4119         if ($has_next_link) {
4120                 $paging_nav .= " &sdot; " .
4121                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4122                                  -accesskey => "n", -title => "Alt-n"}, "next");
4123         } else {
4124                 $paging_nav .= " &sdot; next";
4125         }
4126
4127         return $paging_nav;
4128 }
4129
4130 ## ......................................................................
4131 ## functions printing or outputting HTML: div
4132
4133 sub git_print_header_div {
4134         my ($action, $title, $hash, $hash_base) = @_;
4135         my %args = ();
4136
4137         $args{'action'} = $action;
4138         $args{'hash'} = $hash if $hash;
4139         $args{'hash_base'} = $hash_base if $hash_base;
4140
4141         print "<div class=\"header\">\n" .
4142               $cgi->a({-href => href(%args), -class => "title"},
4143               $title ? $title : $action) .
4144               "\n</div>\n";
4145 }
4146
4147 sub format_repo_url {
4148         my ($name, $url) = @_;
4149         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4150 }
4151
4152 # Group output by placing it in a DIV element and adding a header.
4153 # Options for start_div() can be provided by passing a hash reference as the
4154 # first parameter to the function.
4155 # Options to git_print_header_div() can be provided by passing an array
4156 # reference. This must follow the options to start_div if they are present.
4157 # The content can be a scalar, which is output as-is, a scalar reference, which
4158 # is output after html escaping, an IO handle passed either as *handle or
4159 # *handle{IO}, or a function reference. In the latter case all following
4160 # parameters will be taken as argument to the content function call.
4161 sub git_print_section {
4162         my ($div_args, $header_args, $content);
4163         my $arg = shift;
4164         if (ref($arg) eq 'HASH') {
4165                 $div_args = $arg;
4166                 $arg = shift;
4167         }
4168         if (ref($arg) eq 'ARRAY') {
4169                 $header_args = $arg;
4170                 $arg = shift;
4171         }
4172         $content = $arg;
4173
4174         print $cgi->start_div($div_args);
4175         git_print_header_div(@$header_args);
4176
4177         if (ref($content) eq 'CODE') {
4178                 $content->(@_);
4179         } elsif (ref($content) eq 'SCALAR') {
4180                 print esc_html($$content);
4181         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4182                 print <$content>;
4183         } elsif (!ref($content) && defined($content)) {
4184                 print $content;
4185         }
4186
4187         print $cgi->end_div;
4188 }
4189
4190 sub format_timestamp_html {
4191         my $date = shift;
4192         my $strtime = $date->{'rfc2822'};
4193
4194         my (undef, undef, $datetime_class) =
4195                 gitweb_get_feature('javascript-timezone');
4196         if ($datetime_class) {
4197                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4198         }
4199
4200         my $localtime_format = '(%02d:%02d %s)';
4201         if ($date->{'hour_local'} < 6) {
4202                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4203         }
4204         $strtime .= ' ' .
4205                     sprintf($localtime_format,
4206                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4207
4208         return $strtime;
4209 }
4210
4211 # Outputs the author name and date in long form
4212 sub git_print_authorship {
4213         my $co = shift;
4214         my %opts = @_;
4215         my $tag = $opts{-tag} || 'div';
4216         my $author = $co->{'author_name'};
4217
4218         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4219         print "<$tag class=\"author_date\">" .
4220               format_search_author($author, "author", esc_html($author)) .
4221               " [".format_timestamp_html(\%ad)."]".
4222               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4223               "</$tag>\n";
4224 }
4225
4226 # Outputs table rows containing the full author or committer information,
4227 # in the format expected for 'commit' view (& similar).
4228 # Parameters are a commit hash reference, followed by the list of people
4229 # to output information for. If the list is empty it defaults to both
4230 # author and committer.
4231 sub git_print_authorship_rows {
4232         my $co = shift;
4233         # too bad we can't use @people = @_ || ('author', 'committer')
4234         my @people = @_;
4235         @people = ('author', 'committer') unless @people;
4236         foreach my $who (@people) {
4237                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4238                 print "<tr><td>$who</td><td>" .
4239                       format_search_author($co->{"${who}_name"}, $who,
4240                                            esc_html($co->{"${who}_name"})) . " " .
4241                       format_search_author($co->{"${who}_email"}, $who,
4242                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4243                       "</td><td rowspan=\"2\">" .
4244                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4245                       "</td></tr>\n" .
4246                       "<tr>" .
4247                       "<td></td><td>" .
4248                       format_timestamp_html(\%wd) .
4249                       "</td>" .
4250                       "</tr>\n";
4251         }
4252 }
4253
4254 sub git_print_page_path {
4255         my $name = shift;
4256         my $type = shift;
4257         my $hb = shift;
4258
4259
4260         print "<div class=\"page_path\">";
4261         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4262                       -title => 'tree root'}, to_utf8("[$project]"));
4263         print " / ";
4264         if (defined $name) {
4265                 my @dirname = split '/', $name;
4266                 my $basename = pop @dirname;
4267                 my $fullname = '';
4268
4269                 foreach my $dir (@dirname) {
4270                         $fullname .= ($fullname ? '/' : '') . $dir;
4271                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4272                                                      hash_base=>$hb),
4273                                       -title => $fullname}, esc_path($dir));
4274                         print " / ";
4275                 }
4276                 if (defined $type && $type eq 'blob') {
4277                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4278                                                      hash_base=>$hb),
4279                                       -title => $name}, esc_path($basename));
4280                 } elsif (defined $type && $type eq 'tree') {
4281                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4282                                                      hash_base=>$hb),
4283                                       -title => $name}, esc_path($basename));
4284                         print " / ";
4285                 } else {
4286                         print esc_path($basename);
4287                 }
4288         }
4289         print "<br/></div>\n";
4290 }
4291
4292 sub git_print_log {
4293         my $log = shift;
4294         my %opts = @_;
4295
4296         if ($opts{'-remove_title'}) {
4297                 # remove title, i.e. first line of log
4298                 shift @$log;
4299         }
4300         # remove leading empty lines
4301         while (defined $log->[0] && $log->[0] eq "") {
4302                 shift @$log;
4303         }
4304
4305         # print log
4306         my $signoff = 0;
4307         my $empty = 0;
4308         foreach my $line (@$log) {
4309                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4310                         $signoff = 1;
4311                         $empty = 0;
4312                         if (! $opts{'-remove_signoff'}) {
4313                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4314                                 next;
4315                         } else {
4316                                 # remove signoff lines
4317                                 next;
4318                         }
4319                 } else {
4320                         $signoff = 0;
4321                 }
4322
4323                 # print only one empty line
4324                 # do not print empty line after signoff
4325                 if ($line eq "") {
4326                         next if ($empty || $signoff);
4327                         $empty = 1;
4328                 } else {
4329                         $empty = 0;
4330                 }
4331
4332                 print format_log_line_html($line) . "<br/>\n";
4333         }
4334
4335         if ($opts{'-final_empty_line'}) {
4336                 # end with single empty line
4337                 print "<br/>\n" unless $empty;
4338         }
4339 }
4340
4341 # return link target (what link points to)
4342 sub git_get_link_target {
4343         my $hash = shift;
4344         my $link_target;
4345
4346         # read link
4347         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4348                 or return;
4349         {
4350                 local $/ = undef;
4351                 $link_target = <$fd>;
4352         }
4353         close $fd
4354                 or return;
4355
4356         return $link_target;
4357 }
4358
4359 # given link target, and the directory (basedir) the link is in,
4360 # return target of link relative to top directory (top tree);
4361 # return undef if it is not possible (including absolute links).
4362 sub normalize_link_target {
4363         my ($link_target, $basedir) = @_;
4364
4365         # absolute symlinks (beginning with '/') cannot be normalized
4366         return if (substr($link_target, 0, 1) eq '/');
4367
4368         # normalize link target to path from top (root) tree (dir)
4369         my $path;
4370         if ($basedir) {
4371                 $path = $basedir . '/' . $link_target;
4372         } else {
4373                 # we are in top (root) tree (dir)
4374                 $path = $link_target;
4375         }
4376
4377         # remove //, /./, and /../
4378         my @path_parts;
4379         foreach my $part (split('/', $path)) {
4380                 # discard '.' and ''
4381                 next if (!$part || $part eq '.');
4382                 # handle '..'
4383                 if ($part eq '..') {
4384                         if (@path_parts) {
4385                                 pop @path_parts;
4386                         } else {
4387                                 # link leads outside repository (outside top dir)
4388                                 return;
4389                         }
4390                 } else {
4391                         push @path_parts, $part;
4392                 }
4393         }
4394         $path = join('/', @path_parts);
4395
4396         return $path;
4397 }
4398
4399 # print tree entry (row of git_tree), but without encompassing <tr> element
4400 sub git_print_tree_entry {
4401         my ($t, $basedir, $hash_base, $have_blame) = @_;
4402
4403         my %base_key = ();
4404         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4405
4406         # The format of a table row is: mode list link.  Where mode is
4407         # the mode of the entry, list is the name of the entry, an href,
4408         # and link is the action links of the entry.
4409
4410         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4411         if (exists $t->{'size'}) {
4412                 print "<td class=\"size\">$t->{'size'}</td>\n";
4413         }
4414         if ($t->{'type'} eq "blob") {
4415                 print "<td class=\"list\">" .
4416                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4417                                                file_name=>"$basedir$t->{'name'}", %base_key),
4418                                 -class => "list"}, esc_path($t->{'name'}));
4419                 if (S_ISLNK(oct $t->{'mode'})) {
4420                         my $link_target = git_get_link_target($t->{'hash'});
4421                         if ($link_target) {
4422                                 my $norm_target = normalize_link_target($link_target, $basedir);
4423                                 if (defined $norm_target) {
4424                                         print " -> " .
4425                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4426                                                                      file_name=>$norm_target),
4427                                                        -title => $norm_target}, esc_path($link_target));
4428                                 } else {
4429                                         print " -> " . esc_path($link_target);
4430                                 }
4431                         }
4432                 }
4433                 print "</td>\n";
4434                 print "<td class=\"link\">";
4435                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4436                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4437                               "blob");
4438                 if ($have_blame) {
4439                         print " | " .
4440                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4441                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4442                                       "blame");
4443                 }
4444                 if (defined $hash_base) {
4445                         print " | " .
4446                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4447                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4448                                       "history");
4449                 }
4450                 print " | " .
4451                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4452                                                file_name=>"$basedir$t->{'name'}")},
4453                                 "raw");
4454                 print "</td>\n";
4455
4456         } elsif ($t->{'type'} eq "tree") {
4457                 print "<td class=\"list\">";
4458                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4459                                              file_name=>"$basedir$t->{'name'}",
4460                                              %base_key)},
4461                               esc_path($t->{'name'}));
4462                 print "</td>\n";
4463                 print "<td class=\"link\">";
4464                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4465                                              file_name=>"$basedir$t->{'name'}",
4466                                              %base_key)},
4467                               "tree");
4468                 if (defined $hash_base) {
4469                         print " | " .
4470                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4471                                                      file_name=>"$basedir$t->{'name'}")},
4472                                       "history");
4473                 }
4474                 print "</td>\n";
4475         } else {
4476                 # unknown object: we can only present history for it
4477                 # (this includes 'commit' object, i.e. submodule support)
4478                 print "<td class=\"list\">" .
4479                       esc_path($t->{'name'}) .
4480                       "</td>\n";
4481                 print "<td class=\"link\">";
4482                 if (defined $hash_base) {
4483                         print $cgi->a({-href => href(action=>"history",
4484                                                      hash_base=>$hash_base,
4485                                                      file_name=>"$basedir$t->{'name'}")},
4486                                       "history");
4487                 }
4488                 print "</td>\n";
4489         }
4490 }
4491
4492 ## ......................................................................
4493 ## functions printing large fragments of HTML
4494
4495 # get pre-image filenames for merge (combined) diff
4496 sub fill_from_file_info {
4497         my ($diff, @parents) = @_;
4498
4499         $diff->{'from_file'} = [ ];
4500         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4501         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4502                 if ($diff->{'status'}[$i] eq 'R' ||
4503                     $diff->{'status'}[$i] eq 'C') {
4504                         $diff->{'from_file'}[$i] =
4505                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4506                 }
4507         }
4508
4509         return $diff;
4510 }
4511
4512 # is current raw difftree line of file deletion
4513 sub is_deleted {
4514         my $diffinfo = shift;
4515
4516         return $diffinfo->{'to_id'} eq ('0' x 40);
4517 }
4518
4519 # does patch correspond to [previous] difftree raw line
4520 # $diffinfo  - hashref of parsed raw diff format
4521 # $patchinfo - hashref of parsed patch diff format
4522 #              (the same keys as in $diffinfo)
4523 sub is_patch_split {
4524         my ($diffinfo, $patchinfo) = @_;
4525
4526         return defined $diffinfo && defined $patchinfo
4527                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4528 }
4529
4530
4531 sub git_difftree_body {
4532         my ($difftree, $hash, @parents) = @_;
4533         my ($parent) = $parents[0];
4534         my $have_blame = gitweb_check_feature('blame');
4535         print "<div class=\"list_head\">\n";
4536         if ($#{$difftree} > 10) {
4537                 print(($#{$difftree} + 1) . " files changed:\n");
4538         }
4539         print "</div>\n";
4540
4541         print "<table class=\"" .
4542               (@parents > 1 ? "combined " : "") .
4543               "diff_tree\">\n";
4544
4545         # header only for combined diff in 'commitdiff' view
4546         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4547         if ($has_header) {
4548                 # table header
4549                 print "<thead><tr>\n" .
4550                        "<th></th><th></th>\n"; # filename, patchN link
4551                 for (my $i = 0; $i < @parents; $i++) {
4552                         my $par = $parents[$i];
4553                         print "<th>" .
4554                               $cgi->a({-href => href(action=>"commitdiff",
4555                                                      hash=>$hash, hash_parent=>$par),
4556                                        -title => 'commitdiff to parent number ' .
4557                                                   ($i+1) . ': ' . substr($par,0,7)},
4558                                       $i+1) .
4559                               "&nbsp;</th>\n";
4560                 }
4561                 print "</tr></thead>\n<tbody>\n";
4562         }
4563
4564         my $alternate = 1;
4565         my $patchno = 0;
4566         foreach my $line (@{$difftree}) {
4567                 my $diff = parsed_difftree_line($line);
4568
4569                 if ($alternate) {
4570                         print "<tr class=\"dark\">\n";
4571                 } else {
4572                         print "<tr class=\"light\">\n";
4573                 }
4574                 $alternate ^= 1;
4575
4576                 if (exists $diff->{'nparents'}) { # combined diff
4577
4578                         fill_from_file_info($diff, @parents)
4579                                 unless exists $diff->{'from_file'};
4580
4581                         if (!is_deleted($diff)) {
4582                                 # file exists in the result (child) commit
4583                                 print "<td>" .
4584                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4585                                                              file_name=>$diff->{'to_file'},
4586                                                              hash_base=>$hash),
4587                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4588                                       "</td>\n";
4589                         } else {
4590                                 print "<td>" .
4591                                       esc_path($diff->{'to_file'}) .
4592                                       "</td>\n";
4593                         }
4594
4595                         if ($action eq 'commitdiff') {
4596                                 # link to patch
4597                                 $patchno++;
4598                                 print "<td class=\"link\">" .
4599                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4600                                               "patch") .
4601                                       " | " .
4602                                       "</td>\n";
4603                         }
4604
4605                         my $has_history = 0;
4606                         my $not_deleted = 0;
4607                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4608                                 my $hash_parent = $parents[$i];
4609                                 my $from_hash = $diff->{'from_id'}[$i];
4610                                 my $from_path = $diff->{'from_file'}[$i];
4611                                 my $status = $diff->{'status'}[$i];
4612
4613                                 $has_history ||= ($status ne 'A');
4614                                 $not_deleted ||= ($status ne 'D');
4615
4616                                 if ($status eq 'A') {
4617                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4618                                 } elsif ($status eq 'D') {
4619                                         print "<td class=\"link\">" .
4620                                               $cgi->a({-href => href(action=>"blob",
4621                                                                      hash_base=>$hash,
4622                                                                      hash=>$from_hash,
4623                                                                      file_name=>$from_path)},
4624                                                       "blob" . ($i+1)) .
4625                                               " | </td>\n";
4626                                 } else {
4627                                         if ($diff->{'to_id'} eq $from_hash) {
4628                                                 print "<td class=\"link nochange\">";
4629                                         } else {
4630                                                 print "<td class=\"link\">";
4631                                         }
4632                                         print $cgi->a({-href => href(action=>"blobdiff",
4633                                                                      hash=>$diff->{'to_id'},
4634                                                                      hash_parent=>$from_hash,
4635                                                                      hash_base=>$hash,
4636                                                                      hash_parent_base=>$hash_parent,
4637                                                                      file_name=>$diff->{'to_file'},
4638                                                                      file_parent=>$from_path)},
4639                                                       "diff" . ($i+1)) .
4640                                               " | </td>\n";
4641                                 }
4642                         }
4643
4644                         print "<td class=\"link\">";
4645                         if ($not_deleted) {
4646                                 print $cgi->a({-href => href(action=>"blob",
4647                                                              hash=>$diff->{'to_id'},
4648                                                              file_name=>$diff->{'to_file'},
4649                                                              hash_base=>$hash)},
4650                                               "blob");
4651                                 print " | " if ($has_history);
4652                         }
4653                         if ($has_history) {
4654                                 print $cgi->a({-href => href(action=>"history",
4655                                                              file_name=>$diff->{'to_file'},
4656                                                              hash_base=>$hash)},
4657                                               "history");
4658                         }
4659                         print "</td>\n";
4660
4661                         print "</tr>\n";
4662                         next; # instead of 'else' clause, to avoid extra indent
4663                 }
4664                 # else ordinary diff
4665
4666                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4667                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4668                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4669                         $to_mode_oct = oct $diff->{'to_mode'};
4670                         if (S_ISREG($to_mode_oct)) { # only for regular file
4671                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4672                         }
4673                         $to_file_type = file_type($diff->{'to_mode'});
4674                 }
4675                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4676                         $from_mode_oct = oct $diff->{'from_mode'};
4677                         if (S_ISREG($from_mode_oct)) { # only for regular file
4678                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4679                         }
4680                         $from_file_type = file_type($diff->{'from_mode'});
4681                 }
4682
4683                 if ($diff->{'status'} eq "A") { # created
4684                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4685                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4686                         $mode_chng   .= "]</span>";
4687                         print "<td>";
4688                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4689                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4690                                       -class => "list"}, esc_path($diff->{'file'}));
4691                         print "</td>\n";
4692                         print "<td>$mode_chng</td>\n";
4693                         print "<td class=\"link\">";
4694                         if ($action eq 'commitdiff') {
4695                                 # link to patch
4696                                 $patchno++;
4697                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4698                                               "patch") .
4699                                       " | ";
4700                         }
4701                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4702                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4703                                       "blob");
4704                         print "</td>\n";
4705
4706                 } elsif ($diff->{'status'} eq "D") { # deleted
4707                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4708                         print "<td>";
4709                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4710                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4711                                        -class => "list"}, esc_path($diff->{'file'}));
4712                         print "</td>\n";
4713                         print "<td>$mode_chng</td>\n";
4714                         print "<td class=\"link\">";
4715                         if ($action eq 'commitdiff') {
4716                                 # link to patch
4717                                 $patchno++;
4718                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4719                                               "patch") .
4720                                       " | ";
4721                         }
4722                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4723                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4724                                       "blob") . " | ";
4725                         if ($have_blame) {
4726                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4727                                                              file_name=>$diff->{'file'})},
4728                                               "blame") . " | ";
4729                         }
4730                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4731                                                      file_name=>$diff->{'file'})},
4732                                       "history");
4733                         print "</td>\n";
4734
4735                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4736                         my $mode_chnge = "";
4737                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4738                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4739                                 if ($from_file_type ne $to_file_type) {
4740                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4741                                 }
4742                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4743                                         if ($from_mode_str && $to_mode_str) {
4744                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4745                                         } elsif ($to_mode_str) {
4746                                                 $mode_chnge .= " mode: $to_mode_str";
4747                                         }
4748                                 }
4749                                 $mode_chnge .= "]</span>\n";
4750                         }
4751                         print "<td>";
4752                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4753                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4754                                       -class => "list"}, esc_path($diff->{'file'}));
4755                         print "</td>\n";
4756                         print "<td>$mode_chnge</td>\n";
4757                         print "<td class=\"link\">";
4758                         if ($action eq 'commitdiff') {
4759                                 # link to patch
4760                                 $patchno++;
4761                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4762                                               "patch") .
4763                                       " | ";
4764                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4765                                 # "commit" view and modified file (not onlu mode changed)
4766                                 print $cgi->a({-href => href(action=>"blobdiff",
4767                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4768                                                              hash_base=>$hash, hash_parent_base=>$parent,
4769                                                              file_name=>$diff->{'file'})},
4770                                               "diff") .
4771                                       " | ";
4772                         }
4773                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4774                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4775                                        "blob") . " | ";
4776                         if ($have_blame) {
4777                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4778                                                              file_name=>$diff->{'file'})},
4779                                               "blame") . " | ";
4780                         }
4781                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4782                                                      file_name=>$diff->{'file'})},
4783                                       "history");
4784                         print "</td>\n";
4785
4786                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4787                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4788                         my $nstatus = $status_name{$diff->{'status'}};
4789                         my $mode_chng = "";
4790                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4791                                 # mode also for directories, so we cannot use $to_mode_str
4792                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4793                         }
4794                         print "<td>" .
4795                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4796                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4797                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4798                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4799                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4800                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4801                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4802                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4803                               "<td class=\"link\">";
4804                         if ($action eq 'commitdiff') {
4805                                 # link to patch
4806                                 $patchno++;
4807                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4808                                               "patch") .
4809                                       " | ";
4810                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4811                                 # "commit" view and modified file (not only pure rename or copy)
4812                                 print $cgi->a({-href => href(action=>"blobdiff",
4813                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4814                                                              hash_base=>$hash, hash_parent_base=>$parent,
4815                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4816                                               "diff") .
4817                                       " | ";
4818                         }
4819                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4820                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4821                                       "blob") . " | ";
4822                         if ($have_blame) {
4823                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4824                                                              file_name=>$diff->{'to_file'})},
4825                                               "blame") . " | ";
4826                         }
4827                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4828                                                     file_name=>$diff->{'to_file'})},
4829                                       "history");
4830                         print "</td>\n";
4831
4832                 } # we should not encounter Unmerged (U) or Unknown (X) status
4833                 print "</tr>\n";
4834         }
4835         print "</tbody>" if $has_header;
4836         print "</table>\n";
4837 }
4838
4839 sub format_diff_chunk {
4840         my @chunk = @_;
4841
4842         my $first_class = $chunk[0]->[0];
4843         my @partial = map { $_->[1] } grep { $_->[0] eq $first_class } @chunk;
4844
4845         if (scalar @partial < scalar @chunk) {
4846                 return join '', ("<div class='chunk'><div class='old'>",
4847                              @partial,
4848                              "</div>",
4849                              "<div class='new'>",
4850                              (map {
4851                                  $_->[1];
4852                              } @chunk[scalar @partial..scalar @chunk-1]),
4853                              "</div></div>");
4854         } else {
4855                 return join '', ("<div class='chunk'><div class='",
4856                              ($first_class eq 'add' ? 'new' : 'old'),
4857                              "'>",
4858                              @partial,
4859                              "</div></div>");
4860         }
4861 }
4862
4863 sub git_patchset_body {
4864         my ($fd, $is_inline, $difftree, $hash, @hash_parents) = @_;
4865         my ($hash_parent) = $hash_parents[0];
4866
4867         my $is_combined = (@hash_parents > 1);
4868         my $patch_idx = 0;
4869         my $patch_number = 0;
4870         my $patch_line;
4871         my $diffinfo;
4872         my $to_name;
4873         my (%from, %to);
4874
4875         print "<div class=\"patchset\">\n";
4876
4877         # skip to first patch
4878         while ($patch_line = <$fd>) {
4879                 chomp $patch_line;
4880
4881                 last if ($patch_line =~ m/^diff /);
4882         }
4883
4884  PATCH:
4885         while ($patch_line) {
4886
4887                 # parse "git diff" header line
4888                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4889                         # $1 is from_name, which we do not use
4890                         $to_name = unquote($2);
4891                         $to_name =~ s!^b/!!;
4892                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4893                         # $1 is 'cc' or 'combined', which we do not use
4894                         $to_name = unquote($2);
4895                 } else {
4896                         $to_name = undef;
4897                 }
4898
4899                 # check if current patch belong to current raw line
4900                 # and parse raw git-diff line if needed
4901                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4902                         # this is continuation of a split patch
4903                         print "<div class=\"patch cont\">\n";
4904                 } else {
4905                         # advance raw git-diff output if needed
4906                         $patch_idx++ if defined $diffinfo;
4907
4908                         # read and prepare patch information
4909                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4910
4911                         # compact combined diff output can have some patches skipped
4912                         # find which patch (using pathname of result) we are at now;
4913                         if ($is_combined) {
4914                                 while ($to_name ne $diffinfo->{'to_file'}) {
4915                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4916                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4917                                               "</div>\n";  # class="patch"
4918
4919                                         $patch_idx++;
4920                                         $patch_number++;
4921
4922                                         last if $patch_idx > $#$difftree;
4923                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4924                                 }
4925                         }
4926
4927                         # modifies %from, %to hashes
4928                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4929
4930                         # this is first patch for raw difftree line with $patch_idx index
4931                         # we index @$difftree array from 0, but number patches from 1
4932                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4933                 }
4934
4935                 # git diff header
4936                 #assert($patch_line =~ m/^diff /) if DEBUG;
4937                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4938                 $patch_number++;
4939                 # print "git diff" header
4940                 print format_git_diff_header_line($patch_line, $diffinfo,
4941                                                   \%from, \%to);
4942
4943                 # print extended diff header
4944                 print "<div class=\"diff extended_header\">\n";
4945         EXTENDED_HEADER:
4946                 while ($patch_line = <$fd>) {
4947                         chomp $patch_line;
4948
4949                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4950
4951                         print format_extended_diff_header_line($patch_line, $diffinfo,
4952                                                                \%from, \%to);
4953                 }
4954                 print "</div>\n"; # class="diff extended_header"
4955
4956                 # from-file/to-file diff header
4957                 if (! $patch_line) {
4958                         print "</div>\n"; # class="patch"
4959                         last PATCH;
4960                 }
4961                 next PATCH if ($patch_line =~ m/^diff /);
4962                 #assert($patch_line =~ m/^---/) if DEBUG;
4963
4964                 my $last_patch_line = $patch_line;
4965                 $patch_line = <$fd>;
4966                 chomp $patch_line;
4967                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4968
4969                 print format_diff_from_to_header($last_patch_line, $patch_line,
4970                                                  $diffinfo, \%from, \%to,
4971                                                  @hash_parents);
4972
4973                 # the patch itself
4974         LINE:
4975                 my @chunk;
4976                 while ($patch_line = <$fd>) {
4977                         chomp $patch_line;
4978
4979                         next PATCH if ($patch_line =~ m/^diff /);
4980
4981                         my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
4982                         if ($is_inline) {
4983                                 print $line;
4984                         } elsif ($class eq 'add' || $class eq 'rem') {
4985                                 push @chunk, [ $class, $line ];
4986                         } else {
4987                                 if (@chunk) {
4988                                         print format_diff_chunk(@chunk);
4989                                         @chunk = ();
4990                                 } elsif ($class eq 'chunk_header') {
4991                                         print $line;
4992                                 } else {
4993                                         print '<div class="chunk"><div class="old">',
4994                                               $line,
4995                                               '</div><div class="new">',
4996                                               $line,
4997                                               '</div></div>';
4998                                 }
4999                         }
5000                 }
5001
5002         } continue {
5003                 print "</div>\n"; # class="patch"
5004         }
5005
5006         # for compact combined (--cc) format, with chunk and patch simplification
5007         # the patchset might be empty, but there might be unprocessed raw lines
5008         for (++$patch_idx if $patch_number > 0;
5009              $patch_idx < @$difftree;
5010              ++$patch_idx) {
5011                 # read and prepare patch information
5012                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5013
5014                 # generate anchor for "patch" links in difftree / whatchanged part
5015                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5016                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5017                       "</div>\n";  # class="patch"
5018
5019                 $patch_number++;
5020         }
5021
5022         if ($patch_number == 0) {
5023                 if (@hash_parents > 1) {
5024                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5025                 } else {
5026                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5027                 }
5028         }
5029
5030         print "</div>\n"; # class="patchset"
5031 }
5032
5033 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5034
5035 # fills project list info (age, description, owner, category, forks)
5036 # for each project in the list, removing invalid projects from
5037 # returned list
5038 # NOTE: modifies $projlist, but does not remove entries from it
5039 sub fill_project_list_info {
5040         my $projlist = shift;
5041         my @projects;
5042
5043         my $show_ctags = gitweb_check_feature('ctags');
5044  PROJECT:
5045         foreach my $pr (@$projlist) {
5046                 my (@activity) = git_get_last_activity($pr->{'path'});
5047                 unless (@activity) {
5048                         next PROJECT;
5049                 }
5050                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5051                 if (!defined $pr->{'descr'}) {
5052                         my $descr = git_get_project_description($pr->{'path'}) || "";
5053                         $descr = to_utf8($descr);
5054                         $pr->{'descr_long'} = $descr;
5055                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5056                 }
5057                 if (!defined $pr->{'owner'}) {
5058                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5059                 }
5060                 if ($show_ctags) {
5061                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5062                 }
5063                 if ($projects_list_group_categories && !defined $pr->{'category'}) {
5064                         my $cat = git_get_project_category($pr->{'path'}) ||
5065                                                            $project_list_default_category;
5066                         $pr->{'category'} = to_utf8($cat);
5067                 }
5068
5069                 push @projects, $pr;
5070         }
5071
5072         return @projects;
5073 }
5074
5075 sub sort_projects_list {
5076         my ($projlist, $order) = @_;
5077         my @projects;
5078
5079         my %order_info = (
5080                 project => { key => 'path', type => 'str' },
5081                 descr => { key => 'descr_long', type => 'str' },
5082                 owner => { key => 'owner', type => 'str' },
5083                 age => { key => 'age', type => 'num' }
5084         );
5085         my $oi = $order_info{$order};
5086         return @$projlist unless defined $oi;
5087         if ($oi->{'type'} eq 'str') {
5088                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5089         } else {
5090                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5091         }
5092
5093         return @projects;
5094 }
5095
5096 # returns a hash of categories, containing the list of project
5097 # belonging to each category
5098 sub build_projlist_by_category {
5099         my ($projlist, $from, $to) = @_;
5100         my %categories;
5101
5102         $from = 0 unless defined $from;
5103         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5104
5105         for (my $i = $from; $i <= $to; $i++) {
5106                 my $pr = $projlist->[$i];
5107                 push @{$categories{ $pr->{'category'} }}, $pr;
5108         }
5109
5110         return wantarray ? %categories : \%categories;
5111 }
5112
5113 # print 'sort by' <th> element, generating 'sort by $name' replay link
5114 # if that order is not selected
5115 sub print_sort_th {
5116         print format_sort_th(@_);
5117 }
5118
5119 sub format_sort_th {
5120         my ($name, $order, $header) = @_;
5121         my $sort_th = "";
5122         $header ||= ucfirst($name);
5123
5124         if ($order eq $name) {
5125                 $sort_th .= "<th>$header</th>\n";
5126         } else {
5127                 $sort_th .= "<th>" .
5128                             $cgi->a({-href => href(-replay=>1, order=>$name),
5129                                      -class => "header"}, $header) .
5130                             "</th>\n";
5131         }
5132
5133         return $sort_th;
5134 }
5135
5136 sub git_project_list_rows {
5137         my ($projlist, $from, $to, $check_forks) = @_;
5138
5139         $from = 0 unless defined $from;
5140         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5141
5142         my $alternate = 1;
5143         for (my $i = $from; $i <= $to; $i++) {
5144                 my $pr = $projlist->[$i];
5145
5146                 if ($alternate) {
5147                         print "<tr class=\"dark\">\n";
5148                 } else {
5149                         print "<tr class=\"light\">\n";
5150                 }
5151                 $alternate ^= 1;
5152
5153                 if ($check_forks) {
5154                         print "<td>";
5155                         if ($pr->{'forks'}) {
5156                                 my $nforks = scalar @{$pr->{'forks'}};
5157                                 if ($nforks > 0) {
5158                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5159                                                        -title => "$nforks forks"}, "+");
5160                                 } else {
5161                                         print $cgi->span({-title => "$nforks forks"}, "+");
5162                                 }
5163                         }
5164                         print "</td>\n";
5165                 }
5166                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5167                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5168                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5169                                         -class => "list", -title => $pr->{'descr_long'}},
5170                                         esc_html($pr->{'descr'})) . "</td>\n" .
5171                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5172                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5173                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5174                       "<td class=\"link\">" .
5175                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5176                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5177                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5178                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5179                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5180                       "</td>\n" .
5181                       "</tr>\n";
5182         }
5183 }
5184
5185 sub git_project_list_body {
5186         # actually uses global variable $project
5187         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5188         my @projects = @$projlist;
5189
5190         my $check_forks = gitweb_check_feature('forks');
5191         my $show_ctags  = gitweb_check_feature('ctags');
5192         my $tagfilter = $show_ctags ? $cgi->param('by_tag') : undef;
5193         $check_forks = undef
5194                 if ($tagfilter || $searchtext);
5195
5196         # filtering out forks before filling info allows to do less work
5197         @projects = filter_forks_from_projects_list(\@projects)
5198                 if ($check_forks);
5199         @projects = fill_project_list_info(\@projects);
5200         # searching projects require filling to be run before it
5201         @projects = search_projects_list(\@projects,
5202                                          'searchtext' => $searchtext,
5203                                          'tagfilter'  => $tagfilter)
5204                 if ($tagfilter || $searchtext);
5205
5206         $order ||= $default_projects_order;
5207         $from = 0 unless defined $from;
5208         $to = $#projects if (!defined $to || $#projects < $to);
5209
5210         # short circuit
5211         if ($from > $to) {
5212                 print "<center>\n".
5213                       "<b>No such projects found</b><br />\n".
5214                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5215                       "</center>\n<br />\n";
5216                 return;
5217         }
5218
5219         @projects = sort_projects_list(\@projects, $order);
5220
5221         if ($show_ctags) {
5222                 my $ctags = git_gather_all_ctags(\@projects);
5223                 my $cloud = git_populate_project_tagcloud($ctags);
5224                 print git_show_project_tagcloud($cloud, 64);
5225         }
5226
5227         print "<table class=\"project_list\">\n";
5228         unless ($no_header) {
5229                 print "<tr>\n";
5230                 if ($check_forks) {
5231                         print "<th></th>\n";
5232                 }
5233                 print_sort_th('project', $order, 'Project');
5234                 print_sort_th('descr', $order, 'Description');
5235                 print_sort_th('owner', $order, 'Owner');
5236                 print_sort_th('age', $order, 'Last Change');
5237                 print "<th></th>\n" . # for links
5238                       "</tr>\n";
5239         }
5240
5241         if ($projects_list_group_categories) {
5242                 # only display categories with projects in the $from-$to window
5243                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5244                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5245                 foreach my $cat (sort keys %categories) {
5246                         unless ($cat eq "") {
5247                                 print "<tr>\n";
5248                                 if ($check_forks) {
5249                                         print "<td></td>\n";
5250                                 }
5251                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5252                                 print "</tr>\n";
5253                         }
5254
5255                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5256                 }
5257         } else {
5258                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5259         }
5260
5261         if (defined $extra) {
5262                 print "<tr>\n";
5263                 if ($check_forks) {
5264                         print "<td></td>\n";
5265                 }
5266                 print "<td colspan=\"5\">$extra</td>\n" .
5267                       "</tr>\n";
5268         }
5269         print "</table>\n";
5270 }
5271
5272 sub git_log_body {
5273         # uses global variable $project
5274         my ($commitlist, $from, $to, $refs, $extra) = @_;
5275
5276         $from = 0 unless defined $from;
5277         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5278
5279         for (my $i = 0; $i <= $to; $i++) {
5280                 my %co = %{$commitlist->[$i]};
5281                 next if !%co;
5282                 my $commit = $co{'id'};
5283                 my $ref = format_ref_marker($refs, $commit);
5284                 git_print_header_div('commit',
5285                                "<span class=\"age\">$co{'age_string'}</span>" .
5286                                esc_html($co{'title'}) . $ref,
5287                                $commit);
5288                 print "<div class=\"title_text\">\n" .
5289                       "<div class=\"log_link\">\n" .
5290                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5291                       " | " .
5292                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5293                       " | " .
5294                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5295                       "<br/>\n" .
5296                       "</div>\n";
5297                       git_print_authorship(\%co, -tag => 'span');
5298                       print "<br/>\n</div>\n";
5299
5300                 print "<div class=\"log_body\">\n";
5301                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5302                 print "</div>\n";
5303         }
5304         if ($extra) {
5305                 print "<div class=\"page_nav\">\n";
5306                 print "$extra\n";
5307                 print "</div>\n";
5308         }
5309 }
5310
5311 sub git_shortlog_body {
5312         # uses global variable $project
5313         my ($commitlist, $from, $to, $refs, $extra) = @_;
5314
5315         $from = 0 unless defined $from;
5316         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5317
5318         print "<table class=\"shortlog\">\n";
5319         my $alternate = 1;
5320         for (my $i = $from; $i <= $to; $i++) {
5321                 my %co = %{$commitlist->[$i]};
5322                 my $commit = $co{'id'};
5323                 my $ref = format_ref_marker($refs, $commit);
5324                 if ($alternate) {
5325                         print "<tr class=\"dark\">\n";
5326                 } else {
5327                         print "<tr class=\"light\">\n";
5328                 }
5329                 $alternate ^= 1;
5330                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5331                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5332                       format_author_html('td', \%co, 10) . "<td>";
5333                 print format_subject_html($co{'title'}, $co{'title_short'},
5334                                           href(action=>"commit", hash=>$commit), $ref);
5335                 print "</td>\n" .
5336                       "<td class=\"link\">" .
5337                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5338                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5339                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5340                 my $snapshot_links = format_snapshot_links($commit);
5341                 if (defined $snapshot_links) {
5342                         print " | " . $snapshot_links;
5343                 }
5344                 print "</td>\n" .
5345                       "</tr>\n";
5346         }
5347         if (defined $extra) {
5348                 print "<tr>\n" .
5349                       "<td colspan=\"4\">$extra</td>\n" .
5350                       "</tr>\n";
5351         }
5352         print "</table>\n";
5353 }
5354
5355 sub git_history_body {
5356         # Warning: assumes constant type (blob or tree) during history
5357         my ($commitlist, $from, $to, $refs, $extra,
5358             $file_name, $file_hash, $ftype) = @_;
5359
5360         $from = 0 unless defined $from;
5361         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5362
5363         print "<table class=\"history\">\n";
5364         my $alternate = 1;
5365         for (my $i = $from; $i <= $to; $i++) {
5366                 my %co = %{$commitlist->[$i]};
5367                 if (!%co) {
5368                         next;
5369                 }
5370                 my $commit = $co{'id'};
5371
5372                 my $ref = format_ref_marker($refs, $commit);
5373
5374                 if ($alternate) {
5375                         print "<tr class=\"dark\">\n";
5376                 } else {
5377                         print "<tr class=\"light\">\n";
5378                 }
5379                 $alternate ^= 1;
5380                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5381         # shortlog:   format_author_html('td', \%co, 10)
5382                       format_author_html('td', \%co, 15, 3) . "<td>";
5383                 # originally git_history used chop_str($co{'title'}, 50)
5384                 print format_subject_html($co{'title'}, $co{'title_short'},
5385                                           href(action=>"commit", hash=>$commit), $ref);
5386                 print "</td>\n" .
5387                       "<td class=\"link\">" .
5388                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5389                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5390
5391                 if ($ftype eq 'blob') {
5392                         my $blob_current = $file_hash;
5393                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5394                         if (defined $blob_current && defined $blob_parent &&
5395                                         $blob_current ne $blob_parent) {
5396                                 print " | " .
5397                                         $cgi->a({-href => href(action=>"blobdiff",
5398                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5399                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5400                                                                file_name=>$file_name)},
5401                                                 "diff to current");
5402                         }
5403                 }
5404                 print "</td>\n" .
5405                       "</tr>\n";
5406         }
5407         if (defined $extra) {
5408                 print "<tr>\n" .
5409                       "<td colspan=\"4\">$extra</td>\n" .
5410                       "</tr>\n";
5411         }
5412         print "</table>\n";
5413 }
5414
5415 sub git_tags_body {
5416         # uses global variable $project
5417         my ($taglist, $from, $to, $extra) = @_;
5418         $from = 0 unless defined $from;
5419         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5420
5421         print "<table class=\"tags\">\n";
5422         my $alternate = 1;
5423         for (my $i = $from; $i <= $to; $i++) {
5424                 my $entry = $taglist->[$i];
5425                 my %tag = %$entry;
5426                 my $comment = $tag{'subject'};
5427                 my $comment_short;
5428                 if (defined $comment) {
5429                         $comment_short = chop_str($comment, 30, 5);
5430                 }
5431                 if ($alternate) {
5432                         print "<tr class=\"dark\">\n";
5433                 } else {
5434                         print "<tr class=\"light\">\n";
5435                 }
5436                 $alternate ^= 1;
5437                 if (defined $tag{'age'}) {
5438                         print "<td><i>$tag{'age'}</i></td>\n";
5439                 } else {
5440                         print "<td></td>\n";
5441                 }
5442                 print "<td>" .
5443                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5444                                -class => "list name"}, esc_html($tag{'name'})) .
5445                       "</td>\n" .
5446                       "<td>";
5447                 if (defined $comment) {
5448                         print format_subject_html($comment, $comment_short,
5449                                                   href(action=>"tag", hash=>$tag{'id'}));
5450                 }
5451                 print "</td>\n" .
5452                       "<td class=\"selflink\">";
5453                 if ($tag{'type'} eq "tag") {
5454                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5455                 } else {
5456                         print "&nbsp;";
5457                 }
5458                 print "</td>\n" .
5459                       "<td class=\"link\">" . " | " .
5460                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5461                 if ($tag{'reftype'} eq "commit") {
5462                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5463                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5464                 } elsif ($tag{'reftype'} eq "blob") {
5465                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5466                 }
5467                 print "</td>\n" .
5468                       "</tr>";
5469         }
5470         if (defined $extra) {
5471                 print "<tr>\n" .
5472                       "<td colspan=\"5\">$extra</td>\n" .
5473                       "</tr>\n";
5474         }
5475         print "</table>\n";
5476 }
5477
5478 sub git_heads_body {
5479         # uses global variable $project
5480         my ($headlist, $head, $from, $to, $extra) = @_;
5481         $from = 0 unless defined $from;
5482         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5483
5484         print "<table class=\"heads\">\n";
5485         my $alternate = 1;
5486         for (my $i = $from; $i <= $to; $i++) {
5487                 my $entry = $headlist->[$i];
5488                 my %ref = %$entry;
5489                 my $curr = $ref{'id'} eq $head;
5490                 if ($alternate) {
5491                         print "<tr class=\"dark\">\n";
5492                 } else {
5493                         print "<tr class=\"light\">\n";
5494                 }
5495                 $alternate ^= 1;
5496                 print "<td><i>$ref{'age'}</i></td>\n" .
5497                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5498                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5499                                -class => "list name"},esc_html($ref{'name'})) .
5500                       "</td>\n" .
5501                       "<td class=\"link\">" .
5502                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5503                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5504                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5505                       "</td>\n" .
5506                       "</tr>";
5507         }
5508         if (defined $extra) {
5509                 print "<tr>\n" .
5510                       "<td colspan=\"3\">$extra</td>\n" .
5511                       "</tr>\n";
5512         }
5513         print "</table>\n";
5514 }
5515
5516 # Display a single remote block
5517 sub git_remote_block {
5518         my ($remote, $rdata, $limit, $head) = @_;
5519
5520         my $heads = $rdata->{'heads'};
5521         my $fetch = $rdata->{'fetch'};
5522         my $push = $rdata->{'push'};
5523
5524         my $urls_table = "<table class=\"projects_list\">\n" ;
5525
5526         if (defined $fetch) {
5527                 if ($fetch eq $push) {
5528                         $urls_table .= format_repo_url("URL", $fetch);
5529                 } else {
5530                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5531                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5532                 }
5533         } elsif (defined $push) {
5534                 $urls_table .= format_repo_url("Push URL", $push);
5535         } else {
5536                 $urls_table .= format_repo_url("", "No remote URL");
5537         }
5538
5539         $urls_table .= "</table>\n";
5540
5541         my $dots;
5542         if (defined $limit && $limit < @$heads) {
5543                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5544         }
5545
5546         print $urls_table;
5547         git_heads_body($heads, $head, 0, $limit, $dots);
5548 }
5549
5550 # Display a list of remote names with the respective fetch and push URLs
5551 sub git_remotes_list {
5552         my ($remotedata, $limit) = @_;
5553         print "<table class=\"heads\">\n";
5554         my $alternate = 1;
5555         my @remotes = sort keys %$remotedata;
5556
5557         my $limited = $limit && $limit < @remotes;
5558
5559         $#remotes = $limit - 1 if $limited;
5560
5561         while (my $remote = shift @remotes) {
5562                 my $rdata = $remotedata->{$remote};
5563                 my $fetch = $rdata->{'fetch'};
5564                 my $push = $rdata->{'push'};
5565                 if ($alternate) {
5566                         print "<tr class=\"dark\">\n";
5567                 } else {
5568                         print "<tr class=\"light\">\n";
5569                 }
5570                 $alternate ^= 1;
5571                 print "<td>" .
5572                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5573                                -class=> "list name"},esc_html($remote)) .
5574                       "</td>";
5575                 print "<td class=\"link\">" .
5576                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5577                       " | " .
5578                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5579                       "</td>";
5580
5581                 print "</tr>\n";
5582         }
5583
5584         if ($limited) {
5585                 print "<tr>\n" .
5586                       "<td colspan=\"3\">" .
5587                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5588                       "</td>\n" . "</tr>\n";
5589         }
5590
5591         print "</table>";
5592 }
5593
5594 # Display remote heads grouped by remote, unless there are too many
5595 # remotes, in which case we only display the remote names
5596 sub git_remotes_body {
5597         my ($remotedata, $limit, $head) = @_;
5598         if ($limit and $limit < keys %$remotedata) {
5599                 git_remotes_list($remotedata, $limit);
5600         } else {
5601                 fill_remote_heads($remotedata);
5602                 while (my ($remote, $rdata) = each %$remotedata) {
5603                         git_print_section({-class=>"remote", -id=>$remote},
5604                                 ["remotes", $remote, $remote], sub {
5605                                         git_remote_block($remote, $rdata, $limit, $head);
5606                                 });
5607                 }
5608         }
5609 }
5610
5611 sub git_search_message {
5612         my %co = @_;
5613
5614         my $greptype;
5615         if ($searchtype eq 'commit') {
5616                 $greptype = "--grep=";
5617         } elsif ($searchtype eq 'author') {
5618                 $greptype = "--author=";
5619         } elsif ($searchtype eq 'committer') {
5620                 $greptype = "--committer=";
5621         }
5622         $greptype .= $searchtext;
5623         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5624                                        $greptype, '--regexp-ignore-case',
5625                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5626
5627         my $paging_nav = '';
5628         if ($page > 0) {
5629                 $paging_nav .=
5630                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5631                                 "first") .
5632                         " &sdot; " .
5633                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5634                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5635         } else {
5636                 $paging_nav .= "first &sdot; prev";
5637         }
5638         my $next_link = '';
5639         if ($#commitlist >= 100) {
5640                 $next_link =
5641                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5642                                  -accesskey => "n", -title => "Alt-n"}, "next");
5643                 $paging_nav .= " &sdot; $next_link";
5644         } else {
5645                 $paging_nav .= " &sdot; next";
5646         }
5647
5648         git_header_html();
5649
5650         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5651         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5652         if ($page == 0 && !@commitlist) {
5653                 print "<p>No match.</p>\n";
5654         } else {
5655                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5656         }
5657
5658         git_footer_html();
5659 }
5660
5661 sub git_search_changes {
5662         my %co = @_;
5663
5664         local $/ = "\n";
5665         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5666                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5667                 ($search_use_regexp ? '--pickaxe-regex' : ())
5668                         or die_error(500, "Open git-log failed");
5669
5670         git_header_html();
5671
5672         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5673         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5674
5675         print "<table class=\"pickaxe search\">\n";
5676         my $alternate = 1;
5677         undef %co;
5678         my @files;
5679         while (my $line = <$fd>) {
5680                 chomp $line;
5681                 next unless $line;
5682
5683                 my %set = parse_difftree_raw_line($line);
5684                 if (defined $set{'commit'}) {
5685                         # finish previous commit
5686                         if (%co) {
5687                                 print "</td>\n" .
5688                                       "<td class=\"link\">" .
5689                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5690                                               "commit") .
5691                                       " | " .
5692                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5693                                                              hash_base=>$co{'id'})},
5694                                               "tree") .
5695                                       "</td>\n" .
5696                                       "</tr>\n";
5697                         }
5698
5699                         if ($alternate) {
5700                                 print "<tr class=\"dark\">\n";
5701                         } else {
5702                                 print "<tr class=\"light\">\n";
5703                         }
5704                         $alternate ^= 1;
5705                         %co = parse_commit($set{'commit'});
5706                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5707                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5708                               "<td><i>$author</i></td>\n" .
5709                               "<td>" .
5710                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5711                                       -class => "list subject"},
5712                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
5713                 } elsif (defined $set{'to_id'}) {
5714                         next if ($set{'to_id'} =~ m/^0{40}$/);
5715
5716                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5717                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5718                                       -class => "list"},
5719                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5720                               "<br/>\n";
5721                 }
5722         }
5723         close $fd;
5724
5725         # finish last commit (warning: repetition!)
5726         if (%co) {
5727                 print "</td>\n" .
5728                       "<td class=\"link\">" .
5729                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5730                               "commit") .
5731                       " | " .
5732                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5733                                              hash_base=>$co{'id'})},
5734                               "tree") .
5735                       "</td>\n" .
5736                       "</tr>\n";
5737         }
5738
5739         print "</table>\n";
5740
5741         git_footer_html();
5742 }
5743
5744 sub git_search_files {
5745         my %co = @_;
5746
5747         local $/ = "\n";
5748         open my $fd, "-|", git_cmd(), 'grep', '-n',
5749                 $search_use_regexp ? ('-E', '-i') : '-F',
5750                 $searchtext, $co{'tree'}
5751                         or die_error(500, "Open git-grep failed");
5752
5753         git_header_html();
5754
5755         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5756         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5757
5758         print "<table class=\"grep_search\">\n";
5759         my $alternate = 1;
5760         my $matches = 0;
5761         my $lastfile = '';
5762         while (my $line = <$fd>) {
5763                 chomp $line;
5764                 my ($file, $lno, $ltext, $binary);
5765                 last if ($matches++ > 1000);
5766                 if ($line =~ /^Binary file (.+) matches$/) {
5767                         $file = $1;
5768                         $binary = 1;
5769                 } else {
5770                         (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
5771                 }
5772                 if ($file ne $lastfile) {
5773                         $lastfile and print "</td></tr>\n";
5774                         if ($alternate++) {
5775                                 print "<tr class=\"dark\">\n";
5776                         } else {
5777                                 print "<tr class=\"light\">\n";
5778                         }
5779                         print "<td class=\"list\">".
5780                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5781                                                        file_name=>"$file"),
5782                                         -class => "list"}, esc_path($file));
5783                         print "</td><td>\n";
5784                         $lastfile = $file;
5785                 }
5786                 if ($binary) {
5787                         print "<div class=\"binary\">Binary file</div>\n";
5788                 } else {
5789                         $ltext = untabify($ltext);
5790                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
5791                                 $ltext = esc_html($1, -nbsp=>1);
5792                                 $ltext .= '<span class="match">';
5793                                 $ltext .= esc_html($2, -nbsp=>1);
5794                                 $ltext .= '</span>';
5795                                 $ltext .= esc_html($3, -nbsp=>1);
5796                         } else {
5797                                 $ltext = esc_html($ltext, -nbsp=>1);
5798                         }
5799                         print "<div class=\"pre\">" .
5800                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5801                                                        file_name=>"$file").'#l'.$lno,
5802                                         -class => "linenr"}, sprintf('%4i', $lno))
5803                                 . ' ' .  $ltext . "</div>\n";
5804                 }
5805         }
5806         if ($lastfile) {
5807                 print "</td></tr>\n";
5808                 if ($matches > 1000) {
5809                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
5810                 }
5811         } else {
5812                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
5813         }
5814         close $fd;
5815
5816         print "</table>\n";
5817
5818         git_footer_html();
5819 }
5820
5821 sub git_search_grep_body {
5822         my ($commitlist, $from, $to, $extra) = @_;
5823         $from = 0 unless defined $from;
5824         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5825
5826         print "<table class=\"commit_search\">\n";
5827         my $alternate = 1;
5828         for (my $i = $from; $i <= $to; $i++) {
5829                 my %co = %{$commitlist->[$i]};
5830                 if (!%co) {
5831                         next;
5832                 }
5833                 my $commit = $co{'id'};
5834                 if ($alternate) {
5835                         print "<tr class=\"dark\">\n";
5836                 } else {
5837                         print "<tr class=\"light\">\n";
5838                 }
5839                 $alternate ^= 1;
5840                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5841                       format_author_html('td', \%co, 15, 5) .
5842                       "<td>" .
5843                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5844                                -class => "list subject"},
5845                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5846                 my $comment = $co{'comment'};
5847                 foreach my $line (@$comment) {
5848                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5849                                 my ($lead, $match, $trail) = ($1, $2, $3);
5850                                 $match = chop_str($match, 70, 5, 'center');
5851                                 my $contextlen = int((80 - length($match))/2);
5852                                 $contextlen = 30 if ($contextlen > 30);
5853                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5854                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5855
5856                                 $lead  = esc_html($lead);
5857                                 $match = esc_html($match);
5858                                 $trail = esc_html($trail);
5859
5860                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5861                         }
5862                 }
5863                 print "</td>\n" .
5864                       "<td class=\"link\">" .
5865                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5866                       " | " .
5867                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5868                       " | " .
5869                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5870                 print "</td>\n" .
5871                       "</tr>\n";
5872         }
5873         if (defined $extra) {
5874                 print "<tr>\n" .
5875                       "<td colspan=\"3\">$extra</td>\n" .
5876                       "</tr>\n";
5877         }
5878         print "</table>\n";
5879 }
5880
5881 ## ======================================================================
5882 ## ======================================================================
5883 ## actions
5884
5885 sub git_project_list {
5886         my $order = $input_params{'order'};
5887         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5888                 die_error(400, "Unknown order parameter");
5889         }
5890
5891         my @list = git_get_projects_list();
5892         if (!@list) {
5893                 die_error(404, "No projects found");
5894         }
5895
5896         git_header_html();
5897         if (defined $home_text && -f $home_text) {
5898                 print "<div class=\"index_include\">\n";
5899                 insert_file($home_text);
5900                 print "</div>\n";
5901         }
5902         print $cgi->startform(-method => "get") .
5903               "<p class=\"projsearch\">Search:\n" .
5904               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5905               "</p>" .
5906               $cgi->end_form() . "\n";
5907         git_project_list_body(\@list, $order);
5908         git_footer_html();
5909 }
5910
5911 sub git_forks {
5912         my $order = $input_params{'order'};
5913         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5914                 die_error(400, "Unknown order parameter");
5915         }
5916
5917         my @list = git_get_projects_list($project);
5918         if (!@list) {
5919                 die_error(404, "No forks found");
5920         }
5921
5922         git_header_html();
5923         git_print_page_nav('','');
5924         git_print_header_div('summary', "$project forks");
5925         git_project_list_body(\@list, $order);
5926         git_footer_html();
5927 }
5928
5929 sub git_project_index {
5930         my @projects = git_get_projects_list();
5931         if (!@projects) {
5932                 die_error(404, "No projects found");
5933         }
5934
5935         print $cgi->header(
5936                 -type => 'text/plain',
5937                 -charset => 'utf-8',
5938                 -content_disposition => 'inline; filename="index.aux"');
5939
5940         foreach my $pr (@projects) {
5941                 if (!exists $pr->{'owner'}) {
5942                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5943                 }
5944
5945                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5946                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5947                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5948                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5949                 $path  =~ s/ /\+/g;
5950                 $owner =~ s/ /\+/g;
5951
5952                 print "$path $owner\n";
5953         }
5954 }
5955
5956 sub git_summary {
5957         my $descr = git_get_project_description($project) || "none";
5958         my %co = parse_commit("HEAD");
5959         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5960         my $head = $co{'id'};
5961         my $remote_heads = gitweb_check_feature('remote_heads');
5962
5963         my $owner = git_get_project_owner($project);
5964
5965         my $refs = git_get_references();
5966         # These get_*_list functions return one more to allow us to see if
5967         # there are more ...
5968         my @taglist  = git_get_tags_list(16);
5969         my @headlist = git_get_heads_list(16);
5970         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
5971         my @forklist;
5972         my $check_forks = gitweb_check_feature('forks');
5973
5974         if ($check_forks) {
5975                 # find forks of a project
5976                 @forklist = git_get_projects_list($project);
5977                 # filter out forks of forks
5978                 @forklist = filter_forks_from_projects_list(\@forklist)
5979                         if (@forklist);
5980         }
5981
5982         git_header_html();
5983         git_print_page_nav('summary','', $head);
5984
5985         print "<div class=\"title\">&nbsp;</div>\n";
5986         print "<table class=\"projects_list\">\n" .
5987               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5988               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5989         if (defined $cd{'rfc2822'}) {
5990                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
5991                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
5992         }
5993
5994         # use per project git URL list in $projectroot/$project/cloneurl
5995         # or make project git URL from git base URL and project name
5996         my $url_tag = "URL";
5997         my @url_list = git_get_project_url_list($project);
5998         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5999         foreach my $git_url (@url_list) {
6000                 next unless $git_url;
6001                 print format_repo_url($url_tag, $git_url);
6002                 $url_tag = "";
6003         }
6004
6005         # Tag cloud
6006         my $show_ctags = gitweb_check_feature('ctags');
6007         if ($show_ctags) {
6008                 my $ctags = git_get_project_ctags($project);
6009                 if (%$ctags) {
6010                         # without ability to add tags, don't show if there are none
6011                         my $cloud = git_populate_project_tagcloud($ctags);
6012                         print "<tr id=\"metadata_ctags\">" .
6013                               "<td>content tags</td>" .
6014                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6015                               "</tr>\n";
6016                 }
6017         }
6018
6019         print "</table>\n";
6020
6021         # If XSS prevention is on, we don't include README.html.
6022         # TODO: Allow a readme in some safe format.
6023         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6024                 print "<div class=\"title\">readme</div>\n" .
6025                       "<div class=\"readme\">\n";
6026                 insert_file("$projectroot/$project/README.html");
6027                 print "\n</div>\n"; # class="readme"
6028         }
6029
6030         # we need to request one more than 16 (0..15) to check if
6031         # those 16 are all
6032         my @commitlist = $head ? parse_commits($head, 17) : ();
6033         if (@commitlist) {
6034                 git_print_header_div('shortlog');
6035                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6036                                   $#commitlist <=  15 ? undef :
6037                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6038         }
6039
6040         if (@taglist) {
6041                 git_print_header_div('tags');
6042                 git_tags_body(\@taglist, 0, 15,
6043                               $#taglist <=  15 ? undef :
6044                               $cgi->a({-href => href(action=>"tags")}, "..."));
6045         }
6046
6047         if (@headlist) {
6048                 git_print_header_div('heads');
6049                 git_heads_body(\@headlist, $head, 0, 15,
6050                                $#headlist <= 15 ? undef :
6051                                $cgi->a({-href => href(action=>"heads")}, "..."));
6052         }
6053
6054         if (%remotedata) {
6055                 git_print_header_div('remotes');
6056                 git_remotes_body(\%remotedata, 15, $head);
6057         }
6058
6059         if (@forklist) {
6060                 git_print_header_div('forks');
6061                 git_project_list_body(\@forklist, 'age', 0, 15,
6062                                       $#forklist <= 15 ? undef :
6063                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6064                                       'no_header');
6065         }
6066
6067         git_footer_html();
6068 }
6069
6070 sub git_tag {
6071         my %tag = parse_tag($hash);
6072
6073         if (! %tag) {
6074                 die_error(404, "Unknown tag object");
6075         }
6076
6077         my $head = git_get_head_hash($project);
6078         git_header_html();
6079         git_print_page_nav('','', $head,undef,$head);
6080         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6081         print "<div class=\"title_text\">\n" .
6082               "<table class=\"object_header\">\n" .
6083               "<tr>\n" .
6084               "<td>object</td>\n" .
6085               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6086                                $tag{'object'}) . "</td>\n" .
6087               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6088                                               $tag{'type'}) . "</td>\n" .
6089               "</tr>\n";
6090         if (defined($tag{'author'})) {
6091                 git_print_authorship_rows(\%tag, 'author');
6092         }
6093         print "</table>\n\n" .
6094               "</div>\n";
6095         print "<div class=\"page_body\">";
6096         my $comment = $tag{'comment'};
6097         foreach my $line (@$comment) {
6098                 chomp $line;
6099                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6100         }
6101         print "</div>\n";
6102         git_footer_html();
6103 }
6104
6105 sub git_blame_common {
6106         my $format = shift || 'porcelain';
6107         if ($format eq 'porcelain' && $cgi->param('js')) {
6108                 $format = 'incremental';
6109                 $action = 'blame_incremental'; # for page title etc
6110         }
6111
6112         # permissions
6113         gitweb_check_feature('blame')
6114                 or die_error(403, "Blame view not allowed");
6115
6116         # error checking
6117         die_error(400, "No file name given") unless $file_name;
6118         $hash_base ||= git_get_head_hash($project);
6119         die_error(404, "Couldn't find base commit") unless $hash_base;
6120         my %co = parse_commit($hash_base)
6121                 or die_error(404, "Commit not found");
6122         my $ftype = "blob";
6123         if (!defined $hash) {
6124                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6125                         or die_error(404, "Error looking up file");
6126         } else {
6127                 $ftype = git_get_type($hash);
6128                 if ($ftype !~ "blob") {
6129                         die_error(400, "Object is not a blob");
6130                 }
6131         }
6132
6133         my $fd;
6134         if ($format eq 'incremental') {
6135                 # get file contents (as base)
6136                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6137                         or die_error(500, "Open git-cat-file failed");
6138         } elsif ($format eq 'data') {
6139                 # run git-blame --incremental
6140                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6141                         $hash_base, "--", $file_name
6142                         or die_error(500, "Open git-blame --incremental failed");
6143         } else {
6144                 # run git-blame --porcelain
6145                 open $fd, "-|", git_cmd(), "blame", '-p',
6146                         $hash_base, '--', $file_name
6147                         or die_error(500, "Open git-blame --porcelain failed");
6148         }
6149
6150         # incremental blame data returns early
6151         if ($format eq 'data') {
6152                 print $cgi->header(
6153                         -type=>"text/plain", -charset => "utf-8",
6154                         -status=> "200 OK");
6155                 local $| = 1; # output autoflush
6156                 print while <$fd>;
6157                 close $fd
6158                         or print "ERROR $!\n";
6159
6160                 print 'END';
6161                 if (defined $t0 && gitweb_check_feature('timed')) {
6162                         print ' '.
6163                               tv_interval($t0, [ gettimeofday() ]).
6164                               ' '.$number_of_git_cmds;
6165                 }
6166                 print "\n";
6167
6168                 return;
6169         }
6170
6171         # page header
6172         git_header_html();
6173         my $formats_nav =
6174                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6175                         "blob") .
6176                 " | ";
6177         if ($format eq 'incremental') {
6178                 $formats_nav .=
6179                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6180                                 "blame") . " (non-incremental)";
6181         } else {
6182                 $formats_nav .=
6183                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6184                                 "blame") . " (incremental)";
6185         }
6186         $formats_nav .=
6187                 " | " .
6188                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6189                         "history") .
6190                 " | " .
6191                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6192                         "HEAD");
6193         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6194         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6195         git_print_page_path($file_name, $ftype, $hash_base);
6196
6197         # page body
6198         if ($format eq 'incremental') {
6199                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6200                       "This page requires JavaScript to run.\n Use ".
6201                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6202                               'this page').
6203                       " instead.\n".
6204                       "</b></center></div>\n</noscript>\n";
6205
6206                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6207         }
6208
6209         print qq!<div class="page_body">\n!;
6210         print qq!<div id="progress_info">... / ...</div>\n!
6211                 if ($format eq 'incremental');
6212         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6213               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6214               qq!<thead>\n!.
6215               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6216               qq!</thead>\n!.
6217               qq!<tbody>\n!;
6218
6219         my @rev_color = qw(light dark);
6220         my $num_colors = scalar(@rev_color);
6221         my $current_color = 0;
6222
6223         if ($format eq 'incremental') {
6224                 my $color_class = $rev_color[$current_color];
6225
6226                 #contents of a file
6227                 my $linenr = 0;
6228         LINE:
6229                 while (my $line = <$fd>) {
6230                         chomp $line;
6231                         $linenr++;
6232
6233                         print qq!<tr id="l$linenr" class="$color_class">!.
6234                               qq!<td class="sha1"><a href=""> </a></td>!.
6235                               qq!<td class="linenr">!.
6236                               qq!<a class="linenr" href="">$linenr</a></td>!;
6237                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6238                         print qq!</tr>\n!;
6239                 }
6240
6241         } else { # porcelain, i.e. ordinary blame
6242                 my %metainfo = (); # saves information about commits
6243
6244                 # blame data
6245         LINE:
6246                 while (my $line = <$fd>) {
6247                         chomp $line;
6248                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6249                         # no <lines in group> for subsequent lines in group of lines
6250                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6251                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6252                         if (!exists $metainfo{$full_rev}) {
6253                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6254                         }
6255                         my $meta = $metainfo{$full_rev};
6256                         my $data;
6257                         while ($data = <$fd>) {
6258                                 chomp $data;
6259                                 last if ($data =~ s/^\t//); # contents of line
6260                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6261                                         $meta->{$1} = $2 unless exists $meta->{$1};
6262                                 }
6263                                 if ($data =~ /^previous /) {
6264                                         $meta->{'nprevious'}++;
6265                                 }
6266                         }
6267                         my $short_rev = substr($full_rev, 0, 8);
6268                         my $author = $meta->{'author'};
6269                         my %date =
6270                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6271                         my $date = $date{'iso-tz'};
6272                         if ($group_size) {
6273                                 $current_color = ($current_color + 1) % $num_colors;
6274                         }
6275                         my $tr_class = $rev_color[$current_color];
6276                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6277                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6278                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6279                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6280                         if ($group_size) {
6281                                 print "<td class=\"sha1\"";
6282                                 print " title=\"". esc_html($author) . ", $date\"";
6283                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6284                                 print ">";
6285                                 print $cgi->a({-href => href(action=>"commit",
6286                                                              hash=>$full_rev,
6287                                                              file_name=>$file_name)},
6288                                               esc_html($short_rev));
6289                                 if ($group_size >= 2) {
6290                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6291                                         if (@author_initials) {
6292                                                 print "<br />" .
6293                                                       esc_html(join('', @author_initials));
6294                                                 #           or join('.', ...)
6295                                         }
6296                                 }
6297                                 print "</td>\n";
6298                         }
6299                         # 'previous' <sha1 of parent commit> <filename at commit>
6300                         if (exists $meta->{'previous'} &&
6301                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6302                                 $meta->{'parent'} = $1;
6303                                 $meta->{'file_parent'} = unquote($2);
6304                         }
6305                         my $linenr_commit =
6306                                 exists($meta->{'parent'}) ?
6307                                 $meta->{'parent'} : $full_rev;
6308                         my $linenr_filename =
6309                                 exists($meta->{'file_parent'}) ?
6310                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6311                         my $blamed = href(action => 'blame',
6312                                           file_name => $linenr_filename,
6313                                           hash_base => $linenr_commit);
6314                         print "<td class=\"linenr\">";
6315                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6316                                         -class => "linenr" },
6317                                       esc_html($lineno));
6318                         print "</td>";
6319                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6320                         print "</tr>\n";
6321                 } # end while
6322
6323         }
6324
6325         # footer
6326         print "</tbody>\n".
6327               "</table>\n"; # class="blame"
6328         print "</div>\n";   # class="blame_body"
6329         close $fd
6330                 or print "Reading blob failed\n";
6331
6332         git_footer_html();
6333 }
6334
6335 sub git_blame {
6336         git_blame_common();
6337 }
6338
6339 sub git_blame_incremental {
6340         git_blame_common('incremental');
6341 }
6342
6343 sub git_blame_data {
6344         git_blame_common('data');
6345 }
6346
6347 sub git_tags {
6348         my $head = git_get_head_hash($project);
6349         git_header_html();
6350         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6351         git_print_header_div('summary', $project);
6352
6353         my @tagslist = git_get_tags_list();
6354         if (@tagslist) {
6355                 git_tags_body(\@tagslist);
6356         }
6357         git_footer_html();
6358 }
6359
6360 sub git_heads {
6361         my $head = git_get_head_hash($project);
6362         git_header_html();
6363         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6364         git_print_header_div('summary', $project);
6365
6366         my @headslist = git_get_heads_list();
6367         if (@headslist) {
6368                 git_heads_body(\@headslist, $head);
6369         }
6370         git_footer_html();
6371 }
6372
6373 # used both for single remote view and for list of all the remotes
6374 sub git_remotes {
6375         gitweb_check_feature('remote_heads')
6376                 or die_error(403, "Remote heads view is disabled");
6377
6378         my $head = git_get_head_hash($project);
6379         my $remote = $input_params{'hash'};
6380
6381         my $remotedata = git_get_remotes_list($remote);
6382         die_error(500, "Unable to get remote information") unless defined $remotedata;
6383
6384         unless (%$remotedata) {
6385                 die_error(404, defined $remote ?
6386                         "Remote $remote not found" :
6387                         "No remotes found");
6388         }
6389
6390         git_header_html(undef, undef, -action_extra => $remote);
6391         git_print_page_nav('', '',  $head, undef, $head,
6392                 format_ref_views($remote ? '' : 'remotes'));
6393
6394         fill_remote_heads($remotedata);
6395         if (defined $remote) {
6396                 git_print_header_div('remotes', "$remote remote for $project");
6397                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6398         } else {
6399                 git_print_header_div('summary', "$project remotes");
6400                 git_remotes_body($remotedata, undef, $head);
6401         }
6402
6403         git_footer_html();
6404 }
6405
6406 sub git_blob_plain {
6407         my $type = shift;
6408         my $expires;
6409
6410         if (!defined $hash) {
6411                 if (defined $file_name) {
6412                         my $base = $hash_base || git_get_head_hash($project);
6413                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6414                                 or die_error(404, "Cannot find file");
6415                 } else {
6416                         die_error(400, "No file name defined");
6417                 }
6418         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6419                 # blobs defined by non-textual hash id's can be cached
6420                 $expires = "+1d";
6421         }
6422
6423         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6424                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6425
6426         # content-type (can include charset)
6427         $type = blob_contenttype($fd, $file_name, $type);
6428
6429         # "save as" filename, even when no $file_name is given
6430         my $save_as = "$hash";
6431         if (defined $file_name) {
6432                 $save_as = $file_name;
6433         } elsif ($type =~ m/^text\//) {
6434                 $save_as .= '.txt';
6435         }
6436
6437         # With XSS prevention on, blobs of all types except a few known safe
6438         # ones are served with "Content-Disposition: attachment" to make sure
6439         # they don't run in our security domain.  For certain image types,
6440         # blob view writes an <img> tag referring to blob_plain view, and we
6441         # want to be sure not to break that by serving the image as an
6442         # attachment (though Firefox 3 doesn't seem to care).
6443         my $sandbox = $prevent_xss &&
6444                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6445
6446         # serve text/* as text/plain
6447         if ($prevent_xss &&
6448             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6449              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6450                 my $rest = $1;
6451                 $rest = defined $rest ? $rest : '';
6452                 $type = "text/plain$rest";
6453         }
6454
6455         print $cgi->header(
6456                 -type => $type,
6457                 -expires => $expires,
6458                 -content_disposition =>
6459                         ($sandbox ? 'attachment' : 'inline')
6460                         . '; filename="' . $save_as . '"');
6461         local $/ = undef;
6462         binmode STDOUT, ':raw';
6463         print <$fd>;
6464         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6465         close $fd;
6466 }
6467
6468 sub git_blob {
6469         my $expires;
6470
6471         if (!defined $hash) {
6472                 if (defined $file_name) {
6473                         my $base = $hash_base || git_get_head_hash($project);
6474                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6475                                 or die_error(404, "Cannot find file");
6476                 } else {
6477                         die_error(400, "No file name defined");
6478                 }
6479         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6480                 # blobs defined by non-textual hash id's can be cached
6481                 $expires = "+1d";
6482         }
6483
6484         my $have_blame = gitweb_check_feature('blame');
6485         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6486                 or die_error(500, "Couldn't cat $file_name, $hash");
6487         my $mimetype = blob_mimetype($fd, $file_name);
6488         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6489         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6490                 close $fd;
6491                 return git_blob_plain($mimetype);
6492         }
6493         # we can have blame only for text/* mimetype
6494         $have_blame &&= ($mimetype =~ m!^text/!);
6495
6496         my $highlight = gitweb_check_feature('highlight');
6497         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6498         $fd = run_highlighter($fd, $highlight, $syntax)
6499                 if $syntax;
6500
6501         git_header_html(undef, $expires);
6502         my $formats_nav = '';
6503         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6504                 if (defined $file_name) {
6505                         if ($have_blame) {
6506                                 $formats_nav .=
6507                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6508                                                 "blame") .
6509                                         " | ";
6510                         }
6511                         $formats_nav .=
6512                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6513                                         "history") .
6514                                 " | " .
6515                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6516                                         "raw") .
6517                                 " | " .
6518                                 $cgi->a({-href => href(action=>"blob",
6519                                                        hash_base=>"HEAD", file_name=>$file_name)},
6520                                         "HEAD");
6521                 } else {
6522                         $formats_nav .=
6523                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6524                                         "raw");
6525                 }
6526                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6527                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6528         } else {
6529                 print "<div class=\"page_nav\">\n" .
6530                       "<br/><br/></div>\n" .
6531                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6532         }
6533         git_print_page_path($file_name, "blob", $hash_base);
6534         print "<div class=\"page_body\">\n";
6535         if ($mimetype =~ m!^image/!) {
6536                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6537                 if ($file_name) {
6538                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6539                 }
6540                 print qq! src="! .
6541                       href(action=>"blob_plain", hash=>$hash,
6542                            hash_base=>$hash_base, file_name=>$file_name) .
6543                       qq!" />\n!;
6544         } else {
6545                 my $nr;
6546                 while (my $line = <$fd>) {
6547                         chomp $line;
6548                         $nr++;
6549                         $line = untabify($line);
6550                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6551                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6552                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6553                 }
6554         }
6555         close $fd
6556                 or print "Reading blob failed.\n";
6557         print "</div>";
6558         git_footer_html();
6559 }
6560
6561 sub git_tree {
6562         if (!defined $hash_base) {
6563                 $hash_base = "HEAD";
6564         }
6565         if (!defined $hash) {
6566                 if (defined $file_name) {
6567                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6568                 } else {
6569                         $hash = $hash_base;
6570                 }
6571         }
6572         die_error(404, "No such tree") unless defined($hash);
6573
6574         my $show_sizes = gitweb_check_feature('show-sizes');
6575         my $have_blame = gitweb_check_feature('blame');
6576
6577         my @entries = ();
6578         {
6579                 local $/ = "\0";
6580                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6581                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6582                         or die_error(500, "Open git-ls-tree failed");
6583                 @entries = map { chomp; $_ } <$fd>;
6584                 close $fd
6585                         or die_error(404, "Reading tree failed");
6586         }
6587
6588         my $refs = git_get_references();
6589         my $ref = format_ref_marker($refs, $hash_base);
6590         git_header_html();
6591         my $basedir = '';
6592         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6593                 my @views_nav = ();
6594                 if (defined $file_name) {
6595                         push @views_nav,
6596                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6597                                         "history"),
6598                                 $cgi->a({-href => href(action=>"tree",
6599                                                        hash_base=>"HEAD", file_name=>$file_name)},
6600                                         "HEAD"),
6601                 }
6602                 my $snapshot_links = format_snapshot_links($hash);
6603                 if (defined $snapshot_links) {
6604                         # FIXME: Should be available when we have no hash base as well.
6605                         push @views_nav, $snapshot_links;
6606                 }
6607                 git_print_page_nav('tree','', $hash_base, undef, undef,
6608                                    join(' | ', @views_nav));
6609                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6610         } else {
6611                 undef $hash_base;
6612                 print "<div class=\"page_nav\">\n";
6613                 print "<br/><br/></div>\n";
6614                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6615         }
6616         if (defined $file_name) {
6617                 $basedir = $file_name;
6618                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6619                         $basedir .= '/';
6620                 }
6621                 git_print_page_path($file_name, 'tree', $hash_base);
6622         }
6623         print "<div class=\"page_body\">\n";
6624         print "<table class=\"tree\">\n";
6625         my $alternate = 1;
6626         # '..' (top directory) link if possible
6627         if (defined $hash_base &&
6628             defined $file_name && $file_name =~ m![^/]+$!) {
6629                 if ($alternate) {
6630                         print "<tr class=\"dark\">\n";
6631                 } else {
6632                         print "<tr class=\"light\">\n";
6633                 }
6634                 $alternate ^= 1;
6635
6636                 my $up = $file_name;
6637                 $up =~ s!/?[^/]+$!!;
6638                 undef $up unless $up;
6639                 # based on git_print_tree_entry
6640                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6641                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6642                 print '<td class="list">';
6643                 print $cgi->a({-href => href(action=>"tree",
6644                                              hash_base=>$hash_base,
6645                                              file_name=>$up)},
6646                               "..");
6647                 print "</td>\n";
6648                 print "<td class=\"link\"></td>\n";
6649
6650                 print "</tr>\n";
6651         }
6652         foreach my $line (@entries) {
6653                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6654
6655                 if ($alternate) {
6656                         print "<tr class=\"dark\">\n";
6657                 } else {
6658                         print "<tr class=\"light\">\n";
6659                 }
6660                 $alternate ^= 1;
6661
6662                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6663
6664                 print "</tr>\n";
6665         }
6666         print "</table>\n" .
6667               "</div>";
6668         git_footer_html();
6669 }
6670
6671 sub snapshot_name {
6672         my ($project, $hash) = @_;
6673
6674         # path/to/project.git  -> project
6675         # path/to/project/.git -> project
6676         my $name = to_utf8($project);
6677         $name =~ s,([^/])/*\.git$,$1,;
6678         $name = basename($name);
6679         # sanitize name
6680         $name =~ s/[[:cntrl:]]/?/g;
6681
6682         my $ver = $hash;
6683         if ($hash =~ /^[0-9a-fA-F]+$/) {
6684                 # shorten SHA-1 hash
6685                 my $full_hash = git_get_full_hash($project, $hash);
6686                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6687                         $ver = git_get_short_hash($project, $hash);
6688                 }
6689         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6690                 # tags don't need shortened SHA-1 hash
6691                 $ver = $1;
6692         } else {
6693                 # branches and other need shortened SHA-1 hash
6694                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6695                         $ver = $1;
6696                 }
6697                 $ver .= '-' . git_get_short_hash($project, $hash);
6698         }
6699         # in case of hierarchical branch names
6700         $ver =~ s!/!.!g;
6701
6702         # name = project-version_string
6703         $name = "$name-$ver";
6704
6705         return wantarray ? ($name, $name) : $name;
6706 }
6707
6708 sub git_snapshot {
6709         my $format = $input_params{'snapshot_format'};
6710         if (!@snapshot_fmts) {
6711                 die_error(403, "Snapshots not allowed");
6712         }
6713         # default to first supported snapshot format
6714         $format ||= $snapshot_fmts[0];
6715         if ($format !~ m/^[a-z0-9]+$/) {
6716                 die_error(400, "Invalid snapshot format parameter");
6717         } elsif (!exists($known_snapshot_formats{$format})) {
6718                 die_error(400, "Unknown snapshot format");
6719         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6720                 die_error(403, "Snapshot format not allowed");
6721         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6722                 die_error(403, "Unsupported snapshot format");
6723         }
6724
6725         my $type = git_get_type("$hash^{}");
6726         if (!$type) {
6727                 die_error(404, 'Object does not exist');
6728         }  elsif ($type eq 'blob') {
6729                 die_error(400, 'Object is not a tree-ish');
6730         }
6731
6732         my ($name, $prefix) = snapshot_name($project, $hash);
6733         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6734         my $cmd = quote_command(
6735                 git_cmd(), 'archive',
6736                 "--format=$known_snapshot_formats{$format}{'format'}",
6737                 "--prefix=$prefix/", $hash);
6738         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6739                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6740         }
6741
6742         $filename =~ s/(["\\])/\\$1/g;
6743         print $cgi->header(
6744                 -type => $known_snapshot_formats{$format}{'type'},
6745                 -content_disposition => 'inline; filename="' . $filename . '"',
6746                 -status => '200 OK');
6747
6748         open my $fd, "-|", $cmd
6749                 or die_error(500, "Execute git-archive failed");
6750         binmode STDOUT, ':raw';
6751         print <$fd>;
6752         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6753         close $fd;
6754 }
6755
6756 sub git_log_generic {
6757         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6758
6759         my $head = git_get_head_hash($project);
6760         if (!defined $base) {
6761                 $base = $head;
6762         }
6763         if (!defined $page) {
6764                 $page = 0;
6765         }
6766         my $refs = git_get_references();
6767
6768         my $commit_hash = $base;
6769         if (defined $parent) {
6770                 $commit_hash = "$parent..$base";
6771         }
6772         my @commitlist =
6773                 parse_commits($commit_hash, 101, (100 * $page),
6774                               defined $file_name ? ($file_name, "--full-history") : ());
6775
6776         my $ftype;
6777         if (!defined $file_hash && defined $file_name) {
6778                 # some commits could have deleted file in question,
6779                 # and not have it in tree, but one of them has to have it
6780                 for (my $i = 0; $i < @commitlist; $i++) {
6781                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6782                         last if defined $file_hash;
6783                 }
6784         }
6785         if (defined $file_hash) {
6786                 $ftype = git_get_type($file_hash);
6787         }
6788         if (defined $file_name && !defined $ftype) {
6789                 die_error(500, "Unknown type of object");
6790         }
6791         my %co;
6792         if (defined $file_name) {
6793                 %co = parse_commit($base)
6794                         or die_error(404, "Unknown commit object");
6795         }
6796
6797
6798         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6799         my $next_link = '';
6800         if ($#commitlist >= 100) {
6801                 $next_link =
6802                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6803                                  -accesskey => "n", -title => "Alt-n"}, "next");
6804         }
6805         my $patch_max = gitweb_get_feature('patches');
6806         if ($patch_max && !defined $file_name) {
6807                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6808                         $paging_nav .= " &sdot; " .
6809                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6810                                         "patches");
6811                 }
6812         }
6813
6814         git_header_html();
6815         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6816         if (defined $file_name) {
6817                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6818         } else {
6819                 git_print_header_div('summary', $project)
6820         }
6821         git_print_page_path($file_name, $ftype, $hash_base)
6822                 if (defined $file_name);
6823
6824         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6825                      $file_name, $file_hash, $ftype);
6826
6827         git_footer_html();
6828 }
6829
6830 sub git_log {
6831         git_log_generic('log', \&git_log_body,
6832                         $hash, $hash_parent);
6833 }
6834
6835 sub git_commit {
6836         $hash ||= $hash_base || "HEAD";
6837         my %co = parse_commit($hash)
6838             or die_error(404, "Unknown commit object");
6839
6840         my $parent  = $co{'parent'};
6841         my $parents = $co{'parents'}; # listref
6842
6843         # we need to prepare $formats_nav before any parameter munging
6844         my $formats_nav;
6845         if (!defined $parent) {
6846                 # --root commitdiff
6847                 $formats_nav .= '(initial)';
6848         } elsif (@$parents == 1) {
6849                 # single parent commit
6850                 $formats_nav .=
6851                         '(parent: ' .
6852                         $cgi->a({-href => href(action=>"commit",
6853                                                hash=>$parent)},
6854                                 esc_html(substr($parent, 0, 7))) .
6855                         ')';
6856         } else {
6857                 # merge commit
6858                 $formats_nav .=
6859                         '(merge: ' .
6860                         join(' ', map {
6861                                 $cgi->a({-href => href(action=>"commit",
6862                                                        hash=>$_)},
6863                                         esc_html(substr($_, 0, 7)));
6864                         } @$parents ) .
6865                         ')';
6866         }
6867         if (gitweb_check_feature('patches') && @$parents <= 1) {
6868                 $formats_nav .= " | " .
6869                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6870                                 "patch");
6871         }
6872
6873         if (!defined $parent) {
6874                 $parent = "--root";
6875         }
6876         my @difftree;
6877         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6878                 @diff_opts,
6879                 (@$parents <= 1 ? $parent : '-c'),
6880                 $hash, "--"
6881                 or die_error(500, "Open git-diff-tree failed");
6882         @difftree = map { chomp; $_ } <$fd>;
6883         close $fd or die_error(404, "Reading git-diff-tree failed");
6884
6885         # non-textual hash id's can be cached
6886         my $expires;
6887         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6888                 $expires = "+1d";
6889         }
6890         my $refs = git_get_references();
6891         my $ref = format_ref_marker($refs, $co{'id'});
6892
6893         git_header_html(undef, $expires);
6894         git_print_page_nav('commit', '',
6895                            $hash, $co{'tree'}, $hash,
6896                            $formats_nav);
6897
6898         if (defined $co{'parent'}) {
6899                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6900         } else {
6901                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6902         }
6903         print "<div class=\"title_text\">\n" .
6904               "<table class=\"object_header\">\n";
6905         git_print_authorship_rows(\%co);
6906         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6907         print "<tr>" .
6908               "<td>tree</td>" .
6909               "<td class=\"sha1\">" .
6910               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6911                        class => "list"}, $co{'tree'}) .
6912               "</td>" .
6913               "<td class=\"link\">" .
6914               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6915                       "tree");
6916         my $snapshot_links = format_snapshot_links($hash);
6917         if (defined $snapshot_links) {
6918                 print " | " . $snapshot_links;
6919         }
6920         print "</td>" .
6921               "</tr>\n";
6922
6923         foreach my $par (@$parents) {
6924                 print "<tr>" .
6925                       "<td>parent</td>" .
6926                       "<td class=\"sha1\">" .
6927                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6928                                class => "list"}, $par) .
6929                       "</td>" .
6930                       "<td class=\"link\">" .
6931                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6932                       " | " .
6933                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6934                       "</td>" .
6935                       "</tr>\n";
6936         }
6937         print "</table>".
6938               "</div>\n";
6939
6940         print "<div class=\"page_body\">\n";
6941         git_print_log($co{'comment'});
6942         print "</div>\n";
6943
6944         git_difftree_body(\@difftree, $hash, @$parents);
6945
6946         git_footer_html();
6947 }
6948
6949 sub git_object {
6950         # object is defined by:
6951         # - hash or hash_base alone
6952         # - hash_base and file_name
6953         my $type;
6954
6955         # - hash or hash_base alone
6956         if ($hash || ($hash_base && !defined $file_name)) {
6957                 my $object_id = $hash || $hash_base;
6958
6959                 open my $fd, "-|", quote_command(
6960                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6961                         or die_error(404, "Object does not exist");
6962                 $type = <$fd>;
6963                 chomp $type;
6964                 close $fd
6965                         or die_error(404, "Object does not exist");
6966
6967         # - hash_base and file_name
6968         } elsif ($hash_base && defined $file_name) {
6969                 $file_name =~ s,/+$,,;
6970
6971                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6972                         or die_error(404, "Base object does not exist");
6973
6974                 # here errors should not hapen
6975                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6976                         or die_error(500, "Open git-ls-tree failed");
6977                 my $line = <$fd>;
6978                 close $fd;
6979
6980                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6981                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6982                         die_error(404, "File or directory for given base does not exist");
6983                 }
6984                 $type = $2;
6985                 $hash = $3;
6986         } else {
6987                 die_error(400, "Not enough information to find object");
6988         }
6989
6990         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6991                                           hash=>$hash, hash_base=>$hash_base,
6992                                           file_name=>$file_name),
6993                              -status => '302 Found');
6994 }
6995
6996 sub git_blobdiff {
6997         my $format = shift || 'html';
6998
6999         my $fd;
7000         my @difftree;
7001         my %diffinfo;
7002         my $expires;
7003
7004         # preparing $fd and %diffinfo for git_patchset_body
7005         # new style URI
7006         if (defined $hash_base && defined $hash_parent_base) {
7007                 if (defined $file_name) {
7008                         # read raw output
7009                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7010                                 $hash_parent_base, $hash_base,
7011                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7012                                 or die_error(500, "Open git-diff-tree failed");
7013                         @difftree = map { chomp; $_ } <$fd>;
7014                         close $fd
7015                                 or die_error(404, "Reading git-diff-tree failed");
7016                         @difftree
7017                                 or die_error(404, "Blob diff not found");
7018
7019                 } elsif (defined $hash &&
7020                          $hash =~ /[0-9a-fA-F]{40}/) {
7021                         # try to find filename from $hash
7022
7023                         # read filtered raw output
7024                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7025                                 $hash_parent_base, $hash_base, "--"
7026                                 or die_error(500, "Open git-diff-tree failed");
7027                         @difftree =
7028                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7029                                 # $hash == to_id
7030                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7031                                 map { chomp; $_ } <$fd>;
7032                         close $fd
7033                                 or die_error(404, "Reading git-diff-tree failed");
7034                         @difftree
7035                                 or die_error(404, "Blob diff not found");
7036
7037                 } else {
7038                         die_error(400, "Missing one of the blob diff parameters");
7039                 }
7040
7041                 if (@difftree > 1) {
7042                         die_error(400, "Ambiguous blob diff specification");
7043                 }
7044
7045                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7046                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7047                 $file_name   ||= $diffinfo{'to_file'};
7048
7049                 $hash_parent ||= $diffinfo{'from_id'};
7050                 $hash        ||= $diffinfo{'to_id'};
7051
7052                 # non-textual hash id's can be cached
7053                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7054                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7055                         $expires = '+1d';
7056                 }
7057
7058                 # open patch output
7059                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7060                         '-p', ($format eq 'html' ? "--full-index" : ()),
7061                         $hash_parent_base, $hash_base,
7062                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7063                         or die_error(500, "Open git-diff-tree failed");
7064         }
7065
7066         # old/legacy style URI -- not generated anymore since 1.4.3.
7067         if (!%diffinfo) {
7068                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7069         }
7070
7071         # header
7072         if ($format eq 'html') {
7073                 my $formats_nav =
7074                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7075                                 "raw");
7076                 git_header_html(undef, $expires);
7077                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7078                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7079                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7080                 } else {
7081                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7082                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7083                 }
7084                 if (defined $file_name) {
7085                         git_print_page_path($file_name, "blob", $hash_base);
7086                 } else {
7087                         print "<div class=\"page_path\"></div>\n";
7088                 }
7089
7090         } elsif ($format eq 'plain') {
7091                 print $cgi->header(
7092                         -type => 'text/plain',
7093                         -charset => 'utf-8',
7094                         -expires => $expires,
7095                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7096
7097                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7098
7099         } else {
7100                 die_error(400, "Unknown blobdiff format");
7101         }
7102
7103         # patch
7104         if ($format eq 'html') {
7105                 print "<div class=\"page_body\">\n";
7106
7107                 git_patchset_body($fd, $input_params{diff_style} eq 'inline',
7108                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7109                 close $fd;
7110
7111                 print "</div>\n"; # class="page_body"
7112                 git_footer_html();
7113
7114         } else {
7115                 while (my $line = <$fd>) {
7116                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7117                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7118
7119                         print $line;
7120
7121                         last if $line =~ m!^\+\+\+!;
7122                 }
7123                 local $/ = undef;
7124                 print <$fd>;
7125                 close $fd;
7126         }
7127 }
7128
7129 sub git_blobdiff_plain {
7130         git_blobdiff('plain');
7131 }
7132
7133 sub diff_nav {
7134         my ($style) = @_;
7135
7136         my %pairs = (inline => 'inline', 'sidebyside' => 'side by side');
7137         join '', ($cgi->start_form({ method => 'get' }),
7138                   $cgi->hidden('p'),
7139                   $cgi->hidden('a'),
7140                   $cgi->hidden('h'),
7141                   $cgi->hidden('hp'),
7142                   $cgi->hidden('hb'),
7143                   $cgi->hidden('hpb'),
7144                   $cgi->popup_menu('ds', [keys %pairs], $style, \%pairs),
7145                   $cgi->submit('change'),
7146                   $cgi->end_form);
7147 }
7148
7149 sub git_commitdiff {
7150         my %params = @_;
7151         my $format = $params{-format} || 'html';
7152
7153         my ($patch_max) = gitweb_get_feature('patches');
7154         if ($format eq 'patch') {
7155                 die_error(403, "Patch view not allowed") unless $patch_max;
7156         }
7157
7158         $hash ||= $hash_base || "HEAD";
7159         my %co = parse_commit($hash)
7160             or die_error(404, "Unknown commit object");
7161
7162         # choose format for commitdiff for merge
7163         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7164                 $hash_parent = '--cc';
7165         }
7166         # we need to prepare $formats_nav before almost any parameter munging
7167         my $formats_nav;
7168         if ($format eq 'html') {
7169                 $formats_nav =
7170                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7171                                 "raw");
7172                 if ($patch_max && @{$co{'parents'}} <= 1) {
7173                         $formats_nav .= " | " .
7174                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7175                                         "patch");
7176                 }
7177
7178                 if (defined $hash_parent &&
7179                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7180                         # commitdiff with two commits given
7181                         my $hash_parent_short = $hash_parent;
7182                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7183                                 $hash_parent_short = substr($hash_parent, 0, 7);
7184                         }
7185                         $formats_nav .=
7186                                 ' (from';
7187                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7188                                 if ($co{'parents'}[$i] eq $hash_parent) {
7189                                         $formats_nav .= ' parent ' . ($i+1);
7190                                         last;
7191                                 }
7192                         }
7193                         $formats_nav .= ': ' .
7194                                 $cgi->a({-href => href(action=>"commitdiff",
7195                                                        hash=>$hash_parent)},
7196                                         esc_html($hash_parent_short)) .
7197                                 ')';
7198                 } elsif (!$co{'parent'}) {
7199                         # --root commitdiff
7200                         $formats_nav .= ' (initial)';
7201                 } elsif (scalar @{$co{'parents'}} == 1) {
7202                         # single parent commit
7203                         $formats_nav .=
7204                                 ' (parent: ' .
7205                                 $cgi->a({-href => href(action=>"commitdiff",
7206                                                        hash=>$co{'parent'})},
7207                                         esc_html(substr($co{'parent'}, 0, 7))) .
7208                                 ')';
7209                 } else {
7210                         # merge commit
7211                         if ($hash_parent eq '--cc') {
7212                                 $formats_nav .= ' | ' .
7213                                         $cgi->a({-href => href(action=>"commitdiff",
7214                                                                hash=>$hash, hash_parent=>'-c')},
7215                                                 'combined');
7216                         } else { # $hash_parent eq '-c'
7217                                 $formats_nav .= ' | ' .
7218                                         $cgi->a({-href => href(action=>"commitdiff",
7219                                                                hash=>$hash, hash_parent=>'--cc')},
7220                                                 'compact');
7221                         }
7222                         $formats_nav .=
7223                                 ' (merge: ' .
7224                                 join(' ', map {
7225                                         $cgi->a({-href => href(action=>"commitdiff",
7226                                                                hash=>$_)},
7227                                                 esc_html(substr($_, 0, 7)));
7228                                 } @{$co{'parents'}} ) .
7229                                 ')';
7230                 }
7231         }
7232
7233         my $hash_parent_param = $hash_parent;
7234         if (!defined $hash_parent_param) {
7235                 # --cc for multiple parents, --root for parentless
7236                 $hash_parent_param =
7237                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7238         }
7239
7240         # read commitdiff
7241         my $fd;
7242         my @difftree;
7243         if ($format eq 'html') {
7244                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7245                         "--no-commit-id", "--patch-with-raw", "--full-index",
7246                         $hash_parent_param, $hash, "--"
7247                         or die_error(500, "Open git-diff-tree failed");
7248
7249                 while (my $line = <$fd>) {
7250                         chomp $line;
7251                         # empty line ends raw part of diff-tree output
7252                         last unless $line;
7253                         push @difftree, scalar parse_difftree_raw_line($line);
7254                 }
7255
7256         } elsif ($format eq 'plain') {
7257                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7258                         '-p', $hash_parent_param, $hash, "--"
7259                         or die_error(500, "Open git-diff-tree failed");
7260         } elsif ($format eq 'patch') {
7261                 # For commit ranges, we limit the output to the number of
7262                 # patches specified in the 'patches' feature.
7263                 # For single commits, we limit the output to a single patch,
7264                 # diverging from the git-format-patch default.
7265                 my @commit_spec = ();
7266                 if ($hash_parent) {
7267                         if ($patch_max > 0) {
7268                                 push @commit_spec, "-$patch_max";
7269                         }
7270                         push @commit_spec, '-n', "$hash_parent..$hash";
7271                 } else {
7272                         if ($params{-single}) {
7273                                 push @commit_spec, '-1';
7274                         } else {
7275                                 if ($patch_max > 0) {
7276                                         push @commit_spec, "-$patch_max";
7277                                 }
7278                                 push @commit_spec, "-n";
7279                         }
7280                         push @commit_spec, '--root', $hash;
7281                 }
7282                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7283                         '--encoding=utf8', '--stdout', @commit_spec
7284                         or die_error(500, "Open git-format-patch failed");
7285         } else {
7286                 die_error(400, "Unknown commitdiff format");
7287         }
7288
7289         # non-textual hash id's can be cached
7290         my $expires;
7291         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7292                 $expires = "+1d";
7293         }
7294
7295         # write commit message
7296         if ($format eq 'html') {
7297                 my $refs = git_get_references();
7298                 my $ref = format_ref_marker($refs, $co{'id'});
7299
7300                 git_header_html(undef, $expires);
7301                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash,
7302                                    $formats_nav . diff_nav($input_params{diff_style}));
7303                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7304                 print "<div class=\"title_text\">\n" .
7305                       "<table class=\"object_header\">\n";
7306                 git_print_authorship_rows(\%co);
7307                 print "</table>".
7308                       "</div>\n";
7309                 print "<div class=\"page_body\">\n";
7310                 if (@{$co{'comment'}} > 1) {
7311                         print "<div class=\"log\">\n";
7312                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7313                         print "</div>\n"; # class="log"
7314                 }
7315
7316         } elsif ($format eq 'plain') {
7317                 my $refs = git_get_references("tags");
7318                 my $tagname = git_get_rev_name_tags($hash);
7319                 my $filename = basename($project) . "-$hash.patch";
7320
7321                 print $cgi->header(
7322                         -type => 'text/plain',
7323                         -charset => 'utf-8',
7324                         -expires => $expires,
7325                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7326                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7327                 print "From: " . to_utf8($co{'author'}) . "\n";
7328                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7329                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7330
7331                 print "X-Git-Tag: $tagname\n" if $tagname;
7332                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7333
7334                 foreach my $line (@{$co{'comment'}}) {
7335                         print to_utf8($line) . "\n";
7336                 }
7337                 print "---\n\n";
7338         } elsif ($format eq 'patch') {
7339                 my $filename = basename($project) . "-$hash.patch";
7340
7341                 print $cgi->header(
7342                         -type => 'text/plain',
7343                         -charset => 'utf-8',
7344                         -expires => $expires,
7345                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7346         }
7347
7348         # write patch
7349         if ($format eq 'html') {
7350                 my $use_parents = !defined $hash_parent ||
7351                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7352                 git_difftree_body(\@difftree, $hash,
7353                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7354                 print "<br/>\n";
7355
7356                 git_patchset_body($fd, $input_params{diff_style} eq 'inline',
7357                                   \@difftree, $hash,
7358                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7359                 close $fd;
7360                 print "</div>\n"; # class="page_body"
7361                 git_footer_html();
7362
7363         } elsif ($format eq 'plain') {
7364                 local $/ = undef;
7365                 print <$fd>;
7366                 close $fd
7367                         or print "Reading git-diff-tree failed\n";
7368         } elsif ($format eq 'patch') {
7369                 local $/ = undef;
7370                 print <$fd>;
7371                 close $fd
7372                         or print "Reading git-format-patch failed\n";
7373         }
7374 }
7375
7376 sub git_commitdiff_plain {
7377         git_commitdiff(-format => 'plain');
7378 }
7379
7380 # format-patch-style patches
7381 sub git_patch {
7382         git_commitdiff(-format => 'patch', -single => 1);
7383 }
7384
7385 sub git_patches {
7386         git_commitdiff(-format => 'patch');
7387 }
7388
7389 sub git_history {
7390         git_log_generic('history', \&git_history_body,
7391                         $hash_base, $hash_parent_base,
7392                         $file_name, $hash);
7393 }
7394
7395 sub git_search {
7396         $searchtype ||= 'commit';
7397
7398         # check if appropriate features are enabled
7399         gitweb_check_feature('search')
7400                 or die_error(403, "Search is disabled");
7401         if ($searchtype eq 'pickaxe') {
7402                 # pickaxe may take all resources of your box and run for several minutes
7403                 # with every query - so decide by yourself how public you make this feature
7404                 gitweb_check_feature('pickaxe')
7405                         or die_error(403, "Pickaxe search is disabled");
7406         }
7407         if ($searchtype eq 'grep') {
7408                 # grep search might be potentially CPU-intensive, too
7409                 gitweb_check_feature('grep')
7410                         or die_error(403, "Grep search is disabled");
7411         }
7412
7413         if (!defined $searchtext) {
7414                 die_error(400, "Text field is empty");
7415         }
7416         if (!defined $hash) {
7417                 $hash = git_get_head_hash($project);
7418         }
7419         my %co = parse_commit($hash);
7420         if (!%co) {
7421                 die_error(404, "Unknown commit object");
7422         }
7423         if (!defined $page) {
7424                 $page = 0;
7425         }
7426
7427         if ($searchtype eq 'commit' ||
7428             $searchtype eq 'author' ||
7429             $searchtype eq 'committer') {
7430                 git_search_message(%co);
7431         } elsif ($searchtype eq 'pickaxe') {
7432                 git_search_changes(%co);
7433         } elsif ($searchtype eq 'grep') {
7434                 git_search_files(%co);
7435         } else {
7436                 die_error(400, "Unknown search type");
7437         }
7438 }
7439
7440 sub git_search_help {
7441         git_header_html();
7442         git_print_page_nav('','', $hash,$hash,$hash);
7443         print <<EOT;
7444 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7445 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7446 the pattern entered is recognized as the POSIX extended
7447 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7448 insensitive).</p>
7449 <dl>
7450 <dt><b>commit</b></dt>
7451 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7452 EOT
7453         my $have_grep = gitweb_check_feature('grep');
7454         if ($have_grep) {
7455                 print <<EOT;
7456 <dt><b>grep</b></dt>
7457 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7458     a different one) are searched for the given pattern. On large trees, this search can take
7459 a while and put some strain on the server, so please use it with some consideration. Note that
7460 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7461 case-sensitive.</dd>
7462 EOT
7463         }
7464         print <<EOT;
7465 <dt><b>author</b></dt>
7466 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7467 <dt><b>committer</b></dt>
7468 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7469 EOT
7470         my $have_pickaxe = gitweb_check_feature('pickaxe');
7471         if ($have_pickaxe) {
7472                 print <<EOT;
7473 <dt><b>pickaxe</b></dt>
7474 <dd>All commits that caused the string to appear or disappear from any file (changes that
7475 added, removed or "modified" the string) will be listed. This search can take a while and
7476 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7477 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7478 EOT
7479         }
7480         print "</dl>\n";
7481         git_footer_html();
7482 }
7483
7484 sub git_shortlog {
7485         git_log_generic('shortlog', \&git_shortlog_body,
7486                         $hash, $hash_parent);
7487 }
7488
7489 ## ......................................................................
7490 ## feeds (RSS, Atom; OPML)
7491
7492 sub git_feed {
7493         my $format = shift || 'atom';
7494         my $have_blame = gitweb_check_feature('blame');
7495
7496         # Atom: http://www.atomenabled.org/developers/syndication/
7497         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7498         if ($format ne 'rss' && $format ne 'atom') {
7499                 die_error(400, "Unknown web feed format");
7500         }
7501
7502         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7503         my $head = $hash || 'HEAD';
7504         my @commitlist = parse_commits($head, 150, 0, $file_name);
7505
7506         my %latest_commit;
7507         my %latest_date;
7508         my $content_type = "application/$format+xml";
7509         if (defined $cgi->http('HTTP_ACCEPT') &&
7510                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7511                 # browser (feed reader) prefers text/xml
7512                 $content_type = 'text/xml';
7513         }
7514         if (defined($commitlist[0])) {
7515                 %latest_commit = %{$commitlist[0]};
7516                 my $latest_epoch = $latest_commit{'committer_epoch'};
7517                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7518                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7519                 if (defined $if_modified) {
7520                         my $since;
7521                         if (eval { require HTTP::Date; 1; }) {
7522                                 $since = HTTP::Date::str2time($if_modified);
7523                         } elsif (eval { require Time::ParseDate; 1; }) {
7524                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7525                         }
7526                         if (defined $since && $latest_epoch <= $since) {
7527                                 print $cgi->header(
7528                                         -type => $content_type,
7529                                         -charset => 'utf-8',
7530                                         -last_modified => $latest_date{'rfc2822'},
7531                                         -status => '304 Not Modified');
7532                                 return;
7533                         }
7534                 }
7535                 print $cgi->header(
7536                         -type => $content_type,
7537                         -charset => 'utf-8',
7538                         -last_modified => $latest_date{'rfc2822'});
7539         } else {
7540                 print $cgi->header(
7541                         -type => $content_type,
7542                         -charset => 'utf-8');
7543         }
7544
7545         # Optimization: skip generating the body if client asks only
7546         # for Last-Modified date.
7547         return if ($cgi->request_method() eq 'HEAD');
7548
7549         # header variables
7550         my $title = "$site_name - $project/$action";
7551         my $feed_type = 'log';
7552         if (defined $hash) {
7553                 $title .= " - '$hash'";
7554                 $feed_type = 'branch log';
7555                 if (defined $file_name) {
7556                         $title .= " :: $file_name";
7557                         $feed_type = 'history';
7558                 }
7559         } elsif (defined $file_name) {
7560                 $title .= " - $file_name";
7561                 $feed_type = 'history';
7562         }
7563         $title .= " $feed_type";
7564         my $descr = git_get_project_description($project);
7565         if (defined $descr) {
7566                 $descr = esc_html($descr);
7567         } else {
7568                 $descr = "$project " .
7569                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7570                          " feed";
7571         }
7572         my $owner = git_get_project_owner($project);
7573         $owner = esc_html($owner);
7574
7575         #header
7576         my $alt_url;
7577         if (defined $file_name) {
7578                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7579         } elsif (defined $hash) {
7580                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7581         } else {
7582                 $alt_url = href(-full=>1, action=>"summary");
7583         }
7584         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7585         if ($format eq 'rss') {
7586                 print <<XML;
7587 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7588 <channel>
7589 XML
7590                 print "<title>$title</title>\n" .
7591                       "<link>$alt_url</link>\n" .
7592                       "<description>$descr</description>\n" .
7593                       "<language>en</language>\n" .
7594                       # project owner is responsible for 'editorial' content
7595                       "<managingEditor>$owner</managingEditor>\n";
7596                 if (defined $logo || defined $favicon) {
7597                         # prefer the logo to the favicon, since RSS
7598                         # doesn't allow both
7599                         my $img = esc_url($logo || $favicon);
7600                         print "<image>\n" .
7601                               "<url>$img</url>\n" .
7602                               "<title>$title</title>\n" .
7603                               "<link>$alt_url</link>\n" .
7604                               "</image>\n";
7605                 }
7606                 if (%latest_date) {
7607                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7608                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7609                 }
7610                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7611         } elsif ($format eq 'atom') {
7612                 print <<XML;
7613 <feed xmlns="http://www.w3.org/2005/Atom">
7614 XML
7615                 print "<title>$title</title>\n" .
7616                       "<subtitle>$descr</subtitle>\n" .
7617                       '<link rel="alternate" type="text/html" href="' .
7618                       $alt_url . '" />' . "\n" .
7619                       '<link rel="self" type="' . $content_type . '" href="' .
7620                       $cgi->self_url() . '" />' . "\n" .
7621                       "<id>" . href(-full=>1) . "</id>\n" .
7622                       # use project owner for feed author
7623                       "<author><name>$owner</name></author>\n";
7624                 if (defined $favicon) {
7625                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7626                 }
7627                 if (defined $logo) {
7628                         # not twice as wide as tall: 72 x 27 pixels
7629                         print "<logo>" . esc_url($logo) . "</logo>\n";
7630                 }
7631                 if (! %latest_date) {
7632                         # dummy date to keep the feed valid until commits trickle in:
7633                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7634                 } else {
7635                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7636                 }
7637                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7638         }
7639
7640         # contents
7641         for (my $i = 0; $i <= $#commitlist; $i++) {
7642                 my %co = %{$commitlist[$i]};
7643                 my $commit = $co{'id'};
7644                 # we read 150, we always show 30 and the ones more recent than 48 hours
7645                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7646                         last;
7647                 }
7648                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7649
7650                 # get list of changed files
7651                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7652                         $co{'parent'} || "--root",
7653                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7654                         or next;
7655                 my @difftree = map { chomp; $_ } <$fd>;
7656                 close $fd
7657                         or next;
7658
7659                 # print element (entry, item)
7660                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7661                 if ($format eq 'rss') {
7662                         print "<item>\n" .
7663                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7664                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7665                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7666                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7667                               "<link>$co_url</link>\n" .
7668                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7669                               "<content:encoded>" .
7670                               "<![CDATA[\n";
7671                 } elsif ($format eq 'atom') {
7672                         print "<entry>\n" .
7673                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7674                               "<updated>$cd{'iso-8601'}</updated>\n" .
7675                               "<author>\n" .
7676                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7677                         if ($co{'author_email'}) {
7678                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7679                         }
7680                         print "</author>\n" .
7681                               # use committer for contributor
7682                               "<contributor>\n" .
7683                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7684                         if ($co{'committer_email'}) {
7685                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7686                         }
7687                         print "</contributor>\n" .
7688                               "<published>$cd{'iso-8601'}</published>\n" .
7689                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7690                               "<id>$co_url</id>\n" .
7691                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7692                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7693                 }
7694                 my $comment = $co{'comment'};
7695                 print "<pre>\n";
7696                 foreach my $line (@$comment) {
7697                         $line = esc_html($line);
7698                         print "$line\n";
7699                 }
7700                 print "</pre><ul>\n";
7701                 foreach my $difftree_line (@difftree) {
7702                         my %difftree = parse_difftree_raw_line($difftree_line);
7703                         next if !$difftree{'from_id'};
7704
7705                         my $file = $difftree{'file'} || $difftree{'to_file'};
7706
7707                         print "<li>" .
7708                               "[" .
7709                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7710                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7711                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7712                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7713                                       -title => "diff"}, 'D');
7714                         if ($have_blame) {
7715                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7716                                                              file_name=>$file, hash_base=>$commit),
7717                                               -title => "blame"}, 'B');
7718                         }
7719                         # if this is not a feed of a file history
7720                         if (!defined $file_name || $file_name ne $file) {
7721                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7722                                                              file_name=>$file, hash=>$commit),
7723                                               -title => "history"}, 'H');
7724                         }
7725                         $file = esc_path($file);
7726                         print "] ".
7727                               "$file</li>\n";
7728                 }
7729                 if ($format eq 'rss') {
7730                         print "</ul>]]>\n" .
7731                               "</content:encoded>\n" .
7732                               "</item>\n";
7733                 } elsif ($format eq 'atom') {
7734                         print "</ul>\n</div>\n" .
7735                               "</content>\n" .
7736                               "</entry>\n";
7737                 }
7738         }
7739
7740         # end of feed
7741         if ($format eq 'rss') {
7742                 print "</channel>\n</rss>\n";
7743         } elsif ($format eq 'atom') {
7744                 print "</feed>\n";
7745         }
7746 }
7747
7748 sub git_rss {
7749         git_feed('rss');
7750 }
7751
7752 sub git_atom {
7753         git_feed('atom');
7754 }
7755
7756 sub git_opml {
7757         my @list = git_get_projects_list();
7758         if (!@list) {
7759                 die_error(404, "No projects found");
7760         }
7761
7762         print $cgi->header(
7763                 -type => 'text/xml',
7764                 -charset => 'utf-8',
7765                 -content_disposition => 'inline; filename="opml.xml"');
7766
7767         print <<XML;
7768 <?xml version="1.0" encoding="utf-8"?>
7769 <opml version="1.0">
7770 <head>
7771   <title>$site_name OPML Export</title>
7772 </head>
7773 <body>
7774 <outline text="git RSS feeds">
7775 XML
7776
7777         foreach my $pr (@list) {
7778                 my %proj = %$pr;
7779                 my $head = git_get_head_hash($proj{'path'});
7780                 if (!defined $head) {
7781                         next;
7782                 }
7783                 $git_dir = "$projectroot/$proj{'path'}";
7784                 my %co = parse_commit($head);
7785                 if (!%co) {
7786                         next;
7787                 }
7788
7789                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7790                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7791                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7792                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7793         }
7794         print <<XML;
7795 </outline>
7796 </body>
7797 </opml>
7798 XML
7799 }