git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  exec wish "$0" -- "$@"
  10
  11 set appvers {@@GITGUI_VERSION@@}
  12 set copyright {
  13 Copyright © 2006, 2007 Shawn Pearce, et. al.
  14
  15 This program is free software; you can redistribute it and/or modify
  16 it under the terms of the GNU General Public License as published by
  17 the Free Software Foundation; either version 2 of the License, or
  18 (at your option) any later version.
  19
  20 This program is distributed in the hope that it will be useful,
  21 but WITHOUT ANY WARRANTY; without even the implied warranty of
  22 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  23 GNU General Public License for more details.
  24
  25 You should have received a copy of the GNU General Public License
  26 along with this program; if not, write to the Free Software
  27 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}
  28
  29 ######################################################################
  30 ##
  31 ## Tcl/Tk sanity check
  32
  33 if {[catch {package require Tcl 8.4} err]
  34  || [catch {package require Tk  8.4} err]
  35 } {
  36         catch {wm withdraw .}
  37         tk_messageBox \
  38                 -icon error \
  39                 -type ok \
  40                 -title "git-gui: fatal error" \
  41                 -message $err
  42         exit 1
  43 }
  44
  45 ######################################################################
  46 ##
  47 ## enable verbose loading?
  48
  49 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  50         unset _verbose
  51         rename auto_load real__auto_load
  52         proc auto_load {name args} {
  53                 puts stderr "auto_load $name"
  54                 return [uplevel 1 real__auto_load $name $args]
  55         }
  56         rename source real__source
  57         proc source {name} {
  58                 puts stderr "source    $name"
  59                 uplevel 1 real__source $name
  60         }
  61 }
  62
  63 ######################################################################
  64 ##
  65 ## configure our library
  66
  67 set oguilib {@@GITGUI_LIBDIR@@}
  68 set oguirel {@@GITGUI_RELATIVE@@}
  69 if {$oguirel eq {1}} {
  70         set oguilib [file dirname [file dirname [file normalize $argv0]]]
  71         set oguilib [file join $oguilib share git-gui lib]
  72 } elseif {[string match @@* $oguirel]} {
  73         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  74 }
  75
  76 set idx [file join $oguilib tclIndex]
  77 if {[catch {set fd [open $idx r]} err]} {
  78         catch {wm withdraw .}
  79         tk_messageBox \
  80                 -icon error \
  81                 -type ok \
  82                 -title "git-gui: fatal error" \
  83                 -message $err
  84         exit 1
  85 }
  86 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
  87         set idx [list]
  88         while {[gets $fd n] >= 0} {
  89                 if {$n ne {} && ![string match #* $n]} {
  90                         lappend idx $n
  91                 }
  92         }
  93 } else {
  94         set idx {}
  95 }
  96 close $fd
  97
  98 if {$idx ne {}} {
  99         set loaded [list]
 100         foreach p $idx {
 101                 if {[lsearch -exact $loaded $p] >= 0} continue
 102                 source [file join $oguilib $p]
 103                 lappend loaded $p
 104         }
 105         unset loaded p
 106 } else {
 107         set auto_path [concat [list $oguilib] $auto_path]
 108 }
 109 unset -nocomplain oguirel idx fd
 110
 111 ######################################################################
 112 ##
 113 ## read only globals
 114
 115 set _appname [lindex [file split $argv0] end]
 116 set _gitdir {}
 117 set _gitexec {}
 118 set _reponame {}
 119 set _iscygwin {}
 120
 121 proc appname {} {
 122         global _appname
 123         return $_appname
 124 }
 125
 126 proc gitdir {args} {
 127         global _gitdir
 128         if {$args eq {}} {
 129                 return $_gitdir
 130         }
 131         return [eval [concat [list file join $_gitdir] $args]]
 132 }
 133
 134 proc gitexec {args} {
 135         global _gitexec
 136         if {$_gitexec eq {}} {
 137                 if {[catch {set _gitexec [git --exec-path]} err]} {
 138                         error "Git not installed?\n\n$err"
 139                 }
 140         }
 141         if {$args eq {}} {
 142                 return $_gitexec
 143         }
 144         return [eval [concat [list file join $_gitexec] $args]]
 145 }
 146
 147 proc reponame {} {
 148         global _reponame
 149         return $_reponame
 150 }
 151
 152 proc is_MacOSX {} {
 153         global tcl_platform tk_library
 154         if {[tk windowingsystem] eq {aqua}} {
 155                 return 1
 156         }
 157         return 0
 158 }
 159
 160 proc is_Windows {} {
 161         global tcl_platform
 162         if {$tcl_platform(platform) eq {windows}} {
 163                 return 1
 164         }
 165         return 0
 166 }
 167
 168 proc is_Cygwin {} {
 169         global tcl_platform _iscygwin
 170         if {$_iscygwin eq {}} {
 171                 if {$tcl_platform(platform) eq {windows}} {
 172                         if {[catch {set p [exec cygpath --windir]} err]} {
 173                                 set _iscygwin 0
 174                         } else {
 175                                 set _iscygwin 1
 176                         }
 177                 } else {
 178                         set _iscygwin 0
 179                 }
 180         }
 181         return $_iscygwin
 182 }
 183
 184 proc is_enabled {option} {
 185         global enabled_options
 186         if {[catch {set on $enabled_options($option)}]} {return 0}
 187         return $on
 188 }
 189
 190 proc enable_option {option} {
 191         global enabled_options
 192         set enabled_options($option) 1
 193 }
 194
 195 proc disable_option {option} {
 196         global enabled_options
 197         set enabled_options($option) 0
 198 }
 199
 200 ######################################################################
 201 ##
 202 ## config
 203
 204 proc is_many_config {name} {
 205         switch -glob -- $name {
 206         remote.*.fetch -
 207         remote.*.push
 208                 {return 1}
 209         *
 210                 {return 0}
 211         }
 212 }
 213
 214 proc is_config_true {name} {
 215         global repo_config
 216         if {[catch {set v $repo_config($name)}]} {
 217                 return 0
 218         } elseif {$v eq {true} || $v eq {1} || $v eq {yes}} {
 219                 return 1
 220         } else {
 221                 return 0
 222         }
 223 }
 224
 225 proc get_config {name} {
 226         global repo_config
 227         if {[catch {set v $repo_config($name)}]} {
 228                 return {}
 229         } else {
 230                 return $v
 231         }
 232 }
 233
 234 proc load_config {include_global} {
 235         global repo_config global_config default_config
 236
 237         array unset global_config
 238         if {$include_global} {
 239                 catch {
 240                         set fd_rc [open "| git config --global --list" r]
 241                         while {[gets $fd_rc line] >= 0} {
 242                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 243                                         if {[is_many_config $name]} {
 244                                                 lappend global_config($name) $value
 245                                         } else {
 246                                                 set global_config($name) $value
 247                                         }
 248                                 }
 249                         }
 250                         close $fd_rc
 251                 }
 252         }
 253
 254         array unset repo_config
 255         catch {
 256                 set fd_rc [open "| git config --list" r]
 257                 while {[gets $fd_rc line] >= 0} {
 258                         if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
 259                                 if {[is_many_config $name]} {
 260                                         lappend repo_config($name) $value
 261                                 } else {
 262                                         set repo_config($name) $value
 263                                 }
 264                         }
 265                 }
 266                 close $fd_rc
 267         }
 268
 269         foreach name [array names default_config] {
 270                 if {[catch {set v $global_config($name)}]} {
 271                         set global_config($name) $default_config($name)
 272                 }
 273                 if {[catch {set v $repo_config($name)}]} {
 274                         set repo_config($name) $default_config($name)
 275                 }
 276         }
 277 }
 278
 279 ######################################################################
 280 ##
 281 ## handy utils
 282
 283 proc git {args} {
 284         return [eval exec git $args]
 285 }
 286
 287 proc load_current_branch {} {
 288         global current_branch is_detached
 289
 290         set fd [open [gitdir HEAD] r]
 291         if {[gets $fd ref] < 1} {
 292                 set ref {}
 293         }
 294         close $fd
 295
 296         set pfx {ref: refs/heads/}
 297         set len [string length $pfx]
 298         if {[string equal -length $len $pfx $ref]} {
 299                 # We're on a branch.  It might not exist.  But
 300                 # HEAD looks good enough to be a branch.
 301                 #
 302                 set current_branch [string range $ref $len end]
 303                 set is_detached 0
 304         } else {
 305                 # Assume this is a detached head.
 306                 #
 307                 set current_branch HEAD
 308                 set is_detached 1
 309         }
 310 }
 311
 312 auto_load tk_optionMenu
 313 rename tk_optionMenu real__tkOptionMenu
 314 proc tk_optionMenu {w varName args} {
 315         set m [eval real__tkOptionMenu $w $varName $args]
 316         $m configure -font font_ui
 317         $w configure -font font_ui
 318         return $m
 319 }
 320
 321 ######################################################################
 322 ##
 323 ## version check
 324
 325 if {[catch {set _git_version [git --version]} err]} {
 326         catch {wm withdraw .}
 327         error_popup "Cannot determine Git version:
 328
 329 $err
 330
 331 [appname] requires Git 1.5.0 or later."
 332         exit 1
 333 }
 334 if {![regsub {^git version } $_git_version {} _git_version]} {
 335         catch {wm withdraw .}
 336         error_popup "Cannot parse Git version string:\n\n$_git_version"
 337         exit 1
 338 }
 339 regsub {\.[0-9]+\.g[0-9a-f]+$} $_git_version {} _git_version
 340 regsub {\.rc[0-9]+$} $_git_version {} _git_version
 341
 342 proc git-version {args} {
 343         global _git_version
 344
 345         switch [llength $args] {
 346         0 {
 347                 return $_git_version
 348         }
 349
 350         2 {
 351                 set op [lindex $args 0]
 352                 set vr [lindex $args 1]
 353                 set cm [package vcompare $_git_version $vr]
 354                 return [expr $cm $op 0]
 355         }
 356
 357         4 {
 358                 set type [lindex $args 0]
 359                 set name [lindex $args 1]
 360                 set parm [lindex $args 2]
 361                 set body [lindex $args 3]
 362
 363                 if {($type ne {proc} && $type ne {method})} {
 364                         error "Invalid arguments to git-version"
 365                 }
 366                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
 367                         error "Last arm of $type $name must be default"
 368                 }
 369
 370                 foreach {op vr cb} [lrange $body 0 end-2] {
 371                         if {[git-version $op $vr]} {
 372                                 return [uplevel [list $type $name $parm $cb]]
 373                         }
 374                 }
 375
 376                 return [uplevel [list $type $name $parm [lindex $body end]]]
 377         }
 378
 379         default {
 380                 error "git-version >= x"
 381         }
 382
 383         }
 384 }
 385
 386 if {[git-version < 1.5]} {
 387         catch {wm withdraw .}
 388         error_popup "[appname] requires Git 1.5.0 or later.
 389
 390 You are using [git-version]:
 391
 392 [git --version]"
 393         exit 1
 394 }
 395
 396 ######################################################################
 397 ##
 398 ## repository setup
 399
 400 if {[catch {
 401                 set _gitdir $env(GIT_DIR)
 402                 set _prefix {}
 403                 }]
 404         && [catch {
 405                 set _gitdir [git rev-parse --git-dir]
 406                 set _prefix [git rev-parse --show-prefix]
 407         } err]} {
 408         catch {wm withdraw .}
 409         error_popup "Cannot find the git directory:\n\n$err"
 410         exit 1
 411 }
 412 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
 413         catch {set _gitdir [exec cygpath --unix $_gitdir]}
 414 }
 415 if {![file isdirectory $_gitdir]} {
 416         catch {wm withdraw .}
 417         error_popup "Git directory not found:\n\n$_gitdir"
 418         exit 1
 419 }
 420 if {[lindex [file split $_gitdir] end] ne {.git}} {
 421         catch {wm withdraw .}
 422         error_popup "Cannot use funny .git directory:\n\n$_gitdir"
 423         exit 1
 424 }
 425 if {[catch {cd [file dirname $_gitdir]} err]} {
 426         catch {wm withdraw .}
 427         error_popup "No working directory [file dirname $_gitdir]:\n\n$err"
 428         exit 1
 429 }
 430 set _reponame [lindex [file split \
 431         [file normalize [file dirname $_gitdir]]] \
 432         end]
 433
 434 ######################################################################
 435 ##
 436 ## global init
 437
 438 set current_diff_path {}
 439 set current_diff_side {}
 440 set diff_actions [list]
 441 set ui_status_value {Initializing...}
 442
 443 set HEAD {}
 444 set PARENT {}
 445 set MERGE_HEAD [list]
 446 set commit_type {}
 447 set empty_tree {}
 448 set current_branch {}
 449 set is_detached 0
 450 set current_diff_path {}
 451 set selected_commit_type new
 452
 453 ######################################################################
 454 ##
 455 ## task management
 456
 457 set rescan_active 0
 458 set diff_active 0
 459 set last_clicked {}
 460
 461 set disable_on_lock [list]
 462 set index_lock_type none
 463
 464 proc lock_index {type} {
 465         global index_lock_type disable_on_lock
 466
 467         if {$index_lock_type eq {none}} {
 468                 set index_lock_type $type
 469                 foreach w $disable_on_lock {
 470                         uplevel #0 $w disabled
 471                 }
 472                 return 1
 473         } elseif {$index_lock_type eq "begin-$type"} {
 474                 set index_lock_type $type
 475                 return 1
 476         }
 477         return 0
 478 }
 479
 480 proc unlock_index {} {
 481         global index_lock_type disable_on_lock
 482
 483         set index_lock_type none
 484         foreach w $disable_on_lock {
 485                 uplevel #0 $w normal
 486         }
 487 }
 488
 489 ######################################################################
 490 ##
 491 ## status
 492
 493 proc repository_state {ctvar hdvar mhvar} {
 494         global current_branch
 495         upvar $ctvar ct $hdvar hd $mhvar mh
 496
 497         set mh [list]
 498
 499         load_current_branch
 500         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
 501                 set hd {}
 502                 set ct initial
 503                 return
 504         }
 505
 506         set merge_head [gitdir MERGE_HEAD]
 507         if {[file exists $merge_head]} {
 508                 set ct merge
 509                 set fd_mh [open $merge_head r]
 510                 while {[gets $fd_mh line] >= 0} {
 511                         lappend mh $line
 512                 }
 513                 close $fd_mh
 514                 return
 515         }
 516
 517         set ct normal
 518 }
 519
 520 proc PARENT {} {
 521         global PARENT empty_tree
 522
 523         set p [lindex $PARENT 0]
 524         if {$p ne {}} {
 525                 return $p
 526         }
 527         if {$empty_tree eq {}} {
 528                 set empty_tree [git mktree << {}]
 529         }
 530         return $empty_tree
 531 }
 532
 533 proc rescan {after {honor_trustmtime 1}} {
 534         global HEAD PARENT MERGE_HEAD commit_type
 535         global ui_index ui_workdir ui_comm
 536         global rescan_active file_states
 537         global repo_config
 538
 539         if {$rescan_active > 0 || ![lock_index read]} return
 540
 541         repository_state newType newHEAD newMERGE_HEAD
 542         if {[string match amend* $commit_type]
 543                 && $newType eq {normal}
 544                 && $newHEAD eq $HEAD} {
 545         } else {
 546                 set HEAD $newHEAD
 547                 set PARENT $newHEAD
 548                 set MERGE_HEAD $newMERGE_HEAD
 549                 set commit_type $newType
 550         }
 551
 552         array unset file_states
 553
 554         if {![$ui_comm edit modified]
 555                 || [string trim [$ui_comm get 0.0 end]] eq {}} {
 556                 if {[string match amend* $commit_type]} {
 557                 } elseif {[load_message GITGUI_MSG]} {
 558                 } elseif {[load_message MERGE_MSG]} {
 559                 } elseif {[load_message SQUASH_MSG]} {
 560                 }
 561                 $ui_comm edit reset
 562                 $ui_comm edit modified false
 563         }
 564
 565         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
 566                 rescan_stage2 {} $after
 567         } else {
 568                 set rescan_active 1
 569                 ui_status {Refreshing file status...}
 570                 set cmd [list git update-index]
 571                 lappend cmd -q
 572                 lappend cmd --unmerged
 573                 lappend cmd --ignore-missing
 574                 lappend cmd --refresh
 575                 set fd_rf [open "| $cmd" r]
 576                 fconfigure $fd_rf -blocking 0 -translation binary
 577                 fileevent $fd_rf readable \
 578                         [list rescan_stage2 $fd_rf $after]
 579         }
 580 }
 581
 582 proc rescan_stage2 {fd after} {
 583         global rescan_active buf_rdi buf_rdf buf_rlo
 584
 585         if {$fd ne {}} {
 586                 read $fd
 587                 if {![eof $fd]} return
 588                 close $fd
 589         }
 590
 591         set ls_others [list | git ls-files --others -z \
 592                 --exclude-per-directory=.gitignore]
 593         set info_exclude [gitdir info exclude]
 594         if {[file readable $info_exclude]} {
 595                 lappend ls_others "--exclude-from=$info_exclude"
 596         }
 597
 598         set buf_rdi {}
 599         set buf_rdf {}
 600         set buf_rlo {}
 601
 602         set rescan_active 3
 603         ui_status {Scanning for modified files ...}
 604         set fd_di [open "| git diff-index --cached -z [PARENT]" r]
 605         set fd_df [open "| git diff-files -z" r]
 606         set fd_lo [open $ls_others r]
 607
 608         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
 609         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
 610         fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
 611         fileevent $fd_di readable [list read_diff_index $fd_di $after]
 612         fileevent $fd_df readable [list read_diff_files $fd_df $after]
 613         fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
 614 }
 615
 616 proc load_message {file} {
 617         global ui_comm
 618
 619         set f [gitdir $file]
 620         if {[file isfile $f]} {
 621                 if {[catch {set fd [open $f r]}]} {
 622                         return 0
 623                 }
 624                 set content [string trim [read $fd]]
 625                 close $fd
 626                 regsub -all -line {[ \r\t]+$} $content {} content
 627                 $ui_comm delete 0.0 end
 628                 $ui_comm insert end $content
 629                 return 1
 630         }
 631         return 0
 632 }
 633
 634 proc read_diff_index {fd after} {
 635         global buf_rdi
 636
 637         append buf_rdi [read $fd]
 638         set c 0
 639         set n [string length $buf_rdi]
 640         while {$c < $n} {
 641                 set z1 [string first "\0" $buf_rdi $c]
 642                 if {$z1 == -1} break
 643                 incr z1
 644                 set z2 [string first "\0" $buf_rdi $z1]
 645                 if {$z2 == -1} break
 646
 647                 incr c
 648                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
 649                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
 650                 merge_state \
 651                         [encoding convertfrom $p] \
 652                         [lindex $i 4]? \
 653                         [list [lindex $i 0] [lindex $i 2]] \
 654                         [list]
 655                 set c $z2
 656                 incr c
 657         }
 658         if {$c < $n} {
 659                 set buf_rdi [string range $buf_rdi $c end]
 660         } else {
 661                 set buf_rdi {}
 662         }
 663
 664         rescan_done $fd buf_rdi $after
 665 }
 666
 667 proc read_diff_files {fd after} {
 668         global buf_rdf
 669
 670         append buf_rdf [read $fd]
 671         set c 0
 672         set n [string length $buf_rdf]
 673         while {$c < $n} {
 674                 set z1 [string first "\0" $buf_rdf $c]
 675                 if {$z1 == -1} break
 676                 incr z1
 677                 set z2 [string first "\0" $buf_rdf $z1]
 678                 if {$z2 == -1} break
 679
 680                 incr c
 681                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
 682                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
 683                 merge_state \
 684                         [encoding convertfrom $p] \
 685                         ?[lindex $i 4] \
 686                         [list] \
 687                         [list [lindex $i 0] [lindex $i 2]]
 688                 set c $z2
 689                 incr c
 690         }
 691         if {$c < $n} {
 692                 set buf_rdf [string range $buf_rdf $c end]
 693         } else {
 694                 set buf_rdf {}
 695         }
 696
 697         rescan_done $fd buf_rdf $after
 698 }
 699
 700 proc read_ls_others {fd after} {
 701         global buf_rlo
 702
 703         append buf_rlo [read $fd]
 704         set pck [split $buf_rlo "\0"]
 705         set buf_rlo [lindex $pck end]
 706         foreach p [lrange $pck 0 end-1] {
 707                 merge_state [encoding convertfrom $p] ?O
 708         }
 709         rescan_done $fd buf_rlo $after
 710 }
 711
 712 proc rescan_done {fd buf after} {
 713         global rescan_active current_diff_path
 714         global file_states repo_config
 715         upvar $buf to_clear
 716
 717         if {![eof $fd]} return
 718         set to_clear {}
 719         close $fd
 720         if {[incr rescan_active -1] > 0} return
 721
 722         prune_selection
 723         unlock_index
 724         display_all_files
 725         if {$current_diff_path ne {}} reshow_diff
 726         uplevel #0 $after
 727 }
 728
 729 proc prune_selection {} {
 730         global file_states selected_paths
 731
 732         foreach path [array names selected_paths] {
 733                 if {[catch {set still_here $file_states($path)}]} {
 734                         unset selected_paths($path)
 735                 }
 736         }
 737 }
 738
 739 ######################################################################
 740 ##
 741 ## ui helpers
 742
 743 proc mapicon {w state path} {
 744         global all_icons
 745
 746         if {[catch {set r $all_icons($state$w)}]} {
 747                 puts "error: no icon for $w state={$state} $path"
 748                 return file_plain
 749         }
 750         return $r
 751 }
 752
 753 proc mapdesc {state path} {
 754         global all_descs
 755
 756         if {[catch {set r $all_descs($state)}]} {
 757                 puts "error: no desc for state={$state} $path"
 758                 return $state
 759         }
 760         return $r
 761 }
 762
 763 proc ui_status {msg} {
 764         set ::ui_status_value $msg
 765 }
 766
 767 proc ui_ready {{test {}}} {
 768         if {$test eq {} || $::ui_status_value eq $test} {
 769                 ui_status Ready.
 770         }
 771 }
 772
 773 proc escape_path {path} {
 774         regsub -all {\\} $path "\\\\" path
 775         regsub -all "\n" $path "\\n" path
 776         return $path
 777 }
 778
 779 proc short_path {path} {
 780         return [escape_path [lindex [file split $path] end]]
 781 }
 782
 783 set next_icon_id 0
 784 set null_sha1 [string repeat 0 40]
 785
 786 proc merge_state {path new_state {head_info {}} {index_info {}}} {
 787         global file_states next_icon_id null_sha1
 788
 789         set s0 [string index $new_state 0]
 790         set s1 [string index $new_state 1]
 791
 792         if {[catch {set info $file_states($path)}]} {
 793                 set state __
 794                 set icon n[incr next_icon_id]
 795         } else {
 796                 set state [lindex $info 0]
 797                 set icon [lindex $info 1]
 798                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
 799                 if {$index_info eq {}} {set index_info [lindex $info 3]}
 800         }
 801
 802         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
 803         elseif {$s0 eq {_}} {set s0 _}
 804
 805         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
 806         elseif {$s1 eq {_}} {set s1 _}
 807
 808         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
 809                 set head_info [list 0 $null_sha1]
 810         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
 811                 && $head_info eq {}} {
 812                 set head_info $index_info
 813         }
 814
 815         set file_states($path) [list $s0$s1 $icon \
 816                 $head_info $index_info \
 817                 ]
 818         return $state
 819 }
 820
 821 proc display_file_helper {w path icon_name old_m new_m} {
 822         global file_lists
 823
 824         if {$new_m eq {_}} {
 825                 set lno [lsearch -sorted -exact $file_lists($w) $path]
 826                 if {$lno >= 0} {
 827                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
 828                         incr lno
 829                         $w conf -state normal
 830                         $w delete $lno.0 [expr {$lno + 1}].0
 831                         $w conf -state disabled
 832                 }
 833         } elseif {$old_m eq {_} && $new_m ne {_}} {
 834                 lappend file_lists($w) $path
 835                 set file_lists($w) [lsort -unique $file_lists($w)]
 836                 set lno [lsearch -sorted -exact $file_lists($w) $path]
 837                 incr lno
 838                 $w conf -state normal
 839                 $w image create $lno.0 \
 840                         -align center -padx 5 -pady 1 \
 841                         -name $icon_name \
 842                         -image [mapicon $w $new_m $path]
 843                 $w insert $lno.1 "[escape_path $path]\n"
 844                 $w conf -state disabled
 845         } elseif {$old_m ne $new_m} {
 846                 $w conf -state normal
 847                 $w image conf $icon_name -image [mapicon $w $new_m $path]
 848                 $w conf -state disabled
 849         }
 850 }
 851
 852 proc display_file {path state} {
 853         global file_states selected_paths
 854         global ui_index ui_workdir
 855
 856         set old_m [merge_state $path $state]
 857         set s $file_states($path)
 858         set new_m [lindex $s 0]
 859         set icon_name [lindex $s 1]
 860
 861         set o [string index $old_m 0]
 862         set n [string index $new_m 0]
 863         if {$o eq {U}} {
 864                 set o _
 865         }
 866         if {$n eq {U}} {
 867                 set n _
 868         }
 869         display_file_helper     $ui_index $path $icon_name $o $n
 870
 871         if {[string index $old_m 0] eq {U}} {
 872                 set o U
 873         } else {
 874                 set o [string index $old_m 1]
 875         }
 876         if {[string index $new_m 0] eq {U}} {
 877                 set n U
 878         } else {
 879                 set n [string index $new_m 1]
 880         }
 881         display_file_helper     $ui_workdir $path $icon_name $o $n
 882
 883         if {$new_m eq {__}} {
 884                 unset file_states($path)
 885                 catch {unset selected_paths($path)}
 886         }
 887 }
 888
 889 proc display_all_files_helper {w path icon_name m} {
 890         global file_lists
 891
 892         lappend file_lists($w) $path
 893         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
 894         $w image create end \
 895                 -align center -padx 5 -pady 1 \
 896                 -name $icon_name \
 897                 -image [mapicon $w $m $path]
 898         $w insert end "[escape_path $path]\n"
 899 }
 900
 901 proc display_all_files {} {
 902         global ui_index ui_workdir
 903         global file_states file_lists
 904         global last_clicked
 905
 906         $ui_index conf -state normal
 907         $ui_workdir conf -state normal
 908
 909         $ui_index delete 0.0 end
 910         $ui_workdir delete 0.0 end
 911         set last_clicked {}
 912
 913         set file_lists($ui_index) [list]
 914         set file_lists($ui_workdir) [list]
 915
 916         foreach path [lsort [array names file_states]] {
 917                 set s $file_states($path)
 918                 set m [lindex $s 0]
 919                 set icon_name [lindex $s 1]
 920
 921                 set s [string index $m 0]
 922                 if {$s ne {U} && $s ne {_}} {
 923                         display_all_files_helper $ui_index $path \
 924                                 $icon_name $s
 925                 }
 926
 927                 if {[string index $m 0] eq {U}} {
 928                         set s U
 929                 } else {
 930                         set s [string index $m 1]
 931                 }
 932                 if {$s ne {_}} {
 933                         display_all_files_helper $ui_workdir $path \
 934                                 $icon_name $s
 935                 }
 936         }
 937
 938         $ui_index conf -state disabled
 939         $ui_workdir conf -state disabled
 940 }
 941
 942 ######################################################################
 943 ##
 944 ## icons
 945
 946 set filemask {
 947 #define mask_width 14
 948 #define mask_height 15
 949 static unsigned char mask_bits[] = {
 950    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
 951    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
 952    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
 953 }
 954
 955 image create bitmap file_plain -background white -foreground black -data {
 956 #define plain_width 14
 957 #define plain_height 15
 958 static unsigned char plain_bits[] = {
 959    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
 960    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
 961    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 962 } -maskdata $filemask
 963
 964 image create bitmap file_mod -background white -foreground blue -data {
 965 #define mod_width 14
 966 #define mod_height 15
 967 static unsigned char mod_bits[] = {
 968    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
 969    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
 970    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
 971 } -maskdata $filemask
 972
 973 image create bitmap file_fulltick -background white -foreground "#007000" -data {
 974 #define file_fulltick_width 14
 975 #define file_fulltick_height 15
 976 static unsigned char file_fulltick_bits[] = {
 977    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
 978    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
 979    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 980 } -maskdata $filemask
 981
 982 image create bitmap file_parttick -background white -foreground "#005050" -data {
 983 #define parttick_width 14
 984 #define parttick_height 15
 985 static unsigned char parttick_bits[] = {
 986    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
 987    0x7a, 0x14, 0x02, 0x16, 0x02, 0x13, 0x8a, 0x11, 0xda, 0x10, 0x72, 0x10,
 988    0x22, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 989 } -maskdata $filemask
 990
 991 image create bitmap file_question -background white -foreground black -data {
 992 #define file_question_width 14
 993 #define file_question_height 15
 994 static unsigned char file_question_bits[] = {
 995    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
 996    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
 997    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
 998 } -maskdata $filemask
 999
1000 image create bitmap file_removed -background white -foreground red -data {
1001 #define file_removed_width 14
1002 #define file_removed_height 15
1003 static unsigned char file_removed_bits[] = {
1004    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
1005    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
1006    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
1007 } -maskdata $filemask
1008
1009 image create bitmap file_merge -background white -foreground blue -data {
1010 #define file_merge_width 14
1011 #define file_merge_height 15
1012 static unsigned char file_merge_bits[] = {
1013    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
1014    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
1015    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
1016 } -maskdata $filemask
1017
1018 set file_dir_data {
1019 #define file_width 18
1020 #define file_height 18
1021 static unsigned char file_bits[] = {
1022   0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0xf8, 0x03, 0x00,
1023   0x0c, 0x03, 0x00, 0x04, 0xfe, 0x00, 0x06, 0x80, 0x00, 0xff, 0x9f, 0x00,
1024   0x03, 0x98, 0x00, 0x02, 0x90, 0x00, 0x06, 0xb0, 0x00, 0x04, 0xa0, 0x00,
1025   0x0c, 0xe0, 0x00, 0x08, 0xc0, 0x00, 0xf8, 0xff, 0x00, 0x00, 0x00, 0x00,
1026   0x00, 0x00, 0x00, 0x00, 0x00, 0x00};
1027 }
1028 image create bitmap file_dir -background white -foreground blue \
1029         -data $file_dir_data -maskdata $file_dir_data
1030 unset file_dir_data
1031
1032 set file_uplevel_data {
1033 #define up_width 15
1034 #define up_height 15
1035 static unsigned char up_bits[] = {
1036   0x80, 0x00, 0xc0, 0x01, 0xe0, 0x03, 0xf0, 0x07, 0xf8, 0x0f, 0xfc, 0x1f,
1037   0xfe, 0x3f, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01, 0xc0, 0x01,
1038   0xc0, 0x01, 0xc0, 0x01, 0x00, 0x00};
1039 }
1040 image create bitmap file_uplevel -background white -foreground red \
1041         -data $file_uplevel_data -maskdata $file_uplevel_data
1042 unset file_uplevel_data
1043
1044 set ui_index .vpane.files.index.list
1045 set ui_workdir .vpane.files.workdir.list
1046
1047 set all_icons(_$ui_index)   file_plain
1048 set all_icons(A$ui_index)   file_fulltick
1049 set all_icons(M$ui_index)   file_fulltick
1050 set all_icons(D$ui_index)   file_removed
1051 set all_icons(U$ui_index)   file_merge
1052
1053 set all_icons(_$ui_workdir) file_plain
1054 set all_icons(M$ui_workdir) file_mod
1055 set all_icons(D$ui_workdir) file_question
1056 set all_icons(U$ui_workdir) file_merge
1057 set all_icons(O$ui_workdir) file_plain
1058
1059 set max_status_desc 0
1060 foreach i {
1061                 {__ "Unmodified"}
1062
1063                 {_M "Modified, not staged"}
1064                 {M_ "Staged for commit"}
1065                 {MM "Portions staged for commit"}
1066                 {MD "Staged for commit, missing"}
1067
1068                 {_O "Untracked, not staged"}
1069                 {A_ "Staged for commit"}
1070                 {AM "Portions staged for commit"}
1071                 {AD "Staged for commit, missing"}
1072
1073                 {_D "Missing"}
1074                 {D_ "Staged for removal"}
1075                 {DO "Staged for removal, still present"}
1076
1077                 {U_ "Requires merge resolution"}
1078                 {UU "Requires merge resolution"}
1079                 {UM "Requires merge resolution"}
1080                 {UD "Requires merge resolution"}
1081         } {
1082         if {$max_status_desc < [string length [lindex $i 1]]} {
1083                 set max_status_desc [string length [lindex $i 1]]
1084         }
1085         set all_descs([lindex $i 0]) [lindex $i 1]
1086 }
1087 unset i
1088
1089 ######################################################################
1090 ##
1091 ## util
1092
1093 proc bind_button3 {w cmd} {
1094         bind $w <Any-Button-3> $cmd
1095         if {[is_MacOSX]} {
1096                 bind $w <Control-Button-1> $cmd
1097         }
1098 }
1099
1100 proc scrollbar2many {list mode args} {
1101         foreach w $list {eval $w $mode $args}
1102 }
1103
1104 proc many2scrollbar {list mode sb top bottom} {
1105         $sb set $top $bottom
1106         foreach w $list {$w $mode moveto $top}
1107 }
1108
1109 proc incr_font_size {font {amt 1}} {
1110         set sz [font configure $font -size]
1111         incr sz $amt
1112         font configure $font -size $sz
1113         font configure ${font}bold -size $sz
1114         font configure ${font}italic -size $sz
1115 }
1116
1117 ######################################################################
1118 ##
1119 ## ui commands
1120
1121 set starting_gitk_msg {Starting gitk... please wait...}
1122
1123 proc do_gitk {revs} {
1124         global env starting_gitk_msg
1125
1126         # -- Always start gitk through whatever we were loaded with.  This
1127         #    lets us bypass using shell process on Windows systems.
1128         #
1129         set cmd [list [info nameofexecutable]]
1130         set exe [gitexec gitk]
1131         lappend cmd $exe
1132         if {$revs ne {}} {
1133                 append cmd { }
1134                 append cmd $revs
1135         }
1136
1137         if {! [file exists $exe]} {
1138                 error_popup "Unable to start gitk:\n\n$exe does not exist"
1139         } else {
1140                 eval exec $cmd &
1141                 ui_status $starting_gitk_msg
1142                 after 10000 {
1143                         ui_ready $starting_gitk_msg
1144                 }
1145         }
1146 }
1147
1148 set is_quitting 0
1149
1150 proc do_quit {} {
1151         global ui_comm is_quitting repo_config commit_type
1152
1153         if {$is_quitting} return
1154         set is_quitting 1
1155
1156         if {[winfo exists $ui_comm]} {
1157                 # -- Stash our current commit buffer.
1158                 #
1159                 set save [gitdir GITGUI_MSG]
1160                 set msg [string trim [$ui_comm get 0.0 end]]
1161                 regsub -all -line {[ \r\t]+$} $msg {} msg
1162                 if {(![string match amend* $commit_type]
1163                         || [$ui_comm edit modified])
1164                         && $msg ne {}} {
1165                         catch {
1166                                 set fd [open $save w]
1167                                 puts -nonewline $fd $msg
1168                                 close $fd
1169                         }
1170                 } else {
1171                         catch {file delete $save}
1172                 }
1173
1174                 # -- Stash our current window geometry into this repository.
1175                 #
1176                 set cfg_geometry [list]
1177                 lappend cfg_geometry [wm geometry .]
1178                 lappend cfg_geometry [lindex [.vpane sash coord 0] 1]
1179                 lappend cfg_geometry [lindex [.vpane.files sash coord 0] 0]
1180                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
1181                         set rc_geometry {}
1182                 }
1183                 if {$cfg_geometry ne $rc_geometry} {
1184                         catch {git config gui.geometry $cfg_geometry}
1185                 }
1186         }
1187
1188         destroy .
1189 }
1190
1191 proc do_rescan {} {
1192         rescan ui_ready
1193 }
1194
1195 proc do_commit {} {
1196         commit_tree
1197 }
1198
1199 proc toggle_or_diff {w x y} {
1200         global file_states file_lists current_diff_path ui_index ui_workdir
1201         global last_clicked selected_paths
1202
1203         set pos [split [$w index @$x,$y] .]
1204         set lno [lindex $pos 0]
1205         set col [lindex $pos 1]
1206         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1207         if {$path eq {}} {
1208                 set last_clicked {}
1209                 return
1210         }
1211
1212         set last_clicked [list $w $lno]
1213         array unset selected_paths
1214         $ui_index tag remove in_sel 0.0 end
1215         $ui_workdir tag remove in_sel 0.0 end
1216
1217         if {$col == 0} {
1218                 if {$current_diff_path eq $path} {
1219                         set after {reshow_diff;}
1220                 } else {
1221                         set after {}
1222                 }
1223                 if {$w eq $ui_index} {
1224                         update_indexinfo \
1225                                 "Unstaging [short_path $path] from commit" \
1226                                 [list $path] \
1227                                 [concat $after [list ui_ready]]
1228                 } elseif {$w eq $ui_workdir} {
1229                         update_index \
1230                                 "Adding [short_path $path]" \
1231                                 [list $path] \
1232                                 [concat $after [list ui_ready]]
1233                 }
1234         } else {
1235                 show_diff $path $w $lno
1236         }
1237 }
1238
1239 proc add_one_to_selection {w x y} {
1240         global file_lists last_clicked selected_paths
1241
1242         set lno [lindex [split [$w index @$x,$y] .] 0]
1243         set path [lindex $file_lists($w) [expr {$lno - 1}]]
1244         if {$path eq {}} {
1245                 set last_clicked {}
1246                 return
1247         }
1248
1249         if {$last_clicked ne {}
1250                 && [lindex $last_clicked 0] ne $w} {
1251                 array unset selected_paths
1252                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
1253         }
1254
1255         set last_clicked [list $w $lno]
1256         if {[catch {set in_sel $selected_paths($path)}]} {
1257                 set in_sel 0
1258         }
1259         if {$in_sel} {
1260                 unset selected_paths($path)
1261                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
1262         } else {
1263                 set selected_paths($path) 1
1264                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
1265         }
1266 }
1267
1268 proc add_range_to_selection {w x y} {
1269         global file_lists last_clicked selected_paths
1270
1271         if {[lindex $last_clicked 0] ne $w} {
1272                 toggle_or_diff $w $x $y
1273                 return
1274         }
1275
1276         set lno [lindex [split [$w index @$x,$y] .] 0]
1277         set lc [lindex $last_clicked 1]
1278         if {$lc < $lno} {
1279                 set begin $lc
1280                 set end $lno
1281         } else {
1282                 set begin $lno
1283                 set end $lc
1284         }
1285
1286         foreach path [lrange $file_lists($w) \
1287                 [expr {$begin - 1}] \
1288                 [expr {$end - 1}]] {
1289                 set selected_paths($path) 1
1290         }
1291         $w tag add in_sel $begin.0 [expr {$end + 1}].0
1292 }
1293
1294 ######################################################################
1295 ##
1296 ## config defaults
1297
1298 set cursor_ptr arrow
1299 font create font_diff -family Courier -size 10
1300 font create font_ui
1301 catch {
1302         label .dummy
1303         eval font configure font_ui [font actual [.dummy cget -font]]
1304         destroy .dummy
1305 }
1306
1307 font create font_uiitalic
1308 font create font_uibold
1309 font create font_diffbold
1310 font create font_diffitalic
1311
1312 foreach class {Button Checkbutton Entry Label
1313                 Labelframe Listbox Menu Message
1314                 Radiobutton Spinbox Text} {
1315         option add *$class.font font_ui
1316 }
1317 unset class
1318
1319 if {[is_Windows] || [is_MacOSX]} {
1320         option add *Menu.tearOff 0
1321 }
1322
1323 if {[is_MacOSX]} {
1324         set M1B M1
1325         set M1T Cmd
1326 } else {
1327         set M1B Control
1328         set M1T Ctrl
1329 }
1330
1331 proc apply_config {} {
1332         global repo_config font_descs
1333
1334         foreach option $font_descs {
1335                 set name [lindex $option 0]
1336                 set font [lindex $option 1]
1337                 if {[catch {
1338                         foreach {cn cv} $repo_config(gui.$name) {
1339                                 font configure $font $cn $cv
1340                         }
1341                         } err]} {
1342                         error_popup "Invalid font specified in gui.$name:\n\n$err"
1343                 }
1344                 foreach {cn cv} [font configure $font] {
1345                         font configure ${font}bold $cn $cv
1346                         font configure ${font}italic $cn $cv
1347                 }
1348                 font configure ${font}bold -weight bold
1349                 font configure ${font}italic -slant italic
1350         }
1351 }
1352
1353 set default_config(merge.diffstat) true
1354 set default_config(merge.summary) false
1355 set default_config(merge.verbosity) 2
1356 set default_config(user.name) {}
1357 set default_config(user.email) {}
1358
1359 set default_config(gui.matchtrackingbranch) false
1360 set default_config(gui.pruneduringfetch) false
1361 set default_config(gui.trustmtime) false
1362 set default_config(gui.diffcontext) 5
1363 set default_config(gui.newbranchtemplate) {}
1364 set default_config(gui.fontui) [font configure font_ui]
1365 set default_config(gui.fontdiff) [font configure font_diff]
1366 set font_descs {
1367         {fontui   font_ui   {Main Font}}
1368         {fontdiff font_diff {Diff/Console Font}}
1369 }
1370 load_config 0
1371 apply_config
1372
1373 ######################################################################
1374 ##
1375 ## feature option selection
1376
1377 if {[regexp {^git-(.+)$} [appname] _junk subcommand]} {
1378         unset _junk
1379 } else {
1380         set subcommand gui
1381 }
1382 if {$subcommand eq {gui.sh}} {
1383         set subcommand gui
1384 }
1385 if {$subcommand eq {gui} && [llength $argv] > 0} {
1386         set subcommand [lindex $argv 0]
1387         set argv [lrange $argv 1 end]
1388 }
1389
1390 enable_option multicommit
1391 enable_option branch
1392 enable_option transport
1393
1394 switch -- $subcommand {
1395 browser -
1396 blame {
1397         disable_option multicommit
1398         disable_option branch
1399         disable_option transport
1400 }
1401 citool {
1402         enable_option singlecommit
1403
1404         disable_option multicommit
1405         disable_option branch
1406         disable_option transport
1407 }
1408 }
1409
1410 ######################################################################
1411 ##
1412 ## ui construction
1413
1414 set ui_comm {}
1415
1416 # -- Menu Bar
1417 #
1418 menu .mbar -tearoff 0
1419 .mbar add cascade -label Repository -menu .mbar.repository
1420 .mbar add cascade -label Edit -menu .mbar.edit
1421 if {[is_enabled branch]} {
1422         .mbar add cascade -label Branch -menu .mbar.branch
1423 }
1424 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1425         .mbar add cascade -label Commit -menu .mbar.commit
1426 }
1427 if {[is_enabled transport]} {
1428         .mbar add cascade -label Merge -menu .mbar.merge
1429         .mbar add cascade -label Fetch -menu .mbar.fetch
1430         .mbar add cascade -label Push -menu .mbar.push
1431 }
1432 . configure -menu .mbar
1433
1434 # -- Repository Menu
1435 #
1436 menu .mbar.repository
1437
1438 .mbar.repository add command \
1439         -label {Browse Current Branch} \
1440         -command {browser::new $current_branch}
1441 trace add variable current_branch write ".mbar.repository entryconf [.mbar.repository index last] -label \"Browse \$current_branch\" ;#"
1442 .mbar.repository add separator
1443
1444 .mbar.repository add command \
1445         -label {Visualize Current Branch} \
1446         -command {do_gitk $current_branch}
1447 trace add variable current_branch write ".mbar.repository entryconf [.mbar.repository index last] -label \"Visualize \$current_branch\" ;#"
1448 .mbar.repository add command \
1449         -label {Visualize All Branches} \
1450         -command {do_gitk --all}
1451 .mbar.repository add separator
1452
1453 if {[is_enabled multicommit]} {
1454         .mbar.repository add command -label {Database Statistics} \
1455                 -command do_stats
1456
1457         .mbar.repository add command -label {Compress Database} \
1458                 -command do_gc
1459
1460         .mbar.repository add command -label {Verify Database} \
1461                 -command do_fsck_objects
1462
1463         .mbar.repository add separator
1464
1465         if {[is_Cygwin]} {
1466                 .mbar.repository add command \
1467                         -label {Create Desktop Icon} \
1468                         -command do_cygwin_shortcut
1469         } elseif {[is_Windows]} {
1470                 .mbar.repository add command \
1471                         -label {Create Desktop Icon} \
1472                         -command do_windows_shortcut
1473         } elseif {[is_MacOSX]} {
1474                 .mbar.repository add command \
1475                         -label {Create Desktop Icon} \
1476                         -command do_macosx_app
1477         }
1478 }
1479
1480 .mbar.repository add command -label Quit \
1481         -command do_quit \
1482         -accelerator $M1T-Q
1483
1484 # -- Edit Menu
1485 #
1486 menu .mbar.edit
1487 .mbar.edit add command -label Undo \
1488         -command {catch {[focus] edit undo}} \
1489         -accelerator $M1T-Z
1490 .mbar.edit add command -label Redo \
1491         -command {catch {[focus] edit redo}} \
1492         -accelerator $M1T-Y
1493 .mbar.edit add separator
1494 .mbar.edit add command -label Cut \
1495         -command {catch {tk_textCut [focus]}} \
1496         -accelerator $M1T-X
1497 .mbar.edit add command -label Copy \
1498         -command {catch {tk_textCopy [focus]}} \
1499         -accelerator $M1T-C
1500 .mbar.edit add command -label Paste \
1501         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
1502         -accelerator $M1T-V
1503 .mbar.edit add command -label Delete \
1504         -command {catch {[focus] delete sel.first sel.last}} \
1505         -accelerator Del
1506 .mbar.edit add separator
1507 .mbar.edit add command -label {Select All} \
1508         -command {catch {[focus] tag add sel 0.0 end}} \
1509         -accelerator $M1T-A
1510
1511 # -- Branch Menu
1512 #
1513 if {[is_enabled branch]} {
1514         menu .mbar.branch
1515
1516         .mbar.branch add command -label {Create...} \
1517                 -command branch_create::dialog \
1518                 -accelerator $M1T-N
1519         lappend disable_on_lock [list .mbar.branch entryconf \
1520                 [.mbar.branch index last] -state]
1521
1522         .mbar.branch add command -label {Checkout...} \
1523                 -command branch_checkout::dialog \
1524                 -accelerator $M1T-O
1525         lappend disable_on_lock [list .mbar.branch entryconf \
1526                 [.mbar.branch index last] -state]
1527
1528         .mbar.branch add command -label {Rename...} \
1529                 -command branch_rename::dialog
1530         lappend disable_on_lock [list .mbar.branch entryconf \
1531                 [.mbar.branch index last] -state]
1532
1533         .mbar.branch add command -label {Delete...} \
1534                 -command branch_delete::dialog
1535         lappend disable_on_lock [list .mbar.branch entryconf \
1536                 [.mbar.branch index last] -state]
1537
1538         .mbar.branch add command -label {Reset...} \
1539                 -command merge::reset_hard
1540         lappend disable_on_lock [list .mbar.branch entryconf \
1541                 [.mbar.branch index last] -state]
1542 }
1543
1544 # -- Commit Menu
1545 #
1546 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
1547         menu .mbar.commit
1548
1549         .mbar.commit add radiobutton \
1550                 -label {New Commit} \
1551                 -command do_select_commit_type \
1552                 -variable selected_commit_type \
1553                 -value new
1554         lappend disable_on_lock \
1555                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1556
1557         .mbar.commit add radiobutton \
1558                 -label {Amend Last Commit} \
1559                 -command do_select_commit_type \
1560                 -variable selected_commit_type \
1561                 -value amend
1562         lappend disable_on_lock \
1563                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1564
1565         .mbar.commit add separator
1566
1567         .mbar.commit add command -label Rescan \
1568                 -command do_rescan \
1569                 -accelerator F5
1570         lappend disable_on_lock \
1571                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1572
1573         .mbar.commit add command -label {Add To Commit} \
1574                 -command do_add_selection
1575         lappend disable_on_lock \
1576                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1577
1578         .mbar.commit add command -label {Add Existing To Commit} \
1579                 -command do_add_all \
1580                 -accelerator $M1T-I
1581         lappend disable_on_lock \
1582                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1583
1584         .mbar.commit add command -label {Unstage From Commit} \
1585                 -command do_unstage_selection
1586         lappend disable_on_lock \
1587                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1588
1589         .mbar.commit add command -label {Revert Changes} \
1590                 -command do_revert_selection
1591         lappend disable_on_lock \
1592                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1593
1594         .mbar.commit add separator
1595
1596         .mbar.commit add command -label {Sign Off} \
1597                 -command do_signoff \
1598                 -accelerator $M1T-S
1599
1600         .mbar.commit add command -label Commit \
1601                 -command do_commit \
1602                 -accelerator $M1T-Return
1603         lappend disable_on_lock \
1604                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
1605 }
1606
1607 # -- Merge Menu
1608 #
1609 if {[is_enabled branch]} {
1610         menu .mbar.merge
1611         .mbar.merge add command -label {Local Merge...} \
1612                 -command merge::dialog
1613         lappend disable_on_lock \
1614                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
1615         .mbar.merge add command -label {Abort Merge...} \
1616                 -command merge::reset_hard
1617         lappend disable_on_lock \
1618                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
1619
1620 }
1621
1622 # -- Transport Menu
1623 #
1624 if {[is_enabled transport]} {
1625         menu .mbar.fetch
1626
1627         menu .mbar.push
1628         .mbar.push add command -label {Push...} \
1629                 -command do_push_anywhere \
1630                 -accelerator $M1T-P
1631         .mbar.push add command -label {Delete...} \
1632                 -command remote_branch_delete::dialog
1633 }
1634
1635 if {[is_MacOSX]} {
1636         # -- Apple Menu (Mac OS X only)
1637         #
1638         .mbar add cascade -label Apple -menu .mbar.apple
1639         menu .mbar.apple
1640
1641         .mbar.apple add command -label "About [appname]" \
1642                 -command do_about
1643         .mbar.apple add command -label "Options..." \
1644                 -command do_options
1645 } else {
1646         # -- Edit Menu
1647         #
1648         .mbar.edit add separator
1649         .mbar.edit add command -label {Options...} \
1650                 -command do_options
1651
1652         # -- Tools Menu
1653         #
1654         if {[is_Cygwin] && [file exists /usr/local/miga/lib/gui-miga]} {
1655         proc do_miga {} {
1656                 if {![lock_index update]} return
1657                 set cmd [list sh --login -c "/usr/local/miga/lib/gui-miga \"[pwd]\""]
1658                 set miga_fd [open "|$cmd" r]
1659                 fconfigure $miga_fd -blocking 0
1660                 fileevent $miga_fd readable [list miga_done $miga_fd]
1661                 ui_status {Running miga...}
1662         }
1663         proc miga_done {fd} {
1664                 read $fd 512
1665                 if {[eof $fd]} {
1666                         close $fd
1667                         unlock_index
1668                         rescan ui_ready
1669                 }
1670         }
1671         .mbar add cascade -label Tools -menu .mbar.tools
1672         menu .mbar.tools
1673         .mbar.tools add command -label "Migrate" \
1674                 -command do_miga
1675         lappend disable_on_lock \
1676                 [list .mbar.tools entryconf [.mbar.tools index last] -state]
1677         }
1678 }
1679
1680 # -- Help Menu
1681 #
1682 .mbar add cascade -label Help -menu .mbar.help
1683 menu .mbar.help
1684
1685 if {![is_MacOSX]} {
1686         .mbar.help add command -label "About [appname]" \
1687                 -command do_about
1688 }
1689
1690 set browser {}
1691 catch {set browser $repo_config(instaweb.browser)}
1692 set doc_path [file dirname [gitexec]]
1693 set doc_path [file join $doc_path Documentation index.html]
1694
1695 if {[is_Cygwin]} {
1696         set doc_path [exec cygpath --mixed $doc_path]
1697 }
1698
1699 if {$browser eq {}} {
1700         if {[is_MacOSX]} {
1701                 set browser open
1702         } elseif {[is_Cygwin]} {
1703                 set program_files [file dirname [exec cygpath --windir]]
1704                 set program_files [file join $program_files {Program Files}]
1705                 set firefox [file join $program_files {Mozilla Firefox} firefox.exe]
1706                 set ie [file join $program_files {Internet Explorer} IEXPLORE.EXE]
1707                 if {[file exists $firefox]} {
1708                         set browser $firefox
1709                 } elseif {[file exists $ie]} {
1710                         set browser $ie
1711                 }
1712                 unset program_files firefox ie
1713         }
1714 }
1715
1716 if {[file isfile $doc_path]} {
1717         set doc_url "file:$doc_path"
1718 } else {
1719         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
1720 }
1721
1722 if {$browser ne {}} {
1723         .mbar.help add command -label {Online Documentation} \
1724                 -command [list exec $browser $doc_url &]
1725 }
1726 unset browser doc_path doc_url
1727
1728 # -- Standard bindings
1729 #
1730 wm protocol . WM_DELETE_WINDOW do_quit
1731 bind all <$M1B-Key-q> do_quit
1732 bind all <$M1B-Key-Q> do_quit
1733 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
1734 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
1735
1736 set subcommand_args {}
1737 proc usage {} {
1738         puts stderr "usage: $::argv0 $::subcommand $::subcommand_args"
1739         exit 1
1740 }
1741
1742 # -- Not a normal commit type invocation?  Do that instead!
1743 #
1744 switch -- $subcommand {
1745 browser {
1746         set subcommand_args {rev?}
1747         switch [llength $argv] {
1748         0 { load_current_branch }
1749         1 { set current_branch [lindex $argv 0] }
1750         default usage
1751         }
1752         browser::new $current_branch
1753         return
1754 }
1755 blame {
1756         set subcommand_args {rev? path?}
1757         set head {}
1758         set path {}
1759         set is_path 0
1760         foreach a $argv {
1761                 if {$is_path || [file exists $_prefix$a]} {
1762                         if {$path ne {}} usage
1763                         set path $_prefix$a
1764                         break
1765                 } elseif {$a eq {--}} {
1766                         if {$path ne {}} {
1767                                 if {$head ne {}} usage
1768                                 set head $path
1769                                 set path {}
1770                         }
1771                         set is_path 1
1772                 } elseif {$head eq {}} {
1773                         if {$head ne {}} usage
1774                         set head $a
1775                 } else {
1776                         usage
1777                 }
1778         }
1779         unset is_path
1780
1781         if {$head eq {}} {
1782                 load_current_branch
1783         } else {
1784                 set current_branch $head
1785         }
1786
1787         if {$path eq {}} usage
1788         blame::new $head $path
1789         return
1790 }
1791 citool -
1792 gui {
1793         if {[llength $argv] != 0} {
1794                 puts -nonewline stderr "usage: $argv0"
1795                 if {$subcommand ne {gui} && [appname] ne "git-$subcommand"} {
1796                         puts -nonewline stderr " $subcommand"
1797                 }
1798                 puts stderr {}
1799                 exit 1
1800         }
1801         # fall through to setup UI for commits
1802 }
1803 default {
1804         puts stderr "usage: $argv0 \[{blame|browser|citool}\]"
1805         exit 1
1806 }
1807 }
1808
1809 # -- Branch Control
1810 #
1811 frame .branch \
1812         -borderwidth 1 \
1813         -relief sunken
1814 label .branch.l1 \
1815         -text {Current Branch:} \
1816         -anchor w \
1817         -justify left
1818 label .branch.cb \
1819         -textvariable current_branch \
1820         -anchor w \
1821         -justify left
1822 pack .branch.l1 -side left
1823 pack .branch.cb -side left -fill x
1824 pack .branch -side top -fill x
1825
1826 # -- Main Window Layout
1827 #
1828 panedwindow .vpane -orient vertical
1829 panedwindow .vpane.files -orient horizontal
1830 .vpane add .vpane.files -sticky nsew -height 100 -width 200
1831 pack .vpane -anchor n -side top -fill both -expand 1
1832
1833 # -- Index File List
1834 #
1835 frame .vpane.files.index -height 100 -width 200
1836 label .vpane.files.index.title -text {Staged Changes (Will Be Committed)} \
1837         -background lightgreen
1838 text $ui_index -background white -borderwidth 0 \
1839         -width 20 -height 10 \
1840         -wrap none \
1841         -cursor $cursor_ptr \
1842         -xscrollcommand {.vpane.files.index.sx set} \
1843         -yscrollcommand {.vpane.files.index.sy set} \
1844         -state disabled
1845 scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
1846 scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
1847 pack .vpane.files.index.title -side top -fill x
1848 pack .vpane.files.index.sx -side bottom -fill x
1849 pack .vpane.files.index.sy -side right -fill y
1850 pack $ui_index -side left -fill both -expand 1
1851 .vpane.files add .vpane.files.index -sticky nsew
1852
1853 # -- Working Directory File List
1854 #
1855 frame .vpane.files.workdir -height 100 -width 200
1856 label .vpane.files.workdir.title -text {Unstaged Changes (Will Not Be Committed)} \
1857         -background lightsalmon
1858 text $ui_workdir -background white -borderwidth 0 \
1859         -width 20 -height 10 \
1860         -wrap none \
1861         -cursor $cursor_ptr \
1862         -xscrollcommand {.vpane.files.workdir.sx set} \
1863         -yscrollcommand {.vpane.files.workdir.sy set} \
1864         -state disabled
1865 scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
1866 scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
1867 pack .vpane.files.workdir.title -side top -fill x
1868 pack .vpane.files.workdir.sx -side bottom -fill x
1869 pack .vpane.files.workdir.sy -side right -fill y
1870 pack $ui_workdir -side left -fill both -expand 1
1871 .vpane.files add .vpane.files.workdir -sticky nsew
1872
1873 foreach i [list $ui_index $ui_workdir] {
1874         $i tag conf in_diff -background lightgray
1875         $i tag conf in_sel  -background lightgray
1876 }
1877 unset i
1878
1879 # -- Diff and Commit Area
1880 #
1881 frame .vpane.lower -height 300 -width 400
1882 frame .vpane.lower.commarea
1883 frame .vpane.lower.diff -relief sunken -borderwidth 1
1884 pack .vpane.lower.commarea -side top -fill x
1885 pack .vpane.lower.diff -side bottom -fill both -expand 1
1886 .vpane add .vpane.lower -sticky nsew
1887
1888 # -- Commit Area Buttons
1889 #
1890 frame .vpane.lower.commarea.buttons
1891 label .vpane.lower.commarea.buttons.l -text {} \
1892         -anchor w \
1893         -justify left
1894 pack .vpane.lower.commarea.buttons.l -side top -fill x
1895 pack .vpane.lower.commarea.buttons -side left -fill y
1896
1897 button .vpane.lower.commarea.buttons.rescan -text {Rescan} \
1898         -command do_rescan
1899 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
1900 lappend disable_on_lock \
1901         {.vpane.lower.commarea.buttons.rescan conf -state}
1902
1903 button .vpane.lower.commarea.buttons.incall -text {Add Existing} \
1904         -command do_add_all
1905 pack .vpane.lower.commarea.buttons.incall -side top -fill x
1906 lappend disable_on_lock \
1907         {.vpane.lower.commarea.buttons.incall conf -state}
1908
1909 button .vpane.lower.commarea.buttons.signoff -text {Sign Off} \
1910         -command do_signoff
1911 pack .vpane.lower.commarea.buttons.signoff -side top -fill x
1912
1913 button .vpane.lower.commarea.buttons.commit -text {Commit} \
1914         -command do_commit
1915 pack .vpane.lower.commarea.buttons.commit -side top -fill x
1916 lappend disable_on_lock \
1917         {.vpane.lower.commarea.buttons.commit conf -state}
1918
1919 button .vpane.lower.commarea.buttons.push -text {Push} \
1920         -command do_push_anywhere
1921 pack .vpane.lower.commarea.buttons.push -side top -fill x
1922
1923 # -- Commit Message Buffer
1924 #
1925 frame .vpane.lower.commarea.buffer
1926 frame .vpane.lower.commarea.buffer.header
1927 set ui_comm .vpane.lower.commarea.buffer.t
1928 set ui_coml .vpane.lower.commarea.buffer.header.l
1929 radiobutton .vpane.lower.commarea.buffer.header.new \
1930         -text {New Commit} \
1931         -command do_select_commit_type \
1932         -variable selected_commit_type \
1933         -value new
1934 lappend disable_on_lock \
1935         [list .vpane.lower.commarea.buffer.header.new conf -state]
1936 radiobutton .vpane.lower.commarea.buffer.header.amend \
1937         -text {Amend Last Commit} \
1938         -command do_select_commit_type \
1939         -variable selected_commit_type \
1940         -value amend
1941 lappend disable_on_lock \
1942         [list .vpane.lower.commarea.buffer.header.amend conf -state]
1943 label $ui_coml \
1944         -anchor w \
1945         -justify left
1946 proc trace_commit_type {varname args} {
1947         global ui_coml commit_type
1948         switch -glob -- $commit_type {
1949         initial       {set txt {Initial Commit Message:}}
1950         amend         {set txt {Amended Commit Message:}}
1951         amend-initial {set txt {Amended Initial Commit Message:}}
1952         amend-merge   {set txt {Amended Merge Commit Message:}}
1953         merge         {set txt {Merge Commit Message:}}
1954         *             {set txt {Commit Message:}}
1955         }
1956         $ui_coml conf -text $txt
1957 }
1958 trace add variable commit_type write trace_commit_type
1959 pack $ui_coml -side left -fill x
1960 pack .vpane.lower.commarea.buffer.header.amend -side right
1961 pack .vpane.lower.commarea.buffer.header.new -side right
1962
1963 text $ui_comm -background white -borderwidth 1 \
1964         -undo true \
1965         -maxundo 20 \
1966         -autoseparators true \
1967         -relief sunken \
1968         -width 75 -height 9 -wrap none \
1969         -font font_diff \
1970         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
1971 scrollbar .vpane.lower.commarea.buffer.sby \
1972         -command [list $ui_comm yview]
1973 pack .vpane.lower.commarea.buffer.header -side top -fill x
1974 pack .vpane.lower.commarea.buffer.sby -side right -fill y
1975 pack $ui_comm -side left -fill y
1976 pack .vpane.lower.commarea.buffer -side left -fill y
1977
1978 # -- Commit Message Buffer Context Menu
1979 #
1980 set ctxm .vpane.lower.commarea.buffer.ctxm
1981 menu $ctxm -tearoff 0
1982 $ctxm add command \
1983         -label {Cut} \
1984         -command {tk_textCut $ui_comm}
1985 $ctxm add command \
1986         -label {Copy} \
1987         -command {tk_textCopy $ui_comm}
1988 $ctxm add command \
1989         -label {Paste} \
1990         -command {tk_textPaste $ui_comm}
1991 $ctxm add command \
1992         -label {Delete} \
1993         -command {$ui_comm delete sel.first sel.last}
1994 $ctxm add separator
1995 $ctxm add command \
1996         -label {Select All} \
1997         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
1998 $ctxm add command \
1999         -label {Copy All} \
2000         -command {
2001                 $ui_comm tag add sel 0.0 end
2002                 tk_textCopy $ui_comm
2003                 $ui_comm tag remove sel 0.0 end
2004         }
2005 $ctxm add separator
2006 $ctxm add command \
2007         -label {Sign Off} \
2008         -command do_signoff
2009 bind_button3 $ui_comm "tk_popup $ctxm %X %Y"
2010
2011 # -- Diff Header
2012 #
2013 proc trace_current_diff_path {varname args} {
2014         global current_diff_path diff_actions file_states
2015         if {$current_diff_path eq {}} {
2016                 set s {}
2017                 set f {}
2018                 set p {}
2019                 set o disabled
2020         } else {
2021                 set p $current_diff_path
2022                 set s [mapdesc [lindex $file_states($p) 0] $p]
2023                 set f {File:}
2024                 set p [escape_path $p]
2025                 set o normal
2026         }
2027
2028         .vpane.lower.diff.header.status configure -text $s
2029         .vpane.lower.diff.header.file configure -text $f
2030         .vpane.lower.diff.header.path configure -text $p
2031         foreach w $diff_actions {
2032                 uplevel #0 $w $o
2033         }
2034 }
2035 trace add variable current_diff_path write trace_current_diff_path
2036
2037 frame .vpane.lower.diff.header -background gold
2038 label .vpane.lower.diff.header.status \
2039         -background gold \
2040         -width $max_status_desc \
2041         -anchor w \
2042         -justify left
2043 label .vpane.lower.diff.header.file \
2044         -background gold \
2045         -anchor w \
2046         -justify left
2047 label .vpane.lower.diff.header.path \
2048         -background gold \
2049         -anchor w \
2050         -justify left
2051 pack .vpane.lower.diff.header.status -side left
2052 pack .vpane.lower.diff.header.file -side left
2053 pack .vpane.lower.diff.header.path -fill x
2054 set ctxm .vpane.lower.diff.header.ctxm
2055 menu $ctxm -tearoff 0
2056 $ctxm add command \
2057         -label {Copy} \
2058         -command {
2059                 clipboard clear
2060                 clipboard append \
2061                         -format STRING \
2062                         -type STRING \
2063                         -- $current_diff_path
2064         }
2065 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2066 bind_button3 .vpane.lower.diff.header.path "tk_popup $ctxm %X %Y"
2067
2068 # -- Diff Body
2069 #
2070 frame .vpane.lower.diff.body
2071 set ui_diff .vpane.lower.diff.body.t
2072 text $ui_diff -background white -borderwidth 0 \
2073         -width 80 -height 15 -wrap none \
2074         -font font_diff \
2075         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
2076         -yscrollcommand {.vpane.lower.diff.body.sby set} \
2077         -state disabled
2078 scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
2079         -command [list $ui_diff xview]
2080 scrollbar .vpane.lower.diff.body.sby -orient vertical \
2081         -command [list $ui_diff yview]
2082 pack .vpane.lower.diff.body.sbx -side bottom -fill x
2083 pack .vpane.lower.diff.body.sby -side right -fill y
2084 pack $ui_diff -side left -fill both -expand 1
2085 pack .vpane.lower.diff.header -side top -fill x
2086 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
2087
2088 $ui_diff tag conf d_cr -elide true
2089 $ui_diff tag conf d_@ -foreground blue -font font_diffbold
2090 $ui_diff tag conf d_+ -foreground {#00a000}
2091 $ui_diff tag conf d_- -foreground red
2092
2093 $ui_diff tag conf d_++ -foreground {#00a000}
2094 $ui_diff tag conf d_-- -foreground red
2095 $ui_diff tag conf d_+s \
2096         -foreground {#00a000} \
2097         -background {#e2effa}
2098 $ui_diff tag conf d_-s \
2099         -foreground red \
2100         -background {#e2effa}
2101 $ui_diff tag conf d_s+ \
2102         -foreground {#00a000} \
2103         -background ivory1
2104 $ui_diff tag conf d_s- \
2105         -foreground red \
2106         -background ivory1
2107
2108 $ui_diff tag conf d<<<<<<< \
2109         -foreground orange \
2110         -font font_diffbold
2111 $ui_diff tag conf d======= \
2112         -foreground orange \
2113         -font font_diffbold
2114 $ui_diff tag conf d>>>>>>> \
2115         -foreground orange \
2116         -font font_diffbold
2117
2118 $ui_diff tag raise sel
2119
2120 # -- Diff Body Context Menu
2121 #
2122 set ctxm .vpane.lower.diff.body.ctxm
2123 menu $ctxm -tearoff 0
2124 $ctxm add command \
2125         -label {Refresh} \
2126         -command reshow_diff
2127 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2128 $ctxm add command \
2129         -label {Copy} \
2130         -command {tk_textCopy $ui_diff}
2131 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2132 $ctxm add command \
2133         -label {Select All} \
2134         -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
2135 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2136 $ctxm add command \
2137         -label {Copy All} \
2138         -command {
2139                 $ui_diff tag add sel 0.0 end
2140                 tk_textCopy $ui_diff
2141                 $ui_diff tag remove sel 0.0 end
2142         }
2143 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2144 $ctxm add separator
2145 $ctxm add command \
2146         -label {Apply/Reverse Hunk} \
2147         -command {apply_hunk $cursorX $cursorY}
2148 set ui_diff_applyhunk [$ctxm index last]
2149 lappend diff_actions [list $ctxm entryconf $ui_diff_applyhunk -state]
2150 $ctxm add separator
2151 $ctxm add command \
2152         -label {Decrease Font Size} \
2153         -command {incr_font_size font_diff -1}
2154 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2155 $ctxm add command \
2156         -label {Increase Font Size} \
2157         -command {incr_font_size font_diff 1}
2158 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2159 $ctxm add separator
2160 $ctxm add command \
2161         -label {Show Less Context} \
2162         -command {if {$repo_config(gui.diffcontext) >= 1} {
2163                 incr repo_config(gui.diffcontext) -1
2164                 reshow_diff
2165         }}
2166 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2167 $ctxm add command \
2168         -label {Show More Context} \
2169         -command {if {$repo_config(gui.diffcontext) < 99} {
2170                 incr repo_config(gui.diffcontext)
2171                 reshow_diff
2172         }}
2173 lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
2174 $ctxm add separator
2175 $ctxm add command -label {Options...} \
2176         -command do_options
2177 bind_button3 $ui_diff "
2178         set cursorX %x
2179         set cursorY %y
2180         if {\$ui_index eq \$current_diff_side} {
2181                 $ctxm entryconf $ui_diff_applyhunk -label {Unstage Hunk From Commit}
2182         } else {
2183                 $ctxm entryconf $ui_diff_applyhunk -label {Stage Hunk For Commit}
2184         }
2185         tk_popup $ctxm %X %Y
2186 "
2187 unset ui_diff_applyhunk
2188
2189 # -- Status Bar
2190 #
2191 label .status -textvariable ui_status_value \
2192         -anchor w \
2193         -justify left \
2194         -borderwidth 1 \
2195         -relief sunken
2196 pack .status -anchor w -side bottom -fill x
2197
2198 # -- Load geometry
2199 #
2200 catch {
2201 set gm $repo_config(gui.geometry)
2202 wm geometry . [lindex $gm 0]
2203 .vpane sash place 0 \
2204         [lindex [.vpane sash coord 0] 0] \
2205         [lindex $gm 1]
2206 .vpane.files sash place 0 \
2207         [lindex $gm 2] \
2208         [lindex [.vpane.files sash coord 0] 1]
2209 unset gm
2210 }
2211
2212 # -- Key Bindings
2213 #
2214 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
2215 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
2216 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
2217 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
2218 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
2219 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
2220 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
2221 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
2222 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
2223 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2224 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2225
2226 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
2227 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
2228 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
2229 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
2230 bind $ui_diff <$M1B-Key-v> {break}
2231 bind $ui_diff <$M1B-Key-V> {break}
2232 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
2233 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
2234 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
2235 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
2236 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
2237 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
2238 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
2239 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
2240 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
2241 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
2242 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
2243 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
2244 bind $ui_diff <Button-1>   {focus %W}
2245
2246 if {[is_enabled branch]} {
2247         bind . <$M1B-Key-n> branch_create::dialog
2248         bind . <$M1B-Key-N> branch_create::dialog
2249         bind . <$M1B-Key-o> branch_checkout::dialog
2250         bind . <$M1B-Key-O> branch_checkout::dialog
2251 }
2252 if {[is_enabled transport]} {
2253         bind . <$M1B-Key-p> do_push_anywhere
2254         bind . <$M1B-Key-P> do_push_anywhere
2255 }
2256
2257 bind .   <Key-F5>     do_rescan
2258 bind .   <$M1B-Key-r> do_rescan
2259 bind .   <$M1B-Key-R> do_rescan
2260 bind .   <$M1B-Key-s> do_signoff
2261 bind .   <$M1B-Key-S> do_signoff
2262 bind .   <$M1B-Key-i> do_add_all
2263 bind .   <$M1B-Key-I> do_add_all
2264 bind .   <$M1B-Key-Return> do_commit
2265 foreach i [list $ui_index $ui_workdir] {
2266         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
2267         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
2268         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
2269 }
2270 unset i
2271
2272 set file_lists($ui_index) [list]
2273 set file_lists($ui_workdir) [list]
2274
2275 wm title . "[appname] ([reponame]) [file normalize [file dirname [gitdir]]]"
2276 focus -force $ui_comm
2277
2278 # -- Warn the user about environmental problems.  Cygwin's Tcl
2279 #    does *not* pass its env array onto any processes it spawns.
2280 #    This means that git processes get none of our environment.
2281 #
2282 if {[is_Cygwin]} {
2283         set ignored_env 0
2284         set suggest_user {}
2285         set msg "Possible environment issues exist.
2286
2287 The following environment variables are probably
2288 going to be ignored by any Git subprocess run
2289 by [appname]:
2290
2291 "
2292         foreach name [array names env] {
2293                 switch -regexp -- $name {
2294                 {^GIT_INDEX_FILE$} -
2295                 {^GIT_OBJECT_DIRECTORY$} -
2296                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
2297                 {^GIT_DIFF_OPTS$} -
2298                 {^GIT_EXTERNAL_DIFF$} -
2299                 {^GIT_PAGER$} -
2300                 {^GIT_TRACE$} -
2301                 {^GIT_CONFIG$} -
2302                 {^GIT_CONFIG_LOCAL$} -
2303                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
2304                         append msg " - $name\n"
2305                         incr ignored_env
2306                 }
2307                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
2308                         append msg " - $name\n"
2309                         incr ignored_env
2310                         set suggest_user $name
2311                 }
2312                 }
2313         }
2314         if {$ignored_env > 0} {
2315                 append msg "
2316 This is due to a known issue with the
2317 Tcl binary distributed by Cygwin."
2318
2319                 if {$suggest_user ne {}} {
2320                         append msg "
2321
2322 A good replacement for $suggest_user
2323 is placing values for the user.name and
2324 user.email settings into your personal
2325 ~/.gitconfig file.
2326 "
2327                 }
2328                 warn_popup $msg
2329         }
2330         unset ignored_env msg suggest_user name
2331 }
2332
2333 # -- Only initialize complex UI if we are going to stay running.
2334 #
2335 if {[is_enabled transport]} {
2336         load_all_remotes
2337
2338         populate_fetch_menu
2339         populate_push_menu
2340 }
2341
2342 # -- Only suggest a gc run if we are going to stay running.
2343 #
2344 if {[is_enabled multicommit]} {
2345         set object_limit 2000
2346         if {[is_Windows]} {set object_limit 200}
2347         regexp {^([0-9]+) objects,} [git count-objects] _junk objects_current
2348         if {$objects_current >= $object_limit} {
2349                 if {[ask_popup \
2350                         "This repository currently has $objects_current loose objects.
2351
2352 To maintain optimal performance it is strongly recommended that you compress the database when more than $object_limit loose objects exist.
2353
2354 Compress the database now?"] eq yes} {
2355                         do_gc
2356                 }
2357         }
2358         unset object_limit _junk objects_current
2359 }
2360
2361 lock_index begin-read
2362 after 1 do_rescan