elisp/geiser-debug.el

   1 ;;; geiser-debug.el -- displaying debug information and evaluation results
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013, 2014, 2015 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Mon Feb 23, 2009 22:34
  11
  12 \f
  13
  14 (require 'geiser-edit)
  15 (require 'geiser-autodoc)
  16 (require 'geiser-impl)
  17 (require 'geiser-eval)
  18 (require 'geiser-menu)
  19 (require 'geiser-popup)
  20 (require 'geiser-base)
  21 (require 'geiser-image)
  22
  23 \f
  24 ;;; Customization:
  25
  26 (defgroup geiser-debug nil
  27   "Debugging and error display options."
  28   :group 'geiser)
  29
  30 (geiser-custom--defcustom geiser-debug-always-display-sexp-after-p nil
  31   "Whether to always display the sexp whose evaluation caused an
  32 error after the error message in the debug pop-up. If nil,
  33 expressions shorter than `geiser-debug-long-sexp-lines` lines are
  34 show before the error message."
  35   :group 'geiser-debug
  36   :type 'boolean)
  37
  38 (geiser-custom--defcustom geiser-debug-long-sexp-lines 6
  39   "Length of an expression in order to be relegated to the bottom
  40 of the debug pop-up (after the error message). If
  41 `geiser-debug-always-display-sexp-after-p` is t, this variable
  42 has no effect."
  43   :group 'geiser-debug
  44   :type 'int)
  45
  46 (geiser-custom--defcustom geiser-debug-jump-to-debug-p t
  47   "When set to t (the default), jump to the debug pop-up buffer
  48   in case of evaluation errors.
  49
  50 See also `geiser-debug-show-debug-p`. "
  51   :group 'geiser-debug
  52   :type 'boolean)
  53
  54 (geiser-custom--defcustom geiser-debug-show-debug-p t
  55   "When set to t (the default), show the debug pop-up buffer in
  56   case of evaluation errors.
  57
  58 This option takes effect even if `geiser-debug-jump-to-debug-p`
  59 is set."
  60   :group 'geiser-debug
  61   :type 'boolean)
  62
  63 (geiser-custom--defcustom geiser-debug-auto-display-images-p t
  64   "Whether to automatically invoke the external viewer to display
  65 images when they're evaluated.
  66
  67 See also `geiser-repl-auto-display-images-p'."
  68   :group 'geiser-debug
  69   :type 'boolean)
  70
  71 \f
  72 ;;; Debug buffer mode:
  73
  74 (defvar geiser-debug-mode-map
  75   (let ((map (make-sparse-keymap)))
  76     (suppress-keymap map)
  77     (set-keymap-parent map button-buffer-map)
  78     map))
  79
  80 (defun geiser-debug-mode ()
  81   "A major mode for displaying Scheme compilation and evaluation results.
  82 \\{geiser-debug-mode-map}"
  83   (interactive)
  84   (kill-all-local-variables)
  85   (buffer-disable-undo)
  86   (use-local-map geiser-debug-mode-map)
  87   (set-syntax-table scheme-mode-syntax-table)
  88   (setq mode-name "Geiser DBG")
  89   (setq major-mode 'geiser-debug-mode)
  90   (setq next-error-function 'geiser-edit--open-next)
  91   (setq buffer-read-only t))
  92
  93 (defun geiser-debug--button-p (nextp)
  94   (let ((m (funcall (if nextp 'next-button 'previous-button) (point))))
  95     (and m (funcall (if nextp '< '>) (point) (marker-position m)))))
  96
  97 (geiser-menu--defmenu debug geiser-debug-mode-map
  98   ("Next error" "n" forward-button :enable (geiser-debug--button-p t))
  99   ("Previous error" "p" backward-button :enable (geiser-debug--button-p t))
 100   --
 101   ("Quit" nil View-quit))
 102
 103 \f
 104 ;;; Buffer for displaying evaluation results:
 105
 106 (geiser-popup--define debug "*Geiser dbg*" geiser-debug-mode)
 107
 108 \f
 109 ;;; Displaying retorts
 110
 111 (geiser-impl--define-caller geiser-debug--display-error
 112     display-error (module key message)
 113     "This method takes 3 parameters (a module name, the error key,
 114 and the accompanying error message) and should display
 115 (in the current buffer) a formatted version of the error. If the
 116 error was successfully displayed, the call should evaluate to a
 117 non-null value.")
 118
 119 (geiser-impl--define-caller geiser-debug--enter-debugger
 120     enter-debugger ()
 121   "This method is called upon entering the debugger, in the REPL
 122 buffer.")
 123
 124 (defun geiser-debug--display-after (what)
 125   (or geiser-debug-always-display-sexp-after-p
 126       (>= (with-temp-buffer
 127             (insert what)
 128             (count-lines (point-min) (point-max)))
 129           geiser-debug-long-sexp-lines)))
 130
 131 (defun geiser-debug--insert-res (res)
 132   (let ((begin (point)))
 133     (insert res)
 134     (let ((end (point)))
 135       (goto-char begin)
 136       (let ((no (geiser-image--replace-images
 137                  t geiser-debug-auto-display-images-p)))
 138         (goto-char end)
 139         (newline 2)
 140         (and no (> no 0))))))
 141
 142 (defun geiser-debug--display-retort (what ret &optional res auto-p)
 143   (let* ((err (geiser-eval--retort-error ret))
 144          (key (geiser-eval--error-key err))
 145          (output (geiser-eval--retort-output ret))
 146          (impl geiser-impl--implementation)
 147          (module (geiser-eval--get-module))
 148          (dbg nil)
 149          (img nil)
 150          (dir default-directory)
 151          (buffer (current-buffer))
 152          (debug (eq key 'geiser-debugger))
 153          (after (geiser-debug--display-after what)))
 154     (when debug
 155       (switch-to-geiser nil nil buffer)
 156       (geiser-debug--enter-debugger impl))
 157     (geiser-debug--with-buffer
 158       (erase-buffer)
 159       (when dir (setq default-directory dir))
 160       (unless after
 161         (geiser-debug--display-error impl module nil what)
 162         (newline 2))
 163       (setq img (when (and res (not err)) (geiser-debug--insert-res res)))
 164       (setq dbg (geiser-debug--display-error impl module key output))
 165       (when after
 166         (goto-char (point-max))
 167         (insert "\nExpression evaluated was:\n\n")
 168         (geiser-debug--display-error impl module nil what))
 169       (goto-char (point-min)))
 170     (when (or img dbg)
 171       (geiser-debug--pop-to-buffer)
 172       (when (and dbg (not geiser-debug-jump-to-debug-p))
 173         (next-error)
 174         (when (not geiser-debug-show-debug-p)
 175           (pop-to-buffer (geiser-debug--buffer)
 176                          'display-buffer-reuse-window t)
 177           (View-quit))
 178         (message "Evaluation error: %s" dbg)))))
 179
 180 (defsubst geiser-debug--wrap-region (str)
 181   (format "(begin %s)" str))
 182
 183 (defun geiser-debug--unwrap (str)
 184   (if (string-match "(begin[ \t\n\v\r]+\\(.+\\)*)" str)
 185       (match-string 1 str)
 186     str))
 187
 188 (defun geiser-debug--send-region (compile start end and-go wrap &optional nomsg)
 189   (let* ((str (buffer-substring-no-properties start end))
 190          (wrapped (if wrap (geiser-debug--wrap-region str) str))
 191          (code `(,(if compile :comp :eval) (:scm ,wrapped)))
 192          (ret (geiser-eval--send/wait code))
 193          (res (geiser-eval--retort-result-str ret nil))
 194          (err (geiser-eval--retort-error ret)))
 195     (when and-go (funcall and-go))
 196     (when (not err)
 197       (save-excursion
 198         (goto-char (/ (+ end start) 2))
 199         (geiser-autodoc--clean-cache))
 200       (unless nomsg (message "%s" res)))
 201     (geiser-debug--display-retort (geiser-syntax--scheme-str str) ret res)
 202     ret))
 203
 204 (defun geiser-debug--expand-region (start end all wrap)
 205   (let* ((str (buffer-substring-no-properties start end))
 206          (wrapped (if wrap (geiser-debug--wrap-region str) str))
 207          (code `(:eval (:ge macroexpand (quote (:scm ,wrapped))
 208                             ,(if all :t :f))))
 209          (ret (geiser-eval--send/wait code))
 210          (err (geiser-eval--retort-error ret))
 211          (result (geiser-eval--retort-result ret)))
 212     (if err
 213         (geiser-debug--display-retort str ret)
 214       (geiser-debug--with-buffer
 215         (erase-buffer)
 216         (insert (format "%s" (if wrap (geiser-debug--unwrap result) result)))
 217         (goto-char (point-min)))
 218       (geiser-debug--pop-to-buffer))))
 219
 220 \f
 221 (provide 'geiser-debug)