elisp/geiser-log.el

   1 ;; geiser-log.el -- logging utilities
   2
   3 ;; Copyright (C) 2009, 2010, 2012 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sat Feb 07, 2009 12:07
  11
  12 \f
  13
  14 ;; Some utilities for maintaining a simple log buffer, mainly for
  15 ;; debugging purposes.
  16
  17 (require 'geiser-popup)
  18 (require 'geiser-base)
  19
  20 (require 'comint)
  21
  22 \f
  23 ;;; Customization:
  24
  25 (defvar geiser-log--buffer-name "*geiser messages*"
  26   "Name of the Geiser log buffer.")
  27
  28 (defvar geiser-log--max-buffer-size 32000
  29   "Maximum size of the Geiser messages log.")
  30
  31 (defvar geiser-log--max-message-size 2048
  32   "Maximum size of individual Geiser log messages.")
  33
  34 (defvar geiser-log-verbose-p nil
  35   "Log purely informational messages. Useful for debugging.")
  36
  37 (defvar geiser-log--inhibit-p nil
  38   "Set this to t to inhibit all log messages")
  39
  40 \f
  41 ;;; Log buffer and mode:
  42
  43 (define-derived-mode geiser-messages-mode fundamental-mode "Geiser Messages"
  44   "Simple mode for Geiser log messages buffer."
  45   (buffer-disable-undo)
  46   (add-hook 'after-change-functions
  47             '(lambda (b e len)
  48                (let ((inhibit-read-only t))
  49                  (when (> b geiser-log--max-buffer-size)
  50                    (delete-region (point-min) b))))
  51             nil t)
  52   (setq buffer-read-only t))
  53
  54 (geiser-popup--define log geiser-log--buffer-name geiser-messages-mode)
  55
  56 \f
  57 ;;; Logging functions:
  58
  59 (defun geiser-log--msg (type &rest args)
  60   (unless geiser-log--inhibit-p
  61     (geiser-log--with-buffer
  62       (goto-char (point-max))
  63       (insert (geiser--shorten-str (format "\n%s: %s\n" type
  64                                            (apply 'format args))
  65                                    geiser-log--max-message-size)))))
  66
  67 (defsubst geiser-log--warn (&rest args)
  68   (apply 'geiser-log--msg 'WARNING args))
  69
  70 (defsubst geiser-log--error (&rest args)
  71   (apply 'geiser-log--msg 'ERROR args))
  72
  73 (defsubst geiser-log--info (&rest args)
  74   (when geiser-log-verbose-p
  75     (apply 'geiser-log--msg 'INFO args) ""))
  76
  77 \f
  78 ;;; User commands:
  79
  80 (defun geiser-show-logs (&optional arg)
  81   "Show Geiser log messages.
  82 With prefix, activates all logging levels."
  83   (interactive "P")
  84   (when arg (setq geiser-log-verbose-p t))
  85   (geiser-log--pop-to-buffer))
  86
  87 (defun geiser-log-clear ()
  88   "Clean all logs."
  89   (interactive)
  90   (geiser-log--with-buffer (delete-region (point-min) (point-max))))
  91
  92 (defun geiser-log-toggle-verbose ()
  93   "Toggle verbose logs"
  94   (interactive)
  95   (setq geiser-log-verbose-p (not geiser-log-verbose-p))
  96   (message "Geiser verbose logs %s"
  97            (if geiser-log-verbose-p "enabled" "disabled")))
  98
  99 (defun geiser-log--deactivate ()
 100   (interactive)
 101   (setq geiser-log-verbose-p nil)
 102   (when (eq (current-buffer) (geiser-log--buffer)) (View-quit)))
 103
 104 (define-key geiser-messages-mode-map "c" 'geiser-log-clear)
 105 (define-key geiser-messages-mode-map "Q" 'geiser-log--deactivate)
 106
 107 \f
 108 (provide 'geiser-log)