git-gui.sh

   1 #!/bin/sh
   2 # Tcl ignores the next line -*- tcl -*- \
   3  if test "z$*" = zversion \
   4  || test "z$*" = z--version; \
   5  then \
   6         echo 'git-gui version @@GITGUI_VERSION@@'; \
   7         exit; \
   8  fi; \
   9  argv0=$0; \
  10  exec wish "$argv0" -- "$@"
  11
  12 set appvers {@@GITGUI_VERSION@@}
  13 set copyright [string map [list (c) \u00a9] {
  14 Copyright (c) 2006-2010 Shawn Pearce, et. al.
  15
  16 This program is free software; you can redistribute it and/or modify
  17 it under the terms of the GNU General Public License as published by
  18 the Free Software Foundation; either version 2 of the License, or
  19 (at your option) any later version.
  20
  21 This program is distributed in the hope that it will be useful,
  22 but WITHOUT ANY WARRANTY; without even the implied warranty of
  23 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  24 GNU General Public License for more details.
  25
  26 You should have received a copy of the GNU General Public License
  27 along with this program; if not, write to the Free Software
  28 Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA}]
  29
  30 ######################################################################
  31 ##
  32 ## Tcl/Tk sanity check
  33
  34 if {[catch {package require Tcl 8.4} err]
  35  || [catch {package require Tk  8.4} err]
  36 } {
  37         catch {wm withdraw .}
  38         tk_messageBox \
  39                 -icon error \
  40                 -type ok \
  41                 -title "git-gui: fatal error" \
  42                 -message $err
  43         exit 1
  44 }
  45
  46 catch {rename send {}} ; # What an evil concept...
  47
  48 ######################################################################
  49 ##
  50 ## locate our library
  51
  52 set oguilib {@@GITGUI_LIBDIR@@}
  53 set oguirel {@@GITGUI_RELATIVE@@}
  54 if {$oguirel eq {1}} {
  55         set oguilib [file dirname [file normalize $argv0]]
  56         if {[file tail $oguilib] eq {git-core}} {
  57                 set oguilib [file dirname $oguilib]
  58         }
  59         set oguilib [file dirname $oguilib]
  60         set oguilib [file join $oguilib share git-gui lib]
  61         set oguimsg [file join $oguilib msgs]
  62 } elseif {[string match @@* $oguirel]} {
  63         set oguilib [file join [file dirname [file normalize $argv0]] lib]
  64         set oguimsg [file join [file dirname [file normalize $argv0]] po]
  65 } else {
  66         set oguimsg [file join $oguilib msgs]
  67 }
  68 unset oguirel
  69
  70 ######################################################################
  71 ##
  72 ## enable verbose loading?
  73
  74 if {![catch {set _verbose $env(GITGUI_VERBOSE)}]} {
  75         unset _verbose
  76         rename auto_load real__auto_load
  77         proc auto_load {name args} {
  78                 puts stderr "auto_load $name"
  79                 return [uplevel 1 real__auto_load $name $args]
  80         }
  81         rename source real__source
  82         proc source {name} {
  83                 puts stderr "source    $name"
  84                 uplevel 1 real__source $name
  85         }
  86         if {[tk windowingsystem] eq "win32"} { console show }
  87 }
  88
  89 ######################################################################
  90 ##
  91 ## Internationalization (i18n) through msgcat and gettext. See
  92 ## http://www.gnu.org/software/gettext/manual/html_node/Tcl.html
  93
  94 package require msgcat
  95
  96 # Check for Windows 7 MUI language pack (missed by msgcat < 1.4.4)
  97 if {[tk windowingsystem] eq "win32"
  98         && [package vcompare [package provide msgcat] 1.4.4] < 0
  99 } then {
 100         proc _mc_update_locale {} {
 101                 set key {HKEY_CURRENT_USER\Control Panel\Desktop}
 102                 if {![catch {
 103                         package require registry
 104                         set uilocale [registry get $key "PreferredUILanguages"]
 105                         msgcat::ConvertLocale [string map {- _} [lindex $uilocale 0]]
 106                 } uilocale]} {
 107                         if {[string length $uilocale] > 0} {
 108                                 msgcat::mclocale $uilocale
 109                         }
 110                 }
 111         }
 112         _mc_update_locale
 113 }
 114
 115 proc _mc_trim {fmt} {
 116         set cmk [string first @@ $fmt]
 117         if {$cmk > 0} {
 118                 return [string range $fmt 0 [expr {$cmk - 1}]]
 119         }
 120         return $fmt
 121 }
 122
 123 proc mc {en_fmt args} {
 124         set fmt [_mc_trim [::msgcat::mc $en_fmt]]
 125         if {[catch {set msg [eval [list format $fmt] $args]} err]} {
 126                 set msg [eval [list format [_mc_trim $en_fmt]] $args]
 127         }
 128         return $msg
 129 }
 130
 131 proc strcat {args} {
 132         return [join $args {}]
 133 }
 134
 135 ::msgcat::mcload $oguimsg
 136 unset oguimsg
 137
 138 ######################################################################
 139 ##
 140 ## On Mac, bring the current Wish process window to front
 141
 142 if {[tk windowingsystem] eq "aqua"} {
 143         catch {
 144                 exec osascript -e [format {
 145                         tell application "System Events"
 146                                 set frontmost of processes whose unix id is %d to true
 147                         end tell
 148                 } [pid]]
 149         }
 150 }
 151
 152 ######################################################################
 153 ##
 154 ## read only globals
 155
 156 set _appname {Git Gui}
 157 set _gitdir {}
 158 set _gitworktree {}
 159 set _isbare {}
 160 set _gitexec {}
 161 set _githtmldir {}
 162 set _reponame {}
 163 set _iscygwin {}
 164 set _search_path {}
 165 set _shellpath {@@SHELL_PATH@@}
 166
 167 set _trace [lsearch -exact $argv --trace]
 168 if {$_trace >= 0} {
 169         set argv [lreplace $argv $_trace $_trace]
 170         set _trace 1
 171         if {[tk windowingsystem] eq "win32"} { console show }
 172 } else {
 173         set _trace 0
 174 }
 175
 176 # variable for the last merged branch (useful for a default when deleting
 177 # branches).
 178 set _last_merged_branch {}
 179
 180 proc shellpath {} {
 181         global _shellpath env
 182         if {[string match @@* $_shellpath]} {
 183                 if {[info exists env(SHELL)]} {
 184                         return $env(SHELL)
 185                 } else {
 186                         return /bin/sh
 187                 }
 188         }
 189         return $_shellpath
 190 }
 191
 192 proc appname {} {
 193         global _appname
 194         return $_appname
 195 }
 196
 197 proc gitdir {args} {
 198         global _gitdir
 199         if {$args eq {}} {
 200                 return $_gitdir
 201         }
 202         return [eval [list file join $_gitdir] $args]
 203 }
 204
 205 proc gitexec {args} {
 206         global _gitexec
 207         if {$_gitexec eq {}} {
 208                 if {[catch {set _gitexec [git --exec-path]} err]} {
 209                         error "Git not installed?\n\n$err"
 210                 }
 211                 if {[is_Cygwin]} {
 212                         set _gitexec [exec cygpath \
 213                                 --windows \
 214                                 --absolute \
 215                                 $_gitexec]
 216                 } else {
 217                         set _gitexec [file normalize $_gitexec]
 218                 }
 219         }
 220         if {$args eq {}} {
 221                 return $_gitexec
 222         }
 223         return [eval [list file join $_gitexec] $args]
 224 }
 225
 226 proc githtmldir {args} {
 227         global _githtmldir
 228         if {$_githtmldir eq {}} {
 229                 if {[catch {set _githtmldir [git --html-path]}]} {
 230                         # Git not installed or option not yet supported
 231                         return {}
 232                 }
 233                 if {[is_Cygwin]} {
 234                         set _githtmldir [exec cygpath \
 235                                 --windows \
 236                                 --absolute \
 237                                 $_githtmldir]
 238                 } else {
 239                         set _githtmldir [file normalize $_githtmldir]
 240                 }
 241         }
 242         if {$args eq {}} {
 243                 return $_githtmldir
 244         }
 245         return [eval [list file join $_githtmldir] $args]
 246 }
 247
 248 proc reponame {} {
 249         return $::_reponame
 250 }
 251
 252 proc is_MacOSX {} {
 253         if {[tk windowingsystem] eq {aqua}} {
 254                 return 1
 255         }
 256         return 0
 257 }
 258
 259 proc is_Windows {} {
 260         if {$::tcl_platform(platform) eq {windows}} {
 261                 return 1
 262         }
 263         return 0
 264 }
 265
 266 proc is_Cygwin {} {
 267         global _iscygwin
 268         if {$_iscygwin eq {}} {
 269                 if {$::tcl_platform(platform) eq {windows}} {
 270                         if {[catch {set p [exec cygpath --windir]} err]} {
 271                                 set _iscygwin 0
 272                         } else {
 273                                 set _iscygwin 1
 274                         }
 275                 } else {
 276                         set _iscygwin 0
 277                 }
 278         }
 279         return $_iscygwin
 280 }
 281
 282 proc is_enabled {option} {
 283         global enabled_options
 284         if {[catch {set on $enabled_options($option)}]} {return 0}
 285         return $on
 286 }
 287
 288 proc enable_option {option} {
 289         global enabled_options
 290         set enabled_options($option) 1
 291 }
 292
 293 proc disable_option {option} {
 294         global enabled_options
 295         set enabled_options($option) 0
 296 }
 297
 298 ######################################################################
 299 ##
 300 ## config
 301
 302 proc is_many_config {name} {
 303         switch -glob -- $name {
 304         gui.recentrepo -
 305         remote.*.fetch -
 306         remote.*.push
 307                 {return 1}
 308         *
 309                 {return 0}
 310         }
 311 }
 312
 313 proc is_config_true {name} {
 314         global repo_config
 315         if {[catch {set v $repo_config($name)}]} {
 316                 return 0
 317         }
 318         set v [string tolower $v]
 319         if {$v eq {} || $v eq {true} || $v eq {1} || $v eq {yes} || $v eq {on}} {
 320                 return 1
 321         } else {
 322                 return 0
 323         }
 324 }
 325
 326 proc is_config_false {name} {
 327         global repo_config
 328         if {[catch {set v $repo_config($name)}]} {
 329                 return 0
 330         }
 331         set v [string tolower $v]
 332         if {$v eq {false} || $v eq {0} || $v eq {no} || $v eq {off}} {
 333                 return 1
 334         } else {
 335                 return 0
 336         }
 337 }
 338
 339 proc get_config {name} {
 340         global repo_config
 341         if {[catch {set v $repo_config($name)}]} {
 342                 return {}
 343         } else {
 344                 return $v
 345         }
 346 }
 347
 348 proc is_bare {} {
 349         global _isbare
 350         global _gitdir
 351         global _gitworktree
 352
 353         if {$_isbare eq {}} {
 354                 if {[catch {
 355                         set _bare [git rev-parse --is-bare-repository]
 356                         switch  -- $_bare {
 357                         true { set _isbare 1 }
 358                         false { set _isbare 0}
 359                         default { throw }
 360                         }
 361                 }]} {
 362                         if {[is_config_true core.bare]
 363                                 || ($_gitworktree eq {}
 364                                         && [lindex [file split $_gitdir] end] ne {.git})} {
 365                                 set _isbare 1
 366                         } else {
 367                                 set _isbare 0
 368                         }
 369                 }
 370         }
 371         return $_isbare
 372 }
 373
 374 ######################################################################
 375 ##
 376 ## handy utils
 377
 378 proc _trace_exec {cmd} {
 379         if {!$::_trace} return
 380         set d {}
 381         foreach v $cmd {
 382                 if {$d ne {}} {
 383                         append d { }
 384                 }
 385                 if {[regexp {[ \t\r\n'"$?*]} $v]} {
 386                         set v [sq $v]
 387                 }
 388                 append d $v
 389         }
 390         puts stderr $d
 391 }
 392
 393 #'"  fix poor old emacs font-lock mode
 394
 395 proc _git_cmd {name} {
 396         global _git_cmd_path
 397
 398         if {[catch {set v $_git_cmd_path($name)}]} {
 399                 switch -- $name {
 400                   version   -
 401                 --version   -
 402                 --exec-path { return [list $::_git $name] }
 403                 }
 404
 405                 set p [gitexec git-$name$::_search_exe]
 406                 if {[file exists $p]} {
 407                         set v [list $p]
 408                 } elseif {[is_Windows] && [file exists [gitexec git-$name]]} {
 409                         # Try to determine what sort of magic will make
 410                         # git-$name go and do its thing, because native
 411                         # Tcl on Windows doesn't know it.
 412                         #
 413                         set p [gitexec git-$name]
 414                         set f [open $p r]
 415                         set s [gets $f]
 416                         close $f
 417
 418                         switch -glob -- [lindex $s 0] {
 419                         #!*sh     { set i sh     }
 420                         #!*perl   { set i perl   }
 421                         #!*python { set i python }
 422                         default   { error "git-$name is not supported: $s" }
 423                         }
 424
 425                         upvar #0 _$i interp
 426                         if {![info exists interp]} {
 427                                 set interp [_which $i]
 428                         }
 429                         if {$interp eq {}} {
 430                                 error "git-$name requires $i (not in PATH)"
 431                         }
 432                         set v [concat [list $interp] [lrange $s 1 end] [list $p]]
 433                 } else {
 434                         # Assume it is builtin to git somehow and we
 435                         # aren't actually able to see a file for it.
 436                         #
 437                         set v [list $::_git $name]
 438                 }
 439                 set _git_cmd_path($name) $v
 440         }
 441         return $v
 442 }
 443
 444 proc _which {what args} {
 445         global env _search_exe _search_path
 446
 447         if {$_search_path eq {}} {
 448                 if {[is_Cygwin] && [regexp {^(/|\.:)} $env(PATH)]} {
 449                         set _search_path [split [exec cygpath \
 450                                 --windows \
 451                                 --path \
 452                                 --absolute \
 453                                 $env(PATH)] {;}]
 454                         set _search_exe .exe
 455                 } elseif {[is_Windows]} {
 456                         set gitguidir [file dirname [info script]]
 457                         regsub -all ";" $gitguidir "\\;" gitguidir
 458                         set env(PATH) "$gitguidir;$env(PATH)"
 459                         set _search_path [split $env(PATH) {;}]
 460                         set _search_exe .exe
 461                 } else {
 462                         set _search_path [split $env(PATH) :]
 463                         set _search_exe {}
 464                 }
 465         }
 466
 467         if {[is_Windows] && [lsearch -exact $args -script] >= 0} {
 468                 set suffix {}
 469         } else {
 470                 set suffix $_search_exe
 471         }
 472
 473         foreach p $_search_path {
 474                 set p [file join $p $what$suffix]
 475                 if {[file exists $p]} {
 476                         return [file normalize $p]
 477                 }
 478         }
 479         return {}
 480 }
 481
 482 # Test a file for a hashbang to identify executable scripts on Windows.
 483 proc is_shellscript {filename} {
 484         if {![file exists $filename]} {return 0}
 485         set f [open $filename r]
 486         fconfigure $f -encoding binary
 487         set magic [read $f 2]
 488         close $f
 489         return [expr {$magic eq "#!"}]
 490 }
 491
 492 # Run a command connected via pipes on stdout.
 493 # This is for use with textconv filters and uses sh -c "..." to allow it to
 494 # contain a command with arguments. On windows we must check for shell
 495 # scripts specifically otherwise just call the filter command.
 496 proc open_cmd_pipe {cmd path} {
 497         global env
 498         if {![file executable [shellpath]]} {
 499                 set exe [auto_execok [lindex $cmd 0]]
 500                 if {[is_shellscript [lindex $exe 0]]} {
 501                         set run [linsert [auto_execok sh] end -c "$cmd \"\$0\"" $path]
 502                 } else {
 503                         set run [concat $exe [lrange $cmd 1 end] $path]
 504                 }
 505         } else {
 506                 set run [list [shellpath] -c "$cmd \"\$0\"" $path]
 507         }
 508         return [open |$run r]
 509 }
 510
 511 proc _lappend_nice {cmd_var} {
 512         global _nice
 513         upvar $cmd_var cmd
 514
 515         if {![info exists _nice]} {
 516                 set _nice [_which nice]
 517                 if {[catch {exec $_nice git version}]} {
 518                         set _nice {}
 519                 } elseif {[is_Windows] && [file dirname $_nice] ne [file dirname $::_git]} {
 520                         set _nice {}
 521                 }
 522         }
 523         if {$_nice ne {}} {
 524                 lappend cmd $_nice
 525         }
 526 }
 527
 528 proc git {args} {
 529         set opt [list]
 530
 531         while {1} {
 532                 switch -- [lindex $args 0] {
 533                 --nice {
 534                         _lappend_nice opt
 535                 }
 536
 537                 default {
 538                         break
 539                 }
 540
 541                 }
 542
 543                 set args [lrange $args 1 end]
 544         }
 545
 546         set cmdp [_git_cmd [lindex $args 0]]
 547         set args [lrange $args 1 end]
 548
 549         _trace_exec [concat $opt $cmdp $args]
 550         set result [eval exec $opt $cmdp $args]
 551         if {$::_trace} {
 552                 puts stderr "< $result"
 553         }
 554         return $result
 555 }
 556
 557 proc _open_stdout_stderr {cmd} {
 558         _trace_exec $cmd
 559         if {[catch {
 560                         set fd [open [concat [list | ] $cmd] r]
 561                 } err]} {
 562                 if {   [lindex $cmd end] eq {2>@1}
 563                     && $err eq {can not find channel named "1"}
 564                         } {
 565                         # Older versions of Tcl 8.4 don't have this 2>@1 IO
 566                         # redirect operator.  Fallback to |& cat for those.
 567                         # The command was not actually started, so its safe
 568                         # to try to start it a second time.
 569                         #
 570                         set fd [open [concat \
 571                                 [list | ] \
 572                                 [lrange $cmd 0 end-1] \
 573                                 [list |& cat] \
 574                                 ] r]
 575                 } else {
 576                         error $err
 577                 }
 578         }
 579         fconfigure $fd -eofchar {}
 580         return $fd
 581 }
 582
 583 proc git_read {args} {
 584         set opt [list]
 585
 586         while {1} {
 587                 switch -- [lindex $args 0] {
 588                 --nice {
 589                         _lappend_nice opt
 590                 }
 591
 592                 --stderr {
 593                         lappend args 2>@1
 594                 }
 595
 596                 default {
 597                         break
 598                 }
 599
 600                 }
 601
 602                 set args [lrange $args 1 end]
 603         }
 604
 605         set cmdp [_git_cmd [lindex $args 0]]
 606         set args [lrange $args 1 end]
 607
 608         return [_open_stdout_stderr [concat $opt $cmdp $args]]
 609 }
 610
 611 proc git_write {args} {
 612         set opt [list]
 613
 614         while {1} {
 615                 switch -- [lindex $args 0] {
 616                 --nice {
 617                         _lappend_nice opt
 618                 }
 619
 620                 default {
 621                         break
 622                 }
 623
 624                 }
 625
 626                 set args [lrange $args 1 end]
 627         }
 628
 629         set cmdp [_git_cmd [lindex $args 0]]
 630         set args [lrange $args 1 end]
 631
 632         _trace_exec [concat $opt $cmdp $args]
 633         return [open [concat [list | ] $opt $cmdp $args] w]
 634 }
 635
 636 proc githook_read {hook_name args} {
 637         set pchook [gitdir hooks $hook_name]
 638         lappend args 2>@1
 639
 640         # On Windows [file executable] might lie so we need to ask
 641         # the shell if the hook is executable.  Yes that's annoying.
 642         #
 643         if {[is_Windows]} {
 644                 upvar #0 _sh interp
 645                 if {![info exists interp]} {
 646                         set interp [_which sh]
 647                 }
 648                 if {$interp eq {}} {
 649                         error "hook execution requires sh (not in PATH)"
 650                 }
 651
 652                 set scr {if test -x "$1";then exec "$@";fi}
 653                 set sh_c [list $interp -c $scr $interp $pchook]
 654                 return [_open_stdout_stderr [concat $sh_c $args]]
 655         }
 656
 657         if {[file executable $pchook]} {
 658                 return [_open_stdout_stderr [concat [list $pchook] $args]]
 659         }
 660
 661         return {}
 662 }
 663
 664 proc kill_file_process {fd} {
 665         set process [pid $fd]
 666
 667         catch {
 668                 if {[is_Windows]} {
 669                         # Use a Cygwin-specific flag to allow killing
 670                         # native Windows processes
 671                         exec kill -f $process
 672                 } else {
 673                         exec kill $process
 674                 }
 675         }
 676 }
 677
 678 proc gitattr {path attr default} {
 679         if {[catch {set r [git check-attr $attr -- $path]}]} {
 680                 set r unspecified
 681         } else {
 682                 set r [join [lrange [split $r :] 2 end] :]
 683                 regsub {^ } $r {} r
 684         }
 685         if {$r eq {unspecified}} {
 686                 return $default
 687         }
 688         return $r
 689 }
 690
 691 proc sq {value} {
 692         regsub -all ' $value "'\\''" value
 693         return "'$value'"
 694 }
 695
 696 proc load_current_branch {} {
 697         global current_branch is_detached
 698
 699         set fd [open [gitdir HEAD] r]
 700         if {[gets $fd ref] < 1} {
 701                 set ref {}
 702         }
 703         close $fd
 704
 705         set pfx {ref: refs/heads/}
 706         set len [string length $pfx]
 707         if {[string equal -length $len $pfx $ref]} {
 708                 # We're on a branch.  It might not exist.  But
 709                 # HEAD looks good enough to be a branch.
 710                 #
 711                 set current_branch [string range $ref $len end]
 712                 set is_detached 0
 713         } else {
 714                 # Assume this is a detached head.
 715                 #
 716                 set current_branch HEAD
 717                 set is_detached 1
 718         }
 719 }
 720
 721 auto_load tk_optionMenu
 722 rename tk_optionMenu real__tkOptionMenu
 723 proc tk_optionMenu {w varName args} {
 724         set m [eval real__tkOptionMenu $w $varName $args]
 725         $m configure -font font_ui
 726         $w configure -font font_ui
 727         return $m
 728 }
 729
 730 proc rmsel_tag {text} {
 731         $text tag conf sel \
 732                 -background [$text cget -background] \
 733                 -foreground [$text cget -foreground] \
 734                 -borderwidth 0
 735         $text tag conf in_sel -background lightgray
 736         bind $text <Motion> break
 737         return $text
 738 }
 739
 740 wm withdraw .
 741 set root_exists 0
 742 bind . <Visibility> {
 743         bind . <Visibility> {}
 744         set root_exists 1
 745 }
 746
 747 if {[is_Windows]} {
 748         wm iconbitmap . -default $oguilib/git-gui.ico
 749         set ::tk::AlwaysShowSelection 1
 750         bind . <Control-F2> {console show}
 751
 752         # Spoof an X11 display for SSH
 753         if {![info exists env(DISPLAY)]} {
 754                 set env(DISPLAY) :9999
 755         }
 756 } else {
 757         catch {
 758                 image create photo gitlogo -width 16 -height 16
 759
 760                 gitlogo put #33CC33 -to  7  0  9  2
 761                 gitlogo put #33CC33 -to  4  2 12  4
 762                 gitlogo put #33CC33 -to  7  4  9  6
 763                 gitlogo put #CC3333 -to  4  6 12  8
 764                 gitlogo put gray26  -to  4  9  6 10
 765                 gitlogo put gray26  -to  3 10  6 12
 766                 gitlogo put gray26  -to  8  9 13 11
 767                 gitlogo put gray26  -to  8 11 10 12
 768                 gitlogo put gray26  -to 11 11 13 14
 769                 gitlogo put gray26  -to  3 12  5 14
 770                 gitlogo put gray26  -to  5 13
 771                 gitlogo put gray26  -to 10 13
 772                 gitlogo put gray26  -to  4 14 12 15
 773                 gitlogo put gray26  -to  5 15 11 16
 774                 gitlogo redither
 775
 776                 image create photo gitlogo32 -width 32 -height 32
 777                 gitlogo32 copy gitlogo -zoom 2 2
 778
 779                 wm iconphoto . -default gitlogo gitlogo32
 780         }
 781 }
 782
 783 ######################################################################
 784 ##
 785 ## config defaults
 786
 787 set cursor_ptr arrow
 788 font create font_ui
 789 if {[lsearch -exact [font names] TkDefaultFont] != -1} {
 790         eval [linsert [font actual TkDefaultFont] 0 font configure font_ui]
 791         eval [linsert [font actual TkFixedFont] 0 font create font_diff]
 792 } else {
 793         font create font_diff -family Courier -size 10
 794         catch {
 795                 label .dummy
 796                 eval font configure font_ui [font actual [.dummy cget -font]]
 797                 destroy .dummy
 798         }
 799 }
 800
 801 font create font_uiitalic
 802 font create font_uibold
 803 font create font_diffbold
 804 font create font_diffitalic
 805
 806 foreach class {Button Checkbutton Entry Label
 807                 Labelframe Listbox Message
 808                 Radiobutton Spinbox Text} {
 809         option add *$class.font font_ui
 810 }
 811 if {![is_MacOSX]} {
 812         option add *Menu.font font_ui
 813         option add *Entry.borderWidth 1 startupFile
 814         option add *Entry.relief sunken startupFile
 815         option add *RadioButton.anchor w startupFile
 816 }
 817 unset class
 818
 819 if {[is_Windows] || [is_MacOSX]} {
 820         option add *Menu.tearOff 0
 821 }
 822
 823 if {[is_MacOSX]} {
 824         set M1B M1
 825         set M1T Cmd
 826 } else {
 827         set M1B Control
 828         set M1T Ctrl
 829 }
 830
 831 proc bind_button3 {w cmd} {
 832         bind $w <Any-Button-3> $cmd
 833         if {[is_MacOSX]} {
 834                 # Mac OS X sends Button-2 on right click through three-button mouse,
 835                 # or through trackpad right-clicking (two-finger touch + click).
 836                 bind $w <Any-Button-2> $cmd
 837                 bind $w <Control-Button-1> $cmd
 838         }
 839 }
 840
 841 proc apply_config {} {
 842         global repo_config font_descs
 843
 844         foreach option $font_descs {
 845                 set name [lindex $option 0]
 846                 set font [lindex $option 1]
 847                 if {[catch {
 848                         set need_weight 1
 849                         foreach {cn cv} $repo_config(gui.$name) {
 850                                 if {$cn eq {-weight}} {
 851                                         set need_weight 0
 852                                 }
 853                                 font configure $font $cn $cv
 854                         }
 855                         if {$need_weight} {
 856                                 font configure $font -weight normal
 857                         }
 858                         } err]} {
 859                         error_popup [strcat [mc "Invalid font specified in %s:" "gui.$name"] "\n\n$err"]
 860                 }
 861                 foreach {cn cv} [font configure $font] {
 862                         font configure ${font}bold $cn $cv
 863                         font configure ${font}italic $cn $cv
 864                 }
 865                 font configure ${font}bold -weight bold
 866                 font configure ${font}italic -slant italic
 867         }
 868
 869         global use_ttk NS
 870         set use_ttk 0
 871         set NS {}
 872         if {$repo_config(gui.usettk)} {
 873                 set use_ttk [package vsatisfies [package provide Tk] 8.5]
 874                 if {$use_ttk} {
 875                         set NS ttk
 876                         bind [winfo class .] <<ThemeChanged>> [list InitTheme]
 877                         pave_toplevel .
 878                 }
 879         }
 880 }
 881
 882 set default_config(branch.autosetupmerge) true
 883 set default_config(merge.tool) {}
 884 set default_config(mergetool.keepbackup) true
 885 set default_config(merge.diffstat) true
 886 set default_config(merge.summary) false
 887 set default_config(merge.verbosity) 2
 888 set default_config(user.name) {}
 889 set default_config(user.email) {}
 890
 891 set default_config(gui.encoding) [encoding system]
 892 set default_config(gui.matchtrackingbranch) false
 893 set default_config(gui.textconv) true
 894 set default_config(gui.pruneduringfetch) false
 895 set default_config(gui.trustmtime) false
 896 set default_config(gui.fastcopyblame) false
 897 set default_config(gui.maxrecentrepo) 10
 898 set default_config(gui.copyblamethreshold) 40
 899 set default_config(gui.blamehistoryctx) 7
 900 set default_config(gui.diffcontext) 5
 901 set default_config(gui.diffopts) {}
 902 set default_config(gui.commitmsgwidth) 75
 903 set default_config(gui.newbranchtemplate) {}
 904 set default_config(gui.spellingdictionary) {}
 905 set default_config(gui.fontui) [font configure font_ui]
 906 set default_config(gui.fontdiff) [font configure font_diff]
 907 # TODO: this option should be added to the git-config documentation
 908 set default_config(gui.maxfilesdisplayed) 5000
 909 set default_config(gui.usettk) 1
 910 set default_config(gui.warndetachedcommit) 1
 911 set font_descs {
 912         {fontui   font_ui   {mc "Main Font"}}
 913         {fontdiff font_diff {mc "Diff/Console Font"}}
 914 }
 915 set default_config(gui.stageuntracked) ask
 916 set default_config(gui.displayuntracked) true
 917
 918 ######################################################################
 919 ##
 920 ## find git
 921
 922 set _git  [_which git]
 923 if {$_git eq {}} {
 924         catch {wm withdraw .}
 925         tk_messageBox \
 926                 -icon error \
 927                 -type ok \
 928                 -title [mc "git-gui: fatal error"] \
 929                 -message [mc "Cannot find git in PATH."]
 930         exit 1
 931 }
 932
 933 ######################################################################
 934 ##
 935 ## version check
 936
 937 if {[catch {set _git_version [git --version]} err]} {
 938         catch {wm withdraw .}
 939         tk_messageBox \
 940                 -icon error \
 941                 -type ok \
 942                 -title [mc "git-gui: fatal error"] \
 943                 -message "Cannot determine Git version:
 944
 945 $err
 946
 947 [appname] requires Git 1.5.0 or later."
 948         exit 1
 949 }
 950 if {![regsub {^git version } $_git_version {} _git_version]} {
 951         catch {wm withdraw .}
 952         tk_messageBox \
 953                 -icon error \
 954                 -type ok \
 955                 -title [mc "git-gui: fatal error"] \
 956                 -message [strcat [mc "Cannot parse Git version string:"] "\n\n$_git_version"]
 957         exit 1
 958 }
 959
 960 proc get_trimmed_version {s} {
 961     set r {}
 962     foreach x [split $s -._] {
 963         if {[string is integer -strict $x]} {
 964             lappend r $x
 965         } else {
 966             break
 967         }
 968     }
 969     return [join $r .]
 970 }
 971 set _real_git_version $_git_version
 972 set _git_version [get_trimmed_version $_git_version]
 973
 974 if {![regexp {^[1-9]+(\.[0-9]+)+$} $_git_version]} {
 975         catch {wm withdraw .}
 976         if {[tk_messageBox \
 977                 -icon warning \
 978                 -type yesno \
 979                 -default no \
 980                 -title "[appname]: warning" \
 981                  -message [mc "Git version cannot be determined.
 982
 983 %s claims it is version '%s'.
 984
 985 %s requires at least Git 1.5.0 or later.
 986
 987 Assume '%s' is version 1.5.0?
 988 " $_git $_real_git_version [appname] $_real_git_version]] eq {yes}} {
 989                 set _git_version 1.5.0
 990         } else {
 991                 exit 1
 992         }
 993 }
 994 unset _real_git_version
 995
 996 proc git-version {args} {
 997         global _git_version
 998
 999         switch [llength $args] {
1000         0 {
1001                 return $_git_version
1002         }
1003
1004         2 {
1005                 set op [lindex $args 0]
1006                 set vr [lindex $args 1]
1007                 set cm [package vcompare $_git_version $vr]
1008                 return [expr $cm $op 0]
1009         }
1010
1011         4 {
1012                 set type [lindex $args 0]
1013                 set name [lindex $args 1]
1014                 set parm [lindex $args 2]
1015                 set body [lindex $args 3]
1016
1017                 if {($type ne {proc} && $type ne {method})} {
1018                         error "Invalid arguments to git-version"
1019                 }
1020                 if {[llength $body] < 2 || [lindex $body end-1] ne {default}} {
1021                         error "Last arm of $type $name must be default"
1022                 }
1023
1024                 foreach {op vr cb} [lrange $body 0 end-2] {
1025                         if {[git-version $op $vr]} {
1026                                 return [uplevel [list $type $name $parm $cb]]
1027                         }
1028                 }
1029
1030                 return [uplevel [list $type $name $parm [lindex $body end]]]
1031         }
1032
1033         default {
1034                 error "git-version >= x"
1035         }
1036
1037         }
1038 }
1039
1040 if {[git-version < 1.5]} {
1041         catch {wm withdraw .}
1042         tk_messageBox \
1043                 -icon error \
1044                 -type ok \
1045                 -title [mc "git-gui: fatal error"] \
1046                 -message "[appname] requires Git 1.5.0 or later.
1047
1048 You are using [git-version]:
1049
1050 [git --version]"
1051         exit 1
1052 }
1053
1054 ######################################################################
1055 ##
1056 ## configure our library
1057
1058 set idx [file join $oguilib tclIndex]
1059 if {[catch {set fd [open $idx r]} err]} {
1060         catch {wm withdraw .}
1061         tk_messageBox \
1062                 -icon error \
1063                 -type ok \
1064                 -title [mc "git-gui: fatal error"] \
1065                 -message $err
1066         exit 1
1067 }
1068 if {[gets $fd] eq {# Autogenerated by git-gui Makefile}} {
1069         set idx [list]
1070         while {[gets $fd n] >= 0} {
1071                 if {$n ne {} && ![string match #* $n]} {
1072                         lappend idx $n
1073                 }
1074         }
1075 } else {
1076         set idx {}
1077 }
1078 close $fd
1079
1080 if {$idx ne {}} {
1081         set loaded [list]
1082         foreach p $idx {
1083                 if {[lsearch -exact $loaded $p] >= 0} continue
1084                 source [file join $oguilib $p]
1085                 lappend loaded $p
1086         }
1087         unset loaded p
1088 } else {
1089         set auto_path [concat [list $oguilib] $auto_path]
1090 }
1091 unset -nocomplain idx fd
1092
1093 ######################################################################
1094 ##
1095 ## config file parsing
1096
1097 git-version proc _parse_config {arr_name args} {
1098         >= 1.5.3 {
1099                 upvar $arr_name arr
1100                 array unset arr
1101                 set buf {}
1102                 catch {
1103                         set fd_rc [eval \
1104                                 [list git_read config] \
1105                                 $args \
1106                                 [list --null --list]]
1107                         fconfigure $fd_rc -translation binary
1108                         set buf [read $fd_rc]
1109                         close $fd_rc
1110                 }
1111                 foreach line [split $buf "\0"] {
1112                         if {[regexp {^([^\n]+)\n(.*)$} $line line name value]} {
1113                                 if {[is_many_config $name]} {
1114                                         lappend arr($name) $value
1115                                 } else {
1116                                         set arr($name) $value
1117                                 }
1118                         } elseif {[regexp {^([^\n]+)$} $line line name]} {
1119                                 # no value given, but interpreting them as
1120                                 # boolean will be handled as true
1121                                 set arr($name) {}
1122                         }
1123                 }
1124         }
1125         default {
1126                 upvar $arr_name arr
1127                 array unset arr
1128                 catch {
1129                         set fd_rc [eval [list git_read config --list] $args]
1130                         while {[gets $fd_rc line] >= 0} {
1131                                 if {[regexp {^([^=]+)=(.*)$} $line line name value]} {
1132                                         if {[is_many_config $name]} {
1133                                                 lappend arr($name) $value
1134                                         } else {
1135                                                 set arr($name) $value
1136                                         }
1137                                 } elseif {[regexp {^([^=]+)$} $line line name]} {
1138                                         # no value given, but interpreting them as
1139                                         # boolean will be handled as true
1140                                         set arr($name) {}
1141                                 }
1142                         }
1143                         close $fd_rc
1144                 }
1145         }
1146 }
1147
1148 proc load_config {include_global} {
1149         global repo_config global_config system_config default_config
1150
1151         if {$include_global} {
1152                 _parse_config system_config --system
1153                 _parse_config global_config --global
1154         }
1155         _parse_config repo_config
1156
1157         foreach name [array names default_config] {
1158                 if {[catch {set v $system_config($name)}]} {
1159                         set system_config($name) $default_config($name)
1160                 }
1161         }
1162         foreach name [array names system_config] {
1163                 if {[catch {set v $global_config($name)}]} {
1164                         set global_config($name) $system_config($name)
1165                 }
1166                 if {[catch {set v $repo_config($name)}]} {
1167                         set repo_config($name) $system_config($name)
1168                 }
1169         }
1170 }
1171
1172 ######################################################################
1173 ##
1174 ## feature option selection
1175
1176 if {[regexp {^git-(.+)$} [file tail $argv0] _junk subcommand]} {
1177         unset _junk
1178 } else {
1179         set subcommand gui
1180 }
1181 if {$subcommand eq {gui.sh}} {
1182         set subcommand gui
1183 }
1184 if {$subcommand eq {gui} && [llength $argv] > 0} {
1185         set subcommand [lindex $argv 0]
1186         set argv [lrange $argv 1 end]
1187 }
1188
1189 enable_option multicommit
1190 enable_option branch
1191 enable_option transport
1192 disable_option bare
1193
1194 switch -- $subcommand {
1195 browser -
1196 blame {
1197         enable_option bare
1198
1199         disable_option multicommit
1200         disable_option branch
1201         disable_option transport
1202 }
1203 citool {
1204         enable_option singlecommit
1205         enable_option retcode
1206
1207         disable_option multicommit
1208         disable_option branch
1209         disable_option transport
1210
1211         while {[llength $argv] > 0} {
1212                 set a [lindex $argv 0]
1213                 switch -- $a {
1214                 --amend {
1215                         enable_option initialamend
1216                 }
1217                 --nocommit {
1218                         enable_option nocommit
1219                         enable_option nocommitmsg
1220                 }
1221                 --commitmsg {
1222                         disable_option nocommitmsg
1223                 }
1224                 default {
1225                         break
1226                 }
1227                 }
1228
1229                 set argv [lrange $argv 1 end]
1230         }
1231 }
1232 }
1233
1234 ######################################################################
1235 ##
1236 ## execution environment
1237
1238 set have_tk85 [expr {[package vcompare $tk_version "8.5"] >= 0}]
1239
1240 # Suggest our implementation of askpass, if none is set
1241 if {![info exists env(SSH_ASKPASS)]} {
1242         set env(SSH_ASKPASS) [gitexec git-gui--askpass]
1243 }
1244
1245 ######################################################################
1246 ##
1247 ## repository setup
1248
1249 set picked 0
1250 if {[catch {
1251                 set _gitdir $env(GIT_DIR)
1252                 set _prefix {}
1253                 }]
1254         && [catch {
1255                 # beware that from the .git dir this sets _gitdir to .
1256                 # and _prefix to the empty string
1257                 set _gitdir [git rev-parse --git-dir]
1258                 set _prefix [git rev-parse --show-prefix]
1259         } err]} {
1260         load_config 1
1261         apply_config
1262         choose_repository::pick
1263         set picked 1
1264 }
1265
1266 # we expand the _gitdir when it's just a single dot (i.e. when we're being
1267 # run from the .git dir itself) lest the routines to find the worktree
1268 # get confused
1269 if {$_gitdir eq "."} {
1270         set _gitdir [pwd]
1271 }
1272
1273 if {![file isdirectory $_gitdir] && [is_Cygwin]} {
1274         catch {set _gitdir [exec cygpath --windows $_gitdir]}
1275 }
1276 if {![file isdirectory $_gitdir]} {
1277         catch {wm withdraw .}
1278         error_popup [strcat [mc "Git directory not found:"] "\n\n$_gitdir"]
1279         exit 1
1280 }
1281 # _gitdir exists, so try loading the config
1282 load_config 0
1283 apply_config
1284
1285 # v1.7.0 introduced --show-toplevel to return the canonical work-tree
1286 if {[package vsatisfies $_git_version 1.7.0]} {
1287         if { [is_Cygwin] } {
1288                 catch {set _gitworktree [exec cygpath --windows [git rev-parse --show-toplevel]]}
1289         } else {
1290                 set _gitworktree [git rev-parse --show-toplevel]
1291         }
1292 } else {
1293         # try to set work tree from environment, core.worktree or use
1294         # cdup to obtain a relative path to the top of the worktree. If
1295         # run from the top, the ./ prefix ensures normalize expands pwd.
1296         if {[catch { set _gitworktree $env(GIT_WORK_TREE) }]} {
1297                 set _gitworktree [get_config core.worktree]
1298                 if {$_gitworktree eq ""} {
1299                         set _gitworktree [file normalize ./[git rev-parse --show-cdup]]
1300                 }
1301         }
1302 }
1303
1304 if {$_prefix ne {}} {
1305         if {$_gitworktree eq {}} {
1306                 regsub -all {[^/]+/} $_prefix ../ cdup
1307         } else {
1308                 set cdup $_gitworktree
1309         }
1310         if {[catch {cd $cdup} err]} {
1311                 catch {wm withdraw .}
1312                 error_popup [strcat [mc "Cannot move to top of working directory:"] "\n\n$err"]
1313                 exit 1
1314         }
1315         set _gitworktree [pwd]
1316         unset cdup
1317 } elseif {![is_enabled bare]} {
1318         if {[is_bare]} {
1319                 catch {wm withdraw .}
1320                 error_popup [strcat [mc "Cannot use bare repository:"] "\n\n$_gitdir"]
1321                 exit 1
1322         }
1323         if {$_gitworktree eq {}} {
1324                 set _gitworktree [file dirname $_gitdir]
1325         }
1326         if {[catch {cd $_gitworktree} err]} {
1327                 catch {wm withdraw .}
1328                 error_popup [strcat [mc "No working directory"] " $_gitworktree:\n\n$err"]
1329                 exit 1
1330         }
1331         set _gitworktree [pwd]
1332 }
1333 set _reponame [file split [file normalize $_gitdir]]
1334 if {[lindex $_reponame end] eq {.git}} {
1335         set _reponame [lindex $_reponame end-1]
1336 } else {
1337         set _reponame [lindex $_reponame end]
1338 }
1339
1340 set env(GIT_DIR) $_gitdir
1341 set env(GIT_WORK_TREE) $_gitworktree
1342
1343 ######################################################################
1344 ##
1345 ## global init
1346
1347 set current_diff_path {}
1348 set current_diff_side {}
1349 set diff_actions [list]
1350
1351 set HEAD {}
1352 set PARENT {}
1353 set MERGE_HEAD [list]
1354 set commit_type {}
1355 set empty_tree {}
1356 set current_branch {}
1357 set is_detached 0
1358 set current_diff_path {}
1359 set is_3way_diff 0
1360 set is_submodule_diff 0
1361 set is_conflict_diff 0
1362 set selected_commit_type new
1363 set diff_empty_count 0
1364
1365 set nullid "0000000000000000000000000000000000000000"
1366 set nullid2 "0000000000000000000000000000000000000001"
1367
1368 ######################################################################
1369 ##
1370 ## task management
1371
1372 set rescan_active 0
1373 set diff_active 0
1374 set last_clicked {}
1375
1376 set disable_on_lock [list]
1377 set index_lock_type none
1378
1379 proc lock_index {type} {
1380         global index_lock_type disable_on_lock
1381
1382         if {$index_lock_type eq {none}} {
1383                 set index_lock_type $type
1384                 foreach w $disable_on_lock {
1385                         uplevel #0 $w disabled
1386                 }
1387                 return 1
1388         } elseif {$index_lock_type eq "begin-$type"} {
1389                 set index_lock_type $type
1390                 return 1
1391         }
1392         return 0
1393 }
1394
1395 proc unlock_index {} {
1396         global index_lock_type disable_on_lock
1397
1398         set index_lock_type none
1399         foreach w $disable_on_lock {
1400                 uplevel #0 $w normal
1401         }
1402 }
1403
1404 ######################################################################
1405 ##
1406 ## status
1407
1408 proc repository_state {ctvar hdvar mhvar} {
1409         global current_branch
1410         upvar $ctvar ct $hdvar hd $mhvar mh
1411
1412         set mh [list]
1413
1414         load_current_branch
1415         if {[catch {set hd [git rev-parse --verify HEAD]}]} {
1416                 set hd {}
1417                 set ct initial
1418                 return
1419         }
1420
1421         set merge_head [gitdir MERGE_HEAD]
1422         if {[file exists $merge_head]} {
1423                 set ct merge
1424                 set fd_mh [open $merge_head r]
1425                 while {[gets $fd_mh line] >= 0} {
1426                         lappend mh $line
1427                 }
1428                 close $fd_mh
1429                 return
1430         }
1431
1432         set ct normal
1433 }
1434
1435 proc PARENT {} {
1436         global PARENT empty_tree
1437
1438         set p [lindex $PARENT 0]
1439         if {$p ne {}} {
1440                 return $p
1441         }
1442         if {$empty_tree eq {}} {
1443                 set empty_tree [git mktree << {}]
1444         }
1445         return $empty_tree
1446 }
1447
1448 proc force_amend {} {
1449         global selected_commit_type
1450         global HEAD PARENT MERGE_HEAD commit_type
1451
1452         repository_state newType newHEAD newMERGE_HEAD
1453         set HEAD $newHEAD
1454         set PARENT $newHEAD
1455         set MERGE_HEAD $newMERGE_HEAD
1456         set commit_type $newType
1457
1458         set selected_commit_type amend
1459         do_select_commit_type
1460 }
1461
1462 proc rescan {after {honor_trustmtime 1}} {
1463         global HEAD PARENT MERGE_HEAD commit_type
1464         global ui_index ui_workdir ui_comm
1465         global rescan_active file_states
1466         global repo_config
1467
1468         if {$rescan_active > 0 || ![lock_index read]} return
1469
1470         repository_state newType newHEAD newMERGE_HEAD
1471         if {[string match amend* $commit_type]
1472                 && $newType eq {normal}
1473                 && $newHEAD eq $HEAD} {
1474         } else {
1475                 set HEAD $newHEAD
1476                 set PARENT $newHEAD
1477                 set MERGE_HEAD $newMERGE_HEAD
1478                 set commit_type $newType
1479         }
1480
1481         array unset file_states
1482
1483         if {!$::GITGUI_BCK_exists &&
1484                 (![$ui_comm edit modified]
1485                 || [string trim [$ui_comm get 0.0 end]] eq {})} {
1486                 if {[string match amend* $commit_type]} {
1487                 } elseif {[load_message GITGUI_MSG utf-8]} {
1488                 } elseif {[run_prepare_commit_msg_hook]} {
1489                 } elseif {[load_message MERGE_MSG]} {
1490                 } elseif {[load_message SQUASH_MSG]} {
1491                 }
1492                 $ui_comm edit reset
1493                 $ui_comm edit modified false
1494         }
1495
1496         if {$honor_trustmtime && $repo_config(gui.trustmtime) eq {true}} {
1497                 rescan_stage2 {} $after
1498         } else {
1499                 set rescan_active 1
1500                 ui_status [mc "Refreshing file status..."]
1501                 set fd_rf [git_read update-index \
1502                         -q \
1503                         --unmerged \
1504                         --ignore-missing \
1505                         --refresh \
1506                         ]
1507                 fconfigure $fd_rf -blocking 0 -translation binary
1508                 fileevent $fd_rf readable \
1509                         [list rescan_stage2 $fd_rf $after]
1510         }
1511 }
1512
1513 if {[is_Cygwin]} {
1514         set is_git_info_exclude {}
1515         proc have_info_exclude {} {
1516                 global is_git_info_exclude
1517
1518                 if {$is_git_info_exclude eq {}} {
1519                         if {[catch {exec test -f [gitdir info exclude]}]} {
1520                                 set is_git_info_exclude 0
1521                         } else {
1522                                 set is_git_info_exclude 1
1523                         }
1524                 }
1525                 return $is_git_info_exclude
1526         }
1527 } else {
1528         proc have_info_exclude {} {
1529                 return [file readable [gitdir info exclude]]
1530         }
1531 }
1532
1533 proc rescan_stage2 {fd after} {
1534         global rescan_active buf_rdi buf_rdf buf_rlo
1535
1536         if {$fd ne {}} {
1537                 read $fd
1538                 if {![eof $fd]} return
1539                 close $fd
1540         }
1541
1542         if {[package vsatisfies $::_git_version 1.6.3]} {
1543                 set ls_others [list --exclude-standard]
1544         } else {
1545                 set ls_others [list --exclude-per-directory=.gitignore]
1546                 if {[have_info_exclude]} {
1547                         lappend ls_others "--exclude-from=[gitdir info exclude]"
1548                 }
1549                 set user_exclude [get_config core.excludesfile]
1550                 if {$user_exclude ne {} && [file readable $user_exclude]} {
1551                         lappend ls_others "--exclude-from=[file normalize $user_exclude]"
1552                 }
1553         }
1554
1555         set buf_rdi {}
1556         set buf_rdf {}
1557         set buf_rlo {}
1558
1559         set rescan_active 2
1560         ui_status [mc "Scanning for modified files ..."]
1561         set fd_di [git_read diff-index --cached -z [PARENT]]
1562         set fd_df [git_read diff-files -z]
1563
1564         fconfigure $fd_di -blocking 0 -translation binary -encoding binary
1565         fconfigure $fd_df -blocking 0 -translation binary -encoding binary
1566
1567         fileevent $fd_di readable [list read_diff_index $fd_di $after]
1568         fileevent $fd_df readable [list read_diff_files $fd_df $after]
1569
1570         if {[is_config_true gui.displayuntracked]} {
1571                 set fd_lo [eval git_read ls-files --others -z $ls_others]
1572                 fconfigure $fd_lo -blocking 0 -translation binary -encoding binary
1573                 fileevent $fd_lo readable [list read_ls_others $fd_lo $after]
1574                 incr rescan_active
1575         }
1576 }
1577
1578 proc load_message {file {encoding {}}} {
1579         global ui_comm
1580
1581         set f [gitdir $file]
1582         if {[file isfile $f]} {
1583                 if {[catch {set fd [open $f r]}]} {
1584                         return 0
1585                 }
1586                 fconfigure $fd -eofchar {}
1587                 if {$encoding ne {}} {
1588                         fconfigure $fd -encoding $encoding
1589                 }
1590                 set content [string trim [read $fd]]
1591                 close $fd
1592                 regsub -all -line {[ \r\t]+$} $content {} content
1593                 $ui_comm delete 0.0 end
1594                 $ui_comm insert end $content
1595                 return 1
1596         }
1597         return 0
1598 }
1599
1600 proc run_prepare_commit_msg_hook {} {
1601         global pch_error
1602
1603         # prepare-commit-msg requires PREPARE_COMMIT_MSG exist.  From git-gui
1604         # it will be .git/MERGE_MSG (merge), .git/SQUASH_MSG (squash), or an
1605         # empty file but existent file.
1606
1607         set fd_pcm [open [gitdir PREPARE_COMMIT_MSG] a]
1608
1609         if {[file isfile [gitdir MERGE_MSG]]} {
1610                 set pcm_source "merge"
1611                 set fd_mm [open [gitdir MERGE_MSG] r]
1612                 puts -nonewline $fd_pcm [read $fd_mm]
1613                 close $fd_mm
1614         } elseif {[file isfile [gitdir SQUASH_MSG]]} {
1615                 set pcm_source "squash"
1616                 set fd_sm [open [gitdir SQUASH_MSG] r]
1617                 puts -nonewline $fd_pcm [read $fd_sm]
1618                 close $fd_sm
1619         } else {
1620                 set pcm_source ""
1621         }
1622
1623         close $fd_pcm
1624
1625         set fd_ph [githook_read prepare-commit-msg \
1626                         [gitdir PREPARE_COMMIT_MSG] $pcm_source]
1627         if {$fd_ph eq {}} {
1628                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1629                 return 0;
1630         }
1631
1632         ui_status [mc "Calling prepare-commit-msg hook..."]
1633         set pch_error {}
1634
1635         fconfigure $fd_ph -blocking 0 -translation binary -eofchar {}
1636         fileevent $fd_ph readable \
1637                 [list prepare_commit_msg_hook_wait $fd_ph]
1638
1639         return 1;
1640 }
1641
1642 proc prepare_commit_msg_hook_wait {fd_ph} {
1643         global pch_error
1644
1645         append pch_error [read $fd_ph]
1646         fconfigure $fd_ph -blocking 1
1647         if {[eof $fd_ph]} {
1648                 if {[catch {close $fd_ph}]} {
1649                         ui_status [mc "Commit declined by prepare-commit-msg hook."]
1650                         hook_failed_popup prepare-commit-msg $pch_error
1651                         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1652                         exit 1
1653                 } else {
1654                         load_message PREPARE_COMMIT_MSG
1655                 }
1656                 set pch_error {}
1657                 catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1658                 return
1659         }
1660         fconfigure $fd_ph -blocking 0
1661         catch {file delete [gitdir PREPARE_COMMIT_MSG]}
1662 }
1663
1664 proc read_diff_index {fd after} {
1665         global buf_rdi
1666
1667         append buf_rdi [read $fd]
1668         set c 0
1669         set n [string length $buf_rdi]
1670         while {$c < $n} {
1671                 set z1 [string first "\0" $buf_rdi $c]
1672                 if {$z1 == -1} break
1673                 incr z1
1674                 set z2 [string first "\0" $buf_rdi $z1]
1675                 if {$z2 == -1} break
1676
1677                 incr c
1678                 set i [split [string range $buf_rdi $c [expr {$z1 - 2}]] { }]
1679                 set p [string range $buf_rdi $z1 [expr {$z2 - 1}]]
1680                 merge_state \
1681                         [encoding convertfrom $p] \
1682                         [lindex $i 4]? \
1683                         [list [lindex $i 0] [lindex $i 2]] \
1684                         [list]
1685                 set c $z2
1686                 incr c
1687         }
1688         if {$c < $n} {
1689                 set buf_rdi [string range $buf_rdi $c end]
1690         } else {
1691                 set buf_rdi {}
1692         }
1693
1694         rescan_done $fd buf_rdi $after
1695 }
1696
1697 proc read_diff_files {fd after} {
1698         global buf_rdf
1699
1700         append buf_rdf [read $fd]
1701         set c 0
1702         set n [string length $buf_rdf]
1703         while {$c < $n} {
1704                 set z1 [string first "\0" $buf_rdf $c]
1705                 if {$z1 == -1} break
1706                 incr z1
1707                 set z2 [string first "\0" $buf_rdf $z1]
1708                 if {$z2 == -1} break
1709
1710                 incr c
1711                 set i [split [string range $buf_rdf $c [expr {$z1 - 2}]] { }]
1712                 set p [string range $buf_rdf $z1 [expr {$z2 - 1}]]
1713                 merge_state \
1714                         [encoding convertfrom $p] \
1715                         ?[lindex $i 4] \
1716                         [list] \
1717                         [list [lindex $i 0] [lindex $i 2]]
1718                 set c $z2
1719                 incr c
1720         }
1721         if {$c < $n} {
1722                 set buf_rdf [string range $buf_rdf $c end]
1723         } else {
1724                 set buf_rdf {}
1725         }
1726
1727         rescan_done $fd buf_rdf $after
1728 }
1729
1730 proc read_ls_others {fd after} {
1731         global buf_rlo
1732
1733         append buf_rlo [read $fd]
1734         set pck [split $buf_rlo "\0"]
1735         set buf_rlo [lindex $pck end]
1736         foreach p [lrange $pck 0 end-1] {
1737                 set p [encoding convertfrom $p]
1738                 if {[string index $p end] eq {/}} {
1739                         set p [string range $p 0 end-1]
1740                 }
1741                 merge_state $p ?O
1742         }
1743         rescan_done $fd buf_rlo $after
1744 }
1745
1746 proc rescan_done {fd buf after} {
1747         global rescan_active current_diff_path
1748         global file_states repo_config
1749         upvar $buf to_clear
1750
1751         if {![eof $fd]} return
1752         set to_clear {}
1753         close $fd
1754         if {[incr rescan_active -1] > 0} return
1755
1756         prune_selection
1757         unlock_index
1758         display_all_files
1759         if {$current_diff_path ne {}} { reshow_diff $after }
1760         if {$current_diff_path eq {}} { select_first_diff $after }
1761 }
1762
1763 proc prune_selection {} {
1764         global file_states selected_paths
1765
1766         foreach path [array names selected_paths] {
1767                 if {[catch {set still_here $file_states($path)}]} {
1768                         unset selected_paths($path)
1769                 }
1770         }
1771 }
1772
1773 ######################################################################
1774 ##
1775 ## ui helpers
1776
1777 proc mapicon {w state path} {
1778         global all_icons
1779
1780         if {[catch {set r $all_icons($state$w)}]} {
1781                 puts "error: no icon for $w state={$state} $path"
1782                 return file_plain
1783         }
1784         return $r
1785 }
1786
1787 proc mapdesc {state path} {
1788         global all_descs
1789
1790         if {[catch {set r $all_descs($state)}]} {
1791                 puts "error: no desc for state={$state} $path"
1792                 return $state
1793         }
1794         return $r
1795 }
1796
1797 proc ui_status {msg} {
1798         global main_status
1799         if {[info exists main_status]} {
1800                 $main_status show $msg
1801         }
1802 }
1803
1804 proc ui_ready {{test {}}} {
1805         global main_status
1806         if {[info exists main_status]} {
1807                 $main_status show [mc "Ready."] $test
1808         }
1809 }
1810
1811 proc escape_path {path} {
1812         regsub -all {\\} $path "\\\\" path
1813         regsub -all "\n" $path "\\n" path
1814         return $path
1815 }
1816
1817 proc short_path {path} {
1818         return [escape_path [lindex [file split $path] end]]
1819 }
1820
1821 set next_icon_id 0
1822 set null_sha1 [string repeat 0 40]
1823
1824 proc merge_state {path new_state {head_info {}} {index_info {}}} {
1825         global file_states next_icon_id null_sha1
1826
1827         set s0 [string index $new_state 0]
1828         set s1 [string index $new_state 1]
1829
1830         if {[catch {set info $file_states($path)}]} {
1831                 set state __
1832                 set icon n[incr next_icon_id]
1833         } else {
1834                 set state [lindex $info 0]
1835                 set icon [lindex $info 1]
1836                 if {$head_info eq {}}  {set head_info  [lindex $info 2]}
1837                 if {$index_info eq {}} {set index_info [lindex $info 3]}
1838         }
1839
1840         if     {$s0 eq {?}} {set s0 [string index $state 0]} \
1841         elseif {$s0 eq {_}} {set s0 _}
1842
1843         if     {$s1 eq {?}} {set s1 [string index $state 1]} \
1844         elseif {$s1 eq {_}} {set s1 _}
1845
1846         if {$s0 eq {A} && $s1 eq {_} && $head_info eq {}} {
1847                 set head_info [list 0 $null_sha1]
1848         } elseif {$s0 ne {_} && [string index $state 0] eq {_}
1849                 && $head_info eq {}} {
1850                 set head_info $index_info
1851         } elseif {$s0 eq {_} && [string index $state 0] ne {_}} {
1852                 set index_info $head_info
1853                 set head_info {}
1854         }
1855
1856         set file_states($path) [list $s0$s1 $icon \
1857                 $head_info $index_info \
1858                 ]
1859         return $state
1860 }
1861
1862 proc display_file_helper {w path icon_name old_m new_m} {
1863         global file_lists
1864
1865         if {$new_m eq {_}} {
1866                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1867                 if {$lno >= 0} {
1868                         set file_lists($w) [lreplace $file_lists($w) $lno $lno]
1869                         incr lno
1870                         $w conf -state normal
1871                         $w delete $lno.0 [expr {$lno + 1}].0
1872                         $w conf -state disabled
1873                 }
1874         } elseif {$old_m eq {_} && $new_m ne {_}} {
1875                 lappend file_lists($w) $path
1876                 set file_lists($w) [lsort -unique $file_lists($w)]
1877                 set lno [lsearch -sorted -exact $file_lists($w) $path]
1878                 incr lno
1879                 $w conf -state normal
1880                 $w image create $lno.0 \
1881                         -align center -padx 5 -pady 1 \
1882                         -name $icon_name \
1883                         -image [mapicon $w $new_m $path]
1884                 $w insert $lno.1 "[escape_path $path]\n"
1885                 $w conf -state disabled
1886         } elseif {$old_m ne $new_m} {
1887                 $w conf -state normal
1888                 $w image conf $icon_name -image [mapicon $w $new_m $path]
1889                 $w conf -state disabled
1890         }
1891 }
1892
1893 proc display_file {path state} {
1894         global file_states selected_paths
1895         global ui_index ui_workdir
1896
1897         set old_m [merge_state $path $state]
1898         set s $file_states($path)
1899         set new_m [lindex $s 0]
1900         set icon_name [lindex $s 1]
1901
1902         set o [string index $old_m 0]
1903         set n [string index $new_m 0]
1904         if {$o eq {U}} {
1905                 set o _
1906         }
1907         if {$n eq {U}} {
1908                 set n _
1909         }
1910         display_file_helper     $ui_index $path $icon_name $o $n
1911
1912         if {[string index $old_m 0] eq {U}} {
1913                 set o U
1914         } else {
1915                 set o [string index $old_m 1]
1916         }
1917         if {[string index $new_m 0] eq {U}} {
1918                 set n U
1919         } else {
1920                 set n [string index $new_m 1]
1921         }
1922         display_file_helper     $ui_workdir $path $icon_name $o $n
1923
1924         if {$new_m eq {__}} {
1925                 unset file_states($path)
1926                 catch {unset selected_paths($path)}
1927         }
1928 }
1929
1930 proc display_all_files_helper {w path icon_name m} {
1931         global file_lists
1932
1933         lappend file_lists($w) $path
1934         set lno [expr {[lindex [split [$w index end] .] 0] - 1}]
1935         $w image create end \
1936                 -align center -padx 5 -pady 1 \
1937                 -name $icon_name \
1938                 -image [mapicon $w $m $path]
1939         $w insert end "[escape_path $path]\n"
1940 }
1941
1942 set files_warning 0
1943 proc display_all_files {} {
1944         global ui_index ui_workdir
1945         global file_states file_lists
1946         global last_clicked
1947         global files_warning
1948
1949         $ui_index conf -state normal
1950         $ui_workdir conf -state normal
1951
1952         $ui_index delete 0.0 end
1953         $ui_workdir delete 0.0 end
1954         set last_clicked {}
1955
1956         set file_lists($ui_index) [list]
1957         set file_lists($ui_workdir) [list]
1958
1959         set to_display [lsort [array names file_states]]
1960         set display_limit [get_config gui.maxfilesdisplayed]
1961         if {[llength $to_display] > $display_limit} {
1962                 if {!$files_warning} {
1963                         # do not repeatedly warn:
1964                         set files_warning 1
1965                         info_popup [mc "Displaying only %s of %s files." \
1966                                 $display_limit [llength $to_display]]
1967                 }
1968                 set to_display [lrange $to_display 0 [expr {$display_limit-1}]]
1969         }
1970         foreach path $to_display {
1971                 set s $file_states($path)
1972                 set m [lindex $s 0]
1973                 set icon_name [lindex $s 1]
1974
1975                 set s [string index $m 0]
1976                 if {$s ne {U} && $s ne {_}} {
1977                         display_all_files_helper $ui_index $path \
1978                                 $icon_name $s
1979                 }
1980
1981                 if {[string index $m 0] eq {U}} {
1982                         set s U
1983                 } else {
1984                         set s [string index $m 1]
1985                 }
1986                 if {$s ne {_}} {
1987                         display_all_files_helper $ui_workdir $path \
1988                                 $icon_name $s
1989                 }
1990         }
1991
1992         $ui_index conf -state disabled
1993         $ui_workdir conf -state disabled
1994 }
1995
1996 ######################################################################
1997 ##
1998 ## icons
1999
2000 set filemask {
2001 #define mask_width 14
2002 #define mask_height 15
2003 static unsigned char mask_bits[] = {
2004    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2005    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f,
2006    0xfe, 0x1f, 0xfe, 0x1f, 0xfe, 0x1f};
2007 }
2008
2009 image create bitmap file_plain -background white -foreground black -data {
2010 #define plain_width 14
2011 #define plain_height 15
2012 static unsigned char plain_bits[] = {
2013    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2014    0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10, 0x02, 0x10,
2015    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2016 } -maskdata $filemask
2017
2018 image create bitmap file_mod -background white -foreground blue -data {
2019 #define mod_width 14
2020 #define mod_height 15
2021 static unsigned char mod_bits[] = {
2022    0xfe, 0x01, 0x02, 0x03, 0x7a, 0x05, 0x02, 0x09, 0x7a, 0x1f, 0x02, 0x10,
2023    0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2024    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2025 } -maskdata $filemask
2026
2027 image create bitmap file_fulltick -background white -foreground "#007000" -data {
2028 #define file_fulltick_width 14
2029 #define file_fulltick_height 15
2030 static unsigned char file_fulltick_bits[] = {
2031    0xfe, 0x01, 0x02, 0x1a, 0x02, 0x0c, 0x02, 0x0c, 0x02, 0x16, 0x02, 0x16,
2032    0x02, 0x13, 0x00, 0x13, 0x86, 0x11, 0x8c, 0x11, 0xd8, 0x10, 0xf2, 0x10,
2033    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2034 } -maskdata $filemask
2035
2036 image create bitmap file_question -background white -foreground black -data {
2037 #define file_question_width 14
2038 #define file_question_height 15
2039 static unsigned char file_question_bits[] = {
2040    0xfe, 0x01, 0x02, 0x02, 0xe2, 0x04, 0xf2, 0x09, 0x1a, 0x1b, 0x0a, 0x13,
2041    0x82, 0x11, 0xc2, 0x10, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10, 0x62, 0x10,
2042    0x62, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2043 } -maskdata $filemask
2044
2045 image create bitmap file_removed -background white -foreground red -data {
2046 #define file_removed_width 14
2047 #define file_removed_height 15
2048 static unsigned char file_removed_bits[] = {
2049    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x02, 0x10,
2050    0x1a, 0x16, 0x32, 0x13, 0xe2, 0x11, 0xc2, 0x10, 0xe2, 0x11, 0x32, 0x13,
2051    0x1a, 0x16, 0x02, 0x10, 0xfe, 0x1f};
2052 } -maskdata $filemask
2053
2054 image create bitmap file_merge -background white -foreground blue -data {
2055 #define file_merge_width 14
2056 #define file_merge_height 15
2057 static unsigned char file_merge_bits[] = {
2058    0xfe, 0x01, 0x02, 0x03, 0x62, 0x05, 0x62, 0x09, 0x62, 0x1f, 0x62, 0x10,
2059    0xfa, 0x11, 0xf2, 0x10, 0x62, 0x10, 0x02, 0x10, 0xfa, 0x17, 0x02, 0x10,
2060    0xfa, 0x17, 0x02, 0x10, 0xfe, 0x1f};
2061 } -maskdata $filemask
2062
2063 image create bitmap file_statechange -background white -foreground green -data {
2064 #define file_statechange_width 14
2065 #define file_statechange_height 15
2066 static unsigned char file_statechange_bits[] = {
2067    0xfe, 0x01, 0x02, 0x03, 0x02, 0x05, 0x02, 0x09, 0x02, 0x1f, 0x62, 0x10,
2068    0x62, 0x10, 0xba, 0x11, 0xba, 0x11, 0x62, 0x10, 0x62, 0x10, 0x02, 0x10,
2069    0x02, 0x10, 0x02, 0x10, 0xfe, 0x1f};
2070 } -maskdata $filemask
2071
2072 set ui_index .vpane.files.index.list
2073 set ui_workdir .vpane.files.workdir.list
2074
2075 set all_icons(_$ui_index)   file_plain
2076 set all_icons(A$ui_index)   file_plain
2077 set all_icons(M$ui_index)   file_fulltick
2078 set all_icons(D$ui_index)   file_removed
2079 set all_icons(U$ui_index)   file_merge
2080 set all_icons(T$ui_index)   file_statechange
2081
2082 set all_icons(_$ui_workdir) file_plain
2083 set all_icons(M$ui_workdir) file_mod
2084 set all_icons(D$ui_workdir) file_question
2085 set all_icons(U$ui_workdir) file_merge
2086 set all_icons(O$ui_workdir) file_plain
2087 set all_icons(T$ui_workdir) file_statechange
2088
2089 foreach i {
2090                 {__ {mc "Unmodified"}}
2091
2092                 {_M {mc "Modified, not staged"}}
2093                 {M_ {mc "Staged for commit"}}
2094                 {MM {mc "Portions staged for commit"}}
2095                 {MD {mc "Staged for commit, missing"}}
2096
2097                 {_T {mc "File type changed, not staged"}}
2098                 {MT {mc "File type changed, old type staged for commit"}}
2099                 {AT {mc "File type changed, old type staged for commit"}}
2100                 {T_ {mc "File type changed, staged"}}
2101                 {TM {mc "File type change staged, modification not staged"}}
2102                 {TD {mc "File type change staged, file missing"}}
2103
2104                 {_O {mc "Untracked, not staged"}}
2105                 {A_ {mc "Staged for commit"}}
2106                 {AM {mc "Portions staged for commit"}}
2107                 {AD {mc "Staged for commit, missing"}}
2108
2109                 {_D {mc "Missing"}}
2110                 {D_ {mc "Staged for removal"}}
2111                 {DO {mc "Staged for removal, still present"}}
2112
2113                 {_U {mc "Requires merge resolution"}}
2114                 {U_ {mc "Requires merge resolution"}}
2115                 {UU {mc "Requires merge resolution"}}
2116                 {UM {mc "Requires merge resolution"}}
2117                 {UD {mc "Requires merge resolution"}}
2118                 {UT {mc "Requires merge resolution"}}
2119         } {
2120         set all_descs([lindex $i 0]) [eval [lindex $i 1]]
2121 }
2122 unset i
2123
2124 ######################################################################
2125 ##
2126 ## util
2127
2128 proc scrollbar2many {list mode args} {
2129         foreach w $list {eval $w $mode $args}
2130 }
2131
2132 proc many2scrollbar {list mode sb top bottom} {
2133         $sb set $top $bottom
2134         foreach w $list {$w $mode moveto $top}
2135 }
2136
2137 # delegates mouse selection actions from gutter columns to the main text
2138 # widget
2139 # use delegator_bind, if you need to bind more actions
2140 proc delegate_sel_to {w from} {
2141         set bind_list [list \
2142                 <Button-1> \
2143                 <B1-Motion> \
2144                 <Double-Button-1> \
2145                 <Triple-Button-1> \
2146                 <Shift-Button-1> \
2147                 <Double-Shift-Button-1> \
2148                 <Triple-Shift-Button-1> \
2149         ]
2150
2151         foreach seq $bind_list {
2152                 set script [bind Text $seq]
2153                 set new_script [string map [list %W $w %x 0 word line] $script]
2154                 foreach f $from {
2155                         bind $f $seq "$new_script; focus $w; break"
2156                 }
2157         }
2158 }
2159
2160 # use this for binding any of the mouse actions from a delegator
2161 # see bind_list in delegate_sel_to
2162 proc delegator_bind {tag seq script} {
2163         bind $tag $seq "$script; [bind $tag $seq]"
2164 }
2165
2166 proc incr_font_size {font {amt 1}} {
2167         set sz [font configure $font -size]
2168         incr sz $amt
2169         font configure $font -size $sz
2170         font configure ${font}bold -size $sz
2171         font configure ${font}italic -size $sz
2172 }
2173
2174 ######################################################################
2175 ##
2176 ## ui commands
2177
2178 set starting_gitk_msg [mc "Starting gitk... please wait..."]
2179
2180 proc do_gitk {revs {is_submodule false}} {
2181         global current_diff_path file_states current_diff_side ui_index
2182         global _gitdir _gitworktree
2183
2184         # -- Always start gitk through whatever we were loaded with.  This
2185         #    lets us bypass using shell process on Windows systems.
2186         #
2187         set exe [_which gitk -script]
2188         set cmd [list [info nameofexecutable] $exe]
2189         if {$exe eq {}} {
2190                 error_popup [mc "Couldn't find gitk in PATH"]
2191         } else {
2192                 global env
2193
2194                 set pwd [pwd]
2195
2196                 if {!$is_submodule} {
2197                         if {![is_bare]} {
2198                                 cd $_gitworktree
2199                         }
2200                 } else {
2201                         cd $current_diff_path
2202                         if {$revs eq {--}} {
2203                                 set s $file_states($current_diff_path)
2204                                 set old_sha1 {}
2205                                 set new_sha1 {}
2206                                 switch -glob -- [lindex $s 0] {
2207                                 M_ { set old_sha1 [lindex [lindex $s 2] 1] }
2208                                 _M { set old_sha1 [lindex [lindex $s 3] 1] }
2209                                 MM {
2210                                         if {$current_diff_side eq $ui_index} {
2211                                                 set old_sha1 [lindex [lindex $s 2] 1]
2212                                                 set new_sha1 [lindex [lindex $s 3] 1]
2213                                         } else {
2214                                                 set old_sha1 [lindex [lindex $s 3] 1]
2215                                         }
2216                                 }
2217                                 }
2218                                 set revs $old_sha1...$new_sha1
2219                         }
2220                         # GIT_DIR and GIT_WORK_TREE for the submodule are not the ones
2221                         # we've been using for the main repository, so unset them.
2222                         # TODO we could make life easier (start up faster?) for gitk
2223                         # by setting these to the appropriate values to allow gitk
2224                         # to skip the heuristics to find their proper value
2225                         unset env(GIT_DIR)
2226                         unset env(GIT_WORK_TREE)
2227                 }
2228                 eval exec $cmd $revs "--" "--" &
2229
2230                 set env(GIT_DIR) $_gitdir
2231                 set env(GIT_WORK_TREE) $_gitworktree
2232                 cd $pwd
2233
2234                 ui_status $::starting_gitk_msg
2235                 after 10000 {
2236                         ui_ready $starting_gitk_msg
2237                 }
2238         }
2239 }
2240
2241 proc do_git_gui {} {
2242         global current_diff_path
2243
2244         # -- Always start git gui through whatever we were loaded with.  This
2245         #    lets us bypass using shell process on Windows systems.
2246         #
2247         set exe [list [_which git]]
2248         if {$exe eq {}} {
2249                 error_popup [mc "Couldn't find git gui in PATH"]
2250         } else {
2251                 global env
2252                 global _gitdir _gitworktree
2253
2254                 # see note in do_gitk about unsetting these vars when
2255                 # running tools in a submodule
2256                 unset env(GIT_DIR)
2257                 unset env(GIT_WORK_TREE)
2258
2259                 set pwd [pwd]
2260                 cd $current_diff_path
2261
2262                 eval exec $exe gui &
2263
2264                 set env(GIT_DIR) $_gitdir
2265                 set env(GIT_WORK_TREE) $_gitworktree
2266                 cd $pwd
2267
2268                 ui_status $::starting_gitk_msg
2269                 after 10000 {
2270                         ui_ready $starting_gitk_msg
2271                 }
2272         }
2273 }
2274
2275 proc do_explore {} {
2276         global _gitworktree
2277         set explorer {}
2278         if {[is_Cygwin] || [is_Windows]} {
2279                 set explorer "explorer.exe"
2280         } elseif {[is_MacOSX]} {
2281                 set explorer "open"
2282         } else {
2283                 # freedesktop.org-conforming system is our best shot
2284                 set explorer "xdg-open"
2285         }
2286         eval exec $explorer [list [file nativename $_gitworktree]] &
2287 }
2288
2289 set is_quitting 0
2290 set ret_code    1
2291
2292 proc terminate_me {win} {
2293         global ret_code
2294         if {$win ne {.}} return
2295         exit $ret_code
2296 }
2297
2298 proc do_quit {{rc {1}}} {
2299         global ui_comm is_quitting repo_config commit_type
2300         global GITGUI_BCK_exists GITGUI_BCK_i
2301         global ui_comm_spell
2302         global ret_code use_ttk
2303
2304         if {$is_quitting} return
2305         set is_quitting 1
2306
2307         if {[winfo exists $ui_comm]} {
2308                 # -- Stash our current commit buffer.
2309                 #
2310                 set save [gitdir GITGUI_MSG]
2311                 if {$GITGUI_BCK_exists && ![$ui_comm edit modified]} {
2312                         file rename -force [gitdir GITGUI_BCK] $save
2313                         set GITGUI_BCK_exists 0
2314                 } else {
2315                         set msg [string trim [$ui_comm get 0.0 end]]
2316                         regsub -all -line {[ \r\t]+$} $msg {} msg
2317                         if {(![string match amend* $commit_type]
2318                                 || [$ui_comm edit modified])
2319                                 && $msg ne {}} {
2320                                 catch {
2321                                         set fd [open $save w]
2322                                         fconfigure $fd -encoding utf-8
2323                                         puts -nonewline $fd $msg
2324                                         close $fd
2325                                 }
2326                         } else {
2327                                 catch {file delete $save}
2328                         }
2329                 }
2330
2331                 # -- Cancel our spellchecker if its running.
2332                 #
2333                 if {[info exists ui_comm_spell]} {
2334                         $ui_comm_spell stop
2335                 }
2336
2337                 # -- Remove our editor backup, its not needed.
2338                 #
2339                 after cancel $GITGUI_BCK_i
2340                 if {$GITGUI_BCK_exists} {
2341                         catch {file delete [gitdir GITGUI_BCK]}
2342                 }
2343
2344                 # -- Stash our current window geometry into this repository.
2345                 #
2346                 set cfg_wmstate [wm state .]
2347                 if {[catch {set rc_wmstate $repo_config(gui.wmstate)}]} {
2348                         set rc_wmstate {}
2349                 }
2350                 if {$cfg_wmstate ne $rc_wmstate} {
2351                         catch {git config gui.wmstate $cfg_wmstate}
2352                 }
2353                 if {$cfg_wmstate eq {zoomed}} {
2354                         # on Windows wm geometry will lie about window
2355                         # position (but not size) when window is zoomed
2356                         # restore the window before querying wm geometry
2357                         wm state . normal
2358                 }
2359                 set cfg_geometry [list]
2360                 lappend cfg_geometry [wm geometry .]
2361                 if {$use_ttk} {
2362                         lappend cfg_geometry [.vpane sashpos 0]
2363                         lappend cfg_geometry [.vpane.files sashpos 0]
2364                 } else {
2365                         lappend cfg_geometry [lindex [.vpane sash coord 0] 0]
2366                         lappend cfg_geometry [lindex [.vpane.files sash coord 0] 1]
2367                 }
2368                 if {[catch {set rc_geometry $repo_config(gui.geometry)}]} {
2369                         set rc_geometry {}
2370                 }
2371                 if {$cfg_geometry ne $rc_geometry} {
2372                         catch {git config gui.geometry $cfg_geometry}
2373                 }
2374         }
2375
2376         set ret_code $rc
2377
2378         # Briefly enable send again, working around Tk bug
2379         # http://sourceforge.net/tracker/?func=detail&atid=112997&aid=1821174&group_id=12997
2380         tk appname [appname]
2381
2382         destroy .
2383 }
2384
2385 proc do_rescan {} {
2386         rescan ui_ready
2387 }
2388
2389 proc ui_do_rescan {} {
2390         rescan {force_first_diff ui_ready}
2391 }
2392
2393 proc do_commit {} {
2394         commit_tree
2395 }
2396
2397 proc next_diff {{after {}}} {
2398         global next_diff_p next_diff_w next_diff_i
2399         show_diff $next_diff_p $next_diff_w {} {} $after
2400 }
2401
2402 proc find_anchor_pos {lst name} {
2403         set lid [lsearch -sorted -exact $lst $name]
2404
2405         if {$lid == -1} {
2406                 set lid 0
2407                 foreach lname $lst {
2408                         if {$lname >= $name} break
2409                         incr lid
2410                 }
2411         }
2412
2413         return $lid
2414 }
2415
2416 proc find_file_from {flist idx delta path mmask} {
2417         global file_states
2418
2419         set len [llength $flist]
2420         while {$idx >= 0 && $idx < $len} {
2421                 set name [lindex $flist $idx]
2422
2423                 if {$name ne $path && [info exists file_states($name)]} {
2424                         set state [lindex $file_states($name) 0]
2425
2426                         if {$mmask eq {} || [regexp $mmask $state]} {
2427                                 return $idx
2428                         }
2429                 }
2430
2431                 incr idx $delta
2432         }
2433
2434         return {}
2435 }
2436
2437 proc find_next_diff {w path {lno {}} {mmask {}}} {
2438         global next_diff_p next_diff_w next_diff_i
2439         global file_lists ui_index ui_workdir
2440
2441         set flist $file_lists($w)
2442         if {$lno eq {}} {
2443                 set lno [find_anchor_pos $flist $path]
2444         } else {
2445                 incr lno -1
2446         }
2447
2448         if {$mmask ne {} && ![regexp {(^\^)|(\$$)} $mmask]} {
2449                 if {$w eq $ui_index} {
2450                         set mmask "^$mmask"
2451                 } else {
2452                         set mmask "$mmask\$"
2453                 }
2454         }
2455
2456         set idx [find_file_from $flist $lno 1 $path $mmask]
2457         if {$idx eq {}} {
2458                 incr lno -1
2459                 set idx [find_file_from $flist $lno -1 $path $mmask]
2460         }
2461
2462         if {$idx ne {}} {
2463                 set next_diff_w $w
2464                 set next_diff_p [lindex $flist $idx]
2465                 set next_diff_i [expr {$idx+1}]
2466                 return 1
2467         } else {
2468                 return 0
2469         }
2470 }
2471
2472 proc next_diff_after_action {w path {lno {}} {mmask {}}} {
2473         global current_diff_path
2474
2475         if {$path ne $current_diff_path} {
2476                 return {}
2477         } elseif {[find_next_diff $w $path $lno $mmask]} {
2478                 return {next_diff;}
2479         } else {
2480                 return {reshow_diff;}
2481         }
2482 }
2483
2484 proc select_first_diff {after} {
2485         global ui_workdir
2486
2487         if {[find_next_diff $ui_workdir {} 1 {^_?U}] ||
2488             [find_next_diff $ui_workdir {} 1 {[^O]$}]} {
2489                 next_diff $after
2490         } else {
2491                 uplevel #0 $after
2492         }
2493 }
2494
2495 proc force_first_diff {after} {
2496         global ui_workdir current_diff_path file_states
2497
2498         if {[info exists file_states($current_diff_path)]} {
2499                 set state [lindex $file_states($current_diff_path) 0]
2500         } else {
2501                 set state {OO}
2502         }
2503
2504         set reselect 0
2505         if {[string first {U} $state] >= 0} {
2506                 # Already a conflict, do nothing
2507         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {^_?U}]} {
2508                 set reselect 1
2509         } elseif {[string index $state 1] ne {O}} {
2510                 # Already a diff & no conflicts, do nothing
2511         } elseif {[find_next_diff $ui_workdir $current_diff_path {} {[^O]$}]} {
2512                 set reselect 1
2513         }
2514
2515         if {$reselect} {
2516                 next_diff $after
2517         } else {
2518                 uplevel #0 $after
2519         }
2520 }
2521
2522 proc popup_files_ctxm {m w x y X Y} {
2523         global file_lists popup_path
2524
2525         set ::cursorX $x
2526         set ::cursorY $y
2527
2528         set pos [split [$w index @$x,$y] .]
2529         set lno [lindex $pos 0]
2530         set col [lindex $pos 1]
2531         set popup_path [lindex $file_lists($w) [expr {$lno - 1}]]
2532         if {$popup_path eq {}} {
2533                 return
2534         }
2535         tk_popup $m $X $Y
2536 }
2537
2538 proc toggle_or_diff {w x y} {
2539         global file_states file_lists current_diff_path ui_index ui_workdir
2540         global last_clicked selected_paths
2541
2542         set pos [split [$w index @$x,$y] .]
2543         set lno [lindex $pos 0]
2544         set col [lindex $pos 1]
2545         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2546         if {$path eq {}} {
2547                 set last_clicked {}
2548                 return
2549         }
2550
2551         set last_clicked [list $w $lno]
2552         array unset selected_paths
2553         $ui_index tag remove in_sel 0.0 end
2554         $ui_workdir tag remove in_sel 0.0 end
2555
2556         # Determine the state of the file
2557         if {[info exists file_states($path)]} {
2558                 set state [lindex $file_states($path) 0]
2559         } else {
2560                 set state {__}
2561         }
2562
2563         # Restage the file, or simply show the diff
2564         if {$col == 0 && $y > 1} {
2565                 # Conflicts need special handling
2566                 if {[string first {U} $state] >= 0} {
2567                         # $w must always be $ui_workdir, but...
2568                         if {$w ne $ui_workdir} { set lno {} }
2569                         merge_stage_workdir $path $lno
2570                         return
2571                 }
2572
2573                 if {[string index $state 1] eq {O}} {
2574                         set mmask {}
2575                 } else {
2576                         set mmask {[^O]}
2577                 }
2578
2579                 set after [next_diff_after_action $w $path $lno $mmask]
2580
2581                 if {$w eq $ui_index} {
2582                         update_indexinfo \
2583                                 "Unstaging [short_path $path] from commit" \
2584                                 [list $path] \
2585                                 [concat $after [list ui_ready]]
2586                 } elseif {$w eq $ui_workdir} {
2587                         update_index \
2588                                 "Adding [short_path $path]" \
2589                                 [list $path] \
2590                                 [concat $after [list ui_ready]]
2591                 }
2592         } else {
2593                 show_diff $path $w $lno
2594         }
2595 }
2596
2597 proc add_one_to_selection {w x y} {
2598         global file_lists last_clicked selected_paths
2599
2600         set lno [lindex [split [$w index @$x,$y] .] 0]
2601         set path [lindex $file_lists($w) [expr {$lno - 1}]]
2602         if {$path eq {}} {
2603                 set last_clicked {}
2604                 return
2605         }
2606
2607         if {$last_clicked ne {}
2608                 && [lindex $last_clicked 0] ne $w} {
2609                 array unset selected_paths
2610                 [lindex $last_clicked 0] tag remove in_sel 0.0 end
2611         }
2612
2613         set last_clicked [list $w $lno]
2614         if {[catch {set in_sel $selected_paths($path)}]} {
2615                 set in_sel 0
2616         }
2617         if {$in_sel} {
2618                 unset selected_paths($path)
2619                 $w tag remove in_sel $lno.0 [expr {$lno + 1}].0
2620         } else {
2621                 set selected_paths($path) 1
2622                 $w tag add in_sel $lno.0 [expr {$lno + 1}].0
2623         }
2624 }
2625
2626 proc add_range_to_selection {w x y} {
2627         global file_lists last_clicked selected_paths
2628
2629         if {[lindex $last_clicked 0] ne $w} {
2630                 toggle_or_diff $w $x $y
2631                 return
2632         }
2633
2634         set lno [lindex [split [$w index @$x,$y] .] 0]
2635         set lc [lindex $last_clicked 1]
2636         if {$lc < $lno} {
2637                 set begin $lc
2638                 set end $lno
2639         } else {
2640                 set begin $lno
2641                 set end $lc
2642         }
2643
2644         foreach path [lrange $file_lists($w) \
2645                 [expr {$begin - 1}] \
2646                 [expr {$end - 1}]] {
2647                 set selected_paths($path) 1
2648         }
2649         $w tag add in_sel $begin.0 [expr {$end + 1}].0
2650 }
2651
2652 proc show_more_context {} {
2653         global repo_config
2654         if {$repo_config(gui.diffcontext) < 99} {
2655                 incr repo_config(gui.diffcontext)
2656                 reshow_diff
2657         }
2658 }
2659
2660 proc show_less_context {} {
2661         global repo_config
2662         if {$repo_config(gui.diffcontext) > 1} {
2663                 incr repo_config(gui.diffcontext) -1
2664                 reshow_diff
2665         }
2666 }
2667
2668 ######################################################################
2669 ##
2670 ## ui construction
2671
2672 set ui_comm {}
2673
2674 # -- Menu Bar
2675 #
2676 menu .mbar -tearoff 0
2677 if {[is_MacOSX]} {
2678         # -- Apple Menu (Mac OS X only)
2679         #
2680         .mbar add cascade -label Apple -menu .mbar.apple
2681         menu .mbar.apple
2682 }
2683 .mbar add cascade -label [mc Repository] -menu .mbar.repository
2684 .mbar add cascade -label [mc Edit] -menu .mbar.edit
2685 if {[is_enabled branch]} {
2686         .mbar add cascade -label [mc Branch] -menu .mbar.branch
2687 }
2688 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2689         .mbar add cascade -label [mc Commit@@noun] -menu .mbar.commit
2690 }
2691 if {[is_enabled transport]} {
2692         .mbar add cascade -label [mc Merge] -menu .mbar.merge
2693         .mbar add cascade -label [mc Remote] -menu .mbar.remote
2694 }
2695 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2696         .mbar add cascade -label [mc Tools] -menu .mbar.tools
2697 }
2698
2699 # -- Repository Menu
2700 #
2701 menu .mbar.repository
2702
2703 if {![is_bare]} {
2704         .mbar.repository add command \
2705                 -label [mc "Explore Working Copy"] \
2706                 -command {do_explore}
2707 }
2708
2709 if {[is_Windows]} {
2710         .mbar.repository add command \
2711                 -label [mc "Git Bash"] \
2712                 -command {eval exec [auto_execok start] \
2713                                           [list "Git Bash" bash --login -l &]}
2714 }
2715
2716 if {[is_Windows] || ![is_bare]} {
2717         .mbar.repository add separator
2718 }
2719
2720 .mbar.repository add command \
2721         -label [mc "Browse Current Branch's Files"] \
2722         -command {browser::new $current_branch}
2723 set ui_browse_current [.mbar.repository index last]
2724 .mbar.repository add command \
2725         -label [mc "Browse Branch Files..."] \
2726         -command browser_open::dialog
2727 .mbar.repository add separator
2728
2729 .mbar.repository add command \
2730         -label [mc "Visualize Current Branch's History"] \
2731         -command {do_gitk $current_branch}
2732 set ui_visualize_current [.mbar.repository index last]
2733 .mbar.repository add command \
2734         -label [mc "Visualize All Branch History"] \
2735         -command {do_gitk --all}
2736 .mbar.repository add separator
2737
2738 proc current_branch_write {args} {
2739         global current_branch
2740         .mbar.repository entryconf $::ui_browse_current \
2741                 -label [mc "Browse %s's Files" $current_branch]
2742         .mbar.repository entryconf $::ui_visualize_current \
2743                 -label [mc "Visualize %s's History" $current_branch]
2744 }
2745 trace add variable current_branch write current_branch_write
2746
2747 if {[is_enabled multicommit]} {
2748         .mbar.repository add command -label [mc "Database Statistics"] \
2749                 -command do_stats
2750
2751         .mbar.repository add command -label [mc "Compress Database"] \
2752                 -command do_gc
2753
2754         .mbar.repository add command -label [mc "Verify Database"] \
2755                 -command do_fsck_objects
2756
2757         .mbar.repository add separator
2758
2759         if {[is_Cygwin]} {
2760                 .mbar.repository add command \
2761                         -label [mc "Create Desktop Icon"] \
2762                         -command do_cygwin_shortcut
2763         } elseif {[is_Windows]} {
2764                 .mbar.repository add command \
2765                         -label [mc "Create Desktop Icon"] \
2766                         -command do_windows_shortcut
2767         } elseif {[is_MacOSX]} {
2768                 .mbar.repository add command \
2769                         -label [mc "Create Desktop Icon"] \
2770                         -command do_macosx_app
2771         }
2772 }
2773
2774 if {[is_MacOSX]} {
2775         proc ::tk::mac::Quit {args} { do_quit }
2776 } else {
2777         .mbar.repository add command -label [mc Quit] \
2778                 -command do_quit \
2779                 -accelerator $M1T-Q
2780 }
2781
2782 # -- Edit Menu
2783 #
2784 menu .mbar.edit
2785 .mbar.edit add command -label [mc Undo] \
2786         -command {catch {[focus] edit undo}} \
2787         -accelerator $M1T-Z
2788 .mbar.edit add command -label [mc Redo] \
2789         -command {catch {[focus] edit redo}} \
2790         -accelerator $M1T-Y
2791 .mbar.edit add separator
2792 .mbar.edit add command -label [mc Cut] \
2793         -command {catch {tk_textCut [focus]}} \
2794         -accelerator $M1T-X
2795 .mbar.edit add command -label [mc Copy] \
2796         -command {catch {tk_textCopy [focus]}} \
2797         -accelerator $M1T-C
2798 .mbar.edit add command -label [mc Paste] \
2799         -command {catch {tk_textPaste [focus]; [focus] see insert}} \
2800         -accelerator $M1T-V
2801 .mbar.edit add command -label [mc Delete] \
2802         -command {catch {[focus] delete sel.first sel.last}} \
2803         -accelerator Del
2804 .mbar.edit add separator
2805 .mbar.edit add command -label [mc "Select All"] \
2806         -command {catch {[focus] tag add sel 0.0 end}} \
2807         -accelerator $M1T-A
2808
2809 # -- Branch Menu
2810 #
2811 if {[is_enabled branch]} {
2812         menu .mbar.branch
2813
2814         .mbar.branch add command -label [mc "Create..."] \
2815                 -command branch_create::dialog \
2816                 -accelerator $M1T-N
2817         lappend disable_on_lock [list .mbar.branch entryconf \
2818                 [.mbar.branch index last] -state]
2819
2820         .mbar.branch add command -label [mc "Checkout..."] \
2821                 -command branch_checkout::dialog \
2822                 -accelerator $M1T-O
2823         lappend disable_on_lock [list .mbar.branch entryconf \
2824                 [.mbar.branch index last] -state]
2825
2826         .mbar.branch add command -label [mc "Rename..."] \
2827                 -command branch_rename::dialog
2828         lappend disable_on_lock [list .mbar.branch entryconf \
2829                 [.mbar.branch index last] -state]
2830
2831         .mbar.branch add command -label [mc "Delete..."] \
2832                 -command branch_delete::dialog
2833         lappend disable_on_lock [list .mbar.branch entryconf \
2834                 [.mbar.branch index last] -state]
2835
2836         .mbar.branch add command -label [mc "Reset..."] \
2837                 -command merge::reset_hard
2838         lappend disable_on_lock [list .mbar.branch entryconf \
2839                 [.mbar.branch index last] -state]
2840 }
2841
2842 # -- Commit Menu
2843 #
2844 proc commit_btn_caption {} {
2845         if {[is_enabled nocommit]} {
2846                 return [mc "Done"]
2847         } else {
2848                 return [mc Commit@@verb]
2849         }
2850 }
2851
2852 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2853         menu .mbar.commit
2854
2855         if {![is_enabled nocommit]} {
2856                 .mbar.commit add radiobutton \
2857                         -label [mc "New Commit"] \
2858                         -command do_select_commit_type \
2859                         -variable selected_commit_type \
2860                         -value new
2861                 lappend disable_on_lock \
2862                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2863
2864                 .mbar.commit add radiobutton \
2865                         -label [mc "Amend Last Commit"] \
2866                         -command do_select_commit_type \
2867                         -variable selected_commit_type \
2868                         -value amend
2869                 lappend disable_on_lock \
2870                         [list .mbar.commit entryconf [.mbar.commit index last] -state]
2871
2872                 .mbar.commit add separator
2873         }
2874
2875         .mbar.commit add command -label [mc Rescan] \
2876                 -command ui_do_rescan \
2877                 -accelerator $M1T-R
2878         lappend disable_on_lock \
2879                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2880
2881         .mbar.commit add command -label [mc "Stage To Commit"] \
2882                 -command do_add_selection \
2883                 -accelerator $M1T-T
2884         lappend disable_on_lock \
2885                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2886
2887         .mbar.commit add command -label [mc "Stage Changed Files To Commit"] \
2888                 -command do_add_all \
2889                 -accelerator $M1T-I
2890         lappend disable_on_lock \
2891                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2892
2893         .mbar.commit add command -label [mc "Unstage From Commit"] \
2894                 -command do_unstage_selection \
2895                 -accelerator $M1T-U
2896         lappend disable_on_lock \
2897                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2898
2899         .mbar.commit add command -label [mc "Revert Changes"] \
2900                 -command do_revert_selection \
2901                 -accelerator $M1T-J
2902         lappend disable_on_lock \
2903                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2904
2905         .mbar.commit add separator
2906
2907         .mbar.commit add command -label [mc "Show Less Context"] \
2908                 -command show_less_context \
2909                 -accelerator $M1T-\-
2910
2911         .mbar.commit add command -label [mc "Show More Context"] \
2912                 -command show_more_context \
2913                 -accelerator $M1T-=
2914
2915         .mbar.commit add separator
2916
2917         if {![is_enabled nocommitmsg]} {
2918                 .mbar.commit add command -label [mc "Sign Off"] \
2919                         -command do_signoff \
2920                         -accelerator $M1T-S
2921         }
2922
2923         .mbar.commit add command -label [commit_btn_caption] \
2924                 -command do_commit \
2925                 -accelerator $M1T-Return
2926         lappend disable_on_lock \
2927                 [list .mbar.commit entryconf [.mbar.commit index last] -state]
2928 }
2929
2930 # -- Merge Menu
2931 #
2932 if {[is_enabled branch]} {
2933         menu .mbar.merge
2934         .mbar.merge add command -label [mc "Local Merge..."] \
2935                 -command merge::dialog \
2936                 -accelerator $M1T-M
2937         lappend disable_on_lock \
2938                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2939         .mbar.merge add command -label [mc "Abort Merge..."] \
2940                 -command merge::reset_hard
2941         lappend disable_on_lock \
2942                 [list .mbar.merge entryconf [.mbar.merge index last] -state]
2943 }
2944
2945 # -- Transport Menu
2946 #
2947 if {[is_enabled transport]} {
2948         menu .mbar.remote
2949
2950         .mbar.remote add command \
2951                 -label [mc "Add..."] \
2952                 -command remote_add::dialog \
2953                 -accelerator $M1T-A
2954         .mbar.remote add command \
2955                 -label [mc "Push..."] \
2956                 -command do_push_anywhere \
2957                 -accelerator $M1T-P
2958         .mbar.remote add command \
2959                 -label [mc "Delete Branch..."] \
2960                 -command remote_branch_delete::dialog
2961 }
2962
2963 if {[is_MacOSX]} {
2964         proc ::tk::mac::ShowPreferences {} {do_options}
2965 } else {
2966         # -- Edit Menu
2967         #
2968         .mbar.edit add separator
2969         .mbar.edit add command -label [mc "Options..."] \
2970                 -command do_options
2971 }
2972
2973 # -- Tools Menu
2974 #
2975 if {[is_enabled multicommit] || [is_enabled singlecommit]} {
2976         set tools_menubar .mbar.tools
2977         menu $tools_menubar
2978         $tools_menubar add separator
2979         $tools_menubar add command -label [mc "Add..."] -command tools_add::dialog
2980         $tools_menubar add command -label [mc "Remove..."] -command tools_remove::dialog
2981         if {[array names repo_config guitool.*.cmd] ne {}} {
2982                 tools_populate_all 3
2983         }
2984 }
2985
2986 # -- Help Menu
2987 #
2988 .mbar add cascade -label [mc Help] -menu .mbar.help
2989 menu .mbar.help
2990
2991 if {[is_MacOSX]} {
2992         .mbar.apple add command -label [mc "About %s" [appname]] \
2993                 -command do_about
2994         .mbar.apple add separator
2995 } else {
2996         .mbar.help add command -label [mc "About %s" [appname]] \
2997                 -command do_about
2998 }
2999 . configure -menu .mbar
3000
3001 set doc_path [githtmldir]
3002 if {$doc_path ne {}} {
3003         set doc_path [file join $doc_path index.html]
3004
3005         if {[is_Cygwin]} {
3006                 set doc_path [exec cygpath --mixed $doc_path]
3007         }
3008 }
3009
3010 if {[file isfile $doc_path]} {
3011         set doc_url "file:$doc_path"
3012 } else {
3013         set doc_url {http://www.kernel.org/pub/software/scm/git/docs/}
3014 }
3015
3016 proc start_browser {url} {
3017         git "web--browse" $url
3018 }
3019
3020 .mbar.help add command -label [mc "Online Documentation"] \
3021         -command [list start_browser $doc_url]
3022
3023 .mbar.help add command -label [mc "Show SSH Key"] \
3024         -command do_ssh_key
3025
3026 unset doc_path doc_url
3027
3028 # -- Standard bindings
3029 #
3030 wm protocol . WM_DELETE_WINDOW do_quit
3031 bind all <$M1B-Key-q> do_quit
3032 bind all <$M1B-Key-Q> do_quit
3033 bind all <$M1B-Key-w> {destroy [winfo toplevel %W]}
3034 bind all <$M1B-Key-W> {destroy [winfo toplevel %W]}
3035
3036 set subcommand_args {}
3037 proc usage {} {
3038         set s "usage: $::argv0 $::subcommand $::subcommand_args"
3039         if {[tk windowingsystem] eq "win32"} {
3040                 wm withdraw .
3041                 tk_messageBox -icon info -message $s \
3042                         -title [mc "Usage"]
3043         } else {
3044                 puts stderr $s
3045         }
3046         exit 1
3047 }
3048
3049 proc normalize_relpath {path} {
3050         set elements {}
3051         foreach item [file split $path] {
3052                 if {$item eq {.}} continue
3053                 if {$item eq {..} && [llength $elements] > 0
3054                     && [lindex $elements end] ne {..}} {
3055                         set elements [lrange $elements 0 end-1]
3056                         continue
3057                 }
3058                 lappend elements $item
3059         }
3060         return [eval file join $elements]
3061 }
3062
3063 # -- Not a normal commit type invocation?  Do that instead!
3064 #
3065 switch -- $subcommand {
3066 browser -
3067 blame {
3068         if {$subcommand eq "blame"} {
3069                 set subcommand_args {[--line=<num>] rev? path}
3070         } else {
3071                 set subcommand_args {rev? path}
3072         }
3073         if {$argv eq {}} usage
3074         set head {}
3075         set path {}
3076         set jump_spec {}
3077         set is_path 0
3078         foreach a $argv {
3079                 set p [file join $_prefix $a]
3080
3081                 if {$is_path || [file exists $p]} {
3082                         if {$path ne {}} usage
3083                         set path [normalize_relpath $p]
3084                         break
3085                 } elseif {$a eq {--}} {
3086                         if {$path ne {}} {
3087                                 if {$head ne {}} usage
3088                                 set head $path
3089                                 set path {}
3090                         }
3091                         set is_path 1
3092                 } elseif {[regexp {^--line=(\d+)$} $a a lnum]} {
3093                         if {$jump_spec ne {} || $head ne {}} usage
3094                         set jump_spec [list $lnum]
3095                 } elseif {$head eq {}} {
3096                         if {$head ne {}} usage
3097                         set head $a
3098                         set is_path 1
3099                 } else {
3100                         usage
3101                 }
3102         }
3103         unset is_path
3104
3105         if {$head ne {} && $path eq {}} {
3106                 if {[string index $head 0] eq {/}} {
3107                         set path [normalize_relpath $head]
3108                         set head {}
3109                 } else {
3110                         set path [normalize_relpath $_prefix$head]
3111                         set head {}
3112                 }
3113         }
3114
3115         if {$head eq {}} {
3116                 load_current_branch
3117         } else {
3118                 if {[regexp {^[0-9a-f]{1,39}$} $head]} {
3119                         if {[catch {
3120                                         set head [git rev-parse --verify $head]
3121                                 } err]} {
3122                                 if {[tk windowingsystem] eq "win32"} {
3123                                         tk_messageBox -icon error -title [mc Error] -message $err
3124                                 } else {
3125                                         puts stderr $err
3126                                 }
3127                                 exit 1
3128                         }
3129                 }
3130                 set current_branch $head
3131         }
3132
3133         wm deiconify .
3134         switch -- $subcommand {
3135         browser {
3136                 if {$jump_spec ne {}} usage
3137                 if {$head eq {}} {
3138                         if {$path ne {} && [file isdirectory $path]} {
3139                                 set head $current_branch
3140                         } else {
3141                                 set head $path
3142                                 set path {}
3143                         }
3144                 }
3145                 browser::new $head $path
3146         }
3147         blame   {
3148                 if {$head eq {} && ![file exists $path]} {
3149                         catch {wm withdraw .}
3150                         tk_messageBox \
3151                                 -icon error \
3152                                 -type ok \
3153                                 -title [mc "git-gui: fatal error"] \
3154                                 -message [mc "fatal: cannot stat path %s: No such file or directory" $path]
3155                         exit 1
3156                 }
3157                 blame::new $head $path $jump_spec
3158         }
3159         }
3160         return
3161 }
3162 citool -
3163 gui {
3164         if {[llength $argv] != 0} {
3165                 usage
3166         }
3167         # fall through to setup UI for commits
3168 }
3169 default {
3170         set err "usage: $argv0 \[{blame|browser|citool}\]"
3171         if {[tk windowingsystem] eq "win32"} {
3172                 wm withdraw .
3173                 tk_messageBox -icon error -message $err \
3174                         -title [mc "Usage"]
3175         } else {
3176                 puts stderr $err
3177         }
3178         exit 1
3179 }
3180 }
3181
3182 # -- Branch Control
3183 #
3184 ${NS}::frame .branch
3185 if {!$use_ttk} {.branch configure -borderwidth 1 -relief sunken}
3186 ${NS}::label .branch.l1 \
3187         -text [mc "Current Branch:"] \
3188         -anchor w \
3189         -justify left
3190 ${NS}::label .branch.cb \
3191         -textvariable current_branch \
3192         -anchor w \
3193         -justify left
3194 pack .branch.l1 -side left
3195 pack .branch.cb -side left -fill x
3196 pack .branch -side top -fill x
3197
3198 # -- Main Window Layout
3199 #
3200 ${NS}::panedwindow .vpane -orient horizontal
3201 ${NS}::panedwindow .vpane.files -orient vertical
3202 if {$use_ttk} {
3203         .vpane add .vpane.files -weight 0
3204 } else {
3205         .vpane add .vpane.files -sticky nsew -height 100 -width 200
3206 }
3207 pack .vpane -anchor n -side top -fill both -expand 1
3208
3209 # -- Index File List
3210 #
3211 ${NS}::frame .vpane.files.index -height 100 -width 200
3212 tlabel .vpane.files.index.title \
3213         -text [mc "Staged Changes (Will Commit)"] \
3214         -background lightgreen -foreground black
3215 text $ui_index -background white -foreground black \
3216         -borderwidth 0 \
3217         -width 20 -height 10 \
3218         -wrap none \
3219         -cursor $cursor_ptr \
3220         -xscrollcommand {.vpane.files.index.sx set} \
3221         -yscrollcommand {.vpane.files.index.sy set} \
3222         -state disabled
3223 ${NS}::scrollbar .vpane.files.index.sx -orient h -command [list $ui_index xview]
3224 ${NS}::scrollbar .vpane.files.index.sy -orient v -command [list $ui_index yview]
3225 pack .vpane.files.index.title -side top -fill x
3226 pack .vpane.files.index.sx -side bottom -fill x
3227 pack .vpane.files.index.sy -side right -fill y
3228 pack $ui_index -side left -fill both -expand 1
3229
3230 # -- Working Directory File List
3231 #
3232 ${NS}::frame .vpane.files.workdir -height 100 -width 200
3233 tlabel .vpane.files.workdir.title -text [mc "Unstaged Changes"] \
3234         -background lightsalmon -foreground black
3235 text $ui_workdir -background white -foreground black \
3236         -borderwidth 0 \
3237         -width 20 -height 10 \
3238         -wrap none \
3239         -cursor $cursor_ptr \
3240         -xscrollcommand {.vpane.files.workdir.sx set} \
3241         -yscrollcommand {.vpane.files.workdir.sy set} \
3242         -state disabled
3243 ${NS}::scrollbar .vpane.files.workdir.sx -orient h -command [list $ui_workdir xview]
3244 ${NS}::scrollbar .vpane.files.workdir.sy -orient v -command [list $ui_workdir yview]
3245 pack .vpane.files.workdir.title -side top -fill x
3246 pack .vpane.files.workdir.sx -side bottom -fill x
3247 pack .vpane.files.workdir.sy -side right -fill y
3248 pack $ui_workdir -side left -fill both -expand 1
3249
3250 if {$use_ttk} {
3251         .vpane.files add .vpane.files.workdir -weight 1
3252         .vpane.files add .vpane.files.index -weight 1
3253 } else {
3254         .vpane.files add .vpane.files.workdir -sticky news
3255         .vpane.files add .vpane.files.index -sticky news
3256 }
3257
3258 foreach i [list $ui_index $ui_workdir] {
3259         rmsel_tag $i
3260         $i tag conf in_diff -background [$i tag cget in_sel -background]
3261         #$i tag conf in_diff -underline 1
3262         #$i tag conf in_sel -background {#c6e2ff} -font font_diffitalic
3263         $i tag conf in_sel -background  [$i cget -background] -underline 1
3264 }
3265 unset i
3266
3267 set files_ctxm .vpane.files.ctxm
3268 menu $files_ctxm -tearoff 0
3269 $files_ctxm add separator
3270 $files_ctxm add command -label [mc "Stage All Changed"] -command do_add_all
3271 $files_ctxm add command -label [mc "Stage Selected"] -command do_add_selection
3272 if {[array names repo_config guitool.*.cmd] ne {}} {
3273         files_tools_populate_all 3 popup_path
3274 }
3275
3276
3277 # -- Diff and Commit Area
3278 #
3279 if {$have_tk85} {
3280         ${NS}::panedwindow .vpane.lower -orient vertical
3281         ${NS}::frame .vpane.lower.commarea
3282         ${NS}::frame .vpane.lower.diff -relief sunken -borderwidth 1 -height 500
3283         .vpane.lower add .vpane.lower.diff
3284         .vpane.lower add .vpane.lower.commarea
3285         .vpane add .vpane.lower
3286         if {$use_ttk} {
3287                 .vpane.lower pane .vpane.lower.diff -weight 1
3288                 .vpane.lower pane .vpane.lower.commarea -weight 0
3289         } else {
3290                 .vpane.lower paneconfigure .vpane.lower.diff -stretch always
3291                 .vpane.lower paneconfigure .vpane.lower.commarea -stretch never
3292         }
3293 } else {
3294         frame .vpane.lower -height 300 -width 400
3295         frame .vpane.lower.commarea
3296         frame .vpane.lower.diff -relief sunken -borderwidth 1
3297         pack .vpane.lower.diff -fill both -expand 1
3298         pack .vpane.lower.commarea -side bottom -fill x
3299         .vpane add .vpane.lower
3300         .vpane paneconfigure .vpane.lower -sticky nsew
3301 }
3302
3303 # -- Commit Area Buttons
3304 #
3305 ${NS}::frame .vpane.lower.commarea.buttons
3306 ${NS}::label .vpane.lower.commarea.buttons.l -text {} \
3307         -anchor w \
3308         -justify left
3309 pack .vpane.lower.commarea.buttons.l -side top -fill x
3310 pack .vpane.lower.commarea.buttons -side left -fill y
3311
3312 ${NS}::button .vpane.lower.commarea.buttons.rescan -text [mc Rescan] \
3313         -command ui_do_rescan
3314 pack .vpane.lower.commarea.buttons.rescan -side top -fill x
3315 lappend disable_on_lock \
3316         {.vpane.lower.commarea.buttons.rescan conf -state}
3317
3318 ${NS}::button .vpane.lower.commarea.buttons.incall -text [mc "Stage Changed"] \
3319         -command do_add_all
3320 pack .vpane.lower.commarea.buttons.incall -side top -fill x
3321 lappend disable_on_lock \
3322         {.vpane.lower.commarea.buttons.incall conf -state}
3323
3324 if {![is_enabled nocommitmsg]} {
3325         ${NS}::button .vpane.lower.commarea.buttons.signoff -text [mc "Sign Off"] \
3326                 -command do_signoff
3327         pack .vpane.lower.commarea.buttons.signoff -side top -fill x
3328 }
3329
3330 ${NS}::button .vpane.lower.commarea.buttons.commit -text [commit_btn_caption] \
3331         -command do_commit
3332 pack .vpane.lower.commarea.buttons.commit -side top -fill x
3333 lappend disable_on_lock \
3334         {.vpane.lower.commarea.buttons.commit conf -state}
3335
3336 if {![is_enabled nocommit]} {
3337         ${NS}::button .vpane.lower.commarea.buttons.push -text [mc Push] \
3338                 -command do_push_anywhere
3339         pack .vpane.lower.commarea.buttons.push -side top -fill x
3340 }
3341
3342 # -- Commit Message Buffer
3343 #
3344 ${NS}::frame .vpane.lower.commarea.buffer
3345 ${NS}::frame .vpane.lower.commarea.buffer.header
3346 set ui_comm .vpane.lower.commarea.buffer.t
3347 set ui_coml .vpane.lower.commarea.buffer.header.l
3348
3349 if {![is_enabled nocommit]} {
3350         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.new \
3351                 -text [mc "New Commit"] \
3352                 -command do_select_commit_type \
3353                 -variable selected_commit_type \
3354                 -value new
3355         lappend disable_on_lock \
3356                 [list .vpane.lower.commarea.buffer.header.new conf -state]
3357         ${NS}::radiobutton .vpane.lower.commarea.buffer.header.amend \
3358                 -text [mc "Amend Last Commit"] \
3359                 -command do_select_commit_type \
3360                 -variable selected_commit_type \
3361                 -value amend
3362         lappend disable_on_lock \
3363                 [list .vpane.lower.commarea.buffer.header.amend conf -state]
3364 }
3365
3366 ${NS}::label $ui_coml \
3367         -anchor w \
3368         -justify left
3369 proc trace_commit_type {varname args} {
3370         global ui_coml commit_type
3371         switch -glob -- $commit_type {
3372         initial       {set txt [mc "Initial Commit Message:"]}
3373         amend         {set txt [mc "Amended Commit Message:"]}
3374         amend-initial {set txt [mc "Amended Initial Commit Message:"]}
3375         amend-merge   {set txt [mc "Amended Merge Commit Message:"]}
3376         merge         {set txt [mc "Merge Commit Message:"]}
3377         *             {set txt [mc "Commit Message:"]}
3378         }
3379         $ui_coml conf -text $txt
3380 }
3381 trace add variable commit_type write trace_commit_type
3382 pack $ui_coml -side left -fill x
3383
3384 if {![is_enabled nocommit]} {
3385         pack .vpane.lower.commarea.buffer.header.amend -side right
3386         pack .vpane.lower.commarea.buffer.header.new -side right
3387 }
3388
3389 text $ui_comm -background white -foreground black \
3390         -borderwidth 1 \
3391         -undo true \
3392         -maxundo 20 \
3393         -autoseparators true \
3394         -relief sunken \
3395         -width $repo_config(gui.commitmsgwidth) -height 9 -wrap none \
3396         -font font_diff \
3397         -yscrollcommand {.vpane.lower.commarea.buffer.sby set}
3398 ${NS}::scrollbar .vpane.lower.commarea.buffer.sby \
3399         -command [list $ui_comm yview]
3400 pack .vpane.lower.commarea.buffer.header -side top -fill x
3401 pack .vpane.lower.commarea.buffer.sby -side right -fill y
3402 pack $ui_comm -side left -fill y
3403 pack .vpane.lower.commarea.buffer -side left -fill y
3404
3405 # -- Commit Message Buffer Context Menu
3406 #
3407 set ui_comm_ctxm .vpane.lower.commarea.buffer.ctxm
3408 menu $ui_comm_ctxm -tearoff 0
3409 $ui_comm_ctxm add command \
3410         -label [mc Cut] \
3411         -command {tk_textCut $ui_comm}
3412 $ui_comm_ctxm add command \
3413         -label [mc Copy] \
3414         -command {tk_textCopy $ui_comm}
3415 $ui_comm_ctxm add command \
3416         -label [mc Paste] \
3417         -command {tk_textPaste $ui_comm}
3418 $ui_comm_ctxm add command \
3419         -label [mc Delete] \
3420         -command {catch {$ui_comm delete sel.first sel.last}}
3421 $ui_comm_ctxm add separator
3422 $ui_comm_ctxm add command \
3423         -label [mc "Select All"] \
3424         -command {focus $ui_comm;$ui_comm tag add sel 0.0 end}
3425 $ui_comm_ctxm add command \
3426         -label [mc "Copy All"] \
3427         -command {
3428                 $ui_comm tag add sel 0.0 end
3429                 tk_textCopy $ui_comm
3430                 $ui_comm tag remove sel 0.0 end
3431         }
3432 $ui_comm_ctxm add separator
3433 $ui_comm_ctxm add command \
3434         -label [mc "Sign Off"] \
3435         -command do_signoff
3436
3437 # -- Diff Header
3438 #
3439 proc trace_current_diff_path {varname args} {
3440         global current_diff_path diff_actions file_states
3441         if {$current_diff_path eq {}} {
3442                 set s {}
3443                 set f {}
3444                 set p {}
3445                 set o disabled
3446         } else {
3447                 set p $current_diff_path
3448                 set s [mapdesc [lindex $file_states($p) 0] $p]
3449                 set f [mc "File:"]
3450                 set p [escape_path $p]
3451                 set o normal
3452         }
3453
3454         .vpane.lower.diff.header.status configure -text $s
3455         .vpane.lower.diff.header.file configure -text $f
3456         .vpane.lower.diff.header.path configure -text $p
3457         foreach w $diff_actions {
3458                 uplevel #0 $w $o
3459         }
3460 }
3461 trace add variable current_diff_path write trace_current_diff_path
3462
3463 gold_frame .vpane.lower.diff.header
3464 tlabel .vpane.lower.diff.header.status \
3465         -background gold \
3466         -foreground black \
3467         -anchor w \
3468         -justify left
3469 tlabel .vpane.lower.diff.header.file \
3470         -background gold \
3471         -foreground black \
3472         -anchor w \
3473         -justify left
3474 tlabel .vpane.lower.diff.header.path \
3475         -background gold \
3476         -foreground black \
3477         -anchor w \
3478         -justify left
3479 pack .vpane.lower.diff.header.status -side left
3480 pack .vpane.lower.diff.header.path -side right -fill x
3481 pack .vpane.lower.diff.header.file -side right
3482 set hctxm .vpane.lower.diff.header.ctxm
3483 menu $hctxm -tearoff 0
3484 $hctxm add command \
3485         -label [mc Copy] \
3486         -command {
3487                 clipboard clear
3488                 clipboard append \
3489                         -format STRING \
3490                         -type STRING \
3491                         -- $current_diff_path
3492         }
3493 lappend diff_actions [list $hctxm entryconf [$hctxm index last] -state]
3494 bind_button3 .vpane.lower.diff.header.path "tk_popup $hctxm %X %Y"
3495
3496 # -- Diff Body
3497 #
3498 ${NS}::frame .vpane.lower.diff.body
3499 set ui_diff .vpane.lower.diff.body.t
3500 text $ui_diff -background white -foreground black \
3501         -borderwidth 0 \
3502         -width 80 -height 5 -wrap none \
3503         -font font_diff \
3504         -xscrollcommand {.vpane.lower.diff.body.sbx set} \
3505         -yscrollcommand {.vpane.lower.diff.body.sby set} \
3506         -state disabled
3507 catch {$ui_diff configure -tabstyle wordprocessor}
3508 ${NS}::scrollbar .vpane.lower.diff.body.sbx -orient horizontal \
3509         -command [list $ui_diff xview]
3510 ${NS}::scrollbar .vpane.lower.diff.body.sby -orient vertical \
3511         -command [list $ui_diff yview]
3512 pack .vpane.lower.diff.body.sbx -side bottom -fill x
3513 pack .vpane.lower.diff.body.sby -side right -fill y
3514 pack $ui_diff -side left -fill both -expand 1
3515 pack .vpane.lower.diff.header -side top -fill x
3516 pack .vpane.lower.diff.body -side bottom -fill both -expand 1
3517
3518 foreach {n c} {0 black 1 red4 2 green4 3 yellow4 4 blue4 5 magenta4 6 cyan4 7 grey60} {
3519         $ui_diff tag configure clr4$n -background $c
3520         $ui_diff tag configure clri4$n -foreground $c
3521         $ui_diff tag configure clr3$n -foreground $c
3522         $ui_diff tag configure clri3$n -background $c
3523 }
3524 $ui_diff tag configure clr1 -font font_diffbold
3525 $ui_diff tag configure clr4 -underline 1
3526
3527 $ui_diff tag conf d_info -foreground blue -font font_diffbold
3528
3529 $ui_diff tag conf d_cr -elide true
3530 $ui_diff tag conf d_@ -font font_diffbold
3531 $ui_diff tag conf d_+ -foreground {#00a000}
3532 $ui_diff tag conf d_- -foreground red
3533
3534 $ui_diff tag conf d_++ -foreground {#00a000}
3535 $ui_diff tag conf d_-- -foreground red
3536 $ui_diff tag conf d_+s \
3537         -foreground {#00a000} \
3538         -background {#e2effa}
3539 $ui_diff tag conf d_-s \
3540         -foreground red \
3541         -background {#e2effa}
3542 $ui_diff tag conf d_s+ \
3543         -foreground {#00a000} \
3544         -background ivory1
3545 $ui_diff tag conf d_s- \
3546         -foreground red \
3547         -background ivory1
3548
3549 $ui_diff tag conf d< \
3550         -foreground orange \
3551         -font font_diffbold
3552 $ui_diff tag conf d| \
3553         -foreground orange \
3554         -font font_diffbold
3555 $ui_diff tag conf d= \
3556         -foreground orange \
3557         -font font_diffbold
3558 $ui_diff tag conf d> \
3559         -foreground orange \
3560         -font font_diffbold
3561
3562 $ui_diff tag raise sel
3563
3564 # -- Diff Body Context Menu
3565 #
3566
3567 proc create_common_diff_popup {ctxm} {
3568         $ctxm add command \
3569                 -label [mc Refresh] \
3570                 -command reshow_diff
3571         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3572         $ctxm add command \
3573                 -label [mc Copy] \
3574                 -command {tk_textCopy $ui_diff}
3575         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3576         $ctxm add command \
3577                 -label [mc "Select All"] \
3578                 -command {focus $ui_diff;$ui_diff tag add sel 0.0 end}
3579         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3580         $ctxm add command \
3581                 -label [mc "Copy All"] \
3582                 -command {
3583                         $ui_diff tag add sel 0.0 end
3584                         tk_textCopy $ui_diff
3585                         $ui_diff tag remove sel 0.0 end
3586                 }
3587         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3588         $ctxm add separator
3589         $ctxm add command \
3590                 -label [mc "Decrease Font Size"] \
3591                 -command {incr_font_size font_diff -1}
3592         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3593         $ctxm add command \
3594                 -label [mc "Increase Font Size"] \
3595                 -command {incr_font_size font_diff 1}
3596         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3597         $ctxm add separator
3598         set emenu $ctxm.enc
3599         menu $emenu
3600         build_encoding_menu $emenu [list force_diff_encoding]
3601         $ctxm add cascade \
3602                 -label [mc "Encoding"] \
3603                 -menu $emenu
3604         lappend diff_actions [list $ctxm entryconf [$ctxm index last] -state]
3605         $ctxm add separator
3606         $ctxm add command -label [mc "Options..."] \
3607                 -command do_options
3608 }
3609
3610 set ctxmw .vpane.lower.diff.body.ctxmw
3611 menu $ctxmw -tearoff 0
3612 $ctxmw add command \
3613         -label [mc "Apply/Reverse Hunk"] \
3614         -command {apply_hunk $cursorX $cursorY}
3615 set ui_diff_applyhunk [$ctxmw index last]
3616 lappend diff_actions [list $ctxmw entryconf $ui_diff_applyhunk -state]
3617 $ctxmw add command \
3618         -label [mc "Apply/Reverse Line"] \
3619         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3620 set ui_diff_applyline [$ctxmw index last]
3621 lappend diff_actions [list $ctxmw entryconf $ui_diff_applyline -state]
3622 $ctxmw add separator
3623 $ctxmw add command \
3624         -label [mc "Revert Hunk"] \
3625         -command {apply_hunk $cursorX $cursorY 1}
3626 lappend diff_actions [list $ctxmw entryconf $ui_diff_applyhunk -state]
3627 $ctxmw add command \
3628         -label [mc "Revert Line"] \
3629         -command {apply_range_or_line $cursorX $cursorY 1; do_rescan}
3630 set ui_diff_revertline [$ctxmw index last]
3631 lappend diff_actions [list $ctxmw entryconf $ui_diff_applyline -state]
3632 $ctxmw add separator
3633 $ctxmw add command \
3634         -label [mc "Show Less Context"] \
3635         -command show_less_context
3636 lappend diff_actions [list $ctxmw entryconf [$ctxmw index last] -state]
3637 $ctxmw add command \
3638         -label [mc "Show More Context"] \
3639         -command show_more_context
3640 lappend diff_actions [list $ctxmw entryconf [$ctxmw index last] -state]
3641 $ctxmw add separator
3642 create_common_diff_popup $ctxmw
3643
3644 set ctxmi .vpane.lower.diff.body.ctxmi
3645 menu $ctxmi -tearoff 0
3646 $ctxmi add command \
3647         -label [mc "Apply/Reverse Hunk"] \
3648         -command {apply_hunk $cursorX $cursorY}
3649 lappend diff_actions [list $ctxmi entryconf $ui_diff_applyhunk -state]
3650 $ctxmi add command \
3651         -label [mc "Apply/Reverse Line"] \
3652         -command {apply_range_or_line $cursorX $cursorY; do_rescan}
3653 lappend diff_actions [list $ctxmi entryconf $ui_diff_applyline -state]
3654 $ctxmi add separator
3655 $ctxmi add command \
3656         -label [mc "Show Less Context"] \
3657         -command show_less_context
3658 lappend diff_actions [list $ctxmi entryconf [$ctxmi index last] -state]
3659 $ctxmi add command \
3660         -label [mc "Show More Context"] \
3661         -command show_more_context
3662 lappend diff_actions [list $ctxmi entryconf [$ctxmi index last] -state]
3663 $ctxmi add separator
3664 create_common_diff_popup $ctxmi
3665
3666 set ctxmmg .vpane.lower.diff.body.ctxmmg
3667 menu $ctxmmg -tearoff 0
3668 $ctxmmg add command \
3669         -label [mc "Run Merge Tool"] \
3670         -command {merge_resolve_tool}
3671 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3672 $ctxmmg add separator
3673 $ctxmmg add command \
3674         -label [mc "Use Remote Version"] \
3675         -command {merge_resolve_one 3}
3676 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3677 $ctxmmg add command \
3678         -label [mc "Use Local Version"] \
3679         -command {merge_resolve_one 2}
3680 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3681 $ctxmmg add command \
3682         -label [mc "Revert To Base"] \
3683         -command {merge_resolve_one 1}
3684 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3685 $ctxmmg add separator
3686 $ctxmmg add command \
3687         -label [mc "Show Less Context"] \
3688         -command show_less_context
3689 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3690 $ctxmmg add command \
3691         -label [mc "Show More Context"] \
3692         -command show_more_context
3693 lappend diff_actions [list $ctxmmg entryconf [$ctxmmg index last] -state]
3694 $ctxmmg add separator
3695 create_common_diff_popup $ctxmmg
3696
3697 set ctxmsm .vpane.lower.diff.body.ctxmsm
3698 menu $ctxmsm -tearoff 0
3699 $ctxmsm add command \
3700         -label [mc "Visualize These Changes In The Submodule"] \
3701         -command {do_gitk -- true}
3702 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3703 $ctxmsm add command \
3704         -label [mc "Visualize Current Branch History In The Submodule"] \
3705         -command {do_gitk {} true}
3706 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3707 $ctxmsm add command \
3708         -label [mc "Visualize All Branch History In The Submodule"] \
3709         -command {do_gitk --all true}
3710 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3711 $ctxmsm add separator
3712 $ctxmsm add command \
3713         -label [mc "Start git gui In The Submodule"] \
3714         -command {do_git_gui}
3715 lappend diff_actions [list $ctxmsm entryconf [$ctxmsm index last] -state]
3716 $ctxmsm add separator
3717 create_common_diff_popup $ctxmsm
3718
3719 proc has_textconv {path} {
3720         if {[is_config_false gui.textconv]} {
3721                 return 0
3722         }
3723         set filter [gitattr $path diff set]
3724         set textconv [get_config [join [list diff $filter textconv] .]]
3725         if {$filter ne {set} && $textconv ne {}} {
3726                 return 1
3727         } else {
3728                 return 0
3729         }
3730 }
3731
3732 proc popup_diff_menu {ctxmw ctxmi ctxmmg ctxmsm x y X Y} {
3733         global current_diff_path file_states
3734         set ::cursorX $x
3735         set ::cursorY $y
3736         if {[info exists file_states($current_diff_path)]} {
3737                 set state [lindex $file_states($current_diff_path) 0]
3738         } else {
3739                 set state {__}
3740         }
3741         if {[string first {U} $state] >= 0} {
3742                 tk_popup $ctxmmg $X $Y
3743         } elseif {$::is_submodule_diff} {
3744                 tk_popup $ctxmsm $X $Y
3745         } else {
3746                 set has_range [expr {[$::ui_diff tag nextrange sel 0.0] != {}}]
3747                 if {$::ui_index eq $::current_diff_side} {
3748                         set ctxm $ctxmi
3749                         set l [mc "Unstage Hunk From Commit"]
3750                         if {$has_range} {
3751                                 set t [mc "Unstage Lines From Commit"]
3752                         } else {
3753                                 set t [mc "Unstage Line From Commit"]
3754                         }
3755                 } else {
3756                         set ctxm $ctxmw
3757                         set l [mc "Stage Hunk For Commit"]
3758                         if {$has_range} {
3759                                 set t [mc "Stage Lines For Commit"]
3760                                 set r [mc "Revert Lines"]
3761                         } else {
3762                                 set t [mc "Stage Line For Commit"]
3763                                 set r [mc "Revert Line"]
3764                         }
3765                 }
3766                 if {$::is_3way_diff
3767                         || $current_diff_path eq {}
3768                         || {__} eq $state
3769                         || {_O} eq $state
3770                         || [string match {?T} $state]
3771                         || [string match {T?} $state]
3772                         || [has_textconv $current_diff_path]} {
3773                         set s disabled
3774                 } else {
3775                         set s normal
3776                 }
3777                 $ctxm entryconf $::ui_diff_applyhunk -state $s -label $l
3778                 $ctxm entryconf $::ui_diff_applyline -state $s -label $t
3779                 if {$::ui_workdir eq $::current_diff_side} {
3780                         $ctxm entryconf $::ui_diff_revertline -state $s -label $r
3781                 }
3782                 tk_popup $ctxm $X $Y
3783         }
3784 }
3785 bind_button3 $ui_diff [list popup_diff_menu $ctxmw $ctxmi $ctxmmg $ctxmsm %x %y %X %Y]
3786
3787 # -- Status Bar
3788 #
3789 set main_status [::status_bar::new .status]
3790 pack .status -anchor w -side bottom -fill x
3791 $main_status show [mc "Initializing..."]
3792
3793 # -- Load geometry
3794 #
3795 proc on_ttk_pane_mapped {w pane pos} {
3796         bind $w <Map> {}
3797         after 0 [list after idle [list $w sashpos $pane $pos]]
3798 }
3799 proc on_tk_pane_mapped {w pane x y} {
3800         bind $w <Map> {}
3801         after 0 [list after idle [list $w sash place $pane $x $y]]
3802 }
3803 proc on_application_mapped {} {
3804         global repo_config use_ttk
3805         bind . <Map> {}
3806         set gm $repo_config(gui.geometry)
3807         if {$use_ttk} {
3808                 bind .vpane <Map> \
3809                     [list on_ttk_pane_mapped %W 0 [lindex $gm 1]]
3810                 bind .vpane.files <Map> \
3811                     [list on_ttk_pane_mapped %W 0 [lindex $gm 2]]
3812         } else {
3813                 bind .vpane <Map> \
3814                     [list on_tk_pane_mapped %W 0 \
3815                          [lindex $gm 1] \
3816                          [lindex [.vpane sash coord 0] 1]]
3817                 bind .vpane.files <Map> \
3818                     [list on_tk_pane_mapped %W 0 \
3819                          [lindex [.vpane.files sash coord 0] 0] \
3820                          [lindex $gm 2]]
3821         }
3822         wm geometry . [lindex $gm 0]
3823 }
3824 if {[info exists repo_config(gui.geometry)]} {
3825         bind . <Map> [list on_application_mapped]
3826         wm geometry . [lindex $repo_config(gui.geometry) 0]
3827 }
3828
3829 # -- Load window state
3830 #
3831 if {[info exists repo_config(gui.wmstate)]} {
3832         catch {wm state . $repo_config(gui.wmstate)}
3833 }
3834
3835 # -- Key Bindings
3836 #
3837 bind $ui_comm <$M1B-Key-Return> {do_commit;break}
3838 bind $ui_comm <$M1B-Key-t> {do_add_selection;break}
3839 bind $ui_comm <$M1B-Key-T> {do_add_selection;break}
3840 bind $ui_comm <$M1B-Key-u> {do_unstage_selection;break}
3841 bind $ui_comm <$M1B-Key-U> {do_unstage_selection;break}
3842 bind $ui_comm <$M1B-Key-j> {do_revert_selection;break}
3843 bind $ui_comm <$M1B-Key-J> {do_revert_selection;break}
3844 bind $ui_comm <$M1B-Key-i> {do_add_all;break}
3845 bind $ui_comm <$M1B-Key-I> {do_add_all;break}
3846 bind $ui_comm <$M1B-Key-x> {tk_textCut %W;break}
3847 bind $ui_comm <$M1B-Key-X> {tk_textCut %W;break}
3848 bind $ui_comm <$M1B-Key-c> {tk_textCopy %W;break}
3849 bind $ui_comm <$M1B-Key-C> {tk_textCopy %W;break}
3850 bind $ui_comm <$M1B-Key-v> {tk_textPaste %W; %W see insert; break}
3851 bind $ui_comm <$M1B-Key-V> {tk_textPaste %W; %W see insert; break}
3852 bind $ui_comm <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3853 bind $ui_comm <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3854 bind $ui_comm <$M1B-Key-minus> {show_less_context;break}
3855 bind $ui_comm <$M1B-Key-KP_Subtract> {show_less_context;break}
3856 bind $ui_comm <$M1B-Key-equal> {show_more_context;break}
3857 bind $ui_comm <$M1B-Key-plus> {show_more_context;break}
3858 bind $ui_comm <$M1B-Key-KP_Add> {show_more_context;break}
3859
3860 bind $ui_diff <$M1B-Key-x> {tk_textCopy %W;break}
3861 bind $ui_diff <$M1B-Key-X> {tk_textCopy %W;break}
3862 bind $ui_diff <$M1B-Key-c> {tk_textCopy %W;break}
3863 bind $ui_diff <$M1B-Key-C> {tk_textCopy %W;break}
3864 bind $ui_diff <$M1B-Key-v> {break}
3865 bind $ui_diff <$M1B-Key-V> {break}
3866 bind $ui_diff <$M1B-Key-a> {%W tag add sel 0.0 end;break}
3867 bind $ui_diff <$M1B-Key-A> {%W tag add sel 0.0 end;break}
3868 bind $ui_diff <$M1B-Key-j> {do_revert_selection;break}
3869 bind $ui_diff <$M1B-Key-J> {do_revert_selection;break}
3870 bind $ui_diff <Key-Up>     {catch {%W yview scroll -1 units};break}
3871 bind $ui_diff <Key-Down>   {catch {%W yview scroll  1 units};break}
3872 bind $ui_diff <Key-Left>   {catch {%W xview scroll -1 units};break}
3873 bind $ui_diff <Key-Right>  {catch {%W xview scroll  1 units};break}
3874 bind $ui_diff <Key-k>         {catch {%W yview scroll -1 units};break}
3875 bind $ui_diff <Key-j>         {catch {%W yview scroll  1 units};break}
3876 bind $ui_diff <Key-h>         {catch {%W xview scroll -1 units};break}
3877 bind $ui_diff <Key-l>         {catch {%W xview scroll  1 units};break}
3878 bind $ui_diff <Control-Key-b> {catch {%W yview scroll -1 pages};break}
3879 bind $ui_diff <Control-Key-f> {catch {%W yview scroll  1 pages};break}
3880 bind $ui_diff <Button-1>   {focus %W}
3881
3882 if {[is_enabled branch]} {
3883         bind . <$M1B-Key-n> branch_create::dialog
3884         bind . <$M1B-Key-N> branch_create::dialog
3885         bind . <$M1B-Key-o> branch_checkout::dialog
3886         bind . <$M1B-Key-O> branch_checkout::dialog
3887         bind . <$M1B-Key-m> merge::dialog
3888         bind . <$M1B-Key-M> merge::dialog
3889 }
3890 if {[is_enabled transport]} {
3891         bind . <$M1B-Key-p> do_push_anywhere
3892         bind . <$M1B-Key-P> do_push_anywhere
3893 }
3894
3895 bind .   <Key-F5>     ui_do_rescan
3896 bind .   <$M1B-Key-r> ui_do_rescan
3897 bind .   <$M1B-Key-R> ui_do_rescan
3898 bind .   <$M1B-Key-s> do_signoff
3899 bind .   <$M1B-Key-S> do_signoff
3900 bind .   <$M1B-Key-t> do_add_selection
3901 bind .   <$M1B-Key-T> do_add_selection
3902 bind .   <$M1B-Key-u> do_unstage_selection
3903 bind .   <$M1B-Key-U> do_unstage_selection
3904 bind .   <$M1B-Key-j> do_revert_selection
3905 bind .   <$M1B-Key-J> do_revert_selection
3906 bind .   <$M1B-Key-i> do_add_all
3907 bind .   <$M1B-Key-I> do_add_all
3908 bind .   <$M1B-Key-minus> {show_less_context;break}
3909 bind .   <$M1B-Key-KP_Subtract> {show_less_context;break}
3910 bind .   <$M1B-Key-equal> {show_more_context;break}
3911 bind .   <$M1B-Key-plus> {show_more_context;break}
3912 bind .   <$M1B-Key-KP_Add> {show_more_context;break}
3913 bind .   <$M1B-Key-Return> do_commit
3914 foreach i [list $ui_index $ui_workdir] {
3915         bind $i <Button-1>       "toggle_or_diff         $i %x %y; break"
3916         bind $i <$M1B-Button-1>  "add_one_to_selection   $i %x %y; break"
3917         bind $i <Shift-Button-1> "add_range_to_selection $i %x %y; break"
3918 }
3919 if {[$files_ctxm index end] == 1} {
3920         # remove the separator, when we don't have user specified file tools
3921         $files_ctxm delete 0
3922 }
3923 bind_button3 $ui_index   "popup_files_ctxm $files_ctxm $ui_index %x %y %X %Y; break"
3924 bind_button3 $ui_workdir "popup_files_ctxm $files_ctxm $ui_workdir %x %y %X %Y; break"
3925
3926 unset i
3927
3928 set file_lists($ui_index) [list]
3929 set file_lists($ui_workdir) [list]
3930
3931 wm title . "[appname] ([reponame]) [file normalize $_gitworktree]"
3932 focus -force $ui_comm
3933
3934 # -- Warn the user about environmental problems.  Cygwin's Tcl
3935 #    does *not* pass its env array onto any processes it spawns.
3936 #    This means that git processes get none of our environment.
3937 #
3938 if {[is_Cygwin]} {
3939         set ignored_env 0
3940         set suggest_user {}
3941         set msg [mc "Possible environment issues exist.
3942
3943 The following environment variables are probably
3944 going to be ignored by any Git subprocess run
3945 by %s:
3946
3947 " [appname]]
3948         foreach name [array names env] {
3949                 switch -regexp -- $name {
3950                 {^GIT_INDEX_FILE$} -
3951                 {^GIT_OBJECT_DIRECTORY$} -
3952                 {^GIT_ALTERNATE_OBJECT_DIRECTORIES$} -
3953                 {^GIT_DIFF_OPTS$} -
3954                 {^GIT_EXTERNAL_DIFF$} -
3955                 {^GIT_PAGER$} -
3956                 {^GIT_TRACE$} -
3957                 {^GIT_CONFIG$} -
3958                 {^GIT_(AUTHOR|COMMITTER)_DATE$} {
3959                         append msg " - $name\n"
3960                         incr ignored_env
3961                 }
3962                 {^GIT_(AUTHOR|COMMITTER)_(NAME|EMAIL)$} {
3963                         append msg " - $name\n"
3964                         incr ignored_env
3965                         set suggest_user $name
3966                 }
3967                 }
3968         }
3969         if {$ignored_env > 0} {
3970                 append msg [mc "
3971 This is due to a known issue with the
3972 Tcl binary distributed by Cygwin."]
3973
3974                 if {$suggest_user ne {}} {
3975                         append msg [mc "
3976
3977 A good replacement for %s
3978 is placing values for the user.name and
3979 user.email settings into your personal
3980 ~/.gitconfig file.
3981 " $suggest_user]
3982                 }
3983                 warn_popup $msg
3984         }
3985         unset ignored_env msg suggest_user name
3986 }
3987
3988 # -- Only initialize complex UI if we are going to stay running.
3989 #
3990 if {[is_enabled transport]} {
3991         load_all_remotes
3992
3993         set n [.mbar.remote index end]
3994         populate_remotes_menu
3995         set n [expr {[.mbar.remote index end] - $n}]
3996         if {$n > 0} {
3997                 if {[.mbar.remote type 0] eq "tearoff"} { incr n }
3998                 .mbar.remote insert $n separator
3999         }
4000         unset n
4001 }
4002
4003 if {[winfo exists $ui_comm]} {
4004         set GITGUI_BCK_exists [load_message GITGUI_BCK utf-8]
4005
4006         # -- If both our backup and message files exist use the
4007         #    newer of the two files to initialize the buffer.
4008         #
4009         if {$GITGUI_BCK_exists} {
4010                 set m [gitdir GITGUI_MSG]
4011                 if {[file isfile $m]} {
4012                         if {[file mtime [gitdir GITGUI_BCK]] > [file mtime $m]} {
4013                                 catch {file delete [gitdir GITGUI_MSG]}
4014                         } else {
4015                                 $ui_comm delete 0.0 end
4016                                 $ui_comm edit reset
4017                                 $ui_comm edit modified false
4018                                 catch {file delete [gitdir GITGUI_BCK]}
4019                                 set GITGUI_BCK_exists 0
4020                         }
4021                 }
4022                 unset m
4023         }
4024
4025         proc backup_commit_buffer {} {
4026                 global ui_comm GITGUI_BCK_exists
4027
4028                 set m [$ui_comm edit modified]
4029                 if {$m || $GITGUI_BCK_exists} {
4030                         set msg [string trim [$ui_comm get 0.0 end]]
4031                         regsub -all -line {[ \r\t]+$} $msg {} msg
4032
4033                         if {$msg eq {}} {
4034                                 if {$GITGUI_BCK_exists} {
4035                                         catch {file delete [gitdir GITGUI_BCK]}
4036                                         set GITGUI_BCK_exists 0
4037                                 }
4038                         } elseif {$m} {
4039                                 catch {
4040                                         set fd [open [gitdir GITGUI_BCK] w]
4041                                         fconfigure $fd -encoding utf-8
4042                                         puts -nonewline $fd $msg
4043                                         close $fd
4044                                         set GITGUI_BCK_exists 1
4045                                 }
4046                         }
4047
4048                         $ui_comm edit modified false
4049                 }
4050
4051                 set ::GITGUI_BCK_i [after 2000 backup_commit_buffer]
4052         }
4053
4054         backup_commit_buffer
4055
4056         # -- If the user has aspell available we can drive it
4057         #    in pipe mode to spellcheck the commit message.
4058         #
4059         set spell_cmd [list |]
4060         set spell_dict [get_config gui.spellingdictionary]
4061         lappend spell_cmd aspell
4062         if {$spell_dict ne {}} {
4063                 lappend spell_cmd --master=$spell_dict
4064         }
4065         lappend spell_cmd --mode=none
4066         lappend spell_cmd --encoding=utf-8
4067         lappend spell_cmd pipe
4068         if {$spell_dict eq {none}
4069          || [catch {set spell_fd [open $spell_cmd r+]} spell_err]} {
4070                 bind_button3 $ui_comm [list tk_popup $ui_comm_ctxm %X %Y]
4071         } else {
4072                 set ui_comm_spell [spellcheck::init \
4073                         $spell_fd \
4074                         $ui_comm \
4075                         $ui_comm_ctxm \
4076                 ]
4077         }
4078         unset -nocomplain spell_cmd spell_fd spell_err spell_dict
4079 }
4080
4081 lock_index begin-read
4082 if {![winfo ismapped .]} {
4083         wm deiconify .
4084 }
4085 after 1 {
4086         if {[is_enabled initialamend]} {
4087                 force_amend
4088         } else {
4089                 do_rescan
4090         }
4091
4092         if {[is_enabled nocommitmsg]} {
4093                 $ui_comm configure -state disabled -background gray
4094         }
4095 }
4096 if {[is_enabled multicommit] && ![is_config_false gui.gcwarning]} {
4097         after 1000 hint_gc
4098 }
4099 if {[is_enabled retcode]} {
4100         bind . <Destroy> {+terminate_me %W}
4101 }
4102 if {$picked && [is_config_true gui.autoexplore]} {
4103         do_explore
4104 }
4105
4106 # Local variables:
4107 # mode: tcl
4108 # indent-tabs-mode: t
4109 # tab-width: 4
4110 # End: