elisp/geiser-mode.el

   1 ;; geiser-mode.el -- minor mode for scheme buffers
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:13
  11
  12 \f
  13
  14 (require 'geiser-repl)
  15 (require 'geiser-menu)
  16 (require 'geiser-doc)
  17 (require 'geiser-compile)
  18 (require 'geiser-completion)
  19 (require 'geiser-company)
  20 (require 'geiser-xref)
  21 (require 'geiser-edit)
  22 (require 'geiser-autodoc)
  23 (require 'geiser-debug)
  24 (require 'geiser-syntax)
  25 (require 'geiser-impl)
  26 (require 'geiser-eval)
  27 (require 'geiser-popup)
  28 (require 'geiser-custom)
  29 (require 'geiser-base)
  30
  31 \f
  32 ;;; Customization:
  33
  34 (defgroup geiser-mode nil
  35   "Mode enabling Geiser abilities in Scheme buffers &co.."
  36   :group 'geiser)
  37
  38 (geiser-custom--defcustom geiser-mode-auto-p t
  39   "Whether `geiser-mode' should be active by default in all
  40 scheme buffers."
  41   :group 'geiser-mode
  42   :type 'boolean)
  43
  44 (geiser-custom--defcustom geiser-mode-autodoc-p t
  45   "Whether `geiser-autodoc-mode' gets enabled by default in Scheme buffers."
  46   :group 'geiser-mode
  47   :group 'geiser-autodoc
  48   :type 'boolean)
  49
  50 (geiser-custom--defcustom geiser-mode-company-p t
  51   "Whether to use company-mode for completion, if available."
  52   :group 'geiser-mode
  53   :type 'boolean)
  54
  55 (geiser-custom--defcustom geiser-mode-smart-tab-p nil
  56   "Whether `geiser-smart-tab-mode' gets enabled by default in Scheme buffers."
  57   :group 'geiser-mode
  58   :type 'boolean)
  59
  60
  61 \f
  62 ;;; Evaluation commands:
  63
  64 (defun geiser--go-to-repl ()
  65   (switch-to-geiser nil nil (current-buffer))
  66   (push-mark)
  67   (goto-char (point-max)))
  68
  69 (defun geiser-eval-region (start end &optional and-go raw)
  70   "Eval the current region in the Geiser REPL.
  71 With prefix, goes to the REPL buffer afterwards (as
  72 `geiser-eval-region-and-go')"
  73   (interactive "rP")
  74   (save-restriction
  75     (narrow-to-region start end)
  76     (check-parens))
  77   (geiser-debug--send-region nil
  78                              start
  79                              end
  80                              (and and-go 'geiser--go-to-repl)
  81                              (not raw)))
  82
  83 (defun geiser-eval-region-and-go (start end)
  84   "Eval the current region in the Geiser REPL and visit it afterwads."
  85   (interactive "r")
  86   (geiser-eval-region start end t))
  87
  88 (defun geiser-eval-definition (&optional and-go)
  89   "Eval the current definition in the Geiser REPL.
  90 With prefix, goes to the REPL buffer afterwards (as
  91 `geiser-eval-definition-and-go')"
  92   (interactive "P")
  93   (save-excursion
  94     (end-of-defun)
  95     (let ((end (point)))
  96       (beginning-of-defun)
  97       (geiser-eval-region (point) end and-go t))))
  98
  99 (defun geiser-eval-definition-and-go ()
 100   "Eval the current definition in the Geiser REPL and visit it afterwads."
 101   (interactive)
 102   (geiser-eval-definition t))
 103
 104 (defun geiser-eval-last-sexp ()
 105   "Eval the previous sexp in the Geiser REPL."
 106   (interactive)
 107   (geiser-eval-region (save-excursion (backward-sexp) (point))
 108                       (point)
 109                       nil
 110                       t))
 111
 112 (defun geiser-compile-definition (&optional and-go)
 113   "Compile the current definition in the Geiser REPL.
 114 With prefix, goes to the REPL buffer afterwards (as
 115 `geiser-eval-definition-and-go')"
 116   (interactive "P")
 117   (save-excursion
 118     (end-of-defun)
 119     (let ((end (point)))
 120       (beginning-of-defun)
 121       (geiser-debug--send-region t
 122                                  (point)
 123                                  end
 124                                  (and and-go 'geiser--go-to-repl)
 125                                  t))))
 126
 127 (defun geiser-compile-definition-and-go ()
 128   "Compile the current definition in the Geiser REPL and visit it afterwads."
 129   (interactive)
 130   (geiser-compile-definition t))
 131
 132 (defun geiser-expand-region (start end &optional all raw)
 133   "Macro-expand the current region and display it in a buffer.
 134 With prefix, recursively macro-expand the resulting expression."
 135   (interactive "rP")
 136   (geiser-debug--expand-region start end all (not raw)))
 137
 138 (defun geiser-expand-definition (&optional all)
 139   "Macro-expand the current definition.
 140 With prefix, recursively macro-expand the resulting expression."
 141   (interactive "P")
 142   (save-excursion
 143     (end-of-defun)
 144     (let ((end (point)))
 145       (beginning-of-defun)
 146       (geiser-expand-region (point) end all t))))
 147
 148 (defun geiser-expand-last-sexp (&optional all)
 149   "Macro-expand the previous sexp.
 150 With prefix, recursively macro-expand the resulting expression."
 151   (interactive "P")
 152   (geiser-expand-region (save-excursion (backward-sexp) (point))
 153                         (point)
 154                         all
 155                         t))
 156
 157 (defun geiser-set-scheme ()
 158   "Associates current buffer with a given Scheme implementation."
 159   (interactive)
 160   (let ((impl (geiser-impl--read-impl)))
 161     (geiser-impl--set-buffer-implementation impl)
 162     (geiser-repl--set-up-repl impl)))
 163
 164 (defun geiser-mode-switch-to-repl (arg)
 165   "Switches to Geiser REPL.
 166 With prefix, try to enter the current buffer's module."
 167   (interactive "P")
 168   (if arg
 169       (switch-to-geiser-module (geiser-eval--get-module) (current-buffer))
 170     (switch-to-geiser nil nil (current-buffer))))
 171
 172 (defun geiser-mode-switch-to-repl-and-enter ()
 173   "Switches to Geiser REPL and enters current buffer's module."
 174   (interactive)
 175   (geiser-mode-switch-to-repl t))
 176
 177 (defun geiser-restart-repl ()
 178   "Restarts the REPL associated with the current buffer."
 179   (interactive)
 180   (let ((b (current-buffer)))
 181     (geiser-mode-switch-to-repl nil)
 182     (comint-kill-subjob)
 183     (sit-for 0.1) ;; ugly hack; but i don't care enough to fix it
 184     (call-interactively 'run-geiser)
 185     (sit-for 0.2) ;; ditto
 186     (goto-char (point-max))
 187     (pop-to-buffer b)))
 188
 189 (defun geiser-squarify (n)
 190   "Toggle between () and [] for current form.
 191 With numeric prefix, perform that many toggles, forward for
 192 positive values and backward for negative."
 193   (interactive "p")
 194   (let ((pared (and (boundp 'paredit-mode) paredit-mode))
 195         (fwd (> n 0))
 196         (steps (abs n)))
 197     (when (and pared (fboundp 'paredit-mode)) (paredit-mode -1))
 198     (unwind-protect
 199         (save-excursion
 200           (unless (looking-at-p "\\s(") (backward-up-list))
 201           (while (> steps 0)
 202             (let ((p (point))
 203                   (round (looking-at-p "(")))
 204               (forward-sexp)
 205               (backward-delete-char 1)
 206               (insert (if round "]" ")"))
 207               (goto-char p)
 208               (delete-char 1)
 209               (insert (if round "[" "("))
 210               (setq steps (1- steps))
 211               (backward-char)
 212               (condition-case nil
 213                   (progn (when fwd (forward-sexp 2))
 214                          (backward-sexp))
 215                 (error (setq steps 0))))))
 216       (when (and pared (fboundp 'paredit-mode)) (paredit-mode 1)))))
 217
 218 \f
 219 ;;; Geiser mode:
 220
 221 (make-variable-buffer-local
 222  (defvar geiser-mode-string nil
 223    "Modeline indicator for geiser-mode"))
 224
 225 (defun geiser-mode--lighter ()
 226   (or geiser-mode-string
 227       (format " %s" (or (geiser-impl--impl-str) "G"))))
 228
 229 (defvar geiser-mode-map (make-sparse-keymap))
 230
 231 (define-minor-mode geiser-mode
 232   "Toggle Geiser's mode.
 233 With no argument, this command toggles the mode.
 234 Non-null prefix argument turns on the mode.
 235 Null prefix argument turns off the mode.
 236
 237 When Geiser mode is enabled, a host of nice utilities for
 238 interacting with the Geiser REPL is at your disposal.
 239 \\{geiser-mode-map}"
 240   :init-value nil
 241   :lighter (:eval (geiser-mode--lighter))
 242   :group 'geiser-mode
 243   :keymap geiser-mode-map
 244   (when geiser-mode (geiser-impl--set-buffer-implementation nil t))
 245   (setq geiser-autodoc-mode-string "/A")
 246   (setq geiser-smart-tab-mode-string "/T")
 247   (geiser-company--setup (and geiser-mode geiser-mode-company-p))
 248   (geiser-completion--setup geiser-mode)
 249   (when geiser-mode-autodoc-p
 250     (geiser-autodoc-mode (if geiser-mode 1 -1)))
 251   (when geiser-mode-smart-tab-p
 252     (geiser-smart-tab-mode (if geiser-mode 1 -1)))
 253   (geiser-syntax--add-kws))
 254
 255 (defun turn-on-geiser-mode ()
 256   "Enable `geiser-mode' (in a Scheme buffer)."
 257   (interactive)
 258   (geiser-mode 1))
 259
 260 (defun turn-off-geiser-mode ()
 261   "Disable `geiser-mode' (in a Scheme buffer)."
 262   (interactive)
 263   (geiser-mode -1))
 264
 265 (defun geiser-mode--maybe-activate ()
 266   (when geiser-mode-auto-p (turn-on-geiser-mode)))
 267
 268 \f
 269 ;;; Keys:
 270
 271 (geiser-menu--defmenu geiserm geiser-mode-map
 272   ("Eval sexp before point" "\C-x\C-e" geiser-eval-last-sexp)
 273   ("Eval definition" "\M-\C-x" geiser-eval-definition)
 274   ("Eval definition and go" "\C-c\M-e" geiser-eval-definition-and-go)
 275   ("Eval region" "\C-c\C-r" geiser-eval-region :enable mark-active)
 276   ("Eval region and go" "\C-c\M-r" geiser-eval-region-and-go
 277    geiser-eval-region :enable mark-active)
 278 ;;  ("Compile definition" "\C-c\M-c" geiser-compile-definition)
 279 ;;  ("Compile definition and go" "\C-c\C-c" geiser-compile-definition-and-go)
 280   (menu "Macroexpand"
 281         ("Sexp before point" ("\C-c\C-m\C-e" "\C-c\C-me")
 282          geiser-expand-last-sexp)
 283         ("Region" ("\C-c\C-m\C-r" "\C-c\C-mr") geiser-expand-region)
 284         ("Definition" ("\C-c\C-m\C-x" "\C-c\C-mx") geiser-expand-definition))
 285   --
 286   ("Symbol documentation" ("\C-c\C-d\C-d" "\C-c\C-dd")
 287    geiser-doc-symbol-at-point :enable (geiser--symbol-at-point))
 288   ("Short symbol documentation" ("\C-c\C-d\C-s" "\C-c\C-ds")
 289    geiser-autodoc-show :enable (geiser--symbol-at-point))
 290   ("Module documentation" ("\C-c\C-d\C-m" "\C-c\C-dm") geiser-doc-module)
 291   ("Symbol manual lookup" ("\C-c\C-d\C-i" "\C-c\C-di")
 292    geiser-doc-look-up-manual :enable (geiser-doc--manual-available-p))
 293   (mode "Autodoc mode" ("\C-c\C-d\C-a" "\C-c\C-da") geiser-autodoc-mode)
 294   --
 295   ("Compile buffer" "\C-c\C-k" geiser-compile-current-buffer)
 296   ("Switch to REPL" "\C-c\C-z" geiser-mode-switch-to-repl)
 297   ("Switch to REPL and enter module" "\C-c\C-a"
 298    geiser-mode-switch-to-repl-and-enter)
 299   ("Set Scheme..." "\C-c\C-s" geiser-set-scheme)
 300   --
 301   ("Edit symbol at point" "\M-." geiser-edit-symbol-at-point
 302    :enable (geiser--symbol-at-point))
 303   ("Go to previous definition" "\M-," geiser-pop-symbol-stack)
 304   ("Complete symbol" ((kbd "M-TAB")) completion-at-point
 305    :enable (geiser--symbol-at-point))
 306   ("Complete module name" ((kbd "M-`") (kbd "C-."))
 307    geiser-completion--complete-module)
 308   ("Edit module" ("\C-c\C-e\C-m" "\C-c\C-em") geiser-edit-module)
 309   ("Add to load path..." ("\C-c\C-e\C-l" "\C-c\C-el") geiser-add-to-load-path)
 310   ("Toggle ()/[]" ("\C-c\C-e\C-[" "\C-c\C-e[") geiser-squarify)
 311   --
 312   ("Callers" ((kbd "C-c <")) geiser-xref-callers
 313    :enable (and (geiser-eval--supported-p 'callers)
 314                 (geiser--symbol-at-point)))
 315   ("Callees" ((kbd "C-c >")) geiser-xref-callees
 316    :enable (and (geiser-eval--supported-p 'callees)
 317                 (geiser--symbol-at-point)))
 318   --
 319   (mode "Smart TAB mode" nil geiser-smart-tab-mode)
 320   --
 321   (custom "Customize Geiser mode" geiser-mode))
 322
 323 (define-key geiser-mode-map [menu-bar scheme] 'undefined)
 324
 325 ;; (geiser-mode--triple-chord ?x ?m 'geiser-xref-generic-methods)
 326
 327 \f
 328 ;;; Reload support:
 329
 330 (defun geiser-mode--buffers ()
 331   (let ((buffers))
 332     (dolist (buffer (buffer-list))
 333       (when (buffer-live-p buffer)
 334         (set-buffer buffer)
 335         (when geiser-mode
 336           (push (cons buffer geiser-impl--implementation) buffers))))
 337     buffers))
 338
 339 (defun geiser-mode--restore (buffers)
 340   (dolist (b buffers)
 341     (when (buffer-live-p (car b))
 342       (set-buffer (car b))
 343       (when (cdr b)
 344         (geiser-impl--set-buffer-implementation (cdr b)))
 345       (geiser-mode 1))))
 346
 347 (defun geiser-mode-unload-function ()
 348   (dolist (b (geiser-mode--buffers))
 349     (with-current-buffer (car b) (geiser-mode nil))))
 350
 351 \f
 352 (provide 'geiser-mode)