gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101 # URI of GIT logo (72x27 size)
 102 our $logo = "++GITWEB_LOGO++";
 103 # URI of GIT favicon, assumed to be image/png type
 104 our $favicon = "++GITWEB_FAVICON++";
 105 # URI of gitweb.js (JavaScript code for gitweb)
 106 our $javascript = "++GITWEB_JS++";
 107
 108 # URI and label (title) of GIT logo link
 109 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 110 #our $logo_label = "git documentation";
 111 our $logo_url = "http://git-scm.com/";
 112 our $logo_label = "git homepage";
 113
 114 # source of projects list
 115 our $projects_list = "++GITWEB_LIST++";
 116
 117 # the width (in characters) of the projects list "Description" column
 118 our $projects_list_description_width = 25;
 119
 120 # group projects by category on the projects list
 121 # (enabled if this variable evaluates to true)
 122 our $projects_list_group_categories = 0;
 123
 124 # default category if none specified
 125 # (leave the empty string for no category)
 126 our $project_list_default_category = "";
 127
 128 # default order of projects list
 129 # valid values are none, project, descr, owner, and age
 130 our $default_projects_order = "project";
 131
 132 # show repository only if this file exists
 133 # (only effective if this variable evaluates to true)
 134 our $export_ok = "++GITWEB_EXPORT_OK++";
 135
 136 # show repository only if this subroutine returns true
 137 # when given the path to the project, for example:
 138 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 139 our $export_auth_hook = undef;
 140
 141 # only allow viewing of repositories also shown on the overview page
 142 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 143
 144 # list of git base URLs used for URL to where fetch project from,
 145 # i.e. full URL is "$git_base_url/$project"
 146 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 147
 148 # default blob_plain mimetype and default charset for text/plain blob
 149 our $default_blob_plain_mimetype = 'text/plain';
 150 our $default_text_plain_charset  = undef;
 151
 152 # file to use for guessing MIME types before trying /etc/mime.types
 153 # (relative to the current git repository)
 154 our $mimetypes_file = undef;
 155
 156 # assume this charset if line contains non-UTF-8 characters;
 157 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 158 # for which encoding all byte sequences are valid, for example
 159 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 160 # could be even 'utf-8' for the old behavior)
 161 our $fallback_encoding = 'latin1';
 162
 163 # rename detection options for git-diff and git-diff-tree
 164 # - default is '-M', with the cost proportional to
 165 #   (number of removed files) * (number of new files).
 166 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 167 #   (number of changed files + number of removed files) * (number of new files)
 168 # - even more costly is '-C', '--find-copies-harder' with cost
 169 #   (number of files in the original tree) * (number of new files)
 170 # - one might want to include '-B' option, e.g. '-B', '-M'
 171 our @diff_opts = ('-M'); # taken from git_commit
 172
 173 # Disables features that would allow repository owners to inject script into
 174 # the gitweb domain.
 175 our $prevent_xss = 0;
 176
 177 # Path to the highlight executable to use (must be the one from
 178 # http://www.andre-simon.de due to assumptions about parameters and output).
 179 # Useful if highlight is not installed on your webserver's PATH.
 180 # [Default: highlight]
 181 our $highlight_bin = "++HIGHLIGHT_BIN++";
 182
 183 # information about snapshot formats that gitweb is capable of serving
 184 our %known_snapshot_formats = (
 185         # name => {
 186         #       'display' => display name,
 187         #       'type' => mime type,
 188         #       'suffix' => filename suffix,
 189         #       'format' => --format for git-archive,
 190         #       'compressor' => [compressor command and arguments]
 191         #                       (array reference, optional)
 192         #       'disabled' => boolean (optional)}
 193         #
 194         'tgz' => {
 195                 'display' => 'tar.gz',
 196                 'type' => 'application/x-gzip',
 197                 'suffix' => '.tar.gz',
 198                 'format' => 'tar',
 199                 'compressor' => ['gzip', '-n']},
 200
 201         'tbz2' => {
 202                 'display' => 'tar.bz2',
 203                 'type' => 'application/x-bzip2',
 204                 'suffix' => '.tar.bz2',
 205                 'format' => 'tar',
 206                 'compressor' => ['bzip2']},
 207
 208         'txz' => {
 209                 'display' => 'tar.xz',
 210                 'type' => 'application/x-xz',
 211                 'suffix' => '.tar.xz',
 212                 'format' => 'tar',
 213                 'compressor' => ['xz'],
 214                 'disabled' => 1},
 215
 216         'zip' => {
 217                 'display' => 'zip',
 218                 'type' => 'application/x-zip',
 219                 'suffix' => '.zip',
 220                 'format' => 'zip'},
 221 );
 222
 223 # Aliases so we understand old gitweb.snapshot values in repository
 224 # configuration.
 225 our %known_snapshot_format_aliases = (
 226         'gzip'  => 'tgz',
 227         'bzip2' => 'tbz2',
 228         'xz'    => 'txz',
 229
 230         # backward compatibility: legacy gitweb config support
 231         'x-gzip' => undef, 'gz' => undef,
 232         'x-bzip2' => undef, 'bz2' => undef,
 233         'x-zip' => undef, '' => undef,
 234 );
 235
 236 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 237 # are changed, it may be appropriate to change these values too via
 238 # $GITWEB_CONFIG.
 239 our %avatar_size = (
 240         'default' => 16,
 241         'double'  => 32
 242 );
 243
 244 # Used to set the maximum load that we will still respond to gitweb queries.
 245 # If server load exceed this value then return "503 server busy" error.
 246 # If gitweb cannot determined server load, it is taken to be 0.
 247 # Leave it undefined (or set to 'undef') to turn off load checking.
 248 our $maxload = 300;
 249
 250 # configuration for 'highlight' (http://www.andre-simon.de/)
 251 # match by basename
 252 our %highlight_basename = (
 253         #'Program' => 'py',
 254         #'Library' => 'py',
 255         'SConstruct' => 'py', # SCons equivalent of Makefile
 256         'Makefile' => 'make',
 257 );
 258 # match by extension
 259 our %highlight_ext = (
 260         # main extensions, defining name of syntax;
 261         # see files in /usr/share/highlight/langDefs/ directory
 262         map { $_ => $_ }
 263                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 264         # alternate extensions, see /etc/highlight/filetypes.conf
 265         'h' => 'c',
 266         map { $_ => 'sh'  } qw(bash zsh ksh),
 267         map { $_ => 'cpp' } qw(cxx c++ cc),
 268         map { $_ => 'php' } qw(php3 php4 php5 phps),
 269         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 270         map { $_ => 'make'} qw(mak mk),
 271         map { $_ => 'xml' } qw(xhtml html htm),
 272 );
 273
 274 # You define site-wide feature defaults here; override them with
 275 # $GITWEB_CONFIG as necessary.
 276 our %feature = (
 277         # feature => {
 278         #       'sub' => feature-sub (subroutine),
 279         #       'override' => allow-override (boolean),
 280         #       'default' => [ default options...] (array reference)}
 281         #
 282         # if feature is overridable (it means that allow-override has true value),
 283         # then feature-sub will be called with default options as parameters;
 284         # return value of feature-sub indicates if to enable specified feature
 285         #
 286         # if there is no 'sub' key (no feature-sub), then feature cannot be
 287         # overridden
 288         #
 289         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 290         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 291         # is enabled
 292
 293         # Enable the 'blame' blob view, showing the last commit that modified
 294         # each line in the file. This can be very CPU-intensive.
 295
 296         # To enable system wide have in $GITWEB_CONFIG
 297         # $feature{'blame'}{'default'} = [1];
 298         # To have project specific config enable override in $GITWEB_CONFIG
 299         # $feature{'blame'}{'override'} = 1;
 300         # and in project config gitweb.blame = 0|1;
 301         'blame' => {
 302                 'sub' => sub { feature_bool('blame', @_) },
 303                 'override' => 0,
 304                 'default' => [0]},
 305
 306         # Enable the 'snapshot' link, providing a compressed archive of any
 307         # tree. This can potentially generate high traffic if you have large
 308         # project.
 309
 310         # Value is a list of formats defined in %known_snapshot_formats that
 311         # you wish to offer.
 312         # To disable system wide have in $GITWEB_CONFIG
 313         # $feature{'snapshot'}{'default'} = [];
 314         # To have project specific config enable override in $GITWEB_CONFIG
 315         # $feature{'snapshot'}{'override'} = 1;
 316         # and in project config, a comma-separated list of formats or "none"
 317         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 318         'snapshot' => {
 319                 'sub' => \&feature_snapshot,
 320                 'override' => 0,
 321                 'default' => ['tgz']},
 322
 323         # Enable text search, which will list the commits which match author,
 324         # committer or commit text to a given string.  Enabled by default.
 325         # Project specific override is not supported.
 326         #
 327         # Note that this controls all search features, which means that if
 328         # it is disabled, then 'grep' and 'pickaxe' search would also be
 329         # disabled.
 330         'search' => {
 331                 'override' => 0,
 332                 'default' => [1]},
 333
 334         # Enable grep search, which will list the files in currently selected
 335         # tree containing the given string. Enabled by default. This can be
 336         # potentially CPU-intensive, of course.
 337         # Note that you need to have 'search' feature enabled too.
 338
 339         # To enable system wide have in $GITWEB_CONFIG
 340         # $feature{'grep'}{'default'} = [1];
 341         # To have project specific config enable override in $GITWEB_CONFIG
 342         # $feature{'grep'}{'override'} = 1;
 343         # and in project config gitweb.grep = 0|1;
 344         'grep' => {
 345                 'sub' => sub { feature_bool('grep', @_) },
 346                 'override' => 0,
 347                 'default' => [1]},
 348
 349         # Enable the pickaxe search, which will list the commits that modified
 350         # a given string in a file. This can be practical and quite faster
 351         # alternative to 'blame', but still potentially CPU-intensive.
 352         # Note that you need to have 'search' feature enabled too.
 353
 354         # To enable system wide have in $GITWEB_CONFIG
 355         # $feature{'pickaxe'}{'default'} = [1];
 356         # To have project specific config enable override in $GITWEB_CONFIG
 357         # $feature{'pickaxe'}{'override'} = 1;
 358         # and in project config gitweb.pickaxe = 0|1;
 359         'pickaxe' => {
 360                 'sub' => sub { feature_bool('pickaxe', @_) },
 361                 'override' => 0,
 362                 'default' => [1]},
 363
 364         # Enable showing size of blobs in a 'tree' view, in a separate
 365         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 366
 367         # To disable system wide have in $GITWEB_CONFIG
 368         # $feature{'show-sizes'}{'default'} = [0];
 369         # To have project specific config enable override in $GITWEB_CONFIG
 370         # $feature{'show-sizes'}{'override'} = 1;
 371         # and in project config gitweb.showsizes = 0|1;
 372         'show-sizes' => {
 373                 'sub' => sub { feature_bool('showsizes', @_) },
 374                 'override' => 0,
 375                 'default' => [1]},
 376
 377         # Make gitweb use an alternative format of the URLs which can be
 378         # more readable and natural-looking: project name is embedded
 379         # directly in the path and the query string contains other
 380         # auxiliary information. All gitweb installations recognize
 381         # URL in either format; this configures in which formats gitweb
 382         # generates links.
 383
 384         # To enable system wide have in $GITWEB_CONFIG
 385         # $feature{'pathinfo'}{'default'} = [1];
 386         # Project specific override is not supported.
 387
 388         # Note that you will need to change the default location of CSS,
 389         # favicon, logo and possibly other files to an absolute URL. Also,
 390         # if gitweb.cgi serves as your indexfile, you will need to force
 391         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 392         'pathinfo' => {
 393                 'override' => 0,
 394                 'default' => [0]},
 395
 396         # Make gitweb consider projects in project root subdirectories
 397         # to be forks of existing projects. Given project $projname.git,
 398         # projects matching $projname/*.git will not be shown in the main
 399         # projects list, instead a '+' mark will be added to $projname
 400         # there and a 'forks' view will be enabled for the project, listing
 401         # all the forks. If project list is taken from a file, forks have
 402         # to be listed after the main project.
 403
 404         # To enable system wide have in $GITWEB_CONFIG
 405         # $feature{'forks'}{'default'} = [1];
 406         # Project specific override is not supported.
 407         'forks' => {
 408                 'override' => 0,
 409                 'default' => [0]},
 410
 411         # Insert custom links to the action bar of all project pages.
 412         # This enables you mainly to link to third-party scripts integrating
 413         # into gitweb; e.g. git-browser for graphical history representation
 414         # or custom web-based repository administration interface.
 415
 416         # The 'default' value consists of a list of triplets in the form
 417         # (label, link, position) where position is the label after which
 418         # to insert the link and link is a format string where %n expands
 419         # to the project name, %f to the project path within the filesystem,
 420         # %h to the current hash (h gitweb parameter) and %b to the current
 421         # hash base (hb gitweb parameter); %% expands to %.
 422
 423         # To enable system wide have in $GITWEB_CONFIG e.g.
 424         # $feature{'actions'}{'default'} = [('graphiclog',
 425         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 426         # Project specific override is not supported.
 427         'actions' => {
 428                 'override' => 0,
 429                 'default' => []},
 430
 431         # Allow gitweb scan project content tags of project repository,
 432         # and display the popular Web 2.0-ish "tag cloud" near the projects
 433         # list.  Note that this is something COMPLETELY different from the
 434         # normal Git tags.
 435
 436         # gitweb by itself can show existing tags, but it does not handle
 437         # tagging itself; you need to do it externally, outside gitweb.
 438         # The format is described in git_get_project_ctags() subroutine.
 439         # You may want to install the HTML::TagCloud Perl module to get
 440         # a pretty tag cloud instead of just a list of tags.
 441
 442         # To enable system wide have in $GITWEB_CONFIG
 443         # $feature{'ctags'}{'default'} = [1];
 444         # Project specific override is not supported.
 445
 446         # In the future whether ctags editing is enabled might depend
 447         # on the value, but using 1 should always mean no editing of ctags.
 448         'ctags' => {
 449                 'override' => 0,
 450                 'default' => [0]},
 451
 452         # The maximum number of patches in a patchset generated in patch
 453         # view. Set this to 0 or undef to disable patch view, or to a
 454         # negative number to remove any limit.
 455
 456         # To disable system wide have in $GITWEB_CONFIG
 457         # $feature{'patches'}{'default'} = [0];
 458         # To have project specific config enable override in $GITWEB_CONFIG
 459         # $feature{'patches'}{'override'} = 1;
 460         # and in project config gitweb.patches = 0|n;
 461         # where n is the maximum number of patches allowed in a patchset.
 462         'patches' => {
 463                 'sub' => \&feature_patches,
 464                 'override' => 0,
 465                 'default' => [16]},
 466
 467         # Avatar support. When this feature is enabled, views such as
 468         # shortlog or commit will display an avatar associated with
 469         # the email of the committer(s) and/or author(s).
 470
 471         # Currently available providers are gravatar and picon.
 472         # If an unknown provider is specified, the feature is disabled.
 473
 474         # Gravatar depends on Digest::MD5.
 475         # Picon currently relies on the indiana.edu database.
 476
 477         # To enable system wide have in $GITWEB_CONFIG
 478         # $feature{'avatar'}{'default'} = ['<provider>'];
 479         # where <provider> is either gravatar or picon.
 480         # To have project specific config enable override in $GITWEB_CONFIG
 481         # $feature{'avatar'}{'override'} = 1;
 482         # and in project config gitweb.avatar = <provider>;
 483         'avatar' => {
 484                 'sub' => \&feature_avatar,
 485                 'override' => 0,
 486                 'default' => ['']},
 487
 488         # Enable displaying how much time and how many git commands
 489         # it took to generate and display page.  Disabled by default.
 490         # Project specific override is not supported.
 491         'timed' => {
 492                 'override' => 0,
 493                 'default' => [0]},
 494
 495         # Enable turning some links into links to actions which require
 496         # JavaScript to run (like 'blame_incremental').  Not enabled by
 497         # default.  Project specific override is currently not supported.
 498         'javascript-actions' => {
 499                 'override' => 0,
 500                 'default' => [0]},
 501
 502         # Enable and configure ability to change common timezone for dates
 503         # in gitweb output via JavaScript.  Enabled by default.
 504         # Project specific override is not supported.
 505         'javascript-timezone' => {
 506                 'override' => 0,
 507                 'default' => [
 508                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 509                                      # or undef to turn off this feature
 510                         'gitweb_tz', # name of cookie where to store selected timezone
 511                         'datetime',  # CSS class used to mark up dates for manipulation
 512                 ]},
 513
 514         # Syntax highlighting support. This is based on Daniel Svensson's
 515         # and Sham Chukoury's work in gitweb-xmms2.git.
 516         # It requires the 'highlight' program present in $PATH,
 517         # and therefore is disabled by default.
 518
 519         # To enable system wide have in $GITWEB_CONFIG
 520         # $feature{'highlight'}{'default'} = [1];
 521
 522         'highlight' => {
 523                 'sub' => sub { feature_bool('highlight', @_) },
 524                 'override' => 0,
 525                 'default' => [0]},
 526
 527         # Enable displaying of remote heads in the heads list
 528
 529         # To enable system wide have in $GITWEB_CONFIG
 530         # $feature{'remote_heads'}{'default'} = [1];
 531         # To have project specific config enable override in $GITWEB_CONFIG
 532         # $feature{'remote_heads'}{'override'} = 1;
 533         # and in project config gitweb.remote_heads = 0|1;
 534         'remote_heads' => {
 535                 'sub' => sub { feature_bool('remote_heads', @_) },
 536                 'override' => 0,
 537                 'default' => [0]},
 538 );
 539
 540 sub gitweb_get_feature {
 541         my ($name) = @_;
 542         return unless exists $feature{$name};
 543         my ($sub, $override, @defaults) = (
 544                 $feature{$name}{'sub'},
 545                 $feature{$name}{'override'},
 546                 @{$feature{$name}{'default'}});
 547         # project specific override is possible only if we have project
 548         our $git_dir; # global variable, declared later
 549         if (!$override || !defined $git_dir) {
 550                 return @defaults;
 551         }
 552         if (!defined $sub) {
 553                 warn "feature $name is not overridable";
 554                 return @defaults;
 555         }
 556         return $sub->(@defaults);
 557 }
 558
 559 # A wrapper to check if a given feature is enabled.
 560 # With this, you can say
 561 #
 562 #   my $bool_feat = gitweb_check_feature('bool_feat');
 563 #   gitweb_check_feature('bool_feat') or somecode;
 564 #
 565 # instead of
 566 #
 567 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 568 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 569 #
 570 sub gitweb_check_feature {
 571         return (gitweb_get_feature(@_))[0];
 572 }
 573
 574
 575 sub feature_bool {
 576         my $key = shift;
 577         my ($val) = git_get_project_config($key, '--bool');
 578
 579         if (!defined $val) {
 580                 return ($_[0]);
 581         } elsif ($val eq 'true') {
 582                 return (1);
 583         } elsif ($val eq 'false') {
 584                 return (0);
 585         }
 586 }
 587
 588 sub feature_snapshot {
 589         my (@fmts) = @_;
 590
 591         my ($val) = git_get_project_config('snapshot');
 592
 593         if ($val) {
 594                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 595         }
 596
 597         return @fmts;
 598 }
 599
 600 sub feature_patches {
 601         my @val = (git_get_project_config('patches', '--int'));
 602
 603         if (@val) {
 604                 return @val;
 605         }
 606
 607         return ($_[0]);
 608 }
 609
 610 sub feature_avatar {
 611         my @val = (git_get_project_config('avatar'));
 612
 613         return @val ? @val : @_;
 614 }
 615
 616 # checking HEAD file with -e is fragile if the repository was
 617 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 618 # and then pruned.
 619 sub check_head_link {
 620         my ($dir) = @_;
 621         my $headfile = "$dir/HEAD";
 622         return ((-e $headfile) ||
 623                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 624 }
 625
 626 sub check_export_ok {
 627         my ($dir) = @_;
 628         return (check_head_link($dir) &&
 629                 (!$export_ok || -e "$dir/$export_ok") &&
 630                 (!$export_auth_hook || $export_auth_hook->($dir)));
 631 }
 632
 633 # process alternate names for backward compatibility
 634 # filter out unsupported (unknown) snapshot formats
 635 sub filter_snapshot_fmts {
 636         my @fmts = @_;
 637
 638         @fmts = map {
 639                 exists $known_snapshot_format_aliases{$_} ?
 640                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 641         @fmts = grep {
 642                 exists $known_snapshot_formats{$_} &&
 643                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 644 }
 645
 646 # If it is set to code reference, it is code that it is to be run once per
 647 # request, allowing updating configurations that change with each request,
 648 # while running other code in config file only once.
 649 #
 650 # Otherwise, if it is false then gitweb would process config file only once;
 651 # if it is true then gitweb config would be run for each request.
 652 our $per_request_config = 1;
 653
 654 # read and parse gitweb config file given by its parameter.
 655 # returns true on success, false on recoverable error, allowing
 656 # to chain this subroutine, using first file that exists.
 657 # dies on errors during parsing config file, as it is unrecoverable.
 658 sub read_config_file {
 659         my $filename = shift;
 660         return unless defined $filename;
 661         # die if there are errors parsing config file
 662         if (-e $filename) {
 663                 do $filename;
 664                 die $@ if $@;
 665                 return 1;
 666         }
 667         return;
 668 }
 669
 670 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 671 sub evaluate_gitweb_config {
 672         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 673         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 674         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 675
 676         # Protect agains duplications of file names, to not read config twice.
 677         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 678         # there possibility of duplication of filename there doesn't matter.
 679         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 680         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 681
 682         # Common system-wide settings for convenience.
 683         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 684         read_config_file($GITWEB_CONFIG_COMMON);
 685
 686         # Use first config file that exists.  This means use the per-instance
 687         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 688         read_config_file($GITWEB_CONFIG) and return;
 689         read_config_file($GITWEB_CONFIG_SYSTEM);
 690 }
 691
 692 # Get loadavg of system, to compare against $maxload.
 693 # Currently it requires '/proc/loadavg' present to get loadavg;
 694 # if it is not present it returns 0, which means no load checking.
 695 sub get_loadavg {
 696         if( -e '/proc/loadavg' ){
 697                 open my $fd, '<', '/proc/loadavg'
 698                         or return 0;
 699                 my @load = split(/\s+/, scalar <$fd>);
 700                 close $fd;
 701
 702                 # The first three columns measure CPU and IO utilization of the last one,
 703                 # five, and 10 minute periods.  The fourth column shows the number of
 704                 # currently running processes and the total number of processes in the m/n
 705                 # format.  The last column displays the last process ID used.
 706                 return $load[0] || 0;
 707         }
 708         # additional checks for load average should go here for things that don't export
 709         # /proc/loadavg
 710
 711         return 0;
 712 }
 713
 714 # version of the core git binary
 715 our $git_version;
 716 sub evaluate_git_version {
 717         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 718         $number_of_git_cmds++;
 719 }
 720
 721 sub check_loadavg {
 722         if (defined $maxload && get_loadavg() > $maxload) {
 723                 die_error(503, "The load average on the server is too high");
 724         }
 725 }
 726
 727 # ======================================================================
 728 # input validation and dispatch
 729
 730 # input parameters can be collected from a variety of sources (presently, CGI
 731 # and PATH_INFO), so we define an %input_params hash that collects them all
 732 # together during validation: this allows subsequent uses (e.g. href()) to be
 733 # agnostic of the parameter origin
 734
 735 our %input_params = ();
 736
 737 # input parameters are stored with the long parameter name as key. This will
 738 # also be used in the href subroutine to convert parameters to their CGI
 739 # equivalent, and since the href() usage is the most frequent one, we store
 740 # the name -> CGI key mapping here, instead of the reverse.
 741 #
 742 # XXX: Warning: If you touch this, check the search form for updating,
 743 # too.
 744
 745 our @cgi_param_mapping = (
 746         project => "p",
 747         action => "a",
 748         file_name => "f",
 749         file_parent => "fp",
 750         hash => "h",
 751         hash_parent => "hp",
 752         hash_base => "hb",
 753         hash_parent_base => "hpb",
 754         page => "pg",
 755         order => "o",
 756         searchtext => "s",
 757         searchtype => "st",
 758         snapshot_format => "sf",
 759         extra_options => "opt",
 760         search_use_regexp => "sr",
 761         ctag => "by_tag",
 762         # this must be last entry (for manipulation from JavaScript)
 763         javascript => "js"
 764 );
 765 our %cgi_param_mapping = @cgi_param_mapping;
 766
 767 # we will also need to know the possible actions, for validation
 768 our %actions = (
 769         "blame" => \&git_blame,
 770         "blame_incremental" => \&git_blame_incremental,
 771         "blame_data" => \&git_blame_data,
 772         "blobdiff" => \&git_blobdiff,
 773         "blobdiff_plain" => \&git_blobdiff_plain,
 774         "blob" => \&git_blob,
 775         "blob_plain" => \&git_blob_plain,
 776         "commitdiff" => \&git_commitdiff,
 777         "commitdiff_plain" => \&git_commitdiff_plain,
 778         "commit" => \&git_commit,
 779         "forks" => \&git_forks,
 780         "heads" => \&git_heads,
 781         "history" => \&git_history,
 782         "log" => \&git_log,
 783         "patch" => \&git_patch,
 784         "patches" => \&git_patches,
 785         "remotes" => \&git_remotes,
 786         "rss" => \&git_rss,
 787         "atom" => \&git_atom,
 788         "search" => \&git_search,
 789         "search_help" => \&git_search_help,
 790         "shortlog" => \&git_shortlog,
 791         "summary" => \&git_summary,
 792         "tag" => \&git_tag,
 793         "tags" => \&git_tags,
 794         "tree" => \&git_tree,
 795         "snapshot" => \&git_snapshot,
 796         "object" => \&git_object,
 797         # those below don't need $project
 798         "opml" => \&git_opml,
 799         "project_list" => \&git_project_list,
 800         "project_index" => \&git_project_index,
 801 );
 802
 803 # finally, we have the hash of allowed extra_options for the commands that
 804 # allow them
 805 our %allowed_options = (
 806         "--no-merges" => [ qw(rss atom log shortlog history) ],
 807 );
 808
 809 # fill %input_params with the CGI parameters. All values except for 'opt'
 810 # should be single values, but opt can be an array. We should probably
 811 # build an array of parameters that can be multi-valued, but since for the time
 812 # being it's only this one, we just single it out
 813 sub evaluate_query_params {
 814         our $cgi;
 815
 816         while (my ($name, $symbol) = each %cgi_param_mapping) {
 817                 if ($symbol eq 'opt') {
 818                         $input_params{$name} = [ $cgi->param($symbol) ];
 819                 } else {
 820                         $input_params{$name} = $cgi->param($symbol);
 821                 }
 822         }
 823 }
 824
 825 # now read PATH_INFO and update the parameter list for missing parameters
 826 sub evaluate_path_info {
 827         return if defined $input_params{'project'};
 828         return if !$path_info;
 829         $path_info =~ s,^/+,,;
 830         return if !$path_info;
 831
 832         # find which part of PATH_INFO is project
 833         my $project = $path_info;
 834         $project =~ s,/+$,,;
 835         while ($project && !check_head_link("$projectroot/$project")) {
 836                 $project =~ s,/*[^/]*$,,;
 837         }
 838         return unless $project;
 839         $input_params{'project'} = $project;
 840
 841         # do not change any parameters if an action is given using the query string
 842         return if $input_params{'action'};
 843         $path_info =~ s,^\Q$project\E/*,,;
 844
 845         # next, check if we have an action
 846         my $action = $path_info;
 847         $action =~ s,/.*$,,;
 848         if (exists $actions{$action}) {
 849                 $path_info =~ s,^$action/*,,;
 850                 $input_params{'action'} = $action;
 851         }
 852
 853         # list of actions that want hash_base instead of hash, but can have no
 854         # pathname (f) parameter
 855         my @wants_base = (
 856                 'tree',
 857                 'history',
 858         );
 859
 860         # we want to catch, among others
 861         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 862         my ($parentrefname, $parentpathname, $refname, $pathname) =
 863                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 864
 865         # first, analyze the 'current' part
 866         if (defined $pathname) {
 867                 # we got "branch:filename" or "branch:dir/"
 868                 # we could use git_get_type(branch:pathname), but:
 869                 # - it needs $git_dir
 870                 # - it does a git() call
 871                 # - the convention of terminating directories with a slash
 872                 #   makes it superfluous
 873                 # - embedding the action in the PATH_INFO would make it even
 874                 #   more superfluous
 875                 $pathname =~ s,^/+,,;
 876                 if (!$pathname || substr($pathname, -1) eq "/") {
 877                         $input_params{'action'} ||= "tree";
 878                         $pathname =~ s,/$,,;
 879                 } else {
 880                         # the default action depends on whether we had parent info
 881                         # or not
 882                         if ($parentrefname) {
 883                                 $input_params{'action'} ||= "blobdiff_plain";
 884                         } else {
 885                                 $input_params{'action'} ||= "blob_plain";
 886                         }
 887                 }
 888                 $input_params{'hash_base'} ||= $refname;
 889                 $input_params{'file_name'} ||= $pathname;
 890         } elsif (defined $refname) {
 891                 # we got "branch". In this case we have to choose if we have to
 892                 # set hash or hash_base.
 893                 #
 894                 # Most of the actions without a pathname only want hash to be
 895                 # set, except for the ones specified in @wants_base that want
 896                 # hash_base instead. It should also be noted that hand-crafted
 897                 # links having 'history' as an action and no pathname or hash
 898                 # set will fail, but that happens regardless of PATH_INFO.
 899                 if (defined $parentrefname) {
 900                         # if there is parent let the default be 'shortlog' action
 901                         # (for http://git.example.com/repo.git/A..B links); if there
 902                         # is no parent, dispatch will detect type of object and set
 903                         # action appropriately if required (if action is not set)
 904                         $input_params{'action'} ||= "shortlog";
 905                 }
 906                 if ($input_params{'action'} &&
 907                     grep { $_ eq $input_params{'action'} } @wants_base) {
 908                         $input_params{'hash_base'} ||= $refname;
 909                 } else {
 910                         $input_params{'hash'} ||= $refname;
 911                 }
 912         }
 913
 914         # next, handle the 'parent' part, if present
 915         if (defined $parentrefname) {
 916                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 917                 # someproject/blobdiff/oldrev..newrev:/filename
 918                 if ($parentpathname) {
 919                         $parentpathname =~ s,^/+,,;
 920                         $parentpathname =~ s,/$,,;
 921                         $input_params{'file_parent'} ||= $parentpathname;
 922                 } else {
 923                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 924                 }
 925                 # we assume that hash_parent_base is wanted if a path was specified,
 926                 # or if the action wants hash_base instead of hash
 927                 if (defined $input_params{'file_parent'} ||
 928                         grep { $_ eq $input_params{'action'} } @wants_base) {
 929                         $input_params{'hash_parent_base'} ||= $parentrefname;
 930                 } else {
 931                         $input_params{'hash_parent'} ||= $parentrefname;
 932                 }
 933         }
 934
 935         # for the snapshot action, we allow URLs in the form
 936         # $project/snapshot/$hash.ext
 937         # where .ext determines the snapshot and gets removed from the
 938         # passed $refname to provide the $hash.
 939         #
 940         # To be able to tell that $refname includes the format extension, we
 941         # require the following two conditions to be satisfied:
 942         # - the hash input parameter MUST have been set from the $refname part
 943         #   of the URL (i.e. they must be equal)
 944         # - the snapshot format MUST NOT have been defined already (e.g. from
 945         #   CGI parameter sf)
 946         # It's also useless to try any matching unless $refname has a dot,
 947         # so we check for that too
 948         if (defined $input_params{'action'} &&
 949                 $input_params{'action'} eq 'snapshot' &&
 950                 defined $refname && index($refname, '.') != -1 &&
 951                 $refname eq $input_params{'hash'} &&
 952                 !defined $input_params{'snapshot_format'}) {
 953                 # We loop over the known snapshot formats, checking for
 954                 # extensions. Allowed extensions are both the defined suffix
 955                 # (which includes the initial dot already) and the snapshot
 956                 # format key itself, with a prepended dot
 957                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 958                         my $hash = $refname;
 959                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 960                                 next;
 961                         }
 962                         my $sfx = $1;
 963                         # a valid suffix was found, so set the snapshot format
 964                         # and reset the hash parameter
 965                         $input_params{'snapshot_format'} = $fmt;
 966                         $input_params{'hash'} = $hash;
 967                         # we also set the format suffix to the one requested
 968                         # in the URL: this way a request for e.g. .tgz returns
 969                         # a .tgz instead of a .tar.gz
 970                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 971                         last;
 972                 }
 973         }
 974 }
 975
 976 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 977      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 978      $searchtext, $search_regexp);
 979 sub evaluate_and_validate_params {
 980         our $action = $input_params{'action'};
 981         if (defined $action) {
 982                 if (!validate_action($action)) {
 983                         die_error(400, "Invalid action parameter");
 984                 }
 985         }
 986
 987         # parameters which are pathnames
 988         our $project = $input_params{'project'};
 989         if (defined $project) {
 990                 if (!validate_project($project)) {
 991                         undef $project;
 992                         die_error(404, "No such project");
 993                 }
 994         }
 995
 996         our $file_name = $input_params{'file_name'};
 997         if (defined $file_name) {
 998                 if (!validate_pathname($file_name)) {
 999                         die_error(400, "Invalid file parameter");
1000                 }
1001         }
1002
1003         our $file_parent = $input_params{'file_parent'};
1004         if (defined $file_parent) {
1005                 if (!validate_pathname($file_parent)) {
1006                         die_error(400, "Invalid file parent parameter");
1007                 }
1008         }
1009
1010         # parameters which are refnames
1011         our $hash = $input_params{'hash'};
1012         if (defined $hash) {
1013                 if (!validate_refname($hash)) {
1014                         die_error(400, "Invalid hash parameter");
1015                 }
1016         }
1017
1018         our $hash_parent = $input_params{'hash_parent'};
1019         if (defined $hash_parent) {
1020                 if (!validate_refname($hash_parent)) {
1021                         die_error(400, "Invalid hash parent parameter");
1022                 }
1023         }
1024
1025         our $hash_base = $input_params{'hash_base'};
1026         if (defined $hash_base) {
1027                 if (!validate_refname($hash_base)) {
1028                         die_error(400, "Invalid hash base parameter");
1029                 }
1030         }
1031
1032         our @extra_options = @{$input_params{'extra_options'}};
1033         # @extra_options is always defined, since it can only be (currently) set from
1034         # CGI, and $cgi->param() returns the empty array in array context if the param
1035         # is not set
1036         foreach my $opt (@extra_options) {
1037                 if (not exists $allowed_options{$opt}) {
1038                         die_error(400, "Invalid option parameter");
1039                 }
1040                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1041                         die_error(400, "Invalid option parameter for this action");
1042                 }
1043         }
1044
1045         our $hash_parent_base = $input_params{'hash_parent_base'};
1046         if (defined $hash_parent_base) {
1047                 if (!validate_refname($hash_parent_base)) {
1048                         die_error(400, "Invalid hash parent base parameter");
1049                 }
1050         }
1051
1052         # other parameters
1053         our $page = $input_params{'page'};
1054         if (defined $page) {
1055                 if ($page =~ m/[^0-9]/) {
1056                         die_error(400, "Invalid page parameter");
1057                 }
1058         }
1059
1060         our $searchtype = $input_params{'searchtype'};
1061         if (defined $searchtype) {
1062                 if ($searchtype =~ m/[^a-z]/) {
1063                         die_error(400, "Invalid searchtype parameter");
1064                 }
1065         }
1066
1067         our $search_use_regexp = $input_params{'search_use_regexp'};
1068
1069         our $searchtext = $input_params{'searchtext'};
1070         our $search_regexp;
1071         if (defined $searchtext) {
1072                 if (length($searchtext) < 2) {
1073                         die_error(403, "At least two characters are required for search parameter");
1074                 }
1075                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1076         }
1077 }
1078
1079 # path to the current git repository
1080 our $git_dir;
1081 sub evaluate_git_dir {
1082         our $git_dir = "$projectroot/$project" if $project;
1083 }
1084
1085 our (@snapshot_fmts, $git_avatar);
1086 sub configure_gitweb_features {
1087         # list of supported snapshot formats
1088         our @snapshot_fmts = gitweb_get_feature('snapshot');
1089         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1090
1091         # check that the avatar feature is set to a known provider name,
1092         # and for each provider check if the dependencies are satisfied.
1093         # if the provider name is invalid or the dependencies are not met,
1094         # reset $git_avatar to the empty string.
1095         our ($git_avatar) = gitweb_get_feature('avatar');
1096         if ($git_avatar eq 'gravatar') {
1097                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1098         } elsif ($git_avatar eq 'picon') {
1099                 # no dependencies
1100         } else {
1101                 $git_avatar = '';
1102         }
1103 }
1104
1105 # custom error handler: 'die <message>' is Internal Server Error
1106 sub handle_errors_html {
1107         my $msg = shift; # it is already HTML escaped
1108
1109         # to avoid infinite loop where error occurs in die_error,
1110         # change handler to default handler, disabling handle_errors_html
1111         set_message("Error occured when inside die_error:\n$msg");
1112
1113         # you cannot jump out of die_error when called as error handler;
1114         # the subroutine set via CGI::Carp::set_message is called _after_
1115         # HTTP headers are already written, so it cannot write them itself
1116         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1117 }
1118 set_message(\&handle_errors_html);
1119
1120 # dispatch
1121 sub dispatch {
1122         if (!defined $action) {
1123                 if (defined $hash) {
1124                         $action = git_get_type($hash);
1125                 } elsif (defined $hash_base && defined $file_name) {
1126                         $action = git_get_type("$hash_base:$file_name");
1127                 } elsif (defined $project) {
1128                         $action = 'summary';
1129                 } else {
1130                         $action = 'project_list';
1131                 }
1132         }
1133         if (!defined($actions{$action})) {
1134                 die_error(400, "Unknown action");
1135         }
1136         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1137             !$project) {
1138                 die_error(400, "Project needed");
1139         }
1140         $actions{$action}->();
1141 }
1142
1143 sub reset_timer {
1144         our $t0 = [ gettimeofday() ]
1145                 if defined $t0;
1146         our $number_of_git_cmds = 0;
1147 }
1148
1149 our $first_request = 1;
1150 sub run_request {
1151         reset_timer();
1152
1153         evaluate_uri();
1154         if ($first_request) {
1155                 evaluate_gitweb_config();
1156                 evaluate_git_version();
1157         }
1158         if ($per_request_config) {
1159                 if (ref($per_request_config) eq 'CODE') {
1160                         $per_request_config->();
1161                 } elsif (!$first_request) {
1162                         evaluate_gitweb_config();
1163                 }
1164         }
1165         check_loadavg();
1166
1167         # $projectroot and $projects_list might be set in gitweb config file
1168         $projects_list ||= $projectroot;
1169
1170         evaluate_query_params();
1171         evaluate_path_info();
1172         evaluate_and_validate_params();
1173         evaluate_git_dir();
1174
1175         configure_gitweb_features();
1176
1177         dispatch();
1178 }
1179
1180 our $is_last_request = sub { 1 };
1181 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1182 our $CGI = 'CGI';
1183 our $cgi;
1184 sub configure_as_fcgi {
1185         require CGI::Fast;
1186         our $CGI = 'CGI::Fast';
1187
1188         my $request_number = 0;
1189         # let each child service 100 requests
1190         our $is_last_request = sub { ++$request_number > 100 };
1191 }
1192 sub evaluate_argv {
1193         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1194         configure_as_fcgi()
1195                 if $script_name =~ /\.fcgi$/;
1196
1197         return unless (@ARGV);
1198
1199         require Getopt::Long;
1200         Getopt::Long::GetOptions(
1201                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1202                 'nproc|n=i' => sub {
1203                         my ($arg, $val) = @_;
1204                         return unless eval { require FCGI::ProcManager; 1; };
1205                         my $proc_manager = FCGI::ProcManager->new({
1206                                 n_processes => $val,
1207                         });
1208                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1209                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1210                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1211                 },
1212         );
1213 }
1214
1215 sub run {
1216         evaluate_argv();
1217
1218         $first_request = 1;
1219         $pre_listen_hook->()
1220                 if $pre_listen_hook;
1221
1222  REQUEST:
1223         while ($cgi = $CGI->new()) {
1224                 $pre_dispatch_hook->()
1225                         if $pre_dispatch_hook;
1226
1227                 run_request();
1228
1229                 $post_dispatch_hook->()
1230                         if $post_dispatch_hook;
1231                 $first_request = 0;
1232
1233                 last REQUEST if ($is_last_request->());
1234         }
1235
1236  DONE_GITWEB:
1237         1;
1238 }
1239
1240 run();
1241
1242 if (defined caller) {
1243         # wrapped in a subroutine processing requests,
1244         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1245         return;
1246 } else {
1247         # pure CGI script, serving single request
1248         exit;
1249 }
1250
1251 ## ======================================================================
1252 ## action links
1253
1254 # possible values of extra options
1255 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1256 # -replay => 1      - start from a current view (replay with modifications)
1257 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1258 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1259 sub href {
1260         my %params = @_;
1261         # default is to use -absolute url() i.e. $my_uri
1262         my $href = $params{-full} ? $my_url : $my_uri;
1263
1264         # implicit -replay, must be first of implicit params
1265         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1266
1267         $params{'project'} = $project unless exists $params{'project'};
1268
1269         if ($params{-replay}) {
1270                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1271                         if (!exists $params{$name}) {
1272                                 $params{$name} = $input_params{$name};
1273                         }
1274                 }
1275         }
1276
1277         my $use_pathinfo = gitweb_check_feature('pathinfo');
1278         if (defined $params{'project'} &&
1279             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1280                 # try to put as many parameters as possible in PATH_INFO:
1281                 #   - project name
1282                 #   - action
1283                 #   - hash_parent or hash_parent_base:/file_parent
1284                 #   - hash or hash_base:/filename
1285                 #   - the snapshot_format as an appropriate suffix
1286
1287                 # When the script is the root DirectoryIndex for the domain,
1288                 # $href here would be something like http://gitweb.example.com/
1289                 # Thus, we strip any trailing / from $href, to spare us double
1290                 # slashes in the final URL
1291                 $href =~ s,/$,,;
1292
1293                 # Then add the project name, if present
1294                 $href .= "/".esc_path_info($params{'project'});
1295                 delete $params{'project'};
1296
1297                 # since we destructively absorb parameters, we keep this
1298                 # boolean that remembers if we're handling a snapshot
1299                 my $is_snapshot = $params{'action'} eq 'snapshot';
1300
1301                 # Summary just uses the project path URL, any other action is
1302                 # added to the URL
1303                 if (defined $params{'action'}) {
1304                         $href .= "/".esc_path_info($params{'action'})
1305                                 unless $params{'action'} eq 'summary';
1306                         delete $params{'action'};
1307                 }
1308
1309                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1310                 # stripping nonexistent or useless pieces
1311                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1312                         || $params{'hash_parent'} || $params{'hash'});
1313                 if (defined $params{'hash_base'}) {
1314                         if (defined $params{'hash_parent_base'}) {
1315                                 $href .= esc_path_info($params{'hash_parent_base'});
1316                                 # skip the file_parent if it's the same as the file_name
1317                                 if (defined $params{'file_parent'}) {
1318                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1319                                                 delete $params{'file_parent'};
1320                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1321                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1322                                                 delete $params{'file_parent'};
1323                                         }
1324                                 }
1325                                 $href .= "..";
1326                                 delete $params{'hash_parent'};
1327                                 delete $params{'hash_parent_base'};
1328                         } elsif (defined $params{'hash_parent'}) {
1329                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1330                                 delete $params{'hash_parent'};
1331                         }
1332
1333                         $href .= esc_path_info($params{'hash_base'});
1334                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1335                                 $href .= ":/".esc_path_info($params{'file_name'});
1336                                 delete $params{'file_name'};
1337                         }
1338                         delete $params{'hash'};
1339                         delete $params{'hash_base'};
1340                 } elsif (defined $params{'hash'}) {
1341                         $href .= esc_path_info($params{'hash'});
1342                         delete $params{'hash'};
1343                 }
1344
1345                 # If the action was a snapshot, we can absorb the
1346                 # snapshot_format parameter too
1347                 if ($is_snapshot) {
1348                         my $fmt = $params{'snapshot_format'};
1349                         # snapshot_format should always be defined when href()
1350                         # is called, but just in case some code forgets, we
1351                         # fall back to the default
1352                         $fmt ||= $snapshot_fmts[0];
1353                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1354                         delete $params{'snapshot_format'};
1355                 }
1356         }
1357
1358         # now encode the parameters explicitly
1359         my @result = ();
1360         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1361                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1362                 if (defined $params{$name}) {
1363                         if (ref($params{$name}) eq "ARRAY") {
1364                                 foreach my $par (@{$params{$name}}) {
1365                                         push @result, $symbol . "=" . esc_param($par);
1366                                 }
1367                         } else {
1368                                 push @result, $symbol . "=" . esc_param($params{$name});
1369                         }
1370                 }
1371         }
1372         $href .= "?" . join(';', @result) if scalar @result;
1373
1374         # final transformation: trailing spaces must be escaped (URI-encoded)
1375         $href =~ s/(\s+)$/CGI::escape($1)/e;
1376
1377         if ($params{-anchor}) {
1378                 $href .= "#".esc_param($params{-anchor});
1379         }
1380
1381         return $href;
1382 }
1383
1384
1385 ## ======================================================================
1386 ## validation, quoting/unquoting and escaping
1387
1388 sub validate_action {
1389         my $input = shift || return undef;
1390         return undef unless exists $actions{$input};
1391         return $input;
1392 }
1393
1394 sub validate_project {
1395         my $input = shift || return undef;
1396         if (!validate_pathname($input) ||
1397                 !(-d "$projectroot/$input") ||
1398                 !check_export_ok("$projectroot/$input") ||
1399                 ($strict_export && !project_in_list($input))) {
1400                 return undef;
1401         } else {
1402                 return $input;
1403         }
1404 }
1405
1406 sub validate_pathname {
1407         my $input = shift || return undef;
1408
1409         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1410         # at the beginning, at the end, and between slashes.
1411         # also this catches doubled slashes
1412         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1413                 return undef;
1414         }
1415         # no null characters
1416         if ($input =~ m!\0!) {
1417                 return undef;
1418         }
1419         return $input;
1420 }
1421
1422 sub validate_refname {
1423         my $input = shift || return undef;
1424
1425         # textual hashes are O.K.
1426         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1427                 return $input;
1428         }
1429         # it must be correct pathname
1430         $input = validate_pathname($input)
1431                 or return undef;
1432         # restrictions on ref name according to git-check-ref-format
1433         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1434                 return undef;
1435         }
1436         return $input;
1437 }
1438
1439 # decode sequences of octets in utf8 into Perl's internal form,
1440 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1441 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1442 sub to_utf8 {
1443         my $str = shift;
1444         return undef unless defined $str;
1445         if (utf8::valid($str)) {
1446                 utf8::decode($str);
1447                 return $str;
1448         } else {
1449                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1450         }
1451 }
1452
1453 # quote unsafe chars, but keep the slash, even when it's not
1454 # correct, but quoted slashes look too horrible in bookmarks
1455 sub esc_param {
1456         my $str = shift;
1457         return undef unless defined $str;
1458         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1459         $str =~ s/ /\+/g;
1460         return $str;
1461 }
1462
1463 # the quoting rules for path_info fragment are slightly different
1464 sub esc_path_info {
1465         my $str = shift;
1466         return undef unless defined $str;
1467
1468         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1469         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1470
1471         return $str;
1472 }
1473
1474 # quote unsafe chars in whole URL, so some characters cannot be quoted
1475 sub esc_url {
1476         my $str = shift;
1477         return undef unless defined $str;
1478         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1479         $str =~ s/ /\+/g;
1480         return $str;
1481 }
1482
1483 # quote unsafe characters in HTML attributes
1484 sub esc_attr {
1485
1486         # for XHTML conformance escaping '"' to '&quot;' is not enough
1487         return esc_html(@_);
1488 }
1489
1490 # replace invalid utf8 character with SUBSTITUTION sequence
1491 sub esc_html {
1492         my $str = shift;
1493         my %opts = @_;
1494
1495         return undef unless defined $str;
1496
1497         $str = to_utf8($str);
1498         $str = $cgi->escapeHTML($str);
1499         if ($opts{'-nbsp'}) {
1500                 $str =~ s/ /&nbsp;/g;
1501         }
1502         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1503         return $str;
1504 }
1505
1506 # quote control characters and escape filename to HTML
1507 sub esc_path {
1508         my $str = shift;
1509         my %opts = @_;
1510
1511         return undef unless defined $str;
1512
1513         $str = to_utf8($str);
1514         $str = $cgi->escapeHTML($str);
1515         if ($opts{'-nbsp'}) {
1516                 $str =~ s/ /&nbsp;/g;
1517         }
1518         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1519         return $str;
1520 }
1521
1522 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1523 sub sanitize {
1524         my $str = shift;
1525
1526         return undef unless defined $str;
1527
1528         $str = to_utf8($str);
1529         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1530         return $str;
1531 }
1532
1533 # Make control characters "printable", using character escape codes (CEC)
1534 sub quot_cec {
1535         my $cntrl = shift;
1536         my %opts = @_;
1537         my %es = ( # character escape codes, aka escape sequences
1538                 "\t" => '\t',   # tab            (HT)
1539                 "\n" => '\n',   # line feed      (LF)
1540                 "\r" => '\r',   # carrige return (CR)
1541                 "\f" => '\f',   # form feed      (FF)
1542                 "\b" => '\b',   # backspace      (BS)
1543                 "\a" => '\a',   # alarm (bell)   (BEL)
1544                 "\e" => '\e',   # escape         (ESC)
1545                 "\013" => '\v', # vertical tab   (VT)
1546                 "\000" => '\0', # nul character  (NUL)
1547         );
1548         my $chr = ( (exists $es{$cntrl})
1549                     ? $es{$cntrl}
1550                     : sprintf('\%2x', ord($cntrl)) );
1551         if ($opts{-nohtml}) {
1552                 return $chr;
1553         } else {
1554                 return "<span class=\"cntrl\">$chr</span>";
1555         }
1556 }
1557
1558 # Alternatively use unicode control pictures codepoints,
1559 # Unicode "printable representation" (PR)
1560 sub quot_upr {
1561         my $cntrl = shift;
1562         my %opts = @_;
1563
1564         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1565         if ($opts{-nohtml}) {
1566                 return $chr;
1567         } else {
1568                 return "<span class=\"cntrl\">$chr</span>";
1569         }
1570 }
1571
1572 # git may return quoted and escaped filenames
1573 sub unquote {
1574         my $str = shift;
1575
1576         sub unq {
1577                 my $seq = shift;
1578                 my %es = ( # character escape codes, aka escape sequences
1579                         't' => "\t",   # tab            (HT, TAB)
1580                         'n' => "\n",   # newline        (NL)
1581                         'r' => "\r",   # return         (CR)
1582                         'f' => "\f",   # form feed      (FF)
1583                         'b' => "\b",   # backspace      (BS)
1584                         'a' => "\a",   # alarm (bell)   (BEL)
1585                         'e' => "\e",   # escape         (ESC)
1586                         'v' => "\013", # vertical tab   (VT)
1587                 );
1588
1589                 if ($seq =~ m/^[0-7]{1,3}$/) {
1590                         # octal char sequence
1591                         return chr(oct($seq));
1592                 } elsif (exists $es{$seq}) {
1593                         # C escape sequence, aka character escape code
1594                         return $es{$seq};
1595                 }
1596                 # quoted ordinary character
1597                 return $seq;
1598         }
1599
1600         if ($str =~ m/^"(.*)"$/) {
1601                 # needs unquoting
1602                 $str = $1;
1603                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1604         }
1605         return $str;
1606 }
1607
1608 # escape tabs (convert tabs to spaces)
1609 sub untabify {
1610         my $line = shift;
1611
1612         while ((my $pos = index($line, "\t")) != -1) {
1613                 if (my $count = (8 - ($pos % 8))) {
1614                         my $spaces = ' ' x $count;
1615                         $line =~ s/\t/$spaces/;
1616                 }
1617         }
1618
1619         return $line;
1620 }
1621
1622 sub project_in_list {
1623         my $project = shift;
1624         my @list = git_get_projects_list();
1625         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1626 }
1627
1628 ## ----------------------------------------------------------------------
1629 ## HTML aware string manipulation
1630
1631 # Try to chop given string on a word boundary between position
1632 # $len and $len+$add_len. If there is no word boundary there,
1633 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1634 # (marking chopped part) would be longer than given string.
1635 sub chop_str {
1636         my $str = shift;
1637         my $len = shift;
1638         my $add_len = shift || 10;
1639         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1640
1641         # Make sure perl knows it is utf8 encoded so we don't
1642         # cut in the middle of a utf8 multibyte char.
1643         $str = to_utf8($str);
1644
1645         # allow only $len chars, but don't cut a word if it would fit in $add_len
1646         # if it doesn't fit, cut it if it's still longer than the dots we would add
1647         # remove chopped character entities entirely
1648
1649         # when chopping in the middle, distribute $len into left and right part
1650         # return early if chopping wouldn't make string shorter
1651         if ($where eq 'center') {
1652                 return $str if ($len + 5 >= length($str)); # filler is length 5
1653                 $len = int($len/2);
1654         } else {
1655                 return $str if ($len + 4 >= length($str)); # filler is length 4
1656         }
1657
1658         # regexps: ending and beginning with word part up to $add_len
1659         my $endre = qr/.{$len}\w{0,$add_len}/;
1660         my $begre = qr/\w{0,$add_len}.{$len}/;
1661
1662         if ($where eq 'left') {
1663                 $str =~ m/^(.*?)($begre)$/;
1664                 my ($lead, $body) = ($1, $2);
1665                 if (length($lead) > 4) {
1666                         $lead = " ...";
1667                 }
1668                 return "$lead$body";
1669
1670         } elsif ($where eq 'center') {
1671                 $str =~ m/^($endre)(.*)$/;
1672                 my ($left, $str)  = ($1, $2);
1673                 $str =~ m/^(.*?)($begre)$/;
1674                 my ($mid, $right) = ($1, $2);
1675                 if (length($mid) > 5) {
1676                         $mid = " ... ";
1677                 }
1678                 return "$left$mid$right";
1679
1680         } else {
1681                 $str =~ m/^($endre)(.*)$/;
1682                 my $body = $1;
1683                 my $tail = $2;
1684                 if (length($tail) > 4) {
1685                         $tail = "... ";
1686                 }
1687                 return "$body$tail";
1688         }
1689 }
1690
1691 # takes the same arguments as chop_str, but also wraps a <span> around the
1692 # result with a title attribute if it does get chopped. Additionally, the
1693 # string is HTML-escaped.
1694 sub chop_and_escape_str {
1695         my ($str) = @_;
1696
1697         my $chopped = chop_str(@_);
1698         if ($chopped eq $str) {
1699                 return esc_html($chopped);
1700         } else {
1701                 $str =~ s/[[:cntrl:]]/?/g;
1702                 return $cgi->span({-title=>$str}, esc_html($chopped));
1703         }
1704 }
1705
1706 ## ----------------------------------------------------------------------
1707 ## functions returning short strings
1708
1709 # CSS class for given age value (in seconds)
1710 sub age_class {
1711         my $age = shift;
1712
1713         if (!defined $age) {
1714                 return "noage";
1715         } elsif ($age < 60*60*2) {
1716                 return "age0";
1717         } elsif ($age < 60*60*24*2) {
1718                 return "age1";
1719         } else {
1720                 return "age2";
1721         }
1722 }
1723
1724 # convert age in seconds to "nn units ago" string
1725 sub age_string {
1726         my $age = shift;
1727         my $age_str;
1728
1729         if ($age > 60*60*24*365*2) {
1730                 $age_str = (int $age/60/60/24/365);
1731                 $age_str .= " years ago";
1732         } elsif ($age > 60*60*24*(365/12)*2) {
1733                 $age_str = int $age/60/60/24/(365/12);
1734                 $age_str .= " months ago";
1735         } elsif ($age > 60*60*24*7*2) {
1736                 $age_str = int $age/60/60/24/7;
1737                 $age_str .= " weeks ago";
1738         } elsif ($age > 60*60*24*2) {
1739                 $age_str = int $age/60/60/24;
1740                 $age_str .= " days ago";
1741         } elsif ($age > 60*60*2) {
1742                 $age_str = int $age/60/60;
1743                 $age_str .= " hours ago";
1744         } elsif ($age > 60*2) {
1745                 $age_str = int $age/60;
1746                 $age_str .= " min ago";
1747         } elsif ($age > 2) {
1748                 $age_str = int $age;
1749                 $age_str .= " sec ago";
1750         } else {
1751                 $age_str .= " right now";
1752         }
1753         return $age_str;
1754 }
1755
1756 use constant {
1757         S_IFINVALID => 0030000,
1758         S_IFGITLINK => 0160000,
1759 };
1760
1761 # submodule/subproject, a commit object reference
1762 sub S_ISGITLINK {
1763         my $mode = shift;
1764
1765         return (($mode & S_IFMT) == S_IFGITLINK)
1766 }
1767
1768 # convert file mode in octal to symbolic file mode string
1769 sub mode_str {
1770         my $mode = oct shift;
1771
1772         if (S_ISGITLINK($mode)) {
1773                 return 'm---------';
1774         } elsif (S_ISDIR($mode & S_IFMT)) {
1775                 return 'drwxr-xr-x';
1776         } elsif (S_ISLNK($mode)) {
1777                 return 'lrwxrwxrwx';
1778         } elsif (S_ISREG($mode)) {
1779                 # git cares only about the executable bit
1780                 if ($mode & S_IXUSR) {
1781                         return '-rwxr-xr-x';
1782                 } else {
1783                         return '-rw-r--r--';
1784                 };
1785         } else {
1786                 return '----------';
1787         }
1788 }
1789
1790 # convert file mode in octal to file type string
1791 sub file_type {
1792         my $mode = shift;
1793
1794         if ($mode !~ m/^[0-7]+$/) {
1795                 return $mode;
1796         } else {
1797                 $mode = oct $mode;
1798         }
1799
1800         if (S_ISGITLINK($mode)) {
1801                 return "submodule";
1802         } elsif (S_ISDIR($mode & S_IFMT)) {
1803                 return "directory";
1804         } elsif (S_ISLNK($mode)) {
1805                 return "symlink";
1806         } elsif (S_ISREG($mode)) {
1807                 return "file";
1808         } else {
1809                 return "unknown";
1810         }
1811 }
1812
1813 # convert file mode in octal to file type description string
1814 sub file_type_long {
1815         my $mode = shift;
1816
1817         if ($mode !~ m/^[0-7]+$/) {
1818                 return $mode;
1819         } else {
1820                 $mode = oct $mode;
1821         }
1822
1823         if (S_ISGITLINK($mode)) {
1824                 return "submodule";
1825         } elsif (S_ISDIR($mode & S_IFMT)) {
1826                 return "directory";
1827         } elsif (S_ISLNK($mode)) {
1828                 return "symlink";
1829         } elsif (S_ISREG($mode)) {
1830                 if ($mode & S_IXUSR) {
1831                         return "executable";
1832                 } else {
1833                         return "file";
1834                 };
1835         } else {
1836                 return "unknown";
1837         }
1838 }
1839
1840
1841 ## ----------------------------------------------------------------------
1842 ## functions returning short HTML fragments, or transforming HTML fragments
1843 ## which don't belong to other sections
1844
1845 # format line of commit message.
1846 sub format_log_line_html {
1847         my $line = shift;
1848
1849         $line = esc_html($line, -nbsp=>1);
1850         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1851                 $cgi->a({-href => href(action=>"object", hash=>$1),
1852                                         -class => "text"}, $1);
1853         }eg;
1854
1855         return $line;
1856 }
1857
1858 # format marker of refs pointing to given object
1859
1860 # the destination action is chosen based on object type and current context:
1861 # - for annotated tags, we choose the tag view unless it's the current view
1862 #   already, in which case we go to shortlog view
1863 # - for other refs, we keep the current view if we're in history, shortlog or
1864 #   log view, and select shortlog otherwise
1865 sub format_ref_marker {
1866         my ($refs, $id) = @_;
1867         my $markers = '';
1868
1869         if (defined $refs->{$id}) {
1870                 foreach my $ref (@{$refs->{$id}}) {
1871                         # this code exploits the fact that non-lightweight tags are the
1872                         # only indirect objects, and that they are the only objects for which
1873                         # we want to use tag instead of shortlog as action
1874                         my ($type, $name) = qw();
1875                         my $indirect = ($ref =~ s/\^\{\}$//);
1876                         # e.g. tags/v2.6.11 or heads/next
1877                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1878                                 $type = $1;
1879                                 $name = $2;
1880                         } else {
1881                                 $type = "ref";
1882                                 $name = $ref;
1883                         }
1884
1885                         my $class = $type;
1886                         $class .= " indirect" if $indirect;
1887
1888                         my $dest_action = "shortlog";
1889
1890                         if ($indirect) {
1891                                 $dest_action = "tag" unless $action eq "tag";
1892                         } elsif ($action =~ /^(history|(short)?log)$/) {
1893                                 $dest_action = $action;
1894                         }
1895
1896                         my $dest = "";
1897                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1898                         $dest .= $ref;
1899
1900                         my $link = $cgi->a({
1901                                 -href => href(
1902                                         action=>$dest_action,
1903                                         hash=>$dest
1904                                 )}, $name);
1905
1906                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1907                                 $link . "</span>";
1908                 }
1909         }
1910
1911         if ($markers) {
1912                 return ' <span class="refs">'. $markers . '</span>';
1913         } else {
1914                 return "";
1915         }
1916 }
1917
1918 # format, perhaps shortened and with markers, title line
1919 sub format_subject_html {
1920         my ($long, $short, $href, $extra) = @_;
1921         $extra = '' unless defined($extra);
1922
1923         if (length($short) < length($long)) {
1924                 $long =~ s/[[:cntrl:]]/?/g;
1925                 return $cgi->a({-href => $href, -class => "list subject",
1926                                 -title => to_utf8($long)},
1927                        esc_html($short)) . $extra;
1928         } else {
1929                 return $cgi->a({-href => $href, -class => "list subject"},
1930                        esc_html($long)) . $extra;
1931         }
1932 }
1933
1934 # Rather than recomputing the url for an email multiple times, we cache it
1935 # after the first hit. This gives a visible benefit in views where the avatar
1936 # for the same email is used repeatedly (e.g. shortlog).
1937 # The cache is shared by all avatar engines (currently gravatar only), which
1938 # are free to use it as preferred. Since only one avatar engine is used for any
1939 # given page, there's no risk for cache conflicts.
1940 our %avatar_cache = ();
1941
1942 # Compute the picon url for a given email, by using the picon search service over at
1943 # http://www.cs.indiana.edu/picons/search.html
1944 sub picon_url {
1945         my $email = lc shift;
1946         if (!$avatar_cache{$email}) {
1947                 my ($user, $domain) = split('@', $email);
1948                 $avatar_cache{$email} =
1949                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1950                         "$domain/$user/" .
1951                         "users+domains+unknown/up/single";
1952         }
1953         return $avatar_cache{$email};
1954 }
1955
1956 # Compute the gravatar url for a given email, if it's not in the cache already.
1957 # Gravatar stores only the part of the URL before the size, since that's the
1958 # one computationally more expensive. This also allows reuse of the cache for
1959 # different sizes (for this particular engine).
1960 sub gravatar_url {
1961         my $email = lc shift;
1962         my $size = shift;
1963         $avatar_cache{$email} ||=
1964                 "http://www.gravatar.com/avatar/" .
1965                         Digest::MD5::md5_hex($email) . "?s=";
1966         return $avatar_cache{$email} . $size;
1967 }
1968
1969 # Insert an avatar for the given $email at the given $size if the feature
1970 # is enabled.
1971 sub git_get_avatar {
1972         my ($email, %opts) = @_;
1973         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1974         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1975         $opts{-size} ||= 'default';
1976         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1977         my $url = "";
1978         if ($git_avatar eq 'gravatar') {
1979                 $url = gravatar_url($email, $size);
1980         } elsif ($git_avatar eq 'picon') {
1981                 $url = picon_url($email);
1982         }
1983         # Other providers can be added by extending the if chain, defining $url
1984         # as needed. If no variant puts something in $url, we assume avatars
1985         # are completely disabled/unavailable.
1986         if ($url) {
1987                 return $pre_white .
1988                        "<img width=\"$size\" " .
1989                             "class=\"avatar\" " .
1990                             "src=\"".esc_url($url)."\" " .
1991                             "alt=\"\" " .
1992                        "/>" . $post_white;
1993         } else {
1994                 return "";
1995         }
1996 }
1997
1998 sub format_search_author {
1999         my ($author, $searchtype, $displaytext) = @_;
2000         my $have_search = gitweb_check_feature('search');
2001
2002         if ($have_search) {
2003                 my $performed = "";
2004                 if ($searchtype eq 'author') {
2005                         $performed = "authored";
2006                 } elsif ($searchtype eq 'committer') {
2007                         $performed = "committed";
2008                 }
2009
2010                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2011                                 searchtext=>$author,
2012                                 searchtype=>$searchtype), class=>"list",
2013                                 title=>"Search for commits $performed by $author"},
2014                                 $displaytext);
2015
2016         } else {
2017                 return $displaytext;
2018         }
2019 }
2020
2021 # format the author name of the given commit with the given tag
2022 # the author name is chopped and escaped according to the other
2023 # optional parameters (see chop_str).
2024 sub format_author_html {
2025         my $tag = shift;
2026         my $co = shift;
2027         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2028         return "<$tag class=\"author\">" .
2029                format_search_author($co->{'author_name'}, "author",
2030                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2031                        $author) .
2032                "</$tag>";
2033 }
2034
2035 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2036 sub format_git_diff_header_line {
2037         my $line = shift;
2038         my $diffinfo = shift;
2039         my ($from, $to) = @_;
2040
2041         if ($diffinfo->{'nparents'}) {
2042                 # combined diff
2043                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2044                 if ($to->{'href'}) {
2045                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2046                                          esc_path($to->{'file'}));
2047                 } else { # file was deleted (no href)
2048                         $line .= esc_path($to->{'file'});
2049                 }
2050         } else {
2051                 # "ordinary" diff
2052                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2053                 if ($from->{'href'}) {
2054                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2055                                          'a/' . esc_path($from->{'file'}));
2056                 } else { # file was added (no href)
2057                         $line .= 'a/' . esc_path($from->{'file'});
2058                 }
2059                 $line .= ' ';
2060                 if ($to->{'href'}) {
2061                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2062                                          'b/' . esc_path($to->{'file'}));
2063                 } else { # file was deleted
2064                         $line .= 'b/' . esc_path($to->{'file'});
2065                 }
2066         }
2067
2068         return "<div class=\"diff header\">$line</div>\n";
2069 }
2070
2071 # format extended diff header line, before patch itself
2072 sub format_extended_diff_header_line {
2073         my $line = shift;
2074         my $diffinfo = shift;
2075         my ($from, $to) = @_;
2076
2077         # match <path>
2078         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2079                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2080                                        esc_path($from->{'file'}));
2081         }
2082         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2083                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2084                                  esc_path($to->{'file'}));
2085         }
2086         # match single <mode>
2087         if ($line =~ m/\s(\d{6})$/) {
2088                 $line .= '<span class="info"> (' .
2089                          file_type_long($1) .
2090                          ')</span>';
2091         }
2092         # match <hash>
2093         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2094                 # can match only for combined diff
2095                 $line = 'index ';
2096                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2097                         if ($from->{'href'}[$i]) {
2098                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2099                                                   -class=>"hash"},
2100                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2101                         } else {
2102                                 $line .= '0' x 7;
2103                         }
2104                         # separator
2105                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2106                 }
2107                 $line .= '..';
2108                 if ($to->{'href'}) {
2109                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2110                                          substr($diffinfo->{'to_id'},0,7));
2111                 } else {
2112                         $line .= '0' x 7;
2113                 }
2114
2115         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2116                 # can match only for ordinary diff
2117                 my ($from_link, $to_link);
2118                 if ($from->{'href'}) {
2119                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2120                                              substr($diffinfo->{'from_id'},0,7));
2121                 } else {
2122                         $from_link = '0' x 7;
2123                 }
2124                 if ($to->{'href'}) {
2125                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2126                                            substr($diffinfo->{'to_id'},0,7));
2127                 } else {
2128                         $to_link = '0' x 7;
2129                 }
2130                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2131                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2132         }
2133
2134         return $line . "<br/>\n";
2135 }
2136
2137 # format from-file/to-file diff header
2138 sub format_diff_from_to_header {
2139         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2140         my $line;
2141         my $result = '';
2142
2143         $line = $from_line;
2144         #assert($line =~ m/^---/) if DEBUG;
2145         # no extra formatting for "^--- /dev/null"
2146         if (! $diffinfo->{'nparents'}) {
2147                 # ordinary (single parent) diff
2148                 if ($line =~ m!^--- "?a/!) {
2149                         if ($from->{'href'}) {
2150                                 $line = '--- a/' .
2151                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2152                                                 esc_path($from->{'file'}));
2153                         } else {
2154                                 $line = '--- a/' .
2155                                         esc_path($from->{'file'});
2156                         }
2157                 }
2158                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2159
2160         } else {
2161                 # combined diff (merge commit)
2162                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2163                         if ($from->{'href'}[$i]) {
2164                                 $line = '--- ' .
2165                                         $cgi->a({-href=>href(action=>"blobdiff",
2166                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2167                                                              hash_parent_base=>$parents[$i],
2168                                                              file_parent=>$from->{'file'}[$i],
2169                                                              hash=>$diffinfo->{'to_id'},
2170                                                              hash_base=>$hash,
2171                                                              file_name=>$to->{'file'}),
2172                                                  -class=>"path",
2173                                                  -title=>"diff" . ($i+1)},
2174                                                 $i+1) .
2175                                         '/' .
2176                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2177                                                 esc_path($from->{'file'}[$i]));
2178                         } else {
2179                                 $line = '--- /dev/null';
2180                         }
2181                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2182                 }
2183         }
2184
2185         $line = $to_line;
2186         #assert($line =~ m/^\+\+\+/) if DEBUG;
2187         # no extra formatting for "^+++ /dev/null"
2188         if ($line =~ m!^\+\+\+ "?b/!) {
2189                 if ($to->{'href'}) {
2190                         $line = '+++ b/' .
2191                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2192                                         esc_path($to->{'file'}));
2193                 } else {
2194                         $line = '+++ b/' .
2195                                 esc_path($to->{'file'});
2196                 }
2197         }
2198         $result .= qq!<div class="diff to_file">$line</div>\n!;
2199
2200         return $result;
2201 }
2202
2203 # create note for patch simplified by combined diff
2204 sub format_diff_cc_simplified {
2205         my ($diffinfo, @parents) = @_;
2206         my $result = '';
2207
2208         $result .= "<div class=\"diff header\">" .
2209                    "diff --cc ";
2210         if (!is_deleted($diffinfo)) {
2211                 $result .= $cgi->a({-href => href(action=>"blob",
2212                                                   hash_base=>$hash,
2213                                                   hash=>$diffinfo->{'to_id'},
2214                                                   file_name=>$diffinfo->{'to_file'}),
2215                                     -class => "path"},
2216                                    esc_path($diffinfo->{'to_file'}));
2217         } else {
2218                 $result .= esc_path($diffinfo->{'to_file'});
2219         }
2220         $result .= "</div>\n" . # class="diff header"
2221                    "<div class=\"diff nodifferences\">" .
2222                    "Simple merge" .
2223                    "</div>\n"; # class="diff nodifferences"
2224
2225         return $result;
2226 }
2227
2228 # format patch (diff) line (not to be used for diff headers)
2229 sub format_diff_line {
2230         my $line = shift;
2231         my ($from, $to) = @_;
2232         my $diff_class = "";
2233
2234         chomp $line;
2235
2236         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2237                 # combined diff
2238                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2239                 if ($line =~ m/^\@{3}/) {
2240                         $diff_class = " chunk_header";
2241                 } elsif ($line =~ m/^\\/) {
2242                         $diff_class = " incomplete";
2243                 } elsif ($prefix =~ tr/+/+/) {
2244                         $diff_class = " add";
2245                 } elsif ($prefix =~ tr/-/-/) {
2246                         $diff_class = " rem";
2247                 }
2248         } else {
2249                 # assume ordinary diff
2250                 my $char = substr($line, 0, 1);
2251                 if ($char eq '+') {
2252                         $diff_class = " add";
2253                 } elsif ($char eq '-') {
2254                         $diff_class = " rem";
2255                 } elsif ($char eq '@') {
2256                         $diff_class = " chunk_header";
2257                 } elsif ($char eq "\\") {
2258                         $diff_class = " incomplete";
2259                 }
2260         }
2261         $line = untabify($line);
2262         if ($from && $to && $line =~ m/^\@{2} /) {
2263                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2264                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2265
2266                 $from_lines = 0 unless defined $from_lines;
2267                 $to_lines   = 0 unless defined $to_lines;
2268
2269                 if ($from->{'href'}) {
2270                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2271                                              -class=>"list"}, $from_text);
2272                 }
2273                 if ($to->{'href'}) {
2274                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2275                                              -class=>"list"}, $to_text);
2276                 }
2277                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2278                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2279                 return "<div class=\"diff$diff_class\">$line</div>\n";
2280         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2281                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2282                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2283
2284                 @from_text = split(' ', $ranges);
2285                 for (my $i = 0; $i < @from_text; ++$i) {
2286                         ($from_start[$i], $from_nlines[$i]) =
2287                                 (split(',', substr($from_text[$i], 1)), 0);
2288                 }
2289
2290                 $to_text   = pop @from_text;
2291                 $to_start  = pop @from_start;
2292                 $to_nlines = pop @from_nlines;
2293
2294                 $line = "<span class=\"chunk_info\">$prefix ";
2295                 for (my $i = 0; $i < @from_text; ++$i) {
2296                         if ($from->{'href'}[$i]) {
2297                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2298                                                   -class=>"list"}, $from_text[$i]);
2299                         } else {
2300                                 $line .= $from_text[$i];
2301                         }
2302                         $line .= " ";
2303                 }
2304                 if ($to->{'href'}) {
2305                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2306                                           -class=>"list"}, $to_text);
2307                 } else {
2308                         $line .= $to_text;
2309                 }
2310                 $line .= " $prefix</span>" .
2311                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2312                 return "<div class=\"diff$diff_class\">$line</div>\n";
2313         }
2314         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2315 }
2316
2317 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2318 # linked.  Pass the hash of the tree/commit to snapshot.
2319 sub format_snapshot_links {
2320         my ($hash) = @_;
2321         my $num_fmts = @snapshot_fmts;
2322         if ($num_fmts > 1) {
2323                 # A parenthesized list of links bearing format names.
2324                 # e.g. "snapshot (_tar.gz_ _zip_)"
2325                 return "snapshot (" . join(' ', map
2326                         $cgi->a({
2327                                 -href => href(
2328                                         action=>"snapshot",
2329                                         hash=>$hash,
2330                                         snapshot_format=>$_
2331                                 )
2332                         }, $known_snapshot_formats{$_}{'display'})
2333                 , @snapshot_fmts) . ")";
2334         } elsif ($num_fmts == 1) {
2335                 # A single "snapshot" link whose tooltip bears the format name.
2336                 # i.e. "_snapshot_"
2337                 my ($fmt) = @snapshot_fmts;
2338                 return
2339                         $cgi->a({
2340                                 -href => href(
2341                                         action=>"snapshot",
2342                                         hash=>$hash,
2343                                         snapshot_format=>$fmt
2344                                 ),
2345                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2346                         }, "snapshot");
2347         } else { # $num_fmts == 0
2348                 return undef;
2349         }
2350 }
2351
2352 ## ......................................................................
2353 ## functions returning values to be passed, perhaps after some
2354 ## transformation, to other functions; e.g. returning arguments to href()
2355
2356 # returns hash to be passed to href to generate gitweb URL
2357 # in -title key it returns description of link
2358 sub get_feed_info {
2359         my $format = shift || 'Atom';
2360         my %res = (action => lc($format));
2361
2362         # feed links are possible only for project views
2363         return unless (defined $project);
2364         # some views should link to OPML, or to generic project feed,
2365         # or don't have specific feed yet (so they should use generic)
2366         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2367
2368         my $branch;
2369         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2370         # from tag links; this also makes possible to detect branch links
2371         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2372             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2373                 $branch = $1;
2374         }
2375         # find log type for feed description (title)
2376         my $type = 'log';
2377         if (defined $file_name) {
2378                 $type  = "history of $file_name";
2379                 $type .= "/" if ($action eq 'tree');
2380                 $type .= " on '$branch'" if (defined $branch);
2381         } else {
2382                 $type = "log of $branch" if (defined $branch);
2383         }
2384
2385         $res{-title} = $type;
2386         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2387         $res{'file_name'} = $file_name;
2388
2389         return %res;
2390 }
2391
2392 ## ----------------------------------------------------------------------
2393 ## git utility subroutines, invoking git commands
2394
2395 # returns path to the core git executable and the --git-dir parameter as list
2396 sub git_cmd {
2397         $number_of_git_cmds++;
2398         return $GIT, '--git-dir='.$git_dir;
2399 }
2400
2401 # quote the given arguments for passing them to the shell
2402 # quote_command("command", "arg 1", "arg with ' and ! characters")
2403 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2404 # Try to avoid using this function wherever possible.
2405 sub quote_command {
2406         return join(' ',
2407                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2408 }
2409
2410 # get HEAD ref of given project as hash
2411 sub git_get_head_hash {
2412         return git_get_full_hash(shift, 'HEAD');
2413 }
2414
2415 sub git_get_full_hash {
2416         return git_get_hash(@_);
2417 }
2418
2419 sub git_get_short_hash {
2420         return git_get_hash(@_, '--short=7');
2421 }
2422
2423 sub git_get_hash {
2424         my ($project, $hash, @options) = @_;
2425         my $o_git_dir = $git_dir;
2426         my $retval = undef;
2427         $git_dir = "$projectroot/$project";
2428         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2429             '--verify', '-q', @options, $hash) {
2430                 $retval = <$fd>;
2431                 chomp $retval if defined $retval;
2432                 close $fd;
2433         }
2434         if (defined $o_git_dir) {
2435                 $git_dir = $o_git_dir;
2436         }
2437         return $retval;
2438 }
2439
2440 # get type of given object
2441 sub git_get_type {
2442         my $hash = shift;
2443
2444         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2445         my $type = <$fd>;
2446         close $fd or return;
2447         chomp $type;
2448         return $type;
2449 }
2450
2451 # repository configuration
2452 our $config_file = '';
2453 our %config;
2454
2455 # store multiple values for single key as anonymous array reference
2456 # single values stored directly in the hash, not as [ <value> ]
2457 sub hash_set_multi {
2458         my ($hash, $key, $value) = @_;
2459
2460         if (!exists $hash->{$key}) {
2461                 $hash->{$key} = $value;
2462         } elsif (!ref $hash->{$key}) {
2463                 $hash->{$key} = [ $hash->{$key}, $value ];
2464         } else {
2465                 push @{$hash->{$key}}, $value;
2466         }
2467 }
2468
2469 # return hash of git project configuration
2470 # optionally limited to some section, e.g. 'gitweb'
2471 sub git_parse_project_config {
2472         my $section_regexp = shift;
2473         my %config;
2474
2475         local $/ = "\0";
2476
2477         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2478                 or return;
2479
2480         while (my $keyval = <$fh>) {
2481                 chomp $keyval;
2482                 my ($key, $value) = split(/\n/, $keyval, 2);
2483
2484                 hash_set_multi(\%config, $key, $value)
2485                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2486         }
2487         close $fh;
2488
2489         return %config;
2490 }
2491
2492 # convert config value to boolean: 'true' or 'false'
2493 # no value, number > 0, 'true' and 'yes' values are true
2494 # rest of values are treated as false (never as error)
2495 sub config_to_bool {
2496         my $val = shift;
2497
2498         return 1 if !defined $val;             # section.key
2499
2500         # strip leading and trailing whitespace
2501         $val =~ s/^\s+//;
2502         $val =~ s/\s+$//;
2503
2504         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2505                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2506 }
2507
2508 # convert config value to simple decimal number
2509 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2510 # to be multiplied by 1024, 1048576, or 1073741824
2511 sub config_to_int {
2512         my $val = shift;
2513
2514         # strip leading and trailing whitespace
2515         $val =~ s/^\s+//;
2516         $val =~ s/\s+$//;
2517
2518         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2519                 $unit = lc($unit);
2520                 # unknown unit is treated as 1
2521                 return $num * ($unit eq 'g' ? 1073741824 :
2522                                $unit eq 'm' ?    1048576 :
2523                                $unit eq 'k' ?       1024 : 1);
2524         }
2525         return $val;
2526 }
2527
2528 # convert config value to array reference, if needed
2529 sub config_to_multi {
2530         my $val = shift;
2531
2532         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2533 }
2534
2535 sub git_get_project_config {
2536         my ($key, $type) = @_;
2537
2538         return unless defined $git_dir;
2539
2540         # key sanity check
2541         return unless ($key);
2542         # only subsection, if exists, is case sensitive,
2543         # and not lowercased by 'git config -z -l'
2544         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2545                 $key = join(".", lc($hi), $mi, lc($lo));
2546         } else {
2547                 $key = lc($key);
2548         }
2549         $key =~ s/^gitweb\.//;
2550         return if ($key =~ m/\W/);
2551
2552         # type sanity check
2553         if (defined $type) {
2554                 $type =~ s/^--//;
2555                 $type = undef
2556                         unless ($type eq 'bool' || $type eq 'int');
2557         }
2558
2559         # get config
2560         if (!defined $config_file ||
2561             $config_file ne "$git_dir/config") {
2562                 %config = git_parse_project_config('gitweb');
2563                 $config_file = "$git_dir/config";
2564         }
2565
2566         # check if config variable (key) exists
2567         return unless exists $config{"gitweb.$key"};
2568
2569         # ensure given type
2570         if (!defined $type) {
2571                 return $config{"gitweb.$key"};
2572         } elsif ($type eq 'bool') {
2573                 # backward compatibility: 'git config --bool' returns true/false
2574                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2575         } elsif ($type eq 'int') {
2576                 return config_to_int($config{"gitweb.$key"});
2577         }
2578         return $config{"gitweb.$key"};
2579 }
2580
2581 # get hash of given path at given ref
2582 sub git_get_hash_by_path {
2583         my $base = shift;
2584         my $path = shift || return undef;
2585         my $type = shift;
2586
2587         $path =~ s,/+$,,;
2588
2589         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2590                 or die_error(500, "Open git-ls-tree failed");
2591         my $line = <$fd>;
2592         close $fd or return undef;
2593
2594         if (!defined $line) {
2595                 # there is no tree or hash given by $path at $base
2596                 return undef;
2597         }
2598
2599         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2600         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2601         if (defined $type && $type ne $2) {
2602                 # type doesn't match
2603                 return undef;
2604         }
2605         return $3;
2606 }
2607
2608 # get path of entry with given hash at given tree-ish (ref)
2609 # used to get 'from' filename for combined diff (merge commit) for renames
2610 sub git_get_path_by_hash {
2611         my $base = shift || return;
2612         my $hash = shift || return;
2613
2614         local $/ = "\0";
2615
2616         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2617                 or return undef;
2618         while (my $line = <$fd>) {
2619                 chomp $line;
2620
2621                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2622                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2623                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2624                         close $fd;
2625                         return $1;
2626                 }
2627         }
2628         close $fd;
2629         return undef;
2630 }
2631
2632 ## ......................................................................
2633 ## git utility functions, directly accessing git repository
2634
2635 # get the value of config variable either from file named as the variable
2636 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2637 # configuration variable in the repository config file.
2638 sub git_get_file_or_project_config {
2639         my ($path, $name) = @_;
2640
2641         $git_dir = "$projectroot/$path";
2642         open my $fd, '<', "$git_dir/$name"
2643                 or return git_get_project_config($name);
2644         my $conf = <$fd>;
2645         close $fd;
2646         if (defined $conf) {
2647                 chomp $conf;
2648         }
2649         return $conf;
2650 }
2651
2652 sub git_get_project_description {
2653         my $path = shift;
2654         return git_get_file_or_project_config($path, 'description');
2655 }
2656
2657 sub git_get_project_category {
2658         my $path = shift;
2659         return git_get_file_or_project_config($path, 'category');
2660 }
2661
2662
2663 # supported formats:
2664 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2665 #   - if its contents is a number, use it as tag weight,
2666 #   - otherwise add a tag with weight 1
2667 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2668 #   the same value multiple times increases tag weight
2669 # * `gitweb.ctag' multi-valued repo config variable
2670 sub git_get_project_ctags {
2671         my $project = shift;
2672         my $ctags = {};
2673
2674         $git_dir = "$projectroot/$project";
2675         if (opendir my $dh, "$git_dir/ctags") {
2676                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2677                 foreach my $tagfile (@files) {
2678                         open my $ct, '<', $tagfile
2679                                 or next;
2680                         my $val = <$ct>;
2681                         chomp $val if $val;
2682                         close $ct;
2683
2684                         (my $ctag = $tagfile) =~ s#.*/##;
2685                         if ($val =~ /^\d+$/) {
2686                                 $ctags->{$ctag} = $val;
2687                         } else {
2688                                 $ctags->{$ctag} = 1;
2689                         }
2690                 }
2691                 closedir $dh;
2692
2693         } elsif (open my $fh, '<', "$git_dir/ctags") {
2694                 while (my $line = <$fh>) {
2695                         chomp $line;
2696                         $ctags->{$line}++ if $line;
2697                 }
2698                 close $fh;
2699
2700         } else {
2701                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2702                 foreach my $tag (@$taglist) {
2703                         $ctags->{$tag}++;
2704                 }
2705         }
2706
2707         return $ctags;
2708 }
2709
2710 # return hash, where keys are content tags ('ctags'),
2711 # and values are sum of weights of given tag in every project
2712 sub git_gather_all_ctags {
2713         my $projects = shift;
2714         my $ctags = {};
2715
2716         foreach my $p (@$projects) {
2717                 foreach my $ct (keys %{$p->{'ctags'}}) {
2718                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2719                 }
2720         }
2721
2722         return $ctags;
2723 }
2724
2725 sub git_populate_project_tagcloud {
2726         my $ctags = shift;
2727
2728         # First, merge different-cased tags; tags vote on casing
2729         my %ctags_lc;
2730         foreach (keys %$ctags) {
2731                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2732                 if (not $ctags_lc{lc $_}->{topcount}
2733                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2734                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2735                         $ctags_lc{lc $_}->{topname} = $_;
2736                 }
2737         }
2738
2739         my $cloud;
2740         my $matched = $cgi->param('by_tag');
2741         if (eval { require HTML::TagCloud; 1; }) {
2742                 $cloud = HTML::TagCloud->new;
2743                 foreach my $ctag (sort keys %ctags_lc) {
2744                         # Pad the title with spaces so that the cloud looks
2745                         # less crammed.
2746                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2747                         $title =~ s/ /&nbsp;/g;
2748                         $title =~ s/^/&nbsp;/g;
2749                         $title =~ s/$/&nbsp;/g;
2750                         if (defined $matched && $matched eq $ctag) {
2751                                 $title = qq(<span class="match">$title</span>);
2752                         }
2753                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2754                                     $ctags_lc{$ctag}->{count});
2755                 }
2756         } else {
2757                 $cloud = {};
2758                 foreach my $ctag (keys %ctags_lc) {
2759                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2760                         if (defined $matched && $matched eq $ctag) {
2761                                 $title = qq(<span class="match">$title</span>);
2762                         }
2763                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2764                         $cloud->{$ctag}{ctag} =
2765                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2766                 }
2767         }
2768         return $cloud;
2769 }
2770
2771 sub git_show_project_tagcloud {
2772         my ($cloud, $count) = @_;
2773         if (ref $cloud eq 'HTML::TagCloud') {
2774                 return $cloud->html_and_css($count);
2775         } else {
2776                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2777                 return
2778                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2779                         join (', ', map {
2780                                 $cloud->{$_}->{'ctag'}
2781                         } splice(@tags, 0, $count)) .
2782                         '</div>';
2783         }
2784 }
2785
2786 sub git_get_project_url_list {
2787         my $path = shift;
2788
2789         $git_dir = "$projectroot/$path";
2790         open my $fd, '<', "$git_dir/cloneurl"
2791                 or return wantarray ?
2792                 @{ config_to_multi(git_get_project_config('url')) } :
2793                    config_to_multi(git_get_project_config('url'));
2794         my @git_project_url_list = map { chomp; $_ } <$fd>;
2795         close $fd;
2796
2797         return wantarray ? @git_project_url_list : \@git_project_url_list;
2798 }
2799
2800 sub git_get_projects_list {
2801         my $filter = shift || '';
2802         my @list;
2803
2804         $filter =~ s/\.git$//;
2805
2806         if (-d $projects_list) {
2807                 # search in directory
2808                 my $dir = $projects_list;
2809                 # remove the trailing "/"
2810                 $dir =~ s!/+$!!;
2811                 my $pfxlen = length("$projects_list");
2812                 my $pfxdepth = ($projects_list =~ tr!/!!);
2813                 # when filtering, search only given subdirectory
2814                 if ($filter) {
2815                         $dir .= "/$filter";
2816                         $dir =~ s!/+$!!;
2817                 }
2818
2819                 File::Find::find({
2820                         follow_fast => 1, # follow symbolic links
2821                         follow_skip => 2, # ignore duplicates
2822                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2823                         wanted => sub {
2824                                 # global variables
2825                                 our $project_maxdepth;
2826                                 our $projectroot;
2827                                 # skip project-list toplevel, if we get it.
2828                                 return if (m!^[/.]$!);
2829                                 # only directories can be git repositories
2830                                 return unless (-d $_);
2831                                 # don't traverse too deep (Find is super slow on os x)
2832                                 # $project_maxdepth excludes depth of $projectroot
2833                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2834                                         $File::Find::prune = 1;
2835                                         return;
2836                                 }
2837
2838                                 my $path = substr($File::Find::name, $pfxlen + 1);
2839                                 # we check related file in $projectroot
2840                                 if (check_export_ok("$projectroot/$path")) {
2841                                         push @list, { path => $path };
2842                                         $File::Find::prune = 1;
2843                                 }
2844                         },
2845                 }, "$dir");
2846
2847         } elsif (-f $projects_list) {
2848                 # read from file(url-encoded):
2849                 # 'git%2Fgit.git Linus+Torvalds'
2850                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2851                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2852                 open my $fd, '<', $projects_list or return;
2853         PROJECT:
2854                 while (my $line = <$fd>) {
2855                         chomp $line;
2856                         my ($path, $owner) = split ' ', $line;
2857                         $path = unescape($path);
2858                         $owner = unescape($owner);
2859                         if (!defined $path) {
2860                                 next;
2861                         }
2862                         # if $filter is rpovided, check if $path begins with $filter
2863                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2864                                 next;
2865                         }
2866                         if (check_export_ok("$projectroot/$path")) {
2867                                 my $pr = {
2868                                         path => $path,
2869                                         owner => to_utf8($owner),
2870                                 };
2871                                 push @list, $pr;
2872                         }
2873                 }
2874                 close $fd;
2875         }
2876         return @list;
2877 }
2878
2879 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2880 # as side effects it sets 'forks' field to list of forks for forked projects
2881 sub filter_forks_from_projects_list {
2882         my $projects = shift;
2883
2884         my %trie; # prefix tree of directories (path components)
2885         # generate trie out of those directories that might contain forks
2886         foreach my $pr (@$projects) {
2887                 my $path = $pr->{'path'};
2888                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2889                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2890                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2891                 next unless (-d "$projectroot/$path"); # containing directory exists
2892                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2893
2894                 # add to trie
2895                 my @dirs = split('/', $path);
2896                 # walk the trie, until either runs out of components or out of trie
2897                 my $ref = \%trie;
2898                 while (scalar @dirs &&
2899                        exists($ref->{$dirs[0]})) {
2900                         $ref = $ref->{shift @dirs};
2901                 }
2902                 # create rest of trie structure from rest of components
2903                 foreach my $dir (@dirs) {
2904                         $ref = $ref->{$dir} = {};
2905                 }
2906                 # create end marker, store $pr as a data
2907                 $ref->{''} = $pr if (!exists $ref->{''});
2908         }
2909
2910         # filter out forks, by finding shortest prefix match for paths
2911         my @filtered;
2912  PROJECT:
2913         foreach my $pr (@$projects) {
2914                 # trie lookup
2915                 my $ref = \%trie;
2916         DIR:
2917                 foreach my $dir (split('/', $pr->{'path'})) {
2918                         if (exists $ref->{''}) {
2919                                 # found [shortest] prefix, is a fork - skip it
2920                                 push @{$ref->{''}{'forks'}}, $pr;
2921                                 next PROJECT;
2922                         }
2923                         if (!exists $ref->{$dir}) {
2924                                 # not in trie, cannot have prefix, not a fork
2925                                 push @filtered, $pr;
2926                                 next PROJECT;
2927                         }
2928                         # If the dir is there, we just walk one step down the trie.
2929                         $ref = $ref->{$dir};
2930                 }
2931                 # we ran out of trie
2932                 # (shouldn't happen: it's either no match, or end marker)
2933                 push @filtered, $pr;
2934         }
2935
2936         return @filtered;
2937 }
2938
2939 # note: fill_project_list_info must be run first,
2940 # for 'descr_long' and 'ctags' to be filled
2941 sub search_projects_list {
2942         my ($projlist, %opts) = @_;
2943         my $tagfilter  = $opts{'tagfilter'};
2944         my $searchtext = $opts{'searchtext'};
2945
2946         return @$projlist
2947                 unless ($tagfilter || $searchtext);
2948
2949         my @projects;
2950  PROJECT:
2951         foreach my $pr (@$projlist) {
2952
2953                 if ($tagfilter) {
2954                         next unless ref($pr->{'ctags'}) eq 'HASH';
2955                         next unless
2956                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
2957                 }
2958
2959                 if ($searchtext) {
2960                         next unless
2961                                 $pr->{'path'} =~ /$searchtext/ ||
2962                                 $pr->{'descr_long'} =~ /$searchtext/;
2963                 }
2964
2965                 push @projects, $pr;
2966         }
2967
2968         return @projects;
2969 }
2970
2971 our $gitweb_project_owner = undef;
2972 sub git_get_project_list_from_file {
2973
2974         return if (defined $gitweb_project_owner);
2975
2976         $gitweb_project_owner = {};
2977         # read from file (url-encoded):
2978         # 'git%2Fgit.git Linus+Torvalds'
2979         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2980         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2981         if (-f $projects_list) {
2982                 open(my $fd, '<', $projects_list);
2983                 while (my $line = <$fd>) {
2984                         chomp $line;
2985                         my ($pr, $ow) = split ' ', $line;
2986                         $pr = unescape($pr);
2987                         $ow = unescape($ow);
2988                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2989                 }
2990                 close $fd;
2991         }
2992 }
2993
2994 sub git_get_project_owner {
2995         my $project = shift;
2996         my $owner;
2997
2998         return undef unless $project;
2999         $git_dir = "$projectroot/$project";
3000
3001         if (!defined $gitweb_project_owner) {
3002                 git_get_project_list_from_file();
3003         }
3004
3005         if (exists $gitweb_project_owner->{$project}) {
3006                 $owner = $gitweb_project_owner->{$project};
3007         }
3008         if (!defined $owner){
3009                 $owner = git_get_project_config('owner');
3010         }
3011         if (!defined $owner) {
3012                 $owner = get_file_owner("$git_dir");
3013         }
3014
3015         return $owner;
3016 }
3017
3018 sub git_get_last_activity {
3019         my ($path) = @_;
3020         my $fd;
3021
3022         $git_dir = "$projectroot/$path";
3023         open($fd, "-|", git_cmd(), 'for-each-ref',
3024              '--format=%(committer)',
3025              '--sort=-committerdate',
3026              '--count=1',
3027              'refs/heads') or return;
3028         my $most_recent = <$fd>;
3029         close $fd or return;
3030         if (defined $most_recent &&
3031             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3032                 my $timestamp = $1;
3033                 my $age = time - $timestamp;
3034                 return ($age, age_string($age));
3035         }
3036         return (undef, undef);
3037 }
3038
3039 # Implementation note: when a single remote is wanted, we cannot use 'git
3040 # remote show -n' because that command always work (assuming it's a remote URL
3041 # if it's not defined), and we cannot use 'git remote show' because that would
3042 # try to make a network roundtrip. So the only way to find if that particular
3043 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3044 # and when we find what we want.
3045 sub git_get_remotes_list {
3046         my $wanted = shift;
3047         my %remotes = ();
3048
3049         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3050         return unless $fd;
3051         while (my $remote = <$fd>) {
3052                 chomp $remote;
3053                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3054                 next if $wanted and not $remote eq $wanted;
3055                 my ($url, $key) = ($1, $2);
3056
3057                 $remotes{$remote} ||= { 'heads' => () };
3058                 $remotes{$remote}{$key} = $url;
3059         }
3060         close $fd or return;
3061         return wantarray ? %remotes : \%remotes;
3062 }
3063
3064 # Takes a hash of remotes as first parameter and fills it by adding the
3065 # available remote heads for each of the indicated remotes.
3066 sub fill_remote_heads {
3067         my $remotes = shift;
3068         my @heads = map { "remotes/$_" } keys %$remotes;
3069         my @remoteheads = git_get_heads_list(undef, @heads);
3070         foreach my $remote (keys %$remotes) {
3071                 $remotes->{$remote}{'heads'} = [ grep {
3072                         $_->{'name'} =~ s!^$remote/!!
3073                         } @remoteheads ];
3074         }
3075 }
3076
3077 sub git_get_references {
3078         my $type = shift || "";
3079         my %refs;
3080         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3081         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3082         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3083                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3084                 or return;
3085
3086         while (my $line = <$fd>) {
3087                 chomp $line;
3088                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3089                         if (defined $refs{$1}) {
3090                                 push @{$refs{$1}}, $2;
3091                         } else {
3092                                 $refs{$1} = [ $2 ];
3093                         }
3094                 }
3095         }
3096         close $fd or return;
3097         return \%refs;
3098 }
3099
3100 sub git_get_rev_name_tags {
3101         my $hash = shift || return undef;
3102
3103         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3104                 or return;
3105         my $name_rev = <$fd>;
3106         close $fd;
3107
3108         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3109                 return $1;
3110         } else {
3111                 # catches also '$hash undefined' output
3112                 return undef;
3113         }
3114 }
3115
3116 ## ----------------------------------------------------------------------
3117 ## parse to hash functions
3118
3119 sub parse_date {
3120         my $epoch = shift;
3121         my $tz = shift || "-0000";
3122
3123         my %date;
3124         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3125         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3126         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3127         $date{'hour'} = $hour;
3128         $date{'minute'} = $min;
3129         $date{'mday'} = $mday;
3130         $date{'day'} = $days[$wday];
3131         $date{'month'} = $months[$mon];
3132         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3133                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3134         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3135                              $mday, $months[$mon], $hour ,$min;
3136         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3137                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3138
3139         my ($tz_sign, $tz_hour, $tz_min) =
3140                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3141         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3142         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3143         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3144         $date{'hour_local'} = $hour;
3145         $date{'minute_local'} = $min;
3146         $date{'tz_local'} = $tz;
3147         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3148                                   1900+$year, $mon+1, $mday,
3149                                   $hour, $min, $sec, $tz);
3150         return %date;
3151 }
3152
3153 sub parse_tag {
3154         my $tag_id = shift;
3155         my %tag;
3156         my @comment;
3157
3158         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3159         $tag{'id'} = $tag_id;
3160         while (my $line = <$fd>) {
3161                 chomp $line;
3162                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3163                         $tag{'object'} = $1;
3164                 } elsif ($line =~ m/^type (.+)$/) {
3165                         $tag{'type'} = $1;
3166                 } elsif ($line =~ m/^tag (.+)$/) {
3167                         $tag{'name'} = $1;
3168                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3169                         $tag{'author'} = $1;
3170                         $tag{'author_epoch'} = $2;
3171                         $tag{'author_tz'} = $3;
3172                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3173                                 $tag{'author_name'}  = $1;
3174                                 $tag{'author_email'} = $2;
3175                         } else {
3176                                 $tag{'author_name'} = $tag{'author'};
3177                         }
3178                 } elsif ($line =~ m/--BEGIN/) {
3179                         push @comment, $line;
3180                         last;
3181                 } elsif ($line eq "") {
3182                         last;
3183                 }
3184         }
3185         push @comment, <$fd>;
3186         $tag{'comment'} = \@comment;
3187         close $fd or return;
3188         if (!defined $tag{'name'}) {
3189                 return
3190         };
3191         return %tag
3192 }
3193
3194 sub parse_commit_text {
3195         my ($commit_text, $withparents) = @_;
3196         my @commit_lines = split '\n', $commit_text;
3197         my %co;
3198
3199         pop @commit_lines; # Remove '\0'
3200
3201         if (! @commit_lines) {
3202                 return;
3203         }
3204
3205         my $header = shift @commit_lines;
3206         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3207                 return;
3208         }
3209         ($co{'id'}, my @parents) = split ' ', $header;
3210         while (my $line = shift @commit_lines) {
3211                 last if $line eq "\n";
3212                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3213                         $co{'tree'} = $1;
3214                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3215                         push @parents, $1;
3216                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3217                         $co{'author'} = to_utf8($1);
3218                         $co{'author_epoch'} = $2;
3219                         $co{'author_tz'} = $3;
3220                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3221                                 $co{'author_name'}  = $1;
3222                                 $co{'author_email'} = $2;
3223                         } else {
3224                                 $co{'author_name'} = $co{'author'};
3225                         }
3226                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3227                         $co{'committer'} = to_utf8($1);
3228                         $co{'committer_epoch'} = $2;
3229                         $co{'committer_tz'} = $3;
3230                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3231                                 $co{'committer_name'}  = $1;
3232                                 $co{'committer_email'} = $2;
3233                         } else {
3234                                 $co{'committer_name'} = $co{'committer'};
3235                         }
3236                 }
3237         }
3238         if (!defined $co{'tree'}) {
3239                 return;
3240         };
3241         $co{'parents'} = \@parents;
3242         $co{'parent'} = $parents[0];
3243
3244         foreach my $title (@commit_lines) {
3245                 $title =~ s/^    //;
3246                 if ($title ne "") {
3247                         $co{'title'} = chop_str($title, 80, 5);
3248                         # remove leading stuff of merges to make the interesting part visible
3249                         if (length($title) > 50) {
3250                                 $title =~ s/^Automatic //;
3251                                 $title =~ s/^merge (of|with) /Merge ... /i;
3252                                 if (length($title) > 50) {
3253                                         $title =~ s/(http|rsync):\/\///;
3254                                 }
3255                                 if (length($title) > 50) {
3256                                         $title =~ s/(master|www|rsync)\.//;
3257                                 }
3258                                 if (length($title) > 50) {
3259                                         $title =~ s/kernel.org:?//;
3260                                 }
3261                                 if (length($title) > 50) {
3262                                         $title =~ s/\/pub\/scm//;
3263                                 }
3264                         }
3265                         $co{'title_short'} = chop_str($title, 50, 5);
3266                         last;
3267                 }
3268         }
3269         if (! defined $co{'title'} || $co{'title'} eq "") {
3270                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3271         }
3272         # remove added spaces
3273         foreach my $line (@commit_lines) {
3274                 $line =~ s/^    //;
3275         }
3276         $co{'comment'} = \@commit_lines;
3277
3278         my $age = time - $co{'committer_epoch'};
3279         $co{'age'} = $age;
3280         $co{'age_string'} = age_string($age);
3281         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3282         if ($age > 60*60*24*7*2) {
3283                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3284                 $co{'age_string_age'} = $co{'age_string'};
3285         } else {
3286                 $co{'age_string_date'} = $co{'age_string'};
3287                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3288         }
3289         return %co;
3290 }
3291
3292 sub parse_commit {
3293         my ($commit_id) = @_;
3294         my %co;
3295
3296         local $/ = "\0";
3297
3298         open my $fd, "-|", git_cmd(), "rev-list",
3299                 "--parents",
3300                 "--header",
3301                 "--max-count=1",
3302                 $commit_id,
3303                 "--",
3304                 or die_error(500, "Open git-rev-list failed");
3305         %co = parse_commit_text(<$fd>, 1);
3306         close $fd;
3307
3308         return %co;
3309 }
3310
3311 sub parse_commits {
3312         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3313         my @cos;
3314
3315         $maxcount ||= 1;
3316         $skip ||= 0;
3317
3318         local $/ = "\0";
3319
3320         open my $fd, "-|", git_cmd(), "rev-list",
3321                 "--header",
3322                 @args,
3323                 ("--max-count=" . $maxcount),
3324                 ("--skip=" . $skip),
3325                 @extra_options,
3326                 $commit_id,
3327                 "--",
3328                 ($filename ? ($filename) : ())
3329                 or die_error(500, "Open git-rev-list failed");
3330         while (my $line = <$fd>) {
3331                 my %co = parse_commit_text($line);
3332                 push @cos, \%co;
3333         }
3334         close $fd;
3335
3336         return wantarray ? @cos : \@cos;
3337 }
3338
3339 # parse line of git-diff-tree "raw" output
3340 sub parse_difftree_raw_line {
3341         my $line = shift;
3342         my %res;
3343
3344         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3345         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3346         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3347                 $res{'from_mode'} = $1;
3348                 $res{'to_mode'} = $2;
3349                 $res{'from_id'} = $3;
3350                 $res{'to_id'} = $4;
3351                 $res{'status'} = $5;
3352                 $res{'similarity'} = $6;
3353                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3354                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3355                 } else {
3356                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3357                 }
3358         }
3359         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3360         # combined diff (for merge commit)
3361         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3362                 $res{'nparents'}  = length($1);
3363                 $res{'from_mode'} = [ split(' ', $2) ];
3364                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3365                 $res{'from_id'} = [ split(' ', $3) ];
3366                 $res{'to_id'} = pop @{$res{'from_id'}};
3367                 $res{'status'} = [ split('', $4) ];
3368                 $res{'to_file'} = unquote($5);
3369         }
3370         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3371         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3372                 $res{'commit'} = $1;
3373         }
3374
3375         return wantarray ? %res : \%res;
3376 }
3377
3378 # wrapper: return parsed line of git-diff-tree "raw" output
3379 # (the argument might be raw line, or parsed info)
3380 sub parsed_difftree_line {
3381         my $line_or_ref = shift;
3382
3383         if (ref($line_or_ref) eq "HASH") {
3384                 # pre-parsed (or generated by hand)
3385                 return $line_or_ref;
3386         } else {
3387                 return parse_difftree_raw_line($line_or_ref);
3388         }
3389 }
3390
3391 # parse line of git-ls-tree output
3392 sub parse_ls_tree_line {
3393         my $line = shift;
3394         my %opts = @_;
3395         my %res;
3396
3397         if ($opts{'-l'}) {
3398                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3399                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3400
3401                 $res{'mode'} = $1;
3402                 $res{'type'} = $2;
3403                 $res{'hash'} = $3;
3404                 $res{'size'} = $4;
3405                 if ($opts{'-z'}) {
3406                         $res{'name'} = $5;
3407                 } else {
3408                         $res{'name'} = unquote($5);
3409                 }
3410         } else {
3411                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3412                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3413
3414                 $res{'mode'} = $1;
3415                 $res{'type'} = $2;
3416                 $res{'hash'} = $3;
3417                 if ($opts{'-z'}) {
3418                         $res{'name'} = $4;
3419                 } else {
3420                         $res{'name'} = unquote($4);
3421                 }
3422         }
3423
3424         return wantarray ? %res : \%res;
3425 }
3426
3427 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3428 sub parse_from_to_diffinfo {
3429         my ($diffinfo, $from, $to, @parents) = @_;
3430
3431         if ($diffinfo->{'nparents'}) {
3432                 # combined diff
3433                 $from->{'file'} = [];
3434                 $from->{'href'} = [];
3435                 fill_from_file_info($diffinfo, @parents)
3436                         unless exists $diffinfo->{'from_file'};
3437                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3438                         $from->{'file'}[$i] =
3439                                 defined $diffinfo->{'from_file'}[$i] ?
3440                                         $diffinfo->{'from_file'}[$i] :
3441                                         $diffinfo->{'to_file'};
3442                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3443                                 $from->{'href'}[$i] = href(action=>"blob",
3444                                                            hash_base=>$parents[$i],
3445                                                            hash=>$diffinfo->{'from_id'}[$i],
3446                                                            file_name=>$from->{'file'}[$i]);
3447                         } else {
3448                                 $from->{'href'}[$i] = undef;
3449                         }
3450                 }
3451         } else {
3452                 # ordinary (not combined) diff
3453                 $from->{'file'} = $diffinfo->{'from_file'};
3454                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3455                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3456                                                hash=>$diffinfo->{'from_id'},
3457                                                file_name=>$from->{'file'});
3458                 } else {
3459                         delete $from->{'href'};
3460                 }
3461         }
3462
3463         $to->{'file'} = $diffinfo->{'to_file'};
3464         if (!is_deleted($diffinfo)) { # file exists in result
3465                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3466                                      hash=>$diffinfo->{'to_id'},
3467                                      file_name=>$to->{'file'});
3468         } else {
3469                 delete $to->{'href'};
3470         }
3471 }
3472
3473 ## ......................................................................
3474 ## parse to array of hashes functions
3475
3476 sub git_get_heads_list {
3477         my ($limit, @classes) = @_;
3478         @classes = ('heads') unless @classes;
3479         my @patterns = map { "refs/$_" } @classes;
3480         my @headslist;
3481
3482         open my $fd, '-|', git_cmd(), 'for-each-ref',
3483                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3484                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3485                 @patterns
3486                 or return;
3487         while (my $line = <$fd>) {
3488                 my %ref_item;
3489
3490                 chomp $line;
3491                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3492                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3493                 my ($committer, $epoch, $tz) =
3494                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3495                 $ref_item{'fullname'}  = $name;
3496                 $name =~ s!^refs/(?:head|remote)s/!!;
3497
3498                 $ref_item{'name'}  = $name;
3499                 $ref_item{'id'}    = $hash;
3500                 $ref_item{'title'} = $title || '(no commit message)';
3501                 $ref_item{'epoch'} = $epoch;
3502                 if ($epoch) {
3503                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3504                 } else {
3505                         $ref_item{'age'} = "unknown";
3506                 }
3507
3508                 push @headslist, \%ref_item;
3509         }
3510         close $fd;
3511
3512         return wantarray ? @headslist : \@headslist;
3513 }
3514
3515 sub git_get_tags_list {
3516         my $limit = shift;
3517         my @tagslist;
3518
3519         open my $fd, '-|', git_cmd(), 'for-each-ref',
3520                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3521                 '--format=%(objectname) %(objecttype) %(refname) '.
3522                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3523                 'refs/tags'
3524                 or return;
3525         while (my $line = <$fd>) {
3526                 my %ref_item;
3527
3528                 chomp $line;
3529                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3530                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3531                 my ($creator, $epoch, $tz) =
3532                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3533                 $ref_item{'fullname'} = $name;
3534                 $name =~ s!^refs/tags/!!;
3535
3536                 $ref_item{'type'} = $type;
3537                 $ref_item{'id'} = $id;
3538                 $ref_item{'name'} = $name;
3539                 if ($type eq "tag") {
3540                         $ref_item{'subject'} = $title;
3541                         $ref_item{'reftype'} = $reftype;
3542                         $ref_item{'refid'}   = $refid;
3543                 } else {
3544                         $ref_item{'reftype'} = $type;
3545                         $ref_item{'refid'}   = $id;
3546                 }
3547
3548                 if ($type eq "tag" || $type eq "commit") {
3549                         $ref_item{'epoch'} = $epoch;
3550                         if ($epoch) {
3551                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3552                         } else {
3553                                 $ref_item{'age'} = "unknown";
3554                         }
3555                 }
3556
3557                 push @tagslist, \%ref_item;
3558         }
3559         close $fd;
3560
3561         return wantarray ? @tagslist : \@tagslist;
3562 }
3563
3564 ## ----------------------------------------------------------------------
3565 ## filesystem-related functions
3566
3567 sub get_file_owner {
3568         my $path = shift;
3569
3570         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3571         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3572         if (!defined $gcos) {
3573                 return undef;
3574         }
3575         my $owner = $gcos;
3576         $owner =~ s/[,;].*$//;
3577         return to_utf8($owner);
3578 }
3579
3580 # assume that file exists
3581 sub insert_file {
3582         my $filename = shift;
3583
3584         open my $fd, '<', $filename;
3585         print map { to_utf8($_) } <$fd>;
3586         close $fd;
3587 }
3588
3589 ## ......................................................................
3590 ## mimetype related functions
3591
3592 sub mimetype_guess_file {
3593         my $filename = shift;
3594         my $mimemap = shift;
3595         -r $mimemap or return undef;
3596
3597         my %mimemap;
3598         open(my $mh, '<', $mimemap) or return undef;
3599         while (<$mh>) {
3600                 next if m/^#/; # skip comments
3601                 my ($mimetype, @exts) = split(/\s+/);
3602                 foreach my $ext (@exts) {
3603                         $mimemap{$ext} = $mimetype;
3604                 }
3605         }
3606         close($mh);
3607
3608         $filename =~ /\.([^.]*)$/;
3609         return $mimemap{$1};
3610 }
3611
3612 sub mimetype_guess {
3613         my $filename = shift;
3614         my $mime;
3615         $filename =~ /\./ or return undef;
3616
3617         if ($mimetypes_file) {
3618                 my $file = $mimetypes_file;
3619                 if ($file !~ m!^/!) { # if it is relative path
3620                         # it is relative to project
3621                         $file = "$projectroot/$project/$file";
3622                 }
3623                 $mime = mimetype_guess_file($filename, $file);
3624         }
3625         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3626         return $mime;
3627 }
3628
3629 sub blob_mimetype {
3630         my $fd = shift;
3631         my $filename = shift;
3632
3633         if ($filename) {
3634                 my $mime = mimetype_guess($filename);
3635                 $mime and return $mime;
3636         }
3637
3638         # just in case
3639         return $default_blob_plain_mimetype unless $fd;
3640
3641         if (-T $fd) {
3642                 return 'text/plain';
3643         } elsif (! $filename) {
3644                 return 'application/octet-stream';
3645         } elsif ($filename =~ m/\.png$/i) {
3646                 return 'image/png';
3647         } elsif ($filename =~ m/\.gif$/i) {
3648                 return 'image/gif';
3649         } elsif ($filename =~ m/\.jpe?g$/i) {
3650                 return 'image/jpeg';
3651         } else {
3652                 return 'application/octet-stream';
3653         }
3654 }
3655
3656 sub blob_contenttype {
3657         my ($fd, $file_name, $type) = @_;
3658
3659         $type ||= blob_mimetype($fd, $file_name);
3660         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3661                 $type .= "; charset=$default_text_plain_charset";
3662         }
3663
3664         return $type;
3665 }
3666
3667 # guess file syntax for syntax highlighting; return undef if no highlighting
3668 # the name of syntax can (in the future) depend on syntax highlighter used
3669 sub guess_file_syntax {
3670         my ($highlight, $mimetype, $file_name) = @_;
3671         return undef unless ($highlight && defined $file_name);
3672         my $basename = basename($file_name, '.in');
3673         return $highlight_basename{$basename}
3674                 if exists $highlight_basename{$basename};
3675
3676         $basename =~ /\.([^.]*)$/;
3677         my $ext = $1 or return undef;
3678         return $highlight_ext{$ext}
3679                 if exists $highlight_ext{$ext};
3680
3681         return undef;
3682 }
3683
3684 # run highlighter and return FD of its output,
3685 # or return original FD if no highlighting
3686 sub run_highlighter {
3687         my ($fd, $highlight, $syntax) = @_;
3688         return $fd unless ($highlight && defined $syntax);
3689
3690         close $fd;
3691         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3692                   quote_command($highlight_bin).
3693                   " --replace-tabs=8 --fragment --syntax $syntax |"
3694                 or die_error(500, "Couldn't open file or run syntax highlighter");
3695         return $fd;
3696 }
3697
3698 ## ======================================================================
3699 ## functions printing HTML: header, footer, error page
3700
3701 sub get_page_title {
3702         my $title = to_utf8($site_name);
3703
3704         return $title unless (defined $project);
3705         $title .= " - " . to_utf8($project);
3706
3707         return $title unless (defined $action);
3708         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3709
3710         return $title unless (defined $file_name);
3711         $title .= " - " . esc_path($file_name);
3712         if ($action eq "tree" && $file_name !~ m|/$|) {
3713                 $title .= "/";
3714         }
3715
3716         return $title;
3717 }
3718
3719 sub get_content_type_html {
3720         # require explicit support from the UA if we are to send the page as
3721         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3722         # we have to do this because MSIE sometimes globs '*/*', pretending to
3723         # support xhtml+xml but choking when it gets what it asked for.
3724         if (defined $cgi->http('HTTP_ACCEPT') &&
3725             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3726             $cgi->Accept('application/xhtml+xml') != 0) {
3727                 return 'application/xhtml+xml';
3728         } else {
3729                 return 'text/html';
3730         }
3731 }
3732
3733 sub print_feed_meta {
3734         if (defined $project) {
3735                 my %href_params = get_feed_info();
3736                 if (!exists $href_params{'-title'}) {
3737                         $href_params{'-title'} = 'log';
3738                 }
3739
3740                 foreach my $format (qw(RSS Atom)) {
3741                         my $type = lc($format);
3742                         my %link_attr = (
3743                                 '-rel' => 'alternate',
3744                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3745                                 '-type' => "application/$type+xml"
3746                         );
3747
3748                         $href_params{'action'} = $type;
3749                         $link_attr{'-href'} = href(%href_params);
3750                         print "<link ".
3751                               "rel=\"$link_attr{'-rel'}\" ".
3752                               "title=\"$link_attr{'-title'}\" ".
3753                               "href=\"$link_attr{'-href'}\" ".
3754                               "type=\"$link_attr{'-type'}\" ".
3755                               "/>\n";
3756
3757                         $href_params{'extra_options'} = '--no-merges';
3758                         $link_attr{'-href'} = href(%href_params);
3759                         $link_attr{'-title'} .= ' (no merges)';
3760                         print "<link ".
3761                               "rel=\"$link_attr{'-rel'}\" ".
3762                               "title=\"$link_attr{'-title'}\" ".
3763                               "href=\"$link_attr{'-href'}\" ".
3764                               "type=\"$link_attr{'-type'}\" ".
3765                               "/>\n";
3766                 }
3767
3768         } else {
3769                 printf('<link rel="alternate" title="%s projects list" '.
3770                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3771                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3772                 printf('<link rel="alternate" title="%s projects feeds" '.
3773                        'href="%s" type="text/x-opml" />'."\n",
3774                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3775         }
3776 }
3777
3778 sub print_header_links {
3779         my $status = shift;
3780
3781         # print out each stylesheet that exist, providing backwards capability
3782         # for those people who defined $stylesheet in a config file
3783         if (defined $stylesheet) {
3784                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3785         } else {
3786                 foreach my $stylesheet (@stylesheets) {
3787                         next unless $stylesheet;
3788                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3789                 }
3790         }
3791         print_feed_meta()
3792                 if ($status eq '200 OK');
3793         if (defined $favicon) {
3794                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3795         }
3796 }
3797
3798 sub print_nav_breadcrumbs {
3799         my %opts = @_;
3800
3801         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3802         if (defined $project) {
3803                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3804                 if (defined $action) {
3805                         my $action_print = $action ;
3806                         if (defined $opts{-action_extra}) {
3807                                 $action_print = $cgi->a({-href => href(action=>$action)},
3808                                         $action);
3809                         }
3810                         print " / $action_print";
3811                 }
3812                 if (defined $opts{-action_extra}) {
3813                         print " / $opts{-action_extra}";
3814                 }
3815                 print "\n";
3816         }
3817 }
3818
3819 sub print_search_form {
3820         if (!defined $searchtext) {
3821                 $searchtext = "";
3822         }
3823         my $search_hash;
3824         if (defined $hash_base) {
3825                 $search_hash = $hash_base;
3826         } elsif (defined $hash) {
3827                 $search_hash = $hash;
3828         } else {
3829                 $search_hash = "HEAD";
3830         }
3831         my $action = $my_uri;
3832         my $use_pathinfo = gitweb_check_feature('pathinfo');
3833         if ($use_pathinfo) {
3834                 $action .= "/".esc_url($project);
3835         }
3836         print $cgi->startform(-method => "get", -action => $action) .
3837               "<div class=\"search\">\n" .
3838               (!$use_pathinfo &&
3839               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3840               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3841               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3842               $cgi->popup_menu(-name => 'st', -default => 'commit',
3843                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3844               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3845               " search:\n",
3846               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3847               "<span title=\"Extended regular expression\">" .
3848               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3849                              -checked => $search_use_regexp) .
3850               "</span>" .
3851               "</div>" .
3852               $cgi->end_form() . "\n";
3853 }
3854
3855 sub git_header_html {
3856         my $status = shift || "200 OK";
3857         my $expires = shift;
3858         my %opts = @_;
3859
3860         my $title = get_page_title();
3861         my $content_type = get_content_type_html();
3862         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3863                            -status=> $status, -expires => $expires)
3864                 unless ($opts{'-no_http_header'});
3865         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3866         print <<EOF;
3867 <?xml version="1.0" encoding="utf-8"?>
3868 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3869 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3870 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3871 <!-- git core binaries version $git_version -->
3872 <head>
3873 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3874 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3875 <meta name="robots" content="index, nofollow"/>
3876 <title>$title</title>
3877 EOF
3878         # the stylesheet, favicon etc urls won't work correctly with path_info
3879         # unless we set the appropriate base URL
3880         if ($ENV{'PATH_INFO'}) {
3881                 print "<base href=\"".esc_url($base_url)."\" />\n";
3882         }
3883         print_header_links($status);
3884
3885         if (defined $site_html_head_string) {
3886                 print to_utf8($site_html_head_string);
3887         }
3888
3889         print "</head>\n" .
3890               "<body>\n";
3891
3892         if (defined $site_header && -f $site_header) {
3893                 insert_file($site_header);
3894         }
3895
3896         print "<div class=\"page_header\">\n";
3897         if (defined $logo) {
3898                 print $cgi->a({-href => esc_url($logo_url),
3899                                -title => $logo_label},
3900                               $cgi->img({-src => esc_url($logo),
3901                                          -width => 72, -height => 27,
3902                                          -alt => "git",
3903                                          -class => "logo"}));
3904         }
3905         print_nav_breadcrumbs(%opts);
3906         print "</div>\n";
3907
3908         my $have_search = gitweb_check_feature('search');
3909         if (defined $project && $have_search) {
3910                 print_search_form();
3911         }
3912 }
3913
3914 sub git_footer_html {
3915         my $feed_class = 'rss_logo';
3916
3917         print "<div class=\"page_footer\">\n";
3918         if (defined $project) {
3919                 my $descr = git_get_project_description($project);
3920                 if (defined $descr) {
3921                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3922                 }
3923
3924                 my %href_params = get_feed_info();
3925                 if (!%href_params) {
3926                         $feed_class .= ' generic';
3927                 }
3928                 $href_params{'-title'} ||= 'log';
3929
3930                 foreach my $format (qw(RSS Atom)) {
3931                         $href_params{'action'} = lc($format);
3932                         print $cgi->a({-href => href(%href_params),
3933                                       -title => "$href_params{'-title'} $format feed",
3934                                       -class => $feed_class}, $format)."\n";
3935                 }
3936
3937         } else {
3938                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3939                               -class => $feed_class}, "OPML") . " ";
3940                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3941                               -class => $feed_class}, "TXT") . "\n";
3942         }
3943         print "</div>\n"; # class="page_footer"
3944
3945         if (defined $t0 && gitweb_check_feature('timed')) {
3946                 print "<div id=\"generating_info\">\n";
3947                 print 'This page took '.
3948                       '<span id="generating_time" class="time_span">'.
3949                       tv_interval($t0, [ gettimeofday() ]).
3950                       ' seconds </span>'.
3951                       ' and '.
3952                       '<span id="generating_cmd">'.
3953                       $number_of_git_cmds.
3954                       '</span> git commands '.
3955                       " to generate.\n";
3956                 print "</div>\n"; # class="page_footer"
3957         }
3958
3959         if (defined $site_footer && -f $site_footer) {
3960                 insert_file($site_footer);
3961         }
3962
3963         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3964         if (defined $action &&
3965             $action eq 'blame_incremental') {
3966                 print qq!<script type="text/javascript">\n!.
3967                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3968                       qq!           "!. href() .qq!");\n!.
3969                       qq!</script>\n!;
3970         } else {
3971                 my ($jstimezone, $tz_cookie, $datetime_class) =
3972                         gitweb_get_feature('javascript-timezone');
3973
3974                 print qq!<script type="text/javascript">\n!.
3975                       qq!window.onload = function () {\n!;
3976                 if (gitweb_check_feature('javascript-actions')) {
3977                         print qq!       fixLinks();\n!;
3978                 }
3979                 if ($jstimezone && $tz_cookie && $datetime_class) {
3980                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
3981                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
3982                 }
3983                 print qq!};\n!.
3984                       qq!</script>\n!;
3985         }
3986
3987         print "</body>\n" .
3988               "</html>";
3989 }
3990
3991 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3992 # Example: die_error(404, 'Hash not found')
3993 # By convention, use the following status codes (as defined in RFC 2616):
3994 # 400: Invalid or missing CGI parameters, or
3995 #      requested object exists but has wrong type.
3996 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3997 #      this server or project.
3998 # 404: Requested object/revision/project doesn't exist.
3999 # 500: The server isn't configured properly, or
4000 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4001 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4002 # 503: The server is currently unavailable (because it is overloaded,
4003 #      or down for maintenance).  Generally, this is a temporary state.
4004 sub die_error {
4005         my $status = shift || 500;
4006         my $error = esc_html(shift) || "Internal Server Error";
4007         my $extra = shift;
4008         my %opts = @_;
4009
4010         my %http_responses = (
4011                 400 => '400 Bad Request',
4012                 403 => '403 Forbidden',
4013                 404 => '404 Not Found',
4014                 500 => '500 Internal Server Error',
4015                 503 => '503 Service Unavailable',
4016         );
4017         git_header_html($http_responses{$status}, undef, %opts);
4018         print <<EOF;
4019 <div class="page_body">
4020 <br /><br />
4021 $status - $error
4022 <br />
4023 EOF
4024         if (defined $extra) {
4025                 print "<hr />\n" .
4026                       "$extra\n";
4027         }
4028         print "</div>\n";
4029
4030         git_footer_html();
4031         goto DONE_GITWEB
4032                 unless ($opts{'-error_handler'});
4033 }
4034
4035 ## ----------------------------------------------------------------------
4036 ## functions printing or outputting HTML: navigation
4037
4038 sub git_print_page_nav {
4039         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4040         $extra = '' if !defined $extra; # pager or formats
4041
4042         my @navs = qw(summary shortlog log commit commitdiff tree);
4043         if ($suppress) {
4044                 @navs = grep { $_ ne $suppress } @navs;
4045         }
4046
4047         my %arg = map { $_ => {action=>$_} } @navs;
4048         if (defined $head) {
4049                 for (qw(commit commitdiff)) {
4050                         $arg{$_}{'hash'} = $head;
4051                 }
4052                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4053                         for (qw(shortlog log)) {
4054                                 $arg{$_}{'hash'} = $head;
4055                         }
4056                 }
4057         }
4058
4059         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4060         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4061
4062         my @actions = gitweb_get_feature('actions');
4063         my %repl = (
4064                 '%' => '%',
4065                 'n' => $project,         # project name
4066                 'f' => $git_dir,         # project path within filesystem
4067                 'h' => $treehead || '',  # current hash ('h' parameter)
4068                 'b' => $treebase || '',  # hash base ('hb' parameter)
4069         );
4070         while (@actions) {
4071                 my ($label, $link, $pos) = splice(@actions,0,3);
4072                 # insert
4073                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4074                 # munch munch
4075                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4076                 $arg{$label}{'_href'} = $link;
4077         }
4078
4079         print "<div class=\"page_nav\">\n" .
4080                 (join " | ",
4081                  map { $_ eq $current ?
4082                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4083                  } @navs);
4084         print "<br/>\n$extra<br/>\n" .
4085               "</div>\n";
4086 }
4087
4088 # returns a submenu for the nagivation of the refs views (tags, heads,
4089 # remotes) with the current view disabled and the remotes view only
4090 # available if the feature is enabled
4091 sub format_ref_views {
4092         my ($current) = @_;
4093         my @ref_views = qw{tags heads};
4094         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4095         return join " | ", map {
4096                 $_ eq $current ? $_ :
4097                 $cgi->a({-href => href(action=>$_)}, $_)
4098         } @ref_views
4099 }
4100
4101 sub format_paging_nav {
4102         my ($action, $page, $has_next_link) = @_;
4103         my $paging_nav;
4104
4105
4106         if ($page > 0) {
4107                 $paging_nav .=
4108                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4109                         " &sdot; " .
4110                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4111                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4112         } else {
4113                 $paging_nav .= "first &sdot; prev";
4114         }
4115
4116         if ($has_next_link) {
4117                 $paging_nav .= " &sdot; " .
4118                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4119                                  -accesskey => "n", -title => "Alt-n"}, "next");
4120         } else {
4121                 $paging_nav .= " &sdot; next";
4122         }
4123
4124         return $paging_nav;
4125 }
4126
4127 ## ......................................................................
4128 ## functions printing or outputting HTML: div
4129
4130 sub git_print_header_div {
4131         my ($action, $title, $hash, $hash_base) = @_;
4132         my %args = ();
4133
4134         $args{'action'} = $action;
4135         $args{'hash'} = $hash if $hash;
4136         $args{'hash_base'} = $hash_base if $hash_base;
4137
4138         print "<div class=\"header\">\n" .
4139               $cgi->a({-href => href(%args), -class => "title"},
4140               $title ? $title : $action) .
4141               "\n</div>\n";
4142 }
4143
4144 sub format_repo_url {
4145         my ($name, $url) = @_;
4146         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4147 }
4148
4149 # Group output by placing it in a DIV element and adding a header.
4150 # Options for start_div() can be provided by passing a hash reference as the
4151 # first parameter to the function.
4152 # Options to git_print_header_div() can be provided by passing an array
4153 # reference. This must follow the options to start_div if they are present.
4154 # The content can be a scalar, which is output as-is, a scalar reference, which
4155 # is output after html escaping, an IO handle passed either as *handle or
4156 # *handle{IO}, or a function reference. In the latter case all following
4157 # parameters will be taken as argument to the content function call.
4158 sub git_print_section {
4159         my ($div_args, $header_args, $content);
4160         my $arg = shift;
4161         if (ref($arg) eq 'HASH') {
4162                 $div_args = $arg;
4163                 $arg = shift;
4164         }
4165         if (ref($arg) eq 'ARRAY') {
4166                 $header_args = $arg;
4167                 $arg = shift;
4168         }
4169         $content = $arg;
4170
4171         print $cgi->start_div($div_args);
4172         git_print_header_div(@$header_args);
4173
4174         if (ref($content) eq 'CODE') {
4175                 $content->(@_);
4176         } elsif (ref($content) eq 'SCALAR') {
4177                 print esc_html($$content);
4178         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4179                 print <$content>;
4180         } elsif (!ref($content) && defined($content)) {
4181                 print $content;
4182         }
4183
4184         print $cgi->end_div;
4185 }
4186
4187 sub format_timestamp_html {
4188         my $date = shift;
4189         my $strtime = $date->{'rfc2822'};
4190
4191         my (undef, undef, $datetime_class) =
4192                 gitweb_get_feature('javascript-timezone');
4193         if ($datetime_class) {
4194                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4195         }
4196
4197         my $localtime_format = '(%02d:%02d %s)';
4198         if ($date->{'hour_local'} < 6) {
4199                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4200         }
4201         $strtime .= ' ' .
4202                     sprintf($localtime_format,
4203                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4204
4205         return $strtime;
4206 }
4207
4208 # Outputs the author name and date in long form
4209 sub git_print_authorship {
4210         my $co = shift;
4211         my %opts = @_;
4212         my $tag = $opts{-tag} || 'div';
4213         my $author = $co->{'author_name'};
4214
4215         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4216         print "<$tag class=\"author_date\">" .
4217               format_search_author($author, "author", esc_html($author)) .
4218               " [".format_timestamp_html(\%ad)."]".
4219               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4220               "</$tag>\n";
4221 }
4222
4223 # Outputs table rows containing the full author or committer information,
4224 # in the format expected for 'commit' view (& similar).
4225 # Parameters are a commit hash reference, followed by the list of people
4226 # to output information for. If the list is empty it defaults to both
4227 # author and committer.
4228 sub git_print_authorship_rows {
4229         my $co = shift;
4230         # too bad we can't use @people = @_ || ('author', 'committer')
4231         my @people = @_;
4232         @people = ('author', 'committer') unless @people;
4233         foreach my $who (@people) {
4234                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4235                 print "<tr><td>$who</td><td>" .
4236                       format_search_author($co->{"${who}_name"}, $who,
4237                                            esc_html($co->{"${who}_name"})) . " " .
4238                       format_search_author($co->{"${who}_email"}, $who,
4239                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4240                       "</td><td rowspan=\"2\">" .
4241                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4242                       "</td></tr>\n" .
4243                       "<tr>" .
4244                       "<td></td><td>" .
4245                       format_timestamp_html(\%wd) .
4246                       "</td>" .
4247                       "</tr>\n";
4248         }
4249 }
4250
4251 sub git_print_page_path {
4252         my $name = shift;
4253         my $type = shift;
4254         my $hb = shift;
4255
4256
4257         print "<div class=\"page_path\">";
4258         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4259                       -title => 'tree root'}, to_utf8("[$project]"));
4260         print " / ";
4261         if (defined $name) {
4262                 my @dirname = split '/', $name;
4263                 my $basename = pop @dirname;
4264                 my $fullname = '';
4265
4266                 foreach my $dir (@dirname) {
4267                         $fullname .= ($fullname ? '/' : '') . $dir;
4268                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4269                                                      hash_base=>$hb),
4270                                       -title => $fullname}, esc_path($dir));
4271                         print " / ";
4272                 }
4273                 if (defined $type && $type eq 'blob') {
4274                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4275                                                      hash_base=>$hb),
4276                                       -title => $name}, esc_path($basename));
4277                         print '&nbsp;&nbsp;&nbsp;&nbsp;
4278 <a id="lineNoToggle" href="#" onclick="toggleLineNumbers();"></a>
4279 <script>
4280 function toggleLineNumbers() {
4281         e = document.getElementById("lineNoStyle");
4282         e2 = document.getElementById("lineNoToggle");
4283         if (e2.innerHTML == "[Hide line numbers]") {
4284                 e.innerHTML = ".linenr { display:none; }";
4285                 e2.innerHTML = "[Show line numbers]";
4286         }
4287         else {
4288                 e.innerHTML = "";
4289                 e2.innerHTML = "[Hide line numbers]";
4290         }
4291 }
4292 var style = document.createElement("style");
4293 style.setAttribute("id", "lineNoStyle");
4294 document.getElementsByTagName("head")[0].appendChild(style);
4295 toggleLineNumbers();
4296 </script>
4297 ';
4298                 } elsif (defined $type && $type eq 'tree') {
4299                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4300                                                      hash_base=>$hb),
4301                                       -title => $name}, esc_path($basename));
4302                         print " / ";
4303                 } else {
4304                         print esc_path($basename);
4305                 }
4306         }
4307         print "<br/></div>\n";
4308 }
4309
4310 sub git_print_log {
4311         my $log = shift;
4312         my %opts = @_;
4313
4314         if ($opts{'-remove_title'}) {
4315                 # remove title, i.e. first line of log
4316                 shift @$log;
4317         }
4318         # remove leading empty lines
4319         while (defined $log->[0] && $log->[0] eq "") {
4320                 shift @$log;
4321         }
4322
4323         # print log
4324         my $signoff = 0;
4325         my $empty = 0;
4326         foreach my $line (@$log) {
4327                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4328                         $signoff = 1;
4329                         $empty = 0;
4330                         if (! $opts{'-remove_signoff'}) {
4331                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4332                                 next;
4333                         } else {
4334                                 # remove signoff lines
4335                                 next;
4336                         }
4337                 } else {
4338                         $signoff = 0;
4339                 }
4340
4341                 # print only one empty line
4342                 # do not print empty line after signoff
4343                 if ($line eq "") {
4344                         next if ($empty || $signoff);
4345                         $empty = 1;
4346                 } else {
4347                         $empty = 0;
4348                 }
4349
4350                 print format_log_line_html($line) . "<br/>\n";
4351         }
4352
4353         if ($opts{'-final_empty_line'}) {
4354                 # end with single empty line
4355                 print "<br/>\n" unless $empty;
4356         }
4357 }
4358
4359 # return link target (what link points to)
4360 sub git_get_link_target {
4361         my $hash = shift;
4362         my $link_target;
4363
4364         # read link
4365         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4366                 or return;
4367         {
4368                 local $/ = undef;
4369                 $link_target = <$fd>;
4370         }
4371         close $fd
4372                 or return;
4373
4374         return $link_target;
4375 }
4376
4377 # given link target, and the directory (basedir) the link is in,
4378 # return target of link relative to top directory (top tree);
4379 # return undef if it is not possible (including absolute links).
4380 sub normalize_link_target {
4381         my ($link_target, $basedir) = @_;
4382
4383         # absolute symlinks (beginning with '/') cannot be normalized
4384         return if (substr($link_target, 0, 1) eq '/');
4385
4386         # normalize link target to path from top (root) tree (dir)
4387         my $path;
4388         if ($basedir) {
4389                 $path = $basedir . '/' . $link_target;
4390         } else {
4391                 # we are in top (root) tree (dir)
4392                 $path = $link_target;
4393         }
4394
4395         # remove //, /./, and /../
4396         my @path_parts;
4397         foreach my $part (split('/', $path)) {
4398                 # discard '.' and ''
4399                 next if (!$part || $part eq '.');
4400                 # handle '..'
4401                 if ($part eq '..') {
4402                         if (@path_parts) {
4403                                 pop @path_parts;
4404                         } else {
4405                                 # link leads outside repository (outside top dir)
4406                                 return;
4407                         }
4408                 } else {
4409                         push @path_parts, $part;
4410                 }
4411         }
4412         $path = join('/', @path_parts);
4413
4414         return $path;
4415 }
4416
4417 # print tree entry (row of git_tree), but without encompassing <tr> element
4418 sub git_print_tree_entry {
4419         my ($t, $basedir, $hash_base, $have_blame) = @_;
4420
4421         my %base_key = ();
4422         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4423
4424         # The format of a table row is: mode list link.  Where mode is
4425         # the mode of the entry, list is the name of the entry, an href,
4426         # and link is the action links of the entry.
4427
4428         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4429         if (exists $t->{'size'}) {
4430                 print "<td class=\"size\">$t->{'size'}</td>\n";
4431         }
4432         if ($t->{'type'} eq "blob") {
4433                 print "<td class=\"list\">" .
4434                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4435                                                file_name=>"$basedir$t->{'name'}", %base_key),
4436                                 -class => "list"}, esc_path($t->{'name'}));
4437                 if (S_ISLNK(oct $t->{'mode'})) {
4438                         my $link_target = git_get_link_target($t->{'hash'});
4439                         if ($link_target) {
4440                                 my $norm_target = normalize_link_target($link_target, $basedir);
4441                                 if (defined $norm_target) {
4442                                         print " -> " .
4443                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4444                                                                      file_name=>$norm_target),
4445                                                        -title => $norm_target}, esc_path($link_target));
4446                                 } else {
4447                                         print " -> " . esc_path($link_target);
4448                                 }
4449                         }
4450                 }
4451                 print "</td>\n";
4452                 print "<td class=\"link\">";
4453                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4454                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4455                               "blob");
4456                 if ($have_blame) {
4457                         print " | " .
4458                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4459                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4460                                       "blame");
4461                 }
4462                 if (defined $hash_base) {
4463                         print " | " .
4464                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4465                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4466                                       "history");
4467                 }
4468                 print " | " .
4469                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4470                                                file_name=>"$basedir$t->{'name'}")},
4471                                 "raw");
4472                 print "</td>\n";
4473
4474         } elsif ($t->{'type'} eq "tree") {
4475                 print "<td class=\"list\">";
4476                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4477                                              file_name=>"$basedir$t->{'name'}",
4478                                              %base_key)},
4479                               esc_path($t->{'name'}));
4480                 print "</td>\n";
4481                 print "<td class=\"link\">";
4482                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4483                                              file_name=>"$basedir$t->{'name'}",
4484                                              %base_key)},
4485                               "tree");
4486                 if (defined $hash_base) {
4487                         print " | " .
4488                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4489                                                      file_name=>"$basedir$t->{'name'}")},
4490                                       "history");
4491                 }
4492                 print "</td>\n";
4493         } else {
4494                 # unknown object: we can only present history for it
4495                 # (this includes 'commit' object, i.e. submodule support)
4496                 print "<td class=\"list\">" .
4497                       esc_path($t->{'name'}) .
4498                       "</td>\n";
4499                 print "<td class=\"link\">";
4500                 if (defined $hash_base) {
4501                         print $cgi->a({-href => href(action=>"history",
4502                                                      hash_base=>$hash_base,
4503                                                      file_name=>"$basedir$t->{'name'}")},
4504                                       "history");
4505                 }
4506                 print "</td>\n";
4507         }
4508 }
4509
4510 ## ......................................................................
4511 ## functions printing large fragments of HTML
4512
4513 # get pre-image filenames for merge (combined) diff
4514 sub fill_from_file_info {
4515         my ($diff, @parents) = @_;
4516
4517         $diff->{'from_file'} = [ ];
4518         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4519         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4520                 if ($diff->{'status'}[$i] eq 'R' ||
4521                     $diff->{'status'}[$i] eq 'C') {
4522                         $diff->{'from_file'}[$i] =
4523                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4524                 }
4525         }
4526
4527         return $diff;
4528 }
4529
4530 # is current raw difftree line of file deletion
4531 sub is_deleted {
4532         my $diffinfo = shift;
4533
4534         return $diffinfo->{'to_id'} eq ('0' x 40);
4535 }
4536
4537 # does patch correspond to [previous] difftree raw line
4538 # $diffinfo  - hashref of parsed raw diff format
4539 # $patchinfo - hashref of parsed patch diff format
4540 #              (the same keys as in $diffinfo)
4541 sub is_patch_split {
4542         my ($diffinfo, $patchinfo) = @_;
4543
4544         return defined $diffinfo && defined $patchinfo
4545                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4546 }
4547
4548
4549 sub git_difftree_body {
4550         my ($difftree, $hash, @parents) = @_;
4551         my ($parent) = $parents[0];
4552         my $have_blame = gitweb_check_feature('blame');
4553         print "<div class=\"list_head\">\n";
4554         if ($#{$difftree} > 10) {
4555                 print(($#{$difftree} + 1) . " files changed:\n");
4556         }
4557         print "</div>\n";
4558
4559         print "<table class=\"" .
4560               (@parents > 1 ? "combined " : "") .
4561               "diff_tree\">\n";
4562
4563         # header only for combined diff in 'commitdiff' view
4564         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4565         if ($has_header) {
4566                 # table header
4567                 print "<thead><tr>\n" .
4568                        "<th></th><th></th>\n"; # filename, patchN link
4569                 for (my $i = 0; $i < @parents; $i++) {
4570                         my $par = $parents[$i];
4571                         print "<th>" .
4572                               $cgi->a({-href => href(action=>"commitdiff",
4573                                                      hash=>$hash, hash_parent=>$par),
4574                                        -title => 'commitdiff to parent number ' .
4575                                                   ($i+1) . ': ' . substr($par,0,7)},
4576                                       $i+1) .
4577                               "&nbsp;</th>\n";
4578                 }
4579                 print "</tr></thead>\n<tbody>\n";
4580         }
4581
4582         my $alternate = 1;
4583         my $patchno = 0;
4584         foreach my $line (@{$difftree}) {
4585                 my $diff = parsed_difftree_line($line);
4586
4587                 if ($alternate) {
4588                         print "<tr class=\"dark\">\n";
4589                 } else {
4590                         print "<tr class=\"light\">\n";
4591                 }
4592                 $alternate ^= 1;
4593
4594                 if (exists $diff->{'nparents'}) { # combined diff
4595
4596                         fill_from_file_info($diff, @parents)
4597                                 unless exists $diff->{'from_file'};
4598
4599                         if (!is_deleted($diff)) {
4600                                 # file exists in the result (child) commit
4601                                 print "<td>" .
4602                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4603                                                              file_name=>$diff->{'to_file'},
4604                                                              hash_base=>$hash),
4605                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4606                                       "</td>\n";
4607                         } else {
4608                                 print "<td>" .
4609                                       esc_path($diff->{'to_file'}) .
4610                                       "</td>\n";
4611                         }
4612
4613                         if ($action eq 'commitdiff') {
4614                                 # link to patch
4615                                 $patchno++;
4616                                 print "<td class=\"link\">" .
4617                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4618                                               "patch") .
4619                                       " | " .
4620                                       "</td>\n";
4621                         }
4622
4623                         my $has_history = 0;
4624                         my $not_deleted = 0;
4625                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4626                                 my $hash_parent = $parents[$i];
4627                                 my $from_hash = $diff->{'from_id'}[$i];
4628                                 my $from_path = $diff->{'from_file'}[$i];
4629                                 my $status = $diff->{'status'}[$i];
4630
4631                                 $has_history ||= ($status ne 'A');
4632                                 $not_deleted ||= ($status ne 'D');
4633
4634                                 if ($status eq 'A') {
4635                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4636                                 } elsif ($status eq 'D') {
4637                                         print "<td class=\"link\">" .
4638                                               $cgi->a({-href => href(action=>"blob",
4639                                                                      hash_base=>$hash,
4640                                                                      hash=>$from_hash,
4641                                                                      file_name=>$from_path)},
4642                                                       "blob" . ($i+1)) .
4643                                               " | </td>\n";
4644                                 } else {
4645                                         if ($diff->{'to_id'} eq $from_hash) {
4646                                                 print "<td class=\"link nochange\">";
4647                                         } else {
4648                                                 print "<td class=\"link\">";
4649                                         }
4650                                         print $cgi->a({-href => href(action=>"blobdiff",
4651                                                                      hash=>$diff->{'to_id'},
4652                                                                      hash_parent=>$from_hash,
4653                                                                      hash_base=>$hash,
4654                                                                      hash_parent_base=>$hash_parent,
4655                                                                      file_name=>$diff->{'to_file'},
4656                                                                      file_parent=>$from_path)},
4657                                                       "diff" . ($i+1)) .
4658                                               " | </td>\n";
4659                                 }
4660                         }
4661
4662                         print "<td class=\"link\">";
4663                         if ($not_deleted) {
4664                                 print $cgi->a({-href => href(action=>"blob",
4665                                                              hash=>$diff->{'to_id'},
4666                                                              file_name=>$diff->{'to_file'},
4667                                                              hash_base=>$hash)},
4668                                               "blob");
4669                                 print " | " if ($has_history);
4670                         }
4671                         if ($has_history) {
4672                                 print $cgi->a({-href => href(action=>"history",
4673                                                              file_name=>$diff->{'to_file'},
4674                                                              hash_base=>$hash)},
4675                                               "history");
4676                         }
4677                         print "</td>\n";
4678
4679                         print "</tr>\n";
4680                         next; # instead of 'else' clause, to avoid extra indent
4681                 }
4682                 # else ordinary diff
4683
4684                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4685                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4686                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4687                         $to_mode_oct = oct $diff->{'to_mode'};
4688                         if (S_ISREG($to_mode_oct)) { # only for regular file
4689                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4690                         }
4691                         $to_file_type = file_type($diff->{'to_mode'});
4692                 }
4693                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4694                         $from_mode_oct = oct $diff->{'from_mode'};
4695                         if (S_ISREG($from_mode_oct)) { # only for regular file
4696                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4697                         }
4698                         $from_file_type = file_type($diff->{'from_mode'});
4699                 }
4700
4701                 if ($diff->{'status'} eq "A") { # created
4702                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4703                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4704                         $mode_chng   .= "]</span>";
4705                         print "<td>";
4706                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4707                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4708                                       -class => "list"}, esc_path($diff->{'file'}));
4709                         print "</td>\n";
4710                         print "<td>$mode_chng</td>\n";
4711                         print "<td class=\"link\">";
4712                         if ($action eq 'commitdiff') {
4713                                 # link to patch
4714                                 $patchno++;
4715                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4716                                               "patch") .
4717                                       " | ";
4718                         }
4719                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4720                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4721                                       "blob");
4722                         print "</td>\n";
4723
4724                 } elsif ($diff->{'status'} eq "D") { # deleted
4725                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4726                         print "<td>";
4727                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4728                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4729                                        -class => "list"}, esc_path($diff->{'file'}));
4730                         print "</td>\n";
4731                         print "<td>$mode_chng</td>\n";
4732                         print "<td class=\"link\">";
4733                         if ($action eq 'commitdiff') {
4734                                 # link to patch
4735                                 $patchno++;
4736                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4737                                               "patch") .
4738                                       " | ";
4739                         }
4740                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4741                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4742                                       "blob") . " | ";
4743                         if ($have_blame) {
4744                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4745                                                              file_name=>$diff->{'file'})},
4746                                               "blame") . " | ";
4747                         }
4748                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4749                                                      file_name=>$diff->{'file'})},
4750                                       "history");
4751                         print "</td>\n";
4752
4753                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4754                         my $mode_chnge = "";
4755                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4756                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4757                                 if ($from_file_type ne $to_file_type) {
4758                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4759                                 }
4760                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4761                                         if ($from_mode_str && $to_mode_str) {
4762                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4763                                         } elsif ($to_mode_str) {
4764                                                 $mode_chnge .= " mode: $to_mode_str";
4765                                         }
4766                                 }
4767                                 $mode_chnge .= "]</span>\n";
4768                         }
4769                         print "<td>";
4770                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4771                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4772                                       -class => "list"}, esc_path($diff->{'file'}));
4773                         print "</td>\n";
4774                         print "<td>$mode_chnge</td>\n";
4775                         print "<td class=\"link\">";
4776                         if ($action eq 'commitdiff') {
4777                                 # link to patch
4778                                 $patchno++;
4779                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4780                                               "patch") .
4781                                       " | ";
4782                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4783                                 # "commit" view and modified file (not onlu mode changed)
4784                                 print $cgi->a({-href => href(action=>"blobdiff",
4785                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4786                                                              hash_base=>$hash, hash_parent_base=>$parent,
4787                                                              file_name=>$diff->{'file'})},
4788                                               "diff") .
4789                                       " | ";
4790                         }
4791                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4792                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4793                                        "blob") . " | ";
4794                         if ($have_blame) {
4795                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4796                                                              file_name=>$diff->{'file'})},
4797                                               "blame") . " | ";
4798                         }
4799                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4800                                                      file_name=>$diff->{'file'})},
4801                                       "history");
4802                         print "</td>\n";
4803
4804                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4805                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4806                         my $nstatus = $status_name{$diff->{'status'}};
4807                         my $mode_chng = "";
4808                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4809                                 # mode also for directories, so we cannot use $to_mode_str
4810                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4811                         }
4812                         print "<td>" .
4813                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4814                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4815                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4816                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4817                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4818                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4819                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4820                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4821                               "<td class=\"link\">";
4822                         if ($action eq 'commitdiff') {
4823                                 # link to patch
4824                                 $patchno++;
4825                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4826                                               "patch") .
4827                                       " | ";
4828                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4829                                 # "commit" view and modified file (not only pure rename or copy)
4830                                 print $cgi->a({-href => href(action=>"blobdiff",
4831                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4832                                                              hash_base=>$hash, hash_parent_base=>$parent,
4833                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4834                                               "diff") .
4835                                       " | ";
4836                         }
4837                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4838                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4839                                       "blob") . " | ";
4840                         if ($have_blame) {
4841                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4842                                                              file_name=>$diff->{'to_file'})},
4843                                               "blame") . " | ";
4844                         }
4845                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4846                                                     file_name=>$diff->{'to_file'})},
4847                                       "history");
4848                         print "</td>\n";
4849
4850                 } # we should not encounter Unmerged (U) or Unknown (X) status
4851                 print "</tr>\n";
4852         }
4853         print "</tbody>" if $has_header;
4854         print "</table>\n";
4855 }
4856
4857 sub git_patchset_body {
4858         my ($fd, $difftree, $hash, @hash_parents) = @_;
4859         my ($hash_parent) = $hash_parents[0];
4860
4861         my $is_combined = (@hash_parents > 1);
4862         my $patch_idx = 0;
4863         my $patch_number = 0;
4864         my $patch_line;
4865         my $diffinfo;
4866         my $to_name;
4867         my (%from, %to);
4868
4869         print "<div class=\"patchset\">\n";
4870
4871         # skip to first patch
4872         while ($patch_line = <$fd>) {
4873                 chomp $patch_line;
4874
4875                 last if ($patch_line =~ m/^diff /);
4876         }
4877
4878  PATCH:
4879         while ($patch_line) {
4880
4881                 # parse "git diff" header line
4882                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4883                         # $1 is from_name, which we do not use
4884                         $to_name = unquote($2);
4885                         $to_name =~ s!^b/!!;
4886                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4887                         # $1 is 'cc' or 'combined', which we do not use
4888                         $to_name = unquote($2);
4889                 } else {
4890                         $to_name = undef;
4891                 }
4892
4893                 # check if current patch belong to current raw line
4894                 # and parse raw git-diff line if needed
4895                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4896                         # this is continuation of a split patch
4897                         print "<div class=\"patch cont\">\n";
4898                 } else {
4899                         # advance raw git-diff output if needed
4900                         $patch_idx++ if defined $diffinfo;
4901
4902                         # read and prepare patch information
4903                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4904
4905                         # compact combined diff output can have some patches skipped
4906                         # find which patch (using pathname of result) we are at now;
4907                         if ($is_combined) {
4908                                 while ($to_name ne $diffinfo->{'to_file'}) {
4909                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4910                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4911                                               "</div>\n";  # class="patch"
4912
4913                                         $patch_idx++;
4914                                         $patch_number++;
4915
4916                                         last if $patch_idx > $#$difftree;
4917                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4918                                 }
4919                         }
4920
4921                         # modifies %from, %to hashes
4922                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4923
4924                         # this is first patch for raw difftree line with $patch_idx index
4925                         # we index @$difftree array from 0, but number patches from 1
4926                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4927                 }
4928
4929                 # git diff header
4930                 #assert($patch_line =~ m/^diff /) if DEBUG;
4931                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4932                 $patch_number++;
4933                 # print "git diff" header
4934                 print format_git_diff_header_line($patch_line, $diffinfo,
4935                                                   \%from, \%to);
4936
4937                 # print extended diff header
4938                 print "<div class=\"diff extended_header\">\n";
4939         EXTENDED_HEADER:
4940                 while ($patch_line = <$fd>) {
4941                         chomp $patch_line;
4942
4943                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4944
4945                         print format_extended_diff_header_line($patch_line, $diffinfo,
4946                                                                \%from, \%to);
4947                 }
4948                 print "</div>\n"; # class="diff extended_header"
4949
4950                 # from-file/to-file diff header
4951                 if (! $patch_line) {
4952                         print "</div>\n"; # class="patch"
4953                         last PATCH;
4954                 }
4955                 next PATCH if ($patch_line =~ m/^diff /);
4956                 #assert($patch_line =~ m/^---/) if DEBUG;
4957
4958                 my $last_patch_line = $patch_line;
4959                 $patch_line = <$fd>;
4960                 chomp $patch_line;
4961                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4962
4963                 print format_diff_from_to_header($last_patch_line, $patch_line,
4964                                                  $diffinfo, \%from, \%to,
4965                                                  @hash_parents);
4966
4967                 # the patch itself
4968         LINE:
4969                 while ($patch_line = <$fd>) {
4970                         chomp $patch_line;
4971
4972                         next PATCH if ($patch_line =~ m/^diff /);
4973
4974                         print format_diff_line($patch_line, \%from, \%to);
4975                 }
4976
4977         } continue {
4978                 print "</div>\n"; # class="patch"
4979         }
4980
4981         # for compact combined (--cc) format, with chunk and patch simplification
4982         # the patchset might be empty, but there might be unprocessed raw lines
4983         for (++$patch_idx if $patch_number > 0;
4984              $patch_idx < @$difftree;
4985              ++$patch_idx) {
4986                 # read and prepare patch information
4987                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4988
4989                 # generate anchor for "patch" links in difftree / whatchanged part
4990                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4991                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4992                       "</div>\n";  # class="patch"
4993
4994                 $patch_number++;
4995         }
4996
4997         if ($patch_number == 0) {
4998                 if (@hash_parents > 1) {
4999                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5000                 } else {
5001                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5002                 }
5003         }
5004
5005         print "</div>\n"; # class="patchset"
5006 }
5007
5008 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5009
5010 # fills project list info (age, description, owner, category, forks)
5011 # for each project in the list, removing invalid projects from
5012 # returned list
5013 # NOTE: modifies $projlist, but does not remove entries from it
5014 sub fill_project_list_info {
5015         my $projlist = shift;
5016         my @projects;
5017
5018         my $show_ctags = gitweb_check_feature('ctags');
5019  PROJECT:
5020         foreach my $pr (@$projlist) {
5021                 my (@activity) = git_get_last_activity($pr->{'path'});
5022                 unless (@activity) {
5023                         next PROJECT;
5024                 }
5025                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5026                 if (!defined $pr->{'descr'}) {
5027                         my $descr = git_get_project_description($pr->{'path'}) || "";
5028                         $descr = to_utf8($descr);
5029                         $pr->{'descr_long'} = $descr;
5030                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5031                 }
5032                 if (!defined $pr->{'owner'}) {
5033                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5034                 }
5035                 if ($show_ctags) {
5036                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5037                 }
5038                 if ($projects_list_group_categories && !defined $pr->{'category'}) {
5039                         my $cat = git_get_project_category($pr->{'path'}) ||
5040                                                            $project_list_default_category;
5041                         $pr->{'category'} = to_utf8($cat);
5042                 }
5043
5044                 push @projects, $pr;
5045         }
5046
5047         return @projects;
5048 }
5049
5050 sub sort_projects_list {
5051         my ($projlist, $order) = @_;
5052         my @projects;
5053
5054         my %order_info = (
5055                 project => { key => 'path', type => 'str' },
5056                 descr => { key => 'descr_long', type => 'str' },
5057                 owner => { key => 'owner', type => 'str' },
5058                 age => { key => 'age', type => 'num' }
5059         );
5060         my $oi = $order_info{$order};
5061         return @$projlist unless defined $oi;
5062         if ($oi->{'type'} eq 'str') {
5063                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5064         } else {
5065                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5066         }
5067
5068         return @projects;
5069 }
5070
5071 # returns a hash of categories, containing the list of project
5072 # belonging to each category
5073 sub build_projlist_by_category {
5074         my ($projlist, $from, $to) = @_;
5075         my %categories;
5076
5077         $from = 0 unless defined $from;
5078         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5079
5080         for (my $i = $from; $i <= $to; $i++) {
5081                 my $pr = $projlist->[$i];
5082                 push @{$categories{ $pr->{'category'} }}, $pr;
5083         }
5084
5085         return wantarray ? %categories : \%categories;
5086 }
5087
5088 # print 'sort by' <th> element, generating 'sort by $name' replay link
5089 # if that order is not selected
5090 sub print_sort_th {
5091         print format_sort_th(@_);
5092 }
5093
5094 sub format_sort_th {
5095         my ($name, $order, $header) = @_;
5096         my $sort_th = "";
5097         $header ||= ucfirst($name);
5098
5099         if ($order eq $name) {
5100                 $sort_th .= "<th>$header</th>\n";
5101         } else {
5102                 $sort_th .= "<th>" .
5103                             $cgi->a({-href => href(-replay=>1, order=>$name),
5104                                      -class => "header"}, $header) .
5105                             "</th>\n";
5106         }
5107
5108         return $sort_th;
5109 }
5110
5111 sub git_project_list_rows {
5112         my ($projlist, $from, $to, $check_forks) = @_;
5113
5114         $from = 0 unless defined $from;
5115         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5116
5117         my $alternate = 1;
5118         for (my $i = $from; $i <= $to; $i++) {
5119                 my $pr = $projlist->[$i];
5120
5121                 if ($alternate) {
5122                         print "<tr class=\"dark\">\n";
5123                 } else {
5124                         print "<tr class=\"light\">\n";
5125                 }
5126                 $alternate ^= 1;
5127
5128                 if ($check_forks) {
5129                         print "<td>";
5130                         if ($pr->{'forks'}) {
5131                                 my $nforks = scalar @{$pr->{'forks'}};
5132                                 if ($nforks > 0) {
5133                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5134                                                        -title => "$nforks forks"}, "+");
5135                                 } else {
5136                                         print $cgi->span({-title => "$nforks forks"}, "+");
5137                                 }
5138                         }
5139                         print "</td>\n";
5140                 }
5141                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5142                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5143                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5144                                         -class => "list", -title => $pr->{'descr_long'}},
5145                                         esc_html($pr->{'descr'})) . "</td>\n" .
5146                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5147                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5148                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5149                       "<td class=\"link\">" .
5150                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5151                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5152                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5153                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5154                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5155                       "</td>\n" .
5156                       "</tr>\n";
5157         }
5158 }
5159
5160 sub git_project_list_body {
5161         # actually uses global variable $project
5162         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5163         my @projects = @$projlist;
5164
5165         my $check_forks = gitweb_check_feature('forks');
5166         my $show_ctags  = gitweb_check_feature('ctags');
5167         my $tagfilter = $show_ctags ? $cgi->param('by_tag') : undef;
5168         $check_forks = undef
5169                 if ($tagfilter || $searchtext);
5170
5171         # filtering out forks before filling info allows to do less work
5172         @projects = filter_forks_from_projects_list(\@projects)
5173                 if ($check_forks);
5174         @projects = fill_project_list_info(\@projects);
5175         # searching projects require filling to be run before it
5176         @projects = search_projects_list(\@projects,
5177                                          'searchtext' => $searchtext,
5178                                          'tagfilter'  => $tagfilter)
5179                 if ($tagfilter || $searchtext);
5180
5181         $order ||= $default_projects_order;
5182         $from = 0 unless defined $from;
5183         $to = $#projects if (!defined $to || $#projects < $to);
5184
5185         # short circuit
5186         if ($from > $to) {
5187                 print "<center>\n".
5188                       "<b>No such projects found</b><br />\n".
5189                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5190                       "</center>\n<br />\n";
5191                 return;
5192         }
5193
5194         @projects = sort_projects_list(\@projects, $order);
5195
5196         if ($show_ctags) {
5197                 my $ctags = git_gather_all_ctags(\@projects);
5198                 my $cloud = git_populate_project_tagcloud($ctags);
5199                 print git_show_project_tagcloud($cloud, 64);
5200         }
5201
5202         print "<table class=\"project_list\">\n";
5203         unless ($no_header) {
5204                 print "<tr>\n";
5205                 if ($check_forks) {
5206                         print "<th></th>\n";
5207                 }
5208                 print_sort_th('project', $order, 'Project');
5209                 print_sort_th('descr', $order, 'Description');
5210                 print_sort_th('owner', $order, 'Owner');
5211                 print_sort_th('age', $order, 'Last Change');
5212                 print "<th></th>\n" . # for links
5213                       "</tr>\n";
5214         }
5215
5216         if ($projects_list_group_categories) {
5217                 # only display categories with projects in the $from-$to window
5218                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5219                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5220                 foreach my $cat (sort keys %categories) {
5221                         unless ($cat eq "") {
5222                                 print "<tr>\n";
5223                                 if ($check_forks) {
5224                                         print "<td></td>\n";
5225                                 }
5226                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5227                                 print "</tr>\n";
5228                         }
5229
5230                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5231                 }
5232         } else {
5233                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5234         }
5235
5236         if (defined $extra) {
5237                 print "<tr>\n";
5238                 if ($check_forks) {
5239                         print "<td></td>\n";
5240                 }
5241                 print "<td colspan=\"5\">$extra</td>\n" .
5242                       "</tr>\n";
5243         }
5244         print "</table>\n";
5245 }
5246
5247 sub git_log_body {
5248         # uses global variable $project
5249         my ($commitlist, $from, $to, $refs, $extra) = @_;
5250
5251         $from = 0 unless defined $from;
5252         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5253
5254         for (my $i = 0; $i <= $to; $i++) {
5255                 my %co = %{$commitlist->[$i]};
5256                 next if !%co;
5257                 my $commit = $co{'id'};
5258                 my $ref = format_ref_marker($refs, $commit);
5259                 git_print_header_div('commit',
5260                                "<span class=\"age\">$co{'age_string'}</span>" .
5261                                esc_html($co{'title'}) . $ref,
5262                                $commit);
5263                 print "<div class=\"title_text\">\n" .
5264                       "<div class=\"log_link\">\n" .
5265                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5266                       " | " .
5267                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5268                       " | " .
5269                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5270                       "<br/>\n" .
5271                       "</div>\n";
5272                       git_print_authorship(\%co, -tag => 'span');
5273                       print "<br/>\n</div>\n";
5274
5275                 print "<div class=\"log_body\">\n";
5276                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5277                 print "</div>\n";
5278         }
5279         if ($extra) {
5280                 print "<div class=\"page_nav\">\n";
5281                 print "$extra\n";
5282                 print "</div>\n";
5283         }
5284 }
5285
5286 sub git_shortlog_body {
5287         # uses global variable $project
5288         my ($commitlist, $from, $to, $refs, $extra) = @_;
5289
5290         $from = 0 unless defined $from;
5291         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5292
5293         print "<table class=\"shortlog\">\n";
5294         my $alternate = 1;
5295         for (my $i = $from; $i <= $to; $i++) {
5296                 my %co = %{$commitlist->[$i]};
5297                 my $commit = $co{'id'};
5298                 my $ref = format_ref_marker($refs, $commit);
5299                 if ($alternate) {
5300                         print "<tr class=\"dark\">\n";
5301                 } else {
5302                         print "<tr class=\"light\">\n";
5303                 }
5304                 $alternate ^= 1;
5305                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5306                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5307                       format_author_html('td', \%co, 10) . "<td>";
5308                 print format_subject_html($co{'title'}, $co{'title_short'},
5309                                           href(action=>"commit", hash=>$commit), $ref);
5310                 print "</td>\n" .
5311                       "<td class=\"link\">" .
5312                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5313                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5314                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5315                 my $snapshot_links = format_snapshot_links($commit);
5316                 if (defined $snapshot_links) {
5317                         print " | " . $snapshot_links;
5318                 }
5319                 print "</td>\n" .
5320                       "</tr>\n";
5321         }
5322         if (defined $extra) {
5323                 print "<tr>\n" .
5324                       "<td colspan=\"4\">$extra</td>\n" .
5325                       "</tr>\n";
5326         }
5327         print "</table>\n";
5328 }
5329
5330 sub git_history_body {
5331         # Warning: assumes constant type (blob or tree) during history
5332         my ($commitlist, $from, $to, $refs, $extra,
5333             $file_name, $file_hash, $ftype) = @_;
5334
5335         $from = 0 unless defined $from;
5336         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5337
5338         print "<table class=\"history\">\n";
5339         my $alternate = 1;
5340         for (my $i = $from; $i <= $to; $i++) {
5341                 my %co = %{$commitlist->[$i]};
5342                 if (!%co) {
5343                         next;
5344                 }
5345                 my $commit = $co{'id'};
5346
5347                 my $ref = format_ref_marker($refs, $commit);
5348
5349                 if ($alternate) {
5350                         print "<tr class=\"dark\">\n";
5351                 } else {
5352                         print "<tr class=\"light\">\n";
5353                 }
5354                 $alternate ^= 1;
5355                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5356         # shortlog:   format_author_html('td', \%co, 10)
5357                       format_author_html('td', \%co, 15, 3) . "<td>";
5358                 # originally git_history used chop_str($co{'title'}, 50)
5359                 print format_subject_html($co{'title'}, $co{'title_short'},
5360                                           href(action=>"commit", hash=>$commit), $ref);
5361                 print "</td>\n" .
5362                       "<td class=\"link\">" .
5363                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5364                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5365
5366                 if ($ftype eq 'blob') {
5367                         my $blob_current = $file_hash;
5368                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5369                         if (defined $blob_current && defined $blob_parent &&
5370                                         $blob_current ne $blob_parent) {
5371                                 print " | " .
5372                                         $cgi->a({-href => href(action=>"blobdiff",
5373                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5374                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5375                                                                file_name=>$file_name)},
5376                                                 "diff to current");
5377                         }
5378                 }
5379                 print "</td>\n" .
5380                       "</tr>\n";
5381         }
5382         if (defined $extra) {
5383                 print "<tr>\n" .
5384                       "<td colspan=\"4\">$extra</td>\n" .
5385                       "</tr>\n";
5386         }
5387         print "</table>\n";
5388 }
5389
5390 sub git_tags_body {
5391         # uses global variable $project
5392         my ($taglist, $from, $to, $extra) = @_;
5393         $from = 0 unless defined $from;
5394         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5395
5396         print "<table class=\"tags\">\n";
5397         my $alternate = 1;
5398         for (my $i = $from; $i <= $to; $i++) {
5399                 my $entry = $taglist->[$i];
5400                 my %tag = %$entry;
5401                 my $comment = $tag{'subject'};
5402                 my $comment_short;
5403                 if (defined $comment) {
5404                         $comment_short = chop_str($comment, 30, 5);
5405                 }
5406                 if ($alternate) {
5407                         print "<tr class=\"dark\">\n";
5408                 } else {
5409                         print "<tr class=\"light\">\n";
5410                 }
5411                 $alternate ^= 1;
5412                 if (defined $tag{'age'}) {
5413                         print "<td><i>$tag{'age'}</i></td>\n";
5414                 } else {
5415                         print "<td></td>\n";
5416                 }
5417                 print "<td>" .
5418                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5419                                -class => "list name"}, esc_html($tag{'name'})) .
5420                       "</td>\n" .
5421                       "<td>";
5422                 if (defined $comment) {
5423                         print format_subject_html($comment, $comment_short,
5424                                                   href(action=>"tag", hash=>$tag{'id'}));
5425                 }
5426                 print "</td>\n" .
5427                       "<td class=\"selflink\">";
5428                 if ($tag{'type'} eq "tag") {
5429                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5430                 } else {
5431                         print "&nbsp;";
5432                 }
5433                 print "</td>\n" .
5434                       "<td class=\"link\">" . " | " .
5435                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5436                 if ($tag{'reftype'} eq "commit") {
5437                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5438                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5439                 } elsif ($tag{'reftype'} eq "blob") {
5440                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5441                 }
5442                 print "</td>\n" .
5443                       "</tr>";
5444         }
5445         if (defined $extra) {
5446                 print "<tr>\n" .
5447                       "<td colspan=\"5\">$extra</td>\n" .
5448                       "</tr>\n";
5449         }
5450         print "</table>\n";
5451 }
5452
5453 sub git_heads_body {
5454         # uses global variable $project
5455         my ($headlist, $head, $from, $to, $extra) = @_;
5456         $from = 0 unless defined $from;
5457         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5458
5459         print "<table class=\"heads\">\n";
5460         my $alternate = 1;
5461         for (my $i = $from; $i <= $to; $i++) {
5462                 my $entry = $headlist->[$i];
5463                 my %ref = %$entry;
5464                 my $curr = $ref{'id'} eq $head;
5465                 if ($alternate) {
5466                         print "<tr class=\"dark\">\n";
5467                 } else {
5468                         print "<tr class=\"light\">\n";
5469                 }
5470                 $alternate ^= 1;
5471                 print "<td><i>$ref{'age'}</i></td>\n" .
5472                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5473                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5474                                -class => "list name"},esc_html($ref{'name'})) .
5475                       "</td>\n" .
5476                       "<td class=\"link\">" .
5477                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5478                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5479                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5480                       "</td>\n" .
5481                       "</tr>";
5482         }
5483         if (defined $extra) {
5484                 print "<tr>\n" .
5485                       "<td colspan=\"3\">$extra</td>\n" .
5486                       "</tr>\n";
5487         }
5488         print "</table>\n";
5489 }
5490
5491 # Display a single remote block
5492 sub git_remote_block {
5493         my ($remote, $rdata, $limit, $head) = @_;
5494
5495         my $heads = $rdata->{'heads'};
5496         my $fetch = $rdata->{'fetch'};
5497         my $push = $rdata->{'push'};
5498
5499         my $urls_table = "<table class=\"projects_list\">\n" ;
5500
5501         if (defined $fetch) {
5502                 if ($fetch eq $push) {
5503                         $urls_table .= format_repo_url("URL", $fetch);
5504                 } else {
5505                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5506                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5507                 }
5508         } elsif (defined $push) {
5509                 $urls_table .= format_repo_url("Push URL", $push);
5510         } else {
5511                 $urls_table .= format_repo_url("", "No remote URL");
5512         }
5513
5514         $urls_table .= "</table>\n";
5515
5516         my $dots;
5517         if (defined $limit && $limit < @$heads) {
5518                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5519         }
5520
5521         print $urls_table;
5522         git_heads_body($heads, $head, 0, $limit, $dots);
5523 }
5524
5525 # Display a list of remote names with the respective fetch and push URLs
5526 sub git_remotes_list {
5527         my ($remotedata, $limit) = @_;
5528         print "<table class=\"heads\">\n";
5529         my $alternate = 1;
5530         my @remotes = sort keys %$remotedata;
5531
5532         my $limited = $limit && $limit < @remotes;
5533
5534         $#remotes = $limit - 1 if $limited;
5535
5536         while (my $remote = shift @remotes) {
5537                 my $rdata = $remotedata->{$remote};
5538                 my $fetch = $rdata->{'fetch'};
5539                 my $push = $rdata->{'push'};
5540                 if ($alternate) {
5541                         print "<tr class=\"dark\">\n";
5542                 } else {
5543                         print "<tr class=\"light\">\n";
5544                 }
5545                 $alternate ^= 1;
5546                 print "<td>" .
5547                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5548                                -class=> "list name"},esc_html($remote)) .
5549                       "</td>";
5550                 print "<td class=\"link\">" .
5551                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5552                       " | " .
5553                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5554                       "</td>";
5555
5556                 print "</tr>\n";
5557         }
5558
5559         if ($limited) {
5560                 print "<tr>\n" .
5561                       "<td colspan=\"3\">" .
5562                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5563                       "</td>\n" . "</tr>\n";
5564         }
5565
5566         print "</table>";
5567 }
5568
5569 # Display remote heads grouped by remote, unless there are too many
5570 # remotes, in which case we only display the remote names
5571 sub git_remotes_body {
5572         my ($remotedata, $limit, $head) = @_;
5573         if ($limit and $limit < keys %$remotedata) {
5574                 git_remotes_list($remotedata, $limit);
5575         } else {
5576                 fill_remote_heads($remotedata);
5577                 while (my ($remote, $rdata) = each %$remotedata) {
5578                         git_print_section({-class=>"remote", -id=>$remote},
5579                                 ["remotes", $remote, $remote], sub {
5580                                         git_remote_block($remote, $rdata, $limit, $head);
5581                                 });
5582                 }
5583         }
5584 }
5585
5586 sub git_search_message {
5587         my %co = @_;
5588
5589         my $greptype;
5590         if ($searchtype eq 'commit') {
5591                 $greptype = "--grep=";
5592         } elsif ($searchtype eq 'author') {
5593                 $greptype = "--author=";
5594         } elsif ($searchtype eq 'committer') {
5595                 $greptype = "--committer=";
5596         }
5597         $greptype .= $searchtext;
5598         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5599                                        $greptype, '--regexp-ignore-case',
5600                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5601
5602         my $paging_nav = '';
5603         if ($page > 0) {
5604                 $paging_nav .=
5605                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5606                                 "first") .
5607                         " &sdot; " .
5608                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5609                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5610         } else {
5611                 $paging_nav .= "first &sdot; prev";
5612         }
5613         my $next_link = '';
5614         if ($#commitlist >= 100) {
5615                 $next_link =
5616                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5617                                  -accesskey => "n", -title => "Alt-n"}, "next");
5618                 $paging_nav .= " &sdot; $next_link";
5619         } else {
5620                 $paging_nav .= " &sdot; next";
5621         }
5622
5623         git_header_html();
5624
5625         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5626         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5627         if ($page == 0 && !@commitlist) {
5628                 print "<p>No match.</p>\n";
5629         } else {
5630                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5631         }
5632
5633         git_footer_html();
5634 }
5635
5636 sub git_search_changes {
5637         my %co = @_;
5638
5639         local $/ = "\n";
5640         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5641                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5642                 ($search_use_regexp ? '--pickaxe-regex' : ())
5643                         or die_error(500, "Open git-log failed");
5644
5645         git_header_html();
5646
5647         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5648         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5649
5650         print "<table class=\"pickaxe search\">\n";
5651         my $alternate = 1;
5652         undef %co;
5653         my @files;
5654         while (my $line = <$fd>) {
5655                 chomp $line;
5656                 next unless $line;
5657
5658                 my %set = parse_difftree_raw_line($line);
5659                 if (defined $set{'commit'}) {
5660                         # finish previous commit
5661                         if (%co) {
5662                                 print "</td>\n" .
5663                                       "<td class=\"link\">" .
5664                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5665                                               "commit") .
5666                                       " | " .
5667                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5668                                                              hash_base=>$co{'id'})},
5669                                               "tree") .
5670                                       "</td>\n" .
5671                                       "</tr>\n";
5672                         }
5673
5674                         if ($alternate) {
5675                                 print "<tr class=\"dark\">\n";
5676                         } else {
5677                                 print "<tr class=\"light\">\n";
5678                         }
5679                         $alternate ^= 1;
5680                         %co = parse_commit($set{'commit'});
5681                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5682                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5683                               "<td><i>$author</i></td>\n" .
5684                               "<td>" .
5685                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5686                                       -class => "list subject"},
5687                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
5688                 } elsif (defined $set{'to_id'}) {
5689                         next if ($set{'to_id'} =~ m/^0{40}$/);
5690
5691                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5692                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5693                                       -class => "list"},
5694                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5695                               "<br/>\n";
5696                 }
5697         }
5698         close $fd;
5699
5700         # finish last commit (warning: repetition!)
5701         if (%co) {
5702                 print "</td>\n" .
5703                       "<td class=\"link\">" .
5704                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5705                               "commit") .
5706                       " | " .
5707                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5708                                              hash_base=>$co{'id'})},
5709                               "tree") .
5710                       "</td>\n" .
5711                       "</tr>\n";
5712         }
5713
5714         print "</table>\n";
5715
5716         git_footer_html();
5717 }
5718
5719 sub git_search_files {
5720         my %co = @_;
5721
5722         local $/ = "\n";
5723         open my $fd, "-|", git_cmd(), 'grep', '-n',
5724                 $search_use_regexp ? ('-E', '-i') : '-F',
5725                 $searchtext, $co{'tree'}
5726                         or die_error(500, "Open git-grep failed");
5727
5728         git_header_html();
5729
5730         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5731         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5732
5733         print "<table class=\"grep_search\">\n";
5734         my $alternate = 1;
5735         my $matches = 0;
5736         my $lastfile = '';
5737         while (my $line = <$fd>) {
5738                 chomp $line;
5739                 my ($file, $lno, $ltext, $binary);
5740                 last if ($matches++ > 1000);
5741                 if ($line =~ /^Binary file (.+) matches$/) {
5742                         $file = $1;
5743                         $binary = 1;
5744                 } else {
5745                         (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
5746                 }
5747                 if ($file ne $lastfile) {
5748                         $lastfile and print "</td></tr>\n";
5749                         if ($alternate++) {
5750                                 print "<tr class=\"dark\">\n";
5751                         } else {
5752                                 print "<tr class=\"light\">\n";
5753                         }
5754                         print "<td class=\"list\">".
5755                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5756                                                        file_name=>"$file"),
5757                                         -class => "list"}, esc_path($file));
5758                         print "</td><td>\n";
5759                         $lastfile = $file;
5760                 }
5761                 if ($binary) {
5762                         print "<div class=\"binary\">Binary file</div>\n";
5763                 } else {
5764                         $ltext = untabify($ltext);
5765                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
5766                                 $ltext = esc_html($1, -nbsp=>1);
5767                                 $ltext .= '<span class="match">';
5768                                 $ltext .= esc_html($2, -nbsp=>1);
5769                                 $ltext .= '</span>';
5770                                 $ltext .= esc_html($3, -nbsp=>1);
5771                         } else {
5772                                 $ltext = esc_html($ltext, -nbsp=>1);
5773                         }
5774                         print "<div class=\"pre\">" .
5775                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5776                                                        file_name=>"$file").'#l'.$lno,
5777                                         -class => "linenr"}, sprintf('%4i', $lno))
5778                                 . ' ' .  $ltext . "</div>\n";
5779                 }
5780         }
5781         if ($lastfile) {
5782                 print "</td></tr>\n";
5783                 if ($matches > 1000) {
5784                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
5785                 }
5786         } else {
5787                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
5788         }
5789         close $fd;
5790
5791         print "</table>\n";
5792
5793         git_footer_html();
5794 }
5795
5796 sub git_search_grep_body {
5797         my ($commitlist, $from, $to, $extra) = @_;
5798         $from = 0 unless defined $from;
5799         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5800
5801         print "<table class=\"commit_search\">\n";
5802         my $alternate = 1;
5803         for (my $i = $from; $i <= $to; $i++) {
5804                 my %co = %{$commitlist->[$i]};
5805                 if (!%co) {
5806                         next;
5807                 }
5808                 my $commit = $co{'id'};
5809                 if ($alternate) {
5810                         print "<tr class=\"dark\">\n";
5811                 } else {
5812                         print "<tr class=\"light\">\n";
5813                 }
5814                 $alternate ^= 1;
5815                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5816                       format_author_html('td', \%co, 15, 5) .
5817                       "<td>" .
5818                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5819                                -class => "list subject"},
5820                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5821                 my $comment = $co{'comment'};
5822                 foreach my $line (@$comment) {
5823                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5824                                 my ($lead, $match, $trail) = ($1, $2, $3);
5825                                 $match = chop_str($match, 70, 5, 'center');
5826                                 my $contextlen = int((80 - length($match))/2);
5827                                 $contextlen = 30 if ($contextlen > 30);
5828                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5829                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5830
5831                                 $lead  = esc_html($lead);
5832                                 $match = esc_html($match);
5833                                 $trail = esc_html($trail);
5834
5835                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5836                         }
5837                 }
5838                 print "</td>\n" .
5839                       "<td class=\"link\">" .
5840                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5841                       " | " .
5842                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5843                       " | " .
5844                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5845                 print "</td>\n" .
5846                       "</tr>\n";
5847         }
5848         if (defined $extra) {
5849                 print "<tr>\n" .
5850                       "<td colspan=\"3\">$extra</td>\n" .
5851                       "</tr>\n";
5852         }
5853         print "</table>\n";
5854 }
5855
5856 ## ======================================================================
5857 ## ======================================================================
5858 ## actions
5859
5860 sub git_project_list {
5861         my $order = $input_params{'order'};
5862         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5863                 die_error(400, "Unknown order parameter");
5864         }
5865
5866         my @list = git_get_projects_list();
5867         if (!@list) {
5868                 die_error(404, "No projects found");
5869         }
5870
5871         git_header_html();
5872         if (defined $home_text && -f $home_text) {
5873                 print "<div class=\"index_include\">\n";
5874                 insert_file($home_text);
5875                 print "</div>\n";
5876         }
5877         print $cgi->startform(-method => "get") .
5878               "<p class=\"projsearch\">Search:\n" .
5879               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5880               "</p>" .
5881               $cgi->end_form() . "\n";
5882         git_project_list_body(\@list, $order);
5883         git_footer_html();
5884 }
5885
5886 sub git_forks {
5887         my $order = $input_params{'order'};
5888         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5889                 die_error(400, "Unknown order parameter");
5890         }
5891
5892         my @list = git_get_projects_list($project);
5893         if (!@list) {
5894                 die_error(404, "No forks found");
5895         }
5896
5897         git_header_html();
5898         git_print_page_nav('','');
5899         git_print_header_div('summary', "$project forks");
5900         git_project_list_body(\@list, $order);
5901         git_footer_html();
5902 }
5903
5904 sub git_project_index {
5905         my @projects = git_get_projects_list();
5906         if (!@projects) {
5907                 die_error(404, "No projects found");
5908         }
5909
5910         print $cgi->header(
5911                 -type => 'text/plain',
5912                 -charset => 'utf-8',
5913                 -content_disposition => 'inline; filename="index.aux"');
5914
5915         foreach my $pr (@projects) {
5916                 if (!exists $pr->{'owner'}) {
5917                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5918                 }
5919
5920                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5921                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5922                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5923                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5924                 $path  =~ s/ /\+/g;
5925                 $owner =~ s/ /\+/g;
5926
5927                 print "$path $owner\n";
5928         }
5929 }
5930
5931 sub git_summary {
5932         my $descr = git_get_project_description($project) || "none";
5933         my %co = parse_commit("HEAD");
5934         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5935         my $head = $co{'id'};
5936         my $remote_heads = gitweb_check_feature('remote_heads');
5937
5938         my $owner = git_get_project_owner($project);
5939
5940         my $refs = git_get_references();
5941         # These get_*_list functions return one more to allow us to see if
5942         # there are more ...
5943         my @taglist  = git_get_tags_list(16);
5944         my @headlist = git_get_heads_list(16);
5945         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
5946         my @forklist;
5947         my $check_forks = gitweb_check_feature('forks');
5948
5949         if ($check_forks) {
5950                 # find forks of a project
5951                 @forklist = git_get_projects_list($project);
5952                 # filter out forks of forks
5953                 @forklist = filter_forks_from_projects_list(\@forklist)
5954                         if (@forklist);
5955         }
5956
5957         git_header_html();
5958         git_print_page_nav('summary','', $head);
5959
5960         print "<div class=\"title\">&nbsp;</div>\n";
5961         print "<table class=\"projects_list\">\n" .
5962               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5963               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5964         if (defined $cd{'rfc2822'}) {
5965                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
5966                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
5967         }
5968
5969         # use per project git URL list in $projectroot/$project/cloneurl
5970         # or make project git URL from git base URL and project name
5971         my $url_tag = "URL";
5972         my @url_list = git_get_project_url_list($project);
5973         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5974         foreach my $git_url (@url_list) {
5975                 next unless $git_url;
5976                 print format_repo_url($url_tag, $git_url);
5977                 $url_tag = "";
5978         }
5979
5980         # Tag cloud
5981         my $show_ctags = gitweb_check_feature('ctags');
5982         if ($show_ctags) {
5983                 my $ctags = git_get_project_ctags($project);
5984                 if (%$ctags) {
5985                         # without ability to add tags, don't show if there are none
5986                         my $cloud = git_populate_project_tagcloud($ctags);
5987                         print "<tr id=\"metadata_ctags\">" .
5988                               "<td>content tags</td>" .
5989                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
5990                               "</tr>\n";
5991                 }
5992         }
5993
5994         print "</table>\n";
5995
5996         # If XSS prevention is on, we don't include README.html.
5997         # TODO: Allow a readme in some safe format.
5998         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5999                 print "<div class=\"title\">readme</div>\n" .
6000                       "<div class=\"readme\">\n";
6001                 insert_file("$projectroot/$project/README.html");
6002                 print "\n</div>\n"; # class="readme"
6003         }
6004
6005         # we need to request one more than 16 (0..15) to check if
6006         # those 16 are all
6007         my @commitlist = $head ? parse_commits($head, 17) : ();
6008         if (@commitlist) {
6009                 git_print_header_div('shortlog');
6010                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6011                                   $#commitlist <=  15 ? undef :
6012                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6013         }
6014
6015         if (@taglist) {
6016                 git_print_header_div('tags');
6017                 git_tags_body(\@taglist, 0, 15,
6018                               $#taglist <=  15 ? undef :
6019                               $cgi->a({-href => href(action=>"tags")}, "..."));
6020         }
6021
6022         if (@headlist) {
6023                 git_print_header_div('heads');
6024                 git_heads_body(\@headlist, $head, 0, 15,
6025                                $#headlist <= 15 ? undef :
6026                                $cgi->a({-href => href(action=>"heads")}, "..."));
6027         }
6028
6029         if (%remotedata) {
6030                 git_print_header_div('remotes');
6031                 git_remotes_body(\%remotedata, 15, $head);
6032         }
6033
6034         if (@forklist) {
6035                 git_print_header_div('forks');
6036                 git_project_list_body(\@forklist, 'age', 0, 15,
6037                                       $#forklist <= 15 ? undef :
6038                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6039                                       'no_header');
6040         }
6041
6042         git_footer_html();
6043 }
6044
6045 sub git_tag {
6046         my %tag = parse_tag($hash);
6047
6048         if (! %tag) {
6049                 die_error(404, "Unknown tag object");
6050         }
6051
6052         my $head = git_get_head_hash($project);
6053         git_header_html();
6054         git_print_page_nav('','', $head,undef,$head);
6055         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6056         print "<div class=\"title_text\">\n" .
6057               "<table class=\"object_header\">\n" .
6058               "<tr>\n" .
6059               "<td>object</td>\n" .
6060               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6061                                $tag{'object'}) . "</td>\n" .
6062               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6063                                               $tag{'type'}) . "</td>\n" .
6064               "</tr>\n";
6065         if (defined($tag{'author'})) {
6066                 git_print_authorship_rows(\%tag, 'author');
6067         }
6068         print "</table>\n\n" .
6069               "</div>\n";
6070         print "<div class=\"page_body\">";
6071         my $comment = $tag{'comment'};
6072         foreach my $line (@$comment) {
6073                 chomp $line;
6074                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6075         }
6076         print "</div>\n";
6077         git_footer_html();
6078 }
6079
6080 sub git_blame_common {
6081         my $format = shift || 'porcelain';
6082         if ($format eq 'porcelain' && $cgi->param('js')) {
6083                 $format = 'incremental';
6084                 $action = 'blame_incremental'; # for page title etc
6085         }
6086
6087         # permissions
6088         gitweb_check_feature('blame')
6089                 or die_error(403, "Blame view not allowed");
6090
6091         # error checking
6092         die_error(400, "No file name given") unless $file_name;
6093         $hash_base ||= git_get_head_hash($project);
6094         die_error(404, "Couldn't find base commit") unless $hash_base;
6095         my %co = parse_commit($hash_base)
6096                 or die_error(404, "Commit not found");
6097         my $ftype = "blob";
6098         if (!defined $hash) {
6099                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6100                         or die_error(404, "Error looking up file");
6101         } else {
6102                 $ftype = git_get_type($hash);
6103                 if ($ftype !~ "blob") {
6104                         die_error(400, "Object is not a blob");
6105                 }
6106         }
6107
6108         my $fd;
6109         if ($format eq 'incremental') {
6110                 # get file contents (as base)
6111                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6112                         or die_error(500, "Open git-cat-file failed");
6113         } elsif ($format eq 'data') {
6114                 # run git-blame --incremental
6115                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6116                         $hash_base, "--", $file_name
6117                         or die_error(500, "Open git-blame --incremental failed");
6118         } else {
6119                 # run git-blame --porcelain
6120                 open $fd, "-|", git_cmd(), "blame", '-p',
6121                         $hash_base, '--', $file_name
6122                         or die_error(500, "Open git-blame --porcelain failed");
6123         }
6124
6125         # incremental blame data returns early
6126         if ($format eq 'data') {
6127                 print $cgi->header(
6128                         -type=>"text/plain", -charset => "utf-8",
6129                         -status=> "200 OK");
6130                 local $| = 1; # output autoflush
6131                 print while <$fd>;
6132                 close $fd
6133                         or print "ERROR $!\n";
6134
6135                 print 'END';
6136                 if (defined $t0 && gitweb_check_feature('timed')) {
6137                         print ' '.
6138                               tv_interval($t0, [ gettimeofday() ]).
6139                               ' '.$number_of_git_cmds;
6140                 }
6141                 print "\n";
6142
6143                 return;
6144         }
6145
6146         # page header
6147         git_header_html();
6148         my $formats_nav =
6149                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6150                         "blob") .
6151                 " | ";
6152         if ($format eq 'incremental') {
6153                 $formats_nav .=
6154                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6155                                 "blame") . " (non-incremental)";
6156         } else {
6157                 $formats_nav .=
6158                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6159                                 "blame") . " (incremental)";
6160         }
6161         $formats_nav .=
6162                 " | " .
6163                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6164                         "history") .
6165                 " | " .
6166                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6167                         "HEAD");
6168         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6169         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6170         git_print_page_path($file_name, $ftype, $hash_base);
6171
6172         # page body
6173         if ($format eq 'incremental') {
6174                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6175                       "This page requires JavaScript to run.\n Use ".
6176                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6177                               'this page').
6178                       " instead.\n".
6179                       "</b></center></div>\n</noscript>\n";
6180
6181                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6182         }
6183
6184         print qq!<div class="page_body">\n!;
6185         print qq!<div id="progress_info">... / ...</div>\n!
6186                 if ($format eq 'incremental');
6187         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6188               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6189               qq!<thead>\n!.
6190               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6191               qq!</thead>\n!.
6192               qq!<tbody>\n!;
6193
6194         my @rev_color = qw(light dark);
6195         my $num_colors = scalar(@rev_color);
6196         my $current_color = 0;
6197
6198         if ($format eq 'incremental') {
6199                 my $color_class = $rev_color[$current_color];
6200
6201                 #contents of a file
6202                 my $linenr = 0;
6203         LINE:
6204                 while (my $line = <$fd>) {
6205                         chomp $line;
6206                         $linenr++;
6207
6208                         print qq!<tr id="l$linenr" class="$color_class">!.
6209                               qq!<td class="sha1"><a href=""> </a></td>!.
6210                               qq!<td class="linenr">!.
6211                               qq!<a class="linenr" href="">$linenr</a></td>!;
6212                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6213                         print qq!</tr>\n!;
6214                 }
6215
6216         } else { # porcelain, i.e. ordinary blame
6217                 my %metainfo = (); # saves information about commits
6218
6219                 # blame data
6220         LINE:
6221                 while (my $line = <$fd>) {
6222                         chomp $line;
6223                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6224                         # no <lines in group> for subsequent lines in group of lines
6225                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6226                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6227                         if (!exists $metainfo{$full_rev}) {
6228                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6229                         }
6230                         my $meta = $metainfo{$full_rev};
6231                         my $data;
6232                         while ($data = <$fd>) {
6233                                 chomp $data;
6234                                 last if ($data =~ s/^\t//); # contents of line
6235                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6236                                         $meta->{$1} = $2 unless exists $meta->{$1};
6237                                 }
6238                                 if ($data =~ /^previous /) {
6239                                         $meta->{'nprevious'}++;
6240                                 }
6241                         }
6242                         my $short_rev = substr($full_rev, 0, 8);
6243                         my $author = $meta->{'author'};
6244                         my %date =
6245                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6246                         my $date = $date{'iso-tz'};
6247                         if ($group_size) {
6248                                 $current_color = ($current_color + 1) % $num_colors;
6249                         }
6250                         my $tr_class = $rev_color[$current_color];
6251                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6252                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6253                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6254                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6255                         if ($group_size) {
6256                                 print "<td class=\"sha1\"";
6257                                 print " title=\"". esc_html($author) . ", $date\"";
6258                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6259                                 print ">";
6260                                 print $cgi->a({-href => href(action=>"commit",
6261                                                              hash=>$full_rev,
6262                                                              file_name=>$file_name)},
6263                                               esc_html($short_rev));
6264                                 if ($group_size >= 2) {
6265                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6266                                         if (@author_initials) {
6267                                                 print "<br />" .
6268                                                       esc_html(join('', @author_initials));
6269                                                 #           or join('.', ...)
6270                                         }
6271                                 }
6272                                 print "</td>\n";
6273                         }
6274                         # 'previous' <sha1 of parent commit> <filename at commit>
6275                         if (exists $meta->{'previous'} &&
6276                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6277                                 $meta->{'parent'} = $1;
6278                                 $meta->{'file_parent'} = unquote($2);
6279                         }
6280                         my $linenr_commit =
6281                                 exists($meta->{'parent'}) ?
6282                                 $meta->{'parent'} : $full_rev;
6283                         my $linenr_filename =
6284                                 exists($meta->{'file_parent'}) ?
6285                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6286                         my $blamed = href(action => 'blame',
6287                                           file_name => $linenr_filename,
6288                                           hash_base => $linenr_commit);
6289                         print "<td class=\"linenr\">";
6290                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6291                                         -class => "linenr" },
6292                                       esc_html($lineno));
6293                         print "</td>";
6294                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6295                         print "</tr>\n";
6296                 } # end while
6297
6298         }
6299
6300         # footer
6301         print "</tbody>\n".
6302               "</table>\n"; # class="blame"
6303         print "</div>\n";   # class="blame_body"
6304         close $fd
6305                 or print "Reading blob failed\n";
6306
6307         git_footer_html();
6308 }
6309
6310 sub git_blame {
6311         git_blame_common();
6312 }
6313
6314 sub git_blame_incremental {
6315         git_blame_common('incremental');
6316 }
6317
6318 sub git_blame_data {
6319         git_blame_common('data');
6320 }
6321
6322 sub git_tags {
6323         my $head = git_get_head_hash($project);
6324         git_header_html();
6325         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6326         git_print_header_div('summary', $project);
6327
6328         my @tagslist = git_get_tags_list();
6329         if (@tagslist) {
6330                 git_tags_body(\@tagslist);
6331         }
6332         git_footer_html();
6333 }
6334
6335 sub git_heads {
6336         my $head = git_get_head_hash($project);
6337         git_header_html();
6338         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6339         git_print_header_div('summary', $project);
6340
6341         my @headslist = git_get_heads_list();
6342         if (@headslist) {
6343                 git_heads_body(\@headslist, $head);
6344         }
6345         git_footer_html();
6346 }
6347
6348 # used both for single remote view and for list of all the remotes
6349 sub git_remotes {
6350         gitweb_check_feature('remote_heads')
6351                 or die_error(403, "Remote heads view is disabled");
6352
6353         my $head = git_get_head_hash($project);
6354         my $remote = $input_params{'hash'};
6355
6356         my $remotedata = git_get_remotes_list($remote);
6357         die_error(500, "Unable to get remote information") unless defined $remotedata;
6358
6359         unless (%$remotedata) {
6360                 die_error(404, defined $remote ?
6361                         "Remote $remote not found" :
6362                         "No remotes found");
6363         }
6364
6365         git_header_html(undef, undef, -action_extra => $remote);
6366         git_print_page_nav('', '',  $head, undef, $head,
6367                 format_ref_views($remote ? '' : 'remotes'));
6368
6369         fill_remote_heads($remotedata);
6370         if (defined $remote) {
6371                 git_print_header_div('remotes', "$remote remote for $project");
6372                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6373         } else {
6374                 git_print_header_div('summary', "$project remotes");
6375                 git_remotes_body($remotedata, undef, $head);
6376         }
6377
6378         git_footer_html();
6379 }
6380
6381 sub git_blob_plain {
6382         my $type = shift;
6383         my $expires;
6384
6385         if (!defined $hash) {
6386                 if (defined $file_name) {
6387                         my $base = $hash_base || git_get_head_hash($project);
6388                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6389                                 or die_error(404, "Cannot find file");
6390                 } else {
6391                         die_error(400, "No file name defined");
6392                 }
6393         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6394                 # blobs defined by non-textual hash id's can be cached
6395                 $expires = "+1d";
6396         }
6397
6398         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6399                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6400
6401         # content-type (can include charset)
6402         $type = blob_contenttype($fd, $file_name, $type);
6403
6404         # "save as" filename, even when no $file_name is given
6405         my $save_as = "$hash";
6406         if (defined $file_name) {
6407                 $save_as = $file_name;
6408         } elsif ($type =~ m/^text\//) {
6409                 $save_as .= '.txt';
6410         }
6411
6412         # With XSS prevention on, blobs of all types except a few known safe
6413         # ones are served with "Content-Disposition: attachment" to make sure
6414         # they don't run in our security domain.  For certain image types,
6415         # blob view writes an <img> tag referring to blob_plain view, and we
6416         # want to be sure not to break that by serving the image as an
6417         # attachment (though Firefox 3 doesn't seem to care).
6418         my $sandbox = $prevent_xss &&
6419                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6420
6421         # serve text/* as text/plain
6422         if ($prevent_xss &&
6423             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6424              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6425                 my $rest = $1;
6426                 $rest = defined $rest ? $rest : '';
6427                 $type = "text/plain$rest";
6428         }
6429
6430         print $cgi->header(
6431                 -type => $type,
6432                 -expires => $expires,
6433                 -content_disposition =>
6434                         ($sandbox ? 'attachment' : 'inline')
6435                         . '; filename="' . $save_as . '"');
6436         local $/ = undef;
6437         binmode STDOUT, ':raw';
6438         print <$fd>;
6439         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6440         close $fd;
6441 }
6442
6443 sub git_blob {
6444         my $expires;
6445
6446         if (!defined $hash) {
6447                 if (defined $file_name) {
6448                         my $base = $hash_base || git_get_head_hash($project);
6449                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6450                                 or die_error(404, "Cannot find file");
6451                 } else {
6452                         die_error(400, "No file name defined");
6453                 }
6454         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6455                 # blobs defined by non-textual hash id's can be cached
6456                 $expires = "+1d";
6457         }
6458
6459         my $have_blame = gitweb_check_feature('blame');
6460         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6461                 or die_error(500, "Couldn't cat $file_name, $hash");
6462         my $mimetype = blob_mimetype($fd, $file_name);
6463         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6464         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6465                 close $fd;
6466                 return git_blob_plain($mimetype);
6467         }
6468         # we can have blame only for text/* mimetype
6469         $have_blame &&= ($mimetype =~ m!^text/!);
6470
6471         my $highlight = gitweb_check_feature('highlight');
6472         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6473         $fd = run_highlighter($fd, $highlight, $syntax)
6474                 if $syntax;
6475
6476         git_header_html(undef, $expires);
6477         my $formats_nav = '';
6478         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6479                 if (defined $file_name) {
6480                         if ($have_blame) {
6481                                 $formats_nav .=
6482                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6483                                                 "blame") .
6484                                         " | ";
6485                         }
6486                         $formats_nav .=
6487                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6488                                         "history") .
6489                                 " | " .
6490                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6491                                         "raw") .
6492                                 " | " .
6493                                 $cgi->a({-href => href(action=>"blob",
6494                                                        hash_base=>"HEAD", file_name=>$file_name)},
6495                                         "HEAD");
6496                 } else {
6497                         $formats_nav .=
6498                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6499                                         "raw");
6500                 }
6501                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6502                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6503         } else {
6504                 print "<div class=\"page_nav\">\n" .
6505                       "<br/><br/></div>\n" .
6506                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6507         }
6508         git_print_page_path($file_name, "blob", $hash_base);
6509         print "<div class=\"page_body\">\n";
6510         if ($mimetype =~ m!^image/!) {
6511                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6512                 if ($file_name) {
6513                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6514                 }
6515                 print qq! src="! .
6516                       href(action=>"blob_plain", hash=>$hash,
6517                            hash_base=>$hash_base, file_name=>$file_name) .
6518                       qq!" />\n!;
6519         } else {
6520                 my $nr;
6521                 while (my $line = <$fd>) {
6522                         chomp $line;
6523                         $nr++;
6524                         $line = untabify($line);
6525                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6526                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6527                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6528                 }
6529         }
6530         close $fd
6531                 or print "Reading blob failed.\n";
6532         print "</div>";
6533         git_footer_html();
6534 }
6535
6536 sub git_tree {
6537         if (!defined $hash_base) {
6538                 $hash_base = "HEAD";
6539         }
6540         if (!defined $hash) {
6541                 if (defined $file_name) {
6542                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6543                 } else {
6544                         $hash = $hash_base;
6545                 }
6546         }
6547         die_error(404, "No such tree") unless defined($hash);
6548
6549         my $show_sizes = gitweb_check_feature('show-sizes');
6550         my $have_blame = gitweb_check_feature('blame');
6551
6552         my @entries = ();
6553         {
6554                 local $/ = "\0";
6555                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6556                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6557                         or die_error(500, "Open git-ls-tree failed");
6558                 @entries = map { chomp; $_ } <$fd>;
6559                 close $fd
6560                         or die_error(404, "Reading tree failed");
6561         }
6562
6563         my $refs = git_get_references();
6564         my $ref = format_ref_marker($refs, $hash_base);
6565         git_header_html();
6566         my $basedir = '';
6567         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6568                 my @views_nav = ();
6569                 if (defined $file_name) {
6570                         push @views_nav,
6571                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6572                                         "history"),
6573                                 $cgi->a({-href => href(action=>"tree",
6574                                                        hash_base=>"HEAD", file_name=>$file_name)},
6575                                         "HEAD"),
6576                 }
6577                 my $snapshot_links = format_snapshot_links($hash);
6578                 if (defined $snapshot_links) {
6579                         # FIXME: Should be available when we have no hash base as well.
6580                         push @views_nav, $snapshot_links;
6581                 }
6582                 git_print_page_nav('tree','', $hash_base, undef, undef,
6583                                    join(' | ', @views_nav));
6584                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6585         } else {
6586                 undef $hash_base;
6587                 print "<div class=\"page_nav\">\n";
6588                 print "<br/><br/></div>\n";
6589                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6590         }
6591         if (defined $file_name) {
6592                 $basedir = $file_name;
6593                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6594                         $basedir .= '/';
6595                 }
6596                 git_print_page_path($file_name, 'tree', $hash_base);
6597         }
6598         print "<div class=\"page_body\">\n";
6599         print "<table class=\"tree\">\n";
6600         my $alternate = 1;
6601         # '..' (top directory) link if possible
6602         if (defined $hash_base &&
6603             defined $file_name && $file_name =~ m![^/]+$!) {
6604                 if ($alternate) {
6605                         print "<tr class=\"dark\">\n";
6606                 } else {
6607                         print "<tr class=\"light\">\n";
6608                 }
6609                 $alternate ^= 1;
6610
6611                 my $up = $file_name;
6612                 $up =~ s!/?[^/]+$!!;
6613                 undef $up unless $up;
6614                 # based on git_print_tree_entry
6615                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6616                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6617                 print '<td class="list">';
6618                 print $cgi->a({-href => href(action=>"tree",
6619                                              hash_base=>$hash_base,
6620                                              file_name=>$up)},
6621                               "..");
6622                 print "</td>\n";
6623                 print "<td class=\"link\"></td>\n";
6624
6625                 print "</tr>\n";
6626         }
6627         foreach my $line (@entries) {
6628                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6629
6630                 if ($alternate) {
6631                         print "<tr class=\"dark\">\n";
6632                 } else {
6633                         print "<tr class=\"light\">\n";
6634                 }
6635                 $alternate ^= 1;
6636
6637                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6638
6639                 print "</tr>\n";
6640         }
6641         print "</table>\n" .
6642               "</div>";
6643         git_footer_html();
6644 }
6645
6646 sub snapshot_name {
6647         my ($project, $hash) = @_;
6648
6649         # path/to/project.git  -> project
6650         # path/to/project/.git -> project
6651         my $name = to_utf8($project);
6652         $name =~ s,([^/])/*\.git$,$1,;
6653         $name = basename($name);
6654         # sanitize name
6655         $name =~ s/[[:cntrl:]]/?/g;
6656
6657         my $ver = $hash;
6658         if ($hash =~ /^[0-9a-fA-F]+$/) {
6659                 # shorten SHA-1 hash
6660                 my $full_hash = git_get_full_hash($project, $hash);
6661                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6662                         $ver = git_get_short_hash($project, $hash);
6663                 }
6664         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6665                 # tags don't need shortened SHA-1 hash
6666                 $ver = $1;
6667         } else {
6668                 # branches and other need shortened SHA-1 hash
6669                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6670                         $ver = $1;
6671                 }
6672                 $ver .= '-' . git_get_short_hash($project, $hash);
6673         }
6674         # in case of hierarchical branch names
6675         $ver =~ s!/!.!g;
6676
6677         # name = project-version_string
6678         $name = "$name-$ver";
6679
6680         return wantarray ? ($name, $name) : $name;
6681 }
6682
6683 sub git_snapshot {
6684         my $format = $input_params{'snapshot_format'};
6685         if (!@snapshot_fmts) {
6686                 die_error(403, "Snapshots not allowed");
6687         }
6688         # default to first supported snapshot format
6689         $format ||= $snapshot_fmts[0];
6690         if ($format !~ m/^[a-z0-9]+$/) {
6691                 die_error(400, "Invalid snapshot format parameter");
6692         } elsif (!exists($known_snapshot_formats{$format})) {
6693                 die_error(400, "Unknown snapshot format");
6694         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6695                 die_error(403, "Snapshot format not allowed");
6696         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6697                 die_error(403, "Unsupported snapshot format");
6698         }
6699
6700         my $type = git_get_type("$hash^{}");
6701         if (!$type) {
6702                 die_error(404, 'Object does not exist');
6703         }  elsif ($type eq 'blob') {
6704                 die_error(400, 'Object is not a tree-ish');
6705         }
6706
6707         my ($name, $prefix) = snapshot_name($project, $hash);
6708         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6709         my $cmd = quote_command(
6710                 git_cmd(), 'archive',
6711                 "--format=$known_snapshot_formats{$format}{'format'}",
6712                 "--prefix=$prefix/", $hash);
6713         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6714                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6715         }
6716
6717         $filename =~ s/(["\\])/\\$1/g;
6718         print $cgi->header(
6719                 -type => $known_snapshot_formats{$format}{'type'},
6720                 -content_disposition => 'inline; filename="' . $filename . '"',
6721                 -status => '200 OK');
6722
6723         open my $fd, "-|", $cmd
6724                 or die_error(500, "Execute git-archive failed");
6725         binmode STDOUT, ':raw';
6726         print <$fd>;
6727         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6728         close $fd;
6729 }
6730
6731 sub git_log_generic {
6732         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6733
6734         my $head = git_get_head_hash($project);
6735         if (!defined $base) {
6736                 $base = $head;
6737         }
6738         if (!defined $page) {
6739                 $page = 0;
6740         }
6741         my $refs = git_get_references();
6742
6743         my $commit_hash = $base;
6744         if (defined $parent) {
6745                 $commit_hash = "$parent..$base";
6746         }
6747         my @commitlist =
6748                 parse_commits($commit_hash, 101, (100 * $page),
6749                               defined $file_name ? ($file_name, "--full-history") : ());
6750
6751         my $ftype;
6752         if (!defined $file_hash && defined $file_name) {
6753                 # some commits could have deleted file in question,
6754                 # and not have it in tree, but one of them has to have it
6755                 for (my $i = 0; $i < @commitlist; $i++) {
6756                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6757                         last if defined $file_hash;
6758                 }
6759         }
6760         if (defined $file_hash) {
6761                 $ftype = git_get_type($file_hash);
6762         }
6763         if (defined $file_name && !defined $ftype) {
6764                 die_error(500, "Unknown type of object");
6765         }
6766         my %co;
6767         if (defined $file_name) {
6768                 %co = parse_commit($base)
6769                         or die_error(404, "Unknown commit object");
6770         }
6771
6772
6773         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6774         my $next_link = '';
6775         if ($#commitlist >= 100) {
6776                 $next_link =
6777                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6778                                  -accesskey => "n", -title => "Alt-n"}, "next");
6779         }
6780         my $patch_max = gitweb_get_feature('patches');
6781         if ($patch_max && !defined $file_name) {
6782                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6783                         $paging_nav .= " &sdot; " .
6784                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6785                                         "patches");
6786                 }
6787         }
6788
6789         git_header_html();
6790         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6791         if (defined $file_name) {
6792                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6793         } else {
6794                 git_print_header_div('summary', $project)
6795         }
6796         git_print_page_path($file_name, $ftype, $hash_base)
6797                 if (defined $file_name);
6798
6799         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6800                      $file_name, $file_hash, $ftype);
6801
6802         git_footer_html();
6803 }
6804
6805 sub git_log {
6806         git_log_generic('log', \&git_log_body,
6807                         $hash, $hash_parent);
6808 }
6809
6810 sub git_commit {
6811         $hash ||= $hash_base || "HEAD";
6812         my %co = parse_commit($hash)
6813             or die_error(404, "Unknown commit object");
6814
6815         my $parent  = $co{'parent'};
6816         my $parents = $co{'parents'}; # listref
6817
6818         # we need to prepare $formats_nav before any parameter munging
6819         my $formats_nav;
6820         if (!defined $parent) {
6821                 # --root commitdiff
6822                 $formats_nav .= '(initial)';
6823         } elsif (@$parents == 1) {
6824                 # single parent commit
6825                 $formats_nav .=
6826                         '(parent: ' .
6827                         $cgi->a({-href => href(action=>"commit",
6828                                                hash=>$parent)},
6829                                 esc_html(substr($parent, 0, 7))) .
6830                         ')';
6831         } else {
6832                 # merge commit
6833                 $formats_nav .=
6834                         '(merge: ' .
6835                         join(' ', map {
6836                                 $cgi->a({-href => href(action=>"commit",
6837                                                        hash=>$_)},
6838                                         esc_html(substr($_, 0, 7)));
6839                         } @$parents ) .
6840                         ')';
6841         }
6842         if (gitweb_check_feature('patches') && @$parents <= 1) {
6843                 $formats_nav .= " | " .
6844                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6845                                 "patch");
6846         }
6847
6848         if (!defined $parent) {
6849                 $parent = "--root";
6850         }
6851         my @difftree;
6852         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6853                 @diff_opts,
6854                 (@$parents <= 1 ? $parent : '-c'),
6855                 $hash, "--"
6856                 or die_error(500, "Open git-diff-tree failed");
6857         @difftree = map { chomp; $_ } <$fd>;
6858         close $fd or die_error(404, "Reading git-diff-tree failed");
6859
6860         # non-textual hash id's can be cached
6861         my $expires;
6862         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6863                 $expires = "+1d";
6864         }
6865         my $refs = git_get_references();
6866         my $ref = format_ref_marker($refs, $co{'id'});
6867
6868         git_header_html(undef, $expires);
6869         git_print_page_nav('commit', '',
6870                            $hash, $co{'tree'}, $hash,
6871                            $formats_nav);
6872
6873         if (defined $co{'parent'}) {
6874                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6875         } else {
6876                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6877         }
6878         print "<div class=\"title_text\">\n" .
6879               "<table class=\"object_header\">\n";
6880         git_print_authorship_rows(\%co);
6881         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6882         print "<tr>" .
6883               "<td>tree</td>" .
6884               "<td class=\"sha1\">" .
6885               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6886                        class => "list"}, $co{'tree'}) .
6887               "</td>" .
6888               "<td class=\"link\">" .
6889               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6890                       "tree");
6891         my $snapshot_links = format_snapshot_links($hash);
6892         if (defined $snapshot_links) {
6893                 print " | " . $snapshot_links;
6894         }
6895         print "</td>" .
6896               "</tr>\n";
6897
6898         foreach my $par (@$parents) {
6899                 print "<tr>" .
6900                       "<td>parent</td>" .
6901                       "<td class=\"sha1\">" .
6902                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6903                                class => "list"}, $par) .
6904                       "</td>" .
6905                       "<td class=\"link\">" .
6906                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6907                       " | " .
6908                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6909                       "</td>" .
6910                       "</tr>\n";
6911         }
6912         print "</table>".
6913               "</div>\n";
6914
6915         print "<div class=\"page_body\">\n";
6916         git_print_log($co{'comment'});
6917         print "</div>\n";
6918
6919         git_difftree_body(\@difftree, $hash, @$parents);
6920
6921         git_footer_html();
6922 }
6923
6924 sub git_object {
6925         # object is defined by:
6926         # - hash or hash_base alone
6927         # - hash_base and file_name
6928         my $type;
6929
6930         # - hash or hash_base alone
6931         if ($hash || ($hash_base && !defined $file_name)) {
6932                 my $object_id = $hash || $hash_base;
6933
6934                 open my $fd, "-|", quote_command(
6935                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6936                         or die_error(404, "Object does not exist");
6937                 $type = <$fd>;
6938                 chomp $type;
6939                 close $fd
6940                         or die_error(404, "Object does not exist");
6941
6942         # - hash_base and file_name
6943         } elsif ($hash_base && defined $file_name) {
6944                 $file_name =~ s,/+$,,;
6945
6946                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6947                         or die_error(404, "Base object does not exist");
6948
6949                 # here errors should not hapen
6950                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6951                         or die_error(500, "Open git-ls-tree failed");
6952                 my $line = <$fd>;
6953                 close $fd;
6954
6955                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6956                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6957                         die_error(404, "File or directory for given base does not exist");
6958                 }
6959                 $type = $2;
6960                 $hash = $3;
6961         } else {
6962                 die_error(400, "Not enough information to find object");
6963         }
6964
6965         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6966                                           hash=>$hash, hash_base=>$hash_base,
6967                                           file_name=>$file_name),
6968                              -status => '302 Found');
6969 }
6970
6971 sub git_blobdiff {
6972         my $format = shift || 'html';
6973
6974         my $fd;
6975         my @difftree;
6976         my %diffinfo;
6977         my $expires;
6978
6979         # preparing $fd and %diffinfo for git_patchset_body
6980         # new style URI
6981         if (defined $hash_base && defined $hash_parent_base) {
6982                 if (defined $file_name) {
6983                         # read raw output
6984                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6985                                 $hash_parent_base, $hash_base,
6986                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6987                                 or die_error(500, "Open git-diff-tree failed");
6988                         @difftree = map { chomp; $_ } <$fd>;
6989                         close $fd
6990                                 or die_error(404, "Reading git-diff-tree failed");
6991                         @difftree
6992                                 or die_error(404, "Blob diff not found");
6993
6994                 } elsif (defined $hash &&
6995                          $hash =~ /[0-9a-fA-F]{40}/) {
6996                         # try to find filename from $hash
6997
6998                         # read filtered raw output
6999                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7000                                 $hash_parent_base, $hash_base, "--"
7001                                 or die_error(500, "Open git-diff-tree failed");
7002                         @difftree =
7003                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7004                                 # $hash == to_id
7005                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7006                                 map { chomp; $_ } <$fd>;
7007                         close $fd
7008                                 or die_error(404, "Reading git-diff-tree failed");
7009                         @difftree
7010                                 or die_error(404, "Blob diff not found");
7011
7012                 } else {
7013                         die_error(400, "Missing one of the blob diff parameters");
7014                 }
7015
7016                 if (@difftree > 1) {
7017                         die_error(400, "Ambiguous blob diff specification");
7018                 }
7019
7020                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7021                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7022                 $file_name   ||= $diffinfo{'to_file'};
7023
7024                 $hash_parent ||= $diffinfo{'from_id'};
7025                 $hash        ||= $diffinfo{'to_id'};
7026
7027                 # non-textual hash id's can be cached
7028                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7029                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7030                         $expires = '+1d';
7031                 }
7032
7033                 # open patch output
7034                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7035                         '-p', ($format eq 'html' ? "--full-index" : ()),
7036                         $hash_parent_base, $hash_base,
7037                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7038                         or die_error(500, "Open git-diff-tree failed");
7039         }
7040
7041         # old/legacy style URI -- not generated anymore since 1.4.3.
7042         if (!%diffinfo) {
7043                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7044         }
7045
7046         # header
7047         if ($format eq 'html') {
7048                 my $formats_nav =
7049                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7050                                 "raw");
7051                 git_header_html(undef, $expires);
7052                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7053                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7054                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7055                 } else {
7056                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7057                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7058                 }
7059                 if (defined $file_name) {
7060                         git_print_page_path($file_name, "blob", $hash_base);
7061                 } else {
7062                         print "<div class=\"page_path\"></div>\n";
7063                 }
7064
7065         } elsif ($format eq 'plain') {
7066                 print $cgi->header(
7067                         -type => 'text/plain',
7068                         -charset => 'utf-8',
7069                         -expires => $expires,
7070                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7071
7072                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7073
7074         } else {
7075                 die_error(400, "Unknown blobdiff format");
7076         }
7077
7078         # patch
7079         if ($format eq 'html') {
7080                 print "<div class=\"page_body\">\n";
7081
7082                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
7083                 close $fd;
7084
7085                 print "</div>\n"; # class="page_body"
7086                 git_footer_html();
7087
7088         } else {
7089                 while (my $line = <$fd>) {
7090                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7091                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7092
7093                         print $line;
7094
7095                         last if $line =~ m!^\+\+\+!;
7096                 }
7097                 local $/ = undef;
7098                 print <$fd>;
7099                 close $fd;
7100         }
7101 }
7102
7103 sub git_blobdiff_plain {
7104         git_blobdiff('plain');
7105 }
7106
7107 sub git_commitdiff {
7108         my %params = @_;
7109         my $format = $params{-format} || 'html';
7110
7111         my ($patch_max) = gitweb_get_feature('patches');
7112         if ($format eq 'patch') {
7113                 die_error(403, "Patch view not allowed") unless $patch_max;
7114         }
7115
7116         $hash ||= $hash_base || "HEAD";
7117         my %co = parse_commit($hash)
7118             or die_error(404, "Unknown commit object");
7119
7120         # choose format for commitdiff for merge
7121         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7122                 $hash_parent = '--cc';
7123         }
7124         # we need to prepare $formats_nav before almost any parameter munging
7125         my $formats_nav;
7126         if ($format eq 'html') {
7127                 $formats_nav =
7128                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7129                                 "raw");
7130                 if ($patch_max && @{$co{'parents'}} <= 1) {
7131                         $formats_nav .= " | " .
7132                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7133                                         "patch");
7134                 }
7135
7136                 if (defined $hash_parent &&
7137                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7138                         # commitdiff with two commits given
7139                         my $hash_parent_short = $hash_parent;
7140                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7141                                 $hash_parent_short = substr($hash_parent, 0, 7);
7142                         }
7143                         $formats_nav .=
7144                                 ' (from';
7145                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7146                                 if ($co{'parents'}[$i] eq $hash_parent) {
7147                                         $formats_nav .= ' parent ' . ($i+1);
7148                                         last;
7149                                 }
7150                         }
7151                         $formats_nav .= ': ' .
7152                                 $cgi->a({-href => href(action=>"commitdiff",
7153                                                        hash=>$hash_parent)},
7154                                         esc_html($hash_parent_short)) .
7155                                 ')';
7156                 } elsif (!$co{'parent'}) {
7157                         # --root commitdiff
7158                         $formats_nav .= ' (initial)';
7159                 } elsif (scalar @{$co{'parents'}} == 1) {
7160                         # single parent commit
7161                         $formats_nav .=
7162                                 ' (parent: ' .
7163                                 $cgi->a({-href => href(action=>"commitdiff",
7164                                                        hash=>$co{'parent'})},
7165                                         esc_html(substr($co{'parent'}, 0, 7))) .
7166                                 ')';
7167                 } else {
7168                         # merge commit
7169                         if ($hash_parent eq '--cc') {
7170                                 $formats_nav .= ' | ' .
7171                                         $cgi->a({-href => href(action=>"commitdiff",
7172                                                                hash=>$hash, hash_parent=>'-c')},
7173                                                 'combined');
7174                         } else { # $hash_parent eq '-c'
7175                                 $formats_nav .= ' | ' .
7176                                         $cgi->a({-href => href(action=>"commitdiff",
7177                                                                hash=>$hash, hash_parent=>'--cc')},
7178                                                 'compact');
7179                         }
7180                         $formats_nav .=
7181                                 ' (merge: ' .
7182                                 join(' ', map {
7183                                         $cgi->a({-href => href(action=>"commitdiff",
7184                                                                hash=>$_)},
7185                                                 esc_html(substr($_, 0, 7)));
7186                                 } @{$co{'parents'}} ) .
7187                                 ')';
7188                 }
7189         }
7190
7191         my $hash_parent_param = $hash_parent;
7192         if (!defined $hash_parent_param) {
7193                 # --cc for multiple parents, --root for parentless
7194                 $hash_parent_param =
7195                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7196         }
7197
7198         # read commitdiff
7199         my $fd;
7200         my @difftree;
7201         if ($format eq 'html') {
7202                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7203                         "--no-commit-id", "--patch-with-raw", "--full-index",
7204                         $hash_parent_param, $hash, "--"
7205                         or die_error(500, "Open git-diff-tree failed");
7206
7207                 while (my $line = <$fd>) {
7208                         chomp $line;
7209                         # empty line ends raw part of diff-tree output
7210                         last unless $line;
7211                         push @difftree, scalar parse_difftree_raw_line($line);
7212                 }
7213
7214         } elsif ($format eq 'plain') {
7215                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7216                         '-p', $hash_parent_param, $hash, "--"
7217                         or die_error(500, "Open git-diff-tree failed");
7218         } elsif ($format eq 'patch') {
7219                 # For commit ranges, we limit the output to the number of
7220                 # patches specified in the 'patches' feature.
7221                 # For single commits, we limit the output to a single patch,
7222                 # diverging from the git-format-patch default.
7223                 my @commit_spec = ();
7224                 if ($hash_parent) {
7225                         if ($patch_max > 0) {
7226                                 push @commit_spec, "-$patch_max";
7227                         }
7228                         push @commit_spec, '-n', "$hash_parent..$hash";
7229                 } else {
7230                         if ($params{-single}) {
7231                                 push @commit_spec, '-1';
7232                         } else {
7233                                 if ($patch_max > 0) {
7234                                         push @commit_spec, "-$patch_max";
7235                                 }
7236                                 push @commit_spec, "-n";
7237                         }
7238                         push @commit_spec, '--root', $hash;
7239                 }
7240                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7241                         '--encoding=utf8', '--stdout', @commit_spec
7242                         or die_error(500, "Open git-format-patch failed");
7243         } else {
7244                 die_error(400, "Unknown commitdiff format");
7245         }
7246
7247         # non-textual hash id's can be cached
7248         my $expires;
7249         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7250                 $expires = "+1d";
7251         }
7252
7253         # write commit message
7254         if ($format eq 'html') {
7255                 my $refs = git_get_references();
7256                 my $ref = format_ref_marker($refs, $co{'id'});
7257
7258                 git_header_html(undef, $expires);
7259                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7260                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7261                 print "<div class=\"title_text\">\n" .
7262                       "<table class=\"object_header\">\n";
7263                 git_print_authorship_rows(\%co);
7264                 print "</table>".
7265                       "</div>\n";
7266                 print "<div class=\"page_body\">\n";
7267                 if (@{$co{'comment'}} > 1) {
7268                         print "<div class=\"log\">\n";
7269                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7270                         print "</div>\n"; # class="log"
7271                 }
7272
7273         } elsif ($format eq 'plain') {
7274                 my $refs = git_get_references("tags");
7275                 my $tagname = git_get_rev_name_tags($hash);
7276                 my $filename = basename($project) . "-$hash.patch";
7277
7278                 print $cgi->header(
7279                         -type => 'text/plain',
7280                         -charset => 'utf-8',
7281                         -expires => $expires,
7282                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7283                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7284                 print "From: " . to_utf8($co{'author'}) . "\n";
7285                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7286                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7287
7288                 print "X-Git-Tag: $tagname\n" if $tagname;
7289                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7290
7291                 foreach my $line (@{$co{'comment'}}) {
7292                         print to_utf8($line) . "\n";
7293                 }
7294                 print "---\n\n";
7295         } elsif ($format eq 'patch') {
7296                 my $filename = basename($project) . "-$hash.patch";
7297
7298                 print $cgi->header(
7299                         -type => 'text/plain',
7300                         -charset => 'utf-8',
7301                         -expires => $expires,
7302                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7303         }
7304
7305         # write patch
7306         if ($format eq 'html') {
7307                 my $use_parents = !defined $hash_parent ||
7308                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7309                 git_difftree_body(\@difftree, $hash,
7310                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7311                 print "<br/>\n";
7312
7313                 git_patchset_body($fd, \@difftree, $hash,
7314                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7315                 close $fd;
7316                 print "</div>\n"; # class="page_body"
7317                 git_footer_html();
7318
7319         } elsif ($format eq 'plain') {
7320                 local $/ = undef;
7321                 print <$fd>;
7322                 close $fd
7323                         or print "Reading git-diff-tree failed\n";
7324         } elsif ($format eq 'patch') {
7325                 local $/ = undef;
7326                 print <$fd>;
7327                 close $fd
7328                         or print "Reading git-format-patch failed\n";
7329         }
7330 }
7331
7332 sub git_commitdiff_plain {
7333         git_commitdiff(-format => 'plain');
7334 }
7335
7336 # format-patch-style patches
7337 sub git_patch {
7338         git_commitdiff(-format => 'patch', -single => 1);
7339 }
7340
7341 sub git_patches {
7342         git_commitdiff(-format => 'patch');
7343 }
7344
7345 sub git_history {
7346         git_log_generic('history', \&git_history_body,
7347                         $hash_base, $hash_parent_base,
7348                         $file_name, $hash);
7349 }
7350
7351 sub git_search {
7352         $searchtype ||= 'commit';
7353
7354         # check if appropriate features are enabled
7355         gitweb_check_feature('search')
7356                 or die_error(403, "Search is disabled");
7357         if ($searchtype eq 'pickaxe') {
7358                 # pickaxe may take all resources of your box and run for several minutes
7359                 # with every query - so decide by yourself how public you make this feature
7360                 gitweb_check_feature('pickaxe')
7361                         or die_error(403, "Pickaxe search is disabled");
7362         }
7363         if ($searchtype eq 'grep') {
7364                 # grep search might be potentially CPU-intensive, too
7365                 gitweb_check_feature('grep')
7366                         or die_error(403, "Grep search is disabled");
7367         }
7368
7369         if (!defined $searchtext) {
7370                 die_error(400, "Text field is empty");
7371         }
7372         if (!defined $hash) {
7373                 $hash = git_get_head_hash($project);
7374         }
7375         my %co = parse_commit($hash);
7376         if (!%co) {
7377                 die_error(404, "Unknown commit object");
7378         }
7379         if (!defined $page) {
7380                 $page = 0;
7381         }
7382
7383         if ($searchtype eq 'commit' ||
7384             $searchtype eq 'author' ||
7385             $searchtype eq 'committer') {
7386                 git_search_message(%co);
7387         } elsif ($searchtype eq 'pickaxe') {
7388                 git_search_changes(%co);
7389         } elsif ($searchtype eq 'grep') {
7390                 git_search_files(%co);
7391         } else {
7392                 die_error(400, "Unknown search type");
7393         }
7394 }
7395
7396 sub git_search_help {
7397         git_header_html();
7398         git_print_page_nav('','', $hash,$hash,$hash);
7399         print <<EOT;
7400 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7401 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7402 the pattern entered is recognized as the POSIX extended
7403 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7404 insensitive).</p>
7405 <dl>
7406 <dt><b>commit</b></dt>
7407 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7408 EOT
7409         my $have_grep = gitweb_check_feature('grep');
7410         if ($have_grep) {
7411                 print <<EOT;
7412 <dt><b>grep</b></dt>
7413 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7414     a different one) are searched for the given pattern. On large trees, this search can take
7415 a while and put some strain on the server, so please use it with some consideration. Note that
7416 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7417 case-sensitive.</dd>
7418 EOT
7419         }
7420         print <<EOT;
7421 <dt><b>author</b></dt>
7422 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7423 <dt><b>committer</b></dt>
7424 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7425 EOT
7426         my $have_pickaxe = gitweb_check_feature('pickaxe');
7427         if ($have_pickaxe) {
7428                 print <<EOT;
7429 <dt><b>pickaxe</b></dt>
7430 <dd>All commits that caused the string to appear or disappear from any file (changes that
7431 added, removed or "modified" the string) will be listed. This search can take a while and
7432 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7433 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7434 EOT
7435         }
7436         print "</dl>\n";
7437         git_footer_html();
7438 }
7439
7440 sub git_shortlog {
7441         git_log_generic('shortlog', \&git_shortlog_body,
7442                         $hash, $hash_parent);
7443 }
7444
7445 ## ......................................................................
7446 ## feeds (RSS, Atom; OPML)
7447
7448 sub git_feed {
7449         my $format = shift || 'atom';
7450         my $have_blame = gitweb_check_feature('blame');
7451
7452         # Atom: http://www.atomenabled.org/developers/syndication/
7453         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7454         if ($format ne 'rss' && $format ne 'atom') {
7455                 die_error(400, "Unknown web feed format");
7456         }
7457
7458         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7459         my $head = $hash || 'HEAD';
7460         my @commitlist = parse_commits($head, 150, 0, $file_name);
7461
7462         my %latest_commit;
7463         my %latest_date;
7464         my $content_type = "application/$format+xml";
7465         if (defined $cgi->http('HTTP_ACCEPT') &&
7466                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7467                 # browser (feed reader) prefers text/xml
7468                 $content_type = 'text/xml';
7469         }
7470         if (defined($commitlist[0])) {
7471                 %latest_commit = %{$commitlist[0]};
7472                 my $latest_epoch = $latest_commit{'committer_epoch'};
7473                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7474                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7475                 if (defined $if_modified) {
7476                         my $since;
7477                         if (eval { require HTTP::Date; 1; }) {
7478                                 $since = HTTP::Date::str2time($if_modified);
7479                         } elsif (eval { require Time::ParseDate; 1; }) {
7480                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7481                         }
7482                         if (defined $since && $latest_epoch <= $since) {
7483                                 print $cgi->header(
7484                                         -type => $content_type,
7485                                         -charset => 'utf-8',
7486                                         -last_modified => $latest_date{'rfc2822'},
7487                                         -status => '304 Not Modified');
7488                                 return;
7489                         }
7490                 }
7491                 print $cgi->header(
7492                         -type => $content_type,
7493                         -charset => 'utf-8',
7494                         -last_modified => $latest_date{'rfc2822'});
7495         } else {
7496                 print $cgi->header(
7497                         -type => $content_type,
7498                         -charset => 'utf-8');
7499         }
7500
7501         # Optimization: skip generating the body if client asks only
7502         # for Last-Modified date.
7503         return if ($cgi->request_method() eq 'HEAD');
7504
7505         # header variables
7506         my $title = "$site_name - $project/$action";
7507         my $feed_type = 'log';
7508         if (defined $hash) {
7509                 $title .= " - '$hash'";
7510                 $feed_type = 'branch log';
7511                 if (defined $file_name) {
7512                         $title .= " :: $file_name";
7513                         $feed_type = 'history';
7514                 }
7515         } elsif (defined $file_name) {
7516                 $title .= " - $file_name";
7517                 $feed_type = 'history';
7518         }
7519         $title .= " $feed_type";
7520         my $descr = git_get_project_description($project);
7521         if (defined $descr) {
7522                 $descr = esc_html($descr);
7523         } else {
7524                 $descr = "$project " .
7525                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7526                          " feed";
7527         }
7528         my $owner = git_get_project_owner($project);
7529         $owner = esc_html($owner);
7530
7531         #header
7532         my $alt_url;
7533         if (defined $file_name) {
7534                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7535         } elsif (defined $hash) {
7536                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7537         } else {
7538                 $alt_url = href(-full=>1, action=>"summary");
7539         }
7540         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7541         if ($format eq 'rss') {
7542                 print <<XML;
7543 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7544 <channel>
7545 XML
7546                 print "<title>$title</title>\n" .
7547                       "<link>$alt_url</link>\n" .
7548                       "<description>$descr</description>\n" .
7549                       "<language>en</language>\n" .
7550                       # project owner is responsible for 'editorial' content
7551                       "<managingEditor>$owner</managingEditor>\n";
7552                 if (defined $logo || defined $favicon) {
7553                         # prefer the logo to the favicon, since RSS
7554                         # doesn't allow both
7555                         my $img = esc_url($logo || $favicon);
7556                         print "<image>\n" .
7557                               "<url>$img</url>\n" .
7558                               "<title>$title</title>\n" .
7559                               "<link>$alt_url</link>\n" .
7560                               "</image>\n";
7561                 }
7562                 if (%latest_date) {
7563                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7564                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7565                 }
7566                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7567         } elsif ($format eq 'atom') {
7568                 print <<XML;
7569 <feed xmlns="http://www.w3.org/2005/Atom">
7570 XML
7571                 print "<title>$title</title>\n" .
7572                       "<subtitle>$descr</subtitle>\n" .
7573                       '<link rel="alternate" type="text/html" href="' .
7574                       $alt_url . '" />' . "\n" .
7575                       '<link rel="self" type="' . $content_type . '" href="' .
7576                       $cgi->self_url() . '" />' . "\n" .
7577                       "<id>" . href(-full=>1) . "</id>\n" .
7578                       # use project owner for feed author
7579                       "<author><name>$owner</name></author>\n";
7580                 if (defined $favicon) {
7581                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7582                 }
7583                 if (defined $logo) {
7584                         # not twice as wide as tall: 72 x 27 pixels
7585                         print "<logo>" . esc_url($logo) . "</logo>\n";
7586                 }
7587                 if (! %latest_date) {
7588                         # dummy date to keep the feed valid until commits trickle in:
7589                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7590                 } else {
7591                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7592                 }
7593                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7594         }
7595
7596         # contents
7597         for (my $i = 0; $i <= $#commitlist; $i++) {
7598                 my %co = %{$commitlist[$i]};
7599                 my $commit = $co{'id'};
7600                 # we read 150, we always show 30 and the ones more recent than 48 hours
7601                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7602                         last;
7603                 }
7604                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7605
7606                 # get list of changed files
7607                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7608                         $co{'parent'} || "--root",
7609                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7610                         or next;
7611                 my @difftree = map { chomp; $_ } <$fd>;
7612                 close $fd
7613                         or next;
7614
7615                 # print element (entry, item)
7616                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7617                 if ($format eq 'rss') {
7618                         print "<item>\n" .
7619                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7620                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7621                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7622                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7623                               "<link>$co_url</link>\n" .
7624                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7625                               "<content:encoded>" .
7626                               "<![CDATA[\n";
7627                 } elsif ($format eq 'atom') {
7628                         print "<entry>\n" .
7629                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7630                               "<updated>$cd{'iso-8601'}</updated>\n" .
7631                               "<author>\n" .
7632                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7633                         if ($co{'author_email'}) {
7634                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7635                         }
7636                         print "</author>\n" .
7637                               # use committer for contributor
7638                               "<contributor>\n" .
7639                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7640                         if ($co{'committer_email'}) {
7641                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7642                         }
7643                         print "</contributor>\n" .
7644                               "<published>$cd{'iso-8601'}</published>\n" .
7645                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7646                               "<id>$co_url</id>\n" .
7647                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7648                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7649                 }
7650                 my $comment = $co{'comment'};
7651                 print "<pre>\n";
7652                 foreach my $line (@$comment) {
7653                         $line = esc_html($line);
7654                         print "$line\n";
7655                 }
7656                 print "</pre><ul>\n";
7657                 foreach my $difftree_line (@difftree) {
7658                         my %difftree = parse_difftree_raw_line($difftree_line);
7659                         next if !$difftree{'from_id'};
7660
7661                         my $file = $difftree{'file'} || $difftree{'to_file'};
7662
7663                         print "<li>" .
7664                               "[" .
7665                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7666                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7667                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7668                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7669                                       -title => "diff"}, 'D');
7670                         if ($have_blame) {
7671                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7672                                                              file_name=>$file, hash_base=>$commit),
7673                                               -title => "blame"}, 'B');
7674                         }
7675                         # if this is not a feed of a file history
7676                         if (!defined $file_name || $file_name ne $file) {
7677                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7678                                                              file_name=>$file, hash=>$commit),
7679                                               -title => "history"}, 'H');
7680                         }
7681                         $file = esc_path($file);
7682                         print "] ".
7683                               "$file</li>\n";
7684                 }
7685                 if ($format eq 'rss') {
7686                         print "</ul>]]>\n" .
7687                               "</content:encoded>\n" .
7688                               "</item>\n";
7689                 } elsif ($format eq 'atom') {
7690                         print "</ul>\n</div>\n" .
7691                               "</content>\n" .
7692                               "</entry>\n";
7693                 }
7694         }
7695
7696         # end of feed
7697         if ($format eq 'rss') {
7698                 print "</channel>\n</rss>\n";
7699         } elsif ($format eq 'atom') {
7700                 print "</feed>\n";
7701         }
7702 }
7703
7704 sub git_rss {
7705         git_feed('rss');
7706 }
7707
7708 sub git_atom {
7709         git_feed('atom');
7710 }
7711
7712 sub git_opml {
7713         my @list = git_get_projects_list();
7714         if (!@list) {
7715                 die_error(404, "No projects found");
7716         }
7717
7718         print $cgi->header(
7719                 -type => 'text/xml',
7720                 -charset => 'utf-8',
7721                 -content_disposition => 'inline; filename="opml.xml"');
7722
7723         print <<XML;
7724 <?xml version="1.0" encoding="utf-8"?>
7725 <opml version="1.0">
7726 <head>
7727   <title>$site_name OPML Export</title>
7728 </head>
7729 <body>
7730 <outline text="git RSS feeds">
7731 XML
7732
7733         foreach my $pr (@list) {
7734                 my %proj = %$pr;
7735                 my $head = git_get_head_hash($proj{'path'});
7736                 if (!defined $head) {
7737                         next;
7738                 }
7739                 $git_dir = "$projectroot/$proj{'path'}";
7740                 my %co = parse_commit($head);
7741                 if (!%co) {
7742                         next;
7743                 }
7744
7745                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7746                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7747                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7748                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7749         }
7750         print <<XML;
7751 </outline>
7752 </body>
7753 </opml>
7754 XML
7755 }