app-i18n/mozc/mozc-2.26.4220_p20201212102434_p20201219202429.ebuild

   1 # Copyright 2010-2021 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="7"
   5 PYTHON_COMPAT=(python{3_7,3_8,3_9})
   6
   7 inherit elisp-common multiprocessing python-any-r1 toolchain-funcs desktop xdg
   8
   9 if [[ "${PV}" == "9999" ]]; then
  10         inherit git-r3
  11
  12         EGIT_REPO_URI="https://github.com/google/mozc"
  13         EGIT_SUBMODULES=(src/third_party/japanese_usage_dictionary)
  14 else
  15         MOZC_GIT_REVISION="9ba59b64d53365c1fe93c1c245b4ec3e35bdadf0"
  16         MOZC_DATE="${PV#*_p}"
  17         MOZC_DATE="${MOZC_DATE%%_p*}"
  18
  19         FCITX_MOZC_GIT_REVISION="1ea089debc31ff216473369ad71c08318384ee06"
  20         FCITX_MOZC_DATE="${PV#*_p}"
  21         FCITX_MOZC_DATE="${FCITX_MOZC_DATE#*_p}"
  22         FCITX_MOZC_DATE="${FCITX_MOZC_DATE%%_p*}"
  23
  24         JAPANESE_USAGE_DICTIONARY_GIT_REVISION="a4a66772e33746b91e99caceecced9a28507e925"
  25         JAPANESE_USAGE_DICTIONARY_DATE="20180701040110"
  26 fi
  27
  28 DESCRIPTION="Mozc - Japanese input method editor"
  29 HOMEPAGE="https://github.com/google/mozc"
  30 if [[ "${PV}" == "9999" ]]; then
  31         SRC_URI=""
  32 else
  33         SRC_URI="https://github.com/google/${PN}/archive/${MOZC_GIT_REVISION}.tar.gz -> ${PN}-${PV%%_p*}-${MOZC_DATE}.tar.gz
  34                 https://github.com/hiroyuki-komatsu/japanese-usage-dictionary/archive/${JAPANESE_USAGE_DICTIONARY_GIT_REVISION}.tar.gz -> japanese-usage-dictionary-${JAPANESE_USAGE_DICTIONARY_DATE}.tar.gz
  35                 https://github.com/fcitx/${PN}/archive/${FCITX_MOZC_GIT_REVISION}.tar.gz -> fcitx-${PN}-${PV%%_p*}-${FCITX_MOZC_DATE}.tar.gz"
  36 fi
  37
  38 # Mozc: BSD
  39 # src/data/dictionary_oss: ipadic, public-domain
  40 # src/data/unicode: unicode
  41 # japanese-usage-dictionary: BSD-2
  42 LICENSE="BSD BSD-2 ipadic public-domain unicode"
  43 SLOT="0"
  44 #KEYWORDS="~amd64 ~arm64 ~ppc64 x86"
  45 KEYWORDS="~amd64 ~x86"
  46 IUSE="debug emacs fcitx4 fcitx5 +gui ibus renderer test"
  47 REQUIRED_USE="|| ( emacs fcitx4 fcitx5 ibus )"
  48 RESTRICT="!test? ( test )"
  49
  50 BDEPEND="$(python_gen_any_dep 'dev-python/six[${PYTHON_USEDEP}]')
  51         >=dev-libs/protobuf-3.0.0
  52         dev-util/gyp
  53         dev-util/ninja
  54         virtual/pkgconfig
  55         emacs? ( app-editors/emacs:* )
  56         fcitx4? ( sys-devel/gettext )
  57         fcitx5? ( sys-devel/gettext )"
  58 DEPEND="=dev-cpp/abseil-cpp-20200923*[cxx17(+)]
  59         >=dev-libs/protobuf-3.0.0:=
  60         fcitx4? (
  61                 app-i18n/fcitx:4
  62                 virtual/libintl
  63         )
  64         fcitx5? (
  65                 app-i18n/fcitx5:5
  66                 app-i18n/libime
  67                 sys-devel/gettext
  68                 virtual/libintl
  69         )
  70         gui? (
  71                 dev-qt/qtcore:5
  72                 dev-qt/qtgui:5
  73                 dev-qt/qtwidgets:5
  74         )
  75         ibus? (
  76                 >=app-i18n/ibus-1.4.1
  77                 dev-libs/glib:2
  78                 x11-libs/libxcb
  79         )
  80         renderer? (
  81                 dev-libs/glib:2
  82                 x11-libs/cairo
  83                 x11-libs/gtk+:2
  84                 x11-libs/pango
  85         )
  86         test? (
  87                 >=dev-cpp/gtest-1.8.0
  88                 dev-libs/jsoncpp
  89         )"
  90 RDEPEND="=dev-cpp/abseil-cpp-20200923*[cxx17(+)]
  91         >=dev-libs/protobuf-3.0.0:=
  92         emacs? ( app-editors/emacs:* )
  93         fcitx4? (
  94                 app-i18n/fcitx:4
  95                 virtual/libintl
  96         )
  97         fcitx5? (
  98                 app-i18n/fcitx5:5
  99                 app-i18n/libime
 100                 sys-devel/gettext
 101                 virtual/libintl
 102         )
 103         gui? (
 104                 dev-qt/qtcore:5
 105                 dev-qt/qtgui:5
 106                 dev-qt/qtwidgets:5
 107         )
 108         ibus? (
 109                 >=app-i18n/ibus-1.4.1
 110                 dev-libs/glib:2
 111                 x11-libs/libxcb
 112         )
 113         renderer? (
 114                 dev-libs/glib:2
 115                 x11-libs/cairo
 116                 x11-libs/gtk+:2
 117                 x11-libs/pango
 118         )"
 119
 120 S="${WORKDIR}/${P}/src"
 121
 122 SITEFILE="50${PN}-gentoo.el"
 123
 124 execute() {
 125         einfo "$@"
 126         "$@"
 127 }
 128
 129 python_check_deps() {
 130         has_version -b "dev-python/six[${PYTHON_USEDEP}]"
 131 }
 132
 133 src_unpack() {
 134         if [[ "${PV}" == "9999" ]]; then
 135                 git-r3_src_unpack
 136
 137                 if use fcitx4; then
 138                         local EGIT_SUBMODULES=()
 139                         git-r3_fetch https://github.com/fcitx/mozc refs/heads/fcitx
 140                         git-r3_checkout https://github.com/fcitx/mozc "${WORKDIR}/fcitx-mozc"
 141                 fi
 142                 if use fcitx5; then
 143                         local EGIT_SUBMODULES=()
 144                         git-r3_fetch https://github.com/fcitx/mozc refs/heads/fcitx5
 145                         git-r3_checkout https://github.com/fcitx/mozc "${WORKDIR}/fcitx5-mozc"
 146                 fi
 147         else
 148                 unpack ${PN}-${PV%%_p*}-${MOZC_DATE}.tar.gz
 149                 mv mozc-${MOZC_GIT_REVISION} ${P} || die
 150
 151                 unpack japanese-usage-dictionary-${JAPANESE_USAGE_DICTIONARY_DATE}.tar.gz
 152                 cp -p japanese-usage-dictionary-${JAPANESE_USAGE_DICTIONARY_GIT_REVISION}/usage_dict.txt ${P}/src/third_party/japanese_usage_dictionary || die
 153
 154                 unpack fcitx-${PN}-${PV%%_p*}-${FCITX_MOZC_DATE}.tar.gz
 155                 if use fcitx4; then
 156                         cp -pr mozc-${FCITX_MOZC_GIT_REVISION} fcitx-${PN} || die
 157                 fi
 158                 if use fcitx5; then
 159                         cp -pr mozc-${FCITX_MOZC_GIT_REVISION} fcitx5-${PN} || die
 160                 fi
 161         fi
 162 }
 163
 164 src_prepare() {
 165         if use fcitx4; then
 166                 cp -pr "${WORKDIR}/fcitx-mozc/src/unix/fcitx" unix || die
 167         fi
 168         if use fcitx5; then
 169                 cp -pr "${WORKDIR}/fcitx5-mozc/src/unix/fcitx5" unix || die
 170         fi
 171
 172         pushd "${WORKDIR}/${P}" > /dev/null || die
 173
 174         eapply "${FILESDIR}/${PN}-2.26.4220-system_abseil-cpp.patch"
 175         eapply "${FILESDIR}/${PN}-2.26.4220-system_gtest.patch"
 176         eapply "${FILESDIR}/${PN}-2.26.4220-system_jsoncpp.patch"
 177         eapply "${FILESDIR}/${PN}-2.26.4220-environmental_variables.patch"
 178         eapply "${FILESDIR}/${PN}-2.26.4220-server_path_check.patch"
 179
 180         eapply_user
 181
 182         popd > /dev/null || die
 183
 184         sed \
 185                 -e "s/def GypMain(options, unused_args):/def GypMain(options, gyp_args):/" \
 186                 -e "s/RunOrDie(gyp_command + gyp_options)/RunOrDie(gyp_command + gyp_options + gyp_args)/" \
 187                 -e "s/RunOrDie(\[ninja/&, '-j$(makeopts_jobs)', '-l$(makeopts_loadavg "${MAKEOPTS}" 0)', '-v'/" \
 188                 -i build_mozc.py || die
 189
 190         local ar=($(tc-getAR))
 191         local cc=($(tc-getCC))
 192         local cxx=($(tc-getCXX))
 193         local ld=($(tc-getLD))
 194         local nm=($(tc-getNM))
 195         local readelf=($(tc-getREADELF))
 196
 197         # Use absolute paths. Non-absolute paths are mishandled by GYP.
 198         ar[0]=$(type -P ${ar[0]})
 199         cc[0]=$(type -P ${cc[0]})
 200         cxx[0]=$(type -P ${cxx[0]})
 201         ld[0]=$(type -P ${ld[0]})
 202         nm[0]=$(type -P ${nm[0]})
 203         readelf[0]=$(type -P ${readelf[0]})
 204
 205         sed \
 206                 -e "s:<!(which ar):${ar[@]}:" \
 207                 -e "s:<!(which clang):${cc[@]}:" \
 208                 -e "s:<!(which clang++):${cxx[@]}:" \
 209                 -e "s:<!(which ld):${ld[@]}:" \
 210                 -e "s:<!(which nm):${nm[@]}:" \
 211                 -e "s:<!(which readelf):${readelf[@]}:" \
 212                 -i gyp/common.gypi || die
 213
 214         # https://github.com/google/mozc/issues/489
 215         sed \
 216                 -e "/'-lc++'/d" \
 217                 -e "/'-stdlib=libc++'/d" \
 218                 -i gyp/common.gypi || die
 219 }
 220
 221 src_configure() {
 222         if use debug; then
 223                 BUILD_TYPE="Debug"
 224         else
 225                 BUILD_TYPE="Release"
 226         fi
 227
 228         local gyp_arguments=()
 229
 230         if tc-is-gcc; then
 231                 gyp_arguments+=(-D compiler_host=gcc -D compiler_target=gcc)
 232         elif tc-is-clang; then
 233                 gyp_arguments+=(-D compiler_host=clang -D compiler_target=clang)
 234         else
 235                 gyp_arguments+=(-D compiler_host=unknown -D compiler_target=unknown)
 236         fi
 237
 238         gyp_arguments+=(-D debug_extra_cflags=)
 239         gyp_arguments+=(-D release_extra_cflags=)
 240
 241         gyp_arguments+=(-D use_fcitx=$(usex fcitx4 YES NO))
 242         gyp_arguments+=(-D use_fcitx5=$(usex fcitx5 YES NO))
 243         gyp_arguments+=(-D use_libibus=$(usex ibus 1 0))
 244         gyp_arguments+=(-D use_libprotobuf=1)
 245         gyp_arguments+=(-D use_system_abseil_cpp=1)
 246         gyp_arguments+=(-D use_system_gtest=$(usex test 1 0))
 247         gyp_arguments+=(-D use_system_jsoncpp=$(usex test 1 0))
 248         gyp_arguments+=(-D enable_gtk_renderer=$(usex renderer 1 0))
 249
 250         gyp_arguments+=(-D server_dir="${EPREFIX}/usr/libexec/mozc")
 251         gyp_arguments+=(-D document_dir="${EPREFIX}/usr/libexec/mozc/documents")
 252
 253         if use ibus; then
 254                 gyp_arguments+=(-D ibus_mozc_path="${EPREFIX}/usr/libexec/ibus-engine-mozc")
 255                 gyp_arguments+=(-D ibus_mozc_icon_path="${EPREFIX}/usr/share/ibus-mozc/product_icon.png")
 256         fi
 257
 258         unset AR CC CXX LD NM READELF
 259
 260         execute "${PYTHON}" build_mozc.py gyp \
 261                 --gypdir="${EPREFIX}/usr/bin" \
 262                 --server_dir="${EPREFIX}/usr/libexec/mozc" \
 263                 --verbose \
 264                 $(usex gui "" --noqt) \
 265                 -- "${gyp_arguments[@]}" || die "Configuration failed"
 266 }
 267
 268 src_compile() {
 269         local targets=(server/server.gyp:mozc_server)
 270         if use emacs; then
 271                 targets+=(unix/emacs/emacs.gyp:mozc_emacs_helper)
 272         fi
 273         if use fcitx4; then
 274                 targets+=(unix/fcitx/fcitx.gyp:fcitx-mozc)
 275         fi
 276         if use fcitx5; then
 277                 targets+=(unix/fcitx5/fcitx5.gyp:fcitx5-mozc)
 278         fi
 279         if use gui; then
 280                 targets+=(gui/gui.gyp:mozc_tool)
 281         fi
 282         if use ibus; then
 283                 targets+=(unix/ibus/ibus.gyp:ibus_mozc)
 284         fi
 285         if use renderer; then
 286                 targets+=(renderer/renderer.gyp:mozc_renderer)
 287         fi
 288         if use test; then
 289                 targets+=(gyp/tests.gyp:unittests)
 290         fi
 291
 292         execute "${PYTHON}" build_mozc.py build -c ${BUILD_TYPE} -v "${targets[@]}" || die "Building failed"
 293
 294         if use emacs; then
 295                 elisp-compile unix/emacs/*.el
 296         fi
 297 }
 298
 299 src_test() {
 300         execute "${PYTHON}" build_mozc.py runtests -c ${BUILD_TYPE} --test_jobs 1 || die "Testing failed"
 301 }
 302
 303 src_install() {
 304         exeinto /usr/libexec/mozc
 305         doexe out_linux/${BUILD_TYPE}/mozc_server
 306
 307         if use gui; then
 308                 doexe out_linux/${BUILD_TYPE}/mozc_tool
 309         fi
 310
 311         if use renderer; then
 312                 doexe out_linux/${BUILD_TYPE}/mozc_renderer
 313         fi
 314
 315         insinto /usr/libexec/mozc/documents
 316         doins data/installer/credits_en.html
 317
 318         if use emacs; then
 319                 dobin out_linux/${BUILD_TYPE}/mozc_emacs_helper
 320                 elisp-install ${PN} unix/emacs/*.{el,elc}
 321                 elisp-site-file-install "${FILESDIR}/${SITEFILE}" ${PN}
 322         fi
 323
 324         if use fcitx4; then
 325                 exeinto /usr/$(get_libdir)/fcitx
 326                 doexe out_linux/${BUILD_TYPE}/fcitx-mozc.so
 327
 328                 insinto /usr/share/fcitx/addon
 329                 doins unix/fcitx/fcitx-mozc.conf
 330
 331                 insinto /usr/share/fcitx/inputmethod
 332                 doins unix/fcitx/mozc.conf
 333
 334                 insinto /usr/share/fcitx/mozc/icon
 335                 newins data/images/product_icon_32bpp-128.png mozc.png
 336                 local image
 337                 for image in ../../fcitx-${PN}/src/data/images/unix/ui-*.png; do
 338                         newins "${image}" "mozc-${image#../../fcitx-${PN}/src/data/images/unix/ui-}"
 339                 done
 340
 341                 local locale mo_file
 342                 for mo_file in out_linux/${BUILD_TYPE}/gen/unix/fcitx/po/*.mo; do
 343                         locale="${mo_file##*/}"
 344                         locale="${locale%.mo}"
 345                         insinto /usr/share/locale/${locale}/LC_MESSAGES
 346                         newins "${mo_file}" fcitx-mozc.mo
 347                 done
 348         fi
 349         if use fcitx5; then
 350                 exeinto /usr/$(get_libdir)/fcitx5
 351                 doexe out_linux/${BUILD_TYPE}/fcitx5-mozc.so
 352
 353                 insinto /usr/share/fcitx5/addon
 354                 newins unix/fcitx5/mozc-addon.conf mozc.conf
 355
 356                 insinto /usr/share/fcitx5/inputmethod
 357                 doins unix/fcitx5/mozc.conf
 358
 359                 local orgfcitx5="org.fcitx.Fcitx5.fcitx-mozc"
 360                 newicon -s 128 data/images/product_icon_32bpp-128.png ${orgfcitx5}.png
 361                 newicon -s 128 data/images/product_icon_32bpp-128.png fcitx-mozc.png
 362                 newicon -s 32 data/images/unix/ime_product_icon_opensource-32.png ${orgfcitx5}.png
 363                 newicon -s 32 data/images/unix/ime_product_icon_opensource-32.png fcitx-mozc.png
 364                 for uiimg in ../../fcitx5-mozc/scripts/icons/ui-*.png; do
 365                         dimg=${uiimg#*ui-}
 366                         newicon -s 48 ${uiimg} ${orgfcitx5}-${dimg/_/-}
 367                         newicon -s 48 ${uiimg} fcitx-mozc-${dimg/_/-}
 368                 done
 369
 370                 local locale mo_file
 371                 for mo_file in unix/fcitx5/po/*.po; do
 372                         locale="${mo_file##*/}"
 373                         locale="${locale%.po}"
 374                         msgfmt ${mo_file} -o ${mo_file/.po/.mo} || die
 375                         insinto /usr/share/locale/${locale}/LC_MESSAGES
 376                         newins "${mo_file/.po/.mo}" fcitx5-mozc.mo
 377                 done
 378         fi
 379
 380         if use ibus; then
 381                 exeinto /usr/libexec
 382                 newexe out_linux/${BUILD_TYPE}/ibus_mozc ibus-engine-mozc
 383
 384                 insinto /usr/share/ibus/component
 385                 doins out_linux/${BUILD_TYPE}/gen/unix/ibus/mozc.xml
 386
 387                 insinto /usr/share/ibus-mozc
 388                 newins data/images/unix/ime_product_icon_opensource-32.png product_icon.png
 389                 local image
 390                 for image in data/images/unix/ui-*.png; do
 391                         newins "${image}" "${image#data/images/unix/ui-}"
 392                 done
 393         fi
 394 }
 395
 396 pkg_postinst() {
 397         elog
 398         elog "ENVIRONMENTAL VARIABLES"
 399         elog
 400         elog "MOZC_SERVER_DIRECTORY"
 401         elog "  Mozc server directory"
 402         elog "  Value used by default: \"${EPREFIX}/usr/libexec/mozc\""
 403         elog "MOZC_DOCUMENTS_DIRECTORY"
 404         elog "  Mozc documents directory"
 405         elog "  Value used by default: \"${EPREFIX}/usr/libexec/mozc/documents\""
 406         elog "MOZC_CONFIGURATION_DIRECTORY"
 407         elog "  Mozc configuration directory"
 408         elog "  Value used by default: \"~/.mozc\""
 409         elog
 410         if use emacs; then
 411                 elog
 412                 elog "USAGE IN EMACS"
 413                 elog
 414                 elog "mozc-mode is minor mode to input Japanese text using Mozc server."
 415                 elog "mozc-mode can be used via LEIM (Library of Emacs Input Method)."
 416                 elog
 417                 elog "In order to use mozc-mode by default, the following settings should be added to"
 418                 elog "Emacs init file (~/.emacs.d/init.el or ~/.emacs):"
 419                 elog
 420                 elog "  (require 'mozc)"
 421                 elog "  (set-language-environment \"Japanese\")"
 422                 elog "  (setq default-input-method \"japanese-mozc\")"
 423                 elog
 424                 elog "With the above settings, typing C-\\ (which is bound to \"toggle-input-method\""
 425                 elog "by default) will enable mozc-mode."
 426                 elog
 427                 elog "Alternatively, at run time, after loading mozc.el, mozc-mode can be activated by"
 428                 elog "calling \"set-input-method\" and entering \"japanese-mozc\"."
 429                 elog
 430
 431                 elisp-site-regen
 432         fi
 433         xdg_pkg_postinst
 434 }
 435
 436 pkg_postrm() {
 437         if use emacs; then
 438                 elisp-site-regen
 439         fi
 440         xdg_pkg_postrm
 441 }