elisp/geiser-debug.el

   1 ;;; geiser-debug.el -- displaying debug information and evaluation results
   2
   3 ;; Copyright (C) 2009, 2010 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Mon Feb 23, 2009 22:34
  11
  12 \f
  13
  14 (require 'geiser-edit)
  15 (require 'geiser-autodoc)
  16 (require 'geiser-impl)
  17 (require 'geiser-eval)
  18 (require 'geiser-menu)
  19 (require 'geiser-popup)
  20 (require 'geiser-base)
  21
  22 \f
  23 ;;; Customization:
  24
  25 (defgroup geiser-debug nil
  26   "Debugging and error display options."
  27   :group 'geiser)
  28
  29 (geiser-custom--defcustom geiser-debug-always-display-sexp-after-p nil
  30   "Whether to always display the sexp whose evaluation caused an
  31 error after the error message in the debug pop-up. If nil,
  32 expressions shorter than `geiser-debug-long-sexp-lines` lines are
  33 show before the error message."
  34   :group 'geiser-debug
  35   :type 'boolean)
  36
  37 (geiser-custom--defcustom geiser-debug-long-sexp-lines 6
  38   "Length of an expression in order to be relegated to the bottom
  39 of the debug pop-up (after the error message). If
  40 `geiser-debug-always-display-sexp-after-p` is t, this variable
  41 has no effect."
  42   :group 'geiser-debug
  43   :type 'int)
  44
  45 \f
  46 ;;; Debug buffer mode:
  47
  48 (defvar geiser-debug-mode-map
  49   (let ((map (make-sparse-keymap)))
  50     (suppress-keymap map)
  51     (set-keymap-parent map button-buffer-map)
  52     map))
  53
  54 (defun geiser-debug-mode ()
  55   "A major mode for displaying Scheme compilation and evaluation results.
  56 \\{geiser-debug-mode-map}"
  57   (interactive)
  58   (kill-all-local-variables)
  59   (buffer-disable-undo)
  60   (use-local-map geiser-debug-mode-map)
  61   (set-syntax-table scheme-mode-syntax-table)
  62   (setq mode-name "Geiser DBG")
  63   (setq major-mode 'geiser-debug-mode)
  64   (setq next-error-function 'geiser-edit--open-next)
  65   (setq buffer-read-only t))
  66
  67 (defun geiser-debug--button-p (nextp)
  68   (let ((m (funcall (if nextp 'next-button 'previous-button) (point))))
  69     (and m (funcall (if nextp '< '>) (point) (marker-position m)))))
  70
  71 (geiser-menu--defmenu debug geiser-debug-mode-map
  72   ("Next error" "n" forward-button :enable (geiser-debug--button-p t))
  73   ("Previous error" "p" backward-button :enable (geiser-debug--button-p t))
  74   --
  75   ("Quit" nil View-quit))
  76
  77 \f
  78 ;;; Buffer for displaying evaluation results:
  79
  80 (geiser-popup--define debug "*Geiser dbg*" geiser-debug-mode)
  81
  82 \f
  83 ;;; Displaying retorts
  84
  85 (geiser-impl--define-caller geiser-debug--display-error
  86     display-error (module key message)
  87     "This method takes 3 parameters (a module name, the error key,
  88 and the accompanying error message) and should display
  89 (in the current buffer) a formatted version of the error. If the
  90 error was successfully displayed, the call should evaluate to a
  91 non-null value.")
  92
  93 (geiser-impl--define-caller geiser-debug--enter-debugger
  94     enter-debugger ()
  95   "This method is called upon entering the debugger, in the REPL
  96 buffer.")
  97
  98 (defun geiser-debug--display-after (what)
  99   (or geiser-debug-always-display-sexp-after-p
 100       (>= (with-temp-buffer
 101             (insert what)
 102             (count-lines (point-min) (point-max)))
 103           geiser-debug-long-sexp-lines)))
 104
 105 (defun geiser-debug--display-retort (what ret &optional res)
 106   (let* ((err (geiser-eval--retort-error ret))
 107          (key (geiser-eval--error-key err))
 108          (output (geiser-eval--retort-output ret))
 109          (impl geiser-impl--implementation)
 110          (module (geiser-eval--get-module))
 111          (jump nil)
 112          (dir default-directory)
 113          (buffer (current-buffer))
 114          (debug (eq key 'geiser-debugger))
 115          (after (geiser-debug--display-after what)))
 116     (when debug
 117       (switch-to-geiser nil nil buffer)
 118       (geiser-debug--enter-debugger impl))
 119     (geiser-debug--with-buffer
 120       (erase-buffer)
 121       (when dir (setq default-directory dir))
 122       (unless after
 123         (insert what)
 124         (newline 2))
 125       (when (and res (not err))
 126         (insert res)
 127         (newline 2))
 128       (setq jump (geiser-debug--display-error impl module key output))
 129       (when after
 130         (goto-char (point-max))
 131         (insert "\nExpression evaluated was:\n\n" what))
 132       (goto-char (point-min)))
 133     (when jump (geiser-debug--pop-to-buffer))))
 134
 135 (defsubst geiser-debug--wrap-region (str)
 136   (format "(begin %s)" str))
 137
 138 (defun geiser-debug--unwrap (str)
 139   (if (string-match "(begin[ \t\n\v\r]+\\(.+\\)*)" str)
 140       (match-string 1 str)
 141     str))
 142
 143 (defun geiser-debug--send-region (compile start end and-go wrap)
 144   (let* ((str (buffer-substring-no-properties start end))
 145          (wrapped (if wrap (geiser-debug--wrap-region str) str))
 146          (code `(,(if compile :comp :eval) (:scm ,wrapped)))
 147          (ret (geiser-eval--send/wait code))
 148          (res (geiser-eval--retort-result-str ret))
 149          (err (geiser-eval--retort-error ret)))
 150     (when and-go (funcall and-go))
 151     (when (not err)
 152       (save-excursion
 153         (goto-char (/ (+ end start) 2))
 154         (geiser-autodoc--clean-cache))
 155       (message "%s" res))
 156     (geiser-debug--display-retort (geiser-syntax--scheme-str str) ret res)))
 157
 158 (defun geiser-debug--expand-region (start end all wrap)
 159   (let* ((str (buffer-substring-no-properties start end))
 160          (wrapped (if wrap (geiser-debug--wrap-region str) str))
 161          (code `(:eval (:ge macroexpand (quote (:scm ,wrapped))
 162                             ,(if all :t :f))))
 163          (ret (geiser-eval--send/wait code))
 164          (err (geiser-eval--retort-error ret))
 165          (result (geiser-eval--retort-result ret)))
 166     (if err
 167         (geiser-debug--display-retort str ret)
 168       (geiser-debug--with-buffer
 169         (erase-buffer)
 170         (insert (format "%s" (if wrap (geiser-debug--unwrap result) result)))
 171         (goto-char (point-min)))
 172       (geiser-debug--pop-to-buffer))))
 173
 174 \f
 175 (provide 'geiser-debug)
 176 ;;; geiser-debug.el ends here