elisp/geiser-syntax.el

   1 ;;; geiser-syntax.el -- utilities for parsing scheme syntax
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:03
  11
  12 \f
  13
  14 (require 'geiser-impl)
  15 (require 'geiser-popup)
  16 (require 'geiser-base)
  17
  18 (require 'scheme)
  19
  20 (eval-when-compile (require 'cl))
  21
  22 \f
  23 ;;; Indentation:
  24
  25 (defmacro geiser-syntax--scheme-indent (&rest pairs)
  26   `(progn ,@(mapcar (lambda (p)
  27                       `(put ',(car p) 'scheme-indent-function ',(cadr p)))
  28                     pairs)))
  29
  30 (geiser-syntax--scheme-indent
  31  (case-lambda 0)
  32  (catch defun)
  33  (class defun)
  34  (dynamic-wind 0)
  35  (let*-values 1)
  36  (letrec* 1)
  37  (letrec-values 1)
  38  (let-values 1)
  39  (let/ec 1)
  40  (match defun)
  41  (opt-lambda 1)
  42  (parameterize 1)
  43  (parameterize* 1)
  44  (receive 2)
  45  (syntax-case 2)
  46  (unless 1)
  47  (when 1)
  48  (while 1)
  49  (with-error-to-port 1)
  50  (with-syntax 1))
  51
  52 \f
  53 ;;; Extra syntax keywords
  54 (defconst geiser-syntax--keywords
  55   '(("\\[\\(else\\)\\>" . 1)
  56     ("(\\(parameterize\\)\\>" . 1)))
  57
  58 (font-lock-add-keywords 'scheme-mode geiser-syntax--keywords)
  59
  60 (geiser-impl--define-caller geiser-syntax--impl-kws keywords ()
  61   "A variable (or thunk returning a value) giving additional,
  62 implementation-specific entries for font-lock-keywords.")
  63
  64 (defun geiser-syntax--add-kws ()
  65   (when (not (and (boundp 'quack-mode) quack-mode))
  66     (let ((kw (geiser-syntax--impl-kws geiser-impl--implementation)))
  67       (when kw (font-lock-add-keywords nil kw)))))
  68
  69 \f
  70 ;;; A simple scheme reader
  71
  72 (defvar geiser-syntax--read/buffer-limit nil)
  73
  74 (defsubst geiser-syntax--read/eos ()
  75   (or (eobp)
  76       (and geiser-syntax--read/buffer-limit
  77            (<= geiser-syntax--read/buffer-limit (point)))))
  78
  79 (defsubst geiser-syntax--read/next-char ()
  80   (unless (geiser-syntax--read/eos)
  81     (forward-char)
  82     (char-after)))
  83
  84 (defsubst geiser-syntax--read/token (token)
  85   (geiser-syntax--read/next-char)
  86   (if (listp token) token (list token)))
  87
  88 (defsubst geiser-syntax--read/elisp ()
  89   (ignore-errors (read (current-buffer))))
  90
  91 (defun geiser-syntax--read/symbol ()
  92   (with-syntax-table scheme-mode-syntax-table
  93     (when (re-search-forward "\\(\\sw\\|\\s_\\)+" nil t)
  94       (make-symbol (match-string-no-properties 0)))))
  95
  96 (defun geiser-syntax--read/matching (open close)
  97   (let ((count 1)
  98         (p (1+ (point))))
  99     (while (and (> count 0)
 100                 (geiser-syntax--read/next-char))
 101       (cond ((looking-at-p open) (setq count (1+ count)))
 102             ((looking-at-p close) (setq count (1- count)))))
 103     (buffer-substring-no-properties p (point))))
 104
 105 (defsubst geiser-syntax--read/unprintable ()
 106   (geiser-syntax--read/token
 107    (cons 'unprintable (geiser-syntax--read/matching "<" ">"))))
 108
 109 (defun geiser-syntax--read/skip-comment ()
 110   (while (and (geiser-syntax--read/next-char)
 111               (nth 8 (syntax-ppss))))
 112   (geiser-syntax--read/next-token))
 113
 114 (defun geiser-syntax--read/next-token ()
 115   (skip-syntax-forward "->")
 116   (if (geiser-syntax--read/eos) '(eob)
 117     (case (char-after)
 118       (?\; (geiser-syntax--read/skip-comment))
 119       ((?\( ?\[) (geiser-syntax--read/token 'lparen))
 120       ((?\) ?\]) (geiser-syntax--read/token 'rparen))
 121       (?. (if (memq (car (syntax-after (1+ (point)))) '(0 11 12))
 122               (geiser-syntax--read/token 'dot)
 123             (cons 'atom (geiser-syntax--read/elisp))))
 124       (?\# (case (geiser-syntax--read/next-char)
 125              ('nil '(eob))
 126              (?| (geiser-syntax--read/skip-comment))
 127              (?: (if (geiser-syntax--read/next-char)
 128                      (cons 'kwd (geiser-syntax--read/symbol))
 129                    '(eob)))
 130              (?\\ (cons 'char (geiser-syntax--read/elisp)))
 131              (?\( (geiser-syntax--read/token 'vectorb))
 132              (?\< (geiser-syntax--read/unprintable))
 133              ((?' ?` ?,) (geiser-syntax--read/next-token))
 134              (t (let ((tok (geiser-syntax--read/symbol)))
 135                   (cond ((equal (symbol-name tok) "t") '(boolean . :t))
 136                         ((equal (symbol-name tok) "f") '(boolean . :f))
 137                         (tok (cons 'atom tok))
 138                         (t (geiser-syntax--read/next-token)))))))
 139       (?\' (geiser-syntax--read/token '(quote . quote)))
 140       (?\` (geiser-syntax--read/token
 141             `(backquote . ,backquote-backquote-symbol)))
 142       (?, (if (eq (geiser-syntax--read/next-char) ?@)
 143               (geiser-syntax--read/token
 144                `(splice . ,backquote-splice-symbol))
 145             `(unquote . ,backquote-unquote-symbol)))
 146       (?\" (cons 'string (geiser-syntax--read/elisp)))
 147       (t (cons 'atom (geiser-syntax--read/symbol))))))
 148
 149 (defsubst geiser-syntax--read/match (&rest tks)
 150   (let ((token (geiser-syntax--read/next-token)))
 151     (if (memq (car token) tks) token
 152       (error "Unexpected token: %s" token))))
 153
 154 (defsubst geiser-syntax--read/skip-until (&rest tks)
 155   (let (token)
 156     (while (and (not (memq (car token) tks))
 157                 (not (eq (car token) 'eob)))
 158       (setq token (geiser-syntax--read/next-token)))
 159     token))
 160
 161 (defsubst geiser-syntax--read/try (&rest tks)
 162   (let ((p (point))
 163         (tk (ignore-errors (apply 'geiser-syntax--read/match tks))))
 164     (unless tk (goto-char p))
 165     tk))
 166
 167 (defun geiser-syntax--read/list ()
 168   (cond ((geiser-syntax--read/try 'dot)
 169          (let ((tail (geiser-syntax--read)))
 170            (geiser-syntax--read/skip-until 'eob 'rparen)
 171            tail))
 172         ((geiser-syntax--read/try 'rparen 'eob) nil)
 173         (t (cons (geiser-syntax--read)
 174                  (geiser-syntax--read/list)))))
 175
 176 (defun geiser-syntax--read ()
 177   (let ((token (geiser-syntax--read/next-token))
 178         (max-lisp-eval-depth (max max-lisp-eval-depth 3000)))
 179     (case (car token)
 180       (eob nil)
 181       (lparen (geiser-syntax--read/list))
 182       (vectorb (apply 'vector (geiser-syntax--read/list)))
 183       ((quote backquote unquote splice) (list (cdr token)
 184                                               (geiser-syntax--read)))
 185       (kwd (make-symbol (format ":%s" (cdr token))))
 186       (unprintable (format "#<%s>" (cdr token)))
 187       ((char string atom) (cdr token))
 188       (boolean (cdr token))
 189       (t (error "Reading scheme syntax: unexpected token: %s" token)))))
 190
 191 (defun geiser-syntax--read-from-string (string &optional start end)
 192   (when (stringp string)
 193     (let* ((start (or start 0))
 194            (end (or end (length string)))
 195            (max-lisp-eval-depth (max max-lisp-eval-depth (- end start))))
 196       (with-temp-buffer
 197         (save-excursion (insert string))
 198         (cons (ignore-errors (geiser-syntax--read)) (point))))))
 199
 200 (defsubst geiser-syntax--form-after-point (&optional boundary)
 201   (let ((geiser-syntax--read/buffer-limit (and (numberp boundary) boundary)))
 202     (save-excursion (values (geiser-syntax--read) (point)))))
 203
 204 (defun geiser-syntax--mapconcat (fun lst sep)
 205   (cond ((null lst) "")
 206         ((not (listp lst)) (format ".%s%s" sep (funcall fun lst)))
 207         ((null (cdr lst)) (format "%s" (funcall fun (car lst))))
 208         (t (format "%s%s%s"
 209                    (funcall fun (car lst))
 210                    sep
 211                    (geiser-syntax--mapconcat fun (cdr lst) sep)))))
 212
 213 (defun geiser-syntax--display (a)
 214   (cond ((null a) "()")
 215         ((eq a :t) "#t")
 216         ((eq a :f) "#f")
 217         ((geiser-syntax--keywordp a) (format "#%s" a))
 218         ((symbolp a) (format "%s" a))
 219         ((equal a "...") "...")
 220         ((stringp a) (format "%S" a))
 221         ((and (listp a) (symbolp (car a))
 222               (equal (symbol-name (car a)) "quote"))
 223          (format "'%s" (geiser-syntax--display (cadr a))))
 224         ((listp a)
 225          (format "(%s)"
 226                  (geiser-syntax--mapconcat 'geiser-syntax--display a " ")))
 227         (t (format "%s" a))))
 228
 229 \f
 230 ;;; Code parsing:
 231
 232 (defsubst geiser-syntax--symbol-at-point ()
 233   (and (not (nth 8 (syntax-ppss)))
 234        (car (geiser-syntax--read-from-string (thing-at-point 'symbol)))))
 235
 236 (defsubst geiser-syntax--skip-comment/string ()
 237   (let ((pos (nth 8 (syntax-ppss))))
 238     (goto-char (or pos (point)))
 239     pos))
 240
 241 (defsubst geiser-syntax--nesting-level ()
 242   (or (nth 0 (syntax-ppss)) 0))
 243
 244 (defsubst geiser-syntax--in-string-p ()
 245   (nth 3 (syntax-ppss)))
 246
 247 (defsubst geiser-syntax--pair-length (p)
 248   (if (cdr (last p)) (1+ (safe-length p)) (length p)))
 249
 250 (defun geiser-syntax--shallow-form (boundary)
 251   (when (looking-at-p "\\s(")
 252     (save-excursion
 253       (forward-char)
 254       (let ((elems))
 255         (ignore-errors
 256           (while (< (point) boundary)
 257             (skip-syntax-forward "-<>")
 258             (when (<= (point) boundary)
 259               (forward-sexp)
 260               (let ((s (thing-at-point 'symbol)))
 261                 (unless (equal "." s)
 262                   (push (car (geiser-syntax--read-from-string s)) elems))))))
 263         (nreverse elems)))))
 264
 265 (defsubst geiser-syntax--keywordp (s)
 266   (and s (symbolp s) (string-match "^:.+" (symbol-name s))))
 267
 268 (defsubst geiser-syntax--symbol-eq (s0 s1)
 269   (and (symbolp s0) (symbolp s1) (equal (symbol-name s0) (symbol-name s1))))
 270
 271 (defun geiser-syntax--scan-sexps (&optional begin)
 272   (let* ((fst (geiser-syntax--symbol-at-point))
 273          (smth (or fst (not (looking-at-p "[\s \s)\s>\s<\n]"))))
 274          (path (and fst `((,fst 0)))))
 275     (save-excursion
 276       (while (not (zerop (geiser-syntax--nesting-level)))
 277         (let ((boundary (point)))
 278           (geiser-syntax--skip-comment/string)
 279           (backward-up-list)
 280           (let ((form (geiser-syntax--shallow-form boundary)))
 281             (when (and (listp form) (car form) (symbolp (car form)))
 282               (let* ((len (geiser-syntax--pair-length form))
 283                      (pos (if smth (1- len) (progn (setq smth t) len)))
 284                      (prev (and (> pos 1) (nth (1- pos) form)))
 285                      (prev (and (geiser-syntax--keywordp prev)
 286                                 (list prev))))
 287                 (push `(,(car form) ,pos ,@prev) path)))))))
 288     (mapcar (lambda (e)
 289               (cons (substring-no-properties (format "%s" (car e))) (cdr e)))
 290             (nreverse path))))
 291
 292 (defsubst geiser-syntax--binding-form-p (bfs sbfs f)
 293   (and (symbolp f)
 294        (let ((f (symbol-name f)))
 295          (or (member f '("define" "define*" "define-syntax"
 296                          "syntax-rules" "lambda" "case-lambda"
 297                          "let" "let*" "let-values" "let*-values"
 298                          "letrec" "letrec*" "parameterize"))
 299              (member f bfs)
 300              (member f sbfs)))))
 301
 302 (defsubst geiser-syntax--binding-form*-p (sbfs f)
 303   (and (symbolp f)
 304        (let ((f (symbol-name f)))
 305          (or (member f '("let*" "let*-values" "letrec" "letrec*"))
 306              (member f sbfs)))))
 307
 308 (defsubst geiser-syntax--if-symbol (x) (and (symbolp x) x))
 309 (defsubst geiser-syntax--if-list (x) (and (listp x) x))
 310
 311 (defsubst geiser-syntax--normalize (vars)
 312   (mapcar (lambda (i)
 313             (let ((i (if (listp i) (car i) i)))
 314               (and (symbolp i) (symbol-name i))))
 315           vars))
 316
 317 (defun geiser-syntax--linearize (form)
 318   (cond ((not (listp form)) (list form))
 319         ((null form) nil)
 320         (t (cons (car form) (geiser-syntax--linearize (cdr form))))))
 321
 322 (defun geiser-syntax--scan-locals (bfs sbfs form nesting locals)
 323   (if (or (null form) (not (listp form)))
 324       (geiser-syntax--normalize locals)
 325     (if (not (geiser-syntax--binding-form-p bfs sbfs (car form)))
 326         (geiser-syntax--scan-locals bfs sbfs
 327                                     (car (last form))
 328                                     (1- nesting) locals)
 329       (let* ((head (car form))
 330              (name (geiser-syntax--if-symbol (cadr form)))
 331              (names (if name (geiser-syntax--if-list (caddr form))
 332                       (geiser-syntax--if-list (cadr form))))
 333              (bns (and name
 334                        (geiser-syntax--binding-form-p bfs sbfs (car names))))
 335              (rest (if (and name (not bns)) (cdddr form) (cddr form)))
 336              (use-names (and (or rest
 337                                  (< nesting 1)
 338                                  (geiser-syntax--binding-form*-p sbfs head))
 339                              (not bns))))
 340         (when name (push name locals))
 341         (when (geiser-syntax--symbol-eq head 'case-lambda)
 342           (dolist (n (and (> nesting 0) (caar (last form))))
 343             (when n (push n locals)))
 344           (setq rest (and (> nesting 0) (cdr form)))
 345           (setq use-names nil))
 346         (when (geiser-syntax--symbol-eq head 'syntax-rules)
 347           (dolist (n (and (> nesting 0) (cdaar (last form))))
 348             (when n (push n locals)))
 349           (setq rest (and (> nesting 0) (cdr form))))
 350         (when use-names
 351           (dolist (n (geiser-syntax--linearize names))
 352             (let ((xs (if (and (listp n) (listp (car n))) (car n) (list n))))
 353               (dolist (x xs) (when x (push x locals))))))
 354         (dolist (f (butlast rest))
 355           (when (and (listp f)
 356                      (geiser-syntax--symbol-eq (car f) 'define)
 357                      (cadr f))
 358             (push (cadr f) locals)))
 359         (geiser-syntax--scan-locals bfs sbfs
 360                                     (car (last (or rest names)))
 361                                     (1- nesting)
 362                                     locals)))))
 363
 364 (defun geiser-syntax--locals-around-point (bfs sbfs)
 365   (when (eq major-mode 'scheme-mode)
 366     (save-excursion
 367       (let ((sym (unless (geiser-syntax--skip-comment/string)
 368                    (thing-at-point 'symbol))))
 369         (skip-syntax-forward "->")
 370         (let ((boundary (point))
 371               (nesting (geiser-syntax--nesting-level)))
 372           (while (not (zerop (geiser-syntax--nesting-level)))
 373             (backward-up-list))
 374           (multiple-value-bind (form end)
 375               (geiser-syntax--form-after-point boundary)
 376             (delete sym
 377                     (geiser-syntax--scan-locals bfs
 378                                                 sbfs
 379                                                 form
 380                                                 (1- nesting)
 381                                                 '()))))))))
 382
 383 \f
 384 ;;; Fontify strings as Scheme code:
 385
 386 (defun geiser-syntax--font-lock-buffer ()
 387   (let ((name " *geiser font lock*"))
 388     (or (get-buffer name)
 389         (let ((buffer (get-buffer-create name)))
 390           (set-buffer buffer)
 391           (let ((geiser-default-implementation
 392                  (or geiser-default-implementation
 393                      (car geiser-active-implementations))))
 394             (scheme-mode))
 395           buffer))))
 396
 397 (defun geiser-syntax--scheme-str (str)
 398   (save-current-buffer
 399     (set-buffer (geiser-syntax--font-lock-buffer))
 400     (erase-buffer)
 401     (insert str)
 402     (let ((font-lock-verbose nil)) (font-lock-fontify-buffer))
 403     (buffer-string)))
 404
 405 \f
 406 (provide 'geiser-syntax)