elisp/geiser-autodoc.el

   1 ;; geiser-autodoc.el -- autodoc mode
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 19:44
  11
  12 \f
  13
  14 (require 'geiser-eval)
  15 (require 'geiser-syntax)
  16 (require 'geiser-custom)
  17 (require 'geiser-base)
  18
  19 (require 'eldoc)
  20
  21 \f
  22 ;;; Customization:
  23
  24 (defgroup geiser-autodoc nil
  25   "Options for displaying autodoc strings in the echo area."
  26   :group 'geiser)
  27
  28 (geiser-custom--defface autodoc-current-arg
  29   'bold geiser-autodoc "highlighting current argument in autodoc messages")
  30
  31 (geiser-custom--defface autodoc-identifier
  32   'font-lock-function-name-face
  33   geiser-autodoc "highlighting procedure name in autodoc messages")
  34
  35 (geiser-custom--defcustom geiser-autodoc-delay 0.3
  36   "Delay before autodoc messages are fetched and displayed, in seconds."
  37   :type 'number
  38   :group 'geiser-autodoc)
  39
  40 (geiser-custom--defcustom geiser-autodoc-display-module-p t
  41   "Whether to display procedure module in autodoc strings."
  42   :type 'boolean
  43   :group 'geiser-autodoc)
  44
  45 (geiser-custom--defcustom geiser-autodoc-identifier-format "%s:%s"
  46   "Format for displaying module and procedure or variable name, in that order,
  47 when `geiser-autodoc-display-module-p' is on."
  48   :type 'string
  49   :group 'geiser-autodoc)
  50
  51 \f
  52 ;;; Procedure arguments:
  53
  54 (make-variable-buffer-local
  55  (defvar geiser-autodoc--cached-signatures nil))
  56
  57 (defsubst geiser-autodoc--clean-cache ()
  58   (setq geiser-autodoc--cached-signatures nil))
  59
  60 (defun geiser-autodoc--show-signatures (ret)
  61   (let ((res (geiser-eval--retort-result ret))
  62         (signs))
  63     (when res
  64       (dolist (item res)
  65         (push (cons (format "%s" (car item)) (cdr item)) signs))
  66       (let ((str (geiser-autodoc--autodoc (geiser-syntax--scan-sexps) signs)))
  67         (when (not (string-equal str eldoc-last-message))
  68           (eldoc-message str)))
  69       (setq geiser-autodoc--cached-signatures signs))))
  70
  71 (defun geiser-autodoc--get-signatures (funs)
  72   (when funs
  73     (let ((m (format "'(%s)" (mapconcat 'identity funs " "))))
  74       (geiser-eval--send `(:eval (:ge autodoc (:scm ,m)))
  75                          'geiser-autodoc--show-signatures)))
  76   (and (or (assoc (car funs) geiser-autodoc--cached-signatures)
  77            (assoc (cadr funs) geiser-autodoc--cached-signatures))
  78        geiser-autodoc--cached-signatures))
  79
  80 (defun geiser-autodoc--sanitize-args (args)
  81   (cond ((null args) nil)
  82         ((listp args)
  83          (cons (car args) (geiser-autodoc--sanitize-args (cdr args))))
  84         (t '("..."))))
  85
  86 (defun geiser-autodoc--format-arg (a)
  87   (cond ((and (listp a) (geiser-syntax--keywordp (car a)))
  88          (if (and (cdr a) (listp (cdr a)))
  89              (format "(#%s %s)" (car a) (geiser-syntax--display (cadr a)))
  90            (format "(#%s)" (car a))))
  91         (t (geiser-syntax--display a))))
  92
  93 (defun geiser-autodoc--insert-arg-group (args current &optional pos)
  94   (when args (insert " "))
  95   (dolist (a (geiser-autodoc--sanitize-args args))
  96     (let ((p (point)))
  97       (insert (geiser-autodoc--format-arg a))
  98       (when (or (and (numberp pos)
  99                      (numberp current)
 100                      (setq current (1+ current))
 101                      (= (1+ pos) current))
 102                 (and (geiser-syntax--keywordp current)
 103                      (listp a)
 104                      (geiser-syntax--symbol-eq current (car a))))
 105         (put-text-property p (point)
 106                            'face 'geiser-font-lock-autodoc-current-arg)
 107         (setq pos nil current nil)))
 108     (insert " "))
 109   (when args (backward-char))
 110   current)
 111
 112 (defun geiser-autodoc--insert-args (args pos prev)
 113   (let ((cpos 1)
 114         (reqs (cdr (assoc "required" args)))
 115         (opts (mapcar (lambda (a)
 116                         (if (and (symbolp a)
 117                                  (not (equal (symbol-name a) "...")))
 118                             (list a)
 119                           a))
 120                       (cdr (assoc "optional" args))))
 121         (keys (cdr (assoc "key" args))))
 122     (setq cpos
 123           (geiser-autodoc--insert-arg-group reqs
 124                                             cpos
 125                                             (and (not (zerop pos)) pos)))
 126     (setq cpos (geiser-autodoc--insert-arg-group opts cpos pos))
 127     (geiser-autodoc--insert-arg-group keys prev nil)))
 128
 129 (defsubst geiser-autodoc--id-name (proc module)
 130   (let ((str (if module
 131                  (format geiser-autodoc-identifier-format module proc)
 132                (format "%s" proc))))
 133     (propertize str 'face 'geiser-font-lock-autodoc-identifier)))
 134
 135 (defun geiser-autodoc--str* (full-signature)
 136   (let ((geiser-font-lock-autodoc-current-arg 'default))
 137     (geiser-autodoc--str (list (car full-signature)) full-signature)))
 138
 139 (defsubst geiser-autodoc--value-str (proc module value)
 140   (let ((name (geiser-autodoc--id-name proc module)))
 141     (if value (format "%s => %s" name value) name)))
 142
 143 (defun geiser-autodoc--str (desc signature)
 144   (let ((proc (car desc))
 145         (args (cdr (assoc "args" signature)))
 146         (module (cdr (assoc "module" signature))))
 147     (if (not args)
 148       (geiser-autodoc--value-str proc module (cdr (assoc "value" signature)))
 149       (save-current-buffer
 150         (set-buffer (geiser-syntax--font-lock-buffer))
 151         (erase-buffer)
 152         (insert (format "(%s" (geiser-autodoc--id-name proc module)))
 153         (let ((pos (or (cadr desc) 0))
 154               (prev (car (cddr desc))))
 155           (dolist (a args)
 156             (when (not (member a (cdr (member a args))))
 157               (geiser-autodoc--insert-args a pos prev)
 158               (insert " |"))))
 159         (delete-char -2)
 160         (insert ")")
 161         (buffer-substring (point-min) (point))))))
 162
 163 (defun geiser-autodoc--autodoc (path &optional signs)
 164   (let ((signs (or signs (geiser-autodoc--get-signatures (mapcar 'car path))))
 165         (p (car path))
 166         (s))
 167     (while (and p (not s))
 168       (unless (setq s (cdr (assoc (car p) signs)))
 169         (setq p (car path))
 170         (setq path (cdr path))))
 171     (when s (geiser-autodoc--str p s))))
 172
 173 \f
 174 ;;; Autodoc functions:
 175
 176 (make-variable-buffer-local
 177  (defvar geiser-autodoc--inhibit-function nil))
 178
 179 (defsubst geiser-autodoc--inhibit ()
 180   (and geiser-autodoc--inhibit-function
 181        (funcall geiser-autodoc--inhibit-function)))
 182
 183 (defsubst geiser-autodoc--inhibit-autodoc ()
 184   (setq geiser-autodoc--inhibit-function (lambda () t)))
 185
 186 (defsubst geiser-autodoc--disinhibit-autodoc ()
 187   (setq geiser-autodoc--inhibit-function nil))
 188
 189 (defsubst geiser-autodoc--autodoc-at-point ()
 190   (geiser-autodoc--autodoc (geiser-syntax--scan-sexps)))
 191
 192 (defun geiser-autodoc--eldoc-function ()
 193   (condition-case e
 194       (and (not (geiser-autodoc--inhibit)) (geiser-autodoc--autodoc-at-point))
 195     (error (format "Autodoc not available (%s)" (error-message-string e)))))
 196
 197 (defun geiser-autodoc-show ()
 198   "Show the signature or value of the symbol at point in the echo area."
 199   (interactive)
 200   (message (geiser-autodoc--autodoc-at-point)))
 201
 202 \f
 203 ;;; Autodoc mode:
 204
 205 (make-variable-buffer-local
 206  (defvar geiser-autodoc-mode-string " A"
 207    "Modeline indicator for geiser-autodoc-mode"))
 208
 209 (define-minor-mode geiser-autodoc-mode
 210   "Toggle Geiser's Autodoc mode.
 211 With no argument, this command toggles the mode.
 212 Non-null prefix argument turns on the mode.
 213 Null prefix argument turns off the mode.
 214
 215 When Autodoc mode is enabled, a synopsis of the word at point is
 216 displayed in the minibuffer."
 217   :init-value nil
 218   :lighter geiser-autodoc-mode-string
 219   :group 'geiser-autodoc
 220
 221   (set (make-local-variable 'eldoc-documentation-function)
 222        (when geiser-autodoc-mode 'geiser-autodoc--eldoc-function))
 223   (set (make-local-variable 'eldoc-minor-mode-string) nil)
 224   (set (make-local-variable 'eldoc-idle-delay) geiser-autodoc-delay)
 225   (eldoc-mode (if geiser-autodoc-mode 1 -1))
 226   (when (called-interactively-p nil)
 227     (message "Geiser Autodoc %s"
 228              (if geiser-autodoc-mode "enabled" "disabled"))))
 229
 230 (defadvice eldoc-display-message-no-interference-p
 231   (after geiser-autodoc--message-ok-p)
 232   (when geiser-autodoc-mode
 233     (setq ad-return-value
 234           (and ad-return-value
 235                ;; Display arglist only when the minibuffer is
 236                ;; inactive, e.g. not on `C-x C-f'. Lifted from slime.
 237                (not (active-minibuffer-window)))))
 238   ad-return-value)
 239
 240
 241 \f
 242 (provide 'geiser-autodoc)