elisp/geiser-mode.el

   1 ;; geiser-mode.el -- minor mode for scheme buffers
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013, 2014, 2015, 2016, 2017 Jose Antonio Ortega Ruiz
   4
   5 ;; This program is free software; you can redistribute it and/or
   6 ;; modify it under the terms of the Modified BSD License. You should
   7 ;; have received a copy of the license along with this program. If
   8 ;; not, see <http://www.xfree86.org/3.3.6/COPYRIGHT2.html#5>.
   9
  10 ;; Start date: Sun Feb 08, 2009 15:13
  11
  12 \f
  13
  14 (require 'geiser-repl)
  15 (require 'geiser-menu)
  16 (require 'geiser-doc)
  17 (require 'geiser-compile)
  18 (require 'geiser-completion)
  19 (require 'geiser-company)
  20 (require 'geiser-xref)
  21 (require 'geiser-edit)
  22 (require 'geiser-autodoc)
  23 (require 'geiser-debug)
  24 (require 'geiser-syntax)
  25 (require 'geiser-impl)
  26 (require 'geiser-eval)
  27 (require 'geiser-popup)
  28 (require 'geiser-custom)
  29 (require 'geiser-base)
  30
  31 \f
  32 ;;; Customization:
  33
  34 (defgroup geiser-mode nil
  35   "Mode enabling Geiser abilities in Scheme buffers &co.."
  36   :group 'geiser)
  37
  38 (geiser-custom--defcustom geiser-mode-auto-p t
  39   "Whether `geiser-mode' should be active by default in all scheme buffers."
  40   :group 'geiser-mode
  41   :type 'boolean)
  42
  43 (geiser-custom--defcustom geiser-mode-start-repl-p nil
  44   "Whether a REPL should be automatically started if one is not
  45 active when `geiser-mode' is activated in a buffer."
  46   :group 'geiser-mode
  47   :type 'boolean)
  48
  49 (geiser-custom--defcustom geiser-mode-autodoc-p t
  50   "Whether `geiser-autodoc-mode' gets enabled by default in Scheme buffers."
  51   :group 'geiser-mode
  52   :group 'geiser-autodoc
  53   :type 'boolean)
  54
  55 (geiser-custom--defcustom geiser-mode-company-p t
  56   "Whether to use company-mode for completion, if available."
  57   :group 'geiser-mode
  58   :type 'boolean)
  59
  60 (geiser-custom--defcustom geiser-mode-smart-tab-p nil
  61   "Whether `geiser-smart-tab-mode' gets enabled by default in Scheme buffers."
  62   :group 'geiser-mode
  63   :type 'boolean)
  64
  65 (geiser-custom--defcustom geiser-mode-eval-last-sexp-to-buffer nil
  66   "Whether `eval-last-sexp' prints results to buffer"
  67   :group 'geiser-mode
  68   :type 'boolean)
  69
  70 (geiser-custom--defcustom geiser-mode-eval-to-buffer-prefix " "
  71   "When `geiser-mode-eval-last-sexp-to-buffer', the prefix string which will prepend to results"
  72   :group 'geiser-mode
  73   :type 'string)
  74
  75
  76 \f
  77 ;;; Evaluation commands:
  78
  79 (defun geiser--go-to-repl ()
  80   (switch-to-geiser nil nil (current-buffer))
  81   (push-mark)
  82   (goto-char (point-max)))
  83
  84 (defun geiser-eval-region (start end &optional and-go raw nomsg)
  85   "Eval the current region in the Geiser REPL.
  86
  87 With prefix, goes to the REPL buffer afterwards (as
  88 `geiser-eval-region-and-go')"
  89   (interactive "rP")
  90   (save-restriction
  91     (narrow-to-region start end)
  92     (check-parens))
  93   (geiser-debug--send-region nil
  94                              start
  95                              end
  96                              (and and-go 'geiser--go-to-repl)
  97                              (not raw)
  98                              nomsg))
  99
 100 (defun geiser-eval-region-and-go (start end)
 101   "Eval the current region in the Geiser REPL and visit it afterwads."
 102   (interactive "r")
 103   (geiser-eval-region start end t))
 104
 105 (geiser-impl--define-caller geiser-eval--bounds eval-bounds ()
 106   "A pair with the bounds of a buffer to be evaluated, defaulting
 107   to (cons (point-min) . (point-max)).")
 108
 109 (defun geiser-eval-buffer (&optional and-go raw nomsg)
 110   "Eval the current buffer in the Geiser REPL.
 111
 112 With prefix, goes to the REPL buffer afterwards (as
 113 `geiser-eval-buffer-and-go')"
 114   (interactive "P")
 115   (let* ((bounds (geiser-eval--bounds geiser-impl--implementation))
 116          (from (or (car bounds) (point-min)))
 117          (to (or (cdr bounds) (point-max))))
 118     (geiser-eval-region from to and-go raw nomsg)))
 119
 120 (defun geiser-eval-buffer-and-go ()
 121   "Eval the current buffer in the Geiser REPL and visit it afterwads."
 122   (interactive)
 123   (geiser-eval-buffer t))
 124
 125 (defun geiser-eval-definition (&optional and-go)
 126   "Eval the current definition in the Geiser REPL.
 127
 128 With prefix, goes to the REPL buffer afterwards (as
 129 `geiser-eval-definition-and-go')"
 130   (interactive "P")
 131   (save-excursion
 132     (end-of-defun)
 133     (let ((end (point)))
 134       (beginning-of-defun)
 135       (geiser-eval-region (point) end and-go t))))
 136
 137 (defun geiser-eval-definition-and-go ()
 138   "Eval the current definition in the Geiser REPL and visit it afterwads."
 139   (interactive)
 140   (geiser-eval-definition t))
 141
 142 (defun geiser-eval-last-sexp (print-to-buffer-p)
 143   "Eval the previous sexp in the Geiser REPL.
 144
 145 With a prefix, revert the effect of `geiser-mode-eval-last-sexp-to-buffer' "
 146   (interactive "P")
 147   (let* (bosexp
 148          (eosexp (save-excursion (backward-sexp)
 149                                  (setq bosexp (point))
 150                                  (forward-sexp)
 151                                  (point)))
 152          (ret (geiser-eval-region bosexp ;beginning of sexp
 153                                   eosexp ;end of sexp
 154                                   nil
 155                                   t
 156                                   print-to-buffer-p))
 157          (err (geiser-eval--retort-error ret))
 158          (will-eval-to-buffer (if print-to-buffer-p
 159                                   (not geiser-mode-eval-last-sexp-to-buffer)
 160                                 geiser-mode-eval-last-sexp-to-buffer))
 161          (str (geiser-eval--retort-result-str ret (when will-eval-to-buffer ""))))
 162     (cond  ((not will-eval-to-buffer) str)
 163            (err (insert (format "%sERROR:%s"
 164                                 geiser-mode-eval-to-buffer-prefix
 165                                 (geiser-eval--error-str err))))
 166            ((string= "" str))
 167            (t (push-mark)
 168               (insert (format "%s%s" geiser-mode-eval-to-buffer-prefix str))))))
 169
 170 (defun geiser-compile-definition (&optional and-go)
 171   "Compile the current definition in the Geiser REPL.
 172
 173 With prefix, goes to the REPL buffer afterwards (as
 174 `geiser-eval-definition-and-go')"
 175   (interactive "P")
 176   (save-excursion
 177     (end-of-defun)
 178     (let ((end (point)))
 179       (beginning-of-defun)
 180       (geiser-debug--send-region t
 181                                  (point)
 182                                  end
 183                                  (and and-go 'geiser--go-to-repl)
 184                                  t))))
 185
 186 (defun geiser-compile-definition-and-go ()
 187   "Compile the current definition in the Geiser REPL and visit it afterwads."
 188   (interactive)
 189   (geiser-compile-definition t))
 190
 191 (defun geiser-expand-region (start end &optional all raw)
 192   "Macro-expand the current region and display it in a buffer.
 193 With prefix, recursively macro-expand the resulting expression."
 194   (interactive "rP")
 195   (geiser-debug--expand-region start end all (not raw)))
 196
 197 (defun geiser-expand-definition (&optional all)
 198   "Macro-expand the current definition.
 199
 200 With prefix, recursively macro-expand the resulting expression."
 201   (interactive "P")
 202   (save-excursion
 203     (end-of-defun)
 204     (let ((end (point)))
 205       (beginning-of-defun)
 206       (geiser-expand-region (point) end all t))))
 207
 208 (defun geiser-expand-last-sexp (&optional all)
 209   "Macro-expand the previous sexp.
 210
 211 With prefix, recursively macro-expand the resulting expression."
 212   (interactive "P")
 213   (geiser-expand-region (save-excursion (backward-sexp) (point))
 214                         (point)
 215                         all
 216                         t))
 217
 218 (defun geiser-set-scheme ()
 219   "Associates current buffer with a given Scheme implementation."
 220   (interactive)
 221   (geiser-syntax--remove-kws)
 222   (let ((impl (geiser-impl--read-impl)))
 223     (geiser-impl--set-buffer-implementation impl)
 224     (geiser-repl--set-up-repl impl)
 225     (geiser-syntax--add-kws)
 226     (geiser-syntax--fontify)))
 227
 228 (defun geiser-mode-switch-to-repl (arg)
 229   "Switches to Geiser REPL.
 230
 231 With prefix, try to enter the current buffer's module."
 232   (interactive "P")
 233   (if arg
 234       (switch-to-geiser-module (geiser-eval--get-module) (current-buffer))
 235     (switch-to-geiser nil nil (current-buffer))))
 236
 237 (defun geiser-mode-switch-to-repl-and-enter ()
 238   "Switches to Geiser REPL and enters current buffer's module."
 239   (interactive)
 240   (geiser-mode-switch-to-repl t))
 241
 242 (defun geiser-restart-repl ()
 243   "Restarts the REPL associated with the current buffer."
 244   (interactive)
 245   (let ((b (current-buffer)))
 246     (geiser-mode-switch-to-repl nil)
 247     (comint-kill-subjob)
 248     (sit-for 0.1) ;; ugly hack; but i don't care enough to fix it
 249     (call-interactively 'run-geiser)
 250     (sit-for 0.2) ;; ditto
 251     (goto-char (point-max))
 252     (pop-to-buffer b)))
 253
 254 (defun geiser-squarify (n)
 255   "Toggle between () and [] for current form.
 256
 257 With numeric prefix, perform that many toggles, forward for
 258 positive values and backward for negative."
 259   (interactive "p")
 260   (let ((pared (and (boundp 'paredit-mode) paredit-mode))
 261         (fwd (> n 0))
 262         (steps (abs n)))
 263     (when (and pared (fboundp 'paredit-mode)) (paredit-mode -1))
 264     (unwind-protect
 265         (save-excursion
 266           (unless (looking-at-p "\\s(") (backward-up-list))
 267           (while (> steps 0)
 268             (let ((p (point))
 269                   (round (looking-at-p "(")))
 270               (forward-sexp)
 271               (backward-delete-char 1)
 272               (insert (if round "]" ")"))
 273               (goto-char p)
 274               (delete-char 1)
 275               (insert (if round "[" "("))
 276               (setq steps (1- steps))
 277               (backward-char)
 278               (condition-case nil
 279                   (progn (when fwd (forward-sexp 2))
 280                          (backward-sexp))
 281                 (error (setq steps 0))))))
 282       (when (and pared (fboundp 'paredit-mode)) (paredit-mode 1)))))
 283
 284 (defun geiser-insert-lambda (&optional full)
 285   "Insert λ at point.  With prefix, inserts (λ ())."
 286   (interactive "P")
 287   (if (not full)
 288       (insert (make-char 'greek-iso8859-7 107))
 289     (insert "(" (make-char 'greek-iso8859-7 107) " ())")
 290     (backward-char 2)))
 291
 292 \f
 293 ;;; Geiser mode:
 294
 295 (make-variable-buffer-local
 296  (defvar geiser-mode-string nil
 297    "Modeline indicator for geiser-mode"))
 298
 299 (defun geiser-mode--lighter ()
 300   (or geiser-mode-string
 301       (format " %s" (or (geiser-impl--impl-str) "G"))))
 302
 303 (defvar geiser-mode-map (make-sparse-keymap))
 304
 305 (define-minor-mode geiser-mode
 306   "Toggle Geiser's mode.
 307
 308 With no argument, this command toggles the mode.
 309 Non-null prefix argument turns on the mode.
 310 Null prefix argument turns off the mode.
 311
 312 When Geiser mode is enabled, a host of nice utilities for
 313 interacting with the Geiser REPL is at your disposal.
 314 \\{geiser-mode-map}"
 315   :init-value nil
 316   :lighter (:eval (geiser-mode--lighter))
 317   :group 'geiser-mode
 318   :keymap geiser-mode-map
 319   (when geiser-mode (geiser-impl--set-buffer-implementation nil t))
 320   (setq geiser-autodoc-mode-string "/A")
 321   (setq geiser-smart-tab-mode-string "/T")
 322   (geiser-company--setup (and geiser-mode geiser-mode-company-p))
 323   (geiser-completion--setup geiser-mode)
 324   (when geiser-mode-autodoc-p
 325     (geiser-autodoc-mode (if geiser-mode 1 -1)))
 326   (when geiser-mode-smart-tab-p
 327     (geiser-smart-tab-mode (if geiser-mode 1 -1)))
 328   (geiser-syntax--add-kws)
 329   (when (and geiser-mode
 330              geiser-mode-start-repl-p
 331              (not (geiser-syntax--font-lock-buffer-p))
 332              (not (geiser-repl--connection*)))
 333     (save-window-excursion (run-geiser geiser-impl--implementation))))
 334
 335 (defun turn-on-geiser-mode ()
 336   "Enable `geiser-mode' (in a Scheme buffer)."
 337   (interactive)
 338   (geiser-mode 1))
 339
 340 (defun turn-off-geiser-mode ()
 341   "Disable `geiser-mode' (in a Scheme buffer)."
 342   (interactive)
 343   (geiser-mode -1))
 344
 345 (defun geiser-mode--maybe-activate ()
 346   (when (and geiser-mode-auto-p (eq major-mode 'scheme-mode))
 347     (turn-on-geiser-mode)))
 348
 349 \f
 350 ;;; Keys:
 351
 352 (geiser-menu--defmenu geiserm geiser-mode-map
 353   ("Eval sexp before point" "\C-x\C-e" geiser-eval-last-sexp)
 354   ("Eval definition" ("\M-\C-x" "\C-c\C-c") geiser-eval-definition)
 355   ("Eval definition and go" ("\C-c\M-e" "\C-c\M-e")
 356    geiser-eval-definition-and-go)
 357   ("Eval region" "\C-c\C-r" geiser-eval-region :enable mark-active)
 358   ("Eval region and go" "\C-c\M-r" geiser-eval-region-and-go
 359    geiser-eval-region :enable mark-active)
 360   ("Eval buffer" "\C-c\C-b" geiser-eval-buffer)
 361   ("Eval buffer and go" "\C-c\M-b" geiser-eval-buffer-and-go)
 362   ("Load scheme file..." "\C-c\C-l" geiser-load-file)
 363   (menu "Macroexpand"
 364         ("Sexp before point" ("\C-c\C-m\C-e" "\C-c\C-me")
 365          geiser-expand-last-sexp)
 366         ("Region" ("\C-c\C-m\C-r" "\C-c\C-mr") geiser-expand-region)
 367         ("Definition" ("\C-c\C-m\C-x" "\C-c\C-mx") geiser-expand-definition))
 368   --
 369   ("Symbol documentation" ("\C-c\C-d\C-d" "\C-c\C-dd")
 370    geiser-doc-symbol-at-point :enable (geiser--symbol-at-point))
 371   ("Short symbol documentation" ("\C-c\C-d\C-s" "\C-c\C-ds")
 372    geiser-autodoc-show :enable (geiser--symbol-at-point))
 373   ("Module documentation" ("\C-c\C-d\C-m" "\C-c\C-dm") geiser-doc-module)
 374   ("Symbol manual lookup" ("\C-c\C-d\C-i" "\C-c\C-di")
 375    geiser-doc-look-up-manual :enable (geiser-doc--manual-available-p))
 376   (mode "Autodoc mode" ("\C-c\C-d\C-a" "\C-c\C-da") geiser-autodoc-mode)
 377   --
 378   ("Compile buffer" "\C-c\C-k" geiser-compile-current-buffer)
 379   ("Switch to REPL" "\C-c\C-z" geiser-mode-switch-to-repl)
 380   ("Switch to REPL and enter module" "\C-c\C-a"
 381    geiser-mode-switch-to-repl-and-enter)
 382   ("Set Scheme..." "\C-c\C-s" geiser-set-scheme)
 383   --
 384   ("Edit symbol at point" "\M-." geiser-edit-symbol-at-point
 385    :enable (geiser--symbol-at-point))
 386   ("Go to previous definition" "\M-," geiser-pop-symbol-stack)
 387   ("Complete symbol" ((kbd "M-TAB")) completion-at-point
 388    :enable (geiser--symbol-at-point))
 389   ("Complete module name" ((kbd "M-`") (kbd "C-."))
 390    geiser-completion--complete-module)
 391   ("Edit module" ("\C-c\C-e\C-m" "\C-c\C-em") geiser-edit-module)
 392   ("Add to load path..." ("\C-c\C-e\C-l" "\C-c\C-el") geiser-add-to-load-path)
 393   ("Toggle ()/[]" ("\C-c\C-e\C-[" "\C-c\C-e[") geiser-squarify)
 394   ("Insert λ" ("\C-c\\" "\C-c\C-\\") geiser-insert-lambda)
 395   --
 396   ("Callers" ((kbd "C-c <")) geiser-xref-callers
 397    :enable (and (geiser-eval--supported-p 'callers)
 398                 (geiser--symbol-at-point)))
 399   ("Callees" ((kbd "C-c >")) geiser-xref-callees
 400    :enable (and (geiser-eval--supported-p 'callees)
 401                 (geiser--symbol-at-point)))
 402   --
 403   (mode "Smart TAB mode" nil geiser-smart-tab-mode)
 404   --
 405   (custom "Customize Geiser mode" geiser-mode))
 406
 407 (define-key geiser-mode-map [menu-bar scheme] 'undefined)
 408
 409 ;; (geiser-mode--triple-chord ?x ?m 'geiser-xref-generic-methods)
 410
 411 \f
 412 ;;; Reload support:
 413
 414 (defun geiser-mode--buffers ()
 415   (let ((buffers))
 416     (dolist (buffer (buffer-list))
 417       (when (buffer-live-p buffer)
 418         (set-buffer buffer)
 419         (when geiser-mode
 420           (push (cons buffer geiser-impl--implementation) buffers))))
 421     buffers))
 422
 423 (defun geiser-mode--restore (buffers)
 424   (dolist (b buffers)
 425     (when (buffer-live-p (car b))
 426       (set-buffer (car b))
 427       (when (cdr b)
 428         (geiser-impl--set-buffer-implementation (cdr b)))
 429       (geiser-mode 1))))
 430
 431 (defun geiser-mode-unload-function ()
 432   (dolist (b (geiser-mode--buffers))
 433     (with-current-buffer (car b) (geiser-mode nil))))
 434
 435 \f
 436 (provide 'geiser-mode)