gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  24         eval 'sub CGI::multi_param { CGI::param(@_) }'
  25 }
  26
  27 our $t0 = [ gettimeofday() ];
  28 our $number_of_git_cmds = 0;
  29
  30 BEGIN {
  31         CGI->compile() if $ENV{'MOD_PERL'};
  32 }
  33
  34 our $version = "++GIT_VERSION++";
  35
  36 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  37 sub evaluate_uri {
  38         our $cgi;
  39
  40         our $my_url = $cgi->url();
  41         our $my_uri = $cgi->url(-absolute => 1);
  42
  43         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  44         # needed and used only for URLs with nonempty PATH_INFO
  45         our $base_url = $my_url;
  46
  47         # When the script is used as DirectoryIndex, the URL does not contain the name
  48         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  49         # have to do it ourselves. We make $path_info global because it's also used
  50         # later on.
  51         #
  52         # Another issue with the script being the DirectoryIndex is that the resulting
  53         # $my_url data is not the full script URL: this is good, because we want
  54         # generated links to keep implying the script name if it wasn't explicitly
  55         # indicated in the URL we're handling, but it means that $my_url cannot be used
  56         # as base URL.
  57         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  58         # to build the base URL ourselves:
  59         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  60         if ($path_info) {
  61                 # $path_info has already been URL-decoded by the web server, but
  62                 # $my_url and $my_uri have not. URL-decode them so we can properly
  63                 # strip $path_info.
  64                 $my_url = unescape($my_url);
  65                 $my_uri = unescape($my_uri);
  66                 if ($my_url =~ s,\Q$path_info\E$,, &&
  67                     $my_uri =~ s,\Q$path_info\E$,, &&
  68                     defined $ENV{'SCRIPT_NAME'}) {
  69                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  70                 }
  71         }
  72
  73         # target of the home link on top of all pages
  74         our $home_link = $my_uri || "/";
  75 }
  76
  77 # core git executable to use
  78 # this can just be "git" if your webserver has a sensible PATH
  79 our $GIT = "++GIT_BINDIR++/git";
  80
  81 # absolute fs-path which will be prepended to the project path
  82 #our $projectroot = "/pub/scm";
  83 our $projectroot = "++GITWEB_PROJECTROOT++";
  84
  85 # fs traversing limit for getting project list
  86 # the number is relative to the projectroot
  87 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  88
  89 # string of the home link on top of all pages
  90 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  91
  92 # extra breadcrumbs preceding the home link
  93 our @extra_breadcrumbs = ();
  94
  95 # name of your site or organization to appear in page titles
  96 # replace this with something more descriptive for clearer bookmarks
  97 our $site_name = "++GITWEB_SITENAME++"
  98                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  99
 100 # html snippet to include in the <head> section of each page
 101 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
 102 # filename of html text to include at top of each page
 103 our $site_header = "++GITWEB_SITE_HEADER++";
 104 # html text to include at home page
 105 our $home_text = "++GITWEB_HOMETEXT++";
 106 # filename of html text to include at bottom of each page
 107 our $site_footer = "++GITWEB_SITE_FOOTER++";
 108
 109 # URI of stylesheets
 110 our @stylesheets = ("++GITWEB_CSS++");
 111 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 112 our $stylesheet = undef;
 113 # URI of GIT logo (72x27 size)
 114 our $logo = "++GITWEB_LOGO++";
 115 # URI of GIT favicon, assumed to be image/png type
 116 our $favicon = "++GITWEB_FAVICON++";
 117 # URI of gitweb.js (JavaScript code for gitweb)
 118 our $javascript = "++GITWEB_JS++";
 119
 120 # URI and label (title) of GIT logo link
 121 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 122 #our $logo_label = "git documentation";
 123 our $logo_url = "http://git-scm.com/";
 124 our $logo_label = "git homepage";
 125
 126 # source of projects list
 127 our $projects_list = "++GITWEB_LIST++";
 128
 129 # the width (in characters) of the projects list "Description" column
 130 our $projects_list_description_width = 25;
 131
 132 # group projects by category on the projects list
 133 # (enabled if this variable evaluates to true)
 134 our $projects_list_group_categories = 0;
 135
 136 # default category if none specified
 137 # (leave the empty string for no category)
 138 our $project_list_default_category = "";
 139
 140 # default order of projects list
 141 # valid values are none, project, descr, owner, and age
 142 our $default_projects_order = "project";
 143
 144 # show repository only if this file exists
 145 # (only effective if this variable evaluates to true)
 146 our $export_ok = "++GITWEB_EXPORT_OK++";
 147
 148 # don't generate age column on the projects list page
 149 our $omit_age_column = 0;
 150
 151 # don't generate information about owners of repositories
 152 our $omit_owner=0;
 153
 154 # show repository only if this subroutine returns true
 155 # when given the path to the project, for example:
 156 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 157 our $export_auth_hook = undef;
 158
 159 # only allow viewing of repositories also shown on the overview page
 160 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 161
 162 # list of git base URLs used for URL to where fetch project from,
 163 # i.e. full URL is "$git_base_url/$project"
 164 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 165
 166 # default blob_plain mimetype and default charset for text/plain blob
 167 our $default_blob_plain_mimetype = 'text/plain';
 168 our $default_text_plain_charset  = undef;
 169
 170 # file to use for guessing MIME types before trying /etc/mime.types
 171 # (relative to the current git repository)
 172 our $mimetypes_file = undef;
 173
 174 # assume this charset if line contains non-UTF-8 characters;
 175 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 176 # for which encoding all byte sequences are valid, for example
 177 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 178 # could be even 'utf-8' for the old behavior)
 179 our $fallback_encoding = 'latin1';
 180
 181 # rename detection options for git-diff and git-diff-tree
 182 # - default is '-M', with the cost proportional to
 183 #   (number of removed files) * (number of new files).
 184 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 185 #   (number of changed files + number of removed files) * (number of new files)
 186 # - even more costly is '-C', '--find-copies-harder' with cost
 187 #   (number of files in the original tree) * (number of new files)
 188 # - one might want to include '-B' option, e.g. '-B', '-M'
 189 our @diff_opts = ('-M'); # taken from git_commit
 190
 191 # Disables features that would allow repository owners to inject script into
 192 # the gitweb domain.
 193 our $prevent_xss = 0;
 194
 195 # Path to the highlight executable to use (must be the one from
 196 # http://www.andre-simon.de due to assumptions about parameters and output).
 197 # Useful if highlight is not installed on your webserver's PATH.
 198 # [Default: highlight]
 199 our $highlight_bin = "++HIGHLIGHT_BIN++";
 200
 201 # information about snapshot formats that gitweb is capable of serving
 202 our %known_snapshot_formats = (
 203         # name => {
 204         #       'display' => display name,
 205         #       'type' => mime type,
 206         #       'suffix' => filename suffix,
 207         #       'format' => --format for git-archive,
 208         #       'compressor' => [compressor command and arguments]
 209         #                       (array reference, optional)
 210         #       'disabled' => boolean (optional)}
 211         #
 212         'tgz' => {
 213                 'display' => 'tar.gz',
 214                 'type' => 'application/x-gzip',
 215                 'suffix' => '.tar.gz',
 216                 'format' => 'tar',
 217                 'compressor' => ['gzip', '-n']},
 218
 219         'tbz2' => {
 220                 'display' => 'tar.bz2',
 221                 'type' => 'application/x-bzip2',
 222                 'suffix' => '.tar.bz2',
 223                 'format' => 'tar',
 224                 'compressor' => ['bzip2']},
 225
 226         'txz' => {
 227                 'display' => 'tar.xz',
 228                 'type' => 'application/x-xz',
 229                 'suffix' => '.tar.xz',
 230                 'format' => 'tar',
 231                 'compressor' => ['xz'],
 232                 'disabled' => 1},
 233
 234         'zip' => {
 235                 'display' => 'zip',
 236                 'type' => 'application/x-zip',
 237                 'suffix' => '.zip',
 238                 'format' => 'zip'},
 239 );
 240
 241 # Aliases so we understand old gitweb.snapshot values in repository
 242 # configuration.
 243 our %known_snapshot_format_aliases = (
 244         'gzip'  => 'tgz',
 245         'bzip2' => 'tbz2',
 246         'xz'    => 'txz',
 247
 248         # backward compatibility: legacy gitweb config support
 249         'x-gzip' => undef, 'gz' => undef,
 250         'x-bzip2' => undef, 'bz2' => undef,
 251         'x-zip' => undef, '' => undef,
 252 );
 253
 254 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 255 # are changed, it may be appropriate to change these values too via
 256 # $GITWEB_CONFIG.
 257 our %avatar_size = (
 258         'default' => 16,
 259         'double'  => 32
 260 );
 261
 262 # Used to set the maximum load that we will still respond to gitweb queries.
 263 # If server load exceed this value then return "503 server busy" error.
 264 # If gitweb cannot determined server load, it is taken to be 0.
 265 # Leave it undefined (or set to 'undef') to turn off load checking.
 266 our $maxload = 300;
 267
 268 # configuration for 'highlight' (http://www.andre-simon.de/)
 269 # match by basename
 270 our %highlight_basename = (
 271         #'Program' => 'py',
 272         #'Library' => 'py',
 273         'SConstruct' => 'py', # SCons equivalent of Makefile
 274         'Makefile' => 'make',
 275 );
 276 # match by extension
 277 our %highlight_ext = (
 278         # main extensions, defining name of syntax;
 279         # see files in /usr/share/highlight/langDefs/ directory
 280         (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
 281         # alternate extensions, see /etc/highlight/filetypes.conf
 282         (map { $_ => 'c'   } qw(c h)),
 283         (map { $_ => 'sh'  } qw(sh bash zsh ksh)),
 284         (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
 285         (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
 286         (map { $_ => 'pl'  } qw(pl perl pm)), # perhaps also 'cgi'
 287         (map { $_ => 'make'} qw(make mak mk)),
 288         (map { $_ => 'xml' } qw(xml xhtml html htm)),
 289 );
 290
 291 # You define site-wide feature defaults here; override them with
 292 # $GITWEB_CONFIG as necessary.
 293 our %feature = (
 294         # feature => {
 295         #       'sub' => feature-sub (subroutine),
 296         #       'override' => allow-override (boolean),
 297         #       'default' => [ default options...] (array reference)}
 298         #
 299         # if feature is overridable (it means that allow-override has true value),
 300         # then feature-sub will be called with default options as parameters;
 301         # return value of feature-sub indicates if to enable specified feature
 302         #
 303         # if there is no 'sub' key (no feature-sub), then feature cannot be
 304         # overridden
 305         #
 306         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 307         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 308         # is enabled
 309
 310         # Enable the 'blame' blob view, showing the last commit that modified
 311         # each line in the file. This can be very CPU-intensive.
 312
 313         # To enable system wide have in $GITWEB_CONFIG
 314         # $feature{'blame'}{'default'} = [1];
 315         # To have project specific config enable override in $GITWEB_CONFIG
 316         # $feature{'blame'}{'override'} = 1;
 317         # and in project config gitweb.blame = 0|1;
 318         'blame' => {
 319                 'sub' => sub { feature_bool('blame', @_) },
 320                 'override' => 0,
 321                 'default' => [0]},
 322
 323         # Enable the 'snapshot' link, providing a compressed archive of any
 324         # tree. This can potentially generate high traffic if you have large
 325         # project.
 326
 327         # Value is a list of formats defined in %known_snapshot_formats that
 328         # you wish to offer.
 329         # To disable system wide have in $GITWEB_CONFIG
 330         # $feature{'snapshot'}{'default'} = [];
 331         # To have project specific config enable override in $GITWEB_CONFIG
 332         # $feature{'snapshot'}{'override'} = 1;
 333         # and in project config, a comma-separated list of formats or "none"
 334         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 335         'snapshot' => {
 336                 'sub' => \&feature_snapshot,
 337                 'override' => 0,
 338                 'default' => ['tgz']},
 339
 340         # Enable text search, which will list the commits which match author,
 341         # committer or commit text to a given string.  Enabled by default.
 342         # Project specific override is not supported.
 343         #
 344         # Note that this controls all search features, which means that if
 345         # it is disabled, then 'grep' and 'pickaxe' search would also be
 346         # disabled.
 347         'search' => {
 348                 'override' => 0,
 349                 'default' => [1]},
 350
 351         # Enable grep search, which will list the files in currently selected
 352         # tree containing the given string. Enabled by default. This can be
 353         # potentially CPU-intensive, of course.
 354         # Note that you need to have 'search' feature enabled too.
 355
 356         # To enable system wide have in $GITWEB_CONFIG
 357         # $feature{'grep'}{'default'} = [1];
 358         # To have project specific config enable override in $GITWEB_CONFIG
 359         # $feature{'grep'}{'override'} = 1;
 360         # and in project config gitweb.grep = 0|1;
 361         'grep' => {
 362                 'sub' => sub { feature_bool('grep', @_) },
 363                 'override' => 0,
 364                 'default' => [1]},
 365
 366         # Enable the pickaxe search, which will list the commits that modified
 367         # a given string in a file. This can be practical and quite faster
 368         # alternative to 'blame', but still potentially CPU-intensive.
 369         # Note that you need to have 'search' feature enabled too.
 370
 371         # To enable system wide have in $GITWEB_CONFIG
 372         # $feature{'pickaxe'}{'default'} = [1];
 373         # To have project specific config enable override in $GITWEB_CONFIG
 374         # $feature{'pickaxe'}{'override'} = 1;
 375         # and in project config gitweb.pickaxe = 0|1;
 376         'pickaxe' => {
 377                 'sub' => sub { feature_bool('pickaxe', @_) },
 378                 'override' => 0,
 379                 'default' => [1]},
 380
 381         # Enable showing size of blobs in a 'tree' view, in a separate
 382         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 383
 384         # To disable system wide have in $GITWEB_CONFIG
 385         # $feature{'show-sizes'}{'default'} = [0];
 386         # To have project specific config enable override in $GITWEB_CONFIG
 387         # $feature{'show-sizes'}{'override'} = 1;
 388         # and in project config gitweb.showsizes = 0|1;
 389         'show-sizes' => {
 390                 'sub' => sub { feature_bool('showsizes', @_) },
 391                 'override' => 0,
 392                 'default' => [1]},
 393
 394         # Make gitweb use an alternative format of the URLs which can be
 395         # more readable and natural-looking: project name is embedded
 396         # directly in the path and the query string contains other
 397         # auxiliary information. All gitweb installations recognize
 398         # URL in either format; this configures in which formats gitweb
 399         # generates links.
 400
 401         # To enable system wide have in $GITWEB_CONFIG
 402         # $feature{'pathinfo'}{'default'} = [1];
 403         # Project specific override is not supported.
 404
 405         # Note that you will need to change the default location of CSS,
 406         # favicon, logo and possibly other files to an absolute URL. Also,
 407         # if gitweb.cgi serves as your indexfile, you will need to force
 408         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 409         'pathinfo' => {
 410                 'override' => 0,
 411                 'default' => [0]},
 412
 413         # Make gitweb consider projects in project root subdirectories
 414         # to be forks of existing projects. Given project $projname.git,
 415         # projects matching $projname/*.git will not be shown in the main
 416         # projects list, instead a '+' mark will be added to $projname
 417         # there and a 'forks' view will be enabled for the project, listing
 418         # all the forks. If project list is taken from a file, forks have
 419         # to be listed after the main project.
 420
 421         # To enable system wide have in $GITWEB_CONFIG
 422         # $feature{'forks'}{'default'} = [1];
 423         # Project specific override is not supported.
 424         'forks' => {
 425                 'override' => 0,
 426                 'default' => [0]},
 427
 428         # Insert custom links to the action bar of all project pages.
 429         # This enables you mainly to link to third-party scripts integrating
 430         # into gitweb; e.g. git-browser for graphical history representation
 431         # or custom web-based repository administration interface.
 432
 433         # The 'default' value consists of a list of triplets in the form
 434         # (label, link, position) where position is the label after which
 435         # to insert the link and link is a format string where %n expands
 436         # to the project name, %f to the project path within the filesystem,
 437         # %h to the current hash (h gitweb parameter) and %b to the current
 438         # hash base (hb gitweb parameter); %% expands to %.
 439
 440         # To enable system wide have in $GITWEB_CONFIG e.g.
 441         # $feature{'actions'}{'default'} = [('graphiclog',
 442         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 443         # Project specific override is not supported.
 444         'actions' => {
 445                 'override' => 0,
 446                 'default' => []},
 447
 448         # Allow gitweb scan project content tags of project repository,
 449         # and display the popular Web 2.0-ish "tag cloud" near the projects
 450         # list.  Note that this is something COMPLETELY different from the
 451         # normal Git tags.
 452
 453         # gitweb by itself can show existing tags, but it does not handle
 454         # tagging itself; you need to do it externally, outside gitweb.
 455         # The format is described in git_get_project_ctags() subroutine.
 456         # You may want to install the HTML::TagCloud Perl module to get
 457         # a pretty tag cloud instead of just a list of tags.
 458
 459         # To enable system wide have in $GITWEB_CONFIG
 460         # $feature{'ctags'}{'default'} = [1];
 461         # Project specific override is not supported.
 462
 463         # In the future whether ctags editing is enabled might depend
 464         # on the value, but using 1 should always mean no editing of ctags.
 465         'ctags' => {
 466                 'override' => 0,
 467                 'default' => [0]},
 468
 469         # The maximum number of patches in a patchset generated in patch
 470         # view. Set this to 0 or undef to disable patch view, or to a
 471         # negative number to remove any limit.
 472
 473         # To disable system wide have in $GITWEB_CONFIG
 474         # $feature{'patches'}{'default'} = [0];
 475         # To have project specific config enable override in $GITWEB_CONFIG
 476         # $feature{'patches'}{'override'} = 1;
 477         # and in project config gitweb.patches = 0|n;
 478         # where n is the maximum number of patches allowed in a patchset.
 479         'patches' => {
 480                 'sub' => \&feature_patches,
 481                 'override' => 0,
 482                 'default' => [16]},
 483
 484         # Avatar support. When this feature is enabled, views such as
 485         # shortlog or commit will display an avatar associated with
 486         # the email of the committer(s) and/or author(s).
 487
 488         # Currently available providers are gravatar and picon.
 489         # If an unknown provider is specified, the feature is disabled.
 490
 491         # Gravatar depends on Digest::MD5.
 492         # Picon currently relies on the indiana.edu database.
 493
 494         # To enable system wide have in $GITWEB_CONFIG
 495         # $feature{'avatar'}{'default'} = ['<provider>'];
 496         # where <provider> is either gravatar or picon.
 497         # To have project specific config enable override in $GITWEB_CONFIG
 498         # $feature{'avatar'}{'override'} = 1;
 499         # and in project config gitweb.avatar = <provider>;
 500         'avatar' => {
 501                 'sub' => \&feature_avatar,
 502                 'override' => 0,
 503                 'default' => ['']},
 504
 505         # Enable displaying how much time and how many git commands
 506         # it took to generate and display page.  Disabled by default.
 507         # Project specific override is not supported.
 508         'timed' => {
 509                 'override' => 0,
 510                 'default' => [0]},
 511
 512         # Enable turning some links into links to actions which require
 513         # JavaScript to run (like 'blame_incremental').  Not enabled by
 514         # default.  Project specific override is currently not supported.
 515         'javascript-actions' => {
 516                 'override' => 0,
 517                 'default' => [0]},
 518
 519         # Enable and configure ability to change common timezone for dates
 520         # in gitweb output via JavaScript.  Enabled by default.
 521         # Project specific override is not supported.
 522         'javascript-timezone' => {
 523                 'override' => 0,
 524                 'default' => [
 525                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 526                                      # or undef to turn off this feature
 527                         'gitweb_tz', # name of cookie where to store selected timezone
 528                         'datetime',  # CSS class used to mark up dates for manipulation
 529                 ]},
 530
 531         # Syntax highlighting support. This is based on Daniel Svensson's
 532         # and Sham Chukoury's work in gitweb-xmms2.git.
 533         # It requires the 'highlight' program present in $PATH,
 534         # and therefore is disabled by default.
 535
 536         # To enable system wide have in $GITWEB_CONFIG
 537         # $feature{'highlight'}{'default'} = [1];
 538
 539         'highlight' => {
 540                 'sub' => sub { feature_bool('highlight', @_) },
 541                 'override' => 0,
 542                 'default' => [0]},
 543
 544         # Enable displaying of remote heads in the heads list
 545
 546         # To enable system wide have in $GITWEB_CONFIG
 547         # $feature{'remote_heads'}{'default'} = [1];
 548         # To have project specific config enable override in $GITWEB_CONFIG
 549         # $feature{'remote_heads'}{'override'} = 1;
 550         # and in project config gitweb.remoteheads = 0|1;
 551         'remote_heads' => {
 552                 'sub' => sub { feature_bool('remote_heads', @_) },
 553                 'override' => 0,
 554                 'default' => [0]},
 555
 556         # Enable showing branches under other refs in addition to heads
 557
 558         # To set system wide extra branch refs have in $GITWEB_CONFIG
 559         # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
 560         # To have project specific config enable override in $GITWEB_CONFIG
 561         # $feature{'extra-branch-refs'}{'override'} = 1;
 562         # and in project config gitweb.extrabranchrefs = dirs of choice
 563         # Every directory is separated with whitespace.
 564
 565         'extra-branch-refs' => {
 566                 'sub' => \&feature_extra_branch_refs,
 567                 'override' => 0,
 568                 'default' => []},
 569 );
 570
 571 sub gitweb_get_feature {
 572         my ($name) = @_;
 573         return unless exists $feature{$name};
 574         my ($sub, $override, @defaults) = (
 575                 $feature{$name}{'sub'},
 576                 $feature{$name}{'override'},
 577                 @{$feature{$name}{'default'}});
 578         # project specific override is possible only if we have project
 579         our $git_dir; # global variable, declared later
 580         if (!$override || !defined $git_dir) {
 581                 return @defaults;
 582         }
 583         if (!defined $sub) {
 584                 warn "feature $name is not overridable";
 585                 return @defaults;
 586         }
 587         return $sub->(@defaults);
 588 }
 589
 590 # A wrapper to check if a given feature is enabled.
 591 # With this, you can say
 592 #
 593 #   my $bool_feat = gitweb_check_feature('bool_feat');
 594 #   gitweb_check_feature('bool_feat') or somecode;
 595 #
 596 # instead of
 597 #
 598 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 599 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 600 #
 601 sub gitweb_check_feature {
 602         return (gitweb_get_feature(@_))[0];
 603 }
 604
 605
 606 sub feature_bool {
 607         my $key = shift;
 608         my ($val) = git_get_project_config($key, '--bool');
 609
 610         if (!defined $val) {
 611                 return ($_[0]);
 612         } elsif ($val eq 'true') {
 613                 return (1);
 614         } elsif ($val eq 'false') {
 615                 return (0);
 616         }
 617 }
 618
 619 sub feature_snapshot {
 620         my (@fmts) = @_;
 621
 622         my ($val) = git_get_project_config('snapshot');
 623
 624         if ($val) {
 625                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 626         }
 627
 628         return @fmts;
 629 }
 630
 631 sub feature_patches {
 632         my @val = (git_get_project_config('patches', '--int'));
 633
 634         if (@val) {
 635                 return @val;
 636         }
 637
 638         return ($_[0]);
 639 }
 640
 641 sub feature_avatar {
 642         my @val = (git_get_project_config('avatar'));
 643
 644         return @val ? @val : @_;
 645 }
 646
 647 sub feature_extra_branch_refs {
 648         my (@branch_refs) = @_;
 649         my $values = git_get_project_config('extrabranchrefs');
 650
 651         if ($values) {
 652                 $values = config_to_multi ($values);
 653                 @branch_refs = ();
 654                 foreach my $value (@{$values}) {
 655                         push @branch_refs, split /\s+/, $value;
 656                 }
 657         }
 658
 659         return @branch_refs;
 660 }
 661
 662 # checking HEAD file with -e is fragile if the repository was
 663 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 664 # and then pruned.
 665 sub check_head_link {
 666         my ($dir) = @_;
 667         my $headfile = "$dir/HEAD";
 668         return ((-e $headfile) ||
 669                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 670 }
 671
 672 sub check_export_ok {
 673         my ($dir) = @_;
 674         return (check_head_link($dir) &&
 675                 (!$export_ok || -e "$dir/$export_ok") &&
 676                 (!$export_auth_hook || $export_auth_hook->($dir)));
 677 }
 678
 679 # process alternate names for backward compatibility
 680 # filter out unsupported (unknown) snapshot formats
 681 sub filter_snapshot_fmts {
 682         my @fmts = @_;
 683
 684         @fmts = map {
 685                 exists $known_snapshot_format_aliases{$_} ?
 686                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 687         @fmts = grep {
 688                 exists $known_snapshot_formats{$_} &&
 689                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 690 }
 691
 692 sub filter_and_validate_refs {
 693         my @refs = @_;
 694         my %unique_refs = ();
 695
 696         foreach my $ref (@refs) {
 697                 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
 698                 # 'heads' are added implicitly in get_branch_refs().
 699                 $unique_refs{$ref} = 1 if ($ref ne 'heads');
 700         }
 701         return sort keys %unique_refs;
 702 }
 703
 704 # If it is set to code reference, it is code that it is to be run once per
 705 # request, allowing updating configurations that change with each request,
 706 # while running other code in config file only once.
 707 #
 708 # Otherwise, if it is false then gitweb would process config file only once;
 709 # if it is true then gitweb config would be run for each request.
 710 our $per_request_config = 1;
 711
 712 # If true and fileno STDIN is 0 and getsockname succeeds, then FCGI mode will
 713 # be activated automatically as though the --fcgi option was given.
 714 our $auto_fcgi = 0;
 715
 716 # read and parse gitweb config file given by its parameter.
 717 # returns true on success, false on recoverable error, allowing
 718 # to chain this subroutine, using first file that exists.
 719 # dies on errors during parsing config file, as it is unrecoverable.
 720 sub read_config_file {
 721         my $filename = shift;
 722         return unless defined $filename;
 723         # die if there are errors parsing config file
 724         if (-e $filename) {
 725                 do $filename;
 726                 die $@ if $@;
 727                 return 1;
 728         }
 729         return;
 730 }
 731
 732 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 733 sub evaluate_gitweb_config {
 734         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 735         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 736         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 737
 738         # Protect against duplications of file names, to not read config twice.
 739         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 740         # there possibility of duplication of filename there doesn't matter.
 741         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 742         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 743
 744         # Common system-wide settings for convenience.
 745         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 746         read_config_file($GITWEB_CONFIG_COMMON);
 747
 748         # Use first config file that exists.  This means use the per-instance
 749         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 750         read_config_file($GITWEB_CONFIG) and return;
 751         read_config_file($GITWEB_CONFIG_SYSTEM);
 752 }
 753
 754 our $encode_object;
 755
 756 sub evaluate_encoding {
 757         my $requested = $fallback_encoding || 'ISO-8859-1';
 758         my $obj = Encode::find_encoding($requested) or
 759                 die_error(400, "Requested fallback encoding not found");
 760         if ($obj->name eq 'iso-8859-1') {
 761                 # Use Windows-1252 instead as required by the HTML 5 standard
 762                 my $altobj = Encode::find_encoding('Windows-1252');
 763                 $obj = $altobj if $altobj;
 764         }
 765         $encode_object = $obj;
 766 }
 767
 768 # Get loadavg of system, to compare against $maxload.
 769 # Currently it requires '/proc/loadavg' present to get loadavg;
 770 # if it is not present it returns 0, which means no load checking.
 771 sub get_loadavg {
 772         if( -e '/proc/loadavg' ){
 773                 open my $fd, '<', '/proc/loadavg'
 774                         or return 0;
 775                 my @load = split(/\s+/, scalar <$fd>);
 776                 close $fd;
 777
 778                 # The first three columns measure CPU and IO utilization of the last one,
 779                 # five, and 10 minute periods.  The fourth column shows the number of
 780                 # currently running processes and the total number of processes in the m/n
 781                 # format.  The last column displays the last process ID used.
 782                 return $load[0] || 0;
 783         }
 784         # additional checks for load average should go here for things that don't export
 785         # /proc/loadavg
 786
 787         return 0;
 788 }
 789
 790 # version of the core git binary
 791 our $git_version;
 792 sub evaluate_git_version {
 793         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 794         $number_of_git_cmds++;
 795 }
 796
 797 sub check_loadavg {
 798         if (defined $maxload && get_loadavg() > $maxload) {
 799                 die_error(503, "The load average on the server is too high");
 800         }
 801 }
 802
 803 # ======================================================================
 804 # input validation and dispatch
 805
 806 # input parameters can be collected from a variety of sources (presently, CGI
 807 # and PATH_INFO), so we define an %input_params hash that collects them all
 808 # together during validation: this allows subsequent uses (e.g. href()) to be
 809 # agnostic of the parameter origin
 810
 811 our %input_params = ();
 812
 813 # input parameters are stored with the long parameter name as key. This will
 814 # also be used in the href subroutine to convert parameters to their CGI
 815 # equivalent, and since the href() usage is the most frequent one, we store
 816 # the name -> CGI key mapping here, instead of the reverse.
 817 #
 818 # XXX: Warning: If you touch this, check the search form for updating,
 819 # too.
 820
 821 our @cgi_param_mapping = (
 822         project => "p",
 823         action => "a",
 824         file_name => "f",
 825         file_parent => "fp",
 826         hash => "h",
 827         hash_parent => "hp",
 828         hash_base => "hb",
 829         hash_parent_base => "hpb",
 830         page => "pg",
 831         order => "o",
 832         searchtext => "s",
 833         searchtype => "st",
 834         snapshot_format => "sf",
 835         extra_options => "opt",
 836         search_use_regexp => "sr",
 837         ctag => "by_tag",
 838         diff_style => "ds",
 839         project_filter => "pf",
 840         # this must be last entry (for manipulation from JavaScript)
 841         javascript => "js"
 842 );
 843 our %cgi_param_mapping = @cgi_param_mapping;
 844
 845 # we will also need to know the possible actions, for validation
 846 our %actions = (
 847         "blame" => \&git_blame,
 848         "blame_incremental" => \&git_blame_incremental,
 849         "blame_data" => \&git_blame_data,
 850         "blobdiff" => \&git_blobdiff,
 851         "blobdiff_plain" => \&git_blobdiff_plain,
 852         "blob" => \&git_blob,
 853         "blob_plain" => \&git_blob_plain,
 854         "commitdiff" => \&git_commitdiff,
 855         "commitdiff_plain" => \&git_commitdiff_plain,
 856         "commit" => \&git_commit,
 857         "forks" => \&git_forks,
 858         "heads" => \&git_heads,
 859         "history" => \&git_history,
 860         "log" => \&git_log,
 861         "patch" => \&git_patch,
 862         "patches" => \&git_patches,
 863         "remotes" => \&git_remotes,
 864         "rss" => \&git_rss,
 865         "atom" => \&git_atom,
 866         "search" => \&git_search,
 867         "search_help" => \&git_search_help,
 868         "shortlog" => \&git_shortlog,
 869         "summary" => \&git_summary,
 870         "tag" => \&git_tag,
 871         "tags" => \&git_tags,
 872         "tree" => \&git_tree,
 873         "snapshot" => \&git_snapshot,
 874         "object" => \&git_object,
 875         # those below don't need $project
 876         "opml" => \&git_opml,
 877         "project_list" => \&git_project_list,
 878         "project_index" => \&git_project_index,
 879 );
 880
 881 # finally, we have the hash of allowed extra_options for the commands that
 882 # allow them
 883 our %allowed_options = (
 884         "--no-merges" => [ qw(rss atom log shortlog history) ],
 885 );
 886
 887 # fill %input_params with the CGI parameters. All values except for 'opt'
 888 # should be single values, but opt can be an array. We should probably
 889 # build an array of parameters that can be multi-valued, but since for the time
 890 # being it's only this one, we just single it out
 891 sub evaluate_query_params {
 892         our $cgi;
 893
 894         while (my ($name, $symbol) = each %cgi_param_mapping) {
 895                 if ($symbol eq 'opt') {
 896                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
 897                 } else {
 898                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 899                 }
 900         }
 901 }
 902
 903 # now read PATH_INFO and update the parameter list for missing parameters
 904 sub evaluate_path_info {
 905         return if defined $input_params{'project'};
 906         return if !$path_info;
 907         $path_info =~ s,^/+,,;
 908         return if !$path_info;
 909
 910         # find which part of PATH_INFO is project
 911         my $project = $path_info;
 912         $project =~ s,/+$,,;
 913         while ($project && !check_head_link("$projectroot/$project")) {
 914                 $project =~ s,/*[^/]*$,,;
 915         }
 916         return unless $project;
 917         $input_params{'project'} = $project;
 918
 919         # do not change any parameters if an action is given using the query string
 920         return if $input_params{'action'};
 921         $path_info =~ s,^\Q$project\E/*,,;
 922
 923         # next, check if we have an action
 924         my $action = $path_info;
 925         $action =~ s,/.*$,,;
 926         if (exists $actions{$action}) {
 927                 $path_info =~ s,^$action/*,,;
 928                 $input_params{'action'} = $action;
 929         }
 930
 931         # list of actions that want hash_base instead of hash, but can have no
 932         # pathname (f) parameter
 933         my @wants_base = (
 934                 'tree',
 935                 'history',
 936         );
 937
 938         # we want to catch, among others
 939         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 940         my ($parentrefname, $parentpathname, $refname, $pathname) =
 941                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 942
 943         # first, analyze the 'current' part
 944         if (defined $pathname) {
 945                 # we got "branch:filename" or "branch:dir/"
 946                 # we could use git_get_type(branch:pathname), but:
 947                 # - it needs $git_dir
 948                 # - it does a git() call
 949                 # - the convention of terminating directories with a slash
 950                 #   makes it superfluous
 951                 # - embedding the action in the PATH_INFO would make it even
 952                 #   more superfluous
 953                 $pathname =~ s,^/+,,;
 954                 if (!$pathname || substr($pathname, -1) eq "/") {
 955                         $input_params{'action'} ||= "tree";
 956                         $pathname =~ s,/$,,;
 957                 } else {
 958                         # the default action depends on whether we had parent info
 959                         # or not
 960                         if ($parentrefname) {
 961                                 $input_params{'action'} ||= "blobdiff_plain";
 962                         } else {
 963                                 $input_params{'action'} ||= "blob_plain";
 964                         }
 965                 }
 966                 $input_params{'hash_base'} ||= $refname;
 967                 $input_params{'file_name'} ||= $pathname;
 968         } elsif (defined $refname) {
 969                 # we got "branch". In this case we have to choose if we have to
 970                 # set hash or hash_base.
 971                 #
 972                 # Most of the actions without a pathname only want hash to be
 973                 # set, except for the ones specified in @wants_base that want
 974                 # hash_base instead. It should also be noted that hand-crafted
 975                 # links having 'history' as an action and no pathname or hash
 976                 # set will fail, but that happens regardless of PATH_INFO.
 977                 if (defined $parentrefname) {
 978                         # if there is parent let the default be 'shortlog' action
 979                         # (for http://git.example.com/repo.git/A..B links); if there
 980                         # is no parent, dispatch will detect type of object and set
 981                         # action appropriately if required (if action is not set)
 982                         $input_params{'action'} ||= "shortlog";
 983                 }
 984                 if ($input_params{'action'} &&
 985                     grep { $_ eq $input_params{'action'} } @wants_base) {
 986                         $input_params{'hash_base'} ||= $refname;
 987                 } else {
 988                         $input_params{'hash'} ||= $refname;
 989                 }
 990         }
 991
 992         # next, handle the 'parent' part, if present
 993         if (defined $parentrefname) {
 994                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 995                 # someproject/blobdiff/oldrev..newrev:/filename
 996                 if ($parentpathname) {
 997                         $parentpathname =~ s,^/+,,;
 998                         $parentpathname =~ s,/$,,;
 999                         $input_params{'file_parent'} ||= $parentpathname;
1000                 } else {
1001                         $input_params{'file_parent'} ||= $input_params{'file_name'};
1002                 }
1003                 # we assume that hash_parent_base is wanted if a path was specified,
1004                 # or if the action wants hash_base instead of hash
1005                 if (defined $input_params{'file_parent'} ||
1006                         grep { $_ eq $input_params{'action'} } @wants_base) {
1007                         $input_params{'hash_parent_base'} ||= $parentrefname;
1008                 } else {
1009                         $input_params{'hash_parent'} ||= $parentrefname;
1010                 }
1011         }
1012
1013         # for the snapshot action, we allow URLs in the form
1014         # $project/snapshot/$hash.ext
1015         # where .ext determines the snapshot and gets removed from the
1016         # passed $refname to provide the $hash.
1017         #
1018         # To be able to tell that $refname includes the format extension, we
1019         # require the following two conditions to be satisfied:
1020         # - the hash input parameter MUST have been set from the $refname part
1021         #   of the URL (i.e. they must be equal)
1022         # - the snapshot format MUST NOT have been defined already (e.g. from
1023         #   CGI parameter sf)
1024         # It's also useless to try any matching unless $refname has a dot,
1025         # so we check for that too
1026         if (defined $input_params{'action'} &&
1027                 $input_params{'action'} eq 'snapshot' &&
1028                 defined $refname && index($refname, '.') != -1 &&
1029                 $refname eq $input_params{'hash'} &&
1030                 !defined $input_params{'snapshot_format'}) {
1031                 # We loop over the known snapshot formats, checking for
1032                 # extensions. Allowed extensions are both the defined suffix
1033                 # (which includes the initial dot already) and the snapshot
1034                 # format key itself, with a prepended dot
1035                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1036                         my $hash = $refname;
1037                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1038                                 next;
1039                         }
1040                         my $sfx = $1;
1041                         # a valid suffix was found, so set the snapshot format
1042                         # and reset the hash parameter
1043                         $input_params{'snapshot_format'} = $fmt;
1044                         $input_params{'hash'} = $hash;
1045                         # we also set the format suffix to the one requested
1046                         # in the URL: this way a request for e.g. .tgz returns
1047                         # a .tgz instead of a .tar.gz
1048                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1049                         last;
1050                 }
1051         }
1052 }
1053
1054 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1055      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1056      $searchtext, $search_regexp, $project_filter);
1057 sub evaluate_and_validate_params {
1058         our $action = $input_params{'action'};
1059         if (defined $action) {
1060                 if (!is_valid_action($action)) {
1061                         die_error(400, "Invalid action parameter");
1062                 }
1063         }
1064
1065         # parameters which are pathnames
1066         our $project = $input_params{'project'};
1067         if (defined $project) {
1068                 if (!is_valid_project($project)) {
1069                         undef $project;
1070                         die_error(404, "No such project");
1071                 }
1072         }
1073
1074         our $project_filter = $input_params{'project_filter'};
1075         if (defined $project_filter) {
1076                 if (!is_valid_pathname($project_filter)) {
1077                         die_error(404, "Invalid project_filter parameter");
1078                 }
1079         }
1080
1081         our $file_name = $input_params{'file_name'};
1082         if (defined $file_name) {
1083                 if (!is_valid_pathname($file_name)) {
1084                         die_error(400, "Invalid file parameter");
1085                 }
1086         }
1087
1088         our $file_parent = $input_params{'file_parent'};
1089         if (defined $file_parent) {
1090                 if (!is_valid_pathname($file_parent)) {
1091                         die_error(400, "Invalid file parent parameter");
1092                 }
1093         }
1094
1095         # parameters which are refnames
1096         our $hash = $input_params{'hash'};
1097         if (defined $hash) {
1098                 if (!is_valid_refname($hash)) {
1099                         die_error(400, "Invalid hash parameter");
1100                 }
1101         }
1102
1103         our $hash_parent = $input_params{'hash_parent'};
1104         if (defined $hash_parent) {
1105                 if (!is_valid_refname($hash_parent)) {
1106                         die_error(400, "Invalid hash parent parameter");
1107                 }
1108         }
1109
1110         our $hash_base = $input_params{'hash_base'};
1111         if (defined $hash_base) {
1112                 if (!is_valid_refname($hash_base)) {
1113                         die_error(400, "Invalid hash base parameter");
1114                 }
1115         }
1116
1117         our @extra_options = @{$input_params{'extra_options'}};
1118         # @extra_options is always defined, since it can only be (currently) set from
1119         # CGI, and $cgi->param() returns the empty array in array context if the param
1120         # is not set
1121         foreach my $opt (@extra_options) {
1122                 if (not exists $allowed_options{$opt}) {
1123                         die_error(400, "Invalid option parameter");
1124                 }
1125                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1126                         die_error(400, "Invalid option parameter for this action");
1127                 }
1128         }
1129
1130         our $hash_parent_base = $input_params{'hash_parent_base'};
1131         if (defined $hash_parent_base) {
1132                 if (!is_valid_refname($hash_parent_base)) {
1133                         die_error(400, "Invalid hash parent base parameter");
1134                 }
1135         }
1136
1137         # other parameters
1138         our $page = $input_params{'page'};
1139         if (defined $page) {
1140                 if ($page =~ m/[^0-9]/) {
1141                         die_error(400, "Invalid page parameter");
1142                 }
1143         }
1144
1145         our $searchtype = $input_params{'searchtype'};
1146         if (defined $searchtype) {
1147                 if ($searchtype =~ m/[^a-z]/) {
1148                         die_error(400, "Invalid searchtype parameter");
1149                 }
1150         }
1151
1152         our $search_use_regexp = $input_params{'search_use_regexp'};
1153
1154         our $searchtext = $input_params{'searchtext'};
1155         our $search_regexp = undef;
1156         if (defined $searchtext) {
1157                 if (length($searchtext) < 2) {
1158                         die_error(403, "At least two characters are required for search parameter");
1159                 }
1160                 if ($search_use_regexp) {
1161                         $search_regexp = $searchtext;
1162                         if (!eval { qr/$search_regexp/; 1; }) {
1163                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1164                                 die_error(400, "Invalid search regexp '$search_regexp'",
1165                                           esc_html($error));
1166                         }
1167                 } else {
1168                         $search_regexp = quotemeta $searchtext;
1169                 }
1170         }
1171 }
1172
1173 # path to the current git repository
1174 our $git_dir;
1175 sub evaluate_git_dir {
1176         our $git_dir = "$projectroot/$project" if $project;
1177 }
1178
1179 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1180 sub configure_gitweb_features {
1181         # list of supported snapshot formats
1182         our @snapshot_fmts = gitweb_get_feature('snapshot');
1183         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1184
1185         # check that the avatar feature is set to a known provider name,
1186         # and for each provider check if the dependencies are satisfied.
1187         # if the provider name is invalid or the dependencies are not met,
1188         # reset $git_avatar to the empty string.
1189         our ($git_avatar) = gitweb_get_feature('avatar');
1190         if ($git_avatar eq 'gravatar') {
1191                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1192         } elsif ($git_avatar eq 'picon') {
1193                 # no dependencies
1194         } else {
1195                 $git_avatar = '';
1196         }
1197
1198         our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1199         @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1200 }
1201
1202 sub get_branch_refs {
1203         return ('heads', @extra_branch_refs);
1204 }
1205
1206 # custom error handler: 'die <message>' is Internal Server Error
1207 sub handle_errors_html {
1208         my $msg = shift; # it is already HTML escaped
1209
1210         # to avoid infinite loop where error occurs in die_error,
1211         # change handler to default handler, disabling handle_errors_html
1212         set_message("Error occurred when inside die_error:\n$msg");
1213
1214         # you cannot jump out of die_error when called as error handler;
1215         # the subroutine set via CGI::Carp::set_message is called _after_
1216         # HTTP headers are already written, so it cannot write them itself
1217         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1218 }
1219 set_message(\&handle_errors_html);
1220
1221 # dispatch
1222 sub dispatch {
1223         if (!defined $action) {
1224                 if (defined $hash) {
1225                         $action = git_get_type($hash);
1226                         $action or die_error(404, "Object does not exist");
1227                 } elsif (defined $hash_base && defined $file_name) {
1228                         $action = git_get_type("$hash_base:$file_name");
1229                         $action or die_error(404, "File or directory does not exist");
1230                 } elsif (defined $project) {
1231                         $action = 'summary';
1232                 } else {
1233                         $action = 'project_list';
1234                 }
1235         }
1236         if (!defined($actions{$action})) {
1237                 die_error(400, "Unknown action");
1238         }
1239         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1240             !$project) {
1241                 die_error(400, "Project needed");
1242         }
1243         $actions{$action}->();
1244 }
1245
1246 sub reset_timer {
1247         our $t0 = [ gettimeofday() ]
1248                 if defined $t0;
1249         our $number_of_git_cmds = 0;
1250 }
1251
1252 our $first_request = 1;
1253 sub run_request {
1254         reset_timer();
1255
1256         evaluate_uri();
1257         if ($per_request_config) {
1258                 if (ref($per_request_config) eq 'CODE') {
1259                         $per_request_config->();
1260                 } elsif (!$first_request) {
1261                         evaluate_gitweb_config();
1262                 }
1263         }
1264         check_loadavg();
1265
1266         # $projectroot and $projects_list might be set in gitweb config file
1267         $projects_list ||= $projectroot;
1268
1269         evaluate_query_params();
1270         evaluate_path_info();
1271         evaluate_and_validate_params();
1272         evaluate_git_dir();
1273
1274         configure_gitweb_features();
1275
1276         dispatch();
1277 }
1278
1279 our $is_last_request = sub { 1 };
1280 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1281 our $CGI = 'CGI';
1282 our $cgi;
1283 sub configure_as_fcgi {
1284         require CGI::Fast;
1285         our $CGI = 'CGI::Fast';
1286
1287         $first_request = 0;
1288         my $request_number = 0;
1289         # let each child service 100 requests
1290         our $is_last_request = sub { ++$request_number > 100 };
1291 }
1292 sub evaluate_argv {
1293         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1294         configure_as_fcgi()
1295                 if $script_name =~ /\.fcgi$/
1296                 or $auto_fcgi && defined fileno STDIN && fileno STDIN == 0 && getsockname(STDIN);
1297
1298         return unless (@ARGV);
1299
1300         require Getopt::Long;
1301         Getopt::Long::GetOptions(
1302                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1303                 'nproc|n=i' => sub {
1304                         my ($arg, $val) = @_;
1305                         return unless eval { require FCGI::ProcManager; 1; };
1306                         my $proc_manager = FCGI::ProcManager->new({
1307                                 n_processes => $val,
1308                         });
1309                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1310                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1311                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1312                 },
1313         );
1314 }
1315
1316 sub run {
1317         evaluate_gitweb_config();
1318         evaluate_encoding();
1319         evaluate_git_version();
1320         evaluate_argv();
1321
1322         $first_request = 1;
1323         $pre_listen_hook->()
1324                 if $pre_listen_hook;
1325
1326  REQUEST:
1327         while ($cgi = $CGI->new()) {
1328                 $pre_dispatch_hook->()
1329                         if $pre_dispatch_hook;
1330
1331                 run_request();
1332
1333                 $post_dispatch_hook->()
1334                         if $post_dispatch_hook;
1335                 $first_request = 0;
1336
1337                 last REQUEST if ($is_last_request->());
1338         }
1339
1340  DONE_GITWEB:
1341         1;
1342 }
1343
1344 run();
1345
1346 if (defined caller) {
1347         # wrapped in a subroutine processing requests,
1348         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1349         return;
1350 } else {
1351         # pure CGI script, serving single request
1352         exit;
1353 }
1354
1355 ## ======================================================================
1356 ## action links
1357
1358 # possible values of extra options
1359 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1360 # -replay => 1      - start from a current view (replay with modifications)
1361 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1362 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1363 sub href {
1364         my %params = @_;
1365         # default is to use -absolute url() i.e. $my_uri
1366         my $href = $params{-full} ? $my_url : $my_uri;
1367
1368         # implicit -replay, must be first of implicit params
1369         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1370
1371         $params{'project'} = $project unless exists $params{'project'};
1372
1373         if ($params{-replay}) {
1374                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1375                         if (!exists $params{$name}) {
1376                                 $params{$name} = $input_params{$name};
1377                         }
1378                 }
1379         }
1380
1381         my $use_pathinfo = gitweb_check_feature('pathinfo');
1382         if (defined $params{'project'} &&
1383             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1384                 # try to put as many parameters as possible in PATH_INFO:
1385                 #   - project name
1386                 #   - action
1387                 #   - hash_parent or hash_parent_base:/file_parent
1388                 #   - hash or hash_base:/filename
1389                 #   - the snapshot_format as an appropriate suffix
1390
1391                 # When the script is the root DirectoryIndex for the domain,
1392                 # $href here would be something like http://gitweb.example.com/
1393                 # Thus, we strip any trailing / from $href, to spare us double
1394                 # slashes in the final URL
1395                 $href =~ s,/$,,;
1396
1397                 # Then add the project name, if present
1398                 $href .= "/".esc_path_info($params{'project'});
1399                 delete $params{'project'};
1400
1401                 # since we destructively absorb parameters, we keep this
1402                 # boolean that remembers if we're handling a snapshot
1403                 my $is_snapshot = $params{'action'} eq 'snapshot';
1404
1405                 # Summary just uses the project path URL, any other action is
1406                 # added to the URL
1407                 if (defined $params{'action'}) {
1408                         $href .= "/".esc_path_info($params{'action'})
1409                                 unless $params{'action'} eq 'summary';
1410                         delete $params{'action'};
1411                 }
1412
1413                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1414                 # stripping nonexistent or useless pieces
1415                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1416                         || $params{'hash_parent'} || $params{'hash'});
1417                 if (defined $params{'hash_base'}) {
1418                         if (defined $params{'hash_parent_base'}) {
1419                                 $href .= esc_path_info($params{'hash_parent_base'});
1420                                 # skip the file_parent if it's the same as the file_name
1421                                 if (defined $params{'file_parent'}) {
1422                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1423                                                 delete $params{'file_parent'};
1424                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1425                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1426                                                 delete $params{'file_parent'};
1427                                         }
1428                                 }
1429                                 $href .= "..";
1430                                 delete $params{'hash_parent'};
1431                                 delete $params{'hash_parent_base'};
1432                         } elsif (defined $params{'hash_parent'}) {
1433                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1434                                 delete $params{'hash_parent'};
1435                         }
1436
1437                         $href .= esc_path_info($params{'hash_base'});
1438                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1439                                 $href .= ":/".esc_path_info($params{'file_name'});
1440                                 delete $params{'file_name'};
1441                         }
1442                         delete $params{'hash'};
1443                         delete $params{'hash_base'};
1444                 } elsif (defined $params{'hash'}) {
1445                         $href .= esc_path_info($params{'hash'});
1446                         delete $params{'hash'};
1447                 }
1448
1449                 # If the action was a snapshot, we can absorb the
1450                 # snapshot_format parameter too
1451                 if ($is_snapshot) {
1452                         my $fmt = $params{'snapshot_format'};
1453                         # snapshot_format should always be defined when href()
1454                         # is called, but just in case some code forgets, we
1455                         # fall back to the default
1456                         $fmt ||= $snapshot_fmts[0];
1457                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1458                         delete $params{'snapshot_format'};
1459                 }
1460         }
1461
1462         # now encode the parameters explicitly
1463         my @result = ();
1464         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1465                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1466                 if (defined $params{$name}) {
1467                         if (ref($params{$name}) eq "ARRAY") {
1468                                 foreach my $par (@{$params{$name}}) {
1469                                         push @result, $symbol . "=" . esc_param($par);
1470                                 }
1471                         } else {
1472                                 push @result, $symbol . "=" . esc_param($params{$name});
1473                         }
1474                 }
1475         }
1476         $href .= "?" . join(';', @result) if scalar @result;
1477
1478         # final transformation: trailing spaces must be escaped (URI-encoded)
1479         $href =~ s/(\s+)$/CGI::escape($1)/e;
1480
1481         if ($params{-anchor}) {
1482                 $href .= "#".esc_param($params{-anchor});
1483         }
1484
1485         return $href;
1486 }
1487
1488
1489 ## ======================================================================
1490 ## validation, quoting/unquoting and escaping
1491
1492 sub is_valid_action {
1493         my $input = shift;
1494         return undef unless exists $actions{$input};
1495         return 1;
1496 }
1497
1498 sub is_valid_project {
1499         my $input = shift;
1500
1501         return unless defined $input;
1502         if (!is_valid_pathname($input) ||
1503                 !(-d "$projectroot/$input") ||
1504                 !check_export_ok("$projectroot/$input") ||
1505                 ($strict_export && !project_in_list($input))) {
1506                 return undef;
1507         } else {
1508                 return 1;
1509         }
1510 }
1511
1512 sub is_valid_pathname {
1513         my $input = shift;
1514
1515         return undef unless defined $input;
1516         # no '.' or '..' as elements of path, i.e. no '.' or '..'
1517         # at the beginning, at the end, and between slashes.
1518         # also this catches doubled slashes
1519         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1520                 return undef;
1521         }
1522         # no null characters
1523         if ($input =~ m!\0!) {
1524                 return undef;
1525         }
1526         return 1;
1527 }
1528
1529 sub is_valid_ref_format {
1530         my $input = shift;
1531
1532         return undef unless defined $input;
1533         # restrictions on ref name according to git-check-ref-format
1534         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1535                 return undef;
1536         }
1537         return 1;
1538 }
1539
1540 sub is_valid_refname {
1541         my $input = shift;
1542
1543         return undef unless defined $input;
1544         # textual hashes are O.K.
1545         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1546                 return 1;
1547         }
1548         # it must be correct pathname
1549         is_valid_pathname($input) or return undef;
1550         # check git-check-ref-format restrictions
1551         is_valid_ref_format($input) or return undef;
1552         return 1;
1553 }
1554
1555 # decode sequences of octets in utf8 into Perl's internal form,
1556 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1557 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1558 sub to_utf8 {
1559         my $str = shift;
1560         return undef unless defined $str;
1561
1562         if (utf8::is_utf8($str) || utf8::decode($str)) {
1563                 return $str;
1564         } else {
1565                 return $encode_object->decode($str, Encode::FB_DEFAULT);
1566         }
1567 }
1568
1569 # quote unsafe chars, but keep the slash, even when it's not
1570 # correct, but quoted slashes look too horrible in bookmarks
1571 sub esc_param {
1572         my $str = shift;
1573         return undef unless defined $str;
1574         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1575         $str =~ s/ /\+/g;
1576         return $str;
1577 }
1578
1579 # the quoting rules for path_info fragment are slightly different
1580 sub esc_path_info {
1581         my $str = shift;
1582         return undef unless defined $str;
1583
1584         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1585         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1586
1587         return $str;
1588 }
1589
1590 # quote unsafe chars in whole URL, so some characters cannot be quoted
1591 sub esc_url {
1592         my $str = shift;
1593         return undef unless defined $str;
1594         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1595         $str =~ s/ /\+/g;
1596         return $str;
1597 }
1598
1599 # quote unsafe characters in HTML attributes
1600 sub esc_attr {
1601
1602         # for XHTML conformance escaping '"' to '&quot;' is not enough
1603         return esc_html(@_);
1604 }
1605
1606 # replace invalid utf8 character with SUBSTITUTION sequence
1607 sub esc_html {
1608         my $str = shift;
1609         my %opts = @_;
1610
1611         return undef unless defined $str;
1612
1613         $str = to_utf8($str);
1614         $str = $cgi->escapeHTML($str);
1615         if ($opts{'-nbsp'}) {
1616                 $str =~ s/ /&nbsp;/g;
1617         }
1618         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1619         return $str;
1620 }
1621
1622 # quote control characters and escape filename to HTML
1623 sub esc_path {
1624         my $str = shift;
1625         my %opts = @_;
1626
1627         return undef unless defined $str;
1628
1629         $str = to_utf8($str);
1630         $str = $cgi->escapeHTML($str);
1631         if ($opts{'-nbsp'}) {
1632                 $str =~ s/ /&nbsp;/g;
1633         }
1634         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1635         return $str;
1636 }
1637
1638 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1639 sub sanitize {
1640         my $str = shift;
1641
1642         return undef unless defined $str;
1643
1644         $str = to_utf8($str);
1645         $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1646         return $str;
1647 }
1648
1649 # Make control characters "printable", using character escape codes (CEC)
1650 sub quot_cec {
1651         my $cntrl = shift;
1652         my %opts = @_;
1653         my %es = ( # character escape codes, aka escape sequences
1654                 "\t" => '\t',   # tab            (HT)
1655                 "\n" => '\n',   # line feed      (LF)
1656                 "\r" => '\r',   # carrige return (CR)
1657                 "\f" => '\f',   # form feed      (FF)
1658                 "\b" => '\b',   # backspace      (BS)
1659                 "\a" => '\a',   # alarm (bell)   (BEL)
1660                 "\e" => '\e',   # escape         (ESC)
1661                 "\013" => '\v', # vertical tab   (VT)
1662                 "\000" => '\0', # nul character  (NUL)
1663         );
1664         my $chr = ( (exists $es{$cntrl})
1665                     ? $es{$cntrl}
1666                     : sprintf('\%2x', ord($cntrl)) );
1667         if ($opts{-nohtml}) {
1668                 return $chr;
1669         } else {
1670                 return "<span class=\"cntrl\">$chr</span>";
1671         }
1672 }
1673
1674 # Alternatively use unicode control pictures codepoints,
1675 # Unicode "printable representation" (PR)
1676 sub quot_upr {
1677         my $cntrl = shift;
1678         my %opts = @_;
1679
1680         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1681         if ($opts{-nohtml}) {
1682                 return $chr;
1683         } else {
1684                 return "<span class=\"cntrl\">$chr</span>";
1685         }
1686 }
1687
1688 # git may return quoted and escaped filenames
1689 sub unquote {
1690         my $str = shift;
1691
1692         sub unq {
1693                 my $seq = shift;
1694                 my %es = ( # character escape codes, aka escape sequences
1695                         't' => "\t",   # tab            (HT, TAB)
1696                         'n' => "\n",   # newline        (NL)
1697                         'r' => "\r",   # return         (CR)
1698                         'f' => "\f",   # form feed      (FF)
1699                         'b' => "\b",   # backspace      (BS)
1700                         'a' => "\a",   # alarm (bell)   (BEL)
1701                         'e' => "\e",   # escape         (ESC)
1702                         'v' => "\013", # vertical tab   (VT)
1703                 );
1704
1705                 if ($seq =~ m/^[0-7]{1,3}$/) {
1706                         # octal char sequence
1707                         return chr(oct($seq));
1708                 } elsif (exists $es{$seq}) {
1709                         # C escape sequence, aka character escape code
1710                         return $es{$seq};
1711                 }
1712                 # quoted ordinary character
1713                 return $seq;
1714         }
1715
1716         if ($str =~ m/^"(.*)"$/) {
1717                 # needs unquoting
1718                 $str = $1;
1719                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1720         }
1721         return $str;
1722 }
1723
1724 # escape tabs (convert tabs to spaces)
1725 sub untabify {
1726         my $line = shift;
1727
1728         while ((my $pos = index($line, "\t")) != -1) {
1729                 if (my $count = (8 - ($pos % 8))) {
1730                         my $spaces = ' ' x $count;
1731                         $line =~ s/\t/$spaces/;
1732                 }
1733         }
1734
1735         return $line;
1736 }
1737
1738 sub project_in_list {
1739         my $project = shift;
1740         my @list = git_get_projects_list();
1741         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1742 }
1743
1744 ## ----------------------------------------------------------------------
1745 ## HTML aware string manipulation
1746
1747 # Try to chop given string on a word boundary between position
1748 # $len and $len+$add_len. If there is no word boundary there,
1749 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1750 # (marking chopped part) would be longer than given string.
1751 sub chop_str {
1752         my $str = shift;
1753         my $len = shift;
1754         my $add_len = shift || 10;
1755         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1756
1757         # Make sure perl knows it is utf8 encoded so we don't
1758         # cut in the middle of a utf8 multibyte char.
1759         $str = to_utf8($str);
1760
1761         # allow only $len chars, but don't cut a word if it would fit in $add_len
1762         # if it doesn't fit, cut it if it's still longer than the dots we would add
1763         # remove chopped character entities entirely
1764
1765         # when chopping in the middle, distribute $len into left and right part
1766         # return early if chopping wouldn't make string shorter
1767         if ($where eq 'center') {
1768                 return $str if ($len + 5 >= length($str)); # filler is length 5
1769                 $len = int($len/2);
1770         } else {
1771                 return $str if ($len + 4 >= length($str)); # filler is length 4
1772         }
1773
1774         # regexps: ending and beginning with word part up to $add_len
1775         my $endre = qr/.{$len}\w{0,$add_len}/;
1776         my $begre = qr/\w{0,$add_len}.{$len}/;
1777
1778         if ($where eq 'left') {
1779                 $str =~ m/^(.*?)($begre)$/;
1780                 my ($lead, $body) = ($1, $2);
1781                 if (length($lead) > 4) {
1782                         $lead = " ...";
1783                 }
1784                 return "$lead$body";
1785
1786         } elsif ($where eq 'center') {
1787                 $str =~ m/^($endre)(.*)$/;
1788                 my ($left, $str)  = ($1, $2);
1789                 $str =~ m/^(.*?)($begre)$/;
1790                 my ($mid, $right) = ($1, $2);
1791                 if (length($mid) > 5) {
1792                         $mid = " ... ";
1793                 }
1794                 return "$left$mid$right";
1795
1796         } else {
1797                 $str =~ m/^($endre)(.*)$/;
1798                 my $body = $1;
1799                 my $tail = $2;
1800                 if (length($tail) > 4) {
1801                         $tail = "... ";
1802                 }
1803                 return "$body$tail";
1804         }
1805 }
1806
1807 # takes the same arguments as chop_str, but also wraps a <span> around the
1808 # result with a title attribute if it does get chopped. Additionally, the
1809 # string is HTML-escaped.
1810 sub chop_and_escape_str {
1811         my ($str) = @_;
1812
1813         my $chopped = chop_str(@_);
1814         $str = to_utf8($str);
1815         if ($chopped eq $str) {
1816                 return esc_html($chopped);
1817         } else {
1818                 $str =~ s/[[:cntrl:]]/?/g;
1819                 return $cgi->span({-title=>$str}, esc_html($chopped));
1820         }
1821 }
1822
1823 # Highlight selected fragments of string, using given CSS class,
1824 # and escape HTML.  It is assumed that fragments do not overlap.
1825 # Regions are passed as list of pairs (array references).
1826 #
1827 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1828 # '<span class="mark">foo</span>bar'
1829 sub esc_html_hl_regions {
1830         my ($str, $css_class, @sel) = @_;
1831         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1832         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1833         return esc_html($str, %opts) unless @sel;
1834
1835         my $out = '';
1836         my $pos = 0;
1837
1838         for my $s (@sel) {
1839                 my ($begin, $end) = @$s;
1840
1841                 # Don't create empty <span> elements.
1842                 next if $end <= $begin;
1843
1844                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1845                                        %opts);
1846
1847                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1848                         if ($begin - $pos > 0);
1849                 $out .= $cgi->span({-class => $css_class}, $escaped);
1850
1851                 $pos = $end;
1852         }
1853         $out .= esc_html(substr($str, $pos), %opts)
1854                 if ($pos < length($str));
1855
1856         return $out;
1857 }
1858
1859 # return positions of beginning and end of each match
1860 sub matchpos_list {
1861         my ($str, $regexp) = @_;
1862         return unless (defined $str && defined $regexp);
1863
1864         my @matches;
1865         while ($str =~ /$regexp/g) {
1866                 push @matches, [$-[0], $+[0]];
1867         }
1868         return @matches;
1869 }
1870
1871 # highlight match (if any), and escape HTML
1872 sub esc_html_match_hl {
1873         my ($str, $regexp) = @_;
1874         return esc_html($str) unless defined $regexp;
1875
1876         my @matches = matchpos_list($str, $regexp);
1877         return esc_html($str) unless @matches;
1878
1879         return esc_html_hl_regions($str, 'match', @matches);
1880 }
1881
1882
1883 # highlight match (if any) of shortened string, and escape HTML
1884 sub esc_html_match_hl_chopped {
1885         my ($str, $chopped, $regexp) = @_;
1886         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1887
1888         my @matches = matchpos_list($str, $regexp);
1889         return esc_html($chopped) unless @matches;
1890
1891         # filter matches so that we mark chopped string
1892         my $tail = "... "; # see chop_str
1893         unless ($chopped =~ s/\Q$tail\E$//) {
1894                 $tail = '';
1895         }
1896         my $chop_len = length($chopped);
1897         my $tail_len = length($tail);
1898         my @filtered;
1899
1900         for my $m (@matches) {
1901                 if ($m->[0] > $chop_len) {
1902                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1903                         last;
1904                 } elsif ($m->[1] > $chop_len) {
1905                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1906                         last;
1907                 }
1908                 push @filtered, $m;
1909         }
1910
1911         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1912 }
1913
1914 ## ----------------------------------------------------------------------
1915 ## functions returning short strings
1916
1917 # CSS class for given age value (in seconds)
1918 sub age_class {
1919         my $age = shift;
1920
1921         if (!defined $age) {
1922                 return "noage";
1923         } elsif ($age < 60*60*2) {
1924                 return "age0";
1925         } elsif ($age < 60*60*24*2) {
1926                 return "age1";
1927         } else {
1928                 return "age2";
1929         }
1930 }
1931
1932 # convert age in seconds to "nn units ago" string
1933 sub age_string {
1934         my $age = shift;
1935         my $age_str;
1936
1937         if ($age > 60*60*24*365*2) {
1938                 $age_str = (int $age/60/60/24/365);
1939                 $age_str .= " years ago";
1940         } elsif ($age > 60*60*24*(365/12)*2) {
1941                 $age_str = int $age/60/60/24/(365/12);
1942                 $age_str .= " months ago";
1943         } elsif ($age > 60*60*24*7*2) {
1944                 $age_str = int $age/60/60/24/7;
1945                 $age_str .= " weeks ago";
1946         } elsif ($age > 60*60*24*2) {
1947                 $age_str = int $age/60/60/24;
1948                 $age_str .= " days ago";
1949         } elsif ($age > 60*60*2) {
1950                 $age_str = int $age/60/60;
1951                 $age_str .= " hours ago";
1952         } elsif ($age > 60*2) {
1953                 $age_str = int $age/60;
1954                 $age_str .= " min ago";
1955         } elsif ($age > 2) {
1956                 $age_str = int $age;
1957                 $age_str .= " sec ago";
1958         } else {
1959                 $age_str .= " right now";
1960         }
1961         return $age_str;
1962 }
1963
1964 use constant {
1965         S_IFINVALID => 0030000,
1966         S_IFGITLINK => 0160000,
1967 };
1968
1969 # submodule/subproject, a commit object reference
1970 sub S_ISGITLINK {
1971         my $mode = shift;
1972
1973         return (($mode & S_IFMT) == S_IFGITLINK)
1974 }
1975
1976 # convert file mode in octal to symbolic file mode string
1977 sub mode_str {
1978         my $mode = oct shift;
1979
1980         if (S_ISGITLINK($mode)) {
1981                 return 'm---------';
1982         } elsif (S_ISDIR($mode & S_IFMT)) {
1983                 return 'drwxr-xr-x';
1984         } elsif (S_ISLNK($mode)) {
1985                 return 'lrwxrwxrwx';
1986         } elsif (S_ISREG($mode)) {
1987                 # git cares only about the executable bit
1988                 if ($mode & S_IXUSR) {
1989                         return '-rwxr-xr-x';
1990                 } else {
1991                         return '-rw-r--r--';
1992                 };
1993         } else {
1994                 return '----------';
1995         }
1996 }
1997
1998 # convert file mode in octal to file type string
1999 sub file_type {
2000         my $mode = shift;
2001
2002         if ($mode !~ m/^[0-7]+$/) {
2003                 return $mode;
2004         } else {
2005                 $mode = oct $mode;
2006         }
2007
2008         if (S_ISGITLINK($mode)) {
2009                 return "submodule";
2010         } elsif (S_ISDIR($mode & S_IFMT)) {
2011                 return "directory";
2012         } elsif (S_ISLNK($mode)) {
2013                 return "symlink";
2014         } elsif (S_ISREG($mode)) {
2015                 return "file";
2016         } else {
2017                 return "unknown";
2018         }
2019 }
2020
2021 # convert file mode in octal to file type description string
2022 sub file_type_long {
2023         my $mode = shift;
2024
2025         if ($mode !~ m/^[0-7]+$/) {
2026                 return $mode;
2027         } else {
2028                 $mode = oct $mode;
2029         }
2030
2031         if (S_ISGITLINK($mode)) {
2032                 return "submodule";
2033         } elsif (S_ISDIR($mode & S_IFMT)) {
2034                 return "directory";
2035         } elsif (S_ISLNK($mode)) {
2036                 return "symlink";
2037         } elsif (S_ISREG($mode)) {
2038                 if ($mode & S_IXUSR) {
2039                         return "executable";
2040                 } else {
2041                         return "file";
2042                 };
2043         } else {
2044                 return "unknown";
2045         }
2046 }
2047
2048
2049 ## ----------------------------------------------------------------------
2050 ## functions returning short HTML fragments, or transforming HTML fragments
2051 ## which don't belong to other sections
2052
2053 # format line of commit message.
2054 sub format_log_line_html {
2055         my $line = shift;
2056
2057         $line = esc_html($line, -nbsp=>1);
2058         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
2059                 $cgi->a({-href => href(action=>"object", hash=>$1),
2060                                         -class => "text"}, $1);
2061         }eg;
2062
2063         return $line;
2064 }
2065
2066 # format marker of refs pointing to given object
2067
2068 # the destination action is chosen based on object type and current context:
2069 # - for annotated tags, we choose the tag view unless it's the current view
2070 #   already, in which case we go to shortlog view
2071 # - for other refs, we keep the current view if we're in history, shortlog or
2072 #   log view, and select shortlog otherwise
2073 sub format_ref_marker {
2074         my ($refs, $id) = @_;
2075         my $markers = '';
2076
2077         if (defined $refs->{$id}) {
2078                 foreach my $ref (@{$refs->{$id}}) {
2079                         # this code exploits the fact that non-lightweight tags are the
2080                         # only indirect objects, and that they are the only objects for which
2081                         # we want to use tag instead of shortlog as action
2082                         my ($type, $name) = qw();
2083                         my $indirect = ($ref =~ s/\^\{\}$//);
2084                         # e.g. tags/v2.6.11 or heads/next
2085                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2086                                 $type = $1;
2087                                 $name = $2;
2088                         } else {
2089                                 $type = "ref";
2090                                 $name = $ref;
2091                         }
2092
2093                         my $class = $type;
2094                         $class .= " indirect" if $indirect;
2095
2096                         my $dest_action = "shortlog";
2097
2098                         if ($indirect) {
2099                                 $dest_action = "tag" unless $action eq "tag";
2100                         } elsif ($action =~ /^(history|(short)?log)$/) {
2101                                 $dest_action = $action;
2102                         }
2103
2104                         my $dest = "";
2105                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2106                         $dest .= $ref;
2107
2108                         my $link = $cgi->a({
2109                                 -href => href(
2110                                         action=>$dest_action,
2111                                         hash=>$dest
2112                                 )}, $name);
2113
2114                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2115                                 $link . "</span>";
2116                 }
2117         }
2118
2119         if ($markers) {
2120                 return ' <span class="refs">'. $markers . '</span>';
2121         } else {
2122                 return "";
2123         }
2124 }
2125
2126 # format, perhaps shortened and with markers, title line
2127 sub format_subject_html {
2128         my ($long, $short, $href, $extra) = @_;
2129         $extra = '' unless defined($extra);
2130
2131         if (length($short) < length($long)) {
2132                 $long =~ s/[[:cntrl:]]/?/g;
2133                 return $cgi->a({-href => $href, -class => "list subject",
2134                                 -title => to_utf8($long)},
2135                        esc_html($short)) . $extra;
2136         } else {
2137                 return $cgi->a({-href => $href, -class => "list subject"},
2138                        esc_html($long)) . $extra;
2139         }
2140 }
2141
2142 # Rather than recomputing the url for an email multiple times, we cache it
2143 # after the first hit. This gives a visible benefit in views where the avatar
2144 # for the same email is used repeatedly (e.g. shortlog).
2145 # The cache is shared by all avatar engines (currently gravatar only), which
2146 # are free to use it as preferred. Since only one avatar engine is used for any
2147 # given page, there's no risk for cache conflicts.
2148 our %avatar_cache = ();
2149
2150 # Compute the picon url for a given email, by using the picon search service over at
2151 # http://www.cs.indiana.edu/picons/search.html
2152 sub picon_url {
2153         my $email = lc shift;
2154         if (!$avatar_cache{$email}) {
2155                 my ($user, $domain) = split('@', $email);
2156                 $avatar_cache{$email} =
2157                         "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2158                         "$domain/$user/" .
2159                         "users+domains+unknown/up/single";
2160         }
2161         return $avatar_cache{$email};
2162 }
2163
2164 # Compute the gravatar url for a given email, if it's not in the cache already.
2165 # Gravatar stores only the part of the URL before the size, since that's the
2166 # one computationally more expensive. This also allows reuse of the cache for
2167 # different sizes (for this particular engine).
2168 sub gravatar_url {
2169         my $email = lc shift;
2170         my $size = shift;
2171         $avatar_cache{$email} ||=
2172                 "//www.gravatar.com/avatar/" .
2173                         Digest::MD5::md5_hex($email) . "?s=";
2174         return $avatar_cache{$email} . $size;
2175 }
2176
2177 # Insert an avatar for the given $email at the given $size if the feature
2178 # is enabled.
2179 sub git_get_avatar {
2180         my ($email, %opts) = @_;
2181         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2182         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2183         $opts{-size} ||= 'default';
2184         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2185         my $url = "";
2186         if ($git_avatar eq 'gravatar') {
2187                 $url = gravatar_url($email, $size);
2188         } elsif ($git_avatar eq 'picon') {
2189                 $url = picon_url($email);
2190         }
2191         # Other providers can be added by extending the if chain, defining $url
2192         # as needed. If no variant puts something in $url, we assume avatars
2193         # are completely disabled/unavailable.
2194         if ($url) {
2195                 return $pre_white .
2196                        "<img width=\"$size\" " .
2197                             "class=\"avatar\" " .
2198                             "src=\"".esc_url($url)."\" " .
2199                             "alt=\"\" " .
2200                        "/>" . $post_white;
2201         } else {
2202                 return "";
2203         }
2204 }
2205
2206 sub format_search_author {
2207         my ($author, $searchtype, $displaytext) = @_;
2208         my $have_search = gitweb_check_feature('search');
2209
2210         if ($have_search) {
2211                 my $performed = "";
2212                 if ($searchtype eq 'author') {
2213                         $performed = "authored";
2214                 } elsif ($searchtype eq 'committer') {
2215                         $performed = "committed";
2216                 }
2217
2218                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2219                                 searchtext=>$author,
2220                                 searchtype=>$searchtype), class=>"list",
2221                                 title=>"Search for commits $performed by $author"},
2222                                 $displaytext);
2223
2224         } else {
2225                 return $displaytext;
2226         }
2227 }
2228
2229 # format the author name of the given commit with the given tag
2230 # the author name is chopped and escaped according to the other
2231 # optional parameters (see chop_str).
2232 sub format_author_html {
2233         my $tag = shift;
2234         my $co = shift;
2235         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2236         return "<$tag class=\"author\">" .
2237                format_search_author($co->{'author_name'}, "author",
2238                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2239                        $author) .
2240                "</$tag>";
2241 }
2242
2243 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2244 sub format_git_diff_header_line {
2245         my $line = shift;
2246         my $diffinfo = shift;
2247         my ($from, $to) = @_;
2248
2249         if ($diffinfo->{'nparents'}) {
2250                 # combined diff
2251                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2252                 if ($to->{'href'}) {
2253                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2254                                          esc_path($to->{'file'}));
2255                 } else { # file was deleted (no href)
2256                         $line .= esc_path($to->{'file'});
2257                 }
2258         } else {
2259                 # "ordinary" diff
2260                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2261                 if ($from->{'href'}) {
2262                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2263                                          'a/' . esc_path($from->{'file'}));
2264                 } else { # file was added (no href)
2265                         $line .= 'a/' . esc_path($from->{'file'});
2266                 }
2267                 $line .= ' ';
2268                 if ($to->{'href'}) {
2269                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2270                                          'b/' . esc_path($to->{'file'}));
2271                 } else { # file was deleted
2272                         $line .= 'b/' . esc_path($to->{'file'});
2273                 }
2274         }
2275
2276         return "<div class=\"diff header\">$line</div>\n";
2277 }
2278
2279 # format extended diff header line, before patch itself
2280 sub format_extended_diff_header_line {
2281         my $line = shift;
2282         my $diffinfo = shift;
2283         my ($from, $to) = @_;
2284
2285         # match <path>
2286         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2287                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2288                                        esc_path($from->{'file'}));
2289         }
2290         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2291                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2292                                  esc_path($to->{'file'}));
2293         }
2294         # match single <mode>
2295         if ($line =~ m/\s(\d{6})$/) {
2296                 $line .= '<span class="info"> (' .
2297                          file_type_long($1) .
2298                          ')</span>';
2299         }
2300         # match <hash>
2301         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2302                 # can match only for combined diff
2303                 $line = 'index ';
2304                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2305                         if ($from->{'href'}[$i]) {
2306                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2307                                                   -class=>"hash"},
2308                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2309                         } else {
2310                                 $line .= '0' x 7;
2311                         }
2312                         # separator
2313                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2314                 }
2315                 $line .= '..';
2316                 if ($to->{'href'}) {
2317                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2318                                          substr($diffinfo->{'to_id'},0,7));
2319                 } else {
2320                         $line .= '0' x 7;
2321                 }
2322
2323         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2324                 # can match only for ordinary diff
2325                 my ($from_link, $to_link);
2326                 if ($from->{'href'}) {
2327                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2328                                              substr($diffinfo->{'from_id'},0,7));
2329                 } else {
2330                         $from_link = '0' x 7;
2331                 }
2332                 if ($to->{'href'}) {
2333                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2334                                            substr($diffinfo->{'to_id'},0,7));
2335                 } else {
2336                         $to_link = '0' x 7;
2337                 }
2338                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2339                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2340         }
2341
2342         return $line . "<br/>\n";
2343 }
2344
2345 # format from-file/to-file diff header
2346 sub format_diff_from_to_header {
2347         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2348         my $line;
2349         my $result = '';
2350
2351         $line = $from_line;
2352         #assert($line =~ m/^---/) if DEBUG;
2353         # no extra formatting for "^--- /dev/null"
2354         if (! $diffinfo->{'nparents'}) {
2355                 # ordinary (single parent) diff
2356                 if ($line =~ m!^--- "?a/!) {
2357                         if ($from->{'href'}) {
2358                                 $line = '--- a/' .
2359                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2360                                                 esc_path($from->{'file'}));
2361                         } else {
2362                                 $line = '--- a/' .
2363                                         esc_path($from->{'file'});
2364                         }
2365                 }
2366                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2367
2368         } else {
2369                 # combined diff (merge commit)
2370                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2371                         if ($from->{'href'}[$i]) {
2372                                 $line = '--- ' .
2373                                         $cgi->a({-href=>href(action=>"blobdiff",
2374                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2375                                                              hash_parent_base=>$parents[$i],
2376                                                              file_parent=>$from->{'file'}[$i],
2377                                                              hash=>$diffinfo->{'to_id'},
2378                                                              hash_base=>$hash,
2379                                                              file_name=>$to->{'file'}),
2380                                                  -class=>"path",
2381                                                  -title=>"diff" . ($i+1)},
2382                                                 $i+1) .
2383                                         '/' .
2384                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2385                                                 esc_path($from->{'file'}[$i]));
2386                         } else {
2387                                 $line = '--- /dev/null';
2388                         }
2389                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2390                 }
2391         }
2392
2393         $line = $to_line;
2394         #assert($line =~ m/^\+\+\+/) if DEBUG;
2395         # no extra formatting for "^+++ /dev/null"
2396         if ($line =~ m!^\+\+\+ "?b/!) {
2397                 if ($to->{'href'}) {
2398                         $line = '+++ b/' .
2399                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2400                                         esc_path($to->{'file'}));
2401                 } else {
2402                         $line = '+++ b/' .
2403                                 esc_path($to->{'file'});
2404                 }
2405         }
2406         $result .= qq!<div class="diff to_file">$line</div>\n!;
2407
2408         return $result;
2409 }
2410
2411 # create note for patch simplified by combined diff
2412 sub format_diff_cc_simplified {
2413         my ($diffinfo, @parents) = @_;
2414         my $result = '';
2415
2416         $result .= "<div class=\"diff header\">" .
2417                    "diff --cc ";
2418         if (!is_deleted($diffinfo)) {
2419                 $result .= $cgi->a({-href => href(action=>"blob",
2420                                                   hash_base=>$hash,
2421                                                   hash=>$diffinfo->{'to_id'},
2422                                                   file_name=>$diffinfo->{'to_file'}),
2423                                     -class => "path"},
2424                                    esc_path($diffinfo->{'to_file'}));
2425         } else {
2426                 $result .= esc_path($diffinfo->{'to_file'});
2427         }
2428         $result .= "</div>\n" . # class="diff header"
2429                    "<div class=\"diff nodifferences\">" .
2430                    "Simple merge" .
2431                    "</div>\n"; # class="diff nodifferences"
2432
2433         return $result;
2434 }
2435
2436 sub diff_line_class {
2437         my ($line, $from, $to) = @_;
2438
2439         # ordinary diff
2440         my $num_sign = 1;
2441         # combined diff
2442         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2443                 $num_sign = scalar @{$from->{'href'}};
2444         }
2445
2446         my @diff_line_classifier = (
2447                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2448                 { regexp => qr/^\\/,               class => "incomplete"  },
2449                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2450                 # classifier for context must come before classifier add/rem,
2451                 # or we would have to use more complicated regexp, for example
2452                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2453                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2454                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2455         );
2456         for my $clsfy (@diff_line_classifier) {
2457                 return $clsfy->{'class'}
2458                         if ($line =~ $clsfy->{'regexp'});
2459         }
2460
2461         # fallback
2462         return "";
2463 }
2464
2465 # assumes that $from and $to are defined and correctly filled,
2466 # and that $line holds a line of chunk header for unified diff
2467 sub format_unidiff_chunk_header {
2468         my ($line, $from, $to) = @_;
2469
2470         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2471                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2472
2473         $from_lines = 0 unless defined $from_lines;
2474         $to_lines   = 0 unless defined $to_lines;
2475
2476         if ($from->{'href'}) {
2477                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2478                                      -class=>"list"}, $from_text);
2479         }
2480         if ($to->{'href'}) {
2481                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2482                                      -class=>"list"}, $to_text);
2483         }
2484         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2485                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2486         return $line;
2487 }
2488
2489 # assumes that $from and $to are defined and correctly filled,
2490 # and that $line holds a line of chunk header for combined diff
2491 sub format_cc_diff_chunk_header {
2492         my ($line, $from, $to) = @_;
2493
2494         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2495         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2496
2497         @from_text = split(' ', $ranges);
2498         for (my $i = 0; $i < @from_text; ++$i) {
2499                 ($from_start[$i], $from_nlines[$i]) =
2500                         (split(',', substr($from_text[$i], 1)), 0);
2501         }
2502
2503         $to_text   = pop @from_text;
2504         $to_start  = pop @from_start;
2505         $to_nlines = pop @from_nlines;
2506
2507         $line = "<span class=\"chunk_info\">$prefix ";
2508         for (my $i = 0; $i < @from_text; ++$i) {
2509                 if ($from->{'href'}[$i]) {
2510                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2511                                           -class=>"list"}, $from_text[$i]);
2512                 } else {
2513                         $line .= $from_text[$i];
2514                 }
2515                 $line .= " ";
2516         }
2517         if ($to->{'href'}) {
2518                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2519                                   -class=>"list"}, $to_text);
2520         } else {
2521                 $line .= $to_text;
2522         }
2523         $line .= " $prefix</span>" .
2524                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2525         return $line;
2526 }
2527
2528 # process patch (diff) line (not to be used for diff headers),
2529 # returning HTML-formatted (but not wrapped) line.
2530 # If the line is passed as a reference, it is treated as HTML and not
2531 # esc_html()'ed.
2532 sub format_diff_line {
2533         my ($line, $diff_class, $from, $to) = @_;
2534
2535         if (ref($line)) {
2536                 $line = $$line;
2537         } else {
2538                 chomp $line;
2539                 $line = untabify($line);
2540
2541                 if ($from && $to && $line =~ m/^\@{2} /) {
2542                         $line = format_unidiff_chunk_header($line, $from, $to);
2543                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2544                         $line = format_cc_diff_chunk_header($line, $from, $to);
2545                 } else {
2546                         $line = esc_html($line, -nbsp=>1);
2547                 }
2548         }
2549
2550         my $diff_classes = "diff";
2551         $diff_classes .= " $diff_class" if ($diff_class);
2552         $line = "<div class=\"$diff_classes\">$line</div>\n";
2553
2554         return $line;
2555 }
2556
2557 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2558 # linked.  Pass the hash of the tree/commit to snapshot.
2559 sub format_snapshot_links {
2560         my ($hash) = @_;
2561         my $num_fmts = @snapshot_fmts;
2562         if ($num_fmts > 1) {
2563                 # A parenthesized list of links bearing format names.
2564                 # e.g. "snapshot (_tar.gz_ _zip_)"
2565                 return "snapshot (" . join(' ', map
2566                         $cgi->a({
2567                                 -href => href(
2568                                         action=>"snapshot",
2569                                         hash=>$hash,
2570                                         snapshot_format=>$_
2571                                 )
2572                         }, $known_snapshot_formats{$_}{'display'})
2573                 , @snapshot_fmts) . ")";
2574         } elsif ($num_fmts == 1) {
2575                 # A single "snapshot" link whose tooltip bears the format name.
2576                 # i.e. "_snapshot_"
2577                 my ($fmt) = @snapshot_fmts;
2578                 return
2579                         $cgi->a({
2580                                 -href => href(
2581                                         action=>"snapshot",
2582                                         hash=>$hash,
2583                                         snapshot_format=>$fmt
2584                                 ),
2585                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2586                         }, "snapshot");
2587         } else { # $num_fmts == 0
2588                 return undef;
2589         }
2590 }
2591
2592 ## ......................................................................
2593 ## functions returning values to be passed, perhaps after some
2594 ## transformation, to other functions; e.g. returning arguments to href()
2595
2596 # returns hash to be passed to href to generate gitweb URL
2597 # in -title key it returns description of link
2598 sub get_feed_info {
2599         my $format = shift || 'Atom';
2600         my %res = (action => lc($format));
2601         my $matched_ref = 0;
2602
2603         # feed links are possible only for project views
2604         return unless (defined $project);
2605         # some views should link to OPML, or to generic project feed,
2606         # or don't have specific feed yet (so they should use generic)
2607         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2608
2609         my $branch = undef;
2610         # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2611         # (fullname) to differentiate from tag links; this also makes
2612         # possible to detect branch links
2613         for my $ref (get_branch_refs()) {
2614                 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2615                     (defined $hash      && $hash      =~ m!^refs/\Q$ref\E/(.*)$!)) {
2616                         $branch = $1;
2617                         $matched_ref = $ref;
2618                         last;
2619                 }
2620         }
2621         # find log type for feed description (title)
2622         my $type = 'log';
2623         if (defined $file_name) {
2624                 $type  = "history of $file_name";
2625                 $type .= "/" if ($action eq 'tree');
2626                 $type .= " on '$branch'" if (defined $branch);
2627         } else {
2628                 $type = "log of $branch" if (defined $branch);
2629         }
2630
2631         $res{-title} = $type;
2632         $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2633         $res{'file_name'} = $file_name;
2634
2635         return %res;
2636 }
2637
2638 ## ----------------------------------------------------------------------
2639 ## git utility subroutines, invoking git commands
2640
2641 # returns path to the core git executable and the --git-dir parameter as list
2642 sub git_cmd {
2643         $number_of_git_cmds++;
2644         return $GIT, '--git-dir='.$git_dir;
2645 }
2646
2647 # quote the given arguments for passing them to the shell
2648 # quote_command("command", "arg 1", "arg with ' and ! characters")
2649 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2650 # Try to avoid using this function wherever possible.
2651 sub quote_command {
2652         return join(' ',
2653                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2654 }
2655
2656 # get HEAD ref of given project as hash
2657 sub git_get_head_hash {
2658         return git_get_full_hash(shift, 'HEAD');
2659 }
2660
2661 sub git_get_full_hash {
2662         return git_get_hash(@_);
2663 }
2664
2665 sub git_get_short_hash {
2666         return git_get_hash(@_, '--short=7');
2667 }
2668
2669 sub git_get_hash {
2670         my ($project, $hash, @options) = @_;
2671         my $o_git_dir = $git_dir;
2672         my $retval = undef;
2673         $git_dir = "$projectroot/$project";
2674         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2675             '--verify', '-q', @options, $hash) {
2676                 $retval = <$fd>;
2677                 chomp $retval if defined $retval;
2678                 close $fd;
2679         }
2680         if (defined $o_git_dir) {
2681                 $git_dir = $o_git_dir;
2682         }
2683         return $retval;
2684 }
2685
2686 # get type of given object
2687 sub git_get_type {
2688         my $hash = shift;
2689
2690         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2691         my $type = <$fd>;
2692         close $fd or return;
2693         chomp $type;
2694         return $type;
2695 }
2696
2697 # repository configuration
2698 our $config_file = '';
2699 our %config;
2700
2701 # store multiple values for single key as anonymous array reference
2702 # single values stored directly in the hash, not as [ <value> ]
2703 sub hash_set_multi {
2704         my ($hash, $key, $value) = @_;
2705
2706         if (!exists $hash->{$key}) {
2707                 $hash->{$key} = $value;
2708         } elsif (!ref $hash->{$key}) {
2709                 $hash->{$key} = [ $hash->{$key}, $value ];
2710         } else {
2711                 push @{$hash->{$key}}, $value;
2712         }
2713 }
2714
2715 # return hash of git project configuration
2716 # optionally limited to some section, e.g. 'gitweb'
2717 sub git_parse_project_config {
2718         my $section_regexp = shift;
2719         my %config;
2720
2721         local $/ = "\0";
2722
2723         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2724                 or return;
2725
2726         while (my $keyval = <$fh>) {
2727                 chomp $keyval;
2728                 my ($key, $value) = split(/\n/, $keyval, 2);
2729
2730                 hash_set_multi(\%config, $key, $value)
2731                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2732         }
2733         close $fh;
2734
2735         return %config;
2736 }
2737
2738 # convert config value to boolean: 'true' or 'false'
2739 # no value, number > 0, 'true' and 'yes' values are true
2740 # rest of values are treated as false (never as error)
2741 sub config_to_bool {
2742         my $val = shift;
2743
2744         return 1 if !defined $val;             # section.key
2745
2746         # strip leading and trailing whitespace
2747         $val =~ s/^\s+//;
2748         $val =~ s/\s+$//;
2749
2750         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2751                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2752 }
2753
2754 # convert config value to simple decimal number
2755 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2756 # to be multiplied by 1024, 1048576, or 1073741824
2757 sub config_to_int {
2758         my $val = shift;
2759
2760         # strip leading and trailing whitespace
2761         $val =~ s/^\s+//;
2762         $val =~ s/\s+$//;
2763
2764         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2765                 $unit = lc($unit);
2766                 # unknown unit is treated as 1
2767                 return $num * ($unit eq 'g' ? 1073741824 :
2768                                $unit eq 'm' ?    1048576 :
2769                                $unit eq 'k' ?       1024 : 1);
2770         }
2771         return $val;
2772 }
2773
2774 # convert config value to array reference, if needed
2775 sub config_to_multi {
2776         my $val = shift;
2777
2778         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2779 }
2780
2781 sub git_get_project_config {
2782         my ($key, $type) = @_;
2783
2784         return unless defined $git_dir;
2785
2786         # key sanity check
2787         return unless ($key);
2788         # only subsection, if exists, is case sensitive,
2789         # and not lowercased by 'git config -z -l'
2790         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2791                 $lo =~ s/_//g;
2792                 $key = join(".", lc($hi), $mi, lc($lo));
2793                 return if ($lo =~ /\W/ || $hi =~ /\W/);
2794         } else {
2795                 $key = lc($key);
2796                 $key =~ s/_//g;
2797                 return if ($key =~ /\W/);
2798         }
2799         $key =~ s/^gitweb\.//;
2800
2801         # type sanity check
2802         if (defined $type) {
2803                 $type =~ s/^--//;
2804                 $type = undef
2805                         unless ($type eq 'bool' || $type eq 'int');
2806         }
2807
2808         # get config
2809         if (!defined $config_file ||
2810             $config_file ne "$git_dir/config") {
2811                 %config = git_parse_project_config('gitweb');
2812                 $config_file = "$git_dir/config";
2813         }
2814
2815         # check if config variable (key) exists
2816         return unless exists $config{"gitweb.$key"};
2817
2818         # ensure given type
2819         if (!defined $type) {
2820                 return $config{"gitweb.$key"};
2821         } elsif ($type eq 'bool') {
2822                 # backward compatibility: 'git config --bool' returns true/false
2823                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2824         } elsif ($type eq 'int') {
2825                 return config_to_int($config{"gitweb.$key"});
2826         }
2827         return $config{"gitweb.$key"};
2828 }
2829
2830 # get hash of given path at given ref
2831 sub git_get_hash_by_path {
2832         my $base = shift;
2833         my $path = shift || return undef;
2834         my $type = shift;
2835
2836         $path =~ s,/+$,,;
2837
2838         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2839                 or die_error(500, "Open git-ls-tree failed");
2840         my $line = <$fd>;
2841         close $fd or return undef;
2842
2843         if (!defined $line) {
2844                 # there is no tree or hash given by $path at $base
2845                 return undef;
2846         }
2847
2848         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2849         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2850         if (defined $type && $type ne $2) {
2851                 # type doesn't match
2852                 return undef;
2853         }
2854         return $3;
2855 }
2856
2857 # get path of entry with given hash at given tree-ish (ref)
2858 # used to get 'from' filename for combined diff (merge commit) for renames
2859 sub git_get_path_by_hash {
2860         my $base = shift || return;
2861         my $hash = shift || return;
2862
2863         local $/ = "\0";
2864
2865         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2866                 or return undef;
2867         while (my $line = <$fd>) {
2868                 chomp $line;
2869
2870                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2871                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2872                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2873                         close $fd;
2874                         return $1;
2875                 }
2876         }
2877         close $fd;
2878         return undef;
2879 }
2880
2881 ## ......................................................................
2882 ## git utility functions, directly accessing git repository
2883
2884 # get the value of config variable either from file named as the variable
2885 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2886 # configuration variable in the repository config file.
2887 sub git_get_file_or_project_config {
2888         my ($path, $name) = @_;
2889
2890         $git_dir = "$projectroot/$path";
2891         open my $fd, '<', "$git_dir/$name"
2892                 or return git_get_project_config($name);
2893         my $conf = <$fd>;
2894         close $fd;
2895         if (defined $conf) {
2896                 chomp $conf;
2897         }
2898         return $conf;
2899 }
2900
2901 sub git_get_project_description {
2902         my $path = shift;
2903         return git_get_file_or_project_config($path, 'description');
2904 }
2905
2906 sub git_get_project_category {
2907         my $path = shift;
2908         return git_get_file_or_project_config($path, 'category');
2909 }
2910
2911
2912 # supported formats:
2913 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2914 #   - if its contents is a number, use it as tag weight,
2915 #   - otherwise add a tag with weight 1
2916 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2917 #   the same value multiple times increases tag weight
2918 # * `gitweb.ctag' multi-valued repo config variable
2919 sub git_get_project_ctags {
2920         my $project = shift;
2921         my $ctags = {};
2922
2923         $git_dir = "$projectroot/$project";
2924         if (opendir my $dh, "$git_dir/ctags") {
2925                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2926                 foreach my $tagfile (@files) {
2927                         open my $ct, '<', $tagfile
2928                                 or next;
2929                         my $val = <$ct>;
2930                         chomp $val if $val;
2931                         close $ct;
2932
2933                         (my $ctag = $tagfile) =~ s#.*/##;
2934                         if ($val =~ /^\d+$/) {
2935                                 $ctags->{$ctag} = $val;
2936                         } else {
2937                                 $ctags->{$ctag} = 1;
2938                         }
2939                 }
2940                 closedir $dh;
2941
2942         } elsif (open my $fh, '<', "$git_dir/ctags") {
2943                 while (my $line = <$fh>) {
2944                         chomp $line;
2945                         $ctags->{$line}++ if $line;
2946                 }
2947                 close $fh;
2948
2949         } else {
2950                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2951                 foreach my $tag (@$taglist) {
2952                         $ctags->{$tag}++;
2953                 }
2954         }
2955
2956         return $ctags;
2957 }
2958
2959 # return hash, where keys are content tags ('ctags'),
2960 # and values are sum of weights of given tag in every project
2961 sub git_gather_all_ctags {
2962         my $projects = shift;
2963         my $ctags = {};
2964
2965         foreach my $p (@$projects) {
2966                 foreach my $ct (keys %{$p->{'ctags'}}) {
2967                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2968                 }
2969         }
2970
2971         return $ctags;
2972 }
2973
2974 sub git_populate_project_tagcloud {
2975         my $ctags = shift;
2976
2977         # First, merge different-cased tags; tags vote on casing
2978         my %ctags_lc;
2979         foreach (keys %$ctags) {
2980                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2981                 if (not $ctags_lc{lc $_}->{topcount}
2982                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2983                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2984                         $ctags_lc{lc $_}->{topname} = $_;
2985                 }
2986         }
2987
2988         my $cloud;
2989         my $matched = $input_params{'ctag'};
2990         if (eval { require HTML::TagCloud; 1; }) {
2991                 $cloud = HTML::TagCloud->new;
2992                 foreach my $ctag (sort keys %ctags_lc) {
2993                         # Pad the title with spaces so that the cloud looks
2994                         # less crammed.
2995                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2996                         $title =~ s/ /&nbsp;/g;
2997                         $title =~ s/^/&nbsp;/g;
2998                         $title =~ s/$/&nbsp;/g;
2999                         if (defined $matched && $matched eq $ctag) {
3000                                 $title = qq(<span class="match">$title</span>);
3001                         }
3002                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
3003                                     $ctags_lc{$ctag}->{count});
3004                 }
3005         } else {
3006                 $cloud = {};
3007                 foreach my $ctag (keys %ctags_lc) {
3008                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
3009                         if (defined $matched && $matched eq $ctag) {
3010                                 $title = qq(<span class="match">$title</span>);
3011                         }
3012                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
3013                         $cloud->{$ctag}{ctag} =
3014                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
3015                 }
3016         }
3017         return $cloud;
3018 }
3019
3020 sub git_show_project_tagcloud {
3021         my ($cloud, $count) = @_;
3022         if (ref $cloud eq 'HTML::TagCloud') {
3023                 return $cloud->html_and_css($count);
3024         } else {
3025                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3026                 return
3027                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3028                         join (', ', map {
3029                                 $cloud->{$_}->{'ctag'}
3030                         } splice(@tags, 0, $count)) .
3031                         '</div>';
3032         }
3033 }
3034
3035 sub git_get_project_url_list {
3036         my $path = shift;
3037
3038         $git_dir = "$projectroot/$path";
3039         open my $fd, '<', "$git_dir/cloneurl"
3040                 or return wantarray ?
3041                 @{ config_to_multi(git_get_project_config('url')) } :
3042                    config_to_multi(git_get_project_config('url'));
3043         my @git_project_url_list = map { chomp; $_ } <$fd>;
3044         close $fd;
3045
3046         return wantarray ? @git_project_url_list : \@git_project_url_list;
3047 }
3048
3049 sub git_get_projects_list {
3050         my $filter = shift || '';
3051         my $paranoid = shift;
3052         my @list;
3053
3054         if (-d $projects_list) {
3055                 # search in directory
3056                 my $dir = $projects_list;
3057                 # remove the trailing "/"
3058                 $dir =~ s!/+$!!;
3059                 my $pfxlen = length("$dir");
3060                 my $pfxdepth = ($dir =~ tr!/!!);
3061                 # when filtering, search only given subdirectory
3062                 if ($filter && !$paranoid) {
3063                         $dir .= "/$filter";
3064                         $dir =~ s!/+$!!;
3065                 }
3066
3067                 File::Find::find({
3068                         follow_fast => 1, # follow symbolic links
3069                         follow_skip => 2, # ignore duplicates
3070                         dangling_symlinks => 0, # ignore dangling symlinks, silently
3071                         wanted => sub {
3072                                 # global variables
3073                                 our $project_maxdepth;
3074                                 our $projectroot;
3075                                 # skip project-list toplevel, if we get it.
3076                                 return if (m!^[/.]$!);
3077                                 # only directories can be git repositories
3078                                 return unless (-d $_);
3079                                 # don't traverse too deep (Find is super slow on os x)
3080                                 # $project_maxdepth excludes depth of $projectroot
3081                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3082                                         $File::Find::prune = 1;
3083                                         return;
3084                                 }
3085
3086                                 my $path = substr($File::Find::name, $pfxlen + 1);
3087                                 # paranoidly only filter here
3088                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3089                                         next;
3090                                 }
3091                                 # we check related file in $projectroot
3092                                 if (check_export_ok("$projectroot/$path")) {
3093                                         push @list, { path => $path };
3094                                         $File::Find::prune = 1;
3095                                 }
3096                         },
3097                 }, "$dir");
3098
3099         } elsif (-f $projects_list) {
3100                 # read from file(url-encoded):
3101                 # 'git%2Fgit.git Linus+Torvalds'
3102                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3103                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3104                 open my $fd, '<', $projects_list or return;
3105         PROJECT:
3106                 while (my $line = <$fd>) {
3107                         chomp $line;
3108                         my ($path, $owner) = split ' ', $line;
3109                         $path = unescape($path);
3110                         $owner = unescape($owner);
3111                         if (!defined $path) {
3112                                 next;
3113                         }
3114                         # if $filter is rpovided, check if $path begins with $filter
3115                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3116                                 next;
3117                         }
3118                         if (check_export_ok("$projectroot/$path")) {
3119                                 my $pr = {
3120                                         path => $path
3121                                 };
3122                                 if ($owner) {
3123                                         $pr->{'owner'} = to_utf8($owner);
3124                                 }
3125                                 push @list, $pr;
3126                         }
3127                 }
3128                 close $fd;
3129         }
3130         return @list;
3131 }
3132
3133 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3134 # as side effects it sets 'forks' field to list of forks for forked projects
3135 sub filter_forks_from_projects_list {
3136         my $projects = shift;
3137
3138         my %trie; # prefix tree of directories (path components)
3139         # generate trie out of those directories that might contain forks
3140         foreach my $pr (@$projects) {
3141                 my $path = $pr->{'path'};
3142                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3143                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3144                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3145                 next unless (-d "$projectroot/$path"); # containing directory exists
3146                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3147
3148                 # add to trie
3149                 my @dirs = split('/', $path);
3150                 # walk the trie, until either runs out of components or out of trie
3151                 my $ref = \%trie;
3152                 while (scalar @dirs &&
3153                        exists($ref->{$dirs[0]})) {
3154                         $ref = $ref->{shift @dirs};
3155                 }
3156                 # create rest of trie structure from rest of components
3157                 foreach my $dir (@dirs) {
3158                         $ref = $ref->{$dir} = {};
3159                 }
3160                 # create end marker, store $pr as a data
3161                 $ref->{''} = $pr if (!exists $ref->{''});
3162         }
3163
3164         # filter out forks, by finding shortest prefix match for paths
3165         my @filtered;
3166  PROJECT:
3167         foreach my $pr (@$projects) {
3168                 # trie lookup
3169                 my $ref = \%trie;
3170         DIR:
3171                 foreach my $dir (split('/', $pr->{'path'})) {
3172                         if (exists $ref->{''}) {
3173                                 # found [shortest] prefix, is a fork - skip it
3174                                 push @{$ref->{''}{'forks'}}, $pr;
3175                                 next PROJECT;
3176                         }
3177                         if (!exists $ref->{$dir}) {
3178                                 # not in trie, cannot have prefix, not a fork
3179                                 push @filtered, $pr;
3180                                 next PROJECT;
3181                         }
3182                         # If the dir is there, we just walk one step down the trie.
3183                         $ref = $ref->{$dir};
3184                 }
3185                 # we ran out of trie
3186                 # (shouldn't happen: it's either no match, or end marker)
3187                 push @filtered, $pr;
3188         }
3189
3190         return @filtered;
3191 }
3192
3193 # note: fill_project_list_info must be run first,
3194 # for 'descr_long' and 'ctags' to be filled
3195 sub search_projects_list {
3196         my ($projlist, %opts) = @_;
3197         my $tagfilter  = $opts{'tagfilter'};
3198         my $search_re = $opts{'search_regexp'};
3199
3200         return @$projlist
3201                 unless ($tagfilter || $search_re);
3202
3203         # searching projects require filling to be run before it;
3204         fill_project_list_info($projlist,
3205                                $tagfilter  ? 'ctags' : (),
3206                                $search_re ? ('path', 'descr') : ());
3207         my @projects;
3208  PROJECT:
3209         foreach my $pr (@$projlist) {
3210
3211                 if ($tagfilter) {
3212                         next unless ref($pr->{'ctags'}) eq 'HASH';
3213                         next unless
3214                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3215                 }
3216
3217                 if ($search_re) {
3218                         next unless
3219                                 $pr->{'path'} =~ /$search_re/ ||
3220                                 $pr->{'descr_long'} =~ /$search_re/;
3221                 }
3222
3223                 push @projects, $pr;
3224         }
3225
3226         return @projects;
3227 }
3228
3229 our $gitweb_project_owner = undef;
3230 sub git_get_project_list_from_file {
3231
3232         return if (defined $gitweb_project_owner);
3233
3234         $gitweb_project_owner = {};
3235         # read from file (url-encoded):
3236         # 'git%2Fgit.git Linus+Torvalds'
3237         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3238         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3239         if (-f $projects_list) {
3240                 open(my $fd, '<', $projects_list);
3241                 while (my $line = <$fd>) {
3242                         chomp $line;
3243                         my ($pr, $ow) = split ' ', $line;
3244                         $pr = unescape($pr);
3245                         $ow = unescape($ow);
3246                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3247                 }
3248                 close $fd;
3249         }
3250 }
3251
3252 sub git_get_project_owner {
3253         my $project = shift;
3254         my $owner;
3255
3256         return undef unless $project;
3257         $git_dir = "$projectroot/$project";
3258
3259         if (!defined $gitweb_project_owner) {
3260                 git_get_project_list_from_file();
3261         }
3262
3263         if (exists $gitweb_project_owner->{$project}) {
3264                 $owner = $gitweb_project_owner->{$project};
3265         }
3266         if (!defined $owner){
3267                 $owner = git_get_project_config('owner');
3268         }
3269         if (!defined $owner) {
3270                 $owner = get_file_owner("$git_dir");
3271         }
3272
3273         return $owner;
3274 }
3275
3276 sub git_get_last_activity {
3277         my ($path) = @_;
3278         my $fd;
3279
3280         $git_dir = "$projectroot/$path";
3281         open($fd, "-|", git_cmd(), 'for-each-ref',
3282              '--format=%(committer)',
3283              '--sort=-committerdate',
3284              '--count=1',
3285              map { "refs/$_" } get_branch_refs ()) or return;
3286         my $most_recent = <$fd>;
3287         close $fd or return;
3288         if (defined $most_recent &&
3289             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3290                 my $timestamp = $1;
3291                 my $age = time - $timestamp;
3292                 return ($age, age_string($age));
3293         }
3294         return (undef, undef);
3295 }
3296
3297 # Implementation note: when a single remote is wanted, we cannot use 'git
3298 # remote show -n' because that command always work (assuming it's a remote URL
3299 # if it's not defined), and we cannot use 'git remote show' because that would
3300 # try to make a network roundtrip. So the only way to find if that particular
3301 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3302 # and when we find what we want.
3303 sub git_get_remotes_list {
3304         my $wanted = shift;
3305         my %remotes = ();
3306
3307         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3308         return unless $fd;
3309         while (my $remote = <$fd>) {
3310                 chomp $remote;
3311                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3312                 next if $wanted and not $remote eq $wanted;
3313                 my ($url, $key) = ($1, $2);
3314
3315                 $remotes{$remote} ||= { 'heads' => () };
3316                 $remotes{$remote}{$key} = $url;
3317         }
3318         close $fd or return;
3319         return wantarray ? %remotes : \%remotes;
3320 }
3321
3322 # Takes a hash of remotes as first parameter and fills it by adding the
3323 # available remote heads for each of the indicated remotes.
3324 sub fill_remote_heads {
3325         my $remotes = shift;
3326         my @heads = map { "remotes/$_" } keys %$remotes;
3327         my @remoteheads = git_get_heads_list(undef, @heads);
3328         foreach my $remote (keys %$remotes) {
3329                 $remotes->{$remote}{'heads'} = [ grep {
3330                         $_->{'name'} =~ s!^$remote/!!
3331                         } @remoteheads ];
3332         }
3333 }
3334
3335 sub git_get_references {
3336         my $type = shift || "";
3337         my %refs;
3338         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3339         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3340         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3341                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3342                 or return;
3343
3344         while (my $line = <$fd>) {
3345                 chomp $line;
3346                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3347                         if (defined $refs{$1}) {
3348                                 push @{$refs{$1}}, $2;
3349                         } else {
3350                                 $refs{$1} = [ $2 ];
3351                         }
3352                 }
3353         }
3354         close $fd or return;
3355         return \%refs;
3356 }
3357
3358 sub git_get_rev_name_tags {
3359         my $hash = shift || return undef;
3360
3361         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3362                 or return;
3363         my $name_rev = <$fd>;
3364         close $fd;
3365
3366         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3367                 return $1;
3368         } else {
3369                 # catches also '$hash undefined' output
3370                 return undef;
3371         }
3372 }
3373
3374 ## ----------------------------------------------------------------------
3375 ## parse to hash functions
3376
3377 sub parse_date {
3378         my $epoch = shift;
3379         my $tz = shift || "-0000";
3380
3381         my %date;
3382         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3383         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3384         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3385         $date{'hour'} = $hour;
3386         $date{'minute'} = $min;
3387         $date{'mday'} = $mday;
3388         $date{'day'} = $days[$wday];
3389         $date{'month'} = $months[$mon];
3390         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3391                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3392         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3393                              $mday, $months[$mon], $hour ,$min;
3394         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3395                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3396
3397         my ($tz_sign, $tz_hour, $tz_min) =
3398                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3399         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3400         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3401         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3402         $date{'hour_local'} = $hour;
3403         $date{'minute_local'} = $min;
3404         $date{'tz_local'} = $tz;
3405         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3406                                   1900+$year, $mon+1, $mday,
3407                                   $hour, $min, $sec, $tz);
3408         return %date;
3409 }
3410
3411 sub parse_tag {
3412         my $tag_id = shift;
3413         my %tag;
3414         my @comment;
3415
3416         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3417         $tag{'id'} = $tag_id;
3418         while (my $line = <$fd>) {
3419                 chomp $line;
3420                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3421                         $tag{'object'} = $1;
3422                 } elsif ($line =~ m/^type (.+)$/) {
3423                         $tag{'type'} = $1;
3424                 } elsif ($line =~ m/^tag (.+)$/) {
3425                         $tag{'name'} = $1;
3426                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3427                         $tag{'author'} = $1;
3428                         $tag{'author_epoch'} = $2;
3429                         $tag{'author_tz'} = $3;
3430                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3431                                 $tag{'author_name'}  = $1;
3432                                 $tag{'author_email'} = $2;
3433                         } else {
3434                                 $tag{'author_name'} = $tag{'author'};
3435                         }
3436                 } elsif ($line =~ m/--BEGIN/) {
3437                         push @comment, $line;
3438                         last;
3439                 } elsif ($line eq "") {
3440                         last;
3441                 }
3442         }
3443         push @comment, <$fd>;
3444         $tag{'comment'} = \@comment;
3445         close $fd or return;
3446         if (!defined $tag{'name'}) {
3447                 return
3448         };
3449         return %tag
3450 }
3451
3452 sub parse_commit_text {
3453         my ($commit_text, $withparents) = @_;
3454         my @commit_lines = split '\n', $commit_text;
3455         my %co;
3456
3457         pop @commit_lines; # Remove '\0'
3458
3459         if (! @commit_lines) {
3460                 return;
3461         }
3462
3463         my $header = shift @commit_lines;
3464         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3465                 return;
3466         }
3467         ($co{'id'}, my @parents) = split ' ', $header;
3468         while (my $line = shift @commit_lines) {
3469                 last if $line eq "\n";
3470                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3471                         $co{'tree'} = $1;
3472                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3473                         push @parents, $1;
3474                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3475                         $co{'author'} = to_utf8($1);
3476                         $co{'author_epoch'} = $2;
3477                         $co{'author_tz'} = $3;
3478                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3479                                 $co{'author_name'}  = $1;
3480                                 $co{'author_email'} = $2;
3481                         } else {
3482                                 $co{'author_name'} = $co{'author'};
3483                         }
3484                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3485                         $co{'committer'} = to_utf8($1);
3486                         $co{'committer_epoch'} = $2;
3487                         $co{'committer_tz'} = $3;
3488                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3489                                 $co{'committer_name'}  = $1;
3490                                 $co{'committer_email'} = $2;
3491                         } else {
3492                                 $co{'committer_name'} = $co{'committer'};
3493                         }
3494                 }
3495         }
3496         if (!defined $co{'tree'}) {
3497                 return;
3498         };
3499         $co{'parents'} = \@parents;
3500         $co{'parent'} = $parents[0];
3501
3502         foreach my $title (@commit_lines) {
3503                 $title =~ s/^    //;
3504                 if ($title ne "") {
3505                         $co{'title'} = chop_str($title, 80, 5);
3506                         # remove leading stuff of merges to make the interesting part visible
3507                         if (length($title) > 50) {
3508                                 $title =~ s/^Automatic //;
3509                                 $title =~ s/^merge (of|with) /Merge ... /i;
3510                                 if (length($title) > 50) {
3511                                         $title =~ s/(http|rsync):\/\///;
3512                                 }
3513                                 if (length($title) > 50) {
3514                                         $title =~ s/(master|www|rsync)\.//;
3515                                 }
3516                                 if (length($title) > 50) {
3517                                         $title =~ s/kernel.org:?//;
3518                                 }
3519                                 if (length($title) > 50) {
3520                                         $title =~ s/\/pub\/scm//;
3521                                 }
3522                         }
3523                         $co{'title_short'} = chop_str($title, 50, 5);
3524                         last;
3525                 }
3526         }
3527         if (! defined $co{'title'} || $co{'title'} eq "") {
3528                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3529         }
3530         # remove added spaces
3531         foreach my $line (@commit_lines) {
3532                 $line =~ s/^    //;
3533         }
3534         $co{'comment'} = \@commit_lines;
3535
3536         my $age = time - $co{'committer_epoch'};
3537         $co{'age'} = $age;
3538         $co{'age_string'} = age_string($age);
3539         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3540         if ($age > 60*60*24*7*2) {
3541                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3542                 $co{'age_string_age'} = $co{'age_string'};
3543         } else {
3544                 $co{'age_string_date'} = $co{'age_string'};
3545                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3546         }
3547         return %co;
3548 }
3549
3550 sub parse_commit {
3551         my ($commit_id) = @_;
3552         my %co;
3553
3554         local $/ = "\0";
3555
3556         open my $fd, "-|", git_cmd(), "rev-list",
3557                 "--parents",
3558                 "--header",
3559                 "--max-count=1",
3560                 $commit_id,
3561                 "--",
3562                 or die_error(500, "Open git-rev-list failed");
3563         %co = parse_commit_text(<$fd>, 1);
3564         close $fd;
3565
3566         return %co;
3567 }
3568
3569 sub parse_commits {
3570         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3571         my @cos;
3572
3573         $maxcount ||= 1;
3574         $skip ||= 0;
3575
3576         local $/ = "\0";
3577
3578         open my $fd, "-|", git_cmd(), "rev-list",
3579                 "--header",
3580                 @args,
3581                 ("--max-count=" . $maxcount),
3582                 ("--skip=" . $skip),
3583                 @extra_options,
3584                 $commit_id,
3585                 "--",
3586                 ($filename ? ($filename) : ())
3587                 or die_error(500, "Open git-rev-list failed");
3588         while (my $line = <$fd>) {
3589                 my %co = parse_commit_text($line);
3590                 push @cos, \%co;
3591         }
3592         close $fd;
3593
3594         return wantarray ? @cos : \@cos;
3595 }
3596
3597 # parse line of git-diff-tree "raw" output
3598 sub parse_difftree_raw_line {
3599         my $line = shift;
3600         my %res;
3601
3602         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3603         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3604         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3605                 $res{'from_mode'} = $1;
3606                 $res{'to_mode'} = $2;
3607                 $res{'from_id'} = $3;
3608                 $res{'to_id'} = $4;
3609                 $res{'status'} = $5;
3610                 $res{'similarity'} = $6;
3611                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3612                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3613                 } else {
3614                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3615                 }
3616         }
3617         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3618         # combined diff (for merge commit)
3619         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3620                 $res{'nparents'}  = length($1);
3621                 $res{'from_mode'} = [ split(' ', $2) ];
3622                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3623                 $res{'from_id'} = [ split(' ', $3) ];
3624                 $res{'to_id'} = pop @{$res{'from_id'}};
3625                 $res{'status'} = [ split('', $4) ];
3626                 $res{'to_file'} = unquote($5);
3627         }
3628         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3629         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3630                 $res{'commit'} = $1;
3631         }
3632
3633         return wantarray ? %res : \%res;
3634 }
3635
3636 # wrapper: return parsed line of git-diff-tree "raw" output
3637 # (the argument might be raw line, or parsed info)
3638 sub parsed_difftree_line {
3639         my $line_or_ref = shift;
3640
3641         if (ref($line_or_ref) eq "HASH") {
3642                 # pre-parsed (or generated by hand)
3643                 return $line_or_ref;
3644         } else {
3645                 return parse_difftree_raw_line($line_or_ref);
3646         }
3647 }
3648
3649 # parse line of git-ls-tree output
3650 sub parse_ls_tree_line {
3651         my $line = shift;
3652         my %opts = @_;
3653         my %res;
3654
3655         if ($opts{'-l'}) {
3656                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3657                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3658
3659                 $res{'mode'} = $1;
3660                 $res{'type'} = $2;
3661                 $res{'hash'} = $3;
3662                 $res{'size'} = $4;
3663                 if ($opts{'-z'}) {
3664                         $res{'name'} = $5;
3665                 } else {
3666                         $res{'name'} = unquote($5);
3667                 }
3668         } else {
3669                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3670                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3671
3672                 $res{'mode'} = $1;
3673                 $res{'type'} = $2;
3674                 $res{'hash'} = $3;
3675                 if ($opts{'-z'}) {
3676                         $res{'name'} = $4;
3677                 } else {
3678                         $res{'name'} = unquote($4);
3679                 }
3680         }
3681
3682         return wantarray ? %res : \%res;
3683 }
3684
3685 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3686 sub parse_from_to_diffinfo {
3687         my ($diffinfo, $from, $to, @parents) = @_;
3688
3689         if ($diffinfo->{'nparents'}) {
3690                 # combined diff
3691                 $from->{'file'} = [];
3692                 $from->{'href'} = [];
3693                 fill_from_file_info($diffinfo, @parents)
3694                         unless exists $diffinfo->{'from_file'};
3695                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3696                         $from->{'file'}[$i] =
3697                                 defined $diffinfo->{'from_file'}[$i] ?
3698                                         $diffinfo->{'from_file'}[$i] :
3699                                         $diffinfo->{'to_file'};
3700                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3701                                 $from->{'href'}[$i] = href(action=>"blob",
3702                                                            hash_base=>$parents[$i],
3703                                                            hash=>$diffinfo->{'from_id'}[$i],
3704                                                            file_name=>$from->{'file'}[$i]);
3705                         } else {
3706                                 $from->{'href'}[$i] = undef;
3707                         }
3708                 }
3709         } else {
3710                 # ordinary (not combined) diff
3711                 $from->{'file'} = $diffinfo->{'from_file'};
3712                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3713                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3714                                                hash=>$diffinfo->{'from_id'},
3715                                                file_name=>$from->{'file'});
3716                 } else {
3717                         delete $from->{'href'};
3718                 }
3719         }
3720
3721         $to->{'file'} = $diffinfo->{'to_file'};
3722         if (!is_deleted($diffinfo)) { # file exists in result
3723                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3724                                      hash=>$diffinfo->{'to_id'},
3725                                      file_name=>$to->{'file'});
3726         } else {
3727                 delete $to->{'href'};
3728         }
3729 }
3730
3731 ## ......................................................................
3732 ## parse to array of hashes functions
3733
3734 sub git_get_heads_list {
3735         my ($limit, @classes) = @_;
3736         @classes = get_branch_refs() unless @classes;
3737         my @patterns = map { "refs/$_" } @classes;
3738         my @headslist;
3739
3740         open my $fd, '-|', git_cmd(), 'for-each-ref',
3741                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3742                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3743                 @patterns
3744                 or return;
3745         while (my $line = <$fd>) {
3746                 my %ref_item;
3747
3748                 chomp $line;
3749                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3750                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3751                 my ($committer, $epoch, $tz) =
3752                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3753                 $ref_item{'fullname'}  = $name;
3754                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
3755                 $name =~ s!^refs/($strip_refs|remotes)/!!;
3756                 $ref_item{'name'} = $name;
3757                 # for refs neither in 'heads' nor 'remotes' we want to
3758                 # show their ref dir
3759                 my $ref_dir = (defined $1) ? $1 : '';
3760                 if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
3761                     $ref_item{'name'} .= ' (' . $ref_dir . ')';
3762                 }
3763
3764                 $ref_item{'id'}    = $hash;
3765                 $ref_item{'title'} = $title || '(no commit message)';
3766                 $ref_item{'epoch'} = $epoch;
3767                 if ($epoch) {
3768                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3769                 } else {
3770                         $ref_item{'age'} = "unknown";
3771                 }
3772
3773                 push @headslist, \%ref_item;
3774         }
3775         close $fd;
3776
3777         return wantarray ? @headslist : \@headslist;
3778 }
3779
3780 sub git_get_tags_list {
3781         my $limit = shift;
3782         my @tagslist;
3783
3784         open my $fd, '-|', git_cmd(), 'for-each-ref',
3785                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3786                 '--format=%(objectname) %(objecttype) %(refname) '.
3787                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3788                 'refs/tags'
3789                 or return;
3790         while (my $line = <$fd>) {
3791                 my %ref_item;
3792
3793                 chomp $line;
3794                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3795                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3796                 my ($creator, $epoch, $tz) =
3797                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3798                 $ref_item{'fullname'} = $name;
3799                 $name =~ s!^refs/tags/!!;
3800
3801                 $ref_item{'type'} = $type;
3802                 $ref_item{'id'} = $id;
3803                 $ref_item{'name'} = $name;
3804                 if ($type eq "tag") {
3805                         $ref_item{'subject'} = $title;
3806                         $ref_item{'reftype'} = $reftype;
3807                         $ref_item{'refid'}   = $refid;
3808                 } else {
3809                         $ref_item{'reftype'} = $type;
3810                         $ref_item{'refid'}   = $id;
3811                 }
3812
3813                 if ($type eq "tag" || $type eq "commit") {
3814                         $ref_item{'epoch'} = $epoch;
3815                         if ($epoch) {
3816                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3817                         } else {
3818                                 $ref_item{'age'} = "unknown";
3819                         }
3820                 }
3821
3822                 push @tagslist, \%ref_item;
3823         }
3824         close $fd;
3825
3826         return wantarray ? @tagslist : \@tagslist;
3827 }
3828
3829 ## ----------------------------------------------------------------------
3830 ## filesystem-related functions
3831
3832 sub get_file_owner {
3833         my $path = shift;
3834
3835         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3836         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3837         if (!defined $gcos) {
3838                 return undef;
3839         }
3840         my $owner = $gcos;
3841         $owner =~ s/[,;].*$//;
3842         return to_utf8($owner);
3843 }
3844
3845 # assume that file exists
3846 sub insert_file {
3847         my $filename = shift;
3848
3849         open my $fd, '<', $filename;
3850         print map { to_utf8($_) } <$fd>;
3851         close $fd;
3852 }
3853
3854 ## ......................................................................
3855 ## mimetype related functions
3856
3857 sub mimetype_guess_file {
3858         my $filename = shift;
3859         my $mimemap = shift;
3860         -r $mimemap or return undef;
3861
3862         my %mimemap;
3863         open(my $mh, '<', $mimemap) or return undef;
3864         while (<$mh>) {
3865                 next if m/^#/; # skip comments
3866                 my ($mimetype, @exts) = split(/\s+/);
3867                 foreach my $ext (@exts) {
3868                         $mimemap{$ext} = $mimetype;
3869                 }
3870         }
3871         close($mh);
3872
3873         $filename =~ /\.([^.]*)$/;
3874         return $mimemap{$1};
3875 }
3876
3877 sub mimetype_guess {
3878         my $filename = shift;
3879         my $mime;
3880         $filename =~ /\./ or return undef;
3881
3882         if ($mimetypes_file) {
3883                 my $file = $mimetypes_file;
3884                 if ($file !~ m!^/!) { # if it is relative path
3885                         # it is relative to project
3886                         $file = "$projectroot/$project/$file";
3887                 }
3888                 $mime = mimetype_guess_file($filename, $file);
3889         }
3890         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3891         return $mime;
3892 }
3893
3894 sub blob_mimetype {
3895         my $fd = shift;
3896         my $filename = shift;
3897
3898         if ($filename) {
3899                 my $mime = mimetype_guess($filename);
3900                 $mime and return $mime;
3901         }
3902
3903         # just in case
3904         return $default_blob_plain_mimetype unless $fd;
3905
3906         if (-T $fd) {
3907                 return 'text/plain';
3908         } elsif (! $filename) {
3909                 return 'application/octet-stream';
3910         } elsif ($filename =~ m/\.png$/i) {
3911                 return 'image/png';
3912         } elsif ($filename =~ m/\.gif$/i) {
3913                 return 'image/gif';
3914         } elsif ($filename =~ m/\.jpe?g$/i) {
3915                 return 'image/jpeg';
3916         } else {
3917                 return 'application/octet-stream';
3918         }
3919 }
3920
3921 sub blob_contenttype {
3922         my ($fd, $file_name, $type) = @_;
3923
3924         $type ||= blob_mimetype($fd, $file_name);
3925         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3926                 $type .= "; charset=$default_text_plain_charset";
3927         }
3928
3929         return $type;
3930 }
3931
3932 # guess file syntax for syntax highlighting; return undef if no highlighting
3933 # the name of syntax can (in the future) depend on syntax highlighter used
3934 sub guess_file_syntax {
3935         my ($highlight, $mimetype, $file_name) = @_;
3936         return undef unless ($highlight && defined $file_name);
3937         my $basename = basename($file_name, '.in');
3938         return $highlight_basename{$basename}
3939                 if exists $highlight_basename{$basename};
3940
3941         $basename =~ /\.([^.]*)$/;
3942         my $ext = $1 or return undef;
3943         return $highlight_ext{$ext}
3944                 if exists $highlight_ext{$ext};
3945
3946         return undef;
3947 }
3948
3949 # run highlighter and return FD of its output,
3950 # or return original FD if no highlighting
3951 sub run_highlighter {
3952         my ($fd, $highlight, $syntax) = @_;
3953         return $fd unless ($highlight && defined $syntax);
3954
3955         close $fd;
3956         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3957                   quote_command($highlight_bin).
3958                   " --replace-tabs=8 --fragment --syntax $syntax |"
3959                 or die_error(500, "Couldn't open file or run syntax highlighter");
3960         return $fd;
3961 }
3962
3963 ## ======================================================================
3964 ## functions printing HTML: header, footer, error page
3965
3966 sub get_page_title {
3967         my $title = to_utf8($site_name);
3968
3969         unless (defined $project) {
3970                 if (defined $project_filter) {
3971                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3972                 }
3973                 return $title;
3974         }
3975         $title .= " - " . to_utf8($project);
3976
3977         return $title unless (defined $action);
3978         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3979
3980         return $title unless (defined $file_name);
3981         $title .= " - " . esc_path($file_name);
3982         if ($action eq "tree" && $file_name !~ m|/$|) {
3983                 $title .= "/";
3984         }
3985
3986         return $title;
3987 }
3988
3989 sub get_content_type_html {
3990         # require explicit support from the UA if we are to send the page as
3991         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3992         # we have to do this because MSIE sometimes globs '*/*', pretending to
3993         # support xhtml+xml but choking when it gets what it asked for.
3994         if (defined $cgi->http('HTTP_ACCEPT') &&
3995             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3996             $cgi->Accept('application/xhtml+xml') != 0) {
3997                 return 'application/xhtml+xml';
3998         } else {
3999                 return 'text/html';
4000         }
4001 }
4002
4003 sub print_feed_meta {
4004         if (defined $project) {
4005                 my %href_params = get_feed_info();
4006                 if (!exists $href_params{'-title'}) {
4007                         $href_params{'-title'} = 'log';
4008                 }
4009
4010                 foreach my $format (qw(RSS Atom)) {
4011                         my $type = lc($format);
4012                         my %link_attr = (
4013                                 '-rel' => 'alternate',
4014                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
4015                                 '-type' => "application/$type+xml"
4016                         );
4017
4018                         $href_params{'extra_options'} = undef;
4019                         $href_params{'action'} = $type;
4020                         $link_attr{'-href'} = href(%href_params);
4021                         print "<link ".
4022                               "rel=\"$link_attr{'-rel'}\" ".
4023                               "title=\"$link_attr{'-title'}\" ".
4024                               "href=\"$link_attr{'-href'}\" ".
4025                               "type=\"$link_attr{'-type'}\" ".
4026                               "/>\n";
4027
4028                         $href_params{'extra_options'} = '--no-merges';
4029                         $link_attr{'-href'} = href(%href_params);
4030                         $link_attr{'-title'} .= ' (no merges)';
4031                         print "<link ".
4032                               "rel=\"$link_attr{'-rel'}\" ".
4033                               "title=\"$link_attr{'-title'}\" ".
4034                               "href=\"$link_attr{'-href'}\" ".
4035                               "type=\"$link_attr{'-type'}\" ".
4036                               "/>\n";
4037                 }
4038
4039         } else {
4040                 printf('<link rel="alternate" title="%s projects list" '.
4041                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
4042                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
4043                 printf('<link rel="alternate" title="%s projects feeds" '.
4044                        'href="%s" type="text/x-opml" />'."\n",
4045                        esc_attr($site_name), href(project=>undef, action=>"opml"));
4046         }
4047 }
4048
4049 sub print_header_links {
4050         my $status = shift;
4051
4052         # print out each stylesheet that exist, providing backwards capability
4053         # for those people who defined $stylesheet in a config file
4054         if (defined $stylesheet) {
4055                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4056         } else {
4057                 foreach my $stylesheet (@stylesheets) {
4058                         next unless $stylesheet;
4059                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4060                 }
4061         }
4062         print_feed_meta()
4063                 if ($status eq '200 OK');
4064         if (defined $favicon) {
4065                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
4066         }
4067 }
4068
4069 sub print_nav_breadcrumbs_path {
4070         my $dirprefix = undef;
4071         while (my $part = shift) {
4072                 $dirprefix .= "/" if defined $dirprefix;
4073                 $dirprefix .= $part;
4074                 print $cgi->a({-href => href(project => undef,
4075                                              project_filter => $dirprefix,
4076                                              action => "project_list")},
4077                               esc_html($part)) . " / ";
4078         }
4079 }
4080
4081 sub print_nav_breadcrumbs {
4082         my %opts = @_;
4083
4084         for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
4085                 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
4086         }
4087         if (defined $project) {
4088                 my @dirname = split '/', $project;
4089                 my $projectbasename = pop @dirname;
4090                 print_nav_breadcrumbs_path(@dirname);
4091                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
4092                 if (defined $action) {
4093                         my $action_print = $action ;
4094                         if (defined $opts{-action_extra}) {
4095                                 $action_print = $cgi->a({-href => href(action=>$action)},
4096                                         $action);
4097                         }
4098                         print " / $action_print";
4099                 }
4100                 if (defined $opts{-action_extra}) {
4101                         print " / $opts{-action_extra}";
4102                 }
4103                 print "\n";
4104         } elsif (defined $project_filter) {
4105                 print_nav_breadcrumbs_path(split '/', $project_filter);
4106         }
4107 }
4108
4109 sub print_search_form {
4110         if (!defined $searchtext) {
4111                 $searchtext = "";
4112         }
4113         my $search_hash;
4114         if (defined $hash_base) {
4115                 $search_hash = $hash_base;
4116         } elsif (defined $hash) {
4117                 $search_hash = $hash;
4118         } else {
4119                 $search_hash = "HEAD";
4120         }
4121         my $action = $my_uri;
4122         my $use_pathinfo = gitweb_check_feature('pathinfo');
4123         if ($use_pathinfo) {
4124                 $action .= "/".esc_url($project);
4125         }
4126         print $cgi->start_form(-method => "get", -action => $action) .
4127               "<div class=\"search\">\n" .
4128               (!$use_pathinfo &&
4129               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4130               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4131               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4132               $cgi->popup_menu(-name => 'st', -default => 'commit',
4133                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4134               " " . $cgi->a({-href => href(action=>"search_help"),
4135                              -title => "search help" }, "?") . " search:\n",
4136               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4137               "<span title=\"Extended regular expression\">" .
4138               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4139                              -checked => $search_use_regexp) .
4140               "</span>" .
4141               "</div>" .
4142               $cgi->end_form() . "\n";
4143 }
4144
4145 sub git_header_html {
4146         my $status = shift || "200 OK";
4147         my $expires = shift;
4148         my %opts = @_;
4149
4150         my $title = get_page_title();
4151         my $content_type = get_content_type_html();
4152         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4153                            -status=> $status, -expires => $expires)
4154                 unless ($opts{'-no_http_header'});
4155         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4156         print <<EOF;
4157 <?xml version="1.0" encoding="utf-8"?>
4158 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4159 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4160 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4161 <!-- git core binaries version $git_version -->
4162 <head>
4163 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4164 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4165 <meta name="robots" content="index, nofollow"/>
4166 <title>$title</title>
4167 EOF
4168         # the stylesheet, favicon etc urls won't work correctly with path_info
4169         # unless we set the appropriate base URL
4170         if ($ENV{'PATH_INFO'}) {
4171                 print "<base href=\"".esc_url($base_url)."\" />\n";
4172         }
4173         print_header_links($status);
4174
4175         if (defined $site_html_head_string) {
4176                 print to_utf8($site_html_head_string);
4177         }
4178
4179         print "</head>\n" .
4180               "<body>\n";
4181
4182         if (defined $site_header && -f $site_header) {
4183                 insert_file($site_header);
4184         }
4185
4186         print "<div class=\"page_header\">\n";
4187         if (defined $logo) {
4188                 print $cgi->a({-href => esc_url($logo_url),
4189                                -title => $logo_label},
4190                               $cgi->img({-src => esc_url($logo),
4191                                          -width => 72, -height => 27,
4192                                          -alt => "git",
4193                                          -class => "logo"}));
4194         }
4195         print_nav_breadcrumbs(%opts);
4196         print "</div>\n";
4197
4198         my $have_search = gitweb_check_feature('search');
4199         if (defined $project && $have_search) {
4200                 print_search_form();
4201         }
4202 }
4203
4204 sub git_footer_html {
4205         my $feed_class = 'rss_logo';
4206
4207         print "<div class=\"page_footer\">\n";
4208         if (defined $project) {
4209                 my $descr = git_get_project_description($project);
4210                 if (defined $descr) {
4211                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4212                 }
4213
4214                 my %href_params = get_feed_info();
4215                 if (!%href_params) {
4216                         $feed_class .= ' generic';
4217                 }
4218                 $href_params{'-title'} ||= 'log';
4219
4220                 foreach my $format (qw(RSS Atom)) {
4221                         $href_params{'action'} = lc($format);
4222                         print $cgi->a({-href => href(%href_params),
4223                                       -title => "$href_params{'-title'} $format feed",
4224                                       -class => $feed_class}, $format)."\n";
4225                 }
4226
4227         } else {
4228                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4229                                              project_filter => $project_filter),
4230                               -class => $feed_class}, "OPML") . " ";
4231                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4232                                              project_filter => $project_filter),
4233                               -class => $feed_class}, "TXT") . "\n";
4234         }
4235         print "</div>\n"; # class="page_footer"
4236
4237         if (defined $t0 && gitweb_check_feature('timed')) {
4238                 print "<div id=\"generating_info\">\n";
4239                 print 'This page took '.
4240                       '<span id="generating_time" class="time_span">'.
4241                       tv_interval($t0, [ gettimeofday() ]).
4242                       ' seconds </span>'.
4243                       ' and '.
4244                       '<span id="generating_cmd">'.
4245                       $number_of_git_cmds.
4246                       '</span> git commands '.
4247                       " to generate.\n";
4248                 print "</div>\n"; # class="page_footer"
4249         }
4250
4251         if (defined $site_footer && -f $site_footer) {
4252                 insert_file($site_footer);
4253         }
4254
4255         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4256         if (defined $action &&
4257             $action eq 'blame_incremental') {
4258                 print qq!<script type="text/javascript">\n!.
4259                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4260                       qq!           "!. href() .qq!");\n!.
4261                       qq!</script>\n!;
4262         } else {
4263                 my ($jstimezone, $tz_cookie, $datetime_class) =
4264                         gitweb_get_feature('javascript-timezone');
4265
4266                 print qq!<script type="text/javascript">\n!.
4267                       qq!window.onload = function () {\n!;
4268                 if (gitweb_check_feature('javascript-actions')) {
4269                         print qq!       fixLinks();\n!;
4270                 }
4271                 if ($jstimezone && $tz_cookie && $datetime_class) {
4272                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4273                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4274                 }
4275                 print qq!};\n!.
4276                       qq!</script>\n!;
4277         }
4278
4279         print "</body>\n" .
4280               "</html>";
4281 }
4282
4283 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4284 # Example: die_error(404, 'Hash not found')
4285 # By convention, use the following status codes (as defined in RFC 2616):
4286 # 400: Invalid or missing CGI parameters, or
4287 #      requested object exists but has wrong type.
4288 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4289 #      this server or project.
4290 # 404: Requested object/revision/project doesn't exist.
4291 # 500: The server isn't configured properly, or
4292 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4293 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4294 # 503: The server is currently unavailable (because it is overloaded,
4295 #      or down for maintenance).  Generally, this is a temporary state.
4296 sub die_error {
4297         my $status = shift || 500;
4298         my $error = esc_html(shift) || "Internal Server Error";
4299         my $extra = shift;
4300         my %opts = @_;
4301
4302         my %http_responses = (
4303                 400 => '400 Bad Request',
4304                 403 => '403 Forbidden',
4305                 404 => '404 Not Found',
4306                 500 => '500 Internal Server Error',
4307                 503 => '503 Service Unavailable',
4308         );
4309         git_header_html($http_responses{$status}, undef, %opts);
4310         print <<EOF;
4311 <div class="page_body">
4312 <br /><br />
4313 $status - $error
4314 <br />
4315 EOF
4316         if (defined $extra) {
4317                 print "<hr />\n" .
4318                       "$extra\n";
4319         }
4320         print "</div>\n";
4321
4322         git_footer_html();
4323         goto DONE_GITWEB
4324                 unless ($opts{'-error_handler'});
4325 }
4326
4327 ## ----------------------------------------------------------------------
4328 ## functions printing or outputting HTML: navigation
4329
4330 sub git_print_page_nav {
4331         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4332         $extra = '' if !defined $extra; # pager or formats
4333
4334         my @navs = qw(summary shortlog log commit commitdiff tree);
4335         if ($suppress) {
4336                 @navs = grep { $_ ne $suppress } @navs;
4337         }
4338
4339         my %arg = map { $_ => {action=>$_} } @navs;
4340         if (defined $head) {
4341                 for (qw(commit commitdiff)) {
4342                         $arg{$_}{'hash'} = $head;
4343                 }
4344                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4345                         for (qw(shortlog log)) {
4346                                 $arg{$_}{'hash'} = $head;
4347                         }
4348                 }
4349         }
4350
4351         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4352         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4353
4354         my @actions = gitweb_get_feature('actions');
4355         my %repl = (
4356                 '%' => '%',
4357                 'n' => $project,         # project name
4358                 'f' => $git_dir,         # project path within filesystem
4359                 'h' => $treehead || '',  # current hash ('h' parameter)
4360                 'b' => $treebase || '',  # hash base ('hb' parameter)
4361         );
4362         while (@actions) {
4363                 my ($label, $link, $pos) = splice(@actions,0,3);
4364                 # insert
4365                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4366                 # munch munch
4367                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4368                 $arg{$label}{'_href'} = $link;
4369         }
4370
4371         print "<div class=\"page_nav\">\n" .
4372                 (join " | ",
4373                  map { $_ eq $current ?
4374                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4375                  } @navs);
4376         print "<br/>\n$extra<br/>\n" .
4377               "</div>\n";
4378 }
4379
4380 # returns a submenu for the nagivation of the refs views (tags, heads,
4381 # remotes) with the current view disabled and the remotes view only
4382 # available if the feature is enabled
4383 sub format_ref_views {
4384         my ($current) = @_;
4385         my @ref_views = qw{tags heads};
4386         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4387         return join " | ", map {
4388                 $_ eq $current ? $_ :
4389                 $cgi->a({-href => href(action=>$_)}, $_)
4390         } @ref_views
4391 }
4392
4393 sub format_paging_nav {
4394         my ($action, $page, $has_next_link) = @_;
4395         my $paging_nav;
4396
4397
4398         if ($page > 0) {
4399                 $paging_nav .=
4400                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4401                         " &sdot; " .
4402                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4403                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4404         } else {
4405                 $paging_nav .= "first &sdot; prev";
4406         }
4407
4408         if ($has_next_link) {
4409                 $paging_nav .= " &sdot; " .
4410                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4411                                  -accesskey => "n", -title => "Alt-n"}, "next");
4412         } else {
4413                 $paging_nav .= " &sdot; next";
4414         }
4415
4416         return $paging_nav;
4417 }
4418
4419 ## ......................................................................
4420 ## functions printing or outputting HTML: div
4421
4422 sub git_print_header_div {
4423         my ($action, $title, $hash, $hash_base) = @_;
4424         my %args = ();
4425
4426         $args{'action'} = $action;
4427         $args{'hash'} = $hash if $hash;
4428         $args{'hash_base'} = $hash_base if $hash_base;
4429
4430         print "<div class=\"header\">\n" .
4431               $cgi->a({-href => href(%args), -class => "title"},
4432               $title ? $title : $action) .
4433               "\n</div>\n";
4434 }
4435
4436 sub format_repo_url {
4437         my ($name, $url) = @_;
4438         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4439 }
4440
4441 # Group output by placing it in a DIV element and adding a header.
4442 # Options for start_div() can be provided by passing a hash reference as the
4443 # first parameter to the function.
4444 # Options to git_print_header_div() can be provided by passing an array
4445 # reference. This must follow the options to start_div if they are present.
4446 # The content can be a scalar, which is output as-is, a scalar reference, which
4447 # is output after html escaping, an IO handle passed either as *handle or
4448 # *handle{IO}, or a function reference. In the latter case all following
4449 # parameters will be taken as argument to the content function call.
4450 sub git_print_section {
4451         my ($div_args, $header_args, $content);
4452         my $arg = shift;
4453         if (ref($arg) eq 'HASH') {
4454                 $div_args = $arg;
4455                 $arg = shift;
4456         }
4457         if (ref($arg) eq 'ARRAY') {
4458                 $header_args = $arg;
4459                 $arg = shift;
4460         }
4461         $content = $arg;
4462
4463         print $cgi->start_div($div_args);
4464         git_print_header_div(@$header_args);
4465
4466         if (ref($content) eq 'CODE') {
4467                 $content->(@_);
4468         } elsif (ref($content) eq 'SCALAR') {
4469                 print esc_html($$content);
4470         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4471                 print <$content>;
4472         } elsif (!ref($content) && defined($content)) {
4473                 print $content;
4474         }
4475
4476         print $cgi->end_div;
4477 }
4478
4479 sub format_timestamp_html {
4480         my $date = shift;
4481         my $strtime = $date->{'rfc2822'};
4482
4483         my (undef, undef, $datetime_class) =
4484                 gitweb_get_feature('javascript-timezone');
4485         if ($datetime_class) {
4486                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4487         }
4488
4489         my $localtime_format = '(%02d:%02d %s)';
4490         if ($date->{'hour_local'} < 6) {
4491                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4492         }
4493         $strtime .= ' ' .
4494                     sprintf($localtime_format,
4495                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4496
4497         return $strtime;
4498 }
4499
4500 # Outputs the author name and date in long form
4501 sub git_print_authorship {
4502         my $co = shift;
4503         my %opts = @_;
4504         my $tag = $opts{-tag} || 'div';
4505         my $author = $co->{'author_name'};
4506
4507         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4508         print "<$tag class=\"author_date\">" .
4509               format_search_author($author, "author", esc_html($author)) .
4510               " [".format_timestamp_html(\%ad)."]".
4511               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4512               "</$tag>\n";
4513 }
4514
4515 # Outputs table rows containing the full author or committer information,
4516 # in the format expected for 'commit' view (& similar).
4517 # Parameters are a commit hash reference, followed by the list of people
4518 # to output information for. If the list is empty it defaults to both
4519 # author and committer.
4520 sub git_print_authorship_rows {
4521         my $co = shift;
4522         # too bad we can't use @people = @_ || ('author', 'committer')
4523         my @people = @_;
4524         @people = ('author', 'committer') unless @people;
4525         foreach my $who (@people) {
4526                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4527                 print "<tr><td>$who</td><td>" .
4528                       format_search_author($co->{"${who}_name"}, $who,
4529                                            esc_html($co->{"${who}_name"})) . " " .
4530                       format_search_author($co->{"${who}_email"}, $who,
4531                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4532                       "</td><td rowspan=\"2\">" .
4533                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4534                       "</td></tr>\n" .
4535                       "<tr>" .
4536                       "<td></td><td>" .
4537                       format_timestamp_html(\%wd) .
4538                       "</td>" .
4539                       "</tr>\n";
4540         }
4541 }
4542
4543 sub git_print_page_path {
4544         my $name = shift;
4545         my $type = shift;
4546         my $hb = shift;
4547
4548
4549         print "<div class=\"page_path\">";
4550         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4551                       -title => 'tree root'}, to_utf8("[$project]"));
4552         print " / ";
4553         if (defined $name) {
4554                 my @dirname = split '/', $name;
4555                 my $basename = pop @dirname;
4556                 my $fullname = '';
4557
4558                 foreach my $dir (@dirname) {
4559                         $fullname .= ($fullname ? '/' : '') . $dir;
4560                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4561                                                      hash_base=>$hb),
4562                                       -title => $fullname}, esc_path($dir));
4563                         print " / ";
4564                 }
4565                 if (defined $type && $type eq 'blob') {
4566                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4567                                                      hash_base=>$hb),
4568                                       -title => $name}, esc_path($basename));
4569                 } elsif (defined $type && $type eq 'tree') {
4570                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4571                                                      hash_base=>$hb),
4572                                       -title => $name}, esc_path($basename));
4573                         print " / ";
4574                 } else {
4575                         print esc_path($basename);
4576                 }
4577         }
4578         print "<br/></div>\n";
4579 }
4580
4581 sub git_print_log {
4582         my $log = shift;
4583         my %opts = @_;
4584
4585         if ($opts{'-remove_title'}) {
4586                 # remove title, i.e. first line of log
4587                 shift @$log;
4588         }
4589         # remove leading empty lines
4590         while (defined $log->[0] && $log->[0] eq "") {
4591                 shift @$log;
4592         }
4593
4594         # print log
4595         my $skip_blank_line = 0;
4596         foreach my $line (@$log) {
4597                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-[Bb]y|C[Cc]): /) {
4598                         if (! $opts{'-remove_signoff'}) {
4599                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4600                                 $skip_blank_line = 1;
4601                         }
4602                         next;
4603                 }
4604
4605                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4606                         if (! $opts{'-remove_signoff'}) {
4607                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4608                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4609                                         "</span><br/>\n";
4610                                 $skip_blank_line = 1;
4611                         }
4612                         next;
4613                 }
4614
4615                 # print only one empty line
4616                 # do not print empty line after signoff
4617                 if ($line eq "") {
4618                         next if ($skip_blank_line);
4619                         $skip_blank_line = 1;
4620                 } else {
4621                         $skip_blank_line = 0;
4622                 }
4623
4624                 print format_log_line_html($line) . "<br/>\n";
4625         }
4626
4627         if ($opts{'-final_empty_line'}) {
4628                 # end with single empty line
4629                 print "<br/>\n" unless $skip_blank_line;
4630         }
4631 }
4632
4633 # return link target (what link points to)
4634 sub git_get_link_target {
4635         my $hash = shift;
4636         my $link_target;
4637
4638         # read link
4639         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4640                 or return;
4641         {
4642                 local $/ = undef;
4643                 $link_target = <$fd>;
4644         }
4645         close $fd
4646                 or return;
4647
4648         return $link_target;
4649 }
4650
4651 # given link target, and the directory (basedir) the link is in,
4652 # return target of link relative to top directory (top tree);
4653 # return undef if it is not possible (including absolute links).
4654 sub normalize_link_target {
4655         my ($link_target, $basedir) = @_;
4656
4657         # absolute symlinks (beginning with '/') cannot be normalized
4658         return if (substr($link_target, 0, 1) eq '/');
4659
4660         # normalize link target to path from top (root) tree (dir)
4661         my $path;
4662         if ($basedir) {
4663                 $path = $basedir . '/' . $link_target;
4664         } else {
4665                 # we are in top (root) tree (dir)
4666                 $path = $link_target;
4667         }
4668
4669         # remove //, /./, and /../
4670         my @path_parts;
4671         foreach my $part (split('/', $path)) {
4672                 # discard '.' and ''
4673                 next if (!$part || $part eq '.');
4674                 # handle '..'
4675                 if ($part eq '..') {
4676                         if (@path_parts) {
4677                                 pop @path_parts;
4678                         } else {
4679                                 # link leads outside repository (outside top dir)
4680                                 return;
4681                         }
4682                 } else {
4683                         push @path_parts, $part;
4684                 }
4685         }
4686         $path = join('/', @path_parts);
4687
4688         return $path;
4689 }
4690
4691 # print tree entry (row of git_tree), but without encompassing <tr> element
4692 sub git_print_tree_entry {
4693         my ($t, $basedir, $hash_base, $have_blame) = @_;
4694
4695         my %base_key = ();
4696         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4697
4698         # The format of a table row is: mode list link.  Where mode is
4699         # the mode of the entry, list is the name of the entry, an href,
4700         # and link is the action links of the entry.
4701
4702         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4703         if (exists $t->{'size'}) {
4704                 print "<td class=\"size\">$t->{'size'}</td>\n";
4705         }
4706         if ($t->{'type'} eq "blob") {
4707                 print "<td class=\"list\">" .
4708                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4709                                                file_name=>"$basedir$t->{'name'}", %base_key),
4710                                 -class => "list"}, esc_path($t->{'name'}));
4711                 if (S_ISLNK(oct $t->{'mode'})) {
4712                         my $link_target = git_get_link_target($t->{'hash'});
4713                         if ($link_target) {
4714                                 my $norm_target = normalize_link_target($link_target, $basedir);
4715                                 if (defined $norm_target) {
4716                                         print " -> " .
4717                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4718                                                                      file_name=>$norm_target),
4719                                                        -title => $norm_target}, esc_path($link_target));
4720                                 } else {
4721                                         print " -> " . esc_path($link_target);
4722                                 }
4723                         }
4724                 }
4725                 print "</td>\n";
4726                 print "<td class=\"link\">";
4727                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4728                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4729                               "blob");
4730                 if ($have_blame) {
4731                         print " | " .
4732                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4733                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4734                                       "blame");
4735                 }
4736                 if (defined $hash_base) {
4737                         print " | " .
4738                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4739                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4740                                       "history");
4741                 }
4742                 print " | " .
4743                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4744                                                file_name=>"$basedir$t->{'name'}")},
4745                                 "raw");
4746                 print "</td>\n";
4747
4748         } elsif ($t->{'type'} eq "tree") {
4749                 print "<td class=\"list\">";
4750                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4751                                              file_name=>"$basedir$t->{'name'}",
4752                                              %base_key)},
4753                               esc_path($t->{'name'}));
4754                 print "</td>\n";
4755                 print "<td class=\"link\">";
4756                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4757                                              file_name=>"$basedir$t->{'name'}",
4758                                              %base_key)},
4759                               "tree");
4760                 if (defined $hash_base) {
4761                         print " | " .
4762                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4763                                                      file_name=>"$basedir$t->{'name'}")},
4764                                       "history");
4765                 }
4766                 print "</td>\n";
4767         } else {
4768                 # unknown object: we can only present history for it
4769                 # (this includes 'commit' object, i.e. submodule support)
4770                 print "<td class=\"list\">" .
4771                       esc_path($t->{'name'}) .
4772                       "</td>\n";
4773                 print "<td class=\"link\">";
4774                 if (defined $hash_base) {
4775                         print $cgi->a({-href => href(action=>"history",
4776                                                      hash_base=>$hash_base,
4777                                                      file_name=>"$basedir$t->{'name'}")},
4778                                       "history");
4779                 }
4780                 print "</td>\n";
4781         }
4782 }
4783
4784 ## ......................................................................
4785 ## functions printing large fragments of HTML
4786
4787 # get pre-image filenames for merge (combined) diff
4788 sub fill_from_file_info {
4789         my ($diff, @parents) = @_;
4790
4791         $diff->{'from_file'} = [ ];
4792         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4793         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4794                 if ($diff->{'status'}[$i] eq 'R' ||
4795                     $diff->{'status'}[$i] eq 'C') {
4796                         $diff->{'from_file'}[$i] =
4797                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4798                 }
4799         }
4800
4801         return $diff;
4802 }
4803
4804 # is current raw difftree line of file deletion
4805 sub is_deleted {
4806         my $diffinfo = shift;
4807
4808         return $diffinfo->{'to_id'} eq ('0' x 40);
4809 }
4810
4811 # does patch correspond to [previous] difftree raw line
4812 # $diffinfo  - hashref of parsed raw diff format
4813 # $patchinfo - hashref of parsed patch diff format
4814 #              (the same keys as in $diffinfo)
4815 sub is_patch_split {
4816         my ($diffinfo, $patchinfo) = @_;
4817
4818         return defined $diffinfo && defined $patchinfo
4819                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4820 }
4821
4822
4823 sub git_difftree_body {
4824         my ($difftree, $hash, @parents) = @_;
4825         my ($parent) = $parents[0];
4826         my $have_blame = gitweb_check_feature('blame');
4827         print "<div class=\"list_head\">\n";
4828         if ($#{$difftree} > 10) {
4829                 print(($#{$difftree} + 1) . " files changed:\n");
4830         }
4831         print "</div>\n";
4832
4833         print "<table class=\"" .
4834               (@parents > 1 ? "combined " : "") .
4835               "diff_tree\">\n";
4836
4837         # header only for combined diff in 'commitdiff' view
4838         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4839         if ($has_header) {
4840                 # table header
4841                 print "<thead><tr>\n" .
4842                        "<th></th><th></th>\n"; # filename, patchN link
4843                 for (my $i = 0; $i < @parents; $i++) {
4844                         my $par = $parents[$i];
4845                         print "<th>" .
4846                               $cgi->a({-href => href(action=>"commitdiff",
4847                                                      hash=>$hash, hash_parent=>$par),
4848                                        -title => 'commitdiff to parent number ' .
4849                                                   ($i+1) . ': ' . substr($par,0,7)},
4850                                       $i+1) .
4851                               "&nbsp;</th>\n";
4852                 }
4853                 print "</tr></thead>\n<tbody>\n";
4854         }
4855
4856         my $alternate = 1;
4857         my $patchno = 0;
4858         foreach my $line (@{$difftree}) {
4859                 my $diff = parsed_difftree_line($line);
4860
4861                 if ($alternate) {
4862                         print "<tr class=\"dark\">\n";
4863                 } else {
4864                         print "<tr class=\"light\">\n";
4865                 }
4866                 $alternate ^= 1;
4867
4868                 if (exists $diff->{'nparents'}) { # combined diff
4869
4870                         fill_from_file_info($diff, @parents)
4871                                 unless exists $diff->{'from_file'};
4872
4873                         if (!is_deleted($diff)) {
4874                                 # file exists in the result (child) commit
4875                                 print "<td>" .
4876                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4877                                                              file_name=>$diff->{'to_file'},
4878                                                              hash_base=>$hash),
4879                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4880                                       "</td>\n";
4881                         } else {
4882                                 print "<td>" .
4883                                       esc_path($diff->{'to_file'}) .
4884                                       "</td>\n";
4885                         }
4886
4887                         if ($action eq 'commitdiff') {
4888                                 # link to patch
4889                                 $patchno++;
4890                                 print "<td class=\"link\">" .
4891                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4892                                               "patch") .
4893                                       " | " .
4894                                       "</td>\n";
4895                         }
4896
4897                         my $has_history = 0;
4898                         my $not_deleted = 0;
4899                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4900                                 my $hash_parent = $parents[$i];
4901                                 my $from_hash = $diff->{'from_id'}[$i];
4902                                 my $from_path = $diff->{'from_file'}[$i];
4903                                 my $status = $diff->{'status'}[$i];
4904
4905                                 $has_history ||= ($status ne 'A');
4906                                 $not_deleted ||= ($status ne 'D');
4907
4908                                 if ($status eq 'A') {
4909                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4910                                 } elsif ($status eq 'D') {
4911                                         print "<td class=\"link\">" .
4912                                               $cgi->a({-href => href(action=>"blob",
4913                                                                      hash_base=>$hash,
4914                                                                      hash=>$from_hash,
4915                                                                      file_name=>$from_path)},
4916                                                       "blob" . ($i+1)) .
4917                                               " | </td>\n";
4918                                 } else {
4919                                         if ($diff->{'to_id'} eq $from_hash) {
4920                                                 print "<td class=\"link nochange\">";
4921                                         } else {
4922                                                 print "<td class=\"link\">";
4923                                         }
4924                                         print $cgi->a({-href => href(action=>"blobdiff",
4925                                                                      hash=>$diff->{'to_id'},
4926                                                                      hash_parent=>$from_hash,
4927                                                                      hash_base=>$hash,
4928                                                                      hash_parent_base=>$hash_parent,
4929                                                                      file_name=>$diff->{'to_file'},
4930                                                                      file_parent=>$from_path)},
4931                                                       "diff" . ($i+1)) .
4932                                               " | </td>\n";
4933                                 }
4934                         }
4935
4936                         print "<td class=\"link\">";
4937                         if ($not_deleted) {
4938                                 print $cgi->a({-href => href(action=>"blob",
4939                                                              hash=>$diff->{'to_id'},
4940                                                              file_name=>$diff->{'to_file'},
4941                                                              hash_base=>$hash)},
4942                                               "blob");
4943                                 print " | " if ($has_history);
4944                         }
4945                         if ($has_history) {
4946                                 print $cgi->a({-href => href(action=>"history",
4947                                                              file_name=>$diff->{'to_file'},
4948                                                              hash_base=>$hash)},
4949                                               "history");
4950                         }
4951                         print "</td>\n";
4952
4953                         print "</tr>\n";
4954                         next; # instead of 'else' clause, to avoid extra indent
4955                 }
4956                 # else ordinary diff
4957
4958                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4959                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4960                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4961                         $to_mode_oct = oct $diff->{'to_mode'};
4962                         if (S_ISREG($to_mode_oct)) { # only for regular file
4963                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4964                         }
4965                         $to_file_type = file_type($diff->{'to_mode'});
4966                 }
4967                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4968                         $from_mode_oct = oct $diff->{'from_mode'};
4969                         if (S_ISREG($from_mode_oct)) { # only for regular file
4970                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4971                         }
4972                         $from_file_type = file_type($diff->{'from_mode'});
4973                 }
4974
4975                 if ($diff->{'status'} eq "A") { # created
4976                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4977                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4978                         $mode_chng   .= "]</span>";
4979                         print "<td>";
4980                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4981                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4982                                       -class => "list"}, esc_path($diff->{'file'}));
4983                         print "</td>\n";
4984                         print "<td>$mode_chng</td>\n";
4985                         print "<td class=\"link\">";
4986                         if ($action eq 'commitdiff') {
4987                                 # link to patch
4988                                 $patchno++;
4989                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4990                                               "patch") .
4991                                       " | ";
4992                         }
4993                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4994                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4995                                       "blob");
4996                         print "</td>\n";
4997
4998                 } elsif ($diff->{'status'} eq "D") { # deleted
4999                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
5000                         print "<td>";
5001                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5002                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
5003                                        -class => "list"}, esc_path($diff->{'file'}));
5004                         print "</td>\n";
5005                         print "<td>$mode_chng</td>\n";
5006                         print "<td class=\"link\">";
5007                         if ($action eq 'commitdiff') {
5008                                 # link to patch
5009                                 $patchno++;
5010                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5011                                               "patch") .
5012                                       " | ";
5013                         }
5014                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5015                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
5016                                       "blob") . " | ";
5017                         if ($have_blame) {
5018                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
5019                                                              file_name=>$diff->{'file'})},
5020                                               "blame") . " | ";
5021                         }
5022                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
5023                                                      file_name=>$diff->{'file'})},
5024                                       "history");
5025                         print "</td>\n";
5026
5027                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
5028                         my $mode_chnge = "";
5029                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5030                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
5031                                 if ($from_file_type ne $to_file_type) {
5032                                         $mode_chnge .= " from $from_file_type to $to_file_type";
5033                                 }
5034                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
5035                                         if ($from_mode_str && $to_mode_str) {
5036                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
5037                                         } elsif ($to_mode_str) {
5038                                                 $mode_chnge .= " mode: $to_mode_str";
5039                                         }
5040                                 }
5041                                 $mode_chnge .= "]</span>\n";
5042                         }
5043                         print "<td>";
5044                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5045                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5046                                       -class => "list"}, esc_path($diff->{'file'}));
5047                         print "</td>\n";
5048                         print "<td>$mode_chnge</td>\n";
5049                         print "<td class=\"link\">";
5050                         if ($action eq 'commitdiff') {
5051                                 # link to patch
5052                                 $patchno++;
5053                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5054                                               "patch") .
5055                                       " | ";
5056                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5057                                 # "commit" view and modified file (not onlu mode changed)
5058                                 print $cgi->a({-href => href(action=>"blobdiff",
5059                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5060                                                              hash_base=>$hash, hash_parent_base=>$parent,
5061                                                              file_name=>$diff->{'file'})},
5062                                               "diff") .
5063                                       " | ";
5064                         }
5065                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5066                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5067                                        "blob") . " | ";
5068                         if ($have_blame) {
5069                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5070                                                              file_name=>$diff->{'file'})},
5071                                               "blame") . " | ";
5072                         }
5073                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5074                                                      file_name=>$diff->{'file'})},
5075                                       "history");
5076                         print "</td>\n";
5077
5078                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
5079                         my %status_name = ('R' => 'moved', 'C' => 'copied');
5080                         my $nstatus = $status_name{$diff->{'status'}};
5081                         my $mode_chng = "";
5082                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5083                                 # mode also for directories, so we cannot use $to_mode_str
5084                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
5085                         }
5086                         print "<td>" .
5087                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
5088                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
5089                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
5090                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
5091                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
5092                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
5093                                       -class => "list"}, esc_path($diff->{'from_file'})) .
5094                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5095                               "<td class=\"link\">";
5096                         if ($action eq 'commitdiff') {
5097                                 # link to patch
5098                                 $patchno++;
5099                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5100                                               "patch") .
5101                                       " | ";
5102                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5103                                 # "commit" view and modified file (not only pure rename or copy)
5104                                 print $cgi->a({-href => href(action=>"blobdiff",
5105                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5106                                                              hash_base=>$hash, hash_parent_base=>$parent,
5107                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5108                                               "diff") .
5109                                       " | ";
5110                         }
5111                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5112                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5113                                       "blob") . " | ";
5114                         if ($have_blame) {
5115                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5116                                                              file_name=>$diff->{'to_file'})},
5117                                               "blame") . " | ";
5118                         }
5119                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5120                                                     file_name=>$diff->{'to_file'})},
5121                                       "history");
5122                         print "</td>\n";
5123
5124                 } # we should not encounter Unmerged (U) or Unknown (X) status
5125                 print "</tr>\n";
5126         }
5127         print "</tbody>" if $has_header;
5128         print "</table>\n";
5129 }
5130
5131 # Print context lines and then rem/add lines in a side-by-side manner.
5132 sub print_sidebyside_diff_lines {
5133         my ($ctx, $rem, $add) = @_;
5134
5135         # print context block before add/rem block
5136         if (@$ctx) {
5137                 print join '',
5138                         '<div class="chunk_block ctx">',
5139                                 '<div class="old">',
5140                                 @$ctx,
5141                                 '</div>',
5142                                 '<div class="new">',
5143                                 @$ctx,
5144                                 '</div>',
5145                         '</div>';
5146         }
5147
5148         if (!@$add) {
5149                 # pure removal
5150                 print join '',
5151                         '<div class="chunk_block rem">',
5152                                 '<div class="old">',
5153                                 @$rem,
5154                                 '</div>',
5155                         '</div>';
5156         } elsif (!@$rem) {
5157                 # pure addition
5158                 print join '',
5159                         '<div class="chunk_block add">',
5160                                 '<div class="new">',
5161                                 @$add,
5162                                 '</div>',
5163                         '</div>';
5164         } else {
5165                 print join '',
5166                         '<div class="chunk_block chg">',
5167                                 '<div class="old">',
5168                                 @$rem,
5169                                 '</div>',
5170                                 '<div class="new">',
5171                                 @$add,
5172                                 '</div>',
5173                         '</div>';
5174         }
5175 }
5176
5177 # Print context lines and then rem/add lines in inline manner.
5178 sub print_inline_diff_lines {
5179         my ($ctx, $rem, $add) = @_;
5180
5181         print @$ctx, @$rem, @$add;
5182 }
5183
5184 # Format removed and added line, mark changed part and HTML-format them.
5185 # Implementation is based on contrib/diff-highlight
5186 sub format_rem_add_lines_pair {
5187         my ($rem, $add, $num_parents) = @_;
5188
5189         # We need to untabify lines before split()'ing them;
5190         # otherwise offsets would be invalid.
5191         chomp $rem;
5192         chomp $add;
5193         $rem = untabify($rem);
5194         $add = untabify($add);
5195
5196         my @rem = split(//, $rem);
5197         my @add = split(//, $add);
5198         my ($esc_rem, $esc_add);
5199         # Ignore leading +/- characters for each parent.
5200         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5201         my ($prefix_has_nonspace, $suffix_has_nonspace);
5202
5203         my $shorter = (@rem < @add) ? @rem : @add;
5204         while ($prefix_len < $shorter) {
5205                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5206
5207                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5208                 $prefix_len++;
5209         }
5210
5211         while ($prefix_len + $suffix_len < $shorter) {
5212                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5213
5214                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5215                 $suffix_len++;
5216         }
5217
5218         # Mark lines that are different from each other, but have some common
5219         # part that isn't whitespace.  If lines are completely different, don't
5220         # mark them because that would make output unreadable, especially if
5221         # diff consists of multiple lines.
5222         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5223                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5224                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5225                 $esc_add = esc_html_hl_regions($add, 'marked',
5226                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5227         } else {
5228                 $esc_rem = esc_html($rem, -nbsp=>1);
5229                 $esc_add = esc_html($add, -nbsp=>1);
5230         }
5231
5232         return format_diff_line(\$esc_rem, 'rem'),
5233                format_diff_line(\$esc_add, 'add');
5234 }
5235
5236 # HTML-format diff context, removed and added lines.
5237 sub format_ctx_rem_add_lines {
5238         my ($ctx, $rem, $add, $num_parents) = @_;
5239         my (@new_ctx, @new_rem, @new_add);
5240         my $can_highlight = 0;
5241         my $is_combined = ($num_parents > 1);
5242
5243         # Highlight if every removed line has a corresponding added line.
5244         if (@$add > 0 && @$add == @$rem) {
5245                 $can_highlight = 1;
5246
5247                 # Highlight lines in combined diff only if the chunk contains
5248                 # diff between the same version, e.g.
5249                 #
5250                 #    - a
5251                 #   -  b
5252                 #    + c
5253                 #   +  d
5254                 #
5255                 # Otherwise the highlightling would be confusing.
5256                 if ($is_combined) {
5257                         for (my $i = 0; $i < @$add; $i++) {
5258                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5259                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5260
5261                                 $prefix_rem =~ s/-/+/g;
5262
5263                                 if ($prefix_rem ne $prefix_add) {
5264                                         $can_highlight = 0;
5265                                         last;
5266                                 }
5267                         }
5268                 }
5269         }
5270
5271         if ($can_highlight) {
5272                 for (my $i = 0; $i < @$add; $i++) {
5273                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5274                                 $rem->[$i], $add->[$i], $num_parents);
5275                         push @new_rem, $line_rem;
5276                         push @new_add, $line_add;
5277                 }
5278         } else {
5279                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5280                 @new_add = map { format_diff_line($_, 'add') } @$add;
5281         }
5282
5283         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5284
5285         return (\@new_ctx, \@new_rem, \@new_add);
5286 }
5287
5288 # Print context lines and then rem/add lines.
5289 sub print_diff_lines {
5290         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5291         my $is_combined = $num_parents > 1;
5292
5293         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5294                 $num_parents);
5295
5296         if ($diff_style eq 'sidebyside' && !$is_combined) {
5297                 print_sidebyside_diff_lines($ctx, $rem, $add);
5298         } else {
5299                 # default 'inline' style and unknown styles
5300                 print_inline_diff_lines($ctx, $rem, $add);
5301         }
5302 }
5303
5304 sub print_diff_chunk {
5305         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5306         my (@ctx, @rem, @add);
5307
5308         # The class of the previous line.
5309         my $prev_class = '';
5310
5311         return unless @chunk;
5312
5313         # incomplete last line might be among removed or added lines,
5314         # or both, or among context lines: find which
5315         for (my $i = 1; $i < @chunk; $i++) {
5316                 if ($chunk[$i][0] eq 'incomplete') {
5317                         $chunk[$i][0] = $chunk[$i-1][0];
5318                 }
5319         }
5320
5321         # guardian
5322         push @chunk, ["", ""];
5323
5324         foreach my $line_info (@chunk) {
5325                 my ($class, $line) = @$line_info;
5326
5327                 # print chunk headers
5328                 if ($class && $class eq 'chunk_header') {
5329                         print format_diff_line($line, $class, $from, $to);
5330                         next;
5331                 }
5332
5333                 ## print from accumulator when have some add/rem lines or end
5334                 # of chunk (flush context lines), or when have add and rem
5335                 # lines and new block is reached (otherwise add/rem lines could
5336                 # be reordered)
5337                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5338                     (@rem && @add && $class ne $prev_class)) {
5339                         print_diff_lines(\@ctx, \@rem, \@add,
5340                                          $diff_style, $num_parents);
5341                         @ctx = @rem = @add = ();
5342                 }
5343
5344                 ## adding lines to accumulator
5345                 # guardian value
5346                 last unless $line;
5347                 # rem, add or change
5348                 if ($class eq 'rem') {
5349                         push @rem, $line;
5350                 } elsif ($class eq 'add') {
5351                         push @add, $line;
5352                 }
5353                 # context line
5354                 if ($class eq 'ctx') {
5355                         push @ctx, $line;
5356                 }
5357
5358                 $prev_class = $class;
5359         }
5360 }
5361
5362 sub git_patchset_body {
5363         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5364         my ($hash_parent) = $hash_parents[0];
5365
5366         my $is_combined = (@hash_parents > 1);
5367         my $patch_idx = 0;
5368         my $patch_number = 0;
5369         my $patch_line;
5370         my $diffinfo;
5371         my $to_name;
5372         my (%from, %to);
5373         my @chunk; # for side-by-side diff
5374
5375         print "<div class=\"patchset\">\n";
5376
5377         # skip to first patch
5378         while ($patch_line = <$fd>) {
5379                 chomp $patch_line;
5380
5381                 last if ($patch_line =~ m/^diff /);
5382         }
5383
5384  PATCH:
5385         while ($patch_line) {
5386
5387                 # parse "git diff" header line
5388                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5389                         # $1 is from_name, which we do not use
5390                         $to_name = unquote($2);
5391                         $to_name =~ s!^b/!!;
5392                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5393                         # $1 is 'cc' or 'combined', which we do not use
5394                         $to_name = unquote($2);
5395                 } else {
5396                         $to_name = undef;
5397                 }
5398
5399                 # check if current patch belong to current raw line
5400                 # and parse raw git-diff line if needed
5401                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5402                         # this is continuation of a split patch
5403                         print "<div class=\"patch cont\">\n";
5404                 } else {
5405                         # advance raw git-diff output if needed
5406                         $patch_idx++ if defined $diffinfo;
5407
5408                         # read and prepare patch information
5409                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5410
5411                         # compact combined diff output can have some patches skipped
5412                         # find which patch (using pathname of result) we are at now;
5413                         if ($is_combined) {
5414                                 while ($to_name ne $diffinfo->{'to_file'}) {
5415                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5416                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5417                                               "</div>\n";  # class="patch"
5418
5419                                         $patch_idx++;
5420                                         $patch_number++;
5421
5422                                         last if $patch_idx > $#$difftree;
5423                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5424                                 }
5425                         }
5426
5427                         # modifies %from, %to hashes
5428                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5429
5430                         # this is first patch for raw difftree line with $patch_idx index
5431                         # we index @$difftree array from 0, but number patches from 1
5432                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5433                 }
5434
5435                 # git diff header
5436                 #assert($patch_line =~ m/^diff /) if DEBUG;
5437                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5438                 $patch_number++;
5439                 # print "git diff" header
5440                 print format_git_diff_header_line($patch_line, $diffinfo,
5441                                                   \%from, \%to);
5442
5443                 # print extended diff header
5444                 print "<div class=\"diff extended_header\">\n";
5445         EXTENDED_HEADER:
5446                 while ($patch_line = <$fd>) {
5447                         chomp $patch_line;
5448
5449                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5450
5451                         print format_extended_diff_header_line($patch_line, $diffinfo,
5452                                                                \%from, \%to);
5453                 }
5454                 print "</div>\n"; # class="diff extended_header"
5455
5456                 # from-file/to-file diff header
5457                 if (! $patch_line) {
5458                         print "</div>\n"; # class="patch"
5459                         last PATCH;
5460                 }
5461                 next PATCH if ($patch_line =~ m/^diff /);
5462                 #assert($patch_line =~ m/^---/) if DEBUG;
5463
5464                 my $last_patch_line = $patch_line;
5465                 $patch_line = <$fd>;
5466                 chomp $patch_line;
5467                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5468
5469                 print format_diff_from_to_header($last_patch_line, $patch_line,
5470                                                  $diffinfo, \%from, \%to,
5471                                                  @hash_parents);
5472
5473                 # the patch itself
5474         LINE:
5475                 while ($patch_line = <$fd>) {
5476                         chomp $patch_line;
5477
5478                         next PATCH if ($patch_line =~ m/^diff /);
5479
5480                         my $class = diff_line_class($patch_line, \%from, \%to);
5481
5482                         if ($class eq 'chunk_header') {
5483                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5484                                 @chunk = ();
5485                         }
5486
5487                         push @chunk, [ $class, $patch_line ];
5488                 }
5489
5490         } continue {
5491                 if (@chunk) {
5492                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5493                         @chunk = ();
5494                 }
5495                 print "</div>\n"; # class="patch"
5496         }
5497
5498         # for compact combined (--cc) format, with chunk and patch simplification
5499         # the patchset might be empty, but there might be unprocessed raw lines
5500         for (++$patch_idx if $patch_number > 0;
5501              $patch_idx < @$difftree;
5502              ++$patch_idx) {
5503                 # read and prepare patch information
5504                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5505
5506                 # generate anchor for "patch" links in difftree / whatchanged part
5507                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5508                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5509                       "</div>\n";  # class="patch"
5510
5511                 $patch_number++;
5512         }
5513
5514         if ($patch_number == 0) {
5515                 if (@hash_parents > 1) {
5516                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5517                 } else {
5518                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5519                 }
5520         }
5521
5522         print "</div>\n"; # class="patchset"
5523 }
5524
5525 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5526
5527 sub git_project_search_form {
5528         my ($searchtext, $search_use_regexp) = @_;
5529
5530         my $limit = '';
5531         if ($project_filter) {
5532                 $limit = " in '$project_filter/'";
5533         }
5534
5535         print "<div class=\"projsearch\">\n";
5536         print $cgi->start_form(-method => 'get', -action => $my_uri) .
5537               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5538         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5539                 if (defined $project_filter);
5540         print $cgi->textfield(-name => 's', -value => $searchtext,
5541                               -title => "Search project by name and description$limit",
5542                               -size => 60) . "\n" .
5543               "<span title=\"Extended regular expression\">" .
5544               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5545                              -checked => $search_use_regexp) .
5546               "</span>\n" .
5547               $cgi->submit(-name => 'btnS', -value => 'Search') .
5548               $cgi->end_form() . "\n" .
5549               $cgi->a({-href => href(project => undef, searchtext => undef,
5550                                      project_filter => $project_filter)},
5551                       esc_html("List all projects$limit")) . "<br />\n";
5552         print "</div>\n";
5553 }
5554
5555 # entry for given @keys needs filling if at least one of keys in list
5556 # is not present in %$project_info
5557 sub project_info_needs_filling {
5558         my ($project_info, @keys) = @_;
5559
5560         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5561         foreach my $key (@keys) {
5562                 if (!exists $project_info->{$key}) {
5563                         return 1;
5564                 }
5565         }
5566         return;
5567 }
5568
5569 # fills project list info (age, description, owner, category, forks, etc.)
5570 # for each project in the list, removing invalid projects from
5571 # returned list, or fill only specified info.
5572 #
5573 # Invalid projects are removed from the returned list if and only if you
5574 # ask 'age' or 'age_string' to be filled, because they are the only fields
5575 # that run unconditionally git command that requires repository, and
5576 # therefore do always check if project repository is invalid.
5577 #
5578 # USAGE:
5579 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5580 #   ensures that 'descr_long' and 'ctags' fields are filled
5581 # * @project_list = fill_project_list_info(\@project_list)
5582 #   ensures that all fields are filled (and invalid projects removed)
5583 #
5584 # NOTE: modifies $projlist, but does not remove entries from it
5585 sub fill_project_list_info {
5586         my ($projlist, @wanted_keys) = @_;
5587         my @projects;
5588         my $filter_set = sub { return @_; };
5589         if (@wanted_keys) {
5590                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5591                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5592         }
5593
5594         my $show_ctags = gitweb_check_feature('ctags');
5595  PROJECT:
5596         foreach my $pr (@$projlist) {
5597                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5598                         my (@activity) = git_get_last_activity($pr->{'path'});
5599                         unless (@activity) {
5600                                 next PROJECT;
5601                         }
5602                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5603                 }
5604                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5605                         my $descr = git_get_project_description($pr->{'path'}) || "";
5606                         $descr = to_utf8($descr);
5607                         $pr->{'descr_long'} = $descr;
5608                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5609                 }
5610                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5611                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5612                 }
5613                 if ($show_ctags &&
5614                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5615                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5616                 }
5617                 if ($projects_list_group_categories &&
5618                     project_info_needs_filling($pr, $filter_set->('category'))) {
5619                         my $cat = git_get_project_category($pr->{'path'}) ||
5620                                                            $project_list_default_category;
5621                         $pr->{'category'} = to_utf8($cat);
5622                 }
5623
5624                 push @projects, $pr;
5625         }
5626
5627         return @projects;
5628 }
5629
5630 sub sort_projects_list {
5631         my ($projlist, $order) = @_;
5632
5633         sub order_str {
5634                 my $key = shift;
5635                 return sub { $a->{$key} cmp $b->{$key} };
5636         }
5637
5638         sub order_num_then_undef {
5639                 my $key = shift;
5640                 return sub {
5641                         defined $a->{$key} ?
5642                                 (defined $b->{$key} ? $a->{$key} <=> $b->{$key} : -1) :
5643                                 (defined $b->{$key} ? 1 : 0)
5644                 };
5645         }
5646
5647         my %orderings = (
5648                 project => order_str('path'),
5649                 descr => order_str('descr_long'),
5650                 owner => order_str('owner'),
5651                 age => order_num_then_undef('age'),
5652         );
5653
5654         my $ordering = $orderings{$order};
5655         return defined $ordering ? sort $ordering @$projlist : @$projlist;
5656 }
5657
5658 # returns a hash of categories, containing the list of project
5659 # belonging to each category
5660 sub build_projlist_by_category {
5661         my ($projlist, $from, $to) = @_;
5662         my %categories;
5663
5664         $from = 0 unless defined $from;
5665         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5666
5667         for (my $i = $from; $i <= $to; $i++) {
5668                 my $pr = $projlist->[$i];
5669                 push @{$categories{ $pr->{'category'} }}, $pr;
5670         }
5671
5672         return wantarray ? %categories : \%categories;
5673 }
5674
5675 # print 'sort by' <th> element, generating 'sort by $name' replay link
5676 # if that order is not selected
5677 sub print_sort_th {
5678         print format_sort_th(@_);
5679 }
5680
5681 sub format_sort_th {
5682         my ($name, $order, $header) = @_;
5683         my $sort_th = "";
5684         $header ||= ucfirst($name);
5685
5686         if ($order eq $name) {
5687                 $sort_th .= "<th>$header</th>\n";
5688         } else {
5689                 $sort_th .= "<th>" .
5690                             $cgi->a({-href => href(-replay=>1, order=>$name),
5691                                      -class => "header"}, $header) .
5692                             "</th>\n";
5693         }
5694
5695         return $sort_th;
5696 }
5697
5698 sub git_project_list_rows {
5699         my ($projlist, $from, $to, $check_forks) = @_;
5700
5701         $from = 0 unless defined $from;
5702         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5703
5704         my $alternate = 1;
5705         for (my $i = $from; $i <= $to; $i++) {
5706                 my $pr = $projlist->[$i];
5707
5708                 if ($alternate) {
5709                         print "<tr class=\"dark\">\n";
5710                 } else {
5711                         print "<tr class=\"light\">\n";
5712                 }
5713                 $alternate ^= 1;
5714
5715                 if ($check_forks) {
5716                         print "<td>";
5717                         if ($pr->{'forks'}) {
5718                                 my $nforks = scalar @{$pr->{'forks'}};
5719                                 if ($nforks > 0) {
5720                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5721                                                        -title => "$nforks forks"}, "+");
5722                                 } else {
5723                                         print $cgi->span({-title => "$nforks forks"}, "+");
5724                                 }
5725                         }
5726                         print "</td>\n";
5727                 }
5728                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5729                                         -class => "list"},
5730                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5731                       "</td>\n" .
5732                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5733                                         -class => "list",
5734                                         -title => $pr->{'descr_long'}},
5735                                         $search_regexp
5736                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5737                                                                     $pr->{'descr'}, $search_regexp)
5738                                         : esc_html($pr->{'descr'})) .
5739                       "</td>\n";
5740                 unless ($omit_owner) {
5741                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5742                 }
5743                 unless ($omit_age_column) {
5744                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5745                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5746                 }
5747                 print"<td class=\"link\">" .
5748                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5749                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5750                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5751                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5752                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5753                       "</td>\n" .
5754                       "</tr>\n";
5755         }
5756 }
5757
5758 sub git_project_list_body {
5759         # actually uses global variable $project
5760         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5761         my @projects = @$projlist;
5762
5763         my $check_forks = gitweb_check_feature('forks');
5764         my $show_ctags  = gitweb_check_feature('ctags');
5765         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5766         $check_forks = undef
5767                 if ($tagfilter || $search_regexp);
5768
5769         # filtering out forks before filling info allows to do less work
5770         @projects = filter_forks_from_projects_list(\@projects)
5771                 if ($check_forks);
5772         # search_projects_list pre-fills required info
5773         @projects = search_projects_list(\@projects,
5774                                          'search_regexp' => $search_regexp,
5775                                          'tagfilter'  => $tagfilter)
5776                 if ($tagfilter || $search_regexp);
5777         # fill the rest
5778         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5779         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5780         push @all_fields, 'owner' unless($omit_owner);
5781         @projects = fill_project_list_info(\@projects, @all_fields);
5782
5783         $order ||= $default_projects_order;
5784         $from = 0 unless defined $from;
5785         $to = $#projects if (!defined $to || $#projects < $to);
5786
5787         # short circuit
5788         if ($from > $to) {
5789                 print "<center>\n".
5790                       "<b>No such projects found</b><br />\n".
5791                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5792                       "</center>\n<br />\n";
5793                 return;
5794         }
5795
5796         @projects = sort_projects_list(\@projects, $order);
5797
5798         if ($show_ctags) {
5799                 my $ctags = git_gather_all_ctags(\@projects);
5800                 my $cloud = git_populate_project_tagcloud($ctags);
5801                 print git_show_project_tagcloud($cloud, 64);
5802         }
5803
5804         print "<table class=\"project_list\">\n";
5805         unless ($no_header) {
5806                 print "<tr>\n";
5807                 if ($check_forks) {
5808                         print "<th></th>\n";
5809                 }
5810                 print_sort_th('project', $order, 'Project');
5811                 print_sort_th('descr', $order, 'Description');
5812                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5813                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5814                 print "<th></th>\n" . # for links
5815                       "</tr>\n";
5816         }
5817
5818         if ($projects_list_group_categories) {
5819                 # only display categories with projects in the $from-$to window
5820                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5821                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5822                 foreach my $cat (sort keys %categories) {
5823                         unless ($cat eq "") {
5824                                 print "<tr>\n";
5825                                 if ($check_forks) {
5826                                         print "<td></td>\n";
5827                                 }
5828                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5829                                 print "</tr>\n";
5830                         }
5831
5832                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5833                 }
5834         } else {
5835                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5836         }
5837
5838         if (defined $extra) {
5839                 print "<tr>\n";
5840                 if ($check_forks) {
5841                         print "<td></td>\n";
5842                 }
5843                 print "<td colspan=\"5\">$extra</td>\n" .
5844                       "</tr>\n";
5845         }
5846         print "</table>\n";
5847 }
5848
5849 sub git_log_body {
5850         # uses global variable $project
5851         my ($commitlist, $from, $to, $refs, $extra) = @_;
5852
5853         $from = 0 unless defined $from;
5854         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5855
5856         for (my $i = 0; $i <= $to; $i++) {
5857                 my %co = %{$commitlist->[$i]};
5858                 next if !%co;
5859                 my $commit = $co{'id'};
5860                 my $ref = format_ref_marker($refs, $commit);
5861                 git_print_header_div('commit',
5862                                "<span class=\"age\">$co{'age_string'}</span>" .
5863                                esc_html($co{'title'}) . $ref,
5864                                $commit);
5865                 print "<div class=\"title_text\">\n" .
5866                       "<div class=\"log_link\">\n" .
5867                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5868                       " | " .
5869                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5870                       " | " .
5871                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5872                       "<br/>\n" .
5873                       "</div>\n";
5874                       git_print_authorship(\%co, -tag => 'span');
5875                       print "<br/>\n</div>\n";
5876
5877                 print "<div class=\"log_body\">\n";
5878                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5879                 print "</div>\n";
5880         }
5881         if ($extra) {
5882                 print "<div class=\"page_nav\">\n";
5883                 print "$extra\n";
5884                 print "</div>\n";
5885         }
5886 }
5887
5888 sub git_shortlog_body {
5889         # uses global variable $project
5890         my ($commitlist, $from, $to, $refs, $extra) = @_;
5891
5892         $from = 0 unless defined $from;
5893         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5894
5895         print "<table class=\"shortlog\">\n";
5896         my $alternate = 1;
5897         for (my $i = $from; $i <= $to; $i++) {
5898                 my %co = %{$commitlist->[$i]};
5899                 my $commit = $co{'id'};
5900                 my $ref = format_ref_marker($refs, $commit);
5901                 if ($alternate) {
5902                         print "<tr class=\"dark\">\n";
5903                 } else {
5904                         print "<tr class=\"light\">\n";
5905                 }
5906                 $alternate ^= 1;
5907                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5908                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5909                       format_author_html('td', \%co, 10) . "<td>";
5910                 print format_subject_html($co{'title'}, $co{'title_short'},
5911                                           href(action=>"commit", hash=>$commit), $ref);
5912                 print "</td>\n" .
5913                       "<td class=\"link\">" .
5914                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5915                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5916                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5917                 my $snapshot_links = format_snapshot_links($commit);
5918                 if (defined $snapshot_links) {
5919                         print " | " . $snapshot_links;
5920                 }
5921                 print "</td>\n" .
5922                       "</tr>\n";
5923         }
5924         if (defined $extra) {
5925                 print "<tr>\n" .
5926                       "<td colspan=\"4\">$extra</td>\n" .
5927                       "</tr>\n";
5928         }
5929         print "</table>\n";
5930 }
5931
5932 sub git_history_body {
5933         # Warning: assumes constant type (blob or tree) during history
5934         my ($commitlist, $from, $to, $refs, $extra,
5935             $file_name, $file_hash, $ftype) = @_;
5936
5937         $from = 0 unless defined $from;
5938         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5939
5940         print "<table class=\"history\">\n";
5941         my $alternate = 1;
5942         for (my $i = $from; $i <= $to; $i++) {
5943                 my %co = %{$commitlist->[$i]};
5944                 if (!%co) {
5945                         next;
5946                 }
5947                 my $commit = $co{'id'};
5948
5949                 my $ref = format_ref_marker($refs, $commit);
5950
5951                 if ($alternate) {
5952                         print "<tr class=\"dark\">\n";
5953                 } else {
5954                         print "<tr class=\"light\">\n";
5955                 }
5956                 $alternate ^= 1;
5957                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5958         # shortlog:   format_author_html('td', \%co, 10)
5959                       format_author_html('td', \%co, 15, 3) . "<td>";
5960                 # originally git_history used chop_str($co{'title'}, 50)
5961                 print format_subject_html($co{'title'}, $co{'title_short'},
5962                                           href(action=>"commit", hash=>$commit), $ref);
5963                 print "</td>\n" .
5964                       "<td class=\"link\">" .
5965                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5966                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5967
5968                 if ($ftype eq 'blob') {
5969                         my $blob_current = $file_hash;
5970                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5971                         if (defined $blob_current && defined $blob_parent &&
5972                                         $blob_current ne $blob_parent) {
5973                                 print " | " .
5974                                         $cgi->a({-href => href(action=>"blobdiff",
5975                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5976                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5977                                                                file_name=>$file_name)},
5978                                                 "diff to current");
5979                         }
5980                 }
5981                 print "</td>\n" .
5982                       "</tr>\n";
5983         }
5984         if (defined $extra) {
5985                 print "<tr>\n" .
5986                       "<td colspan=\"4\">$extra</td>\n" .
5987                       "</tr>\n";
5988         }
5989         print "</table>\n";
5990 }
5991
5992 sub git_tags_body {
5993         # uses global variable $project
5994         my ($taglist, $from, $to, $extra) = @_;
5995         $from = 0 unless defined $from;
5996         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5997
5998         print "<table class=\"tags\">\n";
5999         my $alternate = 1;
6000         for (my $i = $from; $i <= $to; $i++) {
6001                 my $entry = $taglist->[$i];
6002                 my %tag = %$entry;
6003                 my $comment = $tag{'subject'};
6004                 my $comment_short;
6005                 if (defined $comment) {
6006                         $comment_short = chop_str($comment, 30, 5);
6007                 }
6008                 if ($alternate) {
6009                         print "<tr class=\"dark\">\n";
6010                 } else {
6011                         print "<tr class=\"light\">\n";
6012                 }
6013                 $alternate ^= 1;
6014                 if (defined $tag{'age'}) {
6015                         print "<td><i>$tag{'age'}</i></td>\n";
6016                 } else {
6017                         print "<td></td>\n";
6018                 }
6019                 print "<td>" .
6020                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
6021                                -class => "list name"}, esc_html($tag{'name'})) .
6022                       "</td>\n" .
6023                       "<td>";
6024                 if (defined $comment) {
6025                         print format_subject_html($comment, $comment_short,
6026                                                   href(action=>"tag", hash=>$tag{'id'}));
6027                 }
6028                 print "</td>\n" .
6029                       "<td class=\"selflink\">";
6030                 if ($tag{'type'} eq "tag") {
6031                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
6032                 } else {
6033                         print "&nbsp;";
6034                 }
6035                 print "</td>\n" .
6036                       "<td class=\"link\">" . " | " .
6037                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
6038                 if ($tag{'reftype'} eq "commit") {
6039                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
6040                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
6041                 } elsif ($tag{'reftype'} eq "blob") {
6042                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
6043                 }
6044                 print "</td>\n" .
6045                       "</tr>";
6046         }
6047         if (defined $extra) {
6048                 print "<tr>\n" .
6049                       "<td colspan=\"5\">$extra</td>\n" .
6050                       "</tr>\n";
6051         }
6052         print "</table>\n";
6053 }
6054
6055 sub git_heads_body {
6056         # uses global variable $project
6057         my ($headlist, $head_at, $from, $to, $extra) = @_;
6058         $from = 0 unless defined $from;
6059         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
6060
6061         print "<table class=\"heads\">\n";
6062         my $alternate = 1;
6063         for (my $i = $from; $i <= $to; $i++) {
6064                 my $entry = $headlist->[$i];
6065                 my %ref = %$entry;
6066                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
6067                 if ($alternate) {
6068                         print "<tr class=\"dark\">\n";
6069                 } else {
6070                         print "<tr class=\"light\">\n";
6071                 }
6072                 $alternate ^= 1;
6073                 print "<td><i>$ref{'age'}</i></td>\n" .
6074                       ($curr ? "<td class=\"current_head\">" : "<td>") .
6075                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
6076                                -class => "list name"},esc_html($ref{'name'})) .
6077                       "</td>\n" .
6078                       "<td class=\"link\">" .
6079                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
6080                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
6081                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
6082                       "</td>\n" .
6083                       "</tr>";
6084         }
6085         if (defined $extra) {
6086                 print "<tr>\n" .
6087                       "<td colspan=\"3\">$extra</td>\n" .
6088                       "</tr>\n";
6089         }
6090         print "</table>\n";
6091 }
6092
6093 # Display a single remote block
6094 sub git_remote_block {
6095         my ($remote, $rdata, $limit, $head) = @_;
6096
6097         my $heads = $rdata->{'heads'};
6098         my $fetch = $rdata->{'fetch'};
6099         my $push = $rdata->{'push'};
6100
6101         my $urls_table = "<table class=\"projects_list\">\n" ;
6102
6103         if (defined $fetch) {
6104                 if ($fetch eq $push) {
6105                         $urls_table .= format_repo_url("URL", $fetch);
6106                 } else {
6107                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6108                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6109                 }
6110         } elsif (defined $push) {
6111                 $urls_table .= format_repo_url("Push URL", $push);
6112         } else {
6113                 $urls_table .= format_repo_url("", "No remote URL");
6114         }
6115
6116         $urls_table .= "</table>\n";
6117
6118         my $dots;
6119         if (defined $limit && $limit < @$heads) {
6120                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6121         }
6122
6123         print $urls_table;
6124         git_heads_body($heads, $head, 0, $limit, $dots);
6125 }
6126
6127 # Display a list of remote names with the respective fetch and push URLs
6128 sub git_remotes_list {
6129         my ($remotedata, $limit) = @_;
6130         print "<table class=\"heads\">\n";
6131         my $alternate = 1;
6132         my @remotes = sort keys %$remotedata;
6133
6134         my $limited = $limit && $limit < @remotes;
6135
6136         $#remotes = $limit - 1 if $limited;
6137
6138         while (my $remote = shift @remotes) {
6139                 my $rdata = $remotedata->{$remote};
6140                 my $fetch = $rdata->{'fetch'};
6141                 my $push = $rdata->{'push'};
6142                 if ($alternate) {
6143                         print "<tr class=\"dark\">\n";
6144                 } else {
6145                         print "<tr class=\"light\">\n";
6146                 }
6147                 $alternate ^= 1;
6148                 print "<td>" .
6149                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6150                                -class=> "list name"},esc_html($remote)) .
6151                       "</td>";
6152                 print "<td class=\"link\">" .
6153                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6154                       " | " .
6155                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6156                       "</td>";
6157
6158                 print "</tr>\n";
6159         }
6160
6161         if ($limited) {
6162                 print "<tr>\n" .
6163                       "<td colspan=\"3\">" .
6164                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6165                       "</td>\n" . "</tr>\n";
6166         }
6167
6168         print "</table>";
6169 }
6170
6171 # Display remote heads grouped by remote, unless there are too many
6172 # remotes, in which case we only display the remote names
6173 sub git_remotes_body {
6174         my ($remotedata, $limit, $head) = @_;
6175         if ($limit and $limit < keys %$remotedata) {
6176                 git_remotes_list($remotedata, $limit);
6177         } else {
6178                 fill_remote_heads($remotedata);
6179                 while (my ($remote, $rdata) = each %$remotedata) {
6180                         git_print_section({-class=>"remote", -id=>$remote},
6181                                 ["remotes", $remote, $remote], sub {
6182                                         git_remote_block($remote, $rdata, $limit, $head);
6183                                 });
6184                 }
6185         }
6186 }
6187
6188 sub git_search_message {
6189         my %co = @_;
6190
6191         my $greptype;
6192         if ($searchtype eq 'commit') {
6193                 $greptype = "--grep=";
6194         } elsif ($searchtype eq 'author') {
6195                 $greptype = "--author=";
6196         } elsif ($searchtype eq 'committer') {
6197                 $greptype = "--committer=";
6198         }
6199         $greptype .= $searchtext;
6200         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6201                                        $greptype, '--regexp-ignore-case',
6202                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6203
6204         my $paging_nav = '';
6205         if ($page > 0) {
6206                 $paging_nav .=
6207                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6208                                 "first") .
6209                         " &sdot; " .
6210                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6211                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6212         } else {
6213                 $paging_nav .= "first &sdot; prev";
6214         }
6215         my $next_link = '';
6216         if ($#commitlist >= 100) {
6217                 $next_link =
6218                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6219                                  -accesskey => "n", -title => "Alt-n"}, "next");
6220                 $paging_nav .= " &sdot; $next_link";
6221         } else {
6222                 $paging_nav .= " &sdot; next";
6223         }
6224
6225         git_header_html();
6226
6227         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6228         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6229         if ($page == 0 && !@commitlist) {
6230                 print "<p>No match.</p>\n";
6231         } else {
6232                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6233         }
6234
6235         git_footer_html();
6236 }
6237
6238 sub git_search_changes {
6239         my %co = @_;
6240
6241         local $/ = "\n";
6242         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6243                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6244                 ($search_use_regexp ? '--pickaxe-regex' : ())
6245                         or die_error(500, "Open git-log failed");
6246
6247         git_header_html();
6248
6249         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6250         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6251
6252         print "<table class=\"pickaxe search\">\n";
6253         my $alternate = 1;
6254         undef %co;
6255         my @files;
6256         while (my $line = <$fd>) {
6257                 chomp $line;
6258                 next unless $line;
6259
6260                 my %set = parse_difftree_raw_line($line);
6261                 if (defined $set{'commit'}) {
6262                         # finish previous commit
6263                         if (%co) {
6264                                 print "</td>\n" .
6265                                       "<td class=\"link\">" .
6266                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6267                                               "commit") .
6268                                       " | " .
6269                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6270                                                              hash_base=>$co{'id'})},
6271                                               "tree") .
6272                                       "</td>\n" .
6273                                       "</tr>\n";
6274                         }
6275
6276                         if ($alternate) {
6277                                 print "<tr class=\"dark\">\n";
6278                         } else {
6279                                 print "<tr class=\"light\">\n";
6280                         }
6281                         $alternate ^= 1;
6282                         %co = parse_commit($set{'commit'});
6283                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6284                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6285                               "<td><i>$author</i></td>\n" .
6286                               "<td>" .
6287                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6288                                       -class => "list subject"},
6289                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6290                 } elsif (defined $set{'to_id'}) {
6291                         next if ($set{'to_id'} =~ m/^0{40}$/);
6292
6293                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6294                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6295                                       -class => "list"},
6296                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6297                               "<br/>\n";
6298                 }
6299         }
6300         close $fd;
6301
6302         # finish last commit (warning: repetition!)
6303         if (%co) {
6304                 print "</td>\n" .
6305                       "<td class=\"link\">" .
6306                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6307                               "commit") .
6308                       " | " .
6309                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6310                                              hash_base=>$co{'id'})},
6311                               "tree") .
6312                       "</td>\n" .
6313                       "</tr>\n";
6314         }
6315
6316         print "</table>\n";
6317
6318         git_footer_html();
6319 }
6320
6321 sub git_search_files {
6322         my %co = @_;
6323
6324         local $/ = "\n";
6325         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6326                 $search_use_regexp ? ('-E', '-i') : '-F',
6327                 $searchtext, $co{'tree'}
6328                         or die_error(500, "Open git-grep failed");
6329
6330         git_header_html();
6331
6332         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6333         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6334
6335         print "<table class=\"grep_search\">\n";
6336         my $alternate = 1;
6337         my $matches = 0;
6338         my $lastfile = '';
6339         my $file_href;
6340         while (my $line = <$fd>) {
6341                 chomp $line;
6342                 my ($file, $lno, $ltext, $binary);
6343                 last if ($matches++ > 1000);
6344                 if ($line =~ /^Binary file (.+) matches$/) {
6345                         $file = $1;
6346                         $binary = 1;
6347                 } else {
6348                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6349                         $file =~ s/^$co{'tree'}://;
6350                 }
6351                 if ($file ne $lastfile) {
6352                         $lastfile and print "</td></tr>\n";
6353                         if ($alternate++) {
6354                                 print "<tr class=\"dark\">\n";
6355                         } else {
6356                                 print "<tr class=\"light\">\n";
6357                         }
6358                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6359                                           file_name=>$file);
6360                         print "<td class=\"list\">".
6361                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6362                         print "</td><td>\n";
6363                         $lastfile = $file;
6364                 }
6365                 if ($binary) {
6366                         print "<div class=\"binary\">Binary file</div>\n";
6367                 } else {
6368                         $ltext = untabify($ltext);
6369                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6370                                 $ltext = esc_html($1, -nbsp=>1);
6371                                 $ltext .= '<span class="match">';
6372                                 $ltext .= esc_html($2, -nbsp=>1);
6373                                 $ltext .= '</span>';
6374                                 $ltext .= esc_html($3, -nbsp=>1);
6375                         } else {
6376                                 $ltext = esc_html($ltext, -nbsp=>1);
6377                         }
6378                         print "<div class=\"pre\">" .
6379                                 $cgi->a({-href => $file_href.'#l'.$lno,
6380                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6381                                 ' ' .  $ltext . "</div>\n";
6382                 }
6383         }
6384         if ($lastfile) {
6385                 print "</td></tr>\n";
6386                 if ($matches > 1000) {
6387                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6388                 }
6389         } else {
6390                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6391         }
6392         close $fd;
6393
6394         print "</table>\n";
6395
6396         git_footer_html();
6397 }
6398
6399 sub git_search_grep_body {
6400         my ($commitlist, $from, $to, $extra) = @_;
6401         $from = 0 unless defined $from;
6402         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6403
6404         print "<table class=\"commit_search\">\n";
6405         my $alternate = 1;
6406         for (my $i = $from; $i <= $to; $i++) {
6407                 my %co = %{$commitlist->[$i]};
6408                 if (!%co) {
6409                         next;
6410                 }
6411                 my $commit = $co{'id'};
6412                 if ($alternate) {
6413                         print "<tr class=\"dark\">\n";
6414                 } else {
6415                         print "<tr class=\"light\">\n";
6416                 }
6417                 $alternate ^= 1;
6418                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6419                       format_author_html('td', \%co, 15, 5) .
6420                       "<td>" .
6421                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6422                                -class => "list subject"},
6423                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6424                 my $comment = $co{'comment'};
6425                 foreach my $line (@$comment) {
6426                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6427                                 my ($lead, $match, $trail) = ($1, $2, $3);
6428                                 $match = chop_str($match, 70, 5, 'center');
6429                                 my $contextlen = int((80 - length($match))/2);
6430                                 $contextlen = 30 if ($contextlen > 30);
6431                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6432                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6433
6434                                 $lead  = esc_html($lead);
6435                                 $match = esc_html($match);
6436                                 $trail = esc_html($trail);
6437
6438                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6439                         }
6440                 }
6441                 print "</td>\n" .
6442                       "<td class=\"link\">" .
6443                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6444                       " | " .
6445                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6446                       " | " .
6447                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6448                 print "</td>\n" .
6449                       "</tr>\n";
6450         }
6451         if (defined $extra) {
6452                 print "<tr>\n" .
6453                       "<td colspan=\"3\">$extra</td>\n" .
6454                       "</tr>\n";
6455         }
6456         print "</table>\n";
6457 }
6458
6459 ## ======================================================================
6460 ## ======================================================================
6461 ## actions
6462
6463 sub git_project_list {
6464         my $order = $input_params{'order'};
6465         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6466                 die_error(400, "Unknown order parameter");
6467         }
6468
6469         my @list = git_get_projects_list($project_filter, $strict_export);
6470         if (!@list) {
6471                 die_error(404, "No projects found");
6472         }
6473
6474         git_header_html();
6475         if (defined $home_text && -f $home_text) {
6476                 print "<div class=\"index_include\">\n";
6477                 insert_file($home_text);
6478                 print "</div>\n";
6479         }
6480
6481         git_project_search_form($searchtext, $search_use_regexp);
6482         git_project_list_body(\@list, $order);
6483         git_footer_html();
6484 }
6485
6486 sub git_forks {
6487         my $order = $input_params{'order'};
6488         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6489                 die_error(400, "Unknown order parameter");
6490         }
6491
6492         my $filter = $project;
6493         $filter =~ s/\.git$//;
6494         my @list = git_get_projects_list($filter);
6495         if (!@list) {
6496                 die_error(404, "No forks found");
6497         }
6498
6499         git_header_html();
6500         git_print_page_nav('','');
6501         git_print_header_div('summary', "$project forks");
6502         git_project_list_body(\@list, $order);
6503         git_footer_html();
6504 }
6505
6506 sub git_project_index {
6507         my @projects = git_get_projects_list($project_filter, $strict_export);
6508         if (!@projects) {
6509                 die_error(404, "No projects found");
6510         }
6511
6512         print $cgi->header(
6513                 -type => 'text/plain',
6514                 -charset => 'utf-8',
6515                 -content_disposition => 'inline; filename="index.aux"');
6516
6517         foreach my $pr (@projects) {
6518                 if (!exists $pr->{'owner'}) {
6519                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6520                 }
6521
6522                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6523                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6524                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6525                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6526                 $path  =~ s/ /\+/g;
6527                 $owner =~ s/ /\+/g;
6528
6529                 print "$path $owner\n";
6530         }
6531 }
6532
6533 sub git_summary {
6534         my $descr = git_get_project_description($project) || "none";
6535         my %co = parse_commit("HEAD");
6536         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6537         my $head = $co{'id'};
6538         my $remote_heads = gitweb_check_feature('remote_heads');
6539
6540         my $owner = git_get_project_owner($project);
6541
6542         my $refs = git_get_references();
6543         # These get_*_list functions return one more to allow us to see if
6544         # there are more ...
6545         my @taglist  = git_get_tags_list(16);
6546         my @headlist = git_get_heads_list(16);
6547         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6548         my @forklist;
6549         my $check_forks = gitweb_check_feature('forks');
6550
6551         if ($check_forks) {
6552                 # find forks of a project
6553                 my $filter = $project;
6554                 $filter =~ s/\.git$//;
6555                 @forklist = git_get_projects_list($filter);
6556                 # filter out forks of forks
6557                 @forklist = filter_forks_from_projects_list(\@forklist)
6558                         if (@forklist);
6559         }
6560
6561         git_header_html();
6562         git_print_page_nav('summary','', $head);
6563
6564         print "<div class=\"title\">&nbsp;</div>\n";
6565         print "<table class=\"projects_list\">\n" .
6566               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6567         if ($owner and not $omit_owner) {
6568                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6569         }
6570         if (defined $cd{'rfc2822'}) {
6571                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6572                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6573         }
6574
6575         # use per project git URL list in $projectroot/$project/cloneurl
6576         # or make project git URL from git base URL and project name
6577         my $url_tag = "URL";
6578         my @url_list = git_get_project_url_list($project);
6579         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6580         foreach my $git_url (@url_list) {
6581                 next unless $git_url;
6582                 print format_repo_url($url_tag, $git_url);
6583                 $url_tag = "";
6584         }
6585
6586         # Tag cloud
6587         my $show_ctags = gitweb_check_feature('ctags');
6588         if ($show_ctags) {
6589                 my $ctags = git_get_project_ctags($project);
6590                 if (%$ctags) {
6591                         # without ability to add tags, don't show if there are none
6592                         my $cloud = git_populate_project_tagcloud($ctags);
6593                         print "<tr id=\"metadata_ctags\">" .
6594                               "<td>content tags</td>" .
6595                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6596                               "</tr>\n";
6597                 }
6598         }
6599
6600         print "</table>\n";
6601
6602         # If XSS prevention is on, we don't include README.html.
6603         # TODO: Allow a readme in some safe format.
6604         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6605                 print "<div class=\"title\">readme</div>\n" .
6606                       "<div class=\"readme\">\n";
6607                 insert_file("$projectroot/$project/README.html");
6608                 print "\n</div>\n"; # class="readme"
6609         }
6610
6611         # we need to request one more than 16 (0..15) to check if
6612         # those 16 are all
6613         my @commitlist = $head ? parse_commits($head, 17) : ();
6614         if (@commitlist) {
6615                 git_print_header_div('shortlog');
6616                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6617                                   $#commitlist <=  15 ? undef :
6618                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6619         }
6620
6621         if (@taglist) {
6622                 git_print_header_div('tags');
6623                 git_tags_body(\@taglist, 0, 15,
6624                               $#taglist <=  15 ? undef :
6625                               $cgi->a({-href => href(action=>"tags")}, "..."));
6626         }
6627
6628         if (@headlist) {
6629                 git_print_header_div('heads');
6630                 git_heads_body(\@headlist, $head, 0, 15,
6631                                $#headlist <= 15 ? undef :
6632                                $cgi->a({-href => href(action=>"heads")}, "..."));
6633         }
6634
6635         if (%remotedata) {
6636                 git_print_header_div('remotes');
6637                 git_remotes_body(\%remotedata, 15, $head);
6638         }
6639
6640         if (@forklist) {
6641                 git_print_header_div('forks');
6642                 git_project_list_body(\@forklist, 'age', 0, 15,
6643                                       $#forklist <= 15 ? undef :
6644                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6645                                       'no_header');
6646         }
6647
6648         git_footer_html();
6649 }
6650
6651 sub git_tag {
6652         my %tag = parse_tag($hash);
6653
6654         if (! %tag) {
6655                 die_error(404, "Unknown tag object");
6656         }
6657
6658         my $head = git_get_head_hash($project);
6659         git_header_html();
6660         git_print_page_nav('','', $head,undef,$head);
6661         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6662         print "<div class=\"title_text\">\n" .
6663               "<table class=\"object_header\">\n" .
6664               "<tr>\n" .
6665               "<td>object</td>\n" .
6666               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6667                                $tag{'object'}) . "</td>\n" .
6668               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6669                                               $tag{'type'}) . "</td>\n" .
6670               "</tr>\n";
6671         if (defined($tag{'author'})) {
6672                 git_print_authorship_rows(\%tag, 'author');
6673         }
6674         print "</table>\n\n" .
6675               "</div>\n";
6676         print "<div class=\"page_body\">";
6677         my $comment = $tag{'comment'};
6678         foreach my $line (@$comment) {
6679                 chomp $line;
6680                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6681         }
6682         print "</div>\n";
6683         git_footer_html();
6684 }
6685
6686 sub git_blame_common {
6687         my $format = shift || 'porcelain';
6688         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6689                 $format = 'incremental';
6690                 $action = 'blame_incremental'; # for page title etc
6691         }
6692
6693         # permissions
6694         gitweb_check_feature('blame')
6695                 or die_error(403, "Blame view not allowed");
6696
6697         # error checking
6698         die_error(400, "No file name given") unless $file_name;
6699         $hash_base ||= git_get_head_hash($project);
6700         die_error(404, "Couldn't find base commit") unless $hash_base;
6701         my %co = parse_commit($hash_base)
6702                 or die_error(404, "Commit not found");
6703         my $ftype = "blob";
6704         if (!defined $hash) {
6705                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6706                         or die_error(404, "Error looking up file");
6707         } else {
6708                 $ftype = git_get_type($hash);
6709                 if ($ftype !~ "blob") {
6710                         die_error(400, "Object is not a blob");
6711                 }
6712         }
6713
6714         my $fd;
6715         if ($format eq 'incremental') {
6716                 # get file contents (as base)
6717                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6718                         or die_error(500, "Open git-cat-file failed");
6719         } elsif ($format eq 'data') {
6720                 # run git-blame --incremental
6721                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6722                         $hash_base, "--", $file_name
6723                         or die_error(500, "Open git-blame --incremental failed");
6724         } else {
6725                 # run git-blame --porcelain
6726                 open $fd, "-|", git_cmd(), "blame", '-p',
6727                         $hash_base, '--', $file_name
6728                         or die_error(500, "Open git-blame --porcelain failed");
6729         }
6730         binmode $fd, ':utf8';
6731
6732         # incremental blame data returns early
6733         if ($format eq 'data') {
6734                 print $cgi->header(
6735                         -type=>"text/plain", -charset => "utf-8",
6736                         -status=> "200 OK");
6737                 local $| = 1; # output autoflush
6738                 while (my $line = <$fd>) {
6739                         print to_utf8($line);
6740                 }
6741                 close $fd
6742                         or print "ERROR $!\n";
6743
6744                 print 'END';
6745                 if (defined $t0 && gitweb_check_feature('timed')) {
6746                         print ' '.
6747                               tv_interval($t0, [ gettimeofday() ]).
6748                               ' '.$number_of_git_cmds;
6749                 }
6750                 print "\n";
6751
6752                 return;
6753         }
6754
6755         # page header
6756         git_header_html();
6757         my $formats_nav =
6758                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6759                         "blob") .
6760                 " | ";
6761         if ($format eq 'incremental') {
6762                 $formats_nav .=
6763                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6764                                 "blame") . " (non-incremental)";
6765         } else {
6766                 $formats_nav .=
6767                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6768                                 "blame") . " (incremental)";
6769         }
6770         $formats_nav .=
6771                 " | " .
6772                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6773                         "history") .
6774                 " | " .
6775                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6776                         "HEAD");
6777         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6778         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6779         git_print_page_path($file_name, $ftype, $hash_base);
6780
6781         # page body
6782         if ($format eq 'incremental') {
6783                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6784                       "This page requires JavaScript to run.\n Use ".
6785                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6786                               'this page').
6787                       " instead.\n".
6788                       "</b></center></div>\n</noscript>\n";
6789
6790                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6791         }
6792
6793         print qq!<div class="page_body">\n!;
6794         print qq!<div id="progress_info">... / ...</div>\n!
6795                 if ($format eq 'incremental');
6796         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6797               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6798               qq!<thead>\n!.
6799               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6800               qq!</thead>\n!.
6801               qq!<tbody>\n!;
6802
6803         my @rev_color = qw(light dark);
6804         my $num_colors = scalar(@rev_color);
6805         my $current_color = 0;
6806
6807         if ($format eq 'incremental') {
6808                 my $color_class = $rev_color[$current_color];
6809
6810                 #contents of a file
6811                 my $linenr = 0;
6812         LINE:
6813                 while (my $line = <$fd>) {
6814                         chomp $line;
6815                         $linenr++;
6816
6817                         print qq!<tr id="l$linenr" class="$color_class">!.
6818                               qq!<td class="sha1"><a href=""> </a></td>!.
6819                               qq!<td class="linenr">!.
6820                               qq!<a class="linenr" href="">$linenr</a></td>!;
6821                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6822                         print qq!</tr>\n!;
6823                 }
6824
6825         } else { # porcelain, i.e. ordinary blame
6826                 my %metainfo = (); # saves information about commits
6827
6828                 # blame data
6829         LINE:
6830                 while (my $line = <$fd>) {
6831                         chomp $line;
6832                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6833                         # no <lines in group> for subsequent lines in group of lines
6834                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6835                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6836                         if (!exists $metainfo{$full_rev}) {
6837                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6838                         }
6839                         my $meta = $metainfo{$full_rev};
6840                         my $data;
6841                         while ($data = <$fd>) {
6842                                 chomp $data;
6843                                 last if ($data =~ s/^\t//); # contents of line
6844                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6845                                         $meta->{$1} = $2 unless exists $meta->{$1};
6846                                 }
6847                                 if ($data =~ /^previous /) {
6848                                         $meta->{'nprevious'}++;
6849                                 }
6850                         }
6851                         my $short_rev = substr($full_rev, 0, 8);
6852                         my $author = $meta->{'author'};
6853                         my %date =
6854                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6855                         my $date = $date{'iso-tz'};
6856                         if ($group_size) {
6857                                 $current_color = ($current_color + 1) % $num_colors;
6858                         }
6859                         my $tr_class = $rev_color[$current_color];
6860                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6861                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6862                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6863                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6864                         if ($group_size) {
6865                                 print "<td class=\"sha1\"";
6866                                 print " title=\"". esc_html($author) . ", $date\"";
6867                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6868                                 print ">";
6869                                 print $cgi->a({-href => href(action=>"commit",
6870                                                              hash=>$full_rev,
6871                                                              file_name=>$file_name)},
6872                                               esc_html($short_rev));
6873                                 if ($group_size >= 2) {
6874                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6875                                         if (@author_initials) {
6876                                                 print "<br />" .
6877                                                       esc_html(join('', @author_initials));
6878                                                 #           or join('.', ...)
6879                                         }
6880                                 }
6881                                 print "</td>\n";
6882                         }
6883                         # 'previous' <sha1 of parent commit> <filename at commit>
6884                         if (exists $meta->{'previous'} &&
6885                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6886                                 $meta->{'parent'} = $1;
6887                                 $meta->{'file_parent'} = unquote($2);
6888                         }
6889                         my $linenr_commit =
6890                                 exists($meta->{'parent'}) ?
6891                                 $meta->{'parent'} : $full_rev;
6892                         my $linenr_filename =
6893                                 exists($meta->{'file_parent'}) ?
6894                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6895                         my $blamed = href(action => 'blame',
6896                                           file_name => $linenr_filename,
6897                                           hash_base => $linenr_commit);
6898                         print "<td class=\"linenr\">";
6899                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6900                                         -class => "linenr" },
6901                                       esc_html($lineno));
6902                         print "</td>";
6903                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6904                         print "</tr>\n";
6905                 } # end while
6906
6907         }
6908
6909         # footer
6910         print "</tbody>\n".
6911               "</table>\n"; # class="blame"
6912         print "</div>\n";   # class="blame_body"
6913         close $fd
6914                 or print "Reading blob failed\n";
6915
6916         git_footer_html();
6917 }
6918
6919 sub git_blame {
6920         git_blame_common();
6921 }
6922
6923 sub git_blame_incremental {
6924         git_blame_common('incremental');
6925 }
6926
6927 sub git_blame_data {
6928         git_blame_common('data');
6929 }
6930
6931 sub git_tags {
6932         my $head = git_get_head_hash($project);
6933         git_header_html();
6934         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6935         git_print_header_div('summary', $project);
6936
6937         my @tagslist = git_get_tags_list();
6938         if (@tagslist) {
6939                 git_tags_body(\@tagslist);
6940         }
6941         git_footer_html();
6942 }
6943
6944 sub git_heads {
6945         my $head = git_get_head_hash($project);
6946         git_header_html();
6947         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6948         git_print_header_div('summary', $project);
6949
6950         my @headslist = git_get_heads_list();
6951         if (@headslist) {
6952                 git_heads_body(\@headslist, $head);
6953         }
6954         git_footer_html();
6955 }
6956
6957 # used both for single remote view and for list of all the remotes
6958 sub git_remotes {
6959         gitweb_check_feature('remote_heads')
6960                 or die_error(403, "Remote heads view is disabled");
6961
6962         my $head = git_get_head_hash($project);
6963         my $remote = $input_params{'hash'};
6964
6965         my $remotedata = git_get_remotes_list($remote);
6966         die_error(500, "Unable to get remote information") unless defined $remotedata;
6967
6968         unless (%$remotedata) {
6969                 die_error(404, defined $remote ?
6970                         "Remote $remote not found" :
6971                         "No remotes found");
6972         }
6973
6974         git_header_html(undef, undef, -action_extra => $remote);
6975         git_print_page_nav('', '',  $head, undef, $head,
6976                 format_ref_views($remote ? '' : 'remotes'));
6977
6978         fill_remote_heads($remotedata);
6979         if (defined $remote) {
6980                 git_print_header_div('remotes', "$remote remote for $project");
6981                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6982         } else {
6983                 git_print_header_div('summary', "$project remotes");
6984                 git_remotes_body($remotedata, undef, $head);
6985         }
6986
6987         git_footer_html();
6988 }
6989
6990 sub git_blob_plain {
6991         my $type = shift;
6992         my $expires;
6993
6994         if (!defined $hash) {
6995                 if (defined $file_name) {
6996                         my $base = $hash_base || git_get_head_hash($project);
6997                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6998                                 or die_error(404, "Cannot find file");
6999                 } else {
7000                         die_error(400, "No file name defined");
7001                 }
7002         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7003                 # blobs defined by non-textual hash id's can be cached
7004                 $expires = "+1d";
7005         }
7006
7007         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7008                 or die_error(500, "Open git-cat-file blob '$hash' failed");
7009
7010         # content-type (can include charset)
7011         $type = blob_contenttype($fd, $file_name, $type);
7012
7013         # "save as" filename, even when no $file_name is given
7014         my $save_as = "$hash";
7015         if (defined $file_name) {
7016                 $save_as = $file_name;
7017         } elsif ($type =~ m/^text\//) {
7018                 $save_as .= '.txt';
7019         }
7020
7021         # With XSS prevention on, blobs of all types except a few known safe
7022         # ones are served with "Content-Disposition: attachment" to make sure
7023         # they don't run in our security domain.  For certain image types,
7024         # blob view writes an <img> tag referring to blob_plain view, and we
7025         # want to be sure not to break that by serving the image as an
7026         # attachment (though Firefox 3 doesn't seem to care).
7027         my $sandbox = $prevent_xss &&
7028                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
7029
7030         # serve text/* as text/plain
7031         if ($prevent_xss &&
7032             ($type =~ m!^text/[a-z]+\b(.*)$! ||
7033              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
7034                 my $rest = $1;
7035                 $rest = defined $rest ? $rest : '';
7036                 $type = "text/plain$rest";
7037         }
7038
7039         print $cgi->header(
7040                 -type => $type,
7041                 -expires => $expires,
7042                 -content_disposition =>
7043                         ($sandbox ? 'attachment' : 'inline')
7044                         . '; filename="' . $save_as . '"');
7045         local $/ = undef;
7046         binmode STDOUT, ':raw';
7047         print <$fd>;
7048         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7049         close $fd;
7050 }
7051
7052 sub git_blob {
7053         my $expires;
7054
7055         if (!defined $hash) {
7056                 if (defined $file_name) {
7057                         my $base = $hash_base || git_get_head_hash($project);
7058                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7059                                 or die_error(404, "Cannot find file");
7060                 } else {
7061                         die_error(400, "No file name defined");
7062                 }
7063         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7064                 # blobs defined by non-textual hash id's can be cached
7065                 $expires = "+1d";
7066         }
7067
7068         my $have_blame = gitweb_check_feature('blame');
7069         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7070                 or die_error(500, "Couldn't cat $file_name, $hash");
7071         my $mimetype = blob_mimetype($fd, $file_name);
7072         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
7073         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
7074                 close $fd;
7075                 return git_blob_plain($mimetype);
7076         }
7077         # we can have blame only for text/* mimetype
7078         $have_blame &&= ($mimetype =~ m!^text/!);
7079
7080         my $highlight = gitweb_check_feature('highlight');
7081         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
7082         $fd = run_highlighter($fd, $highlight, $syntax)
7083                 if $syntax;
7084
7085         git_header_html(undef, $expires);
7086         my $formats_nav = '';
7087         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7088                 if (defined $file_name) {
7089                         if ($have_blame) {
7090                                 $formats_nav .=
7091                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
7092                                                 "blame") .
7093                                         " | ";
7094                         }
7095                         $formats_nav .=
7096                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7097                                         "history") .
7098                                 " | " .
7099                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7100                                         "raw") .
7101                                 " | " .
7102                                 $cgi->a({-href => href(action=>"blob",
7103                                                        hash_base=>"HEAD", file_name=>$file_name)},
7104                                         "HEAD");
7105                 } else {
7106                         $formats_nav .=
7107                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7108                                         "raw");
7109                 }
7110                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7111                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7112         } else {
7113                 print "<div class=\"page_nav\">\n" .
7114                       "<br/><br/></div>\n" .
7115                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7116         }
7117         git_print_page_path($file_name, "blob", $hash_base);
7118         print "<div class=\"page_body\">\n";
7119         if ($mimetype =~ m!^image/!) {
7120                 print qq!<img class="blob" type="!.esc_attr($mimetype).qq!"!;
7121                 if ($file_name) {
7122                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7123                 }
7124                 print qq! src="! .
7125                       href(action=>"blob_plain", hash=>$hash,
7126                            hash_base=>$hash_base, file_name=>$file_name) .
7127                       qq!" />\n!;
7128         } else {
7129                 my $nr;
7130                 while (my $line = <$fd>) {
7131                         chomp $line;
7132                         $nr++;
7133                         $line = untabify($line);
7134                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7135                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7136                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
7137                 }
7138         }
7139         close $fd
7140                 or print "Reading blob failed.\n";
7141         print "</div>";
7142         git_footer_html();
7143 }
7144
7145 sub git_tree {
7146         if (!defined $hash_base) {
7147                 $hash_base = "HEAD";
7148         }
7149         if (!defined $hash) {
7150                 if (defined $file_name) {
7151                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7152                 } else {
7153                         $hash = $hash_base;
7154                 }
7155         }
7156         die_error(404, "No such tree") unless defined($hash);
7157
7158         my $show_sizes = gitweb_check_feature('show-sizes');
7159         my $have_blame = gitweb_check_feature('blame');
7160
7161         my @entries = ();
7162         {
7163                 local $/ = "\0";
7164                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7165                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7166                         or die_error(500, "Open git-ls-tree failed");
7167                 @entries = map { chomp; $_ } <$fd>;
7168                 close $fd
7169                         or die_error(404, "Reading tree failed");
7170         }
7171
7172         my $refs = git_get_references();
7173         my $ref = format_ref_marker($refs, $hash_base);
7174         git_header_html();
7175         my $basedir = '';
7176         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7177                 my @views_nav = ();
7178                 if (defined $file_name) {
7179                         push @views_nav,
7180                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7181                                         "history"),
7182                                 $cgi->a({-href => href(action=>"tree",
7183                                                        hash_base=>"HEAD", file_name=>$file_name)},
7184                                         "HEAD"),
7185                 }
7186                 my $snapshot_links = format_snapshot_links($hash);
7187                 if (defined $snapshot_links) {
7188                         # FIXME: Should be available when we have no hash base as well.
7189                         push @views_nav, $snapshot_links;
7190                 }
7191                 git_print_page_nav('tree','', $hash_base, undef, undef,
7192                                    join(' | ', @views_nav));
7193                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7194         } else {
7195                 undef $hash_base;
7196                 print "<div class=\"page_nav\">\n";
7197                 print "<br/><br/></div>\n";
7198                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7199         }
7200         if (defined $file_name) {
7201                 $basedir = $file_name;
7202                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7203                         $basedir .= '/';
7204                 }
7205                 git_print_page_path($file_name, 'tree', $hash_base);
7206         }
7207         print "<div class=\"page_body\">\n";
7208         print "<table class=\"tree\">\n";
7209         my $alternate = 1;
7210         # '..' (top directory) link if possible
7211         if (defined $hash_base &&
7212             defined $file_name && $file_name =~ m![^/]+$!) {
7213                 if ($alternate) {
7214                         print "<tr class=\"dark\">\n";
7215                 } else {
7216                         print "<tr class=\"light\">\n";
7217                 }
7218                 $alternate ^= 1;
7219
7220                 my $up = $file_name;
7221                 $up =~ s!/?[^/]+$!!;
7222                 undef $up unless $up;
7223                 # based on git_print_tree_entry
7224                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7225                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7226                 print '<td class="list">';
7227                 print $cgi->a({-href => href(action=>"tree",
7228                                              hash_base=>$hash_base,
7229                                              file_name=>$up)},
7230                               "..");
7231                 print "</td>\n";
7232                 print "<td class=\"link\"></td>\n";
7233
7234                 print "</tr>\n";
7235         }
7236         foreach my $line (@entries) {
7237                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7238
7239                 if ($alternate) {
7240                         print "<tr class=\"dark\">\n";
7241                 } else {
7242                         print "<tr class=\"light\">\n";
7243                 }
7244                 $alternate ^= 1;
7245
7246                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7247
7248                 print "</tr>\n";
7249         }
7250         print "</table>\n" .
7251               "</div>";
7252         git_footer_html();
7253 }
7254
7255 sub sanitize_for_filename {
7256     my $name = shift;
7257
7258     $name =~ s!/!-!g;
7259     $name =~ s/[^[:alnum:]_.-]//g;
7260
7261     return $name;
7262 }
7263
7264 sub snapshot_name {
7265         my ($project, $hash) = @_;
7266
7267         # path/to/project.git  -> project
7268         # path/to/project/.git -> project
7269         my $name = to_utf8($project);
7270         $name =~ s,([^/])/*\.git$,$1,;
7271         $name = sanitize_for_filename(basename($name));
7272
7273         my $ver = $hash;
7274         if ($hash =~ /^[0-9a-fA-F]+$/) {
7275                 # shorten SHA-1 hash
7276                 my $full_hash = git_get_full_hash($project, $hash);
7277                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7278                         $ver = git_get_short_hash($project, $hash);
7279                 }
7280         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7281                 # tags don't need shortened SHA-1 hash
7282                 $ver = $1;
7283         } else {
7284                 # branches and other need shortened SHA-1 hash
7285                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
7286                 if ($hash =~ m!^refs/($strip_refs|remotes)/(.*)$!) {
7287                         my $ref_dir = (defined $1) ? $1 : '';
7288                         $ver = $2;
7289
7290                         $ref_dir = sanitize_for_filename($ref_dir);
7291                         # for refs neither in heads nor remotes we want to
7292                         # add a ref dir to archive name
7293                         if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
7294                                 $ver = $ref_dir . '-' . $ver;
7295                         }
7296                 }
7297                 $ver .= '-' . git_get_short_hash($project, $hash);
7298         }
7299         # special case of sanitization for filename - we change
7300         # slashes to dots instead of dashes
7301         # in case of hierarchical branch names
7302         $ver =~ s!/!.!g;
7303         $ver =~ s/[^[:alnum:]_.-]//g;
7304
7305         # name = project-version_string
7306         $name = "$name-$ver";
7307
7308         return wantarray ? ($name, $name) : $name;
7309 }
7310
7311 sub exit_if_unmodified_since {
7312         my ($latest_epoch) = @_;
7313         our $cgi;
7314
7315         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7316         if (defined $if_modified) {
7317                 my $since;
7318                 if (eval { require HTTP::Date; 1; }) {
7319                         $since = HTTP::Date::str2time($if_modified);
7320                 } elsif (eval { require Time::ParseDate; 1; }) {
7321                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7322                 }
7323                 if (defined $since && $latest_epoch <= $since) {
7324                         my %latest_date = parse_date($latest_epoch);
7325                         print $cgi->header(
7326                                 -last_modified => $latest_date{'rfc2822'},
7327                                 -status => '304 Not Modified');
7328                         goto DONE_GITWEB;
7329                 }
7330         }
7331 }
7332
7333 sub git_snapshot {
7334         my $format = $input_params{'snapshot_format'};
7335         if (!@snapshot_fmts) {
7336                 die_error(403, "Snapshots not allowed");
7337         }
7338         # default to first supported snapshot format
7339         $format ||= $snapshot_fmts[0];
7340         if ($format !~ m/^[a-z0-9]+$/) {
7341                 die_error(400, "Invalid snapshot format parameter");
7342         } elsif (!exists($known_snapshot_formats{$format})) {
7343                 die_error(400, "Unknown snapshot format");
7344         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7345                 die_error(403, "Snapshot format not allowed");
7346         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7347                 die_error(403, "Unsupported snapshot format");
7348         }
7349
7350         my $type = git_get_type("$hash^{}");
7351         if (!$type) {
7352                 die_error(404, 'Object does not exist');
7353         }  elsif ($type eq 'blob') {
7354                 die_error(400, 'Object is not a tree-ish');
7355         }
7356
7357         my ($name, $prefix) = snapshot_name($project, $hash);
7358         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7359
7360         my %co = parse_commit($hash);
7361         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7362
7363         my $cmd = quote_command(
7364                 git_cmd(), 'archive',
7365                 "--format=$known_snapshot_formats{$format}{'format'}",
7366                 "--prefix=$prefix/", $hash);
7367         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7368                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7369         }
7370
7371         $filename =~ s/(["\\])/\\$1/g;
7372         my %latest_date;
7373         if (%co) {
7374                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7375         }
7376
7377         print $cgi->header(
7378                 -type => $known_snapshot_formats{$format}{'type'},
7379                 -content_disposition => 'inline; filename="' . $filename . '"',
7380                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7381                 -status => '200 OK');
7382
7383         open my $fd, "-|", $cmd
7384                 or die_error(500, "Execute git-archive failed");
7385         binmode STDOUT, ':raw';
7386         print <$fd>;
7387         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7388         close $fd;
7389 }
7390
7391 sub git_log_generic {
7392         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7393
7394         my $head = git_get_head_hash($project);
7395         if (!defined $base) {
7396                 $base = $head;
7397         }
7398         if (!defined $page) {
7399                 $page = 0;
7400         }
7401         my $refs = git_get_references();
7402
7403         my $commit_hash = $base;
7404         if (defined $parent) {
7405                 $commit_hash = "$parent..$base";
7406         }
7407         my @commitlist =
7408                 parse_commits($commit_hash, 101, (100 * $page),
7409                               defined $file_name ? ($file_name, "--full-history") : ());
7410
7411         my $ftype;
7412         if (!defined $file_hash && defined $file_name) {
7413                 # some commits could have deleted file in question,
7414                 # and not have it in tree, but one of them has to have it
7415                 for (my $i = 0; $i < @commitlist; $i++) {
7416                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7417                         last if defined $file_hash;
7418                 }
7419         }
7420         if (defined $file_hash) {
7421                 $ftype = git_get_type($file_hash);
7422         }
7423         if (defined $file_name && !defined $ftype) {
7424                 die_error(500, "Unknown type of object");
7425         }
7426         my %co;
7427         if (defined $file_name) {
7428                 %co = parse_commit($base)
7429                         or die_error(404, "Unknown commit object");
7430         }
7431
7432
7433         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7434         my $next_link = '';
7435         if ($#commitlist >= 100) {
7436                 $next_link =
7437                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7438                                  -accesskey => "n", -title => "Alt-n"}, "next");
7439         }
7440         my $patch_max = gitweb_get_feature('patches');
7441         if ($patch_max && !defined $file_name) {
7442                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7443                         $paging_nav .= " &sdot; " .
7444                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7445                                         "patches");
7446                 }
7447         }
7448
7449         git_header_html();
7450         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7451         if (defined $file_name) {
7452                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7453         } else {
7454                 git_print_header_div('summary', $project)
7455         }
7456         git_print_page_path($file_name, $ftype, $hash_base)
7457                 if (defined $file_name);
7458
7459         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7460                      $file_name, $file_hash, $ftype);
7461
7462         git_footer_html();
7463 }
7464
7465 sub git_log {
7466         git_log_generic('log', \&git_log_body,
7467                         $hash, $hash_parent);
7468 }
7469
7470 sub git_commit {
7471         $hash ||= $hash_base || "HEAD";
7472         my %co = parse_commit($hash)
7473             or die_error(404, "Unknown commit object");
7474
7475         my $parent  = $co{'parent'};
7476         my $parents = $co{'parents'}; # listref
7477
7478         # we need to prepare $formats_nav before any parameter munging
7479         my $formats_nav;
7480         if (!defined $parent) {
7481                 # --root commitdiff
7482                 $formats_nav .= '(initial)';
7483         } elsif (@$parents == 1) {
7484                 # single parent commit
7485                 $formats_nav .=
7486                         '(parent: ' .
7487                         $cgi->a({-href => href(action=>"commit",
7488                                                hash=>$parent)},
7489                                 esc_html(substr($parent, 0, 7))) .
7490                         ')';
7491         } else {
7492                 # merge commit
7493                 $formats_nav .=
7494                         '(merge: ' .
7495                         join(' ', map {
7496                                 $cgi->a({-href => href(action=>"commit",
7497                                                        hash=>$_)},
7498                                         esc_html(substr($_, 0, 7)));
7499                         } @$parents ) .
7500                         ')';
7501         }
7502         if (gitweb_check_feature('patches') && @$parents <= 1) {
7503                 $formats_nav .= " | " .
7504                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7505                                 "patch");
7506         }
7507
7508         if (!defined $parent) {
7509                 $parent = "--root";
7510         }
7511         my @difftree;
7512         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7513                 @diff_opts,
7514                 (@$parents <= 1 ? $parent : '-c'),
7515                 $hash, "--"
7516                 or die_error(500, "Open git-diff-tree failed");
7517         @difftree = map { chomp; $_ } <$fd>;
7518         close $fd or die_error(404, "Reading git-diff-tree failed");
7519
7520         # non-textual hash id's can be cached
7521         my $expires;
7522         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7523                 $expires = "+1d";
7524         }
7525         my $refs = git_get_references();
7526         my $ref = format_ref_marker($refs, $co{'id'});
7527
7528         git_header_html(undef, $expires);
7529         git_print_page_nav('commit', '',
7530                            $hash, $co{'tree'}, $hash,
7531                            $formats_nav);
7532
7533         if (defined $co{'parent'}) {
7534                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7535         } else {
7536                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7537         }
7538         print "<div class=\"title_text\">\n" .
7539               "<table class=\"object_header\">\n";
7540         git_print_authorship_rows(\%co);
7541         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7542         print "<tr>" .
7543               "<td>tree</td>" .
7544               "<td class=\"sha1\">" .
7545               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7546                        class => "list"}, $co{'tree'}) .
7547               "</td>" .
7548               "<td class=\"link\">" .
7549               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7550                       "tree");
7551         my $snapshot_links = format_snapshot_links($hash);
7552         if (defined $snapshot_links) {
7553                 print " | " . $snapshot_links;
7554         }
7555         print "</td>" .
7556               "</tr>\n";
7557
7558         foreach my $par (@$parents) {
7559                 print "<tr>" .
7560                       "<td>parent</td>" .
7561                       "<td class=\"sha1\">" .
7562                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7563                                class => "list"}, $par) .
7564                       "</td>" .
7565                       "<td class=\"link\">" .
7566                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7567                       " | " .
7568                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7569                       "</td>" .
7570                       "</tr>\n";
7571         }
7572         print "</table>".
7573               "</div>\n";
7574
7575         print "<div class=\"page_body\">\n";
7576         git_print_log($co{'comment'});
7577         print "</div>\n";
7578
7579         git_difftree_body(\@difftree, $hash, @$parents);
7580
7581         git_footer_html();
7582 }
7583
7584 sub git_object {
7585         # object is defined by:
7586         # - hash or hash_base alone
7587         # - hash_base and file_name
7588         my $type;
7589
7590         # - hash or hash_base alone
7591         if ($hash || ($hash_base && !defined $file_name)) {
7592                 my $object_id = $hash || $hash_base;
7593
7594                 open my $fd, "-|", quote_command(
7595                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7596                         or die_error(404, "Object does not exist");
7597                 $type = <$fd>;
7598                 chomp $type;
7599                 close $fd
7600                         or die_error(404, "Object does not exist");
7601
7602         # - hash_base and file_name
7603         } elsif ($hash_base && defined $file_name) {
7604                 $file_name =~ s,/+$,,;
7605
7606                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7607                         or die_error(404, "Base object does not exist");
7608
7609                 # here errors should not happen
7610                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7611                         or die_error(500, "Open git-ls-tree failed");
7612                 my $line = <$fd>;
7613                 close $fd;
7614
7615                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7616                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7617                         die_error(404, "File or directory for given base does not exist");
7618                 }
7619                 $type = $2;
7620                 $hash = $3;
7621         } else {
7622                 die_error(400, "Not enough information to find object");
7623         }
7624
7625         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7626                                           hash=>$hash, hash_base=>$hash_base,
7627                                           file_name=>$file_name),
7628                              -status => '302 Found');
7629 }
7630
7631 sub git_blobdiff {
7632         my $format = shift || 'html';
7633         my $diff_style = $input_params{'diff_style'} || 'inline';
7634
7635         my $fd;
7636         my @difftree;
7637         my %diffinfo;
7638         my $expires;
7639
7640         # preparing $fd and %diffinfo for git_patchset_body
7641         # new style URI
7642         if (defined $hash_base && defined $hash_parent_base) {
7643                 if (defined $file_name) {
7644                         # read raw output
7645                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7646                                 $hash_parent_base, $hash_base,
7647                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7648                                 or die_error(500, "Open git-diff-tree failed");
7649                         @difftree = map { chomp; $_ } <$fd>;
7650                         close $fd
7651                                 or die_error(404, "Reading git-diff-tree failed");
7652                         @difftree
7653                                 or die_error(404, "Blob diff not found");
7654
7655                 } elsif (defined $hash &&
7656                          $hash =~ /[0-9a-fA-F]{40}/) {
7657                         # try to find filename from $hash
7658
7659                         # read filtered raw output
7660                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7661                                 $hash_parent_base, $hash_base, "--"
7662                                 or die_error(500, "Open git-diff-tree failed");
7663                         @difftree =
7664                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7665                                 # $hash == to_id
7666                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7667                                 map { chomp; $_ } <$fd>;
7668                         close $fd
7669                                 or die_error(404, "Reading git-diff-tree failed");
7670                         @difftree
7671                                 or die_error(404, "Blob diff not found");
7672
7673                 } else {
7674                         die_error(400, "Missing one of the blob diff parameters");
7675                 }
7676
7677                 if (@difftree > 1) {
7678                         die_error(400, "Ambiguous blob diff specification");
7679                 }
7680
7681                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7682                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7683                 $file_name   ||= $diffinfo{'to_file'};
7684
7685                 $hash_parent ||= $diffinfo{'from_id'};
7686                 $hash        ||= $diffinfo{'to_id'};
7687
7688                 # non-textual hash id's can be cached
7689                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7690                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7691                         $expires = '+1d';
7692                 }
7693
7694                 # open patch output
7695                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7696                         '-p', ($format eq 'html' ? "--full-index" : ()),
7697                         $hash_parent_base, $hash_base,
7698                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7699                         or die_error(500, "Open git-diff-tree failed");
7700         }
7701
7702         # old/legacy style URI -- not generated anymore since 1.4.3.
7703         if (!%diffinfo) {
7704                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7705         }
7706
7707         # header
7708         if ($format eq 'html') {
7709                 my $formats_nav =
7710                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7711                                 "raw");
7712                 $formats_nav .= diff_style_nav($diff_style);
7713                 git_header_html(undef, $expires);
7714                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7715                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7716                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7717                 } else {
7718                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7719                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7720                 }
7721                 if (defined $file_name) {
7722                         git_print_page_path($file_name, "blob", $hash_base);
7723                 } else {
7724                         print "<div class=\"page_path\"></div>\n";
7725                 }
7726
7727         } elsif ($format eq 'plain') {
7728                 print $cgi->header(
7729                         -type => 'text/plain',
7730                         -charset => 'utf-8',
7731                         -expires => $expires,
7732                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7733
7734                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7735
7736         } else {
7737                 die_error(400, "Unknown blobdiff format");
7738         }
7739
7740         # patch
7741         if ($format eq 'html') {
7742                 print "<div class=\"page_body\">\n";
7743
7744                 git_patchset_body($fd, $diff_style,
7745                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7746                 close $fd;
7747
7748                 print "</div>\n"; # class="page_body"
7749                 git_footer_html();
7750
7751         } else {
7752                 while (my $line = <$fd>) {
7753                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7754                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7755
7756                         print $line;
7757
7758                         last if $line =~ m!^\+\+\+!;
7759                 }
7760                 local $/ = undef;
7761                 print <$fd>;
7762                 close $fd;
7763         }
7764 }
7765
7766 sub git_blobdiff_plain {
7767         git_blobdiff('plain');
7768 }
7769
7770 # assumes that it is added as later part of already existing navigation,
7771 # so it returns "| foo | bar" rather than just "foo | bar"
7772 sub diff_style_nav {
7773         my ($diff_style, $is_combined) = @_;
7774         $diff_style ||= 'inline';
7775
7776         return "" if ($is_combined);
7777
7778         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7779         my %styles = @styles;
7780         @styles =
7781                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7782
7783         return join '',
7784                 map { " | ".$_ }
7785                 map {
7786                         $_ eq $diff_style ? $styles{$_} :
7787                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7788                 } @styles;
7789 }
7790
7791 sub git_commitdiff {
7792         my %params = @_;
7793         my $format = $params{-format} || 'html';
7794         my $diff_style = $input_params{'diff_style'} || 'inline';
7795
7796         my ($patch_max) = gitweb_get_feature('patches');
7797         if ($format eq 'patch') {
7798                 die_error(403, "Patch view not allowed") unless $patch_max;
7799         }
7800
7801         $hash ||= $hash_base || "HEAD";
7802         my %co = parse_commit($hash)
7803             or die_error(404, "Unknown commit object");
7804
7805         # choose format for commitdiff for merge
7806         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7807                 $hash_parent = '--cc';
7808         }
7809         # we need to prepare $formats_nav before almost any parameter munging
7810         my $formats_nav;
7811         if ($format eq 'html') {
7812                 $formats_nav =
7813                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7814                                 "raw");
7815                 if ($patch_max && @{$co{'parents'}} <= 1) {
7816                         $formats_nav .= " | " .
7817                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7818                                         "patch");
7819                 }
7820                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7821
7822                 if (defined $hash_parent &&
7823                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7824                         # commitdiff with two commits given
7825                         my $hash_parent_short = $hash_parent;
7826                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7827                                 $hash_parent_short = substr($hash_parent, 0, 7);
7828                         }
7829                         $formats_nav .=
7830                                 ' (from';
7831                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7832                                 if ($co{'parents'}[$i] eq $hash_parent) {
7833                                         $formats_nav .= ' parent ' . ($i+1);
7834                                         last;
7835                                 }
7836                         }
7837                         $formats_nav .= ': ' .
7838                                 $cgi->a({-href => href(-replay=>1,
7839                                                        hash=>$hash_parent, hash_base=>undef)},
7840                                         esc_html($hash_parent_short)) .
7841                                 ')';
7842                 } elsif (!$co{'parent'}) {
7843                         # --root commitdiff
7844                         $formats_nav .= ' (initial)';
7845                 } elsif (scalar @{$co{'parents'}} == 1) {
7846                         # single parent commit
7847                         $formats_nav .=
7848                                 ' (parent: ' .
7849                                 $cgi->a({-href => href(-replay=>1,
7850                                                        hash=>$co{'parent'}, hash_base=>undef)},
7851                                         esc_html(substr($co{'parent'}, 0, 7))) .
7852                                 ')';
7853                 } else {
7854                         # merge commit
7855                         if ($hash_parent eq '--cc') {
7856                                 $formats_nav .= ' | ' .
7857                                         $cgi->a({-href => href(-replay=>1,
7858                                                                hash=>$hash, hash_parent=>'-c')},
7859                                                 'combined');
7860                         } else { # $hash_parent eq '-c'
7861                                 $formats_nav .= ' | ' .
7862                                         $cgi->a({-href => href(-replay=>1,
7863                                                                hash=>$hash, hash_parent=>'--cc')},
7864                                                 'compact');
7865                         }
7866                         $formats_nav .=
7867                                 ' (merge: ' .
7868                                 join(' ', map {
7869                                         $cgi->a({-href => href(-replay=>1,
7870                                                                hash=>$_, hash_base=>undef)},
7871                                                 esc_html(substr($_, 0, 7)));
7872                                 } @{$co{'parents'}} ) .
7873                                 ')';
7874                 }
7875         }
7876
7877         my $hash_parent_param = $hash_parent;
7878         if (!defined $hash_parent_param) {
7879                 # --cc for multiple parents, --root for parentless
7880                 $hash_parent_param =
7881                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7882         }
7883
7884         # read commitdiff
7885         my $fd;
7886         my @difftree;
7887         if ($format eq 'html') {
7888                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7889                         "--no-commit-id", "--patch-with-raw", "--full-index",
7890                         $hash_parent_param, $hash, "--"
7891                         or die_error(500, "Open git-diff-tree failed");
7892
7893                 while (my $line = <$fd>) {
7894                         chomp $line;
7895                         # empty line ends raw part of diff-tree output
7896                         last unless $line;
7897                         push @difftree, scalar parse_difftree_raw_line($line);
7898                 }
7899
7900         } elsif ($format eq 'plain') {
7901                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7902                         '-p', $hash_parent_param, $hash, "--"
7903                         or die_error(500, "Open git-diff-tree failed");
7904         } elsif ($format eq 'patch') {
7905                 # For commit ranges, we limit the output to the number of
7906                 # patches specified in the 'patches' feature.
7907                 # For single commits, we limit the output to a single patch,
7908                 # diverging from the git-format-patch default.
7909                 my @commit_spec = ();
7910                 if ($hash_parent) {
7911                         if ($patch_max > 0) {
7912                                 push @commit_spec, "-$patch_max";
7913                         }
7914                         push @commit_spec, '-n', "$hash_parent..$hash";
7915                 } else {
7916                         if ($params{-single}) {
7917                                 push @commit_spec, '-1';
7918                         } else {
7919                                 if ($patch_max > 0) {
7920                                         push @commit_spec, "-$patch_max";
7921                                 }
7922                                 push @commit_spec, "-n";
7923                         }
7924                         push @commit_spec, '--root', $hash;
7925                 }
7926                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7927                         '--encoding=utf8', '--stdout', @commit_spec
7928                         or die_error(500, "Open git-format-patch failed");
7929         } else {
7930                 die_error(400, "Unknown commitdiff format");
7931         }
7932
7933         # non-textual hash id's can be cached
7934         my $expires;
7935         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7936                 $expires = "+1d";
7937         }
7938
7939         # write commit message
7940         if ($format eq 'html') {
7941                 my $refs = git_get_references();
7942                 my $ref = format_ref_marker($refs, $co{'id'});
7943
7944                 git_header_html(undef, $expires);
7945                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7946                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7947                 print "<div class=\"title_text\">\n" .
7948                       "<table class=\"object_header\">\n";
7949                 git_print_authorship_rows(\%co);
7950                 print "</table>".
7951                       "</div>\n";
7952                 print "<div class=\"page_body\">\n";
7953                 if (@{$co{'comment'}} > 1) {
7954                         print "<div class=\"log\">\n";
7955                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7956                         print "</div>\n"; # class="log"
7957                 }
7958
7959         } elsif ($format eq 'plain') {
7960                 my $refs = git_get_references("tags");
7961                 my $tagname = git_get_rev_name_tags($hash);
7962                 my $filename = basename($project) . "-$hash.patch";
7963
7964                 print $cgi->header(
7965                         -type => 'text/plain',
7966                         -charset => 'utf-8',
7967                         -expires => $expires,
7968                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7969                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7970                 print "From: " . to_utf8($co{'author'}) . "\n";
7971                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7972                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7973
7974                 print "X-Git-Tag: $tagname\n" if $tagname;
7975                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7976
7977                 foreach my $line (@{$co{'comment'}}) {
7978                         print to_utf8($line) . "\n";
7979                 }
7980                 print "---\n\n";
7981         } elsif ($format eq 'patch') {
7982                 my $filename = basename($project) . "-$hash.patch";
7983
7984                 print $cgi->header(
7985                         -type => 'text/plain',
7986                         -charset => 'utf-8',
7987                         -expires => $expires,
7988                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7989         }
7990
7991         # write patch
7992         if ($format eq 'html') {
7993                 my $use_parents = !defined $hash_parent ||
7994                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7995                 git_difftree_body(\@difftree, $hash,
7996                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7997                 print "<br/>\n";
7998
7999                 git_patchset_body($fd, $diff_style,
8000                                   \@difftree, $hash,
8001                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8002                 close $fd;
8003                 print "</div>\n"; # class="page_body"
8004                 git_footer_html();
8005
8006         } elsif ($format eq 'plain') {
8007                 local $/ = undef;
8008                 print <$fd>;
8009                 close $fd
8010                         or print "Reading git-diff-tree failed\n";
8011         } elsif ($format eq 'patch') {
8012                 local $/ = undef;
8013                 print <$fd>;
8014                 close $fd
8015                         or print "Reading git-format-patch failed\n";
8016         }
8017 }
8018
8019 sub git_commitdiff_plain {
8020         git_commitdiff(-format => 'plain');
8021 }
8022
8023 # format-patch-style patches
8024 sub git_patch {
8025         git_commitdiff(-format => 'patch', -single => 1);
8026 }
8027
8028 sub git_patches {
8029         git_commitdiff(-format => 'patch');
8030 }
8031
8032 sub git_history {
8033         git_log_generic('history', \&git_history_body,
8034                         $hash_base, $hash_parent_base,
8035                         $file_name, $hash);
8036 }
8037
8038 sub git_search {
8039         $searchtype ||= 'commit';
8040
8041         # check if appropriate features are enabled
8042         gitweb_check_feature('search')
8043                 or die_error(403, "Search is disabled");
8044         if ($searchtype eq 'pickaxe') {
8045                 # pickaxe may take all resources of your box and run for several minutes
8046                 # with every query - so decide by yourself how public you make this feature
8047                 gitweb_check_feature('pickaxe')
8048                         or die_error(403, "Pickaxe search is disabled");
8049         }
8050         if ($searchtype eq 'grep') {
8051                 # grep search might be potentially CPU-intensive, too
8052                 gitweb_check_feature('grep')
8053                         or die_error(403, "Grep search is disabled");
8054         }
8055
8056         if (!defined $searchtext) {
8057                 die_error(400, "Text field is empty");
8058         }
8059         if (!defined $hash) {
8060                 $hash = git_get_head_hash($project);
8061         }
8062         my %co = parse_commit($hash);
8063         if (!%co) {
8064                 die_error(404, "Unknown commit object");
8065         }
8066         if (!defined $page) {
8067                 $page = 0;
8068         }
8069
8070         if ($searchtype eq 'commit' ||
8071             $searchtype eq 'author' ||
8072             $searchtype eq 'committer') {
8073                 git_search_message(%co);
8074         } elsif ($searchtype eq 'pickaxe') {
8075                 git_search_changes(%co);
8076         } elsif ($searchtype eq 'grep') {
8077                 git_search_files(%co);
8078         } else {
8079                 die_error(400, "Unknown search type");
8080         }
8081 }
8082
8083 sub git_search_help {
8084         git_header_html();
8085         git_print_page_nav('','', $hash,$hash,$hash);
8086         print <<EOT;
8087 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
8088 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
8089 the pattern entered is recognized as the POSIX extended
8090 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
8091 insensitive).</p>
8092 <dl>
8093 <dt><b>commit</b></dt>
8094 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
8095 EOT
8096         my $have_grep = gitweb_check_feature('grep');
8097         if ($have_grep) {
8098                 print <<EOT;
8099 <dt><b>grep</b></dt>
8100 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
8101     a different one) are searched for the given pattern. On large trees, this search can take
8102 a while and put some strain on the server, so please use it with some consideration. Note that
8103 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
8104 case-sensitive.</dd>
8105 EOT
8106         }
8107         print <<EOT;
8108 <dt><b>author</b></dt>
8109 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
8110 <dt><b>committer</b></dt>
8111 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
8112 EOT
8113         my $have_pickaxe = gitweb_check_feature('pickaxe');
8114         if ($have_pickaxe) {
8115                 print <<EOT;
8116 <dt><b>pickaxe</b></dt>
8117 <dd>All commits that caused the string to appear or disappear from any file (changes that
8118 added, removed or "modified" the string) will be listed. This search can take a while and
8119 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8120 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8121 EOT
8122         }
8123         print "</dl>\n";
8124         git_footer_html();
8125 }
8126
8127 sub git_shortlog {
8128         git_log_generic('shortlog', \&git_shortlog_body,
8129                         $hash, $hash_parent);
8130 }
8131
8132 ## ......................................................................
8133 ## feeds (RSS, Atom; OPML)
8134
8135 sub git_feed {
8136         my $format = shift || 'atom';
8137         my $have_blame = gitweb_check_feature('blame');
8138
8139         # Atom: http://www.atomenabled.org/developers/syndication/
8140         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8141         if ($format ne 'rss' && $format ne 'atom') {
8142                 die_error(400, "Unknown web feed format");
8143         }
8144
8145         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8146         my $head = $hash || 'HEAD';
8147         my @commitlist = parse_commits($head, 150, 0, $file_name);
8148
8149         my %latest_commit;
8150         my %latest_date;
8151         my $content_type = "application/$format+xml";
8152         if (defined $cgi->http('HTTP_ACCEPT') &&
8153                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8154                 # browser (feed reader) prefers text/xml
8155                 $content_type = 'text/xml';
8156         }
8157         if (defined($commitlist[0])) {
8158                 %latest_commit = %{$commitlist[0]};
8159                 my $latest_epoch = $latest_commit{'committer_epoch'};
8160                 exit_if_unmodified_since($latest_epoch);
8161                 %latest_date = parse_date($latest_epoch, $latest_commit{'committer_tz'});
8162         }
8163         print $cgi->header(
8164                 -type => $content_type,
8165                 -charset => 'utf-8',
8166                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8167                 -status => '200 OK');
8168
8169         # Optimization: skip generating the body if client asks only
8170         # for Last-Modified date.
8171         return if ($cgi->request_method() eq 'HEAD');
8172
8173         # header variables
8174         my $title = "$site_name - $project/$action";
8175         my $feed_type = 'log';
8176         if (defined $hash) {
8177                 $title .= " - '$hash'";
8178                 $feed_type = 'branch log';
8179                 if (defined $file_name) {
8180                         $title .= " :: $file_name";
8181                         $feed_type = 'history';
8182                 }
8183         } elsif (defined $file_name) {
8184                 $title .= " - $file_name";
8185                 $feed_type = 'history';
8186         }
8187         $title .= " $feed_type";
8188         $title = esc_html($title);
8189         my $descr = git_get_project_description($project);
8190         if (defined $descr) {
8191                 $descr = esc_html($descr);
8192         } else {
8193                 $descr = "$project " .
8194                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8195                          " feed";
8196         }
8197         my $owner = git_get_project_owner($project);
8198         $owner = esc_html($owner);
8199
8200         #header
8201         my $alt_url;
8202         if (defined $file_name) {
8203                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8204         } elsif (defined $hash) {
8205                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8206         } else {
8207                 $alt_url = href(-full=>1, action=>"summary");
8208         }
8209         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8210         if ($format eq 'rss') {
8211                 print <<XML;
8212 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8213 <channel>
8214 XML
8215                 print "<title>$title</title>\n" .
8216                       "<link>$alt_url</link>\n" .
8217                       "<description>$descr</description>\n" .
8218                       "<language>en</language>\n" .
8219                       # project owner is responsible for 'editorial' content
8220                       "<managingEditor>$owner</managingEditor>\n";
8221                 if (defined $logo || defined $favicon) {
8222                         # prefer the logo to the favicon, since RSS
8223                         # doesn't allow both
8224                         my $img = esc_url($logo || $favicon);
8225                         print "<image>\n" .
8226                               "<url>$img</url>\n" .
8227                               "<title>$title</title>\n" .
8228                               "<link>$alt_url</link>\n" .
8229                               "</image>\n";
8230                 }
8231                 if (%latest_date) {
8232                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8233                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8234                 }
8235                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8236         } elsif ($format eq 'atom') {
8237                 print <<XML;
8238 <feed xmlns="http://www.w3.org/2005/Atom">
8239 XML
8240                 print "<title>$title</title>\n" .
8241                       "<subtitle>$descr</subtitle>\n" .
8242                       '<link rel="alternate" type="text/html" href="' .
8243                       $alt_url . '" />' . "\n" .
8244                       '<link rel="self" type="' . $content_type . '" href="' .
8245                       $cgi->self_url() . '" />' . "\n" .
8246                       "<id>" . href(-full=>1) . "</id>\n" .
8247                       # use project owner for feed author
8248                       "<author><name>$owner</name></author>\n";
8249                 if (defined $favicon) {
8250                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8251                 }
8252                 if (defined $logo) {
8253                         # not twice as wide as tall: 72 x 27 pixels
8254                         print "<logo>" . esc_url($logo) . "</logo>\n";
8255                 }
8256                 if (! %latest_date) {
8257                         # dummy date to keep the feed valid until commits trickle in:
8258                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8259                 } else {
8260                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8261                 }
8262                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8263         }
8264
8265         # contents
8266         for (my $i = 0; $i <= $#commitlist; $i++) {
8267                 my %co = %{$commitlist[$i]};
8268                 my $commit = $co{'id'};
8269                 # we read 150, we always show 30 and the ones more recent than 48 hours
8270                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8271                         last;
8272                 }
8273                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8274
8275                 # get list of changed files
8276                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8277                         $co{'parent'} || "--root",
8278                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8279                         or next;
8280                 my @difftree = map { chomp; $_ } <$fd>;
8281                 close $fd
8282                         or next;
8283
8284                 # print element (entry, item)
8285                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8286                 if ($format eq 'rss') {
8287                         print "<item>\n" .
8288                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8289                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8290                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8291                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8292                               "<link>$co_url</link>\n" .
8293                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8294                               "<content:encoded>" .
8295                               "<![CDATA[\n";
8296                 } elsif ($format eq 'atom') {
8297                         print "<entry>\n" .
8298                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8299                               "<updated>$cd{'iso-8601'}</updated>\n" .
8300                               "<author>\n" .
8301                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8302                         if ($co{'author_email'}) {
8303                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8304                         }
8305                         print "</author>\n" .
8306                               # use committer for contributor
8307                               "<contributor>\n" .
8308                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8309                         if ($co{'committer_email'}) {
8310                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8311                         }
8312                         print "</contributor>\n" .
8313                               "<published>$cd{'iso-8601'}</published>\n" .
8314                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8315                               "<id>$co_url</id>\n" .
8316                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8317                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8318                 }
8319                 my $comment = $co{'comment'};
8320                 print "<pre>\n";
8321                 foreach my $line (@$comment) {
8322                         $line = esc_html($line);
8323                         print "$line\n";
8324                 }
8325                 print "</pre><ul>\n";
8326                 foreach my $difftree_line (@difftree) {
8327                         my %difftree = parse_difftree_raw_line($difftree_line);
8328                         next if !$difftree{'from_id'};
8329
8330                         my $file = $difftree{'file'} || $difftree{'to_file'};
8331
8332                         print "<li>" .
8333                               "[" .
8334                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8335                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8336                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8337                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8338                                       -title => "diff"}, 'D');
8339                         if ($have_blame) {
8340                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8341                                                              file_name=>$file, hash_base=>$commit),
8342                                               -title => "blame"}, 'B');
8343                         }
8344                         # if this is not a feed of a file history
8345                         if (!defined $file_name || $file_name ne $file) {
8346                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8347                                                              file_name=>$file, hash=>$commit),
8348                                               -title => "history"}, 'H');
8349                         }
8350                         $file = esc_path($file);
8351                         print "] ".
8352                               "$file</li>\n";
8353                 }
8354                 if ($format eq 'rss') {
8355                         print "</ul>]]>\n" .
8356                               "</content:encoded>\n" .
8357                               "</item>\n";
8358                 } elsif ($format eq 'atom') {
8359                         print "</ul>\n</div>\n" .
8360                               "</content>\n" .
8361                               "</entry>\n";
8362                 }
8363         }
8364
8365         # end of feed
8366         if ($format eq 'rss') {
8367                 print "</channel>\n</rss>\n";
8368         } elsif ($format eq 'atom') {
8369                 print "</feed>\n";
8370         }
8371 }
8372
8373 sub git_rss {
8374         git_feed('rss');
8375 }
8376
8377 sub git_atom {
8378         git_feed('atom');
8379 }
8380
8381 sub git_opml {
8382         my @list = git_get_projects_list($project_filter, $strict_export);
8383         if (!@list) {
8384                 die_error(404, "No projects found");
8385         }
8386
8387         print $cgi->header(
8388                 -type => 'text/xml',
8389                 -charset => 'utf-8',
8390                 -content_disposition => 'inline; filename="opml.xml"');
8391
8392         my $title = esc_html($site_name);
8393         my $filter = " within subdirectory ";
8394         if (defined $project_filter) {
8395                 $filter .= esc_html($project_filter);
8396         } else {
8397                 $filter = "";
8398         }
8399         print <<XML;
8400 <?xml version="1.0" encoding="utf-8"?>
8401 <opml version="1.0">
8402 <head>
8403   <title>$title OPML Export$filter</title>
8404 </head>
8405 <body>
8406 <outline text="git RSS feeds">
8407 XML
8408
8409         foreach my $pr (@list) {
8410                 my %proj = %$pr;
8411                 my $head = git_get_head_hash($proj{'path'});
8412                 if (!defined $head) {
8413                         next;
8414                 }
8415                 $git_dir = "$projectroot/$proj{'path'}";
8416                 my %co = parse_commit($head);
8417                 if (!%co) {
8418                         next;
8419                 }
8420
8421                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8422                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8423                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8424                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8425         }
8426         print <<XML;
8427 </outline>
8428 </body>
8429 </opml>
8430 XML
8431 }