elisp/geiser-debug.el

   1 ;;; geiser-debug.el -- displaying debug information and evaluation results
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Mon Feb 23, 2009 22:34
  11
  12 \f
  13
  14 (require 'geiser-edit)
  15 (require 'geiser-autodoc)
  16 (require 'geiser-impl)
  17 (require 'geiser-eval)
  18 (require 'geiser-menu)
  19 (require 'geiser-popup)
  20 (require 'geiser-base)
  21 (require 'geiser-image)
  22
  23 \f
  24 ;;; Customization:
  25
  26 (defgroup geiser-debug nil
  27   "Debugging and error display options."
  28   :group 'geiser)
  29
  30 (geiser-custom--defcustom geiser-debug-always-display-sexp-after-p nil
  31   "Whether to always display the sexp whose evaluation caused an
  32 error after the error message in the debug pop-up. If nil,
  33 expressions shorter than `geiser-debug-long-sexp-lines` lines are
  34 show before the error message."
  35   :group 'geiser-debug
  36   :type 'boolean)
  37
  38 (geiser-custom--defcustom geiser-debug-long-sexp-lines 6
  39   "Length of an expression in order to be relegated to the bottom
  40 of the debug pop-up (after the error message). If
  41 `geiser-debug-always-display-sexp-after-p` is t, this variable
  42 has no effect."
  43   :group 'geiser-debug
  44   :type 'int)
  45
  46 (geiser-custom--defcustom geiser-debug-jump-to-debug-p t
  47   "When set to t (the default), jump to the debug pop-up buffer
  48   in case of evaluation errors.
  49
  50 See also `geiser-debug-show-debug-p`. "
  51   :group 'geiser-debug
  52   :type 'boolean)
  53
  54 (geiser-custom--defcustom geiser-debug-show-debug-p t
  55   "When set to t (the default), show the debug pop-up buffer in
  56   case of evaluation errors.
  57
  58 This option takes effect even if `geiser-debug-jump-to-debug-p`
  59 is set."
  60   :group 'geiser-debug
  61   :type 'boolean)
  62
  63 (geiser-custom--defcustom geiser-debug-auto-display-images-p t
  64   "Whether to automatically invoke the external viewer to display
  65 images when they're evaluated.
  66
  67 See also `geiser-repl-auto-display-images-p'."
  68   :group 'geiser-debug
  69   :type 'boolean)
  70
  71 \f
  72 ;;; Debug buffer mode:
  73
  74 (defvar geiser-debug-mode-map
  75   (let ((map (make-sparse-keymap)))
  76     (suppress-keymap map)
  77     (set-keymap-parent map button-buffer-map)
  78     map)
  79   "Keymap for `geiser-debug-mode'.")
  80
  81 (define-derived-mode geiser-debug-mode nil "Geiser DBG"
  82   "A major mode for displaying Scheme compilation and evaluation results.
  83 \\{geiser-debug-mode-map}"
  84   (buffer-disable-undo)
  85   (set-syntax-table scheme-mode-syntax-table)
  86   (setq next-error-function 'geiser-edit--open-next)
  87   (setq buffer-read-only t))
  88
  89 (defun geiser-debug--button-p (nextp)
  90   (let ((m (funcall (if nextp 'next-button 'previous-button) (point))))
  91     (and m (funcall (if nextp '< '>) (point) (marker-position m)))))
  92
  93 (geiser-menu--defmenu debug geiser-debug-mode-map
  94   ("Next error" "n" forward-button :enable (geiser-debug--button-p t))
  95   ("Previous error" "p" backward-button :enable (geiser-debug--button-p t))
  96   --
  97   ("Quit" nil View-quit))
  98
  99 \f
 100 ;;; Buffer for displaying evaluation results:
 101
 102 (geiser-popup--define debug "*Geiser dbg*" geiser-debug-mode)
 103
 104 \f
 105 ;;; Displaying retorts
 106
 107 (geiser-impl--define-caller geiser-debug--display-error
 108     display-error (module key message)
 109     "This method takes 3 parameters (a module name, the error key,
 110 and the accompanying error message) and should display
 111 (in the current buffer) a formatted version of the error. If the
 112 error was successfully displayed, the call should evaluate to a
 113 non-null value.")
 114
 115 (geiser-impl--define-caller geiser-debug--enter-debugger
 116     enter-debugger ()
 117   "This method is called upon entering the debugger, in the REPL
 118 buffer.")
 119
 120 (defun geiser-debug--display-after (what)
 121   (or geiser-debug-always-display-sexp-after-p
 122       (>= (with-temp-buffer
 123             (insert what)
 124             (count-lines (point-min) (point-max)))
 125           geiser-debug-long-sexp-lines)))
 126
 127 (defun geiser-debug--insert-res (res)
 128   (let ((begin (point)))
 129     (insert res)
 130     (let ((end (point)))
 131       (goto-char begin)
 132       (let ((no (geiser-image--replace-images
 133                  t geiser-debug-auto-display-images-p)))
 134         (goto-char end)
 135         (newline 2)
 136         (and no (> no 0))))))
 137
 138 (defun geiser-debug--display-retort (what ret &optional res auto-p)
 139   (let* ((err (geiser-eval--retort-error ret))
 140          (key (geiser-eval--error-key err))
 141          (output (geiser-eval--retort-output ret))
 142          (impl geiser-impl--implementation)
 143          (module (geiser-eval--get-module))
 144          (dbg nil)
 145          (img nil)
 146          (dir default-directory)
 147          (buffer (current-buffer))
 148          (debug (eq key 'geiser-debugger))
 149          (after (geiser-debug--display-after what)))
 150     (when debug
 151       (switch-to-geiser nil nil buffer)
 152       (geiser-debug--enter-debugger impl))
 153     (geiser-debug--with-buffer
 154       (erase-buffer)
 155       (when dir (setq default-directory dir))
 156       (unless after
 157         (geiser-debug--display-error impl module nil what)
 158         (goto-char (point-max))
 159         (newline 2))
 160       (setq img (when (and res (not err)) (geiser-debug--insert-res res)))
 161       (setq dbg (geiser-debug--display-error impl module key output))
 162       (when after
 163         (goto-char (point-max))
 164         (insert "\nExpression evaluated was:\n\n")
 165         (geiser-debug--display-error impl module nil what))
 166       (goto-char (point-min)))
 167     (when (or img dbg)
 168       (when (or geiser-debug-jump-to-debug-p geiser-debug-show-debug-p)
 169         (if geiser-debug-jump-to-debug-p
 170             (geiser-debug--pop-to-buffer)
 171           (display-buffer (geiser-debug--buffer))
 172           (when dbg
 173             (ignore-errors (next-error))
 174             (message "=> %s" dbg)))))))
 175
 176 (defsubst geiser-debug--wrap-region (str)
 177   (format "(begin %s)" str))
 178
 179 (defun geiser-debug--unwrap (str)
 180   (if (string-match "(begin[ \t\n\v\r]+\\(.+\\)*)" str)
 181       (match-string 1 str)
 182     str))
 183
 184 (defun geiser-debug--send-region (compile start end and-go wrap &optional nomsg)
 185   (let* ((str (buffer-substring-no-properties start end))
 186          (wrapped (if wrap (geiser-debug--wrap-region str) str))
 187          (code `(,(if compile :comp :eval) (:scm ,wrapped)))
 188          (ret (geiser-eval--send/wait code))
 189          (res (geiser-eval--retort-result-str ret nil))
 190          (err (geiser-eval--retort-error ret)))
 191     (when and-go (funcall and-go))
 192     (when (not err)
 193       (save-excursion
 194         (goto-char (/ (+ end start) 2))
 195         (geiser-autodoc--clean-cache))
 196       (unless nomsg (message "%s" res)))
 197     (geiser-debug--display-retort (geiser-syntax--scheme-str str) ret res)
 198     ret))
 199
 200 (defun geiser-debug--expand-region (start end all wrap)
 201   (let* ((str (buffer-substring-no-properties start end))
 202          (wrapped (if wrap (geiser-debug--wrap-region str) str))
 203          (code `(:eval (:ge macroexpand (quote (:scm ,wrapped))
 204                             ,(if all :t :f))))
 205          (ret (geiser-eval--send/wait code))
 206          (err (geiser-eval--retort-error ret))
 207          (result (geiser-eval--retort-result ret)))
 208     (if err
 209         (geiser-debug--display-retort str ret)
 210       (geiser-debug--with-buffer
 211         (erase-buffer)
 212         (insert (format "%s" (if wrap (geiser-debug--unwrap result) result)))
 213         (goto-char (point-min)))
 214       (geiser-debug--pop-to-buffer))))
 215
 216 \f
 217 (provide 'geiser-debug)